src/code/typedefs.lisp

   1 ;;;; This file contains the definition of the CTYPE (Compiler TYPE)
   2 ;;;; structure and related macros used for manipulating it. This is
   3 ;;;; sort of a mini object system with rather odd dispatching rules.
   4 ;;;; Other compile-time definitions needed by multiple files are also
   5 ;;;; here.
   6 ;;;;
   7 ;;;; FIXME: The comment above about what's in this file is no longer so
   8 ;;;; true now that I've split off type-class.lisp. Perhaps we should
   9 ;;;; split off CTYPE into the same file as type-class.lisp, rename that
  10 ;;;; file to ctype.lisp, move the current comment to the head of that file,
  11 ;;;; and write a new comment for this file saying how this file holds
  12 ;;;; concrete types.
  13
  14 ;;;; This software is part of the SBCL system. See the README file for
  15 ;;;; more information.
  16 ;;;;
  17 ;;;; This software is derived from the CMU CL system, which was
  18 ;;;; written at Carnegie Mellon University and released into the
  19 ;;;; public domain. The software is in the public domain and is
  20 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  21 ;;;; files for more information.
  22
  23 (in-package "SB!KERNEL")
  24
  25 (!begin-collecting-cold-init-forms)
  26
  27 ;;; Define the translation from a type-specifier to a type structure for
  28 ;;; some particular type. Syntax is identical to DEFTYPE.
  29 (defmacro !def-type-translator (name arglist &body body)
  30   (declare (type symbol name))
  31   ;; FIXME: Now that the T%CL hack is ancient history and we just use CL
  32   ;; instead, we can probably return to using PARSE-DEFMACRO here.
  33   ;;
  34   ;; was:
  35   ;;   This song and dance more or less emulates PARSE-DEFMACRO. The reason for
  36   ;;   doing this emulation instead of just calling PARSE-DEFMACRO is just that
  37   ;;   at cross-compile time PARSE-DEFMACRO expects lambda-list keywords in the
  38   ;;   T%CL package, which is not what we have here. Maybe there's a tidier
  39   ;;   solution.. (Other than wishing that ANSI had used symbols in the KEYWORD
  40   ;;   package as lambda list keywords, rather than using symbols in the LISP
  41   ;;   package!)
  42   (multiple-value-bind (whole wholeless-arglist)
  43       (if (eq '&whole (car arglist))
  44           (values (cadr arglist) (cddr arglist))
  45           (values (gensym) arglist))
  46     (multiple-value-bind (forms decls) (parse-body body nil)
  47       `(progn
  48          (!cold-init-forms
  49           (setf (info :type :translator ',name)
  50                 (lambda (,whole)
  51                   (block ,name
  52                     (destructuring-bind ,wholeless-arglist
  53                         (rest ,whole) ; discarding NAME
  54                       ,@decls
  55                       ,@forms)))))
  56          ',name))))
  57
  58 ;;; DEFVARs for these come later, after we have enough stuff defined.
  59 (declaim (special *wild-type* *universal-type* *empty-type*))
  60 \f
  61 ;;; the base class for the internal representation of types
  62 (def!struct (ctype (:conc-name type-)
  63                    (:constructor nil)
  64                    (:make-load-form-fun make-type-load-form)
  65                    #-sb-xc-host (:pure t))
  66   ;; the class of this type
  67   ;;
  68   ;; FIXME: It's unnecessarily confusing to have a structure accessor
  69   ;; named TYPE-CLASS-INFO which is an accessor for the CTYPE structure
  70   ;; even though the TYPE-CLASS structure also exists in the system.
  71   ;; Rename this slot: TYPE-CLASS or ASSOCIATED-TYPE-CLASS or something.
  72   (class-info (required-argument) :type type-class)
  73   ;; True if this type has a fixed number of members, and as such
  74   ;; could possibly be completely specified in a MEMBER type. This is
  75   ;; used by the MEMBER type methods.
  76   (enumerable nil :read-only t)
  77   ;; an arbitrary hash code used in EQ-style hashing of identity
  78   ;; (since EQ hashing can't be done portably)
  79   (hash-value (random (1+ most-positive-fixnum))
  80               :type (and fixnum unsigned-byte)
  81               :read-only t))
  82 (def!method print-object ((ctype ctype) stream)
  83   (print-unreadable-object (ctype stream :type t)
  84     (prin1 (type-specifier ctype) stream)))
  85
  86 ;;; Just dump it as a specifier. (We'll convert it back upon loading.)
  87 (defun make-type-load-form (type)
  88   (declare (type ctype type))
  89   `(specifier-type ',(type-specifier type)))
  90 \f
  91 ;;;; miscellany
  92
  93 ;;; Look for nice relationships for types that have nice relationships
  94 ;;; only when one is a hierarchical subtype of the other.
  95 (defun hierarchical-intersection2 (type1 type2)
  96   (multiple-value-bind (subtypep1 win1) (csubtypep type1 type2)
  97     (multiple-value-bind (subtypep2 win2) (csubtypep type2 type1)
  98       (cond (subtypep1 type1)
  99             (subtypep2 type2)
 100             ((and win1 win2) *empty-type*)
 101             (t nil)))))
 102 (defun hierarchical-union2 (type1 type2)
 103   (cond ((csubtypep type1 type2) type2)
 104         ((csubtypep type2 type1) type1)
 105         (t nil)))
 106
 107 ;;; Hash two things (types) down to 8 bits. In CMU CL this was an EQ
 108 ;;; hash, but since it now needs to run in vanilla ANSI Common Lisp at
 109 ;;; cross-compile time, it's now based on the CTYPE-HASH-VALUE field
 110 ;;; instead.
 111 ;;;
 112 ;;; FIXME: This was a macro in CMU CL, and is now an INLINE function. Is
 113 ;;; it important for it to be INLINE, or could be become an ordinary
 114 ;;; function without significant loss? -- WHN 19990413
 115 #!-sb-fluid (declaim (inline type-cache-hash))
 116 (declaim (ftype (function (ctype ctype) (unsigned-byte 8)) type-cache-hash))
 117 (defun type-cache-hash (type1 type2)
 118   (logand (logxor (ash (type-hash-value type1) -3)
 119                   (type-hash-value type2))
 120           #xFF))
 121 \f
 122 ;;;; cold loading initializations
 123
 124 (!defun-from-collected-cold-init-forms !typedefs-cold-init)