src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a pathname
  60 designator for the default sysinit file, or NIL. If the function returns NIL,
  61 no sysinit file is used unless one has been specified on the command-line.")
  62
  63 (defvar *userinit-pathname-function* #'userinit-pathname
  64   #!+sb-doc
  65   "Designator for a function of zero arguments called to obtain a pathname
  66 designator or a stream for the default userinit file, or NIL. If the function
  67 returns NIL, no userinit file is used unless one has been specified on the
  68 command-line.")
  69
  70 \f
  71 ;;;; miscellaneous utilities for working with with TOPLEVEL
  72
  73 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  74 ;;; by QUIT) is caught and any final processing and return codes are
  75 ;;; handled appropriately.
  76 (defmacro handling-end-of-the-world (&body body)
  77   (with-unique-names (caught)
  78     `(without-interrupts
  79        (let ((,caught
  80                (catch '%end-of-the-world
  81                  (unwind-protect
  82                       (with-local-interrupts ,@body (quit))
  83                    (handler-case
  84                        (with-local-interrupts
  85                          (call-hooks "exit" *exit-hooks* :on-error :warn))
  86                      (serious-condition ()
  87                        1))))))
  88          ;; If user called QUIT and exit hooks were OK, the status is what it
  89          ;; is -- even eg. streams cannot be flushed anymore. Even if
  90          ;; something goes wrong now, we still report what was asked. We still
  91          ;; want to have %END-OF-THE-WORLD visible, though.
  92          (catch '%end-of-the-world
  93            (handler-case
  94                (unwind-protect
  95                     (progn
  96                       (flush-standard-output-streams)
  97                       (sb!thread::terminate-session))
  98                  (sb!unix:unix-exit ,caught))
  99              (serious-condition ())))))))
 100 \f
 101 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
 102
 103 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
 104 ;;; of hyperspace.
 105 (defmacro infinite-error-protect (&rest forms)
 106   `(unless (infinite-error-protector)
 107      (/show0 "back from INFINITE-ERROR-PROTECTOR")
 108      (let ((*current-error-depth* (1+ *current-error-depth*)))
 109        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
 110        ;; arbitrary truncation
 111        #!+sb-show (sb!debug:backtrace 8)
 112        ,@forms)))
 113
 114 ;;; a helper function for INFINITE-ERROR-PROTECT
 115 (defun infinite-error-protector ()
 116   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 117   (/hexstr *current-error-depth*)
 118   (cond ((not *cold-init-complete-p*)
 119          (%primitive print "Argh! error in cold init, halting")
 120          (%primitive sb!c:halt))
 121         ((or (not (boundp '*current-error-depth*))
 122              (not (realp   *current-error-depth*))
 123              (not (boundp '*maximum-error-depth*))
 124              (not (realp   *maximum-error-depth*)))
 125          (%primitive print "Argh! corrupted error depth, halting")
 126          (%primitive sb!c:halt))
 127         ((> *current-error-depth* *maximum-error-depth*)
 128          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 129          (/hexstr *maximum-error-depth*)
 130          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 131          (error-error "Help! "
 132                       *current-error-depth*
 133                       " nested errors. "
 134                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 135          t)
 136         (t
 137          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 138          nil)))
 139
 140 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 141 ;;; one point (shown below), and SBCL cross-compiled it without
 142 ;;; warning about FORMS being undefined. Check whether that problem
 143 ;;; (missing warning) is repeatable in the final system and if so, fix
 144 ;;; it.
 145 #|
 146 (defun infinite-error-protector ()
 147   `(cond ((not *cold-init-complete-p*)
 148           (%primitive print "Argh! error in cold init, halting")
 149           (%primitive sb!c:halt))
 150          ((or (not (boundp '*current-error-depth*))
 151               (not (realp   *current-error-depth*))
 152               (not (boundp '*maximum-error-depth*))
 153               (not (realp   *maximum-error-depth*)))
 154           (%primitive print "Argh! corrupted error depth, halting")
 155           (%primitive sb!c:halt))
 156          ((> *current-error-depth* *maximum-error-depth*)
 157           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 158           (error-error "Help! "
 159                        *current-error-depth*
 160                        " nested errors. "
 161                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 162           (progn ,@forms)
 163           t)
 164          (t
 165           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 166           nil)))
 167 |#
 168 \f
 169 ;;;; miscellaneous external functions
 170
 171 (defun sleep (seconds)
 172   #!+sb-doc
 173   "This function causes execution to be suspended for SECONDS. SECONDS may be
 174 any non-negative real number."
 175   (when (or (not (realp seconds))
 176             (minusp seconds))
 177     (error 'simple-type-error
 178            :format-control "invalid argument to SLEEP: ~S"
 179            :format-arguments (list seconds)
 180            :datum seconds
 181            :expected-type '(real 0)))
 182   #!-win32
 183   (multiple-value-bind (sec nsec)
 184       (if (integerp seconds)
 185           (values seconds 0)
 186           (multiple-value-bind (sec frac)
 187               (truncate seconds)
 188             (values sec (truncate frac 1e-9))))
 189     ;; nanosleep() accepts time_t as the first argument, but on some platforms
 190     ;; it is restricted to 100 million seconds. Maybe someone can actually
 191     ;; have a reason to sleep for over 3 years?
 192     (loop while (> sec (expt 10 8))
 193           do (decf sec (expt 10 8))
 194              (sb!unix:nanosleep (expt 10 8) 0))
 195     (sb!unix:nanosleep sec nsec))
 196   #!+win32
 197   (sb!win32:millisleep (truncate (* seconds 1000)))
 198   nil)
 199 \f
 200 ;;;; the default toplevel function
 201
 202 (defvar / nil
 203   #!+sb-doc
 204   "a list of all the values returned by the most recent top level EVAL")
 205 (defvar //  nil #!+sb-doc "the previous value of /")
 206 (defvar /// nil #!+sb-doc "the previous value of //")
 207 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 208 (defvar **  nil #!+sb-doc "the previous value of *")
 209 (defvar *** nil #!+sb-doc "the previous value of **")
 210 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 211 (defvar ++  nil #!+sb-doc "the previous value of +")
 212 (defvar +++ nil #!+sb-doc "the previous value of ++")
 213 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 214
 215 (defun interactive-eval (form &key (eval #'eval))
 216   #!+sb-doc
 217   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 218 +++, ++, +, ///, //, /, and -."
 219   (setf - form)
 220   (unwind-protect
 221        (let ((results (multiple-value-list (funcall eval form))))
 222          (setf /// //
 223                // /
 224                / results
 225                *** **
 226                ** *
 227                * (car results)))
 228     (setf +++ ++
 229           ++ +
 230           + -))
 231   (unless (boundp '*)
 232     ;; The bogon returned an unbound marker.
 233     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 234     ;; instead of just the first one.
 235     (setf * nil)
 236     (cerror "Go on with * set to NIL."
 237             "EVAL returned an unbound marker."))
 238   (values-list /))
 239
 240 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 241 ;;; output streams before proceeding.
 242 (defun flush-standard-output-streams ()
 243   (dolist (name '(*debug-io*
 244                   *error-output*
 245                   *query-io*
 246                   *standard-output*
 247                   *trace-output*
 248                   *terminal-io*))
 249     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 250     (force-output (symbol-value name)))
 251   (values))
 252
 253 (defun process-init-file (specified-pathname kind)
 254   (multiple-value-bind (context default-function)
 255       (ecase kind
 256         (:system
 257          (values "sysinit" *sysinit-pathname-function*))
 258         (:user
 259          (values "userinit" *userinit-pathname-function*)))
 260     (if specified-pathname
 261         (with-open-file (stream (parse-native-namestring specified-pathname)
 262                                 :if-does-not-exist nil)
 263           (if stream
 264               (load-as-source stream :context context)
 265               (cerror "Ignore missing init file"
 266                       "The specified ~A file ~A was not found."
 267                       context specified-pathname)))
 268         (let ((default (funcall default-function)))
 269           (when default
 270             (with-open-file (stream (pathname default) :if-does-not-exist nil)
 271               (when stream
 272                 (load-as-source stream :context context))))))))
 273
 274 (defun process-eval/load-options (options)
 275   (/show0 "handling --eval and --load options")
 276   (flet ((process-1 (cons)
 277            (destructuring-bind (opt . value) cons
 278              (ecase opt
 279                (:eval
 280                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 281                                                value)
 282                   (multiple-value-bind (expr pos) (read-from-string value)
 283                     (if (eq value (read-from-string value nil value :start pos))
 284                         (eval expr)
 285                         (error "Multiple expressions in --eval option: ~S"
 286                                value)))))
 287                (:load
 288                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 289                                                value)
 290                   (load (native-pathname value))))))
 291            (flush-standard-output-streams)))
 292     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 293       (dolist (option options)
 294         (process-1 option)))))
 295
 296 (defun process-script (script)
 297   (let ((pathname (native-pathname script)))
 298     (handling-end-of-the-world
 299       (with-open-file (f pathname :element-type :default)
 300         (sb!fasl::maybe-skip-shebang-line f)
 301         ;; Scripts don't need to be stylish or fast, but silence is usually a
 302         ;; desirable quality...
 303         (handler-bind (((or style-warning compiler-note) #'muffle-warning))
 304           (load f :verbose nil :print nil))))))
 305
 306 ;; Errors while processing the command line cause the system to QUIT,
 307 ;; instead of trying to go into the Lisp debugger, because trying to
 308 ;; go into the Lisp debugger would get into various annoying issues of
 309 ;; where we should go after the user tries to return from the
 310 ;; debugger.
 311 (defun startup-error (control-string &rest args)
 312   (format *error-output*
 313           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 314           control-string
 315           args)
 316   (quit :unix-status 1))
 317
 318 ;;; the default system top level function
 319 (defun toplevel-init ()
 320   (/show0 "entering TOPLEVEL-INIT")
 321   (let ( ;; value of --sysinit option
 322         (sysinit nil)
 323         ;; t if --no-sysinit option given
 324         (no-sysinit nil)
 325         ;; value of --userinit option
 326         (userinit nil)
 327         ;; t if --no-userinit option given
 328         (no-userinit nil)
 329         ;; t if --disable-debugger option given
 330         (disable-debugger nil)
 331         ;; list of (<kind> . <string>) conses representing --eval and --load
 332         ;; options. options. --eval options are stored as strings, so that
 333         ;; they can be passed to READ only after their predecessors have been
 334         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 335         ;; creates a package referred to in the next EVAL form. Storing the
 336         ;; original string also makes for easier debugging.
 337         (reversed-options nil)
 338         ;; Has a --noprint option been seen?
 339         (noprint nil)
 340         ;; Has a --script option been seen?
 341         (script nil)
 342         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 343         (options (rest *posix-argv*)))
 344
 345     (declare (type list options))
 346
 347     (/show0 "done with outer LET in TOPLEVEL-INIT")
 348
 349     ;; FIXME: There are lots of ways for errors to happen around here
 350     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 351     ;; READ an --eval string). Make sure that they're handled
 352     ;; reasonably.
 353
 354     ;; Process command line options.
 355     (loop while options do
 356          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 357          (let ((option (first options)))
 358            (flet ((pop-option ()
 359                     (if options
 360                         (pop options)
 361                         (startup-error
 362                          "unexpected end of command line options"))))
 363              (cond ((string= option "--script")
 364                     (pop-option)
 365                     (setf disable-debugger t
 366                           no-userinit t
 367                           no-sysinit t
 368                           script (pop-option))
 369                     (return))
 370                    ((string= option "--sysinit")
 371                     (pop-option)
 372                     (if sysinit
 373                         (startup-error "multiple --sysinit options")
 374                         (setf sysinit (pop-option))))
 375                    ((string= option "--no-sysinit")
 376                     (pop-option)
 377                     (setf no-sysinit t))
 378                    ((string= option "--userinit")
 379                     (pop-option)
 380                     (if userinit
 381                         (startup-error "multiple --userinit options")
 382                         (setf userinit (pop-option))))
 383                    ((string= option "--no-userinit")
 384                     (pop-option)
 385                     (setf no-userinit t))
 386                    ((string= option "--eval")
 387                     (pop-option)
 388                     (push (cons :eval (pop-option)) reversed-options))
 389                    ((string= option "--load")
 390                     (pop-option)
 391                     (push (cons :load (pop-option)) reversed-options))
 392                    ((string= option "--noprint")
 393                     (pop-option)
 394                     (setf noprint t))
 395                    ((string= option "--disable-debugger")
 396                     (pop-option)
 397                     (setf disable-debugger t))
 398                    ((string= option "--end-toplevel-options")
 399                     (pop-option)
 400                     (return))
 401                    (t
 402                     ;; Anything we don't recognize as a toplevel
 403                     ;; option must be the start of user-level
 404                     ;; options.. except that if we encounter
 405                     ;; "--end-toplevel-options" after we gave up
 406                     ;; because we didn't recognize an option as a
 407                     ;; toplevel option, then the option we gave up on
 408                     ;; must have been an error. (E.g. in
 409                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 410                     ;; this test will let us detect that the string
 411                     ;; "--eval(b)" is an error.)
 412                     (if (find "--end-toplevel-options" options
 413                               :test #'string=)
 414                         (startup-error "bad toplevel option: ~S"
 415                                        (first options))
 416                         (return)))))))
 417     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 418
 419     ;; Delete all the options that we processed, so that only
 420     ;; user-level options are left visible to user code.
 421     (setf (rest *posix-argv*) options)
 422
 423     ;; Disable debugger before processing initialization files & co.
 424     (when disable-debugger
 425       (sb!ext:disable-debugger))
 426
 427     ;; Handle initialization files.
 428     (/show0 "handling initialization files in TOPLEVEL-INIT")
 429     ;; This CATCH is needed for the debugger command TOPLEVEL to
 430     ;; work.
 431     (catch 'toplevel-catcher
 432       ;; We wrap all the pre-REPL user/system customized startup
 433       ;; code in a restart.
 434       ;;
 435       ;; (Why not wrap everything, even the stuff above, in this
 436       ;; restart? Errors above here are basically command line
 437       ;; or Unix environment errors, e.g. a missing file or a
 438       ;; typo on the Unix command line, and you don't need to
 439       ;; get into Lisp to debug them, you should just start over
 440       ;; and do it right at the Unix level. Errors below here
 441       ;; are generally errors in user Lisp code, and it might be
 442       ;; helpful to let the user reach the REPL in order to help
 443       ;; figure out what's going on.)
 444       (restart-case
 445           (progn
 446             (unless no-sysinit
 447               (process-init-file sysinit :system))
 448             (unless no-userinit
 449               (process-init-file userinit :user))
 450             (process-eval/load-options (nreverse reversed-options))
 451             (when script
 452               (process-script script)
 453               (bug "PROCESS-SCRIPT returned")))
 454         (abort ()
 455           :report (lambda (s)
 456                     (write-string
 457                      (if script
 458                          ;; In case script calls (enable-debugger)!
 459                          "Abort script, exiting lisp."
 460                          "Skip to toplevel READ/EVAL/PRINT loop.")
 461                      s))
 462           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 463           (values))                     ; (no-op, just fall through)
 464         (quit ()
 465           :report "Quit SBCL (calling #'QUIT, killing the process)."
 466           :test (lambda (c) (declare (ignore c)) (not script))
 467           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 468           (quit :unix-status 1))))
 469
 470     ;; one more time for good measure, in case we fell out of the
 471     ;; RESTART-CASE above before one of the flushes in the ordinary
 472     ;; flow of control had a chance to operate
 473     (flush-standard-output-streams)
 474
 475     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 476     (toplevel-repl noprint)
 477     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 478     (critically-unreachable "after TOPLEVEL-REPL")))
 479
 480 ;;; hooks to support customized toplevels like ACL-style toplevel from
 481 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 482 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 483 (defvar *repl-read-form-fun* #'repl-read-form-fun
 484   #!+sb-doc
 485   "A function of two stream arguments IN and OUT for the toplevel REPL to
 486 call: Return the next Lisp form to evaluate (possibly handling other magic --
 487 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 488 stream is there to support magic which requires issuing new prompts.")
 489 (defvar *repl-prompt-fun* #'repl-prompt-fun
 490   #!+sb-doc
 491   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 492 the user for input.")
 493 (defvar *repl-fun-generator* (constantly #'repl-fun)
 494   #!+sb-doc
 495   "A function of no arguments returning a function of one argument NOPRINT
 496 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 497 *STANDARD-OUTPUT* are set up.")
 498
 499 ;;; read-eval-print loop for the default system toplevel
 500 (defun toplevel-repl (noprint)
 501   (/show0 "entering TOPLEVEL-REPL")
 502   (let ((* nil) (** nil) (*** nil)
 503         (- nil)
 504         (+ nil) (++ nil) (+++ nil)
 505         (/// nil) (// nil) (/ nil))
 506     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 507     (let ((repl-fun (funcall *repl-fun-generator*)))
 508       ;; Each REPL in a multithreaded world should have bindings of
 509       ;; most CL specials (most critically *PACKAGE*).
 510       (with-rebound-io-syntax
 511           (handler-bind ((step-condition 'invoke-stepper))
 512             (loop
 513                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 514                ;; CLHS recommends that there should always be an
 515                ;; ABORT restart; we have this one here, and one per
 516                ;; debugger level.
 517                (with-simple-restart
 518                    (abort "~@<Exit debugger, returning to top level.~@:>")
 519                  (catch 'toplevel-catcher
 520                    ;; In the event of a control-stack-exhausted-error, we
 521                    ;; should have unwound enough stack by the time we get
 522                    ;; here that this is now possible.
 523                    #!-win32
 524                    (sb!kernel::reset-control-stack-guard-page)
 525                    (funcall repl-fun noprint)
 526                    (critically-unreachable "after REPL")))))))))
 527
 528 ;;; Our default REPL prompt is the minimal traditional one.
 529 (defun repl-prompt-fun (stream)
 530   (fresh-line stream)
 531   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 532
 533 ;;; Our default form reader does relatively little magic, but does
 534 ;;; handle the Unix-style EOF-is-end-of-process convention.
 535 (defun repl-read-form-fun (in out)
 536   (declare (type stream in out) (ignore out))
 537   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 538   ;; recovered from -- flip it here.
 539   (when *read-suppress*
 540     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 541     (setf *read-suppress* nil))
 542   (let* ((eof-marker (cons nil nil))
 543          (form (read in nil eof-marker)))
 544     (if (eq form eof-marker)
 545         (quit)
 546         form)))
 547
 548 (defun repl-fun (noprint)
 549   (/show0 "entering REPL")
 550   (loop
 551    (unwind-protect
 552         (progn
 553           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 554           (scrub-control-stack)
 555           (sb!thread::get-foreground)
 556           (unless noprint
 557             (flush-standard-output-streams)
 558             (funcall *repl-prompt-fun* *standard-output*)
 559             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 560             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 561             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 562             ;; odd. But maybe there *is* a valid reason in some
 563             ;; circumstances? perhaps some deadlock issue when being driven
 564             ;; by another process or something...)
 565             (force-output *standard-output*))
 566           (let* ((form (funcall *repl-read-form-fun*
 567                                 *standard-input*
 568                                 *standard-output*))
 569                  (results (multiple-value-list (interactive-eval form))))
 570             (unless noprint
 571               (dolist (result results)
 572                 (fresh-line)
 573                 (prin1 result)))))
 574      ;; If we started stepping in the debugger we want to stop now.
 575      (disable-stepping))))
 576 \f
 577 ;;; a convenient way to get into the assembly-level debugger
 578 (defun %halt ()
 579   (%primitive sb!c:halt))