src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 ;;; Given a C-level zero-terminated array of C strings, return a
  31 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  32 (defun c-strings->string-list (c-strings)
  33   (declare (type (alien (* c-string)) c-strings))
  34   (let ((reversed-result nil))
  35     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  36       (declare (type index i))
  37       (let ((c-string (deref c-strings i)))
  38         (if c-string
  39             (push c-string reversed-result)
  40             (return (nreverse reversed-result)))))))
  41 \f
  42 ;;;; Lisp types used by syscalls
  43
  44 (deftype unix-pathname () 'simple-string)
  45 (deftype unix-fd () `(integer 0 ,sb!xc:most-positive-fixnum))
  46
  47 (deftype unix-file-mode () '(unsigned-byte 32))
  48 (deftype unix-pid () '(unsigned-byte 32))
  49 (deftype unix-uid () '(unsigned-byte 32))
  50 (deftype unix-gid () '(unsigned-byte 32))
  51 \f
  52 ;;;; system calls
  53
  54 (/show0 "unix.lisp 74")
  55
  56 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  57 ;;; macros in this file, are only used in this file, and could be
  58 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  59 ;;;
  60 ;;; SB-EXECUTABLE, at least, uses one of these macros; other libraries
  61 ;;; and programs have been known to use them as well.  Perhaps they
  62 ;;; should live in SB-SYS or even SB-EXT?
  63
  64 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  65   `(locally
  66     (declare (optimize (sb!c::float-accuracy 0)))
  67     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69       (if (minusp result)
  70           (values nil (get-errno))
  71           ,success-form))))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(locally
  78     (declare (optimize (sb!c::float-accuracy 0)))
  79     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  80                                  ,@args)))
  81       (if (minusp result)
  82           (error "Syscall ~A failed: ~A" ,name (strerror))
  83           ,success-form))))
  84
  85 (defmacro int-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  87
  88 (defmacro with-restarted-syscall ((&optional (value (gensym))
  89                                              (errno (gensym)))
  90                                   syscall-form &rest body)
  91   #!+sb-doc
  92   "Evaluate BODY with VALUE and ERRNO bound to the return values of
  93 SYSCALL-FORM. Repeat evaluation of SYSCALL-FORM if it is interrupted."
  94   `(let (,value ,errno)
  95      (loop (multiple-value-setq (,value ,errno)
  96              ,syscall-form)
  97         (unless #!-win32 (eql ,errno sb!unix:eintr) #!+win32 nil
  98           (return (values ,value ,errno))))
  99      ,@body))
 100
 101 (defmacro void-syscall ((name &rest arg-types) &rest args)
 102   `(syscall (,name ,@arg-types) (values t 0) ,@args))
 103
 104 #!+win32
 105 (progn
 106   (defconstant espipe 29))
 107 \f
 108 ;;;; hacking the Unix environment
 109
 110 #!-win32
 111 (define-alien-routine ("getenv" posix-getenv) c-string
 112   "Return the \"value\" part of the environment string \"name=value\" which
 113 corresponds to NAME, or NIL if there is none."
 114   (name (c-string :not-null t)))
 115 \f
 116 ;;; from stdio.h
 117
 118 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 119 ;;; error code is returned if an error occurs.
 120 #!-win32
 121 (defun unix-rename (name1 name2)
 122   (declare (type unix-pathname name1 name2))
 123   (void-syscall ("rename" (c-string :not-null t)
 124                           (c-string :not-null t))
 125                 name1 name2))
 126 \f
 127 ;;; from sys/types.h and gnu/types.h
 128
 129 (/show0 "unix.lisp 220")
 130
 131 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 132 ;;; like this unless we have extreme provocation. Reading directories
 133 ;;; is not extreme enough, since it doesn't need to be blindingly
 134 ;;; fast: we can just implement those functions in C as a wrapper
 135 ;;; layer.
 136 (define-alien-type fd-mask unsigned-long)
 137
 138 (define-alien-type nil
 139   (struct fd-set
 140           (fds-bits (array fd-mask #.(/ fd-setsize
 141                                         sb!vm:n-machine-word-bits)))))
 142
 143 (/show0 "unix.lisp 304")
 144 \f
 145 \f
 146 ;;;; fcntl.h
 147 ;;;;
 148 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 149
 150 ;;; Open the file whose pathname is specified by PATH for reading
 151 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 152 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 153 ;;;
 154 ;;; If the O_CREAT flag is specified, then the file is created with a
 155 ;;; permission of argument MODE if the file doesn't exist. An integer
 156 ;;; file descriptor is returned by UNIX-OPEN.
 157 (defun unix-open (path flags mode)
 158   (declare (type unix-pathname path)
 159            (type fixnum flags)
 160            (type unix-file-mode mode))
 161   (with-restarted-syscall (value errno)
 162     (int-syscall ("open" c-string int int)
 163                  path
 164                  (logior #!+win32 o_binary
 165                          #!+largefile o_largefile
 166                          flags)
 167                  mode)))
 168
 169 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 170 ;;; associated with it.
 171 (/show0 "unix.lisp 391")
 172 (defun unix-close (fd)
 173   (declare (type unix-fd fd))
 174   (void-syscall ("close" int) fd))
 175 \f
 176 ;;;; stdlib.h
 177
 178 ;;; There are good reasons to implement some OPEN options with an
 179 ;;; mkstemp(3)-like routine, but we don't do that yet.  Instead, this
 180 ;;; function is used only to make a temporary file for RUN-PROGRAM.
 181 ;;; sb_mkstemp() is a wrapper that lives in src/runtime/wrap.c.  Since
 182 ;;; SUSv3 mkstemp() doesn't specify the mode of the created file and
 183 ;;; since we have to implement most of this ourselves for Windows
 184 ;;; anyway, it seems worthwhile to depart from the mkstemp()
 185 ;;; specification by taking a mode to use when creating the new file.
 186 (defun sb-mkstemp (template-string mode)
 187   (declare (type string template-string)
 188            (type unix-file-mode mode))
 189   (let ((template-buffer (string-to-octets template-string :null-terminate t)))
 190     (with-pinned-objects (template-buffer)
 191       (let ((fd (alien-funcall (extern-alien "sb_mkstemp"
 192                                              (function int (* char) int))
 193                                (vector-sap template-buffer)
 194                                mode)))
 195         (if (minusp fd)
 196             (values nil (get-errno))
 197             (values fd (octets-to-string template-buffer)))))))
 198 \f
 199 ;;;; timebits.h
 200
 201 ;; A time value that is accurate to the nearest
 202 ;; microsecond but also has a range of years.
 203 ;; CLH: Note that tv-usec used to be a time-t, but that this seems
 204 ;; problematic on Darwin x86-64 (and wrong). Trying suseconds-t.
 205 #!-(or win32 openbsd netbsd)
 206 (define-alien-type nil
 207   (struct timeval
 208           (tv-sec time-t)           ; seconds
 209           (tv-usec suseconds-t)))   ; and microseconds
 210
 211 ;; The above definition doesn't work on 64-bit OpenBSD platforms.
 212 ;; Both tv_sec and tv_usec are declared as long instead of time_t, and
 213 ;; time_t is a typedef for int.
 214 #!+(or openbsd netbsd)
 215 (define-alien-type nil
 216   (struct timeval
 217           (tv-sec long)             ; seconds
 218           (tv-usec long)))          ; and microseconds
 219
 220 #!+win32
 221 (define-alien-type nil
 222   (struct timeval
 223           (tv-sec time-t)           ; seconds
 224           (tv-usec long)))          ; and microseconds
 225 \f
 226 ;;;; resourcebits.h
 227
 228 (defconstant rusage_self 0) ; the calling process
 229 (defconstant rusage_children -1) ; terminated child processes
 230 (defconstant rusage_both -2)
 231
 232 (define-alien-type nil
 233   (struct rusage
 234     (ru-utime (struct timeval))     ; user time used
 235     (ru-stime (struct timeval))     ; system time used.
 236     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 237     (ru-ixrss long)                 ; integral shared memory size
 238     (ru-idrss long)                 ; integral unshared data size
 239     (ru-isrss long)                 ; integral unshared stack size
 240     (ru-minflt long)                ; page reclaims
 241     (ru-majflt long)                ; page faults
 242     (ru-nswap long)                 ; swaps
 243     (ru-inblock long)               ; block input operations
 244     (ru-oublock long)               ; block output operations
 245     (ru-msgsnd long)                ; messages sent
 246     (ru-msgrcv long)                ; messages received
 247     (ru-nsignals long)              ; signals received
 248     (ru-nvcsw long)                 ; voluntary context switches
 249     (ru-nivcsw long)))              ; involuntary context switches
 250 \f
 251 ;;;; unistd.h
 252
 253 ;;; Given a file path (a string) and one of four constant modes,
 254 ;;; return T if the file is accessible with that mode and NIL if not.
 255 ;;; When NIL, also return an errno value with NIL which tells why the
 256 ;;; file was not accessible.
 257 ;;;
 258 ;;; The access modes are:
 259 ;;;   r_ok     Read permission.
 260 ;;;   w_ok     Write permission.
 261 ;;;   x_ok     Execute permission.
 262 ;;;   f_ok     Presence of file.
 263
 264 ;;; In Windows, the MODE argument to access is defined in terms of
 265 ;;; literal magic numbers---there are no constants to grovel.  X_OK
 266 ;;; is not defined.
 267 #!+win32
 268 (progn
 269   (defconstant f_ok 0)
 270   (defconstant w_ok 2)
 271   (defconstant r_ok 4))
 272
 273 (defun unix-access (path mode)
 274   (declare (type unix-pathname path)
 275            (type (mod 8) mode))
 276   (void-syscall ("access" c-string int) path mode))
 277
 278 ;;; values for the second argument to UNIX-LSEEK
 279 ;;; Note that nowadays these are called SEEK_SET, SEEK_CUR, and SEEK_END
 280 (defconstant l_set 0) ; to set the file pointer
 281 (defconstant l_incr 1) ; to increment the file pointer
 282 (defconstant l_xtnd 2) ; to extend the file size
 283
 284 ;;; Is a stream interactive?
 285 (defun unix-isatty (fd)
 286   (declare (type unix-fd fd))
 287   (int-syscall ("isatty" int) fd))
 288
 289 (defun unix-lseek (fd offset whence)
 290   "Unix-lseek accepts a file descriptor and moves the file pointer by
 291    OFFSET octets.  Whence can be any of the following:
 292
 293    L_SET        Set the file pointer.
 294    L_INCR       Increment the file pointer.
 295    L_XTND       Extend the file size.
 296   "
 297   (declare (type unix-fd fd)
 298            (type (integer 0 2) whence))
 299   (let ((result (alien-funcall (extern-alien #!-largefile "lseek"
 300                                              #!+largefile "lseek_largefile"
 301                                              (function off-t int off-t int))
 302                  fd offset whence)))
 303     (if (minusp result)
 304         (values nil (get-errno))
 305       (values result 0))))
 306
 307 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 308 ;;; It attempts to read len bytes from the device associated with fd
 309 ;;; and store them into the buffer. It returns the actual number of
 310 ;;; bytes read.
 311
 312 #!-sb!fluid
 313 (declaim (maybe-inline unix-read))
 314
 315 (defun unix-read (fd buf len)
 316   (declare (type unix-fd fd)
 317            (type (unsigned-byte 32) len))
 318   (int-syscall ("read" int (* char) int) fd buf len))
 319
 320 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 321 ;;; length to write. It attempts to write len bytes to the device
 322 ;;; associated with fd from the buffer starting at offset. It returns
 323 ;;; the actual number of bytes written.
 324 (defun unix-write (fd buf offset len)
 325   (declare (type unix-fd fd)
 326            (type (unsigned-byte 32) offset len))
 327   (flet ((%write (sap)
 328            (declare (system-area-pointer sap))
 329            (int-syscall ("write" int (* char) int)
 330                         fd
 331                         (with-alien ((ptr (* char) sap))
 332                           (addr (deref ptr offset)))
 333                         len)))
 334     (etypecase buf
 335       ((simple-array * (*))
 336        (with-pinned-objects (buf)
 337          (%write (vector-sap buf))))
 338       (system-area-pointer
 339        (%write buf)))))
 340
 341 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 342 ;;; output pipe. Return two values: if no error occurred the first
 343 ;;; value is the pipe to be read from and the second is can be written
 344 ;;; to. If an error occurred the first value is NIL and the second the
 345 ;;; unix error code.
 346 #!-win32
 347 (defun unix-pipe ()
 348   (with-alien ((fds (array int 2)))
 349     (syscall ("pipe" (* int))
 350              (values (deref fds 0) (deref fds 1))
 351              (cast fds (* int)))))
 352 #!+win32
 353 (defun msvcrt-raw-pipe (fds size mode)
 354   (syscall ("_pipe" (* int) int int)
 355            (values (deref fds 0) (deref fds 1))
 356            (cast fds (* int)) size mode))
 357 #!+win32
 358 (defun unix-pipe ()
 359   (with-alien ((fds (array int 2)))
 360     (msvcrt-raw-pipe fds 256 o_binary)))
 361
 362 ;; Windows mkdir() doesn't take the mode argument. It's cdecl, so we could
 363 ;; actually call it passing the mode argument, but some sharp-eyed reader
 364 ;; would put five and twenty-seven together and ask us about it, so...
 365 ;;    -- AB, 2005-12-27
 366 #!-win32
 367 (defun unix-mkdir (name mode)
 368   (declare (type unix-pathname name)
 369            (type unix-file-mode mode)
 370            #!+win32 (ignore mode))
 371   (void-syscall ("mkdir" c-string #!-win32 int) name #!-win32 mode))
 372
 373 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 374 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 375 (defun newcharstar-string (newcharstar)
 376   (declare (type (alien (* char)) newcharstar))
 377   (if (null-alien newcharstar)
 378       nil
 379       (prog1
 380           (cast newcharstar c-string)
 381         (free-alien newcharstar))))
 382
 383 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 384 ;;; style returned by getcwd() (no trailing slash character).
 385 #!-win32
 386 (defun posix-getcwd ()
 387   ;; This implementation relies on a BSD/Linux extension to getcwd()
 388   ;; behavior, automatically allocating memory when a null buffer
 389   ;; pointer is used. On a system which doesn't support that
 390   ;; extension, it'll have to be rewritten somehow.
 391   ;;
 392   ;; SunOS and OSF/1 provide almost as useful an extension: if given a null
 393   ;; buffer pointer, it will automatically allocate size space. The
 394   ;; KLUDGE in this solution arises because we have just read off
 395   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 396   ;; a constant. Going the grovel_headers route doesn't seem to be
 397   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 398   ;; unistd.h.
 399   ;;
 400   ;; FIXME: The (,stub,) nastiness produces an error message about a
 401   ;; comma not inside a backquote. This error has absolutely nothing
 402   ;; to do with the actual meaning of the error (and little to do with
 403   ;; its location, either).
 404   #!-(or linux openbsd freebsd netbsd sunos osf1 darwin hpux win32) (,stub,)
 405   #!+(or linux openbsd freebsd netbsd sunos osf1 darwin hpux win32)
 406   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 407                                                        (function (* char)
 408                                                                  (* char)
 409                                                                  size-t))
 410                                          nil
 411                                          #!+(or linux openbsd freebsd netbsd darwin win32) 0
 412                                          #!+(or sunos osf1 hpux) 1025))
 413       (simple-perror "getcwd")))
 414
 415 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 416 ;;; by a slash character.
 417 (defun posix-getcwd/ ()
 418   (concatenate 'string (posix-getcwd) "/"))
 419
 420 ;;; Duplicate an existing file descriptor (given as the argument) and
 421 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 422 ;;; number are returned.
 423 (defun unix-dup (fd)
 424   (declare (type unix-fd fd))
 425   (int-syscall ("dup" int) fd))
 426
 427 ;;; Terminate the current process with an optional error code. If
 428 ;;; successful, the call doesn't return. If unsuccessful, the call
 429 ;;; returns NIL and an error number.
 430 (defun unix-exit (&optional (code 0))
 431   (declare (type (signed-byte 32) code))
 432   (void-syscall ("exit" int) code))
 433
 434 ;;; Return the process id of the current process.
 435 (define-alien-routine ("getpid" unix-getpid) int)
 436
 437 ;;; Return the real user id associated with the current process.
 438 #!-win32
 439 (define-alien-routine ("getuid" unix-getuid) int)
 440
 441 ;;; Translate a user id into a login name.
 442 #!-win32
 443 (defun uid-username (uid)
 444   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 445                                                        (function (* char) int))
 446                                          uid))
 447       (error "found no match for Unix uid=~S" uid)))
 448
 449 ;;; Return the namestring of the home directory, being careful to
 450 ;;; include a trailing #\/
 451 #!-win32
 452 (progn
 453   (defun uid-homedir (uid)
 454     (or (newcharstar-string (alien-funcall (extern-alien "uid_homedir"
 455                                                          (function (* char) int))
 456                                            uid))
 457         (error "failed to resolve home directory for Unix uid=~S" uid)))
 458
 459   (defun user-homedir (uid)
 460     (or (newcharstar-string (alien-funcall (extern-alien "user_homedir"
 461                                                          (function (* char) c-string))
 462                                            uid))
 463         (error "failed to resolve home directory for Unix uid=~S" uid))))
 464
 465 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 466 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 467 ;;; failure.
 468 #!-win32
 469 (defun unix-readlink (path)
 470   (declare (type unix-pathname path))
 471   (with-alien ((ptr (* char)
 472                     (alien-funcall (extern-alien
 473                                     "wrapped_readlink"
 474                                     (function (* char) c-string))
 475                                    path)))
 476     (if (null-alien ptr)
 477         (values nil (get-errno))
 478         (multiple-value-prog1
 479             (values (with-alien ((c-string c-string ptr)) c-string)
 480                     nil)
 481           (free-alien ptr)))))
 482 #!+win32
 483 ;; Win32 doesn't do links, but something likes to call this anyway.
 484 ;; Something in this file, no less. But it only takes one result, so...
 485 (defun unix-readlink (path)
 486   (declare (ignore path))
 487   nil)
 488
 489 (defun unix-realpath (path)
 490   (declare (type unix-pathname path))
 491   (with-alien ((ptr (* char)
 492                     (alien-funcall (extern-alien
 493                                     "sb_realpath"
 494                                     (function (* char) c-string))
 495                                    path)))
 496     (if (null-alien ptr)
 497         (values nil (get-errno))
 498         (multiple-value-prog1
 499             (values (with-alien ((c-string c-string ptr)) c-string)
 500                     nil)
 501           (free-alien ptr)))))
 502
 503 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 504 ;;; name and the file if this is the last link.
 505 (defun unix-unlink (name)
 506   (declare (type unix-pathname name))
 507   (void-syscall ("unlink" c-string) name))
 508
 509 ;;; Return the name of the host machine as a string.
 510 #!-win32
 511 (defun unix-gethostname ()
 512   (with-alien ((buf (array char 256)))
 513     (syscall ("gethostname" (* char) int)
 514              (cast buf c-string)
 515              (cast buf (* char)) 256)))
 516
 517 #!-win32
 518 (defun unix-setsid ()
 519   (int-syscall ("setsid")))
 520
 521 ;;;; sys/ioctl.h
 522
 523 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 524 ;;; descriptors. See the UNIX Programmer's Manual for more
 525 ;;; information.
 526 #!-win32
 527 (defun unix-ioctl (fd cmd arg)
 528   (declare (type unix-fd fd)
 529            (type (signed-byte 32) cmd))
 530   (void-syscall ("ioctl" int int (* char)) fd cmd arg))
 531 \f
 532 ;;;; sys/resource.h
 533
 534 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 535 ;;;
 536 ;;; This is like getrusage(2), except it returns only the system and
 537 ;;; user time, and returns the seconds and microseconds as separate
 538 ;;; values.
 539 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 540 #!-win32
 541 (defun unix-fast-getrusage (who)
 542   (declare (values (member t)
 543                    (unsigned-byte 31) (integer 0 1000000)
 544                    (unsigned-byte 31) (integer 0 1000000)))
 545   (with-alien ((usage (struct rusage)))
 546     (syscall* ("getrusage" int (* (struct rusage)))
 547               (values t
 548                       (slot (slot usage 'ru-utime) 'tv-sec)
 549                       (slot (slot usage 'ru-utime) 'tv-usec)
 550                       (slot (slot usage 'ru-stime) 'tv-sec)
 551                       (slot (slot usage 'ru-stime) 'tv-usec))
 552               who (addr usage))))
 553
 554 ;;; Return information about the resource usage of the process
 555 ;;; specified by WHO. WHO can be either the current process
 556 ;;; (rusage_self) or all of the terminated child processes
 557 ;;; (rusage_children). NIL and an error number is returned if the call
 558 ;;; fails.
 559 #!-win32
 560 (defun unix-getrusage (who)
 561   (with-alien ((usage (struct rusage)))
 562     (syscall ("getrusage" int (* (struct rusage)))
 563               (values t
 564                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 565                          (slot (slot usage 'ru-utime) 'tv-usec))
 566                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 567                          (slot (slot usage 'ru-stime) 'tv-usec))
 568                       (slot usage 'ru-maxrss)
 569                       (slot usage 'ru-ixrss)
 570                       (slot usage 'ru-idrss)
 571                       (slot usage 'ru-isrss)
 572                       (slot usage 'ru-minflt)
 573                       (slot usage 'ru-majflt)
 574                       (slot usage 'ru-nswap)
 575                       (slot usage 'ru-inblock)
 576                       (slot usage 'ru-oublock)
 577                       (slot usage 'ru-msgsnd)
 578                       (slot usage 'ru-msgrcv)
 579                       (slot usage 'ru-nsignals)
 580                       (slot usage 'ru-nvcsw)
 581                       (slot usage 'ru-nivcsw))
 582               who (addr usage))))
 583 \f
 584 (defvar *on-dangerous-wait* :warn)
 585
 586 ;;; Calling select in a bad place can hang in a nasty manner, so it's better
 587 ;;; to have some way to detect these.
 588 (defun note-dangerous-wait (type)
 589   (let ((action *on-dangerous-wait*)
 590         (*on-dangerous-wait* nil))
 591     (case action
 592       (:warn
 593        (warn "Starting a ~A without a timeout while interrupts are ~
 594              disabled."
 595              type))
 596       (:error
 597        (error "Starting a ~A without a timeout while interrupts are ~
 598               disabled."
 599               type))
 600       (:backtrace
 601        (format *debug-io*
 602                "~&=== Starting a ~A without a timeout while interrupts are disabled. ===~%"
 603                type)
 604        (sb!debug:backtrace)))
 605     nil))
 606 \f
 607 ;;;; poll.h
 608 #!+os-provides-poll
 609 (progn
 610   (define-alien-type nil
 611       (struct pollfd
 612               (fd      int)
 613               (events  short)           ; requested events
 614               (revents short)))         ; returned events
 615
 616   (defun unix-simple-poll (fd direction to-msec)
 617     (declare (fixnum fd to-msec))
 618     (when (and (minusp to-msec) (not *interrupts-enabled*))
 619       (note-dangerous-wait "poll(2)"))
 620     (let ((events (ecase direction
 621                     (:input (logior pollin pollpri))
 622                     (:output pollout))))
 623       (with-alien ((fds (struct pollfd)))
 624         (with-restarted-syscall (count errno)
 625           (progn
 626             (setf (slot fds 'fd) fd
 627                   (slot fds 'events) events
 628                   (slot fds 'revents) 0)
 629             (int-syscall ("poll" (* (struct pollfd)) int int)
 630                          (addr fds) 1 to-msec))
 631           (if (zerop errno)
 632               (let ((revents (slot fds 'revents)))
 633                 (or (and (eql 1 count) (logtest events revents))
 634                     (logtest pollhup revents)))
 635               (error "Syscall poll(2) failed: ~A" (strerror))))))))
 636 \f
 637 ;;;; sys/select.h
 638
 639 (defmacro with-fd-setsize ((n) &body body)
 640   `(let ((,n (if (< 0 ,n fd-setsize)
 641                  ,n
 642                  (error "Cannot select(2) on ~D: above FD_SETSIZE limit."
 643                         (1- num-descriptors)))))
 644      (declare (type (integer 0 #.fd-setsize) ,n))
 645      ,@body))
 646
 647 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 648
 649 ;;; Perform the UNIX select(2) system call.
 650 (declaim (inline unix-fast-select))
 651 (defun unix-fast-select (num-descriptors
 652                          read-fds write-fds exception-fds
 653                          timeout-secs timeout-usecs)
 654   (declare (type integer num-descriptors)
 655            (type (or (alien (* (struct fd-set))) null)
 656                  read-fds write-fds exception-fds)
 657            (type (or null (unsigned-byte 31)) timeout-secs timeout-usecs))
 658   (with-fd-setsize (num-descriptors)
 659     (flet ((select (tv-sap)
 660              (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 661                                     (* (struct fd-set)) (* (struct timeval)))
 662                           num-descriptors read-fds write-fds exception-fds
 663                           tv-sap)))
 664       (cond ((or timeout-secs timeout-usecs)
 665              (with-alien ((tv (struct timeval)))
 666                (setf (slot tv 'tv-sec) (or timeout-secs 0))
 667                (setf (slot tv 'tv-usec) (or timeout-usecs 0))
 668                (select (alien-sap (addr tv)))))
 669             (t
 670              (unless *interrupts-enabled*
 671                (note-dangerous-wait "select(2)"))
 672              (select (int-sap 0)))))))
 673
 674 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 675 ;;; to happen on one of them or to time out.
 676 (defmacro num-to-fd-set (fdset num)
 677   `(if (fixnump ,num)
 678        (progn
 679          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 680          ,@(loop for index upfrom 1 below (/ fd-setsize
 681                                              sb!vm:n-machine-word-bits)
 682              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 683        (progn
 684          ,@(loop for index upfrom 0 below (/ fd-setsize
 685                                              sb!vm:n-machine-word-bits)
 686              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 687                             (ldb (byte sb!vm:n-machine-word-bits
 688                                        ,(* index sb!vm:n-machine-word-bits))
 689                                  ,num))))))
 690
 691 (defmacro fd-set-to-num (nfds fdset)
 692   `(if (<= ,nfds sb!vm:n-machine-word-bits)
 693        (deref (slot ,fdset 'fds-bits) 0)
 694        (+ ,@(loop for index upfrom 0 below (/ fd-setsize
 695                                               sb!vm:n-machine-word-bits)
 696               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 697                             ,(* index sb!vm:n-machine-word-bits))))))
 698
 699 ;;; Examine the sets of descriptors passed as arguments to see whether
 700 ;;; they are ready for reading and writing. See the UNIX Programmer's
 701 ;;; Manual for more information.
 702 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 703   (declare (type integer nfds)
 704            (type unsigned-byte rdfds wrfds xpfds)
 705            (type (or (unsigned-byte 31) null) to-secs)
 706            (type (unsigned-byte 31) to-usecs)
 707            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 708   (with-fd-setsize (nfds)
 709     (with-alien ((tv (struct timeval))
 710                  (rdf (struct fd-set))
 711                  (wrf (struct fd-set))
 712                  (xpf (struct fd-set)))
 713       (cond (to-secs
 714              (setf (slot tv 'tv-sec) to-secs
 715                    (slot tv 'tv-usec) to-usecs))
 716             ((not *interrupts-enabled*)
 717              (note-dangerous-wait "select(2)")))
 718       (num-to-fd-set rdf rdfds)
 719       (num-to-fd-set wrf wrfds)
 720       (num-to-fd-set xpf xpfds)
 721       (macrolet ((frob (lispvar alienvar)
 722                    `(if (zerop ,lispvar)
 723                         (int-sap 0)
 724                         (alien-sap (addr ,alienvar)))))
 725         (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 726                            (* (struct fd-set)) (* (struct timeval)))
 727                  (values result
 728                          (fd-set-to-num nfds rdf)
 729                          (fd-set-to-num nfds wrf)
 730                          (fd-set-to-num nfds xpf))
 731                  nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 732                  (if to-secs (alien-sap (addr tv)) (int-sap 0)))))))
 733
 734 ;;; Lisp-side implmentations of FD_FOO macros. Abandon all hope who enters
 735 ;;; here...
 736 ;;;
 737 (defmacro fd-set (offset fd-set)
 738   (with-unique-names (word bit)
 739     `(multiple-value-bind (,word ,bit) (floor ,offset
 740                                               sb!vm:n-machine-word-bits)
 741        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 742              (logior (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
 743                                 (ash 1 ,bit))
 744                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 745
 746 (defmacro fd-clr (offset fd-set)
 747   (with-unique-names (word bit)
 748     `(multiple-value-bind (,word ,bit) (floor ,offset
 749                                               sb!vm:n-machine-word-bits)
 750        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 751              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 752                      (sb!kernel:word-logical-not
 753                       (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
 754                                  (ash 1 ,bit))))))))
 755
 756 (defmacro fd-isset (offset fd-set)
 757   (with-unique-names (word bit)
 758     `(multiple-value-bind (,word ,bit) (floor ,offset
 759                                               sb!vm:n-machine-word-bits)
 760        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 761
 762 (defmacro fd-zero (fd-set)
 763   `(progn
 764      ,@(loop for index upfrom 0 below (/ fd-setsize sb!vm:n-machine-word-bits)
 765          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 766
 767 #!-os-provides-poll
 768 (defun unix-simple-poll (fd direction to-msec)
 769   (multiple-value-bind (to-sec to-usec)
 770       (if (minusp to-msec)
 771           (values nil nil)
 772           (multiple-value-bind (to-sec to-msec2) (truncate to-msec 1000)
 773             (values to-sec (* to-msec2 1000))))
 774     (sb!unix:with-restarted-syscall (count errno)
 775       (sb!alien:with-alien ((fds (sb!alien:struct sb!unix:fd-set)))
 776         (sb!unix:fd-zero fds)
 777         (sb!unix:fd-set fd fds)
 778         (multiple-value-bind (read-fds write-fds)
 779             (ecase direction
 780               (:input
 781                (values (addr fds) nil))
 782               (:output
 783                (values nil (addr fds))))
 784           (sb!unix:unix-fast-select (1+ fd)
 785                                     read-fds write-fds nil
 786                                     to-sec to-usec)))
 787       (case count
 788         ((1) t)
 789         ((0) nil)
 790         (otherwise
 791          (error "Syscall select(2) failed on fd ~D: ~A" fd (strerror)))))))
 792 \f
 793 ;;;; sys/stat.h
 794
 795 ;;; This is a structure defined in src/runtime/wrap.c, to look
 796 ;;; basically like "struct stat" according to stat(2). It may not
 797 ;;; actually correspond to the real in-memory stat structure that the
 798 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 799 ;;; stat macros, and trying to keep Lisp code in correspondence with
 800 ;;; it is more pain than it's worth, so we just let our C runtime
 801 ;;; synthesize a nice consistent structure for us.
 802 ;;;
 803 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 804 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn't support
 805 ;;; those. We don't actually access that field anywhere, though, so
 806 ;;; until we can get 64 bit alien support it'll do. Also note that
 807 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 808 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 809 ;;; longer than 32 bits anyway, right?":-|
 810 ;;;
 811 ;;; The comment about alien and 64-bit quantities has not been kept in
 812 ;;; sync with the comment now in wrap.h (formerly wrap.c), but it's
 813 ;;; not clear whether either comment is correct.  -- RMK 2007-11-14.
 814 (define-alien-type nil
 815   (struct wrapped_stat
 816     (st-dev wst-dev-t)
 817     (st-ino ino-t)
 818     (st-mode mode-t)
 819     (st-nlink wst-nlink-t)
 820     (st-uid wst-uid-t)
 821     (st-gid wst-gid-t)
 822     (st-rdev wst-dev-t)
 823     (st-size wst-off-t)
 824     (st-blksize wst-blksize-t)
 825     (st-blocks wst-blkcnt-t)
 826     (st-atime time-t)
 827     (st-mtime time-t)
 828     (st-ctime time-t)))
 829
 830 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 831 ;;; family of Unix system calls
 832 ;;;
 833 ;;; FIXME: I think this should probably not be INLINE. However, when
 834 ;;; this was not inline, it seemed to cause memory corruption
 835 ;;; problems. My first guess is that it's a bug in the FFI code, where
 836 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 837 ;;; around a call to a function returning >10 values. But I didn't try
 838 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 839 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 840 ;;; output in the not-inlined case and see whether there's a problem,
 841 ;;; and maybe even find a fix..
 842 (declaim (inline %extract-stat-results))
 843 (defun %extract-stat-results (wrapped-stat)
 844   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 845   (values t
 846           (slot wrapped-stat 'st-dev)
 847           (slot wrapped-stat 'st-ino)
 848           (slot wrapped-stat 'st-mode)
 849           (slot wrapped-stat 'st-nlink)
 850           (slot wrapped-stat 'st-uid)
 851           (slot wrapped-stat 'st-gid)
 852           (slot wrapped-stat 'st-rdev)
 853           (slot wrapped-stat 'st-size)
 854           (slot wrapped-stat 'st-atime)
 855           (slot wrapped-stat 'st-mtime)
 856           (slot wrapped-stat 'st-ctime)
 857           (slot wrapped-stat 'st-blksize)
 858           (slot wrapped-stat 'st-blocks)))
 859
 860 ;;; Unix system calls in the stat(2) family are handled by calls to
 861 ;;; C-level wrapper functions which copy all the raw "struct stat"
 862 ;;; slots into the system-independent wrapped_stat format.
 863 ;;;    stat(2) <->  stat_wrapper()
 864 ;;;   fstat(2) <-> fstat_wrapper()
 865 ;;;   lstat(2) <-> lstat_wrapper()
 866 (defun unix-stat (name)
 867   (declare (type unix-pathname name))
 868   (with-alien ((buf (struct wrapped_stat)))
 869     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 870              (%extract-stat-results (addr buf))
 871              name (addr buf))))
 872 (defun unix-lstat (name)
 873   (declare (type unix-pathname name))
 874   (with-alien ((buf (struct wrapped_stat)))
 875     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 876              (%extract-stat-results (addr buf))
 877              name (addr buf))))
 878 (defun unix-fstat (fd)
 879   (declare (type unix-fd fd))
 880   (with-alien ((buf (struct wrapped_stat)))
 881     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 882              (%extract-stat-results (addr buf))
 883              fd (addr buf))))
 884
 885 #!-win32
 886 (defun fd-type (fd)
 887   (declare (type unix-fd fd))
 888   (let ((fmt (logand
 889               sb!unix:s-ifmt
 890               (or (with-alien ((buf (struct wrapped_stat)))
 891                     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 892                              (slot buf 'st-mode)
 893                              fd (addr buf)))
 894                   0))))
 895     (cond ((logtest sb!unix:s-ififo fmt)
 896            :fifo)
 897           ((logtest sb!unix:s-ifchr fmt)
 898            :character)
 899           ((logtest sb!unix:s-ifdir fmt)
 900            :directory)
 901           ((logtest sb!unix:s-ifblk fmt)
 902            :block)
 903           ((logtest sb!unix:s-ifreg fmt)
 904            :regular)
 905           ((logtest sb!unix:s-ifsock fmt)
 906            :socket)
 907           (t
 908            :unknown))))
 909 \f
 910 ;;;; time.h
 911
 912 ;; the POSIX.4 structure for a time value. This is like a "struct
 913 ;; timeval" but has nanoseconds instead of microseconds.
 914 #!-(or openbsd netbsd)
 915 (define-alien-type nil
 916     (struct timespec
 917             (tv-sec long)   ; seconds
 918             (tv-nsec long))) ; nanoseconds
 919
 920 ;; Just as with struct timeval, 64-bit OpenBSD has problems with the
 921 ;; above definition.  tv_sec is declared as time_t instead of long,
 922 ;; and time_t is a typedef for int.
 923 #!+(or openbsd netbsd)
 924 (define-alien-type nil
 925     (struct timespec
 926             (tv-sec time-t)  ; seconds
 927             (tv-nsec long))) ; nanoseconds
 928
 929 ;; used by other time functions
 930 (define-alien-type nil
 931     (struct tm
 932             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 933             (tm-min int)   ; Minutes.   [0-59]
 934             (tm-hour int)  ; Hours.     [0-23]
 935             (tm-mday int)  ; Day.       [1-31]
 936             (tm-mon int)   ; Month.     [0-11]
 937             (tm-year int)  ; Year - 1900.
 938             (tm-wday int)  ; Day of week. [0-6]
 939             (tm-yday int)  ; Days in year. [0-365]
 940             (tm-isdst int) ; DST.       [-1/0/1]
 941             (tm-gmtoff long) ;  Seconds east of UTC.
 942             (tm-zone c-string))) ; Timezone abbreviation.
 943
 944 (define-alien-routine get-timezone sb!alien:void
 945   (when time-t :in)
 946   (seconds-west sb!alien:int :out)
 947   (daylight-savings-p sb!alien:boolean :out))
 948
 949 #!-win32
 950 (defun nanosleep (secs nsecs)
 951   (with-alien ((req (struct timespec))
 952                (rem (struct timespec)))
 953     (setf (slot req 'tv-sec) secs
 954           (slot req 'tv-nsec) nsecs)
 955     (loop while (and (eql sb!unix:eintr
 956                           (nth-value 1
 957                                      (int-syscall ("nanosleep" (* (struct timespec))
 958                                                                (* (struct timespec)))
 959                                                   (addr req) (addr rem))))
 960                      ;; KLUDGE: On Darwin, if an interrupt cases nanosleep to
 961                      ;; take longer than the requested time, the call will
 962                      ;; return with EINT and (unsigned)-1 seconds in the
 963                      ;; remainder timespec, which would cause us to enter
 964                      ;; nanosleep again for ~136 years. So, we check that the
 965                      ;; remainder time is actually decreasing.
 966                      ;;
 967                      ;; It would be neat to do this bit of defensive
 968                      ;; programming on all platforms, but unfortunately on
 969                      ;; Linux, REM can be a little higher than REQ if the
 970                      ;; nanosleep() call is interrupted quickly enough,
 971                      ;; probably due to the request being rounded up to the
 972                      ;; nearest HZ. This would cause the sleep to return way
 973                      ;; too early.
 974                      #!+darwin
 975                      (let ((rem-sec (slot rem 'tv-sec))
 976                            (rem-nsec (slot rem 'tv-nsec)))
 977                        (when (or (> secs rem-sec)
 978                                  (and (= secs rem-sec) (>= nsecs rem-nsec)))
 979                          ;; Update for next round.
 980                          (setf secs  rem-sec
 981                                nsecs rem-nsec)
 982                          t)))
 983           do (setf (slot req 'tv-sec) (slot rem 'tv-sec)
 984                    (slot req 'tv-nsec) (slot rem 'tv-nsec)))))
 985
 986 (defun unix-get-seconds-west (secs)
 987   (multiple-value-bind (ignore seconds dst) (get-timezone secs)
 988     (declare (ignore ignore) (ignore dst))
 989     (values seconds)))
 990 \f
 991 ;;;; sys/time.h
 992
 993 ;;; Structure crudely representing a timezone. KLUDGE: This is
 994 ;;; obsolete and should never be used.
 995 (define-alien-type nil
 996   (struct timezone
 997     (tz-minuteswest int)                ; minutes west of Greenwich
 998     (tz-dsttime int)))                  ; type of dst correction
 999 \f
1000
1001 ;; Type of the second argument to `getitimer' and
1002 ;; the second and third arguments `setitimer'.
1003 (define-alien-type nil
1004   (struct itimerval
1005     (it-interval (struct timeval))      ; timer interval
1006     (it-value (struct timeval))))       ; current value
1007
1008 (defconstant itimer-real 0)
1009 (defconstant itimer-virtual 1)
1010 (defconstant itimer-prof 2)
1011
1012 #!-win32
1013 (defun unix-getitimer (which)
1014   "Unix-getitimer returns the INTERVAL and VALUE slots of one of
1015    three system timers (:real :virtual or :profile). On success,
1016    unix-getitimer returns 5 values,
1017    T, it-interval-secs, it-interval-usec, it-value-secs, it-value-usec."
1018   (declare (type (member :real :virtual :profile) which)
1019            (values t
1020                    (unsigned-byte 29) (mod 1000000)
1021                    (unsigned-byte 29) (mod 1000000)))
1022   (let ((which (ecase which
1023                  (:real itimer-real)
1024                  (:virtual itimer-virtual)
1025                  (:profile itimer-prof))))
1026     (with-alien ((itv (struct itimerval)))
1027       (syscall* ("getitimer" int (* (struct itimerval)))
1028                 (values t
1029                         (slot (slot itv 'it-interval) 'tv-sec)
1030                         (slot (slot itv 'it-interval) 'tv-usec)
1031                         (slot (slot itv 'it-value) 'tv-sec)
1032                         (slot (slot itv 'it-value) 'tv-usec))
1033                 which (alien-sap (addr itv))))))
1034
1035 #!-win32
1036 (defun unix-setitimer (which int-secs int-usec val-secs val-usec)
1037   " Unix-setitimer sets the INTERVAL and VALUE slots of one of
1038    three system timers (:real :virtual or :profile). A SIGALRM signal
1039    will be delivered VALUE <seconds+microseconds> from now. INTERVAL,
1040    when non-zero, is <seconds+microseconds> to be loaded each time
1041    the timer expires. Setting INTERVAL and VALUE to zero disables
1042    the timer. See the Unix man page for more details. On success,
1043    unix-setitimer returns the old contents of the INTERVAL and VALUE
1044    slots as in unix-getitimer."
1045   (declare (type (member :real :virtual :profile) which)
1046            (type (unsigned-byte 29) int-secs val-secs)
1047            (type (integer 0 (1000000)) int-usec val-usec)
1048            (values t
1049                    (unsigned-byte 29) (mod 1000000)
1050                    (unsigned-byte 29) (mod 1000000)))
1051   (let ((which (ecase which
1052                  (:real itimer-real)
1053                  (:virtual itimer-virtual)
1054                  (:profile itimer-prof))))
1055     (with-alien ((itvn (struct itimerval))
1056                  (itvo (struct itimerval)))
1057       (setf (slot (slot itvn 'it-interval) 'tv-sec ) int-secs
1058             (slot (slot itvn 'it-interval) 'tv-usec) int-usec
1059             (slot (slot itvn 'it-value   ) 'tv-sec ) val-secs
1060             (slot (slot itvn 'it-value   ) 'tv-usec) val-usec)
1061       (syscall* ("setitimer" int (* (struct timeval))(* (struct timeval)))
1062                 (values t
1063                         (slot (slot itvo 'it-interval) 'tv-sec)
1064                         (slot (slot itvo 'it-interval) 'tv-usec)
1065                         (slot (slot itvo 'it-value) 'tv-sec)
1066                         (slot (slot itvo 'it-value) 'tv-usec))
1067                 which (alien-sap (addr itvn))(alien-sap (addr itvo))))))
1068
1069 \f
1070 ;;; FIXME: Many Unix error code definitions were deleted from the old
1071 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
1072 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
1073 ;;; unused symbols in package exports, but if I don't, there are
1074 ;;; enough of them all in one place here that they should probably be
1075 ;;; removed by hand.
1076 \f
1077 (defconstant micro-seconds-per-internal-time-unit
1078   (/ 1000000 sb!xc:internal-time-units-per-second))
1079
1080 ;;; UNIX specific code, that has been cleanly separated from the
1081 ;;; Windows build.
1082 #!-win32
1083 (progn
1084
1085   #!-sb-fluid (declaim (inline get-time-of-day))
1086   (defun get-time-of-day ()
1087     "Return the number of seconds and microseconds since the beginning of
1088 the UNIX epoch (January 1st 1970.)"
1089     #!+darwin
1090     (with-alien ((tv (struct timeval)))
1091       ;; CLH: FIXME! This seems to be a MacOS bug, but on x86-64/darwin,
1092       ;; gettimeofday occasionally fails. passing in a null pointer for the
1093       ;; timezone struct seems to work around the problem. NS notes: Darwin
1094       ;; manpage says the timezone is not used anymore in their implementation
1095       ;; at all.
1096       (syscall* ("gettimeofday" (* (struct timeval))
1097                                 (* (struct timezone)))
1098                 (values (slot tv 'tv-sec)
1099                         (slot tv 'tv-usec))
1100                 (addr tv)
1101                 nil))
1102     #!-(and x86-64 darwin)
1103     (with-alien ((tv (struct timeval))
1104                  (tz (struct timezone)))
1105       (syscall* ("gettimeofday" (* (struct timeval))
1106                                 (* (struct timezone)))
1107                 (values (slot tv 'tv-sec)
1108                         (slot tv 'tv-usec))
1109                 (addr tv)
1110                 (addr tz))))
1111
1112   (declaim (inline system-internal-run-time
1113                    system-real-time-values))
1114
1115   (defun system-real-time-values ()
1116     (multiple-value-bind (sec usec) (get-time-of-day)
1117       (declare (type (unsigned-byte 32) sec usec))
1118       (values sec (truncate usec micro-seconds-per-internal-time-unit))))
1119
1120   ;; There are two optimizations here that actually matter (on 32-bit
1121   ;; systems): substract the epoch from seconds and milliseconds
1122   ;; separately, as those should remain fixnums for the first 17 years
1123   ;; or so of runtime. Also, avoid doing consing a new bignum if the
1124   ;; result would be = to the last result given.
1125   ;;
1126   ;; Note: the next trick would be to spin a separate thread to update
1127   ;; a global value once per internal tick, so each individual call to
1128   ;; get-internal-real-time would be just a memory read... but that is
1129   ;; probably best left for user-level code. ;)
1130   ;;
1131   ;; Thanks to James Anderson for the optimization hint.
1132   ;;
1133   ;; Yes, it is possible to a computation to be GET-INTERNAL-REAL-TIME
1134   ;; bound.
1135   ;;
1136   ;; --NS 2007-04-05
1137   (let ((e-sec 0)
1138         (e-msec 0)
1139         (c-sec 0)
1140         (c-msec 0)
1141         (now 0))
1142     (declare (type (unsigned-byte 32) e-sec c-sec)
1143              (type fixnum e-msec c-msec)
1144              (type unsigned-byte now))
1145     (defun reinit-internal-real-time ()
1146       (setf (values e-sec e-msec) (system-real-time-values)
1147             c-sec 0
1148             c-msec 0))
1149     ;; If two threads call this at the same time, we're still safe, I
1150     ;; believe, as long as NOW is updated before either of C-MSEC or
1151     ;; C-SEC. Same applies to interrupts. --NS
1152     ;;
1153     ;; I believe this is almost correct with x86/x86-64 cache
1154     ;; coherency, but if the new value of C-SEC, C-MSEC can become
1155     ;; visible to another CPU without NOW doing the same then it's
1156     ;; unsafe. It's `almost' correct on x86 because writes by other
1157     ;; processors may become visible in any order provided transitity
1158     ;; holds. With at least three cpus, C-MSEC and C-SEC may be from
1159     ;; different threads and an incorrect value may be returned.
1160     ;; Considering that this failure is not detectable by the caller -
1161     ;; it looks like time passes a bit slowly - and that it should be
1162     ;; an extremely rare occurance I'm inclinded to leave it as it is.
1163     ;; --MG
1164     (defun get-internal-real-time ()
1165       (multiple-value-bind (sec msec) (system-real-time-values)
1166         (unless (and (= msec c-msec) (= sec c-sec))
1167           (setf now (+ (* (- sec e-sec)
1168                           sb!xc:internal-time-units-per-second)
1169                        (- msec e-msec))
1170                 c-msec msec
1171                 c-sec sec))
1172         now)))
1173
1174   (defun system-internal-run-time ()
1175     (multiple-value-bind (ignore utime-sec utime-usec stime-sec stime-usec)
1176         (unix-fast-getrusage rusage_self)
1177       (declare (ignore ignore)
1178                (type (unsigned-byte 31) utime-sec stime-sec)
1179                ;; (Classic CMU CL had these (MOD 1000000) instead, but
1180                ;; at least in Linux 2.2.12, the type doesn't seem to
1181                ;; be documented anywhere and the observed behavior is
1182                ;; to sometimes return 1000000 exactly.)
1183                (type (integer 0 1000000) utime-usec stime-usec))
1184       (let ((result (+ (* (+ utime-sec stime-sec)
1185                           sb!xc:internal-time-units-per-second)
1186                        (floor (+ utime-usec
1187                                  stime-usec
1188                                  (floor micro-seconds-per-internal-time-unit 2))
1189                               micro-seconds-per-internal-time-unit))))
1190         result))))
1191 \f
1192 ;;; FIXME, KLUDGE: GET-TIME-OF-DAY used to be UNIX-GETTIMEOFDAY, and had a
1193 ;;; primary return value indicating sucess, and also returned timezone
1194 ;;; information -- though the timezone data was not there on Darwin.
1195 ;;; Now we have GET-TIME-OF-DAY, but it turns out that despite SB-UNIX being
1196 ;;; an implementation package UNIX-GETTIMEOFDAY has users in the wild.
1197 ;;; So we're stuck with it for a while -- maybe delete it towards the end
1198 ;;; of 2009.
1199 (defun unix-gettimeofday ()
1200   (multiple-value-bind (sec usec) (get-time-of-day)
1201     (values t sec usec nil nil)))
1202 \f
1203 ;;;; opendir, readdir, closedir, and dirent-name
1204
1205 (declaim (inline unix-opendir))
1206 (defun unix-opendir (namestring &optional (errorp t))
1207   (let ((dir (alien-funcall
1208               (extern-alien "sb_opendir"
1209                             (function system-area-pointer c-string))
1210               namestring)))
1211     (if (zerop (sap-int dir))
1212         (when errorp (simple-perror
1213                       (format nil "Error opening directory ~S"
1214                               namestring)))
1215         dir)))
1216
1217 (declaim (inline unix-readdir))
1218 (defun unix-readdir (dir &optional (errorp t) namestring)
1219   (let ((ent (alien-funcall
1220               (extern-alien "sb_readdir"
1221                             (function system-area-pointer system-area-pointer))
1222                             dir)))
1223     (if (zerop (sap-int ent))
1224         (when errorp (simple-perror
1225                       (format nil "Error reading directory entry~@[ from ~S~]"
1226                               namestring)))
1227         ent)))
1228
1229 (declaim (inline unix-closedir))
1230 (defun unix-closedir (dir &optional (errorp t) namestring)
1231   (let ((r (alien-funcall
1232             (extern-alien "sb_closedir" (function int system-area-pointer))
1233             dir)))
1234     (if (minusp r)
1235         (when errorp (simple-perror
1236                       (format nil "Error closing directory~@[ ~S~]"
1237                               namestring)))
1238         r)))
1239
1240 (declaim (inline unix-dirent-name))
1241 (defun unix-dirent-name (ent)
1242   (alien-funcall
1243    (extern-alien "sb_dirent_name" (function c-string system-area-pointer))
1244    ent))
1245 \f
1246 ;;;; A magic constant for wait3().
1247 ;;;;
1248 ;;;; FIXME: This used to be defined in run-program.lisp as
1249 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
1250 ;;;; According to some of the man pages, the #o177 is part of the API
1251 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
1252 ;;;; the headers that may or may not be the same thing. To be
1253 ;;;; investigated. -- CSR, 2002-03-25
1254 (defconstant wstopped #o177)