src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar *current-catch-block*)
  22   (defvar *current-unwind-protect-block*)
  23   (defvar *free-interrupt-context-index*))
  24 \f
  25 ;;; specials initialized by !COLD-INIT
  26
  27 ;;; FIXME: These could be converted to DEFVARs.
  28 (declaim (special *gc-inhibit* *need-to-collect-garbage*
  29                   *before-gc-hooks* *after-gc-hooks*
  30                   #!+x86 *pseudo-atomic-atomic*
  31                   #!+x86 *pseudo-atomic-interrupted*
  32                   sb!unix::*interrupts-enabled*
  33                   sb!unix::*interrupt-pending*
  34                   *type-system-initialized*))
  35
  36 (defvar *cold-init-complete-p*)
  37
  38 ;;; counts of nested errors (with internal errors double-counted)
  39 (defvar *maximum-error-depth*)
  40 (defvar *current-error-depth*)
  41 \f
  42 ;;;; miscellaneous utilities for working with with TOPLEVEL
  43
  44 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  45 ;;; by QUIT) is caught and any final processing and return codes are
  46 ;;; handled appropriately.
  47 (defmacro handling-end-of-the-world (&body body)
  48   (with-unique-names (caught)
  49     `(let ((,caught (catch '%end-of-the-world
  50                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  51                       ,@body)))
  52        (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  53        (flush-standard-output-streams)
  54        (/show0 "calling UNIX-EXIT")
  55        (sb!unix:unix-exit ,caught))))
  56 \f
  57 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  58
  59 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  60 ;;; of hyperspace.
  61 (defmacro infinite-error-protect (&rest forms)
  62   `(unless (infinite-error-protector)
  63      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  64      (let ((*current-error-depth* (1+ *current-error-depth*)))
  65        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  66        ;; arbitrary truncation
  67        #!+sb-show (sb!debug:backtrace 8)
  68        ,@forms)))
  69
  70 ;;; a helper function for INFINITE-ERROR-PROTECT
  71 (defun infinite-error-protector ()
  72   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  73   (/hexstr *current-error-depth*)
  74   (cond ((not *cold-init-complete-p*)
  75          (%primitive print "Argh! error in cold init, halting")
  76          (%primitive sb!c:halt))
  77         ((or (not (boundp '*current-error-depth*))
  78              (not (realp   *current-error-depth*))
  79              (not (boundp '*maximum-error-depth*))
  80              (not (realp   *maximum-error-depth*)))
  81          (%primitive print "Argh! corrupted error depth, halting")
  82          (%primitive sb!c:halt))
  83         ((> *current-error-depth* *maximum-error-depth*)
  84          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  85          (/hexstr *maximum-error-depth*)
  86          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  87          (error-error "Help! "
  88                       *current-error-depth*
  89                       " nested errors. "
  90                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
  91          t)
  92         (t
  93          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
  94          nil)))
  95
  96 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
  97 ;;; one point (shown below), and SBCL cross-compiled it without
  98 ;;; warning about FORMS being undefined. Check whether that problem
  99 ;;; (missing warning) is repeatable in the final system and if so, fix
 100 ;;; it.
 101 #|
 102 (defun infinite-error-protector ()
 103   `(cond ((not *cold-init-complete-p*)
 104           (%primitive print "Argh! error in cold init, halting")
 105           (%primitive sb!c:halt))
 106          ((or (not (boundp '*current-error-depth*))
 107               (not (realp   *current-error-depth*))
 108               (not (boundp '*maximum-error-depth*))
 109               (not (realp   *maximum-error-depth*)))
 110           (%primitive print "Argh! corrupted error depth, halting")
 111           (%primitive sb!c:halt))
 112          ((> *current-error-depth* *maximum-error-depth*)
 113           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 114           (error-error "Help! "
 115                        *current-error-depth*
 116                        " nested errors. "
 117                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 118           (progn ,@forms)
 119           t)
 120          (t
 121           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 122           nil)))
 123 |#
 124 \f
 125 ;;;; miscellaneous external functions
 126
 127 (defun sleep (n)
 128   #!+sb-doc
 129   "This function causes execution to be suspended for N seconds. N may
 130   be any non-negative, non-complex number."
 131   (when (or (not (realp n))
 132             (minusp n))
 133     (error 'simple-type-error
 134            :format-control "invalid argument to SLEEP: ~S"
 135            :format-arguments (list n)
 136            :datum n
 137            :expected-type '(real 0)))
 138   (multiple-value-bind (sec usec)
 139       (if (integerp n)
 140           (values n 0)
 141           (multiple-value-bind (sec frac)
 142               (truncate n)
 143             (values sec (truncate frac 1e-6))))
 144     (sb!unix:unix-select 0 0 0 0 sec usec))
 145   nil)
 146 \f
 147 ;;;; SCRUB-CONTROL-STACK
 148
 149 (defconstant bytes-per-scrub-unit 2048)
 150
 151 ;;; Zero the unused portion of the control stack so that old objects
 152 ;;; are not kept alive because of uninitialized stack variables.
 153
 154 ;;; "To summarize the problem, since not all allocated stack frame
 155 ;;; slots are guaranteed to be written by the time you call an another
 156 ;;; function or GC, there may be garbage pointers retained in your
 157 ;;; dead stack locations.  The stack scrubbing only affects the part
 158 ;;; of the stack from the SP to the end of the allocated stack."
 159 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 160
 161 ;;; So, as an (admittedly lame) workaround, from time to time we call
 162 ;;; scrub-control-stack to zero out all the unused portion.  This is
 163 ;;; supposed to happen when the stack is mostly empty, so that we have
 164 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 165 ;;; REPL and SUB-GC
 166
 167 (defun scrub-control-stack ()
 168   (declare (optimize (speed 3) (safety 0))
 169            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 170
 171   #!-stack-grows-downward-not-upward
 172   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 173          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 174          (end-of-stack
 175           (- (sb!vm:fixnumize sb!vm:*control-stack-end*)
 176              sb!c:*backend-page-size*)))
 177     (labels
 178         ((scrub (ptr offset count)
 179            (declare (type system-area-pointer ptr)
 180                     (type (unsigned-byte 16) offset)
 181                     (type (unsigned-byte 20) count)
 182                     (values (unsigned-byte 20)))
 183            (cond ((>= (sap-int ptr) end-of-stack) 0)
 184                  ((= offset bytes-per-scrub-unit)
 185                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 186                  (t
 187                   (setf (sap-ref-32 ptr offset) 0)
 188                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 189          (look (ptr offset count)
 190            (declare (type system-area-pointer ptr)
 191                     (type (unsigned-byte 16) offset)
 192                     (type (unsigned-byte 20) count)
 193                     (values (unsigned-byte 20)))
 194            (cond ((>= (sap-int ptr) end-of-stack) 0)
 195                  ((= offset bytes-per-scrub-unit)
 196                   count)
 197                  ((zerop (sap-ref-32 ptr offset))
 198                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 199                  (t
 200                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 201       (declare (type (unsigned-byte 32) csp))
 202       (scrub (int-sap (- csp initial-offset))
 203              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 204              0)))
 205
 206   #!+stack-grows-downward-not-upward
 207   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 208          (end-of-stack (+ (sb!vm:fixnumize sb!vm:*control-stack-start*)
 209                           sb!c:*backend-page-size*))
 210          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 211     (labels
 212         ((scrub (ptr offset count)
 213            (declare (type system-area-pointer ptr)
 214                     (type (unsigned-byte 16) offset)
 215                     (type (unsigned-byte 20) count)
 216                     (values (unsigned-byte 20)))
 217            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 218              (cond ((< (sap-int loc) end-of-stack) 0)
 219                    ((= offset bytes-per-scrub-unit)
 220                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 221                           0 count))
 222                    (t ;; need to fix bug in %SET-STACK-REF
 223                     (setf (sap-ref-32 loc 0) 0)
 224                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 225          (look (ptr offset count)
 226            (declare (type system-area-pointer ptr)
 227                     (type (unsigned-byte 16) offset)
 228                     (type (unsigned-byte 20) count)
 229                     (values (unsigned-byte 20)))
 230            (let ((loc (int-sap (- (sap-int ptr) offset))))
 231              (cond ((< (sap-int loc) end-of-stack) 0)
 232                    ((= offset bytes-per-scrub-unit)
 233                     count)
 234                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 235                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 236                    (t
 237                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 238       (declare (type (unsigned-byte 32) csp))
 239       (scrub (int-sap (+ csp initial-offset))
 240              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 241              0))))
 242 \f
 243 ;;;; the default toplevel function
 244
 245 (defvar / nil
 246   #!+sb-doc
 247   "a list of all the values returned by the most recent top level EVAL")
 248 (defvar //  nil #!+sb-doc "the previous value of /")
 249 (defvar /// nil #!+sb-doc "the previous value of //")
 250 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 251 (defvar **  nil #!+sb-doc "the previous value of *")
 252 (defvar *** nil #!+sb-doc "the previous value of **")
 253 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 254 (defvar ++  nil #!+sb-doc "the previous value of +")
 255 (defvar +++ nil #!+sb-doc "the previous value of ++")
 256 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 257
 258 (defun interactive-eval (form)
 259   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 260    +++, ++, +, ///, //, /, and -."
 261   (setf - form)
 262   (let ((results
 263          (multiple-value-list
 264           (eval-in-lexenv form
 265                           (make-null-interactive-lexenv)))))
 266     (setf /// //
 267           // /
 268           / results
 269           *** **
 270           ** *
 271           * (car results)))
 272   (setf +++ ++
 273         ++ +
 274         + -)
 275   (unless (boundp '*)
 276     ;; The bogon returned an unbound marker.
 277     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 278     ;; instead of just the first one.
 279     (setf * nil)
 280     (cerror "Go on with * set to NIL."
 281             "EVAL returned an unbound marker."))
 282   (values-list /))
 283
 284 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 285 ;;; output streams before proceeding.
 286 (defun flush-standard-output-streams ()
 287   (dolist (name '(*debug-io*
 288                   *error-output*
 289                   *query-io*
 290                   *standard-output*
 291                   *trace-output*))
 292     (finish-output (symbol-value name)))
 293   (values))
 294
 295 ;;; the default system top level function
 296 (defun toplevel-init ()
 297
 298   (/show0 "entering TOPLEVEL-INIT")
 299   (setf sb!thread::*session-lock* (sb!thread:make-mutex :name "the terminal"))
 300   (sb!thread::get-foreground)
 301   (let (;; value of --sysinit option
 302         (sysinit nil)
 303         ;; value of --userinit option
 304         (userinit nil)
 305         ;; values of --eval options, in reverse order; and also any
 306         ;; other options (like --load) which're translated into --eval
 307         ;;
 308         ;; The values are stored as strings, so that they can be
 309         ;; passed to READ only after their predecessors have been
 310         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL
 311         ;; form creates a package referred to in the next EVAL form.
 312         (reversed-evals nil)
 313         ;; Has a --noprint option been seen?
 314         (noprint nil)
 315         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 316         (options (rest *posix-argv*)))
 317
 318     (declare (type list options))
 319
 320     (/show0 "done with outer LET in TOPLEVEL-INIT")
 321
 322     ;; FIXME: There are lots of ways for errors to happen around here
 323     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 324     ;; READ an --eval string). Make sure that they're handled
 325     ;; reasonably. Also, perhaps all errors while parsing the command
 326     ;; line should cause the system to QUIT, instead of trying to go
 327     ;; into the Lisp debugger, since trying to go into the debugger
 328     ;; gets into various annoying issues of where we should go after
 329     ;; the user tries to return from the debugger.
 330
 331     ;; Parse command line options.
 332     (loop while options do
 333           (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 334           (let ((option (first options)))
 335             (flet ((pop-option ()
 336                      (if options
 337                          (pop options)
 338                          (error "unexpected end of command line options"))))
 339               (cond ((string= option "--sysinit")
 340                      (pop-option)
 341                      (if sysinit
 342                          (error "multiple --sysinit options")
 343                          (setf sysinit (pop-option))))
 344                     ((string= option "--userinit")
 345                      (pop-option)
 346                      (if userinit
 347                          (error "multiple --userinit options")
 348                          (setf userinit (pop-option))))
 349                     ((string= option "--eval")
 350                      (pop-option)
 351                      (push (pop-option) reversed-evals))
 352                     ((string= option "--load")
 353                      (pop-option)
 354                      (push (concatenate 'string "(LOAD \"" (pop-option) "\")")
 355                            reversed-evals))
 356                     ((string= option "--noprint")
 357                      (pop-option)
 358                      (setf noprint t))
 359                     ;; FIXME: --noprogrammer was deprecated in 0.7.5, and
 360                     ;; in a year or so this backwards compatibility can
 361                     ;; go away.
 362                     ((string= option "--noprogrammer")
 363                      (warn "treating deprecated --noprogrammer as --disable-debugger")
 364                      (pop-option)
 365                      (push "(DISABLE-DEBUGGER)" reversed-evals))
 366                     ((string= option "--disable-debugger")
 367                      (pop-option)
 368                      (push "(DISABLE-DEBUGGER)" reversed-evals))
 369                     ((string= option "--end-toplevel-options")
 370                      (pop-option)
 371                      (return))
 372                     (t
 373                      ;; Anything we don't recognize as a toplevel
 374                      ;; option must be the start of user-level
 375                      ;; options.. except that if we encounter
 376                      ;; "--end-toplevel-options" after we gave up
 377                      ;; because we didn't recognize an option as a
 378                      ;; toplevel option, then the option we gave up on
 379                      ;; must have been an error. (E.g. in
 380                      ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 381                      ;; this test will let us detect that the string
 382                      ;; "--eval(b)" is an error.)
 383                      (if (find "--end-toplevel-options" options
 384                                :test #'string=)
 385                          (error "bad toplevel option: ~S" (first options))
 386                          (return)))))))
 387     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 388
 389     ;; Delete all the options that we processed, so that only
 390     ;; user-level options are left visible to user code.
 391     (setf (rest *posix-argv*) options)
 392
 393     ;; Handle initialization files.
 394     (/show0 "handling initialization files in TOPLEVEL-INIT")
 395     (flet (;; If any of POSSIBLE-INIT-FILE-NAMES names a real file,
 396            ;; return its truename.
 397            (probe-init-files (&rest possible-init-file-names)
 398              (declare (type list possible-init-file-names))
 399              (/show0 "entering PROBE-INIT-FILES")
 400              (prog1
 401                  (find-if (lambda (x)
 402                             (and (stringp x) (probe-file x)))
 403                           possible-init-file-names)
 404                (/show0 "leaving PROBE-INIT-FILES"))))
 405       (let* ((sbcl-home (posix-getenv "SBCL_HOME"))
 406              (sysinit-truename (if sbcl-home
 407                                    (probe-init-files sysinit
 408                                                      (concatenate 'string
 409                                                                   sbcl-home
 410                                                                   "/sbclrc"))
 411                                    (probe-init-files sysinit
 412                                                      "/etc/sbclrc"
 413                                                      "/usr/local/etc/sbclrc")))
 414              (user-home (or (posix-getenv "HOME")
 415                             (error "The HOME environment variable is unbound, ~
 416                                     so user init file can't be found.")))
 417              (userinit-truename (probe-init-files userinit
 418                                                   (concatenate 'string
 419                                                                user-home
 420                                                                "/.sbclrc"))))
 421
 422         ;; We wrap all the pre-REPL user/system customized startup code
 423         ;; in a restart.
 424         ;;
 425         ;; (Why not wrap everything, even the stuff above, in this
 426         ;; restart? Errors above here are basically command line or
 427         ;; Unix environment errors, e.g. a missing file or a typo on
 428         ;; the Unix command line, and you don't need to get into Lisp
 429         ;; to debug them, you should just start over and do it right
 430         ;; at the Unix level. Errors below here are generally errors
 431         ;; in user Lisp code, and it might be helpful to let the user
 432         ;; reach the REPL in order to help figure out what's going
 433         ;; on.)
 434         (restart-case
 435             (progn
 436               (flet ((process-init-file (truename)
 437                        (when truename
 438                          (unless (load truename)
 439                            (error "~S was not successfully loaded." truename))
 440                          (flush-standard-output-streams))))
 441                 (process-init-file sysinit-truename)
 442                 (process-init-file userinit-truename))
 443
 444               ;; Process --eval options.
 445               (/show0 "handling --eval options in TOPLEVEL-INIT")
 446               (dolist (expr-as-string (reverse reversed-evals))
 447                 (/show0 "handling one --eval option in TOPLEVEL-INIT")
 448                 (let ((expr (with-input-from-string (eval-stream
 449                                                      expr-as-string)
 450                               (let* ((eof-marker (cons :eof :eof))
 451                                      (result (read eval-stream nil eof-marker))
 452                                      (eof (read eval-stream nil eof-marker)))
 453                                 (cond ((eq result eof-marker)
 454                                        (error "unable to parse ~S"
 455                                               expr-as-string))
 456                                       ((not (eq eof eof-marker))
 457                                        (error "more than one expression in ~S"
 458                                               expr-as-string))
 459                                       (t
 460                                        result))))))
 461                   (eval expr)
 462                   (flush-standard-output-streams))))
 463           (continue ()
 464             :report
 465             "Continue anyway (skipping to toplevel read/eval/print loop)."
 466             (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 467             (values)) ; (no-op, just fall through)
 468           (quit ()
 469             :report "Quit SBCL (calling #'QUIT, killing the process)."
 470             (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 471             (quit))))
 472
 473       ;; one more time for good measure, in case we fell out of the
 474       ;; RESTART-CASE above before one of the flushes in the ordinary
 475       ;; flow of control had a chance to operate
 476       (flush-standard-output-streams)
 477
 478       (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 479       (toplevel-repl noprint)
 480       ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 481       (critically-unreachable "after TOPLEVEL-REPL"))))
 482
 483 ;;; halt-on-failures and prompt-on-failures modes, suitable for
 484 ;;; noninteractive and interactive use respectively
 485 (defun disable-debugger ()
 486   (setf *debugger-hook* 'noprogrammer-debugger-hook-fun
 487         *debug-io* *error-output*))
 488 (defun enable-debugger ()
 489   (setf *debugger-hook* nil
 490         *debug-io* *query-io*))
 491
 492 ;;; read-eval-print loop for the default system toplevel
 493 (defun toplevel-repl (noprint)
 494   (/show0 "entering TOPLEVEL-REPL")
 495   (let ((* nil) (** nil) (*** nil)
 496         (- nil)
 497         (+ nil) (++ nil) (+++ nil)
 498         (/// nil) (// nil) (/ nil))
 499     ;; WITH-SIMPLE-RESTART doesn't actually restart its body as some
 500     ;; (like WHN for an embarrassingly long time ca. 2001-12-07) might
 501     ;; think, but instead drops control back out at the end. So when a
 502     ;; TOPLEVEL or outermost-ABORT restart happens, we need this outer
 503     ;; LOOP wrapper to grab control and start over again. (And it also
 504     ;; wraps CATCH 'TOPLEVEL-CATCHER for similar reasons.)
 505     (loop
 506      (/show0 "about to set up restarts in TOPLEVEL-REPL")
 507      ;; There should only be one TOPLEVEL restart, and it's here, so
 508      ;; restarting at TOPLEVEL always bounces you all the way out here.
 509      (with-simple-restart (toplevel
 510                            "Restart at toplevel READ/EVAL/PRINT loop.")
 511        ;; We add a new ABORT restart for every debugger level, so
 512        ;; restarting at ABORT in a nested debugger gets you out to the
 513        ;; innermost enclosing debugger, and only when you're in the
 514        ;; outermost, unnested debugger level does restarting at ABORT
 515        ;; get you out to here.
 516        (with-simple-restart
 517            (abort
 518             "~@<Reduce debugger level (leaving debugger, returning to toplevel).~@:>")
 519          (catch 'toplevel-catcher
 520            #!-sunos (sb!unix:unix-sigsetmask 0) ; FIXME: What is this for?
 521            ;; in the event of a control-stack-exhausted-error, we should
 522            ;; have unwound enough stack by the time we get here that this
 523            ;; is now possible
 524            (sb!kernel::protect-control-stack-guard-page 1)
 525            (funcall *repl-fun* noprint)
 526            (critically-unreachable "after REPL")))))))
 527
 528 ;;; Our default REPL prompt is the minimal traditional one.
 529 (defun repl-prompt-fun (stream)
 530   (fresh-line stream)
 531   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 532
 533 ;;; Our default form reader does relatively little magic, but does
 534 ;;; handle the Unix-style EOF-is-end-of-process convention.
 535 (defun repl-read-form-fun (in out)
 536   (declare (type stream in out) (ignore out))
 537   (let* ((eof-marker (cons nil nil))
 538          (form (read in nil eof-marker)))
 539     (if (eq form eof-marker)
 540         (quit)
 541         form)))
 542
 543 ;;; hooks to support customized toplevels like ACL-style toplevel
 544 ;;; from KMR on sbcl-devel 2002-12-21
 545 (defvar *repl-read-form-fun* #'repl-read-form-fun
 546   "a function of two stream arguments IN and OUT for the toplevel REPL to
 547   call: Return the next Lisp form to evaluate (possibly handling other
 548   magic -- like ACL-style keyword commands -- which precede the next
 549   Lisp form). The OUT stream is there to support magic which requires
 550   issuing new prompts.")
 551 (defvar *repl-prompt-fun* #'repl-prompt-fun
 552   "a function of one argument STREAM for the toplevel REPL to call: Prompt
 553   the user for input.")
 554 (defvar *repl-fun* #'repl-fun
 555   "a function of one argument NOPRINT that provides the REPL for the system.
 556   Assumes that *standard-input* and *standard-output* are setup.")
 557
 558 (defun repl-fun (noprint)
 559   (/show0 "entering REPL")
 560   (loop
 561    ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 562    (scrub-control-stack)
 563    (unless noprint
 564      (funcall *repl-prompt-fun* *standard-output*)
 565      ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 566      ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 567      ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 568      ;; odd. But maybe there *is* a valid reason in some
 569      ;; circumstances? perhaps some deadlock issue when being driven
 570      ;; by another process or something...)
 571      (force-output *standard-output*))
 572    (let* ((form (funcall *repl-read-form-fun*
 573                          *standard-input*
 574                          *standard-output*))
 575           (results (multiple-value-list (interactive-eval form))))
 576      (unless noprint
 577        (dolist (result results)
 578          (fresh-line)
 579          (prin1 result))))))
 580
 581 ;;; suitable value for *DEBUGGER-HOOK* for a noninteractive Unix-y program
 582 (defun noprogrammer-debugger-hook-fun (condition old-debugger-hook)
 583   (declare (ignore old-debugger-hook))
 584   (flet ((failure-quit (&key recklessly-p)
 585            (/show0 "in FAILURE-QUIT (in --disable-debugger debugger hook)")
 586            (quit :unix-status 1 :recklessly-p recklessly-p)))
 587     ;; This HANDLER-CASE is here mostly to stop output immediately
 588     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 589     ;; when we're run under a shell script or something, we can die
 590     ;; cleanly when the script dies (and our pipes are cut), instead
 591     ;; of falling into ldb or something messy like that.
 592     (handler-case
 593         (progn
 594           (format *error-output*
 595                   "~&~@<unhandled condition (of type ~S): ~2I~_~A~:>~2%"
 596                   (type-of condition)
 597                   condition)
 598           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 599           ;; even if we hit an error within BACKTRACE (e.g. a bug in
 600           ;; the debugger's own frame-walking code, or a bug in a user
 601           ;; PRINT-OBJECT method) we'll at least have the CONDITION
 602           ;; printed out before we die.
 603           (finish-output *error-output*)
 604           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 605           ;; it seems as though we should at least truncate it somewhere.)
 606           (sb!debug:backtrace 128 *error-output*)
 607           (format
 608            *error-output*
 609            "~%unhandled condition in --disable-debugger mode, quitting~%")
 610           (finish-output *error-output*)
 611           (failure-quit))
 612       (condition ()
 613         ;; We IGNORE-ERRORS here because even %PRIMITIVE PRINT can
 614         ;; fail when our output streams are blown away, as e.g. when
 615         ;; we're running under a Unix shell script and it dies somehow
 616         ;; (e.g. because of a SIGINT). In that case, we might as well
 617         ;; just give it up for a bad job, and stop trying to notify
 618         ;; the user of anything.
 619         ;;
 620         ;; Actually, the only way I've run across to exercise the
 621         ;; problem is to have more than one layer of shell script.
 622         ;; I have a shell script which does
 623         ;;   time nice -10 sh make.sh "$1" 2>&1 | tee make.tmp
 624         ;; and the problem occurs when I interrupt this with Ctrl-C
 625         ;; under Linux 2.2.14-5.0 and GNU bash, version 1.14.7(1).
 626         ;; I haven't figured out whether it's bash, time, tee, Linux, or
 627         ;; what that is responsible, but that it's possible at all
 628         ;; means that we should IGNORE-ERRORS here. -- WHN 2001-04-24
 629         (ignore-errors
 630          (%primitive print
 631                      "Argh! error within --disable-debugger error handling"))
 632         (failure-quit :recklessly-p t)))))
 633 \f
 634 ;;; a convenient way to get into the assembly-level debugger
 635 (defun %halt ()
 636   (%primitive sb!c:halt))