src/code/typep.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!KERNEL")
  11
  12 ;;; The actual TYPEP engine. The compiler only generates calls to this
  13 ;;; function when it can't figure out anything more intelligent to do.
  14 (defun %typep (object specifier)
  15   (%%typep object
  16            (if (ctype-p specifier)
  17                specifier
  18                (specifier-type specifier))))
  19 (defun %%typep (object type)
  20   (declare (type ctype type))
  21   (etypecase type
  22     (named-type
  23      (ecase (named-type-name type)
  24        ((* t) t)
  25        ((nil) nil)))
  26     (numeric-type
  27      (and (numberp object)
  28           (let ((num (if (complexp object) (realpart object) object)))
  29             (ecase (numeric-type-class type)
  30               (integer (integerp num))
  31               (rational (rationalp num))
  32               (float
  33                (ecase (numeric-type-format type)
  34                  (short-float (typep num 'short-float))
  35                  (single-float (typep num 'single-float))
  36                  (double-float (typep num 'double-float))
  37                  (long-float (typep num 'long-float))
  38                  ((nil) (floatp num))))
  39               ((nil) t)))
  40           #!-negative-zero-is-not-zero
  41           (flet ((bound-test (val)
  42                    (let ((low (numeric-type-low type))
  43                          (high (numeric-type-high type)))
  44                      (and (cond ((null low) t)
  45                                 ((listp low) (> val (car low)))
  46                                 (t (>= val low)))
  47                           (cond ((null high) t)
  48                                 ((listp high) (< val (car high)))
  49                                 (t (<= val high)))))))
  50             (ecase (numeric-type-complexp type)
  51               ((nil) t)
  52               (:complex
  53                (and (complexp object)
  54                     (bound-test (realpart object))
  55                     (bound-test (imagpart object))))
  56               (:real
  57                (and (not (complexp object))
  58                     (bound-test object)))))
  59           #!+negative-zero-is-not-zero
  60           (labels ((signed-> (x y)
  61                      (if (and (zerop x) (zerop y) (floatp x) (floatp y))
  62                          (> (float-sign x) (float-sign y))
  63                          (> x y)))
  64                    (signed->= (x y)
  65                      (if (and (zerop x) (zerop y) (floatp x) (floatp y))
  66                          (>= (float-sign x) (float-sign y))
  67                          (>= x y)))
  68                    (bound-test (val)
  69                      (let ((low (numeric-type-low type))
  70                            (high (numeric-type-high type)))
  71                        (and (cond ((null low) t)
  72                                   ((listp low)
  73                                    (signed-> val (car low)))
  74                                   (t
  75                                    (signed->= val low)))
  76                             (cond ((null high) t)
  77                                   ((listp high)
  78                                    (signed-> (car high) val))
  79                                   (t
  80                                    (signed->= high val)))))))
  81             (ecase (numeric-type-complexp type)
  82               ((nil) t)
  83               (:complex
  84                (and (complexp object)
  85                     (bound-test (realpart object))
  86                     (bound-test (imagpart object))))
  87               (:real
  88                (and (not (complexp object))
  89                     (bound-test object)))))))
  90     (array-type
  91      (and (arrayp object)
  92           (ecase (array-type-complexp type)
  93             ((t) (not (typep object 'simple-array)))
  94             ((nil) (typep object 'simple-array))
  95             ((:maybe) t))
  96           (or (eq (array-type-dimensions type) '*)
  97               (do ((want (array-type-dimensions type) (cdr want))
  98                    (got (array-dimensions object) (cdr got)))
  99                   ((and (null want) (null got)) t)
 100                 (unless (and want got
 101                              (or (eq (car want) '*)
 102                                  (= (car want) (car got))))
 103                   (return nil))))
 104           (or (eq (array-type-element-type type) *wild-type*)
 105               (values (type= (array-type-specialized-element-type type)
 106                              (specifier-type (array-element-type
 107                                               object)))))))
 108     (member-type
 109      (if (member object (member-type-members type)) t))
 110     (sb!xc:class
 111      #+sb-xc-host (ctypep object type)
 112      #-sb-xc-host (class-typep (layout-of object) type object))
 113     (union-type
 114      (dolist (type (union-type-types type))
 115        (when (%%typep object type)
 116          (return t))))
 117     ;; MNA: cons compound-type patch
 118     ;; FIXIT: all commented out
 119 ;     (cons-type
 120 ;      (and (consp object)
 121 ;         (%%typep (car object) (cons-type-car-type type))
 122 ;         (%%typep (cdr object) (cons-type-cdr-type type))))
 123     (unknown-type
 124      ;; dunno how to do this ANSIly -- WHN 19990413
 125      #+sb-xc-host (error "stub: %%TYPEP UNKNOWN-TYPE in xcompilation host")
 126      ;; Parse it again to make sure it's really undefined.
 127      (let ((reparse (specifier-type (unknown-type-specifier type))))
 128        (if (typep reparse 'unknown-type)
 129            (error "unknown type specifier: ~S"
 130                   (unknown-type-specifier reparse))
 131            (%%typep object reparse))))
 132     (hairy-type
 133      ;; Now the tricky stuff.
 134      (let* ((hairy-spec (hairy-type-specifier type))
 135             (symbol (if (consp hairy-spec) (car hairy-spec) hairy-spec)))
 136        (ecase symbol
 137          (and
 138           (or (atom hairy-spec)
 139               (dolist (spec (cdr hairy-spec) t)
 140                 (unless (%%typep object (specifier-type spec))
 141                   (return nil)))))
 142          (not
 143           (unless (proper-list-of-length-p hairy-spec 2)
 144             (error "invalid type specifier: ~S" hairy-spec))
 145           (not (%%typep object (specifier-type (cadr hairy-spec)))))
 146          (satisfies
 147           (unless (proper-list-of-length-p hairy-spec 2)
 148             (error "invalid type specifier: ~S" hairy-spec))
 149           (let ((fn (cadr hairy-spec)))
 150             (if (funcall (typecase fn
 151                            (function fn)
 152                            (symbol (symbol-function fn))
 153                            (t
 154                             (coerce fn 'function)))
 155                          object)
 156                 t
 157                 nil))))))
 158     (alien-type-type
 159      (sb!alien-internals:alien-typep object (alien-type-type-alien-type type)))
 160     (function-type
 161      (error "Function types are not a legal argument to TYPEP:~%  ~S"
 162             (type-specifier type)))))
 163
 164 ;;; Do type test from a class cell, allowing forward reference and
 165 ;;; redefinition.
 166 (defun class-cell-typep (obj-layout cell object)
 167   (let ((class (class-cell-class cell)))
 168     (unless class
 169       (error "The class ~S has not yet been defined." (class-cell-name cell)))
 170     (class-typep obj-layout class object)))
 171
 172 ;;; Test whether Obj-Layout is from an instance of Class.
 173 (defun class-typep (obj-layout class object)
 174   (declare (optimize speed))
 175   (when (layout-invalid obj-layout)
 176     (if (and (typep (sb!xc:class-of object) 'sb!xc:standard-class) object)
 177         (setq obj-layout (pcl-check-wrapper-validity-hook object))
 178         (error "TYPEP was called on an obsolete object (was class ~S)."
 179                (class-proper-name (layout-class obj-layout)))))
 180   (let ((layout (class-layout class))
 181         (obj-inherits (layout-inherits obj-layout)))
 182     (when (layout-invalid layout)
 183       (error "The class ~S is currently invalid." class))
 184     (or (eq obj-layout layout)
 185         (dotimes (i (length obj-inherits) nil)
 186           (when (eq (svref obj-inherits i) layout)
 187             (return t))))))
 188
 189 ;;; to be redefined as PCL::CHECK-WRAPPER-VALIDITY when PCL is loaded
 190 ;;;
 191 ;;; FIXME: should probably be renamed SB!PCL:CHECK-WRAPPER-VALIDITY
 192 (defun pcl-check-wrapper-validity-hook (object)
 193   object)