src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar *current-catch-block*)
  22   (defvar *current-unwind-protect-block*)
  23   (defvar *free-interrupt-context-index*))
  24 \f
  25 ;;; specials initialized by !COLD-INIT
  26
  27 ;;; FIXME: These could be converted to DEFVARs.
  28 (declaim (special *gc-inhibit* *need-to-collect-garbage*
  29                   *before-gc-hooks* *after-gc-hooks*
  30                   #!+x86 *pseudo-atomic-atomic*
  31                   #!+x86 *pseudo-atomic-interrupted*
  32                   sb!unix::*interrupts-enabled*
  33                   sb!unix::*interrupt-pending*
  34                   *type-system-initialized*))
  35
  36 (defvar *cold-init-complete-p*)
  37
  38 ;;; counts of nested errors (with internal errors double-counted)
  39 (defvar *maximum-error-depth*)
  40 (defvar *current-error-depth*)
  41 \f
  42 ;;;; miscellaneous utilities for working with with TOPLEVEL
  43
  44 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  45 ;;; by QUIT) is caught and any final processing and return codes are
  46 ;;; handled appropriately.
  47 (defmacro handling-end-of-the-world (&body body)
  48   (with-unique-names (caught)
  49     `(let ((,caught (catch '%end-of-the-world
  50                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  51                       ,@body)))
  52       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  53       (flush-standard-output-streams)
  54       (sb!thread::terminate-session)
  55       (/show0 "calling UNIX-EXIT")
  56       (sb!unix:unix-exit ,caught))))
  57 \f
  58 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  59
  60 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  61 ;;; of hyperspace.
  62 (defmacro infinite-error-protect (&rest forms)
  63   `(unless (infinite-error-protector)
  64      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  65      (let ((*current-error-depth* (1+ *current-error-depth*)))
  66        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  67        ;; arbitrary truncation
  68        #!+sb-show (sb!debug:backtrace 8)
  69        ,@forms)))
  70
  71 ;;; a helper function for INFINITE-ERROR-PROTECT
  72 (defun infinite-error-protector ()
  73   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  74   (/hexstr *current-error-depth*)
  75   (cond ((not *cold-init-complete-p*)
  76          (%primitive print "Argh! error in cold init, halting")
  77          (%primitive sb!c:halt))
  78         ((or (not (boundp '*current-error-depth*))
  79              (not (realp   *current-error-depth*))
  80              (not (boundp '*maximum-error-depth*))
  81              (not (realp   *maximum-error-depth*)))
  82          (%primitive print "Argh! corrupted error depth, halting")
  83          (%primitive sb!c:halt))
  84         ((> *current-error-depth* *maximum-error-depth*)
  85          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  86          (/hexstr *maximum-error-depth*)
  87          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  88          (error-error "Help! "
  89                       *current-error-depth*
  90                       " nested errors. "
  91                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
  92          t)
  93         (t
  94          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
  95          nil)))
  96
  97 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
  98 ;;; one point (shown below), and SBCL cross-compiled it without
  99 ;;; warning about FORMS being undefined. Check whether that problem
 100 ;;; (missing warning) is repeatable in the final system and if so, fix
 101 ;;; it.
 102 #|
 103 (defun infinite-error-protector ()
 104   `(cond ((not *cold-init-complete-p*)
 105           (%primitive print "Argh! error in cold init, halting")
 106           (%primitive sb!c:halt))
 107          ((or (not (boundp '*current-error-depth*))
 108               (not (realp   *current-error-depth*))
 109               (not (boundp '*maximum-error-depth*))
 110               (not (realp   *maximum-error-depth*)))
 111           (%primitive print "Argh! corrupted error depth, halting")
 112           (%primitive sb!c:halt))
 113          ((> *current-error-depth* *maximum-error-depth*)
 114           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 115           (error-error "Help! "
 116                        *current-error-depth*
 117                        " nested errors. "
 118                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 119           (progn ,@forms)
 120           t)
 121          (t
 122           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 123           nil)))
 124 |#
 125 \f
 126 ;;;; miscellaneous external functions
 127
 128 (defun sleep (n)
 129   #!+sb-doc
 130   "This function causes execution to be suspended for N seconds. N may
 131   be any non-negative, non-complex number."
 132   (when (or (not (realp n))
 133             (minusp n))
 134     (error 'simple-type-error
 135            :format-control "invalid argument to SLEEP: ~S"
 136            :format-arguments (list n)
 137            :datum n
 138            :expected-type '(real 0)))
 139   (multiple-value-bind (sec usec)
 140       (if (integerp n)
 141           (values n 0)
 142           (multiple-value-bind (sec frac)
 143               (truncate n)
 144             (values sec (truncate frac 1e-6))))
 145     (sb!unix:unix-select 0 0 0 0 sec usec))
 146   nil)
 147 \f
 148 ;;;; SCRUB-CONTROL-STACK
 149
 150 (defconstant bytes-per-scrub-unit 2048)
 151
 152 ;;; Zero the unused portion of the control stack so that old objects
 153 ;;; are not kept alive because of uninitialized stack variables.
 154
 155 ;;; "To summarize the problem, since not all allocated stack frame
 156 ;;; slots are guaranteed to be written by the time you call an another
 157 ;;; function or GC, there may be garbage pointers retained in your
 158 ;;; dead stack locations.  The stack scrubbing only affects the part
 159 ;;; of the stack from the SP to the end of the allocated stack."
 160 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 161
 162 ;;; So, as an (admittedly lame) workaround, from time to time we call
 163 ;;; scrub-control-stack to zero out all the unused portion.  This is
 164 ;;; supposed to happen when the stack is mostly empty, so that we have
 165 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 166 ;;; REPL and SUB-GC
 167
 168 (defun scrub-control-stack ()
 169   (declare (optimize (speed 3) (safety 0))
 170            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 171
 172   #!-stack-grows-downward-not-upward
 173   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 174          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 175          (end-of-stack
 176           (- (sb!vm:fixnumize sb!vm:*control-stack-end*)
 177              sb!c:*backend-page-size*)))
 178     (labels
 179         ((scrub (ptr offset count)
 180            (declare (type system-area-pointer ptr)
 181                     (type (unsigned-byte 16) offset)
 182                     (type (unsigned-byte 20) count)
 183                     (values (unsigned-byte 20)))
 184            (cond ((>= (sap-int ptr) end-of-stack) 0)
 185                  ((= offset bytes-per-scrub-unit)
 186                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 187                  (t
 188                   (setf (sap-ref-32 ptr offset) 0)
 189                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 190          (look (ptr offset count)
 191            (declare (type system-area-pointer ptr)
 192                     (type (unsigned-byte 16) offset)
 193                     (type (unsigned-byte 20) count)
 194                     (values (unsigned-byte 20)))
 195            (cond ((>= (sap-int ptr) end-of-stack) 0)
 196                  ((= offset bytes-per-scrub-unit)
 197                   count)
 198                  ((zerop (sap-ref-32 ptr offset))
 199                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 200                  (t
 201                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 202       (declare (type (unsigned-byte 32) csp))
 203       (scrub (int-sap (- csp initial-offset))
 204              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 205              0)))
 206
 207   #!+stack-grows-downward-not-upward
 208   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 209          (end-of-stack (+ (sb!vm:fixnumize sb!vm:*control-stack-start*)
 210                           sb!c:*backend-page-size*))
 211          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 212     (labels
 213         ((scrub (ptr offset count)
 214            (declare (type system-area-pointer ptr)
 215                     (type (unsigned-byte 16) offset)
 216                     (type (unsigned-byte 20) count)
 217                     (values (unsigned-byte 20)))
 218            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 219              (cond ((< (sap-int loc) end-of-stack) 0)
 220                    ((= offset bytes-per-scrub-unit)
 221                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 222                           0 count))
 223                    (t ;; need to fix bug in %SET-STACK-REF
 224                     (setf (sap-ref-32 loc 0) 0)
 225                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 226          (look (ptr offset count)
 227            (declare (type system-area-pointer ptr)
 228                     (type (unsigned-byte 16) offset)
 229                     (type (unsigned-byte 20) count)
 230                     (values (unsigned-byte 20)))
 231            (let ((loc (int-sap (- (sap-int ptr) offset))))
 232              (cond ((< (sap-int loc) end-of-stack) 0)
 233                    ((= offset bytes-per-scrub-unit)
 234                     count)
 235                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 236                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 237                    (t
 238                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 239       (declare (type (unsigned-byte 32) csp))
 240       (scrub (int-sap (+ csp initial-offset))
 241              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 242              0))))
 243 \f
 244 ;;;; the default toplevel function
 245
 246 (defvar / nil
 247   #!+sb-doc
 248   "a list of all the values returned by the most recent top level EVAL")
 249 (defvar //  nil #!+sb-doc "the previous value of /")
 250 (defvar /// nil #!+sb-doc "the previous value of //")
 251 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 252 (defvar **  nil #!+sb-doc "the previous value of *")
 253 (defvar *** nil #!+sb-doc "the previous value of **")
 254 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 255 (defvar ++  nil #!+sb-doc "the previous value of +")
 256 (defvar +++ nil #!+sb-doc "the previous value of ++")
 257 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 258
 259 (defun interactive-eval (form)
 260   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 261    +++, ++, +, ///, //, /, and -."
 262   (setf - form)
 263   (let ((results
 264          (multiple-value-list
 265           (eval-in-lexenv form
 266                           (make-null-interactive-lexenv)))))
 267     (setf /// //
 268           // /
 269           / results
 270           *** **
 271           ** *
 272           * (car results)))
 273   (setf +++ ++
 274         ++ +
 275         + -)
 276   (unless (boundp '*)
 277     ;; The bogon returned an unbound marker.
 278     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 279     ;; instead of just the first one.
 280     (setf * nil)
 281     (cerror "Go on with * set to NIL."
 282             "EVAL returned an unbound marker."))
 283   (values-list /))
 284
 285 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 286 ;;; output streams before proceeding.
 287 (defun flush-standard-output-streams ()
 288   (dolist (name '(*debug-io*
 289                   *error-output*
 290                   *query-io*
 291                   *standard-output*
 292                   *trace-output*))
 293     (finish-output (symbol-value name)))
 294   (values))
 295
 296 ;;; the default system top level function
 297 (defun toplevel-init ()
 298
 299   (/show0 "entering TOPLEVEL-INIT")
 300   (sb!thread::init-job-control)
 301   (sb!thread::get-foreground)
 302   (let (;; value of --sysinit option
 303         (sysinit nil)
 304         ;; value of --userinit option
 305         (userinit nil)
 306         ;; values of --eval options, in reverse order; and also any
 307         ;; other options (like --load) which're translated into --eval
 308         ;;
 309         ;; The values are stored as strings, so that they can be
 310         ;; passed to READ only after their predecessors have been
 311         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL
 312         ;; form creates a package referred to in the next EVAL form.
 313         (reversed-evals nil)
 314         ;; Has a --noprint option been seen?
 315         (noprint nil)
 316         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 317         (options (rest *posix-argv*)))
 318
 319     (declare (type list options))
 320
 321     (/show0 "done with outer LET in TOPLEVEL-INIT")
 322
 323     ;; FIXME: There are lots of ways for errors to happen around here
 324     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 325     ;; READ an --eval string). Make sure that they're handled
 326     ;; reasonably. Also, perhaps all errors while parsing the command
 327     ;; line should cause the system to QUIT, instead of trying to go
 328     ;; into the Lisp debugger, since trying to go into the debugger
 329     ;; gets into various annoying issues of where we should go after
 330     ;; the user tries to return from the debugger.
 331
 332     ;; Parse command line options.
 333     (loop while options do
 334           (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 335           (let ((option (first options)))
 336             (flet ((pop-option ()
 337                      (if options
 338                          (pop options)
 339                          (error "unexpected end of command line options"))))
 340               (cond ((string= option "--sysinit")
 341                      (pop-option)
 342                      (if sysinit
 343                          (error "multiple --sysinit options")
 344                          (setf sysinit (pop-option))))
 345                     ((string= option "--userinit")
 346                      (pop-option)
 347                      (if userinit
 348                          (error "multiple --userinit options")
 349                          (setf userinit (pop-option))))
 350                     ((string= option "--eval")
 351                      (pop-option)
 352                      (push (pop-option) reversed-evals))
 353                     ((string= option "--load")
 354                      (pop-option)
 355                      (push
 356                       ;; FIXME: see BUG 296
 357                       (concatenate 'string "(|LOAD| \"" (pop-option) "\")")
 358                       reversed-evals))
 359                     ((string= option "--noprint")
 360                      (pop-option)
 361                      (setf noprint t))
 362                     ;; FIXME: --noprogrammer was deprecated in 0.7.5, and
 363                     ;; in a year or so this backwards compatibility can
 364                     ;; go away.
 365                     ((string= option "--noprogrammer")
 366                      (warn "treating deprecated --noprogrammer as --disable-debugger")
 367                      (pop-option)
 368                      (push "(|DISABLE-DEBUGGER|)" reversed-evals))
 369                     ((string= option "--disable-debugger")
 370                      (pop-option)
 371                      (push "(|DISABLE-DEBUGGER|)" reversed-evals))
 372                     ((string= option "--end-toplevel-options")
 373                      (pop-option)
 374                      (return))
 375                     (t
 376                      ;; Anything we don't recognize as a toplevel
 377                      ;; option must be the start of user-level
 378                      ;; options.. except that if we encounter
 379                      ;; "--end-toplevel-options" after we gave up
 380                      ;; because we didn't recognize an option as a
 381                      ;; toplevel option, then the option we gave up on
 382                      ;; must have been an error. (E.g. in
 383                      ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 384                      ;; this test will let us detect that the string
 385                      ;; "--eval(b)" is an error.)
 386                      (if (find "--end-toplevel-options" options
 387                                :test #'string=)
 388                          (error "bad toplevel option: ~S" (first options))
 389                          (return)))))))
 390     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 391
 392     ;; Delete all the options that we processed, so that only
 393     ;; user-level options are left visible to user code.
 394     (setf (rest *posix-argv*) options)
 395
 396     ;; Handle initialization files.
 397     (/show0 "handling initialization files in TOPLEVEL-INIT")
 398     (flet (;; If any of POSSIBLE-INIT-FILE-NAMES names a real file,
 399            ;; return its truename.
 400            (probe-init-files (&rest possible-init-file-names)
 401              (declare (type list possible-init-file-names))
 402              (/show0 "entering PROBE-INIT-FILES")
 403              (prog1
 404                  (find-if (lambda (x)
 405                             (and (stringp x) (probe-file x)))
 406                           possible-init-file-names)
 407                (/show0 "leaving PROBE-INIT-FILES"))))
 408       (let* ((sbcl-home (posix-getenv "SBCL_HOME"))
 409              (sysinit-truename
 410               (probe-init-files sysinit
 411                                 (concatenate 'string sbcl-home "/sbclrc")
 412                                 "/etc/sbclrc"))
 413              (user-home (or (posix-getenv "HOME")
 414                             (error "The HOME environment variable is unbound, ~
 415                                     so user init file can't be found.")))
 416              (userinit-truename (probe-init-files userinit
 417                                                   (concatenate 'string
 418                                                                user-home
 419                                                                "/.sbclrc"))))
 420
 421         ;; We wrap all the pre-REPL user/system customized startup code
 422         ;; in a restart.
 423         ;;
 424         ;; (Why not wrap everything, even the stuff above, in this
 425         ;; restart? Errors above here are basically command line or
 426         ;; Unix environment errors, e.g. a missing file or a typo on
 427         ;; the Unix command line, and you don't need to get into Lisp
 428         ;; to debug them, you should just start over and do it right
 429         ;; at the Unix level. Errors below here are generally errors
 430         ;; in user Lisp code, and it might be helpful to let the user
 431         ;; reach the REPL in order to help figure out what's going
 432         ;; on.)
 433         (restart-case
 434             (progn
 435               (flet ((process-init-file (truename)
 436                        (when truename
 437                          (unless (load truename)
 438                            (error "~S was not successfully loaded." truename))
 439                          (flush-standard-output-streams))))
 440                 (process-init-file sysinit-truename)
 441                 (process-init-file userinit-truename))
 442
 443               ;; Process --eval options.
 444               (/show0 "handling --eval options in TOPLEVEL-INIT")
 445               (dolist (expr-as-string (reverse reversed-evals))
 446                 (/show0 "handling one --eval option in TOPLEVEL-INIT")
 447                 (let ((expr (with-input-from-string (eval-stream
 448                                                      expr-as-string)
 449                               (let* ((eof-marker (cons :eof :eof))
 450                                      (result (read eval-stream nil eof-marker))
 451                                      (eof (read eval-stream nil eof-marker)))
 452                                 (cond ((eq result eof-marker)
 453                                        (error "unable to parse ~S"
 454                                               expr-as-string))
 455                                       ((not (eq eof eof-marker))
 456                                        (error "more than one expression in ~S"
 457                                               expr-as-string))
 458                                       (t
 459                                        result))))))
 460                   (eval expr)
 461                   (flush-standard-output-streams))))
 462           (continue ()
 463             :report
 464             "Continue anyway (skipping to toplevel read/eval/print loop)."
 465             (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 466             (values)) ; (no-op, just fall through)
 467           (quit ()
 468             :report "Quit SBCL (calling #'QUIT, killing the process)."
 469             (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 470             (quit))))
 471
 472       ;; one more time for good measure, in case we fell out of the
 473       ;; RESTART-CASE above before one of the flushes in the ordinary
 474       ;; flow of control had a chance to operate
 475       (flush-standard-output-streams)
 476
 477       (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 478       (toplevel-repl noprint)
 479       ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 480       (critically-unreachable "after TOPLEVEL-REPL"))))
 481
 482 ;;; hooks to support customized toplevels like ACL-style toplevel from
 483 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 484 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 485 (defvar *repl-read-form-fun* #'repl-read-form-fun
 486   "a function of two stream arguments IN and OUT for the toplevel REPL to
 487   call: Return the next Lisp form to evaluate (possibly handling other
 488   magic -- like ACL-style keyword commands -- which precede the next
 489   Lisp form). The OUT stream is there to support magic which requires
 490   issuing new prompts.")
 491 (defvar *repl-prompt-fun* #'repl-prompt-fun
 492   "a function of one argument STREAM for the toplevel REPL to call: Prompt
 493   the user for input.")
 494 (defvar *repl-fun-generator* (constantly #'repl-fun)
 495   "a function of no arguments returning a function of one argument
 496   NOPRINT that provides the REPL for the system.  Assumes that
 497   *STANDARD-INPUT* and *STANDARD-OUTPUT* are set up.")
 498
 499 ;;; read-eval-print loop for the default system toplevel
 500 (defun toplevel-repl (noprint)
 501   (/show0 "entering TOPLEVEL-REPL")
 502   (let ((* nil) (** nil) (*** nil)
 503         (- nil)
 504         (+ nil) (++ nil) (+++ nil)
 505         (/// nil) (// nil) (/ nil))
 506     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 507     (let ((repl-fun (funcall *repl-fun-generator*)))
 508       ;; Each REPL in a multithreaded world should have bindings of
 509       ;; most CL specials (most critically *PACKAGE*).
 510       (with-rebound-io-syntax
 511         ;; WITH-SIMPLE-RESTART doesn't actually restart its body as
 512         ;; some (like WHN for an embarrassingly long time
 513         ;; ca. 2001-12-07) might think, but instead drops control back
 514         ;; out at the end. So when a TOPLEVEL or outermost-ABORT
 515         ;; restart happens, we need this outer LOOP wrapper to grab
 516         ;; control and start over again. (And it also wraps CATCH
 517         ;; 'TOPLEVEL-CATCHER for similar reasons.)
 518         (loop
 519          (/show0 "about to set up restarts in TOPLEVEL-REPL")
 520          ;; There should only be one TOPLEVEL restart, and it's here,
 521          ;; so restarting at TOPLEVEL always bounces you all the way
 522          ;; out here.
 523          (with-simple-restart (toplevel
 524                                "Restart at toplevel READ/EVAL/PRINT loop.")
 525            ;; We add a new ABORT restart for every debugger level, so
 526            ;; restarting at ABORT in a nested debugger gets you out to
 527            ;; the innermost enclosing debugger, and only when you're
 528            ;; in the outermost, unnested debugger level does
 529            ;; restarting at ABORT get you out to here.
 530            (with-simple-restart
 531                (abort
 532                 "~@<Reduce debugger level (leaving debugger, returning to toplevel).~@:>")
 533              (catch 'toplevel-catcher
 534                (sb!unix::reset-signal-mask)
 535                ;; in the event of a control-stack-exhausted-error, we
 536                ;; should have unwound enough stack by the time we get
 537                ;; here that this is now possible
 538                (sb!kernel::protect-control-stack-guard-page 1)
 539                (funcall repl-fun noprint)
 540                (critically-unreachable "after REPL")))))))))
 541
 542 ;;; Our default REPL prompt is the minimal traditional one.
 543 (defun repl-prompt-fun (stream)
 544   (fresh-line stream)
 545   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 546
 547 ;;; Our default form reader does relatively little magic, but does
 548 ;;; handle the Unix-style EOF-is-end-of-process convention.
 549 (defun repl-read-form-fun (in out)
 550   (declare (type stream in out) (ignore out))
 551   (let* ((eof-marker (cons nil nil))
 552          (form (read in nil eof-marker)))
 553     (if (eq form eof-marker)
 554         (quit)
 555         form)))
 556
 557 (defun repl-fun (noprint)
 558   (/show0 "entering REPL")
 559   (loop
 560    ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 561    (scrub-control-stack)
 562    (sb!thread::get-foreground)
 563    (unless noprint
 564      (funcall *repl-prompt-fun* *standard-output*)
 565      ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 566      ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 567      ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 568      ;; odd. But maybe there *is* a valid reason in some
 569      ;; circumstances? perhaps some deadlock issue when being driven
 570      ;; by another process or something...)
 571      (force-output *standard-output*))
 572    (let* ((form (funcall *repl-read-form-fun*
 573                          *standard-input*
 574                          *standard-output*))
 575           (results (multiple-value-list (interactive-eval form))))
 576      (unless noprint
 577        (dolist (result results)
 578          (fresh-line)
 579          (prin1 result))))))
 580 \f
 581 ;;; a convenient way to get into the assembly-level debugger
 582 (defun %halt ()
 583   (%primitive sb!c:halt))