src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 (defconstant most-positive-fixnum #.sb!vm:*target-most-positive-fixnum*
  17   #!+sb-doc
  18   "the fixnum closest in value to positive infinity")
  19
  20 (defconstant most-negative-fixnum #.sb!vm:*target-most-negative-fixnum*
  21   #!+sb-doc
  22   "the fixnum closest in value to negative infinity")
  23 \f
  24 ;;;; magic specials initialized by GENESIS
  25
  26 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  27 ;;; of all static symbols in early-impl.lisp.
  28 (progn
  29   (defvar *current-catch-block*)
  30   (defvar *current-unwind-protect-block*)
  31   (defvar *free-interrupt-context-index*))
  32 \f
  33 ;;; specials initialized by !COLD-INIT
  34
  35 ;;; FIXME: These could be converted to DEFVARs.
  36 (declaim (special *gc-inhibit* *already-maybe-gcing*
  37                   *need-to-collect-garbage*
  38                   *gc-notify-stream*
  39                   *before-gc-hooks* *after-gc-hooks*
  40                   #!+x86 *pseudo-atomic-atomic*
  41                   #!+x86 *pseudo-atomic-interrupted*
  42                   sb!unix::*interrupts-enabled*
  43                   sb!unix::*interrupt-pending*
  44                   *type-system-initialized*))
  45
  46 (defvar *cold-init-complete-p*)
  47
  48 ;;; counts of nested errors (with internal errors double-counted)
  49 (defvar *maximum-error-depth*)
  50 (defvar *current-error-depth*)
  51 \f
  52 ;;;; miscellaneous utilities for working with with TOPLEVEL
  53
  54 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  55 ;;; by QUIT) is caught and any final processing and return codes are
  56 ;;; handled appropriately.
  57 (defmacro handling-end-of-the-world (&body body)
  58   (let ((caught (gensym "CAUGHT")))
  59     `(let ((,caught (catch '%end-of-the-world
  60                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  61                       ,@body)))
  62        (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  63        (flush-standard-output-streams)
  64        (/show0 "calling UNIX-EXIT")
  65        (sb!unix:unix-exit ,caught))))
  66 \f
  67 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  68
  69 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  70 ;;; of hyperspace.
  71 (defmacro infinite-error-protect (&rest forms)
  72   `(unless (infinite-error-protector)
  73      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  74      (let ((*current-error-depth* (1+ *current-error-depth*)))
  75        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  76        #+sb-show (sb-debug:backtrace)
  77        ,@forms)))
  78
  79 ;;; a helper function for INFINITE-ERROR-PROTECT
  80 (defun infinite-error-protector ()
  81   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  82   (/hexstr *current-error-depth*)
  83   (cond ((not *cold-init-complete-p*)
  84          (%primitive print "Argh! error in cold init, halting")
  85          (%primitive sb!c:halt))
  86         ((or (not (boundp '*current-error-depth*))
  87              (not (realp   *current-error-depth*))
  88              (not (boundp '*maximum-error-depth*))
  89              (not (realp   *maximum-error-depth*)))
  90          (%primitive print "Argh! corrupted error depth, halting")
  91          (%primitive sb!c:halt))
  92         ((> *current-error-depth* *maximum-error-depth*)
  93          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  94          (/hexstr *maximum-error-depth*)
  95          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  96          (error-error "Help! "
  97                       *current-error-depth*
  98                       " nested errors. "
  99                       "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 100          t)
 101         (t
 102          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 103          nil)))
 104
 105 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 106 ;;; one point (shown below), and SBCL cross-compiled it without
 107 ;;; warning about FORMS being undefined. Check whether that problem
 108 ;;; (missing warning) is repeatable in the final system and if so, fix
 109 ;;; it.
 110 #|
 111 (defun infinite-error-protector ()
 112   `(cond ((not *cold-init-complete-p*)
 113           (%primitive print "Argh! error in cold init, halting")
 114           (%primitive sb!c:halt))
 115          ((or (not (boundp '*current-error-depth*))
 116               (not (realp   *current-error-depth*))
 117               (not (boundp '*maximum-error-depth*))
 118               (not (realp   *maximum-error-depth*)))
 119           (%primitive print "Argh! corrupted error depth, halting")
 120           (%primitive sb!c:halt))
 121          ((> *current-error-depth* *maximum-error-depth*)
 122           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 123           (error-error "Help! "
 124                        *current-error-depth*
 125                        " nested errors. "
 126                        "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 127           (progn ,@forms)
 128           t)
 129          (t
 130           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 131           nil)))
 132 |#
 133 \f
 134 ;;;; miscellaneous external functions
 135
 136 #!-mp ; The multi-processing version is defined in multi-proc.lisp.
 137 (defun sleep (n)
 138   #!+sb-doc
 139   "This function causes execution to be suspended for N seconds. N may
 140   be any non-negative, non-complex number."
 141   (when (or (not (realp n))
 142             (minusp n))
 143     (error "Invalid argument to SLEEP: ~S.~%~
 144             Must be a non-negative, non-complex number."
 145            n))
 146   (multiple-value-bind (sec usec)
 147       (if (integerp n)
 148           (values n 0)
 149           (multiple-value-bind (sec frac)
 150               (truncate n)
 151             (values sec(truncate frac 1e-6))))
 152     (sb!unix:unix-select 0 0 0 0 sec usec))
 153   nil)
 154 \f
 155 ;;;; SCRUB-CONTROL-STACK
 156
 157 (defconstant bytes-per-scrub-unit 2048)
 158
 159 ;;; Zero the unused portion of the control stack so that old objects
 160 ;;; are not kept alive because of uninitialized stack variables.
 161 ;;;
 162 ;;; FIXME: Why do we need to do this instead of just letting GC read
 163 ;;; the stack pointer and avoid messing with the unused portion of
 164 ;;; the control stack? (Is this a multithreading thing where there's
 165 ;;; one control stack and stack pointer per thread, and it might not
 166 ;;; be easy to tell what a thread's stack pointer value is when
 167 ;;; looking in from another thread?)
 168 (defun scrub-control-stack ()
 169   (declare (optimize (speed 3) (safety 0))
 170            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 171
 172   #!-x86 ; machines where stack grows upwards (I guess) -- WHN 19990906
 173   (labels
 174       ((scrub (ptr offset count)
 175          (declare (type system-area-pointer ptr)
 176                   (type (unsigned-byte 16) offset)
 177                   (type (unsigned-byte 20) count)
 178                   (values (unsigned-byte 20)))
 179          (cond ((= offset bytes-per-scrub-unit)
 180                 (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 181                (t
 182                 (setf (sap-ref-32 ptr offset) 0)
 183                 (scrub ptr (+ offset sb!vm:word-bytes) count))))
 184        (look (ptr offset count)
 185          (declare (type system-area-pointer ptr)
 186                   (type (unsigned-byte 16) offset)
 187                   (type (unsigned-byte 20) count)
 188                   (values (unsigned-byte 20)))
 189          (cond ((= offset bytes-per-scrub-unit)
 190                 count)
 191                ((zerop (sap-ref-32 ptr offset))
 192                 (look ptr (+ offset sb!vm:word-bytes) count))
 193                (t
 194                 (scrub ptr offset (+ count sb!vm:word-bytes))))))
 195     (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 196            (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 197       (declare (type (unsigned-byte 32) csp))
 198       (scrub (int-sap (- csp initial-offset))
 199              (* (floor initial-offset sb!vm:word-bytes) sb!vm:word-bytes)
 200              0)))
 201
 202   #!+x86 ;; (Stack grows downwards.)
 203   (labels
 204       ((scrub (ptr offset count)
 205          (declare (type system-area-pointer ptr)
 206                   (type (unsigned-byte 16) offset)
 207                   (type (unsigned-byte 20) count)
 208                   (values (unsigned-byte 20)))
 209          (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:word-bytes)))))
 210            (cond ((= offset bytes-per-scrub-unit)
 211                   (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 212                         0 count))
 213                  (t ;; need to fix bug in %SET-STACK-REF
 214                   (setf (sap-ref-32 loc 0) 0)
 215                   (scrub ptr (+ offset sb!vm:word-bytes) count)))))
 216        (look (ptr offset count)
 217          (declare (type system-area-pointer ptr)
 218                   (type (unsigned-byte 16) offset)
 219                   (type (unsigned-byte 20) count)
 220                   (values (unsigned-byte 20)))
 221          (let ((loc (int-sap (- (sap-int ptr) offset))))
 222            (cond ((= offset bytes-per-scrub-unit)
 223                   count)
 224                  ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 225                   (look ptr (+ offset sb!vm:word-bytes) count))
 226                  (t
 227                   (scrub ptr offset (+ count sb!vm:word-bytes)))))))
 228     (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 229            (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 230       (declare (type (unsigned-byte 32) csp))
 231       (scrub (int-sap (+ csp initial-offset))
 232              (* (floor initial-offset sb!vm:word-bytes) sb!vm:word-bytes)
 233              0))))
 234 \f
 235 ;;;; the default toplevel function
 236
 237 ;;; FIXME: Most stuff below here can probably be byte-compiled.
 238
 239 (defvar / nil
 240   #!+sb-doc
 241   "a list of all the values returned by the most recent top-level EVAL")
 242 (defvar //  nil #!+sb-doc "the previous value of /")
 243 (defvar /// nil #!+sb-doc "the previous value of //")
 244 (defvar *   nil #!+sb-doc "the value of the most recent top-level EVAL")
 245 (defvar **  nil #!+sb-doc "the previous value of *")
 246 (defvar *** nil #!+sb-doc "the previous value of **")
 247 (defvar +   nil #!+sb-doc "the value of the most recent top-level READ")
 248 (defvar ++  nil #!+sb-doc "the previous value of +")
 249 (defvar +++ nil #!+sb-doc "the previous value of ++")
 250 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 251 (defvar *prompt* "* "
 252   #!+sb-doc
 253   "The top-level prompt string. This also may be a function of no arguments
 254    that returns a simple-string.")
 255
 256 (defun interactive-eval (form)
 257   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 258    +++, ++, +, ///, //, /, and -."
 259   (setf - form)
 260   (let ((results (multiple-value-list (eval form))))
 261     (setf /// //
 262           // /
 263           / results
 264           *** **
 265           ** *
 266           * (car results)))
 267   (setf +++ ++
 268         ++ +
 269         + -)
 270   (unless (boundp '*)
 271     ;; The bogon returned an unbound marker.
 272     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 273     ;; instead of just the first one.
 274     (setf * nil)
 275     (cerror "Go on with * set to NIL."
 276             "EVAL returned an unbound marker."))
 277   (values-list /))
 278
 279 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 280 ;;; output streams before proceeding.
 281 (defun flush-standard-output-streams ()
 282   (dolist (name '(*debug-io*
 283                   *error-output*
 284                   *query-io*
 285                   *standard-output*
 286                   *trace-output*))
 287     (finish-output (symbol-value name)))
 288   (values))
 289
 290 ;;; the default system top-level function
 291 (defun toplevel-init ()
 292
 293   (/show0 "entering TOPLEVEL-INIT")
 294
 295   (let ((sysinit nil)        ; value of --sysinit option
 296         (userinit nil)       ; value of --userinit option
 297         (reversed-evals nil) ; values of --eval options, in reverse order
 298         (noprint nil)        ; Has a --noprint option been seen?
 299         (noprogrammer nil)   ; Has a --noprogammer option been seen?
 300         (options (rest *posix-argv*))) ; skipping program name
 301
 302     (/show0 "done with outer LET in TOPLEVEL-INIT")
 303
 304     ;; FIXME: There are lots of ways for errors to happen around here
 305     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 306     ;; READ an --eval string). Make sure that they're handled
 307     ;; reasonably. Also, perhaps all errors while parsing the command
 308     ;; line should cause the system to QUIT, instead of trying to go
 309     ;; into the Lisp debugger.
 310
 311     ;; Parse command line options.
 312     (loop while options do
 313           (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 314           (let ((option (first options)))
 315             (flet ((pop-option ()
 316                      (if options
 317                          (pop options)
 318                          (error "unexpected end of command line options"))))
 319               (cond ((string= option "--sysinit")
 320                      (pop-option)
 321                      (if sysinit
 322                          (error "multiple --sysinit options")
 323                          (setf sysinit (pop-option))))
 324                     ((string= option "--userinit")
 325                      (pop-option)
 326                      (if userinit
 327                          (error "multiple --userinit options")
 328                          (setf userinit (pop-option))))
 329                     ((string= option "--eval")
 330                      (pop-option)
 331                      (let ((eval-as-string (pop-option)))
 332                        (with-input-from-string (eval-stream eval-as-string)
 333                          (let* ((eof-marker (cons :eof :eof))
 334                                 (eval (read eval-stream nil eof-marker))
 335                                 (eof (read eval-stream nil eof-marker)))
 336                            (cond ((eq eval eof-marker)
 337                                   (error "unable to parse ~S"
 338                                          eval-as-string))
 339                                  ((not (eq eof eof-marker))
 340                                   (error "more than one expression in ~S"
 341                                          eval-as-string))
 342                                  (t
 343                                   (push eval reversed-evals)))))))
 344                     ((string= option "--noprint")
 345                      (pop-option)
 346                      (setf noprint t))
 347                     ((string= option "--noprogrammer")
 348                      (pop-option)
 349                      (setf noprogrammer t))
 350                     ((string= option "--end-toplevel-options")
 351                      (pop-option)
 352                      (return))
 353                     (t
 354                      ;; Anything we don't recognize as a toplevel
 355                      ;; option must be the start of user-level
 356                      ;; options.. except that if we encounter
 357                      ;; "--end-toplevel-options" after we gave up
 358                      ;; because we didn't recognize an option as a
 359                      ;; toplevel option, then the option we gave up on
 360                      ;; must have been an error. (E.g. in
 361                      ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 362                      ;; this test will let us detect that the string
 363                      ;; "--eval(b)" is an error.)
 364                      (if (find "--end-toplevel-options" options
 365                                :test #'string=)
 366                          (error "bad toplevel option: ~S" (first options))
 367                          (return)))))))
 368     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 369
 370     ;; Excise all the options that we processed, so that only
 371     ;; user-level options are left visible to user code.
 372     (setf (rest *posix-argv*) options)
 373
 374     ;; Handle --noprogrammer option. We intentionally do this
 375     ;; early so that it will affect the handling of initialization
 376     ;; files and --eval options.
 377     (/show0 "handling --noprogrammer option in TOPLEVEL-INIT")
 378     (when noprogrammer
 379       (setf *debugger-hook* 'noprogrammer-debugger-hook-fun
 380             *debug-io* *error-output*))
 381
 382     ;; FIXME: Verify that errors in init files and/or --eval operations
 383     ;; lead to reasonable behavior.
 384
 385     ;; Handle initialization files.
 386     (/show0 "handling initialization files in TOPLEVEL-INIT")
 387     (flet (;; If any of POSSIBLE-INIT-FILE-NAMES names a real file,
 388            ;; return its truename.
 389            (probe-init-files (&rest possible-init-file-names)
 390              (/show0 "entering PROBE-INIT-FILES")
 391              (prog1
 392                  (find-if (lambda (x)
 393                             (and (stringp x) (probe-file x)))
 394                           possible-init-file-names)
 395                (/show0 "leaving PROBE-INIT-FILES"))))
 396       (let* ((sbcl-home (posix-getenv "SBCL_HOME"))
 397              (sysinit-truename (if sbcl-home
 398                                    (probe-init-files sysinit
 399                                                      (concatenate
 400                                                       'string
 401                                                       sbcl-home
 402                                                       "/sbclrc"))
 403                                    (probe-init-files sysinit
 404                                                      "/etc/sbclrc"
 405                                                      "/usr/local/etc/sbclrc")))
 406              (user-home (or (posix-getenv "HOME")
 407                             (error "The HOME environment variable is unbound, ~
 408                                     so user init file can't be found.")))
 409              (userinit-truename (probe-init-files userinit
 410                                                   (concatenate
 411                                                    'string
 412                                                    user-home
 413                                                    "/.sbclrc"))))
 414         (/show0 "assigned SYSINIT-TRUENAME and USERINIT-TRUENAME")
 415
 416
 417         ;; We wrap all the pre-REPL user/system customized startup code
 418         ;; in a restart.
 419         ;;
 420         ;; (Why not wrap everything, even the stuff above, in this
 421         ;; restart? Errors above here are basically command line or
 422         ;; Unix environment errors, e.g. a missing file or a typo on
 423         ;; the Unix command line, and you don't need to get into Lisp
 424         ;; to debug them, you should just start over and do it right
 425         ;; at the Unix level. Errors below here are usually errors in
 426         ;; user Lisp code, and it might be helpful to let the user
 427         ;; reach the REPL in order to help figure out what's going on.)
 428         (restart-case
 429             (flet ((process-init-file (truename)
 430                      (when truename
 431                        (unless (load truename)
 432                          (error "~S was not successfully loaded." truename))
 433                        (flush-standard-output-streams))))
 434               (process-init-file sysinit-truename)
 435               (process-init-file userinit-truename)
 436
 437               ;; Process --eval options.
 438               (/show0 "handling --eval options in TOPLEVEL-INIT")
 439               (dolist (eval (reverse reversed-evals))
 440                 (/show0 "handling one --eval option in TOPLEVEL-INIT")
 441                 (eval eval)
 442                 (flush-standard-output-streams)))
 443           (continue ()
 444                     :report "Continue anyway (skipping to toplevel read/eval/print loop)."
 445                     (values)) ; (no-op, just fall through)
 446           (quit ()
 447                 :report "Quit SBCL (calling #'QUIT, killing the process)."
 448                 (quit))))
 449
 450       ;; one more time for good measure, in case we fell out of the
 451       ;; RESTART-CASE above before one of the flushes in the ordinary
 452       ;; flow of control had a chance to operate
 453       (flush-standard-output-streams)
 454
 455       (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 456       (toplevel-repl noprint))))
 457
 458 ;;; read-eval-print loop for the default system toplevel
 459 (defun toplevel-repl (noprint)
 460   (/show0 "entering TOPLEVEL-REPL")
 461   (let ((* nil) (** nil) (*** nil)
 462         (- nil)
 463         (+ nil) (++ nil) (+++ nil)
 464         (/// nil) (// nil) (/ nil)
 465         (eof-marker (cons :eof nil)))
 466     (loop
 467       (/show0 "at head of outer LOOP in TOPLEVEL-REPL")
 468       ;; There should only be one TOPLEVEL restart, and it's here, so
 469       ;; restarting at TOPLEVEL always bounces you all the way out here.
 470       (with-simple-restart (toplevel
 471                             "Restart at toplevel READ/EVAL/PRINT loop.")
 472         ;; We add a new ABORT restart for every debugger level, so
 473         ;; restarting at ABORT in a nested debugger gets you out to the
 474         ;; innermost enclosing debugger, and only when you're in the
 475         ;; outermost, unnested debugger level does restarting at ABORT
 476         ;; get you out to here.
 477         (with-simple-restart (abort
 478                               "Reduce debugger level (leaving debugger).")
 479           (catch 'top-level-catcher
 480           (sb!unix:unix-sigsetmask 0)   ; FIXME: What is this for?
 481           (/show0 "about to enter inner LOOP in TOPLEVEL-REPL")
 482           (loop                         ; FIXME: Do we need this inner LOOP?
 483            ;; FIXME: It seems bad to have GC behavior depend on scrubbing
 484            ;; the control stack before each interactive command. Isn't
 485            ;; there some way we can convince the GC to just ignore
 486            ;; dead areas of the control stack, so that we don't need to
 487            ;; rely on this half-measure?
 488            (scrub-control-stack)
 489            (unless noprint
 490              (fresh-line)
 491              (princ (if (functionp *prompt*)
 492                         (funcall *prompt*)
 493                         *prompt*))
 494              (flush-standard-output-streams))
 495            (let ((form (read *standard-input* nil eof-marker)))
 496              (if (eq form eof-marker)
 497                  (quit)
 498                  (let ((results
 499                         (multiple-value-list (interactive-eval form))))
 500                    (unless noprint
 501                      (dolist (result results)
 502                        (fresh-line)
 503                        (prin1 result)))))))))))))
 504
 505 (defun noprogrammer-debugger-hook-fun (condition old-debugger-hook)
 506   (declare (ignore old-debugger-hook))
 507   (flet ((failure-quit (&key recklessly-p)
 508            (quit :unix-status 1 :recklessly-p recklessly-p)))
 509     ;; This HANDLER-CASE is here mostly to stop output immediately
 510     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 511     ;; when we're run under a shell script or something, we can die
 512     ;; cleanly when the script dies (and our pipes are cut), instead
 513     ;; of falling into ldb or something messy like that.
 514     (handler-case
 515         (progn
 516           (format *error-output*
 517                   "~@<unhandled condition (of type ~S): ~2I~_~A~:>~2%"
 518                   (type-of condition)
 519                   condition)
 520           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 521           ;; even if we hit an error within BACKTRACE we'll at least
 522           ;; have the CONDITION printed out before we die.
 523           (finish-output *error-output*)
 524           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 525           ;; it seems as though we should at least truncate it somewhere.)
 526           (sb!debug:backtrace 128 *error-output*)
 527           (format *error-output*
 528                   "~%unhandled condition in --noprogrammer mode, quitting~%")
 529           (finish-output *error-output*)
 530           (failure-quit))
 531       (condition ()
 532         ;; We IGNORE-ERRORS here because even %PRIMITIVE PRINT can
 533         ;; fail when our output streams are blown away, as e.g. when
 534         ;; we're running under a Unix shell script and it dies somehow
 535         ;; (e.g. because of a SIGINT). In that case, we might as well
 536         ;; just give it up for a bad job, and stop trying to notify
 537         ;; the user of anything.
 538         ;;
 539         ;; Actually, the only way I've run across to exercise the
 540         ;; problem is to have more than one layer of shell script.
 541         ;; I have a shell script which does
 542         ;;   time nice -10 sh make.sh "$1" 2>&1 | tee make.tmp
 543         ;; and the problem occurs when I interrupt this with Ctrl-C
 544         ;; under Linux 2.2.14-5.0 and GNU bash, version 1.14.7(1).
 545         ;; I haven't figured out whether it's bash, time, tee, Linux, or
 546         ;; what that is responsible, but that it's possible at all
 547         ;; means that we should IGNORE-ERRORS here. -- WHN 2001-04-24
 548         (ignore-errors
 549          (%primitive print "Argh! error within --noprogrammer error handling"))
 550         (failure-quit :recklessly-p t)))))
 551 \f
 552 ;;; a convenient way to get into the assembly-level debugger
 553 (defun %halt ()
 554   (%primitive sb!c:halt))