src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69      (if (minusp result)
  70          (values nil (get-errno))
  71          ,success-form)))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  78                                 ,@args)))
  79      (if (minusp result)
  80          (error "Syscall ~A failed: ~A" ,name (strerror))
  81          ,success-form)))
  82
  83 (/show0 "unix.lisp 109")
  84
  85 (defmacro void-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  87
  88 (defmacro int-syscall ((name &rest arg-types) &rest args)
  89   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  90 \f
  91 ;;;; hacking the Unix environment
  92
  93 (define-alien-routine ("getenv" posix-getenv) c-string
  94   "Return the \"value\" part of the environment string \"name=value\" which
  95    corresponds to NAME, or NIL if there is none."
  96   (name c-string))
  97 \f
  98 ;;; from stdio.h
  99
 100 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 101 ;;; error code is returned if an error occurs.
 102 (defun unix-rename (name1 name2)
 103   (declare (type unix-pathname name1 name2))
 104   (void-syscall ("rename" c-string c-string) name1 name2))
 105 \f
 106 ;;; from sys/types.h and gnu/types.h
 107
 108 (/show0 "unix.lisp 220")
 109
 110 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 111 ;;; like this unless we have extreme provocation. Reading directories
 112 ;;; is not extreme enough, since it doesn't need to be blindingly
 113 ;;; fast: we can just implement those functions in C as a wrapper
 114 ;;; layer.
 115 (define-alien-type fd-mask unsigned-long)
 116
 117 (eval-when (:compile-toplevel :load-toplevel :execute)
 118   (defconstant fd-setsize 1024))
 119
 120 (define-alien-type nil
 121   (struct fd-set
 122           (fds-bits (array fd-mask #.(/ fd-setsize 32)))))
 123
 124 (/show0 "unix.lisp 304")
 125 \f
 126 \f
 127 ;;;; fcntl.h
 128 ;;;;
 129 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 130
 131 ;;; Open the file whose pathname is specified by PATH for reading
 132 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 133 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 134 ;;;
 135 ;;; If the O_CREAT flag is specified, then the file is created with a
 136 ;;; permission of argument MODE if the file doesn't exist. An integer
 137 ;;; file descriptor is returned by UNIX-OPEN.
 138 (defun unix-open (path flags mode)
 139   (declare (type unix-pathname path)
 140            (type fixnum flags)
 141            (type unix-file-mode mode))
 142   (int-syscall ("open" c-string int int) path flags mode))
 143
 144 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 145 ;;; associated with it.
 146 (/show0 "unix.lisp 391")
 147 (defun unix-close (fd)
 148   (declare (type unix-fd fd))
 149   (void-syscall ("close" int) fd))
 150 \f
 151 ;;;; timebits.h
 152
 153 ;; A time value that is accurate to the nearest
 154 ;; microsecond but also has a range of years.
 155 (define-alien-type nil
 156   (struct timeval
 157           (tv-sec time-t)               ; seconds
 158           (tv-usec time-t)))            ; and microseconds
 159 \f
 160 ;;;; resourcebits.h
 161
 162 (defconstant rusage_self 0) ; the calling process
 163 (defconstant rusage_children -1) ; terminated child processes
 164 (defconstant rusage_both -2)
 165
 166 (define-alien-type nil
 167   (struct rusage
 168     (ru-utime (struct timeval))     ; user time used
 169     (ru-stime (struct timeval))     ; system time used.
 170     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 171     (ru-ixrss long)                 ; integral shared memory size
 172     (ru-idrss long)                 ; integral unshared data size
 173     (ru-isrss long)                 ; integral unshared stack size
 174     (ru-minflt long)                ; page reclaims
 175     (ru-majflt long)                ; page faults
 176     (ru-nswap long)                 ; swaps
 177     (ru-inblock long)               ; block input operations
 178     (ru-oublock long)               ; block output operations
 179     (ru-msgsnd long)                ; messages sent
 180     (ru-msgrcv long)                ; messages received
 181     (ru-nsignals long)              ; signals received
 182     (ru-nvcsw long)                 ; voluntary context switches
 183     (ru-nivcsw long)))              ; involuntary context switches
 184 \f
 185 ;;;; unistd.h
 186
 187 ;;; Given a file path (a string) and one of four constant modes,
 188 ;;; return T if the file is accessible with that mode and NIL if not.
 189 ;;; When NIL, also return an errno value with NIL which tells why the
 190 ;;; file was not accessible.
 191 ;;;
 192 ;;; The access modes are:
 193 ;;;   r_ok     Read permission.
 194 ;;;   w_ok     Write permission.
 195 ;;;   x_ok     Execute permission.
 196 ;;;   f_ok     Presence of file.
 197 (defun unix-access (path mode)
 198   (declare (type unix-pathname path)
 199            (type (mod 8) mode))
 200   (void-syscall ("access" c-string int) path mode))
 201
 202 ;;; values for the second argument to UNIX-LSEEK
 203 (defconstant l_set 0) ; to set the file pointer
 204 (defconstant l_incr 1) ; to increment the file pointer
 205 (defconstant l_xtnd 2) ; to extend the file size
 206
 207 ;;; Accept a file descriptor and move the file pointer ahead
 208 ;;; a certain offset for that file. WHENCE can be any of the following:
 209 ;;;  L_SET     Set the file pointer.
 210 ;;;  L_INCR    Increment the file pointer.
 211 ;;;  L_XTND    Extend the file size.
 212 (defun unix-lseek (fd offset whence)
 213   (declare (type unix-fd fd)
 214            (type (unsigned-byte 32) offset)
 215            (type (integer 0 2) whence))
 216   #!-(and x86 bsd)
 217   (int-syscall ("lseek" int off-t int) fd offset whence)
 218   ;; Need a 64-bit return value type for this. TBD. For now,
 219   ;; don't use this with any 2G+ partitions.
 220   #!+(and x86 bsd)
 221   (int-syscall ("lseek" int unsigned-long unsigned-long int)
 222                fd offset 0 whence))
 223
 224 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 225 ;;; It attempts to read len bytes from the device associated with fd
 226 ;;; and store them into the buffer. It returns the actual number of
 227 ;;; bytes read.
 228 (defun unix-read (fd buf len)
 229   (declare (type unix-fd fd)
 230            (type (unsigned-byte 32) len))
 231
 232   (int-syscall ("read" int (* char) int) fd buf len))
 233
 234 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 235 ;;; length to write. It attempts to write len bytes to the device
 236 ;;; associated with fd from the the buffer starting at offset. It returns
 237 ;;; the actual number of bytes written.
 238 (defun unix-write (fd buf offset len)
 239   (declare (type unix-fd fd)
 240            (type (unsigned-byte 32) offset len))
 241   (int-syscall ("write" int (* char) int)
 242                fd
 243                (with-alien ((ptr (* char) (etypecase buf
 244                                             ((simple-array * (*))
 245                                              (vector-sap buf))
 246                                             (system-area-pointer
 247                                              buf))))
 248                  (addr (deref ptr offset)))
 249                len))
 250
 251 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 252 ;;; output pipe. Return two values: if no error occurred the first
 253 ;;; value is the pipe to be read from and the second is can be written
 254 ;;; to. If an error occurred the first value is NIL and the second the
 255 ;;; unix error code.
 256 (defun unix-pipe ()
 257   (with-alien ((fds (array int 2)))
 258     (syscall ("pipe" (* int))
 259              (values (deref fds 0) (deref fds 1))
 260              (cast fds (* int)))))
 261
 262 (defun unix-mkdir (name mode)
 263   (declare (type unix-pathname name)
 264            (type unix-file-mode mode))
 265   (void-syscall ("mkdir" c-string int) name mode))
 266
 267 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 268 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 269 (defun newcharstar-string (newcharstar)
 270   (declare (type (alien (* char)) newcharstar))
 271   (if (null-alien newcharstar)
 272       nil
 273       (prog1
 274           (cast newcharstar c-string)
 275         (free-alien newcharstar))))
 276
 277 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 278 ;;; style returned by getcwd() (no trailing slash character).
 279 (defun posix-getcwd ()
 280   ;; This implementation relies on a BSD/Linux extension to getcwd()
 281   ;; behavior, automatically allocating memory when a null buffer
 282   ;; pointer is used. On a system which doesn't support that
 283   ;; extension, it'll have to be rewritten somehow.
 284   ;;
 285   ;; SunOS provides almost as useful an extension: if given a null
 286   ;; buffer pointer, it will automatically allocate size space. The
 287   ;; KLUDGE in this solution arises because we have just read off
 288   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 289   ;; a constant. Going the grovel_headers route doesn't seem to be
 290   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 291   ;; unistd.h.
 292   #!-(or linux openbsd freebsd sunos) (,stub,)
 293   #!+(or linux openbsd freebsd sunos)
 294   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 295                                                        (function (* char)
 296                                                                  (* char)
 297                                                                  size-t))
 298                                          nil
 299                                          #!+(or linux openbsd freebsd) 0
 300                                          #!+sunos 1025))
 301       (simple-perror "getcwd")))
 302
 303 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 304 ;;; by a slash character.
 305 (defun posix-getcwd/ ()
 306   (concatenate 'string (posix-getcwd) "/"))
 307
 308 ;;; Convert at the UNIX level from a possibly relative filename to
 309 ;;; an absolute filename.
 310 ;;;
 311 ;;; FIXME: Do we still need this even as we switch to
 312 ;;; *DEFAULT-PATHNAME-DEFAULTS*? I think maybe we do, since it seems
 313 ;;; to be valid for the user to set *DEFAULT-PATHNAME-DEFAULTS* to
 314 ;;; have a NIL directory component, and then this'd be the only way to
 315 ;;; interpret a relative directory specification. But I don't find the
 316 ;;; ANSI pathname documentation to be a model of clarity. Maybe
 317 ;;; someone who understands it better can take a look at this.. -- WHN
 318 (defun unix-maybe-prepend-current-directory (name)
 319   (declare (simple-string name))
 320   (if (and (> (length name) 0) (char= (schar name 0) #\/))
 321       name
 322       (concatenate 'simple-string (posix-getcwd/) name)))
 323
 324 ;;; Duplicate an existing file descriptor (given as the argument) and
 325 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 326 ;;; number are returned.
 327 (defun unix-dup (fd)
 328   (declare (type unix-fd fd))
 329   (int-syscall ("dup" int) fd))
 330
 331 ;;; Terminate the current process with an optional error code. If
 332 ;;; successful, the call doesn't return. If unsuccessful, the call
 333 ;;; returns NIL and an error number.
 334 (defun unix-exit (&optional (code 0))
 335   (declare (type (signed-byte 32) code))
 336   (void-syscall ("exit" int) code))
 337
 338 ;;; Return the process id of the current process.
 339 (define-alien-routine ("getpid" unix-getpid) int)
 340
 341 ;;; Return the real user id associated with the current process.
 342 (define-alien-routine ("getuid" unix-getuid) int)
 343
 344 ;;; Translate a user id into a login name.
 345 (defun uid-username (uid)
 346   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 347                                                        (function (* char) int))
 348                                          uid))
 349       (error "found no match for Unix uid=~S" uid)))
 350
 351 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 352 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 353 ;;; failure.
 354 (defun unix-readlink (path)
 355   (declare (type unix-pathname path))
 356   (with-alien ((ptr (* char)
 357                     (alien-funcall (extern-alien
 358                                     "wrapped_readlink"
 359                                     (function (* char) c-string))
 360                                    path)))
 361     (if (null-alien ptr)
 362         (values nil (get-errno))
 363         (multiple-value-prog1
 364             (values (with-alien ((c-string c-string ptr)) c-string)
 365                     nil)
 366           (free-alien ptr)))))
 367
 368 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 369 ;;; name and the file if this is the last link.
 370 (defun unix-unlink (name)
 371   (declare (type unix-pathname name))
 372   (void-syscall ("unlink" c-string) name))
 373
 374 ;;; Return the name of the host machine as a string.
 375 (defun unix-gethostname ()
 376   (with-alien ((buf (array char 256)))
 377     (syscall ("gethostname" (* char) int)
 378              (cast buf c-string)
 379              (cast buf (* char)) 256)))
 380
 381 ;;; Write the core image of the file described by FD to disk.
 382 (defun unix-fsync (fd)
 383   (declare (type unix-fd fd))
 384   (void-syscall ("fsync" int) fd))
 385 \f
 386 ;;;; sys/ioctl.h
 387
 388 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 389 ;;; descriptors. See the UNIX Programmer's Manual for more
 390 ;;; information.
 391 (defun unix-ioctl (fd cmd arg)
 392   (declare (type unix-fd fd)
 393            (type (unsigned-byte 32) cmd))
 394   (void-syscall ("ioctl" int unsigned-int (* char)) fd cmd arg))
 395 \f
 396 ;;;; sys/resource.h
 397
 398 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 399 ;;;
 400 ;;; This is like getrusage(2), except it returns only the system and
 401 ;;; user time, and returns the seconds and microseconds as separate
 402 ;;; values.
 403 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 404 (defun unix-fast-getrusage (who)
 405   (declare (values (member t)
 406                    (unsigned-byte 31) (integer 0 1000000)
 407                    (unsigned-byte 31) (integer 0 1000000)))
 408   (with-alien ((usage (struct rusage)))
 409     (syscall* ("getrusage" int (* (struct rusage)))
 410               (values t
 411                       (slot (slot usage 'ru-utime) 'tv-sec)
 412                       (slot (slot usage 'ru-utime) 'tv-usec)
 413                       (slot (slot usage 'ru-stime) 'tv-sec)
 414                       (slot (slot usage 'ru-stime) 'tv-usec))
 415               who (addr usage))))
 416
 417 ;;; Return information about the resource usage of the process
 418 ;;; specified by WHO. WHO can be either the current process
 419 ;;; (rusage_self) or all of the terminated child processes
 420 ;;; (rusage_children). NIL and an error number is returned if the call
 421 ;;; fails.
 422 (defun unix-getrusage (who)
 423   (with-alien ((usage (struct rusage)))
 424     (syscall ("getrusage" int (* (struct rusage)))
 425               (values t
 426                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 427                          (slot (slot usage 'ru-utime) 'tv-usec))
 428                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 429                          (slot (slot usage 'ru-stime) 'tv-usec))
 430                       (slot usage 'ru-maxrss)
 431                       (slot usage 'ru-ixrss)
 432                       (slot usage 'ru-idrss)
 433                       (slot usage 'ru-isrss)
 434                       (slot usage 'ru-minflt)
 435                       (slot usage 'ru-majflt)
 436                       (slot usage 'ru-nswap)
 437                       (slot usage 'ru-inblock)
 438                       (slot usage 'ru-oublock)
 439                       (slot usage 'ru-msgsnd)
 440                       (slot usage 'ru-msgrcv)
 441                       (slot usage 'ru-nsignals)
 442                       (slot usage 'ru-nvcsw)
 443                       (slot usage 'ru-nivcsw))
 444               who (addr usage))))
 445 \f
 446 ;;;; sys/select.h
 447
 448 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 449
 450 ;;; Perform the UNIX select(2) system call.
 451 (declaim (inline unix-fast-select)) ; (used to be a macro in CMU CL)
 452 (defun unix-fast-select (num-descriptors
 453                          read-fds write-fds exception-fds
 454                          timeout-secs &optional (timeout-usecs 0))
 455   (declare (type (integer 0 #.fd-setsize) num-descriptors)
 456            (type (or (alien (* (struct fd-set))) null)
 457                  read-fds write-fds exception-fds)
 458            (type (or null (unsigned-byte 31)) timeout-secs)
 459            (type (unsigned-byte 31) timeout-usecs))
 460   ;; FIXME: CMU CL had
 461   ;;   (declare (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 462   ;; here. Is that important for SBCL? If so, why? Profiling might tell us..
 463   (with-alien ((tv (struct timeval)))
 464     (when timeout-secs
 465       (setf (slot tv 'tv-sec) timeout-secs)
 466       (setf (slot tv 'tv-usec) timeout-usecs))
 467     (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 468                   (* (struct fd-set)) (* (struct timeval)))
 469                  num-descriptors read-fds write-fds exception-fds
 470                  (if timeout-secs (alien-sap (addr tv)) (int-sap 0)))))
 471
 472 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 473 ;;; to happen on one of them or to time out.
 474 (defmacro num-to-fd-set (fdset num)
 475   `(if (fixnump ,num)
 476        (progn
 477          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 478          ,@(loop for index upfrom 1 below (/ fd-setsize 32)
 479              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 480        (progn
 481          ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 482              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 483                             (ldb (byte 32 ,(* index 32)) ,num))))))
 484
 485 (defmacro fd-set-to-num (nfds fdset)
 486   `(if (<= ,nfds 32)
 487        (deref (slot ,fdset 'fds-bits) 0)
 488        (+ ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 489               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 490                             ,(* index 32))))))
 491
 492 ;;; Examine the sets of descriptors passed as arguments to see whether
 493 ;;; they are ready for reading and writing. See the UNIX Programmer's
 494 ;;; Manual for more information.
 495 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 496   (declare (type (integer 0 #.FD-SETSIZE) nfds)
 497            (type unsigned-byte rdfds wrfds xpfds)
 498            (type (or (unsigned-byte 31) null) to-secs)
 499            (type (unsigned-byte 31) to-usecs)
 500            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 501   (with-alien ((tv (struct timeval))
 502                (rdf (struct fd-set))
 503                (wrf (struct fd-set))
 504                (xpf (struct fd-set)))
 505     (when to-secs
 506       (setf (slot tv 'tv-sec) to-secs)
 507      (setf (slot tv 'tv-usec) to-usecs))
 508     (num-to-fd-set rdf rdfds)
 509     (num-to-fd-set wrf wrfds)
 510     (num-to-fd-set xpf xpfds)
 511     (macrolet ((frob (lispvar alienvar)
 512                  `(if (zerop ,lispvar)
 513                       (int-sap 0)
 514                       (alien-sap (addr ,alienvar)))))
 515       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 516                 (* (struct fd-set)) (* (struct timeval)))
 517                (values result
 518                        (fd-set-to-num nfds rdf)
 519                        (fd-set-to-num nfds wrf)
 520                        (fd-set-to-num nfds xpf))
 521                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 522                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 523 \f
 524 ;;;; sys/stat.h
 525
 526 ;;; This is a structure defined in src/runtime/wrap.c, to look
 527 ;;; basically like "struct stat" according to stat(2). It may not
 528 ;;; actually correspond to the real in-memory stat structure that the
 529 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 530 ;;; stat macros, and trying to keep Lisp code in correspondence with
 531 ;;; it is more pain than it's worth, so we just let our C runtime
 532 ;;; synthesize a nice consistent structure for us.
 533 ;;;
 534 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 535 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn's support
 536 ;;; those. We don't actually access that field anywhere, though, so
 537 ;;; until we can get 64 bit alien support it'll do. Also note that
 538 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 539 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 540 ;;; longer than 32 bits anyway, right?":-|
 541 (define-alien-type nil
 542   (struct wrapped_stat
 543     (st-dev unsigned-long)              ; would be dev-t in a real stat
 544     (st-ino ino-t)
 545     (st-mode mode-t)
 546     (st-nlink  nlink-t)
 547     (st-uid  uid-t)
 548     (st-gid  gid-t)
 549     (st-rdev unsigned-long)             ; would be dev-t in a real stat
 550     (st-size unsigned-long)             ; would be off-t in a real stat
 551     (st-blksize unsigned-long)
 552     (st-blocks unsigned-long)
 553     (st-atime time-t)
 554     (st-mtime time-t)
 555     (st-ctime time-t)))
 556
 557 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 558 ;;; family of Unix system calls
 559 ;;;
 560 ;;; FIXME: I think this should probably not be INLINE. However, when
 561 ;;; this was not inline, it seemed to cause memory corruption
 562 ;;; problems. My first guess is that it's a bug in the FFI code, where
 563 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 564 ;;; around a call to a function returning >10 values. But I didn't try
 565 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 566 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 567 ;;; output in the not-inlined case and see whether there's a problem,
 568 ;;; and maybe even find a fix..
 569 (declaim (inline %extract-stat-results))
 570 (defun %extract-stat-results (wrapped-stat)
 571   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 572   (values t
 573           (slot wrapped-stat 'st-dev)
 574           (slot wrapped-stat 'st-ino)
 575           (slot wrapped-stat 'st-mode)
 576           (slot wrapped-stat 'st-nlink)
 577           (slot wrapped-stat 'st-uid)
 578           (slot wrapped-stat 'st-gid)
 579           (slot wrapped-stat 'st-rdev)
 580           (slot wrapped-stat 'st-size)
 581           (slot wrapped-stat 'st-atime)
 582           (slot wrapped-stat 'st-mtime)
 583           (slot wrapped-stat 'st-ctime)
 584           (slot wrapped-stat 'st-blksize)
 585           (slot wrapped-stat 'st-blocks)))
 586
 587 ;;; Unix system calls in the stat(2) family are handled by calls to
 588 ;;; C-level wrapper functions which copy all the raw "struct stat"
 589 ;;; slots into the system-independent wrapped_stat format.
 590 ;;;    stat(2) <->  stat_wrapper()
 591 ;;;   fstat(2) <-> fstat_wrapper()
 592 ;;;   lstat(2) <-> lstat_wrapper()
 593 (defun unix-stat (name)
 594   (declare (type unix-pathname name))
 595   (with-alien ((buf (struct wrapped_stat)))
 596     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 597              (%extract-stat-results (addr buf))
 598              name (addr buf))))
 599 (defun unix-lstat (name)
 600   (declare (type unix-pathname name))
 601   (with-alien ((buf (struct wrapped_stat)))
 602     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 603              (%extract-stat-results (addr buf))
 604              name (addr buf))))
 605 (defun unix-fstat (fd)
 606   (declare (type unix-fd fd))
 607   (with-alien ((buf (struct wrapped_stat)))
 608     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 609              (%extract-stat-results (addr buf))
 610              fd (addr buf))))
 611 \f
 612 ;;;; time.h
 613
 614 ;; the POSIX.4 structure for a time value. This is like a "struct
 615 ;; timeval" but has nanoseconds instead of microseconds.
 616 (define-alien-type nil
 617     (struct timespec
 618             (tv-sec long)   ; seconds
 619             (tv-nsec long))) ; nanoseconds
 620
 621 ;; used by other time functions
 622 (define-alien-type nil
 623     (struct tm
 624             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 625             (tm-min int)   ; Minutes.   [0-59]
 626             (tm-hour int)  ; Hours.     [0-23]
 627             (tm-mday int)  ; Day.       [1-31]
 628             (tm-mon int)   ; Month.     [0-11]
 629             (tm-year int)  ; Year - 1900.
 630             (tm-wday int)  ; Day of week. [0-6]
 631             (tm-yday int)  ; Days in year. [0-365]
 632             (tm-isdst int) ; DST.       [-1/0/1]
 633             (tm-gmtoff long) ;  Seconds east of UTC.
 634             (tm-zone c-string))) ; Timezone abbreviation.
 635
 636 (define-alien-routine get-timezone sb!alien:void
 637   (when sb!alien:long :in)
 638   (minutes-west sb!alien:int :out)
 639   (daylight-savings-p sb!alien:boolean :out))
 640
 641 (defun unix-get-minutes-west (secs)
 642   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 643     (declare (ignore ignore) (ignore dst))
 644     (values minutes)))
 645
 646 (defun unix-get-timezone (secs)
 647   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 648     (declare (ignore ignore) (ignore minutes))
 649     (values (deref unix-tzname (if dst 1 0)))))
 650
 651 \f
 652 ;;;; sys/time.h
 653
 654 ;;; Structure crudely representing a timezone. KLUDGE: This is
 655 ;;; obsolete and should never be used.
 656 (define-alien-type nil
 657   (struct timezone
 658     (tz-minuteswest int)                ; minutes west of Greenwich
 659     (tz-dsttime int)))                  ; type of dst correction
 660
 661 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 662 ;;; and microseconds of the current time of day, the timezone (in
 663 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 664 ;;; doesn't work, it returns NIL and the errno.
 665 #!-sb-fluid (declaim (inline unix-gettimeofday))
 666 (defun unix-gettimeofday ()
 667   (with-alien ((tv (struct timeval))
 668                (tz (struct timezone)))
 669     (syscall* ("gettimeofday" (* (struct timeval))
 670                               (* (struct timezone)))
 671               (values T
 672                       (slot tv 'tv-sec)
 673                       (slot tv 'tv-usec)
 674                       (slot tz 'tz-minuteswest)
 675                       (slot tz 'tz-dsttime))
 676               (addr tv)
 677               (addr tz))))
 678 \f
 679
 680 (defconstant ENOENT 2) ; Unix error code, "No such file or directory"
 681 (defconstant EINTR 4) ; Unix error code, "Interrupted system call"
 682 (defconstant EIO 5) ; Unix error code, "I/O error"
 683 (defconstant EEXIST 17) ; Unix error code, "File exists"
 684 (defconstant ESPIPE 29) ; Unix error code, "Illegal seek"
 685 (defconstant EWOULDBLOCK 11) ; Unix error code, "Operation would block"
 686 ;;; FIXME: Many Unix error code definitions were deleted from the old
 687 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 688 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 689 ;;; unused symbols in package exports, but if I don't, there are
 690 ;;; enough of them all in one place here that they should probably be
 691 ;;; removed by hand.
 692 \f
 693 \f
 694 ;;;; support routines for dealing with Unix pathnames
 695
 696 (defun unix-file-kind (name &optional check-for-links)
 697   #!+sb-doc
 698   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 699   (declare (simple-string name))
 700   (multiple-value-bind (res dev ino mode)
 701       (if check-for-links (unix-lstat name) (unix-stat name))
 702     (declare (type (or fixnum null) mode)
 703              (ignore dev ino))
 704     (when res
 705       (let ((kind (logand mode s-ifmt)))
 706         (cond ((eql kind s-ifdir) :directory)
 707               ((eql kind s-ifreg) :file)
 708               ((eql kind s-iflnk) :link)
 709               (t :special))))))
 710
 711 ;;; Is the Unix pathname PATHNAME relative, instead of absolute? (E.g.
 712 ;;; "passwd" or "etc/passwd" instead of "/etc/passwd"?)
 713 (defun relative-unix-pathname? (pathname)
 714   (declare (type simple-string pathname))
 715   (or (zerop (length pathname))
 716       (char/= (schar pathname 0) #\/)))
 717
 718 ;;; Return PATHNAME with all symbolic links resolved. PATHNAME should
 719 ;;; already be a complete absolute Unix pathname, since at least in
 720 ;;; sbcl-0.6.12.36 we're called only from TRUENAME, and only after
 721 ;;; paths have been converted to absolute paths, so we don't need to
 722 ;;; try to handle any more generality than that.
 723 (defun unix-resolve-links (pathname)
 724   (declare (type simple-string pathname))
 725   (aver (not (relative-unix-pathname? pathname)))
 726   (/noshow "entering UNIX-RESOLVE-LINKS")
 727   (loop with previous-pathnames = nil do
 728         (/noshow pathname previous-pathnames)
 729         (let ((link (unix-readlink pathname)))
 730           (/noshow link)
 731           ;; Unlike the old CMU CL code, we handle a broken symlink by
 732           ;; returning the link itself. That way, CL:TRUENAME on a
 733           ;; broken link returns the link itself, so that CL:DIRECTORY
 734           ;; can return broken links, so that even without
 735           ;; Unix-specific extensions to do interesting things with
 736           ;; them, at least Lisp programs can see them and, if
 737           ;; necessary, delete them. (This is handy e.g. when your
 738           ;; managed-by-Lisp directories are visited by Emacs, which
 739           ;; creates broken links as notes to itself.)
 740           (if (null link)
 741               (return pathname)
 742               (let ((new-pathname
 743                      (unix-simplify-pathname
 744                       (if (relative-unix-pathname? link)
 745                           (let* ((dir-len (1+ (position #\/
 746                                                         pathname
 747                                                         :from-end t)))
 748                                  (dir (subseq pathname 0 dir-len)))
 749                             (/noshow dir)
 750                             (concatenate 'string dir link))
 751                           link))))
 752                 (if (unix-file-kind new-pathname)
 753                     (setf pathname new-pathname)
 754                     (return pathname)))))
 755         ;; To generalize the principle that even if portable Lisp code
 756         ;; can't do anything interesting with a broken symlink, at
 757         ;; least it should be able to see and delete it, when we
 758         ;; detect a cyclic link, we return the link itself. (So even
 759         ;; though portable Lisp code can't do anything interesting
 760         ;; with a cyclic link, at least it can see it and delete it.)
 761         (if (member pathname previous-pathnames :test #'string=)
 762             (return pathname)
 763             (push pathname previous-pathnames))))
 764
 765 (defun unix-simplify-pathname (src)
 766   (declare (type simple-string src))
 767   (let* ((src-len (length src))
 768          (dst (make-string src-len))
 769          (dst-len 0)
 770          (dots 0)
 771          (last-slash nil))
 772     (macrolet ((deposit (char)
 773                  `(progn
 774                     (setf (schar dst dst-len) ,char)
 775                     (incf dst-len))))
 776       (dotimes (src-index src-len)
 777         (let ((char (schar src src-index)))
 778           (cond ((char= char #\.)
 779                  (when dots
 780                    (incf dots))
 781                  (deposit char))
 782                 ((char= char #\/)
 783                  (case dots
 784                    (0
 785                     ;; either ``/...' or ``...//...'
 786                     (unless last-slash
 787                       (setf last-slash dst-len)
 788                       (deposit char)))
 789                    (1
 790                     ;; either ``./...'' or ``..././...''
 791                     (decf dst-len))
 792                    (2
 793                     ;; We've found ..
 794                     (cond
 795                      ((and last-slash (not (zerop last-slash)))
 796                       ;; There is something before this ..
 797                       (let ((prev-prev-slash
 798                              (position #\/ dst :end last-slash :from-end t)))
 799                         (cond ((and (= (+ (or prev-prev-slash 0) 2)
 800                                        last-slash)
 801                                     (char= (schar dst (- last-slash 2)) #\.)
 802                                     (char= (schar dst (1- last-slash)) #\.))
 803                                ;; The something before this .. is another ..
 804                                (deposit char)
 805                                (setf last-slash dst-len))
 806                               (t
 807                                ;; The something is some directory or other.
 808                                (setf dst-len
 809                                      (if prev-prev-slash
 810                                          (1+ prev-prev-slash)
 811                                          0))
 812                                (setf last-slash prev-prev-slash)))))
 813                      (t
 814                       ;; There is nothing before this .., so we need to keep it
 815                       (setf last-slash dst-len)
 816                       (deposit char))))
 817                    (t
 818                     ;; something other than a dot between slashes
 819                     (setf last-slash dst-len)
 820                     (deposit char)))
 821                  (setf dots 0))
 822                 (t
 823                  (setf dots nil)
 824                  (setf (schar dst dst-len) char)
 825                  (incf dst-len))))))
 826     (when (and last-slash (not (zerop last-slash)))
 827       (case dots
 828         (1
 829          ;; We've got  ``foobar/.''
 830          (decf dst-len))
 831         (2
 832          ;; We've got ``foobar/..''
 833          (unless (and (>= last-slash 2)
 834                       (char= (schar dst (1- last-slash)) #\.)
 835                       (char= (schar dst (- last-slash 2)) #\.)
 836                       (or (= last-slash 2)
 837                           (char= (schar dst (- last-slash 3)) #\/)))
 838            (let ((prev-prev-slash
 839                   (position #\/ dst :end last-slash :from-end t)))
 840              (if prev-prev-slash
 841                  (setf dst-len (1+ prev-prev-slash))
 842                  (return-from unix-simplify-pathname "./")))))))
 843     (cond ((zerop dst-len)
 844            "./")
 845           ((= dst-len src-len)
 846            dst)
 847           (t
 848            (subseq dst 0 dst-len)))))
 849 \f
 850 ;;;; A magic constant for wait3().
 851 ;;;;
 852 ;;;; FIXME: This used to be defined in run-program.lisp as
 853 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
 854 ;;;; According to some of the man pages, the #o177 is part of the API
 855 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
 856 ;;;; the headers that may or may not be the same thing. To be
 857 ;;;; investigated. -- CSR, 2002-03-25
 858 (defconstant wstopped #o177)
 859
 860 \f
 861 ;;;; stuff not yet found in the header files
 862 ;;;;
 863 ;;;; Abandon all hope who enters here...
 864
 865 ;;; not checked for linux...
 866 (defmacro fd-set (offset fd-set)
 867   (let ((word (gensym))
 868         (bit (gensym)))
 869     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 870        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 871              (logior (truly-the (unsigned-byte 32) (ash 1 ,bit))
 872                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 873
 874 ;;; not checked for linux...
 875 (defmacro fd-clr (offset fd-set)
 876   (let ((word (gensym))
 877         (bit (gensym)))
 878     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 879        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 880              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 881                      (sb!kernel:32bit-logical-not
 882                       (truly-the (unsigned-byte 32) (ash 1 ,bit))))))))
 883
 884 ;;; not checked for linux...
 885 (defmacro fd-isset (offset fd-set)
 886   (let ((word (gensym))
 887         (bit (gensym)))
 888     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 889        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 890
 891 ;;; not checked for linux...
 892 (defmacro fd-zero (fd-set)
 893   `(progn
 894      ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 895          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 896
 897