src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a pathname
  60 designator for the default sysinit file, or NIL. If the function returns NIL,
  61 no sysinit file is used unless one has been specified on the command-line.")
  62
  63 (defvar *userinit-pathname-function* #'userinit-pathname
  64   #!+sb-doc
  65   "Designator for a function of zero arguments called to obtain a pathname
  66 designator or a stream for the default userinit file, or NIL. If the function
  67 returns NIL, no userinit file is used unless one has been specified on the
  68 command-line.")
  69
  70 \f
  71 ;;;; miscellaneous utilities for working with with TOPLEVEL
  72
  73 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  74 ;;; by QUIT) is caught and any final processing and return codes are
  75 ;;; handled appropriately.
  76 (defmacro handling-end-of-the-world (&body body)
  77   (with-unique-names (caught)
  78     `(let ((,caught (catch '%end-of-the-world
  79                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  80                       (unwind-protect
  81                            (progn ,@body)
  82                         (call-hooks "exit" *exit-hooks*)))))
  83       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  84       (flush-standard-output-streams)
  85       (sb!thread::terminate-session)
  86       (/show0 "calling UNIX-EXIT")
  87       (sb!unix:unix-exit ,caught))))
  88 \f
  89 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  90
  91 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  92 ;;; of hyperspace.
  93 (defmacro infinite-error-protect (&rest forms)
  94   `(unless (infinite-error-protector)
  95      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  96      (let ((*current-error-depth* (1+ *current-error-depth*)))
  97        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  98        ;; arbitrary truncation
  99        #!+sb-show (sb!debug:backtrace 8)
 100        ,@forms)))
 101
 102 ;;; a helper function for INFINITE-ERROR-PROTECT
 103 (defun infinite-error-protector ()
 104   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 105   (/hexstr *current-error-depth*)
 106   (cond ((not *cold-init-complete-p*)
 107          (%primitive print "Argh! error in cold init, halting")
 108          (%primitive sb!c:halt))
 109         ((or (not (boundp '*current-error-depth*))
 110              (not (realp   *current-error-depth*))
 111              (not (boundp '*maximum-error-depth*))
 112              (not (realp   *maximum-error-depth*)))
 113          (%primitive print "Argh! corrupted error depth, halting")
 114          (%primitive sb!c:halt))
 115         ((> *current-error-depth* *maximum-error-depth*)
 116          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 117          (/hexstr *maximum-error-depth*)
 118          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 119          (error-error "Help! "
 120                       *current-error-depth*
 121                       " nested errors. "
 122                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 123          t)
 124         (t
 125          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 126          nil)))
 127
 128 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 129 ;;; one point (shown below), and SBCL cross-compiled it without
 130 ;;; warning about FORMS being undefined. Check whether that problem
 131 ;;; (missing warning) is repeatable in the final system and if so, fix
 132 ;;; it.
 133 #|
 134 (defun infinite-error-protector ()
 135   `(cond ((not *cold-init-complete-p*)
 136           (%primitive print "Argh! error in cold init, halting")
 137           (%primitive sb!c:halt))
 138          ((or (not (boundp '*current-error-depth*))
 139               (not (realp   *current-error-depth*))
 140               (not (boundp '*maximum-error-depth*))
 141               (not (realp   *maximum-error-depth*)))
 142           (%primitive print "Argh! corrupted error depth, halting")
 143           (%primitive sb!c:halt))
 144          ((> *current-error-depth* *maximum-error-depth*)
 145           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 146           (error-error "Help! "
 147                        *current-error-depth*
 148                        " nested errors. "
 149                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 150           (progn ,@forms)
 151           t)
 152          (t
 153           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 154           nil)))
 155 |#
 156 \f
 157 ;;;; miscellaneous external functions
 158
 159 (defun sleep (n)
 160   #!+sb-doc
 161   "This function causes execution to be suspended for N seconds. N may
 162   be any non-negative, non-complex number."
 163   (when (or (not (realp n))
 164             (minusp n))
 165     (error 'simple-type-error
 166            :format-control "invalid argument to SLEEP: ~S"
 167            :format-arguments (list n)
 168            :datum n
 169            :expected-type '(real 0)))
 170   #!-win32
 171   (multiple-value-bind (sec nsec)
 172       (if (integerp n)
 173           (values n 0)
 174           (multiple-value-bind (sec frac)
 175               (truncate n)
 176             (values sec (truncate frac 1e-9))))
 177     (sb!unix:nanosleep sec nsec))
 178   #!+win32
 179   (sb!win32:millisleep (truncate (* n 1000)))
 180   nil)
 181 \f
 182 ;;;; SCRUB-CONTROL-STACK
 183
 184 (defconstant bytes-per-scrub-unit 2048)
 185
 186 ;;; Zero the unused portion of the control stack so that old objects
 187 ;;; are not kept alive because of uninitialized stack variables.
 188
 189 ;;; "To summarize the problem, since not all allocated stack frame
 190 ;;; slots are guaranteed to be written by the time you call an another
 191 ;;; function or GC, there may be garbage pointers retained in your
 192 ;;; dead stack locations.  The stack scrubbing only affects the part
 193 ;;; of the stack from the SP to the end of the allocated stack."
 194 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 195
 196 ;;; So, as an (admittedly lame) workaround, from time to time we call
 197 ;;; scrub-control-stack to zero out all the unused portion.  This is
 198 ;;; supposed to happen when the stack is mostly empty, so that we have
 199 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 200 ;;; REPL and SUB-GC
 201
 202 (defun scrub-control-stack ()
 203   (declare (optimize (speed 3) (safety 0))
 204            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 205
 206   #!-stack-grows-downward-not-upward
 207   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 208          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 209          (end-of-stack
 210           (- (sap-int (sb!di::descriptor-sap sb!vm:*control-stack-end*))
 211              (* 2 sb!c:*backend-page-bytes*))))
 212     (labels
 213         ((scrub (ptr offset count)
 214            (declare (type system-area-pointer ptr)
 215                     (type (unsigned-byte 16) offset)
 216                     (type (unsigned-byte 20) count)
 217                     (values (unsigned-byte 20)))
 218            (cond ((>= (sap-int ptr) end-of-stack) 0)
 219                  ((= offset bytes-per-scrub-unit)
 220                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 221                  (t
 222                   (setf (sap-ref-word ptr offset) 0)
 223                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 224          (look (ptr offset count)
 225            (declare (type system-area-pointer ptr)
 226                     (type (unsigned-byte 16) offset)
 227                     (type (unsigned-byte 20) count)
 228                     (values (unsigned-byte 20)))
 229            (cond ((>= (sap-int ptr) end-of-stack) 0)
 230                  ((= offset bytes-per-scrub-unit)
 231                   count)
 232                  ((zerop (sap-ref-word ptr offset))
 233                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 234                  (t
 235                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 236       (declare (type sb!vm::word csp))
 237       (scrub (int-sap (- csp initial-offset))
 238              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 239              0)))
 240
 241   #!+stack-grows-downward-not-upward
 242   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 243          (end-of-stack (+ (sap-int
 244                            (sb!di::descriptor-sap sb!vm:*control-stack-start*))
 245                           (* 2 sb!c:*backend-page-bytes*)))
 246          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 247     (labels
 248         ((scrub (ptr offset count)
 249            (declare (type system-area-pointer ptr)
 250                     (type (unsigned-byte 16) offset)
 251                     (type (unsigned-byte 20) count)
 252                     (values (unsigned-byte 20)))
 253            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 254              (cond ((< (sap-int loc) end-of-stack) 0)
 255                    ((= offset bytes-per-scrub-unit)
 256                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 257                           0 count))
 258                    (t ;; need to fix bug in %SET-STACK-REF
 259                     (setf (sap-ref-word loc 0) 0)
 260                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 261          (look (ptr offset count)
 262            (declare (type system-area-pointer ptr)
 263                     (type (unsigned-byte 16) offset)
 264                     (type (unsigned-byte 20) count)
 265                     (values (unsigned-byte 20)))
 266            (let ((loc (int-sap (- (sap-int ptr) offset))))
 267              (cond ((< (sap-int loc) end-of-stack) 0)
 268                    ((= offset bytes-per-scrub-unit)
 269                     count)
 270                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 271                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 272                    (t
 273                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 274       (declare (type sb!vm::word csp))
 275       (scrub (int-sap (+ csp initial-offset))
 276              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 277              0))))
 278 \f
 279 ;;;; the default toplevel function
 280
 281 (defvar / nil
 282   #!+sb-doc
 283   "a list of all the values returned by the most recent top level EVAL")
 284 (defvar //  nil #!+sb-doc "the previous value of /")
 285 (defvar /// nil #!+sb-doc "the previous value of //")
 286 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 287 (defvar **  nil #!+sb-doc "the previous value of *")
 288 (defvar *** nil #!+sb-doc "the previous value of **")
 289 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 290 (defvar ++  nil #!+sb-doc "the previous value of +")
 291 (defvar +++ nil #!+sb-doc "the previous value of ++")
 292 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 293
 294 (defun interactive-eval (form &key (eval #'eval))
 295   #!+sb-doc
 296   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 297 +++, ++, +, ///, //, /, and -."
 298   (setf - form)
 299   (unwind-protect
 300        (let ((results (multiple-value-list (funcall eval form))))
 301          (setf /// //
 302                // /
 303                / results
 304                *** **
 305                ** *
 306                * (car results)))
 307     (setf +++ ++
 308           ++ +
 309           + -))
 310   (unless (boundp '*)
 311     ;; The bogon returned an unbound marker.
 312     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 313     ;; instead of just the first one.
 314     (setf * nil)
 315     (cerror "Go on with * set to NIL."
 316             "EVAL returned an unbound marker."))
 317   (values-list /))
 318
 319 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 320 ;;; output streams before proceeding.
 321 (defun flush-standard-output-streams ()
 322   (dolist (name '(*debug-io*
 323                   *error-output*
 324                   *query-io*
 325                   *standard-output*
 326                   *trace-output*
 327                   *terminal-io*))
 328     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 329     (force-output (symbol-value name)))
 330   (values))
 331
 332 (defun process-init-file (specified-pathname kind)
 333   (multiple-value-bind (context default-function)
 334       (ecase kind
 335         (:system
 336          (values "sysinit" *sysinit-pathname-function*))
 337         (:user
 338          (values "userinit" *userinit-pathname-function*)))
 339     (flet ((process-stream (stream pathname)
 340              (with-simple-restart (abort "Skip rest of ~A file ~S."
 341                                          context (native-namestring pathname))
 342                (loop
 343                  (with-simple-restart
 344                      (continue "Ignore error and continue processing ~A file ~S."
 345                                context (native-namestring pathname))
 346                    (let ((form (read stream nil stream)))
 347                      (if (eq stream form)
 348                          (return-from process-init-file nil)
 349                          (eval form))))))))
 350       (if specified-pathname
 351           (with-open-file (stream (parse-native-namestring specified-pathname)
 352                                   :if-does-not-exist nil)
 353             (if stream
 354                 (process-stream stream (pathname stream))
 355                 (cerror "Ignore missing init file"
 356                         "The specified ~A file ~A was not found."
 357                         context specified-pathname)))
 358           (let ((default (funcall default-function)))
 359             (when default
 360               (with-open-file (stream (pathname default) :if-does-not-exist nil)
 361                 (when stream
 362                   (process-stream stream (pathname stream))))))))))
 363
 364 (defun process-eval/load-options (options)
 365   (/show0 "handling --eval and --load options")
 366   (flet ((process-1 (cons)
 367            (destructuring-bind (opt . value) cons
 368              (ecase opt
 369                (:eval
 370                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 371                                                value)
 372                   (multiple-value-bind (expr pos) (read-from-string value)
 373                     (if (eq value (read-from-string value nil value :start pos))
 374                         (eval expr)
 375                         (error "Multiple expressions in --eval option: ~S"
 376                                value)))))
 377                (:load
 378                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 379                                                value)
 380                   (load (native-pathname value))))))
 381            (flush-standard-output-streams)))
 382     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 383       (dolist (option options)
 384         (process-1 option)))))
 385
 386 ;;; Skips past the shebang line on stream, if any.
 387 (defun maybe-skip-shebang-line (stream)
 388   (let ((p (file-position stream)))
 389     (flet ((next () (read-byte stream nil)))
 390       (unwind-protect
 391            (when (and (eq (next) (char-code #\#))
 392                       (eq (next) (char-code #\!)))
 393              (setf p nil)
 394              (loop for x = (next)
 395                    until (or (not x) (eq x (char-code #\newline)))))
 396         (when p
 397           (file-position stream p))))
 398     t))
 399
 400 (defun process-script (script)
 401   (let ((pathname (native-pathname script))
 402         (ok nil))
 403     (unwind-protect
 404          (with-open-file (f pathname :element-type :default)
 405            (maybe-skip-shebang-line f)
 406            (load f :verbose nil :print nil)
 407            (setf ok t))
 408       (quit :unix-status (if ok 0 1)))))
 409
 410 ;; Errors while processing the command line cause the system to QUIT,
 411 ;; instead of trying to go into the Lisp debugger, because trying to
 412 ;; go into the Lisp debugger would get into various annoying issues of
 413 ;; where we should go after the user tries to return from the
 414 ;; debugger.
 415 (defun startup-error (control-string &rest args)
 416   (format *error-output*
 417           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 418           control-string
 419           args)
 420   (quit :unix-status 1))
 421
 422 ;;; the default system top level function
 423 (defun toplevel-init ()
 424   (/show0 "entering TOPLEVEL-INIT")
 425   (let ( ;; value of --sysinit option
 426         (sysinit nil)
 427         ;; t if --no-sysinit option given
 428         (no-sysinit nil)
 429         ;; value of --userinit option
 430         (userinit nil)
 431         ;; t if --no-userinit option given
 432         (no-userinit nil)
 433         ;; t if --disable-debugger option given
 434         (disable-debugger nil)
 435         ;; list of (<kind> . <string>) conses representing --eval and --load
 436         ;; options. options. --eval options are stored as strings, so that
 437         ;; they can be passed to READ only after their predecessors have been
 438         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 439         ;; creates a package referred to in the next EVAL form. Storing the
 440         ;; original string also makes for easier debugging.
 441         (reversed-options nil)
 442         ;; Has a --noprint option been seen?
 443         (noprint nil)
 444         ;; Has a --script option been seen?
 445         (script nil)
 446         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 447         (options (rest *posix-argv*)))
 448
 449     (declare (type list options))
 450
 451     (/show0 "done with outer LET in TOPLEVEL-INIT")
 452
 453     ;; FIXME: There are lots of ways for errors to happen around here
 454     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 455     ;; READ an --eval string). Make sure that they're handled
 456     ;; reasonably.
 457
 458     ;; Process command line options.
 459     (loop while options do
 460          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 461          (let ((option (first options)))
 462            (flet ((pop-option ()
 463                     (if options
 464                         (pop options)
 465                         (startup-error
 466                          "unexpected end of command line options"))))
 467              (cond ((string= option "--script")
 468                     (pop-option)
 469                     (setf disable-debugger t
 470                           no-userinit t
 471                           no-sysinit t
 472                           script (pop-option))
 473                     (return))
 474                    ((string= option "--sysinit")
 475                     (pop-option)
 476                     (if sysinit
 477                         (startup-error "multiple --sysinit options")
 478                         (setf sysinit (pop-option))))
 479                    ((string= option "--no-sysinit")
 480                     (pop-option)
 481                     (setf no-sysinit t))
 482                    ((string= option "--userinit")
 483                     (pop-option)
 484                     (if userinit
 485                         (startup-error "multiple --userinit options")
 486                         (setf userinit (pop-option))))
 487                    ((string= option "--no-userinit")
 488                     (pop-option)
 489                     (setf no-userinit t))
 490                    ((string= option "--eval")
 491                     (pop-option)
 492                     (push (cons :eval (pop-option)) reversed-options))
 493                    ((string= option "--load")
 494                     (pop-option)
 495                     (push (cons :load (pop-option)) reversed-options))
 496                    ((string= option "--noprint")
 497                     (pop-option)
 498                     (setf noprint t))
 499                    ((string= option "--disable-debugger")
 500                     (pop-option)
 501                     (setf disable-debugger t))
 502                    ((string= option "--end-toplevel-options")
 503                     (pop-option)
 504                     (return))
 505                    (t
 506                     ;; Anything we don't recognize as a toplevel
 507                     ;; option must be the start of user-level
 508                     ;; options.. except that if we encounter
 509                     ;; "--end-toplevel-options" after we gave up
 510                     ;; because we didn't recognize an option as a
 511                     ;; toplevel option, then the option we gave up on
 512                     ;; must have been an error. (E.g. in
 513                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 514                     ;; this test will let us detect that the string
 515                     ;; "--eval(b)" is an error.)
 516                     (if (find "--end-toplevel-options" options
 517                               :test #'string=)
 518                         (startup-error "bad toplevel option: ~S"
 519                                        (first options))
 520                         (return)))))))
 521     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 522
 523     ;; Delete all the options that we processed, so that only
 524     ;; user-level options are left visible to user code.
 525     (setf (rest *posix-argv*) options)
 526
 527     ;; Disable debugger before processing initialization files & co.
 528     (when disable-debugger
 529       (sb!ext:disable-debugger))
 530
 531     ;; Handle initialization files.
 532     (/show0 "handling initialization files in TOPLEVEL-INIT")
 533     ;; This CATCH is needed for the debugger command TOPLEVEL to
 534     ;; work.
 535     (catch 'toplevel-catcher
 536       ;; We wrap all the pre-REPL user/system customized startup
 537       ;; code in a restart.
 538       ;;
 539       ;; (Why not wrap everything, even the stuff above, in this
 540       ;; restart? Errors above here are basically command line
 541       ;; or Unix environment errors, e.g. a missing file or a
 542       ;; typo on the Unix command line, and you don't need to
 543       ;; get into Lisp to debug them, you should just start over
 544       ;; and do it right at the Unix level. Errors below here
 545       ;; are generally errors in user Lisp code, and it might be
 546       ;; helpful to let the user reach the REPL in order to help
 547       ;; figure out what's going on.)
 548       (restart-case
 549           (progn
 550             (unless no-sysinit
 551               (process-init-file sysinit :system))
 552             (unless no-userinit
 553               (process-init-file userinit :user))
 554             (process-eval/load-options (nreverse reversed-options))
 555             (when script
 556               (process-script script)
 557               (bug "PROCESS-SCRIPT returned")))
 558         (abort ()
 559           :report (lambda (s)
 560                     (write-string
 561                      (if script
 562                          ;; In case script calls (enable-debugger)!
 563                          "Abort script, exiting lisp."
 564                          "Skip to toplevel READ/EVAL/PRINT loop.")
 565                      s))
 566           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 567           (values))                     ; (no-op, just fall through)
 568         (quit ()
 569           :report "Quit SBCL (calling #'QUIT, killing the process)."
 570           :test (lambda (c) (declare (ignore c)) (not script))
 571           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 572           (quit :unix-status 1))))
 573
 574     ;; one more time for good measure, in case we fell out of the
 575     ;; RESTART-CASE above before one of the flushes in the ordinary
 576     ;; flow of control had a chance to operate
 577     (flush-standard-output-streams)
 578
 579     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 580     (toplevel-repl noprint)
 581     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 582     (critically-unreachable "after TOPLEVEL-REPL")))
 583
 584 ;;; hooks to support customized toplevels like ACL-style toplevel from
 585 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 586 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 587 (defvar *repl-read-form-fun* #'repl-read-form-fun
 588   #!+sb-doc
 589   "A function of two stream arguments IN and OUT for the toplevel REPL to
 590 call: Return the next Lisp form to evaluate (possibly handling other magic --
 591 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 592 stream is there to support magic which requires issuing new prompts.")
 593 (defvar *repl-prompt-fun* #'repl-prompt-fun
 594   #!+sb-doc
 595   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 596 the user for input.")
 597 (defvar *repl-fun-generator* (constantly #'repl-fun)
 598   #!+sb-doc
 599   "A function of no arguments returning a function of one argument NOPRINT
 600 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 601 *STANDARD-OUTPUT* are set up.")
 602
 603 ;;; read-eval-print loop for the default system toplevel
 604 (defun toplevel-repl (noprint)
 605   (/show0 "entering TOPLEVEL-REPL")
 606   (let ((* nil) (** nil) (*** nil)
 607         (- nil)
 608         (+ nil) (++ nil) (+++ nil)
 609         (/// nil) (// nil) (/ nil))
 610     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 611     (let ((repl-fun (funcall *repl-fun-generator*)))
 612       ;; Each REPL in a multithreaded world should have bindings of
 613       ;; most CL specials (most critically *PACKAGE*).
 614       (with-rebound-io-syntax
 615           (handler-bind ((step-condition 'invoke-stepper))
 616             (loop
 617                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 618                ;; CLHS recommends that there should always be an
 619                ;; ABORT restart; we have this one here, and one per
 620                ;; debugger level.
 621                (with-simple-restart
 622                    (abort "~@<Exit debugger, returning to top level.~@:>")
 623                  (catch 'toplevel-catcher
 624                    ;; In the event of a control-stack-exhausted-error, we
 625                    ;; should have unwound enough stack by the time we get
 626                    ;; here that this is now possible.
 627                    #!-win32
 628                    (sb!kernel::protect-control-stack-guard-page 1)
 629                    (funcall repl-fun noprint)
 630                    (critically-unreachable "after REPL")))))))))
 631
 632 ;;; Our default REPL prompt is the minimal traditional one.
 633 (defun repl-prompt-fun (stream)
 634   (fresh-line stream)
 635   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 636
 637 ;;; Our default form reader does relatively little magic, but does
 638 ;;; handle the Unix-style EOF-is-end-of-process convention.
 639 (defun repl-read-form-fun (in out)
 640   (declare (type stream in out) (ignore out))
 641   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 642   ;; recovered from -- flip it here.
 643   (when *read-suppress*
 644     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 645     (setf *read-suppress* nil))
 646   (let* ((eof-marker (cons nil nil))
 647          (form (read in nil eof-marker)))
 648     (if (eq form eof-marker)
 649         (quit)
 650         form)))
 651
 652 (defun repl-fun (noprint)
 653   (/show0 "entering REPL")
 654   (loop
 655    (unwind-protect
 656         (progn
 657           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 658           (scrub-control-stack)
 659           (sb!thread::get-foreground)
 660           (unless noprint
 661             (flush-standard-output-streams)
 662             (funcall *repl-prompt-fun* *standard-output*)
 663             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 664             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 665             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 666             ;; odd. But maybe there *is* a valid reason in some
 667             ;; circumstances? perhaps some deadlock issue when being driven
 668             ;; by another process or something...)
 669             (force-output *standard-output*))
 670           (let* ((form (funcall *repl-read-form-fun*
 671                                 *standard-input*
 672                                 *standard-output*))
 673                  (results (multiple-value-list (interactive-eval form))))
 674             (unless noprint
 675               (dolist (result results)
 676                 (fresh-line)
 677                 (prin1 result)))))
 678      ;; If we started stepping in the debugger we want to stop now.
 679      (disable-stepping))))
 680 \f
 681 ;;; a convenient way to get into the assembly-level debugger
 682 (defun %halt ()
 683   (%primitive sb!c:halt))