src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a pathname
  60 designator for the default sysinit file, or NIL. If the function returns NIL,
  61 no sysinit file is used unless one has been specified on the command-line.")
  62
  63 (defvar *userinit-pathname-function* #'userinit-pathname
  64   #!+sb-doc
  65   "Designator for a function of zero arguments called to obtain a pathname
  66 designator or a stream for the default userinit file, or NIL. If the function
  67 returns NIL, no userinit file is used unless one has been specified on the
  68 command-line.")
  69
  70 \f
  71 ;;;; miscellaneous utilities for working with with TOPLEVEL
  72
  73 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  74 ;;; by QUIT) is caught and any final processing and return codes are
  75 ;;; handled appropriately.
  76 (defmacro handling-end-of-the-world (&body body)
  77   (with-unique-names (caught)
  78     `(let ((,caught (catch '%end-of-the-world
  79                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  80                       (unwind-protect
  81                            (progn ,@body)
  82                         (call-hooks "exit" *exit-hooks*)))))
  83       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  84       (flush-standard-output-streams)
  85       (sb!thread::terminate-session)
  86       (/show0 "calling UNIX-EXIT")
  87       (sb!unix:unix-exit ,caught))))
  88 \f
  89 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  90
  91 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  92 ;;; of hyperspace.
  93 (defmacro infinite-error-protect (&rest forms)
  94   `(unless (infinite-error-protector)
  95      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  96      (let ((*current-error-depth* (1+ *current-error-depth*)))
  97        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  98        ;; arbitrary truncation
  99        #!+sb-show (sb!debug:backtrace 8)
 100        ,@forms)))
 101
 102 ;;; a helper function for INFINITE-ERROR-PROTECT
 103 (defun infinite-error-protector ()
 104   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 105   (/hexstr *current-error-depth*)
 106   (cond ((not *cold-init-complete-p*)
 107          (%primitive print "Argh! error in cold init, halting")
 108          (%primitive sb!c:halt))
 109         ((or (not (boundp '*current-error-depth*))
 110              (not (realp   *current-error-depth*))
 111              (not (boundp '*maximum-error-depth*))
 112              (not (realp   *maximum-error-depth*)))
 113          (%primitive print "Argh! corrupted error depth, halting")
 114          (%primitive sb!c:halt))
 115         ((> *current-error-depth* *maximum-error-depth*)
 116          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 117          (/hexstr *maximum-error-depth*)
 118          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 119          (error-error "Help! "
 120                       *current-error-depth*
 121                       " nested errors. "
 122                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 123          t)
 124         (t
 125          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 126          nil)))
 127
 128 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 129 ;;; one point (shown below), and SBCL cross-compiled it without
 130 ;;; warning about FORMS being undefined. Check whether that problem
 131 ;;; (missing warning) is repeatable in the final system and if so, fix
 132 ;;; it.
 133 #|
 134 (defun infinite-error-protector ()
 135   `(cond ((not *cold-init-complete-p*)
 136           (%primitive print "Argh! error in cold init, halting")
 137           (%primitive sb!c:halt))
 138          ((or (not (boundp '*current-error-depth*))
 139               (not (realp   *current-error-depth*))
 140               (not (boundp '*maximum-error-depth*))
 141               (not (realp   *maximum-error-depth*)))
 142           (%primitive print "Argh! corrupted error depth, halting")
 143           (%primitive sb!c:halt))
 144          ((> *current-error-depth* *maximum-error-depth*)
 145           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 146           (error-error "Help! "
 147                        *current-error-depth*
 148                        " nested errors. "
 149                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 150           (progn ,@forms)
 151           t)
 152          (t
 153           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 154           nil)))
 155 |#
 156 \f
 157 ;;;; miscellaneous external functions
 158
 159 (defun sleep (n)
 160   #!+sb-doc
 161   "This function causes execution to be suspended for N seconds. N may
 162   be any non-negative, non-complex number."
 163   (when (or (not (realp n))
 164             (minusp n))
 165     (error 'simple-type-error
 166            :format-control "invalid argument to SLEEP: ~S"
 167            :format-arguments (list n)
 168            :datum n
 169            :expected-type '(real 0)))
 170   #!-win32
 171   (multiple-value-bind (sec nsec)
 172       (if (integerp n)
 173           (values n 0)
 174           (multiple-value-bind (sec frac)
 175               (truncate n)
 176             (values sec (truncate frac 1e-9))))
 177     (sb!unix:nanosleep sec nsec))
 178   #!+win32
 179   (sb!win32:millisleep (truncate (* n 1000)))
 180   nil)
 181 \f
 182 ;;;; the default toplevel function
 183
 184 (defvar / nil
 185   #!+sb-doc
 186   "a list of all the values returned by the most recent top level EVAL")
 187 (defvar //  nil #!+sb-doc "the previous value of /")
 188 (defvar /// nil #!+sb-doc "the previous value of //")
 189 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 190 (defvar **  nil #!+sb-doc "the previous value of *")
 191 (defvar *** nil #!+sb-doc "the previous value of **")
 192 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 193 (defvar ++  nil #!+sb-doc "the previous value of +")
 194 (defvar +++ nil #!+sb-doc "the previous value of ++")
 195 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 196
 197 (defun interactive-eval (form &key (eval #'eval))
 198   #!+sb-doc
 199   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 200 +++, ++, +, ///, //, /, and -."
 201   (setf - form)
 202   (unwind-protect
 203        (let ((results (multiple-value-list (funcall eval form))))
 204          (setf /// //
 205                // /
 206                / results
 207                *** **
 208                ** *
 209                * (car results)))
 210     (setf +++ ++
 211           ++ +
 212           + -))
 213   (unless (boundp '*)
 214     ;; The bogon returned an unbound marker.
 215     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 216     ;; instead of just the first one.
 217     (setf * nil)
 218     (cerror "Go on with * set to NIL."
 219             "EVAL returned an unbound marker."))
 220   (values-list /))
 221
 222 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 223 ;;; output streams before proceeding.
 224 (defun flush-standard-output-streams ()
 225   (dolist (name '(*debug-io*
 226                   *error-output*
 227                   *query-io*
 228                   *standard-output*
 229                   *trace-output*
 230                   *terminal-io*))
 231     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 232     (force-output (symbol-value name)))
 233   (values))
 234
 235 (defun process-init-file (specified-pathname kind)
 236   (multiple-value-bind (context default-function)
 237       (ecase kind
 238         (:system
 239          (values "sysinit" *sysinit-pathname-function*))
 240         (:user
 241          (values "userinit" *userinit-pathname-function*)))
 242     (flet ((process-stream (stream pathname)
 243              (with-simple-restart (abort "Skip rest of ~A file ~S."
 244                                          context (native-namestring pathname))
 245                (loop
 246                  (with-simple-restart
 247                      (continue "Ignore error and continue processing ~A file ~S."
 248                                context (native-namestring pathname))
 249                    (let ((form (read stream nil stream)))
 250                      (if (eq stream form)
 251                          (return-from process-init-file nil)
 252                          (eval form))))))))
 253       (if specified-pathname
 254           (with-open-file (stream (parse-native-namestring specified-pathname)
 255                                   :if-does-not-exist nil)
 256             (if stream
 257                 (process-stream stream (pathname stream))
 258                 (cerror "Ignore missing init file"
 259                         "The specified ~A file ~A was not found."
 260                         context specified-pathname)))
 261           (let ((default (funcall default-function)))
 262             (when default
 263               (with-open-file (stream (pathname default) :if-does-not-exist nil)
 264                 (when stream
 265                   (process-stream stream (pathname stream))))))))))
 266
 267 (defun process-eval/load-options (options)
 268   (/show0 "handling --eval and --load options")
 269   (flet ((process-1 (cons)
 270            (destructuring-bind (opt . value) cons
 271              (ecase opt
 272                (:eval
 273                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 274                                                value)
 275                   (multiple-value-bind (expr pos) (read-from-string value)
 276                     (if (eq value (read-from-string value nil value :start pos))
 277                         (eval expr)
 278                         (error "Multiple expressions in --eval option: ~S"
 279                                value)))))
 280                (:load
 281                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 282                                                value)
 283                   (load (native-pathname value))))))
 284            (flush-standard-output-streams)))
 285     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 286       (dolist (option options)
 287         (process-1 option)))))
 288
 289 (defun process-script (script)
 290   (let ((pathname (native-pathname script)))
 291     (handling-end-of-the-world
 292       (with-open-file (f pathname :element-type :default)
 293         (sb!fasl::maybe-skip-shebang-line f)
 294         (load f :verbose nil :print nil)
 295         (quit)))))
 296
 297 ;; Errors while processing the command line cause the system to QUIT,
 298 ;; instead of trying to go into the Lisp debugger, because trying to
 299 ;; go into the Lisp debugger would get into various annoying issues of
 300 ;; where we should go after the user tries to return from the
 301 ;; debugger.
 302 (defun startup-error (control-string &rest args)
 303   (format *error-output*
 304           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 305           control-string
 306           args)
 307   (quit :unix-status 1))
 308
 309 ;;; the default system top level function
 310 (defun toplevel-init ()
 311   (/show0 "entering TOPLEVEL-INIT")
 312   (let ( ;; value of --sysinit option
 313         (sysinit nil)
 314         ;; t if --no-sysinit option given
 315         (no-sysinit nil)
 316         ;; value of --userinit option
 317         (userinit nil)
 318         ;; t if --no-userinit option given
 319         (no-userinit nil)
 320         ;; t if --disable-debugger option given
 321         (disable-debugger nil)
 322         ;; list of (<kind> . <string>) conses representing --eval and --load
 323         ;; options. options. --eval options are stored as strings, so that
 324         ;; they can be passed to READ only after their predecessors have been
 325         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 326         ;; creates a package referred to in the next EVAL form. Storing the
 327         ;; original string also makes for easier debugging.
 328         (reversed-options nil)
 329         ;; Has a --noprint option been seen?
 330         (noprint nil)
 331         ;; Has a --script option been seen?
 332         (script nil)
 333         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 334         (options (rest *posix-argv*)))
 335
 336     (declare (type list options))
 337
 338     (/show0 "done with outer LET in TOPLEVEL-INIT")
 339
 340     ;; FIXME: There are lots of ways for errors to happen around here
 341     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 342     ;; READ an --eval string). Make sure that they're handled
 343     ;; reasonably.
 344
 345     ;; Process command line options.
 346     (loop while options do
 347          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 348          (let ((option (first options)))
 349            (flet ((pop-option ()
 350                     (if options
 351                         (pop options)
 352                         (startup-error
 353                          "unexpected end of command line options"))))
 354              (cond ((string= option "--script")
 355                     (pop-option)
 356                     (setf disable-debugger t
 357                           no-userinit t
 358                           no-sysinit t
 359                           script (pop-option))
 360                     (return))
 361                    ((string= option "--sysinit")
 362                     (pop-option)
 363                     (if sysinit
 364                         (startup-error "multiple --sysinit options")
 365                         (setf sysinit (pop-option))))
 366                    ((string= option "--no-sysinit")
 367                     (pop-option)
 368                     (setf no-sysinit t))
 369                    ((string= option "--userinit")
 370                     (pop-option)
 371                     (if userinit
 372                         (startup-error "multiple --userinit options")
 373                         (setf userinit (pop-option))))
 374                    ((string= option "--no-userinit")
 375                     (pop-option)
 376                     (setf no-userinit t))
 377                    ((string= option "--eval")
 378                     (pop-option)
 379                     (push (cons :eval (pop-option)) reversed-options))
 380                    ((string= option "--load")
 381                     (pop-option)
 382                     (push (cons :load (pop-option)) reversed-options))
 383                    ((string= option "--noprint")
 384                     (pop-option)
 385                     (setf noprint t))
 386                    ((string= option "--disable-debugger")
 387                     (pop-option)
 388                     (setf disable-debugger t))
 389                    ((string= option "--end-toplevel-options")
 390                     (pop-option)
 391                     (return))
 392                    (t
 393                     ;; Anything we don't recognize as a toplevel
 394                     ;; option must be the start of user-level
 395                     ;; options.. except that if we encounter
 396                     ;; "--end-toplevel-options" after we gave up
 397                     ;; because we didn't recognize an option as a
 398                     ;; toplevel option, then the option we gave up on
 399                     ;; must have been an error. (E.g. in
 400                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 401                     ;; this test will let us detect that the string
 402                     ;; "--eval(b)" is an error.)
 403                     (if (find "--end-toplevel-options" options
 404                               :test #'string=)
 405                         (startup-error "bad toplevel option: ~S"
 406                                        (first options))
 407                         (return)))))))
 408     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 409
 410     ;; Delete all the options that we processed, so that only
 411     ;; user-level options are left visible to user code.
 412     (setf (rest *posix-argv*) options)
 413
 414     ;; Disable debugger before processing initialization files & co.
 415     (when disable-debugger
 416       (sb!ext:disable-debugger))
 417
 418     ;; Handle initialization files.
 419     (/show0 "handling initialization files in TOPLEVEL-INIT")
 420     ;; This CATCH is needed for the debugger command TOPLEVEL to
 421     ;; work.
 422     (catch 'toplevel-catcher
 423       ;; We wrap all the pre-REPL user/system customized startup
 424       ;; code in a restart.
 425       ;;
 426       ;; (Why not wrap everything, even the stuff above, in this
 427       ;; restart? Errors above here are basically command line
 428       ;; or Unix environment errors, e.g. a missing file or a
 429       ;; typo on the Unix command line, and you don't need to
 430       ;; get into Lisp to debug them, you should just start over
 431       ;; and do it right at the Unix level. Errors below here
 432       ;; are generally errors in user Lisp code, and it might be
 433       ;; helpful to let the user reach the REPL in order to help
 434       ;; figure out what's going on.)
 435       (restart-case
 436           (progn
 437             (unless no-sysinit
 438               (process-init-file sysinit :system))
 439             (unless no-userinit
 440               (process-init-file userinit :user))
 441             (process-eval/load-options (nreverse reversed-options))
 442             (when script
 443               (process-script script)
 444               (bug "PROCESS-SCRIPT returned")))
 445         (abort ()
 446           :report (lambda (s)
 447                     (write-string
 448                      (if script
 449                          ;; In case script calls (enable-debugger)!
 450                          "Abort script, exiting lisp."
 451                          "Skip to toplevel READ/EVAL/PRINT loop.")
 452                      s))
 453           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 454           (values))                     ; (no-op, just fall through)
 455         (quit ()
 456           :report "Quit SBCL (calling #'QUIT, killing the process)."
 457           :test (lambda (c) (declare (ignore c)) (not script))
 458           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 459           (quit :unix-status 1))))
 460
 461     ;; one more time for good measure, in case we fell out of the
 462     ;; RESTART-CASE above before one of the flushes in the ordinary
 463     ;; flow of control had a chance to operate
 464     (flush-standard-output-streams)
 465
 466     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 467     (toplevel-repl noprint)
 468     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 469     (critically-unreachable "after TOPLEVEL-REPL")))
 470
 471 ;;; hooks to support customized toplevels like ACL-style toplevel from
 472 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 473 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 474 (defvar *repl-read-form-fun* #'repl-read-form-fun
 475   #!+sb-doc
 476   "A function of two stream arguments IN and OUT for the toplevel REPL to
 477 call: Return the next Lisp form to evaluate (possibly handling other magic --
 478 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 479 stream is there to support magic which requires issuing new prompts.")
 480 (defvar *repl-prompt-fun* #'repl-prompt-fun
 481   #!+sb-doc
 482   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 483 the user for input.")
 484 (defvar *repl-fun-generator* (constantly #'repl-fun)
 485   #!+sb-doc
 486   "A function of no arguments returning a function of one argument NOPRINT
 487 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 488 *STANDARD-OUTPUT* are set up.")
 489
 490 ;;; read-eval-print loop for the default system toplevel
 491 (defun toplevel-repl (noprint)
 492   (/show0 "entering TOPLEVEL-REPL")
 493   (let ((* nil) (** nil) (*** nil)
 494         (- nil)
 495         (+ nil) (++ nil) (+++ nil)
 496         (/// nil) (// nil) (/ nil))
 497     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 498     (let ((repl-fun (funcall *repl-fun-generator*)))
 499       ;; Each REPL in a multithreaded world should have bindings of
 500       ;; most CL specials (most critically *PACKAGE*).
 501       (with-rebound-io-syntax
 502           (handler-bind ((step-condition 'invoke-stepper))
 503             (loop
 504                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 505                ;; CLHS recommends that there should always be an
 506                ;; ABORT restart; we have this one here, and one per
 507                ;; debugger level.
 508                (with-simple-restart
 509                    (abort "~@<Exit debugger, returning to top level.~@:>")
 510                  (catch 'toplevel-catcher
 511                    ;; In the event of a control-stack-exhausted-error, we
 512                    ;; should have unwound enough stack by the time we get
 513                    ;; here that this is now possible.
 514                    #!-win32
 515                    (sb!kernel::reset-control-stack-guard-page)
 516                    (funcall repl-fun noprint)
 517                    (critically-unreachable "after REPL")))))))))
 518
 519 ;;; Our default REPL prompt is the minimal traditional one.
 520 (defun repl-prompt-fun (stream)
 521   (fresh-line stream)
 522   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 523
 524 ;;; Our default form reader does relatively little magic, but does
 525 ;;; handle the Unix-style EOF-is-end-of-process convention.
 526 (defun repl-read-form-fun (in out)
 527   (declare (type stream in out) (ignore out))
 528   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 529   ;; recovered from -- flip it here.
 530   (when *read-suppress*
 531     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 532     (setf *read-suppress* nil))
 533   (let* ((eof-marker (cons nil nil))
 534          (form (read in nil eof-marker)))
 535     (if (eq form eof-marker)
 536         (quit)
 537         form)))
 538
 539 (defun repl-fun (noprint)
 540   (/show0 "entering REPL")
 541   (loop
 542    (unwind-protect
 543         (progn
 544           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 545           (scrub-control-stack)
 546           (sb!thread::get-foreground)
 547           (unless noprint
 548             (flush-standard-output-streams)
 549             (funcall *repl-prompt-fun* *standard-output*)
 550             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 551             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 552             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 553             ;; odd. But maybe there *is* a valid reason in some
 554             ;; circumstances? perhaps some deadlock issue when being driven
 555             ;; by another process or something...)
 556             (force-output *standard-output*))
 557           (let* ((form (funcall *repl-read-form-fun*
 558                                 *standard-input*
 559                                 *standard-output*))
 560                  (results (multiple-value-list (interactive-eval form))))
 561             (unless noprint
 562               (dolist (result results)
 563                 (fresh-line)
 564                 (prin1 result)))))
 565      ;; If we started stepping in the debugger we want to stop now.
 566      (disable-stepping))))
 567 \f
 568 ;;; a convenient way to get into the assembly-level debugger
 569 (defun %halt ()
 570   (%primitive sb!c:halt))