src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69      (if (minusp result)
  70          (values nil (get-errno))
  71          ,success-form)))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  78                                 ,@args)))
  79      (if (minusp result)
  80          (error "Syscall ~A failed: ~A" ,name (strerror))
  81          ,success-form)))
  82
  83 (/show0 "unix.lisp 109")
  84
  85 (defmacro void-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  87
  88 (defmacro int-syscall ((name &rest arg-types) &rest args)
  89   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  90 \f
  91 ;;;; hacking the Unix environment
  92
  93 (define-alien-routine ("getenv" posix-getenv) c-string
  94   "Return the \"value\" part of the environment string \"name=value\" which
  95    corresponds to NAME, or NIL if there is none."
  96   (name c-string))
  97 \f
  98 ;;; from stdio.h
  99
 100 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 101 ;;; error code is returned if an error occurs.
 102 (defun unix-rename (name1 name2)
 103   (declare (type unix-pathname name1 name2))
 104   (void-syscall ("rename" c-string c-string) name1 name2))
 105 \f
 106 ;;; from sys/types.h and gnu/types.h
 107
 108 (/show0 "unix.lisp 220")
 109
 110 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 111 ;;; like this unless we have extreme provocation. Reading directories
 112 ;;; is not extreme enough, since it doesn't need to be blindingly
 113 ;;; fast: we can just implement those functions in C as a wrapper
 114 ;;; layer.
 115 (define-alien-type fd-mask unsigned-long)
 116
 117 (eval-when (:compile-toplevel :load-toplevel :execute)
 118   (defconstant fd-setsize 1024))
 119
 120 (define-alien-type nil
 121   (struct fd-set
 122           (fds-bits (array fd-mask #.(/ fd-setsize 32)))))
 123
 124 (/show0 "unix.lisp 304")
 125 \f
 126 \f
 127 ;;;; fcntl.h
 128 ;;;;
 129 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 130
 131 ;;; Open the file whose pathname is specified by PATH for reading
 132 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 133 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 134 ;;;
 135 ;;; If the O_CREAT flag is specified, then the file is created with a
 136 ;;; permission of argument MODE if the file doesn't exist. An integer
 137 ;;; file descriptor is returned by UNIX-OPEN.
 138 (defun unix-open (path flags mode)
 139   (declare (type unix-pathname path)
 140            (type fixnum flags)
 141            (type unix-file-mode mode))
 142   (int-syscall ("open" c-string int int) path flags mode))
 143
 144 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 145 ;;; associated with it.
 146 (/show0 "unix.lisp 391")
 147 (defun unix-close (fd)
 148   (declare (type unix-fd fd))
 149   (void-syscall ("close" int) fd))
 150 \f
 151 ;;;; timebits.h
 152
 153 ;; A time value that is accurate to the nearest
 154 ;; microsecond but also has a range of years.
 155 (define-alien-type nil
 156   (struct timeval
 157           (tv-sec time-t)               ; seconds
 158           (tv-usec time-t)))            ; and microseconds
 159 \f
 160 ;;;; resourcebits.h
 161
 162 (defconstant rusage_self 0) ; the calling process
 163 (defconstant rusage_children -1) ; terminated child processes
 164 (defconstant rusage_both -2)
 165
 166 (define-alien-type nil
 167   (struct rusage
 168     (ru-utime (struct timeval))     ; user time used
 169     (ru-stime (struct timeval))     ; system time used.
 170     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 171     (ru-ixrss long)                 ; integral shared memory size
 172     (ru-idrss long)                 ; integral unshared data size
 173     (ru-isrss long)                 ; integral unshared stack size
 174     (ru-minflt long)                ; page reclaims
 175     (ru-majflt long)                ; page faults
 176     (ru-nswap long)                 ; swaps
 177     (ru-inblock long)               ; block input operations
 178     (ru-oublock long)               ; block output operations
 179     (ru-msgsnd long)                ; messages sent
 180     (ru-msgrcv long)                ; messages received
 181     (ru-nsignals long)              ; signals received
 182     (ru-nvcsw long)                 ; voluntary context switches
 183     (ru-nivcsw long)))              ; involuntary context switches
 184 \f
 185 ;;;; unistd.h
 186
 187 ;;; Given a file path (a string) and one of four constant modes,
 188 ;;; return T if the file is accessible with that mode and NIL if not.
 189 ;;; When NIL, also return an errno value with NIL which tells why the
 190 ;;; file was not accessible.
 191 ;;;
 192 ;;; The access modes are:
 193 ;;;   r_ok     Read permission.
 194 ;;;   w_ok     Write permission.
 195 ;;;   x_ok     Execute permission.
 196 ;;;   f_ok     Presence of file.
 197 (defun unix-access (path mode)
 198   (declare (type unix-pathname path)
 199            (type (mod 8) mode))
 200   (void-syscall ("access" c-string int) path mode))
 201
 202 ;;; values for the second argument to UNIX-LSEEK
 203 (defconstant l_set 0) ; to set the file pointer
 204 (defconstant l_incr 1) ; to increment the file pointer
 205 (defconstant l_xtnd 2) ; to extend the file size
 206
 207 ;;; Accept a file descriptor and move the file pointer ahead
 208 ;;; a certain offset for that file. WHENCE can be any of the following:
 209 ;;;  L_SET     Set the file pointer.
 210 ;;;  L_INCR    Increment the file pointer.
 211 ;;;  L_XTND    Extend the file size.
 212 (defun unix-lseek (fd offset whence)
 213   (declare (type unix-fd fd)
 214            (type (unsigned-byte 32) offset)
 215            (type (integer 0 2) whence))
 216   #!-(and x86 bsd)
 217   (int-syscall ("lseek" int off-t int) fd offset whence)
 218   ;; Need a 64-bit return value type for this. TBD. For now,
 219   ;; don't use this with any 2G+ partitions.
 220   #!+(and x86 bsd)
 221   (int-syscall ("lseek" int unsigned-long unsigned-long int)
 222                fd offset 0 whence))
 223
 224 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 225 ;;; It attempts to read len bytes from the device associated with fd
 226 ;;; and store them into the buffer. It returns the actual number of
 227 ;;; bytes read.
 228 (defun unix-read (fd buf len)
 229   (declare (type unix-fd fd)
 230            (type (unsigned-byte 32) len))
 231
 232   (int-syscall ("read" int (* char) int) fd buf len))
 233
 234 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 235 ;;; length to write. It attempts to write len bytes to the device
 236 ;;; associated with fd from the the buffer starting at offset. It returns
 237 ;;; the actual number of bytes written.
 238 (defun unix-write (fd buf offset len)
 239   (declare (type unix-fd fd)
 240            (type (unsigned-byte 32) offset len))
 241   (int-syscall ("write" int (* char) int)
 242                fd
 243                (with-alien ((ptr (* char) (etypecase buf
 244                                             ((simple-array * (*))
 245                                              (vector-sap buf))
 246                                             (system-area-pointer
 247                                              buf))))
 248                  (addr (deref ptr offset)))
 249                len))
 250
 251 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 252 ;;; output pipe. Return two values: if no error occurred the first
 253 ;;; value is the pipe to be read from and the second is can be written
 254 ;;; to. If an error occurred the first value is NIL and the second the
 255 ;;; unix error code.
 256 (defun unix-pipe ()
 257   (with-alien ((fds (array int 2)))
 258     (syscall ("pipe" (* int))
 259              (values (deref fds 0) (deref fds 1))
 260              (cast fds (* int)))))
 261
 262 (defun unix-mkdir (name mode)
 263   (declare (type unix-pathname name)
 264            (type unix-file-mode mode))
 265   (void-syscall ("mkdir" c-string int) name mode))
 266
 267 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 268 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 269 (defun newcharstar-string (newcharstar)
 270   (declare (type (alien (* char)) newcharstar))
 271   (if (null-alien newcharstar)
 272       nil
 273       (prog1
 274           (cast newcharstar c-string)
 275         (free-alien newcharstar))))
 276
 277 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 278 ;;; style returned by getcwd() (no trailing slash character).
 279 (defun posix-getcwd ()
 280   ;; This implementation relies on a BSD/Linux extension to getcwd()
 281   ;; behavior, automatically allocating memory when a null buffer
 282   ;; pointer is used. On a system which doesn't support that
 283   ;; extension, it'll have to be rewritten somehow.
 284   #!-(or linux openbsd freebsd) (,stub,)
 285   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 286                                                        (function (* char)
 287                                                                  (* char)
 288                                                                  size-t))
 289                                          nil 0))
 290       (simple-perror "getcwd")))
 291
 292 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 293 ;;; by a slash character.
 294 (defun posix-getcwd/ ()
 295   (concatenate 'string (posix-getcwd) "/"))
 296
 297 ;;; Convert at the UNIX level from a possibly relative filename to
 298 ;;; an absolute filename.
 299 ;;;
 300 ;;; FIXME: Do we still need this even as we switch to
 301 ;;; *DEFAULT-PATHNAME-DEFAULTS*? I think maybe we do, since it seems
 302 ;;; to be valid for the user to set *DEFAULT-PATHNAME-DEFAULTS* to
 303 ;;; have a NIL directory component, and then this'd be the only way to
 304 ;;; interpret a relative directory specification. But I don't find the
 305 ;;; ANSI pathname documentation to be a model of clarity. Maybe
 306 ;;; someone who understands it better can take a look at this.. -- WHN
 307 (defun unix-maybe-prepend-current-directory (name)
 308   (declare (simple-string name))
 309   (if (and (> (length name) 0) (char= (schar name 0) #\/))
 310       name
 311       (concatenate 'simple-string (posix-getcwd/) name)))
 312
 313 ;;; Duplicate an existing file descriptor (given as the argument) and
 314 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 315 ;;; number are returned.
 316 (defun unix-dup (fd)
 317   (declare (type unix-fd fd))
 318   (int-syscall ("dup" int) fd))
 319
 320 ;;; Terminate the current process with an optional error code. If
 321 ;;; successful, the call doesn't return. If unsuccessful, the call
 322 ;;; returns NIL and an error number.
 323 (defun unix-exit (&optional (code 0))
 324   (declare (type (signed-byte 32) code))
 325   (void-syscall ("exit" int) code))
 326
 327 ;;; Return the process id of the current process.
 328 (define-alien-routine ("getpid" unix-getpid) int)
 329
 330 ;;; Return the real user id associated with the current process.
 331 (define-alien-routine ("getuid" unix-getuid) int)
 332
 333 ;;; Translate a user id into a login name.
 334 (defun uid-username (uid)
 335   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 336                                                        (function (* char) int))
 337                                          uid))
 338       (error "found no match for Unix uid=~S" uid)))
 339
 340 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 341 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 342 ;;; failure.
 343 (defun unix-readlink (path)
 344   (declare (type unix-pathname path))
 345   (with-alien ((ptr (* char)
 346                     (alien-funcall (extern-alien
 347                                     "wrapped_readlink"
 348                                     (function (* char) c-string))
 349                                    path)))
 350     (if (null-alien ptr)
 351         (values nil (get-errno))
 352         (multiple-value-prog1
 353             (values (with-alien ((c-string c-string ptr)) c-string)
 354                     nil)
 355           (free-alien ptr)))))
 356
 357 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 358 ;;; name and the file if this is the last link.
 359 (defun unix-unlink (name)
 360   (declare (type unix-pathname name))
 361   (void-syscall ("unlink" c-string) name))
 362
 363 ;;; Return the name of the host machine as a string.
 364 (defun unix-gethostname ()
 365   (with-alien ((buf (array char 256)))
 366     (syscall ("gethostname" (* char) int)
 367              (cast buf c-string)
 368              (cast buf (* char)) 256)))
 369
 370 ;;; Write the core image of the file described by FD to disk.
 371 (defun unix-fsync (fd)
 372   (declare (type unix-fd fd))
 373   (void-syscall ("fsync" int) fd))
 374 \f
 375 ;;;; sys/ioctl.h
 376
 377 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 378 ;;; descriptors. See the UNIX Programmer's Manual for more
 379 ;;; information.
 380 (defun unix-ioctl (fd cmd arg)
 381   (declare (type unix-fd fd)
 382            (type (unsigned-byte 32) cmd))
 383   (void-syscall ("ioctl" int unsigned-int (* char)) fd cmd arg))
 384 \f
 385 ;;;; sys/resource.h
 386
 387 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 388 ;;;
 389 ;;; This is like getrusage(2), except it returns only the system and
 390 ;;; user time, and returns the seconds and microseconds as separate
 391 ;;; values.
 392 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 393 (defun unix-fast-getrusage (who)
 394   (declare (values (member t)
 395                    (unsigned-byte 31) (integer 0 1000000)
 396                    (unsigned-byte 31) (integer 0 1000000)))
 397   (with-alien ((usage (struct rusage)))
 398     (syscall* ("getrusage" int (* (struct rusage)))
 399               (values t
 400                       (slot (slot usage 'ru-utime) 'tv-sec)
 401                       (slot (slot usage 'ru-utime) 'tv-usec)
 402                       (slot (slot usage 'ru-stime) 'tv-sec)
 403                       (slot (slot usage 'ru-stime) 'tv-usec))
 404               who (addr usage))))
 405
 406 ;;; Return information about the resource usage of the process
 407 ;;; specified by WHO. WHO can be either the current process
 408 ;;; (rusage_self) or all of the terminated child processes
 409 ;;; (rusage_children). NIL and an error number is returned if the call
 410 ;;; fails.
 411 (defun unix-getrusage (who)
 412   (with-alien ((usage (struct rusage)))
 413     (syscall ("getrusage" int (* (struct rusage)))
 414               (values t
 415                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 416                          (slot (slot usage 'ru-utime) 'tv-usec))
 417                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 418                          (slot (slot usage 'ru-stime) 'tv-usec))
 419                       (slot usage 'ru-maxrss)
 420                       (slot usage 'ru-ixrss)
 421                       (slot usage 'ru-idrss)
 422                       (slot usage 'ru-isrss)
 423                       (slot usage 'ru-minflt)
 424                       (slot usage 'ru-majflt)
 425                       (slot usage 'ru-nswap)
 426                       (slot usage 'ru-inblock)
 427                       (slot usage 'ru-oublock)
 428                       (slot usage 'ru-msgsnd)
 429                       (slot usage 'ru-msgrcv)
 430                       (slot usage 'ru-nsignals)
 431                       (slot usage 'ru-nvcsw)
 432                       (slot usage 'ru-nivcsw))
 433               who (addr usage))))
 434 \f
 435 ;;;; sys/select.h
 436
 437 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 438
 439 ;;; Perform the UNIX select(2) system call.
 440 (declaim (inline unix-fast-select)) ; (used to be a macro in CMU CL)
 441 (defun unix-fast-select (num-descriptors
 442                          read-fds write-fds exception-fds
 443                          timeout-secs &optional (timeout-usecs 0))
 444   (declare (type (integer 0 #.fd-setsize) num-descriptors)
 445            (type (or (alien (* (struct fd-set))) null)
 446                  read-fds write-fds exception-fds)
 447            (type (or null (unsigned-byte 31)) timeout-secs)
 448            (type (unsigned-byte 31) timeout-usecs))
 449   ;; FIXME: CMU CL had
 450   ;;   (declare (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 451   ;; here. Is that important for SBCL? If so, why? Profiling might tell us..
 452   (with-alien ((tv (struct timeval)))
 453     (when timeout-secs
 454       (setf (slot tv 'tv-sec) timeout-secs)
 455       (setf (slot tv 'tv-usec) timeout-usecs))
 456     (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 457                   (* (struct fd-set)) (* (struct timeval)))
 458                  num-descriptors read-fds write-fds exception-fds
 459                  (if timeout-secs (alien-sap (addr tv)) (int-sap 0)))))
 460
 461 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 462 ;;; to happen on one of them or to time out.
 463 (defmacro num-to-fd-set (fdset num)
 464   `(if (fixnump ,num)
 465        (progn
 466          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 467          ,@(loop for index upfrom 1 below (/ fd-setsize 32)
 468              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 469        (progn
 470          ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 471              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 472                             (ldb (byte 32 ,(* index 32)) ,num))))))
 473
 474 (defmacro fd-set-to-num (nfds fdset)
 475   `(if (<= ,nfds 32)
 476        (deref (slot ,fdset 'fds-bits) 0)
 477        (+ ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 478               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 479                             ,(* index 32))))))
 480
 481 ;;; Examine the sets of descriptors passed as arguments to see whether
 482 ;;; they are ready for reading and writing. See the UNIX Programmer's
 483 ;;; Manual for more information.
 484 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 485   (declare (type (integer 0 #.FD-SETSIZE) nfds)
 486            (type unsigned-byte rdfds wrfds xpfds)
 487            (type (or (unsigned-byte 31) null) to-secs)
 488            (type (unsigned-byte 31) to-usecs)
 489            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 490   (with-alien ((tv (struct timeval))
 491                (rdf (struct fd-set))
 492                (wrf (struct fd-set))
 493                (xpf (struct fd-set)))
 494     (when to-secs
 495       (setf (slot tv 'tv-sec) to-secs)
 496      (setf (slot tv 'tv-usec) to-usecs))
 497     (num-to-fd-set rdf rdfds)
 498     (num-to-fd-set wrf wrfds)
 499     (num-to-fd-set xpf xpfds)
 500     (macrolet ((frob (lispvar alienvar)
 501                  `(if (zerop ,lispvar)
 502                       (int-sap 0)
 503                       (alien-sap (addr ,alienvar)))))
 504       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 505                 (* (struct fd-set)) (* (struct timeval)))
 506                (values result
 507                        (fd-set-to-num nfds rdf)
 508                        (fd-set-to-num nfds wrf)
 509                        (fd-set-to-num nfds xpf))
 510                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 511                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 512 \f
 513 ;;;; sys/stat.h
 514
 515 ;;; This is a structure defined in src/runtime/wrap.c, to look
 516 ;;; basically like "struct stat" according to stat(2). It may not
 517 ;;; actually correspond to the real in-memory stat structure that the
 518 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 519 ;;; stat macros, and trying to keep Lisp code in correspondence with
 520 ;;; it is more pain than it's worth, so we just let our C runtime
 521 ;;; synthesize a nice consistent structure for us.
 522 ;;;
 523 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 524 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn's support
 525 ;;; those. We don't actually access that field anywhere, though, so
 526 ;;; until we can get 64 bit alien support it'll do. Also note that
 527 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 528 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 529 ;;; longer than 32 bits anyway, right?":-|
 530 (define-alien-type nil
 531   (struct wrapped_stat
 532     (st-dev unsigned-long)              ; would be dev-t in a real stat
 533     (st-ino ino-t)
 534     (st-mode mode-t)
 535     (st-nlink  nlink-t)
 536     (st-uid  uid-t)
 537     (st-gid  gid-t)
 538     (st-rdev unsigned-long)             ; would be dev-t in a real stat
 539     (st-size unsigned-long)             ; would be off-t in a real stat
 540     (st-blksize unsigned-long)
 541     (st-blocks unsigned-long)
 542     (st-atime time-t)
 543     (st-mtime time-t)
 544     (st-ctime time-t)))
 545
 546 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 547 ;;; family of Unix system calls
 548 ;;;
 549 ;;; FIXME: I think this should probably not be INLINE. However, when
 550 ;;; this was not inline, it seemed to cause memory corruption
 551 ;;; problems. My first guess is that it's a bug in the FFI code, where
 552 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 553 ;;; around a call to a function returning >10 values. But I didn't try
 554 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 555 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 556 ;;; output in the not-inlined case and see whether there's a problem,
 557 ;;; and maybe even find a fix..
 558 (declaim (inline %extract-stat-results))
 559 (defun %extract-stat-results (wrapped-stat)
 560   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 561   (values t
 562           (slot wrapped-stat 'st-dev)
 563           (slot wrapped-stat 'st-ino)
 564           (slot wrapped-stat 'st-mode)
 565           (slot wrapped-stat 'st-nlink)
 566           (slot wrapped-stat 'st-uid)
 567           (slot wrapped-stat 'st-gid)
 568           (slot wrapped-stat 'st-rdev)
 569           (slot wrapped-stat 'st-size)
 570           (slot wrapped-stat 'st-atime)
 571           (slot wrapped-stat 'st-mtime)
 572           (slot wrapped-stat 'st-ctime)
 573           (slot wrapped-stat 'st-blksize)
 574           (slot wrapped-stat 'st-blocks)))
 575
 576 ;;; Unix system calls in the stat(2) family are handled by calls to
 577 ;;; C-level wrapper functions which copy all the raw "struct stat"
 578 ;;; slots into the system-independent wrapped_stat format.
 579 ;;;    stat(2) <->  stat_wrapper()
 580 ;;;   fstat(2) <-> fstat_wrapper()
 581 ;;;   lstat(2) <-> lstat_wrapper()
 582 (defun unix-stat (name)
 583   (declare (type unix-pathname name))
 584   (with-alien ((buf (struct wrapped_stat)))
 585     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 586              (%extract-stat-results (addr buf))
 587              name (addr buf))))
 588 (defun unix-lstat (name)
 589   (declare (type unix-pathname name))
 590   (with-alien ((buf (struct wrapped_stat)))
 591     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 592              (%extract-stat-results (addr buf))
 593              name (addr buf))))
 594 (defun unix-fstat (fd)
 595   (declare (type unix-fd fd))
 596   (with-alien ((buf (struct wrapped_stat)))
 597     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 598              (%extract-stat-results (addr buf))
 599              fd (addr buf))))
 600 \f
 601 ;;;; time.h
 602
 603 ;; the POSIX.4 structure for a time value. This is like a "struct
 604 ;; timeval" but has nanoseconds instead of microseconds.
 605 (define-alien-type nil
 606     (struct timespec
 607             (tv-sec long)   ; seconds
 608             (tv-nsec long))) ; nanoseconds
 609
 610 ;; used by other time functions
 611 (define-alien-type nil
 612     (struct tm
 613             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 614             (tm-min int)   ; Minutes.   [0-59]
 615             (tm-hour int)  ; Hours.     [0-23]
 616             (tm-mday int)  ; Day.       [1-31]
 617             (tm-mon int)   ; Month.     [0-11]
 618             (tm-year int)  ; Year - 1900.
 619             (tm-wday int)  ; Day of week. [0-6]
 620             (tm-yday int)  ; Days in year. [0-365]
 621             (tm-isdst int) ; DST.       [-1/0/1]
 622             (tm-gmtoff long) ;  Seconds east of UTC.
 623             (tm-zone c-string))) ; Timezone abbreviation.
 624
 625 (define-alien-routine get-timezone sb!alien:void
 626   (when sb!alien:long :in)
 627   (minutes-west sb!alien:int :out)
 628   (daylight-savings-p sb!alien:boolean :out))
 629
 630 (defun unix-get-minutes-west (secs)
 631   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 632     (declare (ignore ignore) (ignore dst))
 633     (values minutes)))
 634
 635 (defun unix-get-timezone (secs)
 636   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 637     (declare (ignore ignore) (ignore minutes))
 638     (values (deref unix-tzname (if dst 1 0)))))
 639
 640 \f
 641 ;;;; sys/time.h
 642
 643 ;;; Structure crudely representing a timezone. KLUDGE: This is
 644 ;;; obsolete and should never be used.
 645 (define-alien-type nil
 646   (struct timezone
 647     (tz-minuteswest int)                ; minutes west of Greenwich
 648     (tz-dsttime int)))                  ; type of dst correction
 649
 650 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 651 ;;; and microseconds of the current time of day, the timezone (in
 652 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 653 ;;; doesn't work, it returns NIL and the errno.
 654 #!-sb-fluid (declaim (inline unix-gettimeofday))
 655 (defun unix-gettimeofday ()
 656   (with-alien ((tv (struct timeval))
 657                (tz (struct timezone)))
 658     (syscall* ("gettimeofday" (* (struct timeval))
 659                               (* (struct timezone)))
 660               (values T
 661                       (slot tv 'tv-sec)
 662                       (slot tv 'tv-usec)
 663                       (slot tz 'tz-minuteswest)
 664                       (slot tz 'tz-dsttime))
 665               (addr tv)
 666               (addr tz))))
 667 \f
 668
 669 (defconstant ENOENT 2) ; Unix error code, "No such file or directory"
 670 (defconstant EINTR 4) ; Unix error code, "Interrupted system call"
 671 (defconstant EIO 5) ; Unix error code, "I/O error"
 672 (defconstant EEXIST 17) ; Unix error code, "File exists"
 673 (defconstant ESPIPE 29) ; Unix error code, "Illegal seek"
 674 (defconstant EWOULDBLOCK 11) ; Unix error code, "Operation would block"
 675 ;;; FIXME: Many Unix error code definitions were deleted from the old
 676 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 677 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 678 ;;; unused symbols in package exports, but if I don't, there are
 679 ;;; enough of them all in one place here that they should probably be
 680 ;;; removed by hand.
 681 \f
 682 \f
 683 ;;;; support routines for dealing with Unix pathnames
 684
 685 (defun unix-file-kind (name &optional check-for-links)
 686   #!+sb-doc
 687   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 688   (declare (simple-string name))
 689   (multiple-value-bind (res dev ino mode)
 690       (if check-for-links (unix-lstat name) (unix-stat name))
 691     (declare (type (or fixnum null) mode)
 692              (ignore dev ino))
 693     (when res
 694       (let ((kind (logand mode s-ifmt)))
 695         (cond ((eql kind s-ifdir) :directory)
 696               ((eql kind s-ifreg) :file)
 697               ((eql kind s-iflnk) :link)
 698               (t :special))))))
 699
 700 ;;; Is the Unix pathname PATHNAME relative, instead of absolute? (E.g.
 701 ;;; "passwd" or "etc/passwd" instead of "/etc/passwd"?)
 702 (defun relative-unix-pathname? (pathname)
 703   (declare (type simple-string pathname))
 704   (or (zerop (length pathname))
 705       (char/= (schar pathname 0) #\/)))
 706
 707 ;;; Return PATHNAME with all symbolic links resolved. PATHNAME should
 708 ;;; already be a complete absolute Unix pathname, since at least in
 709 ;;; sbcl-0.6.12.36 we're called only from TRUENAME, and only after
 710 ;;; paths have been converted to absolute paths, so we don't need to
 711 ;;; try to handle any more generality than that.
 712 (defun unix-resolve-links (pathname)
 713   (declare (type simple-string pathname))
 714   (aver (not (relative-unix-pathname? pathname)))
 715   (/noshow "entering UNIX-RESOLVE-LINKS")
 716   (loop with previous-pathnames = nil do
 717         (/noshow pathname previous-pathnames)
 718         (let ((link (unix-readlink pathname)))
 719           (/noshow link)
 720           ;; Unlike the old CMU CL code, we handle a broken symlink by
 721           ;; returning the link itself. That way, CL:TRUENAME on a
 722           ;; broken link returns the link itself, so that CL:DIRECTORY
 723           ;; can return broken links, so that even without
 724           ;; Unix-specific extensions to do interesting things with
 725           ;; them, at least Lisp programs can see them and, if
 726           ;; necessary, delete them. (This is handy e.g. when your
 727           ;; managed-by-Lisp directories are visited by Emacs, which
 728           ;; creates broken links as notes to itself.)
 729           (if (null link)
 730               (return pathname)
 731               (let ((new-pathname
 732                      (unix-simplify-pathname
 733                       (if (relative-unix-pathname? link)
 734                           (let* ((dir-len (1+ (position #\/
 735                                                         pathname
 736                                                         :from-end t)))
 737                                  (dir (subseq pathname 0 dir-len)))
 738                             (/noshow dir)
 739                             (concatenate 'string dir link))
 740                           link))))
 741                 (if (unix-file-kind new-pathname)
 742                     (setf pathname new-pathname)
 743                     (return pathname)))))
 744         ;; To generalize the principle that even if portable Lisp code
 745         ;; can't do anything interesting with a broken symlink, at
 746         ;; least it should be able to see and delete it, when we
 747         ;; detect a cyclic link, we return the link itself. (So even
 748         ;; though portable Lisp code can't do anything interesting
 749         ;; with a cyclic link, at least it can see it and delete it.)
 750         (if (member pathname previous-pathnames :test #'string=)
 751             (return pathname)
 752             (push pathname previous-pathnames))))
 753
 754 (defun unix-simplify-pathname (src)
 755   (declare (type simple-string src))
 756   (let* ((src-len (length src))
 757          (dst (make-string src-len))
 758          (dst-len 0)
 759          (dots 0)
 760          (last-slash nil))
 761     (macrolet ((deposit (char)
 762                  `(progn
 763                     (setf (schar dst dst-len) ,char)
 764                     (incf dst-len))))
 765       (dotimes (src-index src-len)
 766         (let ((char (schar src src-index)))
 767           (cond ((char= char #\.)
 768                  (when dots
 769                    (incf dots))
 770                  (deposit char))
 771                 ((char= char #\/)
 772                  (case dots
 773                    (0
 774                     ;; either ``/...' or ``...//...'
 775                     (unless last-slash
 776                       (setf last-slash dst-len)
 777                       (deposit char)))
 778                    (1
 779                     ;; either ``./...'' or ``..././...''
 780                     (decf dst-len))
 781                    (2
 782                     ;; We've found ..
 783                     (cond
 784                      ((and last-slash (not (zerop last-slash)))
 785                       ;; There is something before this ..
 786                       (let ((prev-prev-slash
 787                              (position #\/ dst :end last-slash :from-end t)))
 788                         (cond ((and (= (+ (or prev-prev-slash 0) 2)
 789                                        last-slash)
 790                                     (char= (schar dst (- last-slash 2)) #\.)
 791                                     (char= (schar dst (1- last-slash)) #\.))
 792                                ;; The something before this .. is another ..
 793                                (deposit char)
 794                                (setf last-slash dst-len))
 795                               (t
 796                                ;; The something is some directory or other.
 797                                (setf dst-len
 798                                      (if prev-prev-slash
 799                                          (1+ prev-prev-slash)
 800                                          0))
 801                                (setf last-slash prev-prev-slash)))))
 802                      (t
 803                       ;; There is nothing before this .., so we need to keep it
 804                       (setf last-slash dst-len)
 805                       (deposit char))))
 806                    (t
 807                     ;; something other than a dot between slashes
 808                     (setf last-slash dst-len)
 809                     (deposit char)))
 810                  (setf dots 0))
 811                 (t
 812                  (setf dots nil)
 813                  (setf (schar dst dst-len) char)
 814                  (incf dst-len))))))
 815     (when (and last-slash (not (zerop last-slash)))
 816       (case dots
 817         (1
 818          ;; We've got  ``foobar/.''
 819          (decf dst-len))
 820         (2
 821          ;; We've got ``foobar/..''
 822          (unless (and (>= last-slash 2)
 823                       (char= (schar dst (1- last-slash)) #\.)
 824                       (char= (schar dst (- last-slash 2)) #\.)
 825                       (or (= last-slash 2)
 826                           (char= (schar dst (- last-slash 3)) #\/)))
 827            (let ((prev-prev-slash
 828                   (position #\/ dst :end last-slash :from-end t)))
 829              (if prev-prev-slash
 830                  (setf dst-len (1+ prev-prev-slash))
 831                  (return-from unix-simplify-pathname "./")))))))
 832     (cond ((zerop dst-len)
 833            "./")
 834           ((= dst-len src-len)
 835            dst)
 836           (t
 837            (subseq dst 0 dst-len)))))
 838 \f
 839 ;;;; stuff not yet found in the header files
 840 ;;;;
 841 ;;;; Abandon all hope who enters here...
 842
 843 ;;; not checked for linux...
 844 (defmacro fd-set (offset fd-set)
 845   (let ((word (gensym))
 846         (bit (gensym)))
 847     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 848        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 849              (logior (truly-the (unsigned-byte 32) (ash 1 ,bit))
 850                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 851
 852 ;;; not checked for linux...
 853 (defmacro fd-clr (offset fd-set)
 854   (let ((word (gensym))
 855         (bit (gensym)))
 856     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 857        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 858              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 859                      (sb!kernel:32bit-logical-not
 860                       (truly-the (unsigned-byte 32) (ash 1 ,bit))))))))
 861
 862 ;;; not checked for linux...
 863 (defmacro fd-isset (offset fd-set)
 864   (let ((word (gensym))
 865         (bit (gensym)))
 866     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 867        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 868
 869 ;;; not checked for linux...
 870 (defmacro fd-zero (fd-set)
 871   `(progn
 872      ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 873          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 874
 875