src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a
  60 pathname designator for the default sysinit file, or NIL. If the
  61 function returns NIL, no sysinit file is used unless one has been
  62 specified on the command-line.")
  63
  64 (defvar *userinit-pathname-function* #'userinit-pathname
  65   #!+sb-doc
  66   "Designator for a function of zero arguments called to obtain a
  67 pathname designator or a stream for the default userinit file, or NIL.
  68 If the function returns NIL, no userinit file is used unless one has
  69 been specified on the command-line.")
  70
  71 \f
  72 ;;;; miscellaneous utilities for working with with TOPLEVEL
  73
  74 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  75 ;;; by QUIT) is caught and any final processing and return codes are
  76 ;;; handled appropriately.
  77 (defmacro handling-end-of-the-world (&body body)
  78   (with-unique-names (caught)
  79     `(without-interrupts
  80        (let ((,caught
  81                (catch '%end-of-the-world
  82                  (unwind-protect
  83                       (with-local-interrupts ,@body (quit))
  84                    (handler-case
  85                        (with-local-interrupts
  86                          (call-hooks "exit" *exit-hooks* :on-error :warn))
  87                      (serious-condition ()
  88                        1))))))
  89          ;; If user called QUIT and exit hooks were OK, the status is what it
  90          ;; is -- even eg. streams cannot be flushed anymore. Even if
  91          ;; something goes wrong now, we still report what was asked. We still
  92          ;; want to have %END-OF-THE-WORLD visible, though.
  93          (catch '%end-of-the-world
  94            (handler-case
  95                (unwind-protect
  96                     (progn
  97                       (flush-standard-output-streams)
  98                       (sb!thread::terminate-session))
  99                  (sb!unix:unix-exit ,caught))
 100              (serious-condition ())))))))
 101 \f
 102 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
 103
 104 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
 105 ;;; of hyperspace.
 106 (defmacro infinite-error-protect (&rest forms)
 107   `(unless (infinite-error-protector)
 108      (/show0 "back from INFINITE-ERROR-PROTECTOR")
 109      (let ((*current-error-depth* (1+ *current-error-depth*)))
 110        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
 111        ;; arbitrary truncation
 112        #!+sb-show (sb!debug:backtrace 8)
 113        ,@forms)))
 114
 115 ;;; a helper function for INFINITE-ERROR-PROTECT
 116 (defun infinite-error-protector ()
 117   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 118   (/hexstr *current-error-depth*)
 119   (cond ((not *cold-init-complete-p*)
 120          (%primitive print "Argh! error in cold init, halting")
 121          (%primitive sb!c:halt))
 122         ((or (not (boundp '*current-error-depth*))
 123              (not (realp   *current-error-depth*))
 124              (not (boundp '*maximum-error-depth*))
 125              (not (realp   *maximum-error-depth*)))
 126          (%primitive print "Argh! corrupted error depth, halting")
 127          (%primitive sb!c:halt))
 128         ((> *current-error-depth* *maximum-error-depth*)
 129          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 130          (/hexstr *maximum-error-depth*)
 131          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 132          (error-error "Help! "
 133                       *current-error-depth*
 134                       " nested errors. "
 135                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 136          t)
 137         (t
 138          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 139          nil)))
 140
 141 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 142 ;;; one point (shown below), and SBCL cross-compiled it without
 143 ;;; warning about FORMS being undefined. Check whether that problem
 144 ;;; (missing warning) is repeatable in the final system and if so, fix
 145 ;;; it.
 146 #|
 147 (defun infinite-error-protector ()
 148   `(cond ((not *cold-init-complete-p*)
 149           (%primitive print "Argh! error in cold init, halting")
 150           (%primitive sb!c:halt))
 151          ((or (not (boundp '*current-error-depth*))
 152               (not (realp   *current-error-depth*))
 153               (not (boundp '*maximum-error-depth*))
 154               (not (realp   *maximum-error-depth*)))
 155           (%primitive print "Argh! corrupted error depth, halting")
 156           (%primitive sb!c:halt))
 157          ((> *current-error-depth* *maximum-error-depth*)
 158           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 159           (error-error "Help! "
 160                        *current-error-depth*
 161                        " nested errors. "
 162                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 163           (progn ,@forms)
 164           t)
 165          (t
 166           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 167           nil)))
 168 |#
 169 \f
 170 ;;;; miscellaneous external functions
 171
 172 (defun sleep (seconds)
 173   #!+sb-doc
 174   "This function causes execution to be suspended for SECONDS. SECONDS may be
 175 any non-negative real number."
 176   (when (or (not (realp seconds))
 177             (minusp seconds))
 178     (error 'simple-type-error
 179            :format-control "invalid argument to SLEEP: ~S"
 180            :format-arguments (list seconds)
 181            :datum seconds
 182            :expected-type '(real 0)))
 183   #!-win32
 184   (multiple-value-bind (sec nsec)
 185       (if (integerp seconds)
 186           (values seconds 0)
 187           (multiple-value-bind (sec frac)
 188               (truncate seconds)
 189             (values sec (truncate frac 1e-9))))
 190     ;; nanosleep() accepts time_t as the first argument, but on some platforms
 191     ;; it is restricted to 100 million seconds. Maybe someone can actually
 192     ;; have a reason to sleep for over 3 years?
 193     (loop while (> sec (expt 10 8))
 194           do (decf sec (expt 10 8))
 195              (sb!unix:nanosleep (expt 10 8) 0))
 196     (sb!unix:nanosleep sec nsec))
 197   #!+win32
 198   (sb!win32:millisleep (truncate (* seconds 1000)))
 199   nil)
 200 \f
 201 ;;;; the default toplevel function
 202
 203 (defvar / nil
 204   #!+sb-doc
 205   "a list of all the values returned by the most recent top level EVAL")
 206 (defvar //  nil #!+sb-doc "the previous value of /")
 207 (defvar /// nil #!+sb-doc "the previous value of //")
 208 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 209 (defvar **  nil #!+sb-doc "the previous value of *")
 210 (defvar *** nil #!+sb-doc "the previous value of **")
 211 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 212 (defvar ++  nil #!+sb-doc "the previous value of +")
 213 (defvar +++ nil #!+sb-doc "the previous value of ++")
 214 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 215
 216 (defun interactive-eval (form &key (eval #'eval))
 217   #!+sb-doc
 218   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 219 +++, ++, +, ///, //, /, and -."
 220   (setf - form)
 221   (unwind-protect
 222        (let ((results (multiple-value-list (funcall eval form))))
 223          (setf /// //
 224                // /
 225                / results
 226                *** **
 227                ** *
 228                * (car results)))
 229     (setf +++ ++
 230           ++ +
 231           + -))
 232   (unless (boundp '*)
 233     ;; The bogon returned an unbound marker.
 234     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 235     ;; instead of just the first one.
 236     (setf * nil)
 237     (cerror "Go on with * set to NIL."
 238             "EVAL returned an unbound marker."))
 239   (values-list /))
 240
 241 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 242 ;;; output streams before proceeding.
 243 (defun flush-standard-output-streams ()
 244   (dolist (name '(*debug-io*
 245                   *error-output*
 246                   *query-io*
 247                   *standard-output*
 248                   *trace-output*
 249                   *terminal-io*))
 250     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 251     (force-output (symbol-value name)))
 252   (values))
 253
 254 (defun process-init-file (specified-pathname kind)
 255   (multiple-value-bind (context default-function)
 256       (ecase kind
 257         (:system
 258          (values "sysinit" *sysinit-pathname-function*))
 259         (:user
 260          (values "userinit" *userinit-pathname-function*)))
 261     (if specified-pathname
 262         (with-open-file (stream (parse-native-namestring specified-pathname)
 263                                 :if-does-not-exist nil)
 264           (if stream
 265               (load-as-source stream :context context)
 266               (cerror "Ignore missing init file"
 267                       "The specified ~A file ~A was not found."
 268                       context specified-pathname)))
 269         (let ((default (funcall default-function)))
 270           (when default
 271             (with-open-file (stream (pathname default) :if-does-not-exist nil)
 272               (when stream
 273                 (load-as-source stream :context context))))))))
 274
 275 (defun process-eval/load-options (options)
 276   (/show0 "handling --eval and --load options")
 277   (flet ((process-1 (cons)
 278            (destructuring-bind (opt . value) cons
 279              (ecase opt
 280                (:eval
 281                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 282                                                value)
 283                   (multiple-value-bind (expr pos) (read-from-string value)
 284                     (if (eq value (read-from-string value nil value :start pos))
 285                         (eval expr)
 286                         (error "Multiple expressions in --eval option: ~S"
 287                                value)))))
 288                (:load
 289                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 290                                                value)
 291                   (load (native-pathname value))))
 292                (:quit
 293                 (quit))))
 294            (flush-standard-output-streams)))
 295     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 296       (dolist (option options)
 297         (process-1 option)))))
 298
 299 (defun process-script (script)
 300   (flet ((load-script (stream)
 301            ;; Scripts don't need to be stylish or fast, but silence is usually a
 302            ;; desirable quality...
 303            (handler-bind (((or style-warning compiler-note) #'muffle-warning)
 304                           (stream-error (lambda (e)
 305                                           ;; Shell-style.
 306                                           (when (member (stream-error-stream e)
 307                                                         (list *stdout* *stdin* *stderr*))
 308                                             (quit)))))
 309              ;; Let's not use the *TTY* for scripts, ok? Also, normally we use
 310              ;; synonym streams, but in order to have the broken pipe/eof error
 311              ;; handling right we want to bind them for scripts.
 312              (let ((*terminal-io* (make-two-way-stream *stdin* *stdout*))
 313                    (*debug-io* (make-two-way-stream *stdin* *stderr*))
 314                    (*standard-input* *stdin*)
 315                    (*standard-output* *stdout*)
 316                    (*error-output* *stderr*))
 317                (load stream :verbose nil :print nil)))))
 318     (handling-end-of-the-world
 319       (if (eq t script)
 320           (load-script *stdin*)
 321           (with-open-file (f (native-pathname script) :element-type :default)
 322             (sb!fasl::maybe-skip-shebang-line f)
 323             (load-script f))))))
 324
 325 ;; Errors while processing the command line cause the system to QUIT,
 326 ;; instead of trying to go into the Lisp debugger, because trying to
 327 ;; go into the Lisp debugger would get into various annoying issues of
 328 ;; where we should go after the user tries to return from the
 329 ;; debugger.
 330 (defun startup-error (control-string &rest args)
 331   (format *error-output*
 332           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 333           control-string
 334           args)
 335   (quit :unix-status 1))
 336
 337 ;;; the default system top level function
 338 (defun toplevel-init ()
 339   (/show0 "entering TOPLEVEL-INIT")
 340   (let ( ;; value of --sysinit option
 341         (sysinit nil)
 342         ;; t if --no-sysinit option given
 343         (no-sysinit nil)
 344         ;; value of --userinit option
 345         (userinit nil)
 346         ;; t if --no-userinit option given
 347         (no-userinit nil)
 348         ;; t if --disable-debugger option given
 349         (disable-debugger nil)
 350         ;; list of (<kind> . <string>) conses representing --eval and --load
 351         ;; options. options. --eval options are stored as strings, so that
 352         ;; they can be passed to READ only after their predecessors have been
 353         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 354         ;; creates a package referred to in the next EVAL form. Storing the
 355         ;; original string also makes for easier debugging.
 356         (reversed-options nil)
 357         ;; Has a --noprint option been seen?
 358         (noprint nil)
 359         ;; Has a --script option been seen?
 360         (script nil)
 361         ;; Quit after processing other options?
 362         (finally-quit nil)
 363         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 364         (options (rest *posix-argv*)))
 365
 366     (declare (type list options))
 367
 368     (/show0 "done with outer LET in TOPLEVEL-INIT")
 369
 370     ;; FIXME: There are lots of ways for errors to happen around here
 371     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 372     ;; READ an --eval string). Make sure that they're handled
 373     ;; reasonably.
 374
 375     ;; Process command line options.
 376     (loop while options do
 377          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 378          (let ((option (first options)))
 379            (flet ((pop-option ()
 380                     (if options
 381                         (pop options)
 382                         (startup-error
 383                          "unexpected end of command line options"))))
 384              (cond ((string= option "--script")
 385                     (pop-option)
 386                     (setf disable-debugger t
 387                           no-userinit t
 388                           no-sysinit t
 389                           script (if options (pop-option) t))
 390                     (return))
 391                    ((string= option "--sysinit")
 392                     (pop-option)
 393                     (if sysinit
 394                         (startup-error "multiple --sysinit options")
 395                         (setf sysinit (pop-option))))
 396                    ((string= option "--no-sysinit")
 397                     (pop-option)
 398                     (setf no-sysinit t))
 399                    ((string= option "--userinit")
 400                     (pop-option)
 401                     (if userinit
 402                         (startup-error "multiple --userinit options")
 403                         (setf userinit (pop-option))))
 404                    ((string= option "--no-userinit")
 405                     (pop-option)
 406                     (setf no-userinit t))
 407                    ((string= option "--eval")
 408                     (pop-option)
 409                     (push (cons :eval (pop-option)) reversed-options))
 410                    ((string= option "--load")
 411                     (pop-option)
 412                     (push (cons :load (pop-option)) reversed-options))
 413                    ((string= option "--noprint")
 414                     (pop-option)
 415                     (setf noprint t))
 416                    ((string= option "--disable-debugger")
 417                     (pop-option)
 418                     (setf disable-debugger t))
 419                    ((string= option "--quit")
 420                     (pop-option)
 421                     (setf finally-quit t))
 422                    ((string= option "--non-interactive")
 423                     ;; This option is short for --quit and --disable-debugger,
 424                     ;; which are needed in combination for reliable non-
 425                     ;; interactive startup.
 426                     (pop-option)
 427                     (setf finally-quit t)
 428                     (setf disable-debugger t))
 429                    ((string= option "--end-toplevel-options")
 430                     (pop-option)
 431                     (return))
 432                    (t
 433                     ;; Anything we don't recognize as a toplevel
 434                     ;; option must be the start of user-level
 435                     ;; options.. except that if we encounter
 436                     ;; "--end-toplevel-options" after we gave up
 437                     ;; because we didn't recognize an option as a
 438                     ;; toplevel option, then the option we gave up on
 439                     ;; must have been an error. (E.g. in
 440                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 441                     ;; this test will let us detect that the string
 442                     ;; "--eval(b)" is an error.)
 443                     (if (find "--end-toplevel-options" options
 444                               :test #'string=)
 445                         (startup-error "bad toplevel option: ~S"
 446                                        (first options))
 447                         (return)))))))
 448     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 449
 450     ;; Delete all the options that we processed, so that only
 451     ;; user-level options are left visible to user code.
 452     (setf (rest *posix-argv*) options)
 453
 454     ;; Disable debugger before processing initialization files & co.
 455     (when disable-debugger
 456       (sb!ext:disable-debugger))
 457
 458     ;; Handle initialization files.
 459     (/show0 "handling initialization files in TOPLEVEL-INIT")
 460     ;; This CATCH is needed for the debugger command TOPLEVEL to
 461     ;; work.
 462     (catch 'toplevel-catcher
 463       ;; We wrap all the pre-REPL user/system customized startup
 464       ;; code in a restart.
 465       ;;
 466       ;; (Why not wrap everything, even the stuff above, in this
 467       ;; restart? Errors above here are basically command line
 468       ;; or Unix environment errors, e.g. a missing file or a
 469       ;; typo on the Unix command line, and you don't need to
 470       ;; get into Lisp to debug them, you should just start over
 471       ;; and do it right at the Unix level. Errors below here
 472       ;; are generally errors in user Lisp code, and it might be
 473       ;; helpful to let the user reach the REPL in order to help
 474       ;; figure out what's going on.)
 475       (restart-case
 476           (progn
 477             (unless no-sysinit
 478               (process-init-file sysinit :system))
 479             (unless no-userinit
 480               (process-init-file userinit :user))
 481             (when finally-quit
 482               (push (list :quit) reversed-options))
 483             (process-eval/load-options (nreverse reversed-options))
 484             (when script
 485               (process-script script)
 486               (bug "PROCESS-SCRIPT returned")))
 487         (abort ()
 488           :report (lambda (s)
 489                     (write-string
 490                      (if script
 491                          ;; In case script calls (enable-debugger)!
 492                          "Abort script, exiting lisp."
 493                          "Skip to toplevel READ/EVAL/PRINT loop.")
 494                      s))
 495           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 496           (values))                     ; (no-op, just fall through)
 497         (quit ()
 498           :report "Quit SBCL (calling #'QUIT, killing the process)."
 499           :test (lambda (c) (declare (ignore c)) (not script))
 500           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 501           (quit :unix-status 1))))
 502
 503     ;; one more time for good measure, in case we fell out of the
 504     ;; RESTART-CASE above before one of the flushes in the ordinary
 505     ;; flow of control had a chance to operate
 506     (flush-standard-output-streams)
 507
 508     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 509     (toplevel-repl noprint)
 510     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 511     (critically-unreachable "after TOPLEVEL-REPL")))
 512
 513 ;;; hooks to support customized toplevels like ACL-style toplevel from
 514 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 515 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 516 (defvar *repl-read-form-fun* #'repl-read-form-fun
 517   #!+sb-doc
 518   "A function of two stream arguments IN and OUT for the toplevel REPL to
 519 call: Return the next Lisp form to evaluate (possibly handling other magic --
 520 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 521 stream is there to support magic which requires issuing new prompts.")
 522 (defvar *repl-prompt-fun* #'repl-prompt-fun
 523   #!+sb-doc
 524   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 525 the user for input.")
 526 (defvar *repl-fun-generator* (constantly #'repl-fun)
 527   #!+sb-doc
 528   "A function of no arguments returning a function of one argument NOPRINT
 529 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 530 *STANDARD-OUTPUT* are set up.")
 531
 532 ;;; read-eval-print loop for the default system toplevel
 533 (defun toplevel-repl (noprint)
 534   (/show0 "entering TOPLEVEL-REPL")
 535   (let ((* nil) (** nil) (*** nil)
 536         (- nil)
 537         (+ nil) (++ nil) (+++ nil)
 538         (/// nil) (// nil) (/ nil))
 539     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 540     (let ((repl-fun (funcall *repl-fun-generator*)))
 541       ;; Each REPL in a multithreaded world should have bindings of
 542       ;; most CL specials (most critically *PACKAGE*).
 543       (with-rebound-io-syntax
 544           (handler-bind ((step-condition 'invoke-stepper))
 545             (loop
 546                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 547                ;; CLHS recommends that there should always be an
 548                ;; ABORT restart; we have this one here, and one per
 549                ;; debugger level.
 550                (with-simple-restart
 551                    (abort "~@<Exit debugger, returning to top level.~@:>")
 552                  (catch 'toplevel-catcher
 553                    ;; In the event of a control-stack-exhausted-error, we
 554                    ;; should have unwound enough stack by the time we get
 555                    ;; here that this is now possible.
 556                    #!-win32
 557                    (sb!kernel::reset-control-stack-guard-page)
 558                    (funcall repl-fun noprint)
 559                    (critically-unreachable "after REPL")))))))))
 560
 561 ;;; Our default REPL prompt is the minimal traditional one.
 562 (defun repl-prompt-fun (stream)
 563   (fresh-line stream)
 564   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 565
 566 ;;; Our default form reader does relatively little magic, but does
 567 ;;; handle the Unix-style EOF-is-end-of-process convention.
 568 (defun repl-read-form-fun (in out)
 569   (declare (type stream in out) (ignore out))
 570   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 571   ;; recovered from -- flip it here.
 572   (when *read-suppress*
 573     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 574     (setf *read-suppress* nil))
 575   (let* ((eof-marker (cons nil nil))
 576          (form (read in nil eof-marker)))
 577     (if (eq form eof-marker)
 578         (quit)
 579         form)))
 580
 581 (defun repl-fun (noprint)
 582   (/show0 "entering REPL")
 583   (loop
 584    (unwind-protect
 585         (progn
 586           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 587           (scrub-control-stack)
 588           (sb!thread::get-foreground)
 589           (unless noprint
 590             (flush-standard-output-streams)
 591             (funcall *repl-prompt-fun* *standard-output*)
 592             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 593             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 594             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 595             ;; odd. But maybe there *is* a valid reason in some
 596             ;; circumstances? perhaps some deadlock issue when being driven
 597             ;; by another process or something...)
 598             (force-output *standard-output*))
 599           (let* ((form (funcall *repl-read-form-fun*
 600                                 *standard-input*
 601                                 *standard-output*))
 602                  (results (multiple-value-list (interactive-eval form))))
 603             (unless noprint
 604               (dolist (result results)
 605                 (fresh-line)
 606                 (prin1 result)))))
 607      ;; If we started stepping in the debugger we want to stop now.
 608      (disable-stepping))))
 609 \f
 610 ;;; a convenient way to get into the assembly-level debugger
 611 (defun %halt ()
 612   (%primitive sb!c:halt))