src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a pathname
  60 designator for the default sysinit file, or NIL. If the function returns NIL,
  61 no sysinit file is used unless one has been specified on the command-line.")
  62
  63 (defvar *userinit-pathname-function* #'userinit-pathname
  64   #!+sb-doc
  65   "Designator for a function of zero arguments called to obtain a pathname
  66 designator or a stream for the default userinit file, or NIL. If the function
  67 returns NIL, no userinit file is used unless one has been specified on the
  68 command-line.")
  69
  70 \f
  71 ;;;; miscellaneous utilities for working with with TOPLEVEL
  72
  73 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  74 ;;; by QUIT) is caught and any final processing and return codes are
  75 ;;; handled appropriately.
  76 (defmacro handling-end-of-the-world (&body body)
  77   (with-unique-names (caught)
  78     `(let ((,caught (catch '%end-of-the-world
  79                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  80                       (unwind-protect
  81                            (progn ,@body)
  82                         (call-hooks "exit" *exit-hooks*)))))
  83       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  84       (flush-standard-output-streams)
  85       (sb!thread::terminate-session)
  86       (/show0 "calling UNIX-EXIT")
  87       (sb!unix:unix-exit ,caught))))
  88 \f
  89 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  90
  91 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  92 ;;; of hyperspace.
  93 (defmacro infinite-error-protect (&rest forms)
  94   `(unless (infinite-error-protector)
  95      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  96      (let ((*current-error-depth* (1+ *current-error-depth*)))
  97        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  98        ;; arbitrary truncation
  99        #!+sb-show (sb!debug:backtrace 8)
 100        ,@forms)))
 101
 102 ;;; a helper function for INFINITE-ERROR-PROTECT
 103 (defun infinite-error-protector ()
 104   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 105   (/hexstr *current-error-depth*)
 106   (cond ((not *cold-init-complete-p*)
 107          (%primitive print "Argh! error in cold init, halting")
 108          (%primitive sb!c:halt))
 109         ((or (not (boundp '*current-error-depth*))
 110              (not (realp   *current-error-depth*))
 111              (not (boundp '*maximum-error-depth*))
 112              (not (realp   *maximum-error-depth*)))
 113          (%primitive print "Argh! corrupted error depth, halting")
 114          (%primitive sb!c:halt))
 115         ((> *current-error-depth* *maximum-error-depth*)
 116          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 117          (/hexstr *maximum-error-depth*)
 118          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 119          (error-error "Help! "
 120                       *current-error-depth*
 121                       " nested errors. "
 122                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 123          t)
 124         (t
 125          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 126          nil)))
 127
 128 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 129 ;;; one point (shown below), and SBCL cross-compiled it without
 130 ;;; warning about FORMS being undefined. Check whether that problem
 131 ;;; (missing warning) is repeatable in the final system and if so, fix
 132 ;;; it.
 133 #|
 134 (defun infinite-error-protector ()
 135   `(cond ((not *cold-init-complete-p*)
 136           (%primitive print "Argh! error in cold init, halting")
 137           (%primitive sb!c:halt))
 138          ((or (not (boundp '*current-error-depth*))
 139               (not (realp   *current-error-depth*))
 140               (not (boundp '*maximum-error-depth*))
 141               (not (realp   *maximum-error-depth*)))
 142           (%primitive print "Argh! corrupted error depth, halting")
 143           (%primitive sb!c:halt))
 144          ((> *current-error-depth* *maximum-error-depth*)
 145           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 146           (error-error "Help! "
 147                        *current-error-depth*
 148                        " nested errors. "
 149                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 150           (progn ,@forms)
 151           t)
 152          (t
 153           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 154           nil)))
 155 |#
 156 \f
 157 ;;;; miscellaneous external functions
 158
 159 (defun sleep (seconds)
 160   #!+sb-doc
 161   "This function causes execution to be suspended for SECONDS. SECONDS may be
 162 any non-negative real number."
 163   (when (or (not (realp seconds))
 164             (minusp seconds))
 165     (error 'simple-type-error
 166            :format-control "invalid argument to SLEEP: ~S"
 167            :format-arguments (list seconds)
 168            :datum seconds
 169            :expected-type '(real 0)))
 170   #!-win32
 171   (multiple-value-bind (sec nsec)
 172       (if (integerp seconds)
 173           (values seconds 0)
 174           (multiple-value-bind (sec frac)
 175               (truncate seconds)
 176             (values sec (truncate frac 1e-9))))
 177     ;; nanosleep accepts time_t as the first argument,
 178     ;; so truncating is needed. 68 years on 32-bit platform should be enough
 179     (sb!unix:nanosleep (min sec (1- (ash 1 (1- sb!vm:n-word-bits)))) nsec))
 180   #!+win32
 181   (sb!win32:millisleep (truncate (* seconds 1000)))
 182   nil)
 183 \f
 184 ;;;; the default toplevel function
 185
 186 (defvar / nil
 187   #!+sb-doc
 188   "a list of all the values returned by the most recent top level EVAL")
 189 (defvar //  nil #!+sb-doc "the previous value of /")
 190 (defvar /// nil #!+sb-doc "the previous value of //")
 191 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 192 (defvar **  nil #!+sb-doc "the previous value of *")
 193 (defvar *** nil #!+sb-doc "the previous value of **")
 194 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 195 (defvar ++  nil #!+sb-doc "the previous value of +")
 196 (defvar +++ nil #!+sb-doc "the previous value of ++")
 197 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 198
 199 (defun interactive-eval (form &key (eval #'eval))
 200   #!+sb-doc
 201   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 202 +++, ++, +, ///, //, /, and -."
 203   (setf - form)
 204   (unwind-protect
 205        (let ((results (multiple-value-list (funcall eval form))))
 206          (setf /// //
 207                // /
 208                / results
 209                *** **
 210                ** *
 211                * (car results)))
 212     (setf +++ ++
 213           ++ +
 214           + -))
 215   (unless (boundp '*)
 216     ;; The bogon returned an unbound marker.
 217     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 218     ;; instead of just the first one.
 219     (setf * nil)
 220     (cerror "Go on with * set to NIL."
 221             "EVAL returned an unbound marker."))
 222   (values-list /))
 223
 224 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 225 ;;; output streams before proceeding.
 226 (defun flush-standard-output-streams ()
 227   (dolist (name '(*debug-io*
 228                   *error-output*
 229                   *query-io*
 230                   *standard-output*
 231                   *trace-output*
 232                   *terminal-io*))
 233     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 234     (force-output (symbol-value name)))
 235   (values))
 236
 237 (defun process-init-file (specified-pathname kind)
 238   (multiple-value-bind (context default-function)
 239       (ecase kind
 240         (:system
 241          (values "sysinit" *sysinit-pathname-function*))
 242         (:user
 243          (values "userinit" *userinit-pathname-function*)))
 244     (flet ((process-stream (stream pathname)
 245              (with-simple-restart (abort "Skip rest of ~A file ~S."
 246                                          context (native-namestring pathname))
 247                (loop
 248                  (with-simple-restart
 249                      (continue "Ignore error and continue processing ~A file ~S."
 250                                context (native-namestring pathname))
 251                    (let ((form (read stream nil stream)))
 252                      (if (eq stream form)
 253                          (return-from process-init-file nil)
 254                          (eval form))))))))
 255       (if specified-pathname
 256           (with-open-file (stream (parse-native-namestring specified-pathname)
 257                                   :if-does-not-exist nil)
 258             (if stream
 259                 (process-stream stream (pathname stream))
 260                 (cerror "Ignore missing init file"
 261                         "The specified ~A file ~A was not found."
 262                         context specified-pathname)))
 263           (let ((default (funcall default-function)))
 264             (when default
 265               (with-open-file (stream (pathname default) :if-does-not-exist nil)
 266                 (when stream
 267                   (process-stream stream (pathname stream))))))))))
 268
 269 (defun process-eval/load-options (options)
 270   (/show0 "handling --eval and --load options")
 271   (flet ((process-1 (cons)
 272            (destructuring-bind (opt . value) cons
 273              (ecase opt
 274                (:eval
 275                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 276                                                value)
 277                   (multiple-value-bind (expr pos) (read-from-string value)
 278                     (if (eq value (read-from-string value nil value :start pos))
 279                         (eval expr)
 280                         (error "Multiple expressions in --eval option: ~S"
 281                                value)))))
 282                (:load
 283                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 284                                                value)
 285                   (load (native-pathname value))))))
 286            (flush-standard-output-streams)))
 287     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 288       (dolist (option options)
 289         (process-1 option)))))
 290
 291 (defun process-script (script)
 292   (let ((pathname (native-pathname script)))
 293     (handling-end-of-the-world
 294       (with-open-file (f pathname :element-type :default)
 295         (sb!fasl::maybe-skip-shebang-line f)
 296         (load f :verbose nil :print nil)
 297         (quit)))))
 298
 299 ;; Errors while processing the command line cause the system to QUIT,
 300 ;; instead of trying to go into the Lisp debugger, because trying to
 301 ;; go into the Lisp debugger would get into various annoying issues of
 302 ;; where we should go after the user tries to return from the
 303 ;; debugger.
 304 (defun startup-error (control-string &rest args)
 305   (format *error-output*
 306           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 307           control-string
 308           args)
 309   (quit :unix-status 1))
 310
 311 ;;; the default system top level function
 312 (defun toplevel-init ()
 313   (/show0 "entering TOPLEVEL-INIT")
 314   (let ( ;; value of --sysinit option
 315         (sysinit nil)
 316         ;; t if --no-sysinit option given
 317         (no-sysinit nil)
 318         ;; value of --userinit option
 319         (userinit nil)
 320         ;; t if --no-userinit option given
 321         (no-userinit nil)
 322         ;; t if --disable-debugger option given
 323         (disable-debugger nil)
 324         ;; list of (<kind> . <string>) conses representing --eval and --load
 325         ;; options. options. --eval options are stored as strings, so that
 326         ;; they can be passed to READ only after their predecessors have been
 327         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 328         ;; creates a package referred to in the next EVAL form. Storing the
 329         ;; original string also makes for easier debugging.
 330         (reversed-options nil)
 331         ;; Has a --noprint option been seen?
 332         (noprint nil)
 333         ;; Has a --script option been seen?
 334         (script nil)
 335         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 336         (options (rest *posix-argv*)))
 337
 338     (declare (type list options))
 339
 340     (/show0 "done with outer LET in TOPLEVEL-INIT")
 341
 342     ;; FIXME: There are lots of ways for errors to happen around here
 343     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 344     ;; READ an --eval string). Make sure that they're handled
 345     ;; reasonably.
 346
 347     ;; Process command line options.
 348     (loop while options do
 349          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 350          (let ((option (first options)))
 351            (flet ((pop-option ()
 352                     (if options
 353                         (pop options)
 354                         (startup-error
 355                          "unexpected end of command line options"))))
 356              (cond ((string= option "--script")
 357                     (pop-option)
 358                     (setf disable-debugger t
 359                           no-userinit t
 360                           no-sysinit t
 361                           script (pop-option))
 362                     (return))
 363                    ((string= option "--sysinit")
 364                     (pop-option)
 365                     (if sysinit
 366                         (startup-error "multiple --sysinit options")
 367                         (setf sysinit (pop-option))))
 368                    ((string= option "--no-sysinit")
 369                     (pop-option)
 370                     (setf no-sysinit t))
 371                    ((string= option "--userinit")
 372                     (pop-option)
 373                     (if userinit
 374                         (startup-error "multiple --userinit options")
 375                         (setf userinit (pop-option))))
 376                    ((string= option "--no-userinit")
 377                     (pop-option)
 378                     (setf no-userinit t))
 379                    ((string= option "--eval")
 380                     (pop-option)
 381                     (push (cons :eval (pop-option)) reversed-options))
 382                    ((string= option "--load")
 383                     (pop-option)
 384                     (push (cons :load (pop-option)) reversed-options))
 385                    ((string= option "--noprint")
 386                     (pop-option)
 387                     (setf noprint t))
 388                    ((string= option "--disable-debugger")
 389                     (pop-option)
 390                     (setf disable-debugger t))
 391                    ((string= option "--end-toplevel-options")
 392                     (pop-option)
 393                     (return))
 394                    (t
 395                     ;; Anything we don't recognize as a toplevel
 396                     ;; option must be the start of user-level
 397                     ;; options.. except that if we encounter
 398                     ;; "--end-toplevel-options" after we gave up
 399                     ;; because we didn't recognize an option as a
 400                     ;; toplevel option, then the option we gave up on
 401                     ;; must have been an error. (E.g. in
 402                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 403                     ;; this test will let us detect that the string
 404                     ;; "--eval(b)" is an error.)
 405                     (if (find "--end-toplevel-options" options
 406                               :test #'string=)
 407                         (startup-error "bad toplevel option: ~S"
 408                                        (first options))
 409                         (return)))))))
 410     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 411
 412     ;; Delete all the options that we processed, so that only
 413     ;; user-level options are left visible to user code.
 414     (setf (rest *posix-argv*) options)
 415
 416     ;; Disable debugger before processing initialization files & co.
 417     (when disable-debugger
 418       (sb!ext:disable-debugger))
 419
 420     ;; Handle initialization files.
 421     (/show0 "handling initialization files in TOPLEVEL-INIT")
 422     ;; This CATCH is needed for the debugger command TOPLEVEL to
 423     ;; work.
 424     (catch 'toplevel-catcher
 425       ;; We wrap all the pre-REPL user/system customized startup
 426       ;; code in a restart.
 427       ;;
 428       ;; (Why not wrap everything, even the stuff above, in this
 429       ;; restart? Errors above here are basically command line
 430       ;; or Unix environment errors, e.g. a missing file or a
 431       ;; typo on the Unix command line, and you don't need to
 432       ;; get into Lisp to debug them, you should just start over
 433       ;; and do it right at the Unix level. Errors below here
 434       ;; are generally errors in user Lisp code, and it might be
 435       ;; helpful to let the user reach the REPL in order to help
 436       ;; figure out what's going on.)
 437       (restart-case
 438           (progn
 439             (unless no-sysinit
 440               (process-init-file sysinit :system))
 441             (unless no-userinit
 442               (process-init-file userinit :user))
 443             (process-eval/load-options (nreverse reversed-options))
 444             (when script
 445               (process-script script)
 446               (bug "PROCESS-SCRIPT returned")))
 447         (abort ()
 448           :report (lambda (s)
 449                     (write-string
 450                      (if script
 451                          ;; In case script calls (enable-debugger)!
 452                          "Abort script, exiting lisp."
 453                          "Skip to toplevel READ/EVAL/PRINT loop.")
 454                      s))
 455           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 456           (values))                     ; (no-op, just fall through)
 457         (quit ()
 458           :report "Quit SBCL (calling #'QUIT, killing the process)."
 459           :test (lambda (c) (declare (ignore c)) (not script))
 460           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 461           (quit :unix-status 1))))
 462
 463     ;; one more time for good measure, in case we fell out of the
 464     ;; RESTART-CASE above before one of the flushes in the ordinary
 465     ;; flow of control had a chance to operate
 466     (flush-standard-output-streams)
 467
 468     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 469     (toplevel-repl noprint)
 470     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 471     (critically-unreachable "after TOPLEVEL-REPL")))
 472
 473 ;;; hooks to support customized toplevels like ACL-style toplevel from
 474 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 475 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 476 (defvar *repl-read-form-fun* #'repl-read-form-fun
 477   #!+sb-doc
 478   "A function of two stream arguments IN and OUT for the toplevel REPL to
 479 call: Return the next Lisp form to evaluate (possibly handling other magic --
 480 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 481 stream is there to support magic which requires issuing new prompts.")
 482 (defvar *repl-prompt-fun* #'repl-prompt-fun
 483   #!+sb-doc
 484   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 485 the user for input.")
 486 (defvar *repl-fun-generator* (constantly #'repl-fun)
 487   #!+sb-doc
 488   "A function of no arguments returning a function of one argument NOPRINT
 489 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 490 *STANDARD-OUTPUT* are set up.")
 491
 492 ;;; read-eval-print loop for the default system toplevel
 493 (defun toplevel-repl (noprint)
 494   (/show0 "entering TOPLEVEL-REPL")
 495   (let ((* nil) (** nil) (*** nil)
 496         (- nil)
 497         (+ nil) (++ nil) (+++ nil)
 498         (/// nil) (// nil) (/ nil))
 499     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 500     (let ((repl-fun (funcall *repl-fun-generator*)))
 501       ;; Each REPL in a multithreaded world should have bindings of
 502       ;; most CL specials (most critically *PACKAGE*).
 503       (with-rebound-io-syntax
 504           (handler-bind ((step-condition 'invoke-stepper))
 505             (loop
 506                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 507                ;; CLHS recommends that there should always be an
 508                ;; ABORT restart; we have this one here, and one per
 509                ;; debugger level.
 510                (with-simple-restart
 511                    (abort "~@<Exit debugger, returning to top level.~@:>")
 512                  (catch 'toplevel-catcher
 513                    ;; In the event of a control-stack-exhausted-error, we
 514                    ;; should have unwound enough stack by the time we get
 515                    ;; here that this is now possible.
 516                    #!-win32
 517                    (sb!kernel::reset-control-stack-guard-page)
 518                    (funcall repl-fun noprint)
 519                    (critically-unreachable "after REPL")))))))))
 520
 521 ;;; Our default REPL prompt is the minimal traditional one.
 522 (defun repl-prompt-fun (stream)
 523   (fresh-line stream)
 524   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 525
 526 ;;; Our default form reader does relatively little magic, but does
 527 ;;; handle the Unix-style EOF-is-end-of-process convention.
 528 (defun repl-read-form-fun (in out)
 529   (declare (type stream in out) (ignore out))
 530   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 531   ;; recovered from -- flip it here.
 532   (when *read-suppress*
 533     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 534     (setf *read-suppress* nil))
 535   (let* ((eof-marker (cons nil nil))
 536          (form (read in nil eof-marker)))
 537     (if (eq form eof-marker)
 538         (quit)
 539         form)))
 540
 541 (defun repl-fun (noprint)
 542   (/show0 "entering REPL")
 543   (loop
 544    (unwind-protect
 545         (progn
 546           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 547           (scrub-control-stack)
 548           (sb!thread::get-foreground)
 549           (unless noprint
 550             (flush-standard-output-streams)
 551             (funcall *repl-prompt-fun* *standard-output*)
 552             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 553             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 554             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 555             ;; odd. But maybe there *is* a valid reason in some
 556             ;; circumstances? perhaps some deadlock issue when being driven
 557             ;; by another process or something...)
 558             (force-output *standard-output*))
 559           (let* ((form (funcall *repl-read-form-fun*
 560                                 *standard-input*
 561                                 *standard-output*))
 562                  (results (multiple-value-list (interactive-eval form))))
 563             (unless noprint
 564               (dolist (result results)
 565                 (fresh-line)
 566                 (prin1 result)))))
 567      ;; If we started stepping in the debugger we want to stop now.
 568      (disable-stepping))))
 569 \f
 570 ;;; a convenient way to get into the assembly-level debugger
 571 (defun %halt ()
 572   (%primitive sb!c:halt))