src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 ;;; Given a C-level zero-terminated array of C strings, return a
  31 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  32 (defun c-strings->string-list (c-strings)
  33   (declare (type (alien (* c-string)) c-strings))
  34   (let ((reversed-result nil))
  35     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  36       (declare (type index i))
  37       (let ((c-string (deref c-strings i)))
  38         (if c-string
  39             (push c-string reversed-result)
  40             (return (nreverse reversed-result)))))))
  41 \f
  42 ;;;; Lisp types used by syscalls
  43
  44 (deftype unix-pathname () 'simple-string)
  45 (deftype unix-fd () `(integer 0 ,sb!xc:most-positive-fixnum))
  46
  47 (deftype unix-file-mode () '(unsigned-byte 32))
  48 (deftype unix-pid () '(unsigned-byte 32))
  49 (deftype unix-uid () '(unsigned-byte 32))
  50 (deftype unix-gid () '(unsigned-byte 32))
  51 \f
  52 ;;;; system calls
  53
  54 (/show0 "unix.lisp 74")
  55
  56 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  57 ;;; macros in this file, are only used in this file, and could be
  58 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  59 ;;;
  60 ;;; SB-EXECUTABLE, at least, uses one of these macros; other libraries
  61 ;;; and programs have been known to use them as well.  Perhaps they
  62 ;;; should live in SB-SYS or even SB-EXT?
  63
  64 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  65   `(locally
  66     (declare (optimize (sb!c::float-accuracy 0)))
  67     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69       (if (minusp result)
  70           (values nil (get-errno))
  71           ,success-form))))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(locally
  78     (declare (optimize (sb!c::float-accuracy 0)))
  79     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  80                                  ,@args)))
  81       (if (minusp result)
  82           (error "Syscall ~A failed: ~A" ,name (strerror))
  83           ,success-form))))
  84
  85 (defmacro int-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  87
  88 (defmacro with-restarted-syscall ((&optional (value (gensym))
  89                                              (errno (gensym)))
  90                                   syscall-form &rest body)
  91   #!+sb-doc
  92   "Evaluate BODY with VALUE and ERRNO bound to the return values of
  93 SYSCALL-FORM. Repeat evaluation of SYSCALL-FORM if it is interrupted."
  94   `(let (,value ,errno)
  95      (loop (multiple-value-setq (,value ,errno)
  96              ,syscall-form)
  97         (unless #!-win32 (eql ,errno sb!unix:eintr) #!+win32 nil
  98           (return (values ,value ,errno))))
  99      ,@body))
 100
 101 (defmacro void-syscall ((name &rest arg-types) &rest args)
 102   `(syscall (,name ,@arg-types) (values t 0) ,@args))
 103
 104 #!+win32
 105 (progn
 106   (defconstant espipe 29))
 107 \f
 108 ;;;; hacking the Unix environment
 109
 110 #!-win32
 111 (define-alien-routine ("getenv" posix-getenv) c-string
 112   "Return the \"value\" part of the environment string \"name=value\" which
 113 corresponds to NAME, or NIL if there is none."
 114   (name (c-string :not-null t)))
 115 \f
 116 ;;; from stdio.h
 117
 118 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 119 ;;; error code is returned if an error occurs.
 120 #!-win32
 121 (defun unix-rename (name1 name2)
 122   (declare (type unix-pathname name1 name2))
 123   (void-syscall ("rename" (c-string :not-null t)
 124                           (c-string :not-null t))
 125                 name1 name2))
 126 \f
 127 ;;; from sys/types.h and gnu/types.h
 128
 129 (/show0 "unix.lisp 220")
 130
 131 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 132 ;;; like this unless we have extreme provocation. Reading directories
 133 ;;; is not extreme enough, since it doesn't need to be blindingly
 134 ;;; fast: we can just implement those functions in C as a wrapper
 135 ;;; layer.
 136 (define-alien-type fd-mask unsigned-long)
 137
 138 (define-alien-type nil
 139   (struct fd-set
 140           (fds-bits (array fd-mask #.(/ fd-setsize
 141                                         sb!vm:n-machine-word-bits)))))
 142
 143 (/show0 "unix.lisp 304")
 144 \f
 145 \f
 146 ;;;; fcntl.h
 147 ;;;;
 148 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 149
 150 ;;; Open the file whose pathname is specified by PATH for reading
 151 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 152 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 153 ;;;
 154 ;;; If the O_CREAT flag is specified, then the file is created with a
 155 ;;; permission of argument MODE if the file doesn't exist. An integer
 156 ;;; file descriptor is returned by UNIX-OPEN.
 157 (defun unix-open (path flags mode)
 158   (declare (type unix-pathname path)
 159            (type fixnum flags)
 160            (type unix-file-mode mode))
 161   (with-restarted-syscall (value errno)
 162     (int-syscall ("open" c-string int int)
 163                  path
 164                  (logior #!+win32 o_binary
 165                          #!+largefile o_largefile
 166                          flags)
 167                  mode)))
 168
 169 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 170 ;;; associated with it.
 171 (/show0 "unix.lisp 391")
 172 (defun unix-close (fd)
 173   (declare (type unix-fd fd))
 174   (void-syscall ("close" int) fd))
 175 \f
 176 ;;;; stdlib.h
 177
 178 ;;; There are good reasons to implement some OPEN options with an
 179 ;;; mkstemp(3)-like routine, but we don't do that yet.  Instead, this
 180 ;;; function is used only to make a temporary file for RUN-PROGRAM.
 181 ;;; sb_mkstemp() is a wrapper that lives in src/runtime/wrap.c.  Since
 182 ;;; SUSv3 mkstemp() doesn't specify the mode of the created file and
 183 ;;; since we have to implement most of this ourselves for Windows
 184 ;;; anyway, it seems worthwhile to depart from the mkstemp()
 185 ;;; specification by taking a mode to use when creating the new file.
 186 (defun sb-mkstemp (template-string mode)
 187   (declare (type string template-string)
 188            (type unix-file-mode mode))
 189   (let ((template-buffer (string-to-octets template-string :null-terminate t)))
 190     (with-pinned-objects (template-buffer)
 191       (let ((fd (alien-funcall (extern-alien "sb_mkstemp"
 192                                              (function int (* char) int))
 193                                (vector-sap template-buffer)
 194                                mode)))
 195         (if (minusp fd)
 196             (values nil (get-errno))
 197             (values fd (octets-to-string template-buffer)))))))
 198 \f
 199 ;;;; timebits.h
 200
 201 ;; A time value that is accurate to the nearest
 202 ;; microsecond but also has a range of years.
 203 ;; CLH: Note that tv-usec used to be a time-t, but that this seems
 204 ;; problematic on Darwin x86-64 (and wrong). Trying suseconds-t.
 205 #!-(or win32 openbsd netbsd)
 206 (define-alien-type nil
 207   (struct timeval
 208           (tv-sec time-t)           ; seconds
 209           (tv-usec suseconds-t)))   ; and microseconds
 210
 211 ;; The above definition doesn't work on 64-bit OpenBSD platforms.
 212 ;; Both tv_sec and tv_usec are declared as long instead of time_t, and
 213 ;; time_t is a typedef for int.
 214 #!+(or openbsd netbsd)
 215 (define-alien-type nil
 216   (struct timeval
 217           (tv-sec long)             ; seconds
 218           (tv-usec long)))          ; and microseconds
 219
 220 #!+win32
 221 (define-alien-type nil
 222   (struct timeval
 223           (tv-sec time-t)           ; seconds
 224           (tv-usec long)))          ; and microseconds
 225 \f
 226 ;;;; resourcebits.h
 227
 228 (defconstant rusage_self 0) ; the calling process
 229 (defconstant rusage_children -1) ; terminated child processes
 230 (defconstant rusage_both -2)
 231
 232 (define-alien-type nil
 233   (struct rusage
 234     (ru-utime (struct timeval))     ; user time used
 235     (ru-stime (struct timeval))     ; system time used.
 236     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 237     (ru-ixrss long)                 ; integral shared memory size
 238     (ru-idrss long)                 ; integral unshared data size
 239     (ru-isrss long)                 ; integral unshared stack size
 240     (ru-minflt long)                ; page reclaims
 241     (ru-majflt long)                ; page faults
 242     (ru-nswap long)                 ; swaps
 243     (ru-inblock long)               ; block input operations
 244     (ru-oublock long)               ; block output operations
 245     (ru-msgsnd long)                ; messages sent
 246     (ru-msgrcv long)                ; messages received
 247     (ru-nsignals long)              ; signals received
 248     (ru-nvcsw long)                 ; voluntary context switches
 249     (ru-nivcsw long)))              ; involuntary context switches
 250 \f
 251 ;;;; unistd.h
 252
 253 ;;; Given a file path (a string) and one of four constant modes,
 254 ;;; return T if the file is accessible with that mode and NIL if not.
 255 ;;; When NIL, also return an errno value with NIL which tells why the
 256 ;;; file was not accessible.
 257 ;;;
 258 ;;; The access modes are:
 259 ;;;   r_ok     Read permission.
 260 ;;;   w_ok     Write permission.
 261 ;;;   x_ok     Execute permission.
 262 ;;;   f_ok     Presence of file.
 263
 264 ;;; In Windows, the MODE argument to access is defined in terms of
 265 ;;; literal magic numbers---there are no constants to grovel.  X_OK
 266 ;;; is not defined.
 267 #!+win32
 268 (progn
 269   (defconstant f_ok 0)
 270   (defconstant w_ok 2)
 271   (defconstant r_ok 4))
 272
 273 (defun unix-access (path mode)
 274   (declare (type unix-pathname path)
 275            (type (mod 8) mode))
 276   (void-syscall ("access" c-string int) path mode))
 277
 278 ;;; values for the second argument to UNIX-LSEEK
 279 (defconstant l_set 0) ; to set the file pointer
 280 (defconstant l_incr 1) ; to increment the file pointer
 281 (defconstant l_xtnd 2) ; to extend the file size
 282
 283 ;;; Is a stream interactive?
 284 (defun unix-isatty (fd)
 285   (declare (type unix-fd fd))
 286   (int-syscall ("isatty" int) fd))
 287
 288 (defun unix-lseek (fd offset whence)
 289   "Unix-lseek accepts a file descriptor and moves the file pointer by
 290    OFFSET octets.  Whence can be any of the following:
 291
 292    L_SET        Set the file pointer.
 293    L_INCR       Increment the file pointer.
 294    L_XTND       Extend the file size.
 295   "
 296   (declare (type unix-fd fd)
 297            (type (integer 0 2) whence))
 298   (let ((result (alien-funcall (extern-alien #!-largefile "lseek"
 299                                              #!+largefile "lseek_largefile"
 300                                              (function off-t int off-t int))
 301                  fd offset whence)))
 302     (if (minusp result)
 303         (values nil (get-errno))
 304       (values result 0))))
 305
 306 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 307 ;;; It attempts to read len bytes from the device associated with fd
 308 ;;; and store them into the buffer. It returns the actual number of
 309 ;;; bytes read.
 310
 311 #!-sb!fluid
 312 (declaim (maybe-inline unix-read))
 313
 314 (defun unix-read (fd buf len)
 315   (declare (type unix-fd fd)
 316            (type (unsigned-byte 32) len))
 317   (int-syscall ("read" int (* char) int) fd buf len))
 318
 319 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 320 ;;; length to write. It attempts to write len bytes to the device
 321 ;;; associated with fd from the buffer starting at offset. It returns
 322 ;;; the actual number of bytes written.
 323 (defun unix-write (fd buf offset len)
 324   (declare (type unix-fd fd)
 325            (type (unsigned-byte 32) offset len))
 326   (flet ((%write (sap)
 327            (declare (system-area-pointer sap))
 328            (int-syscall ("write" int (* char) int)
 329                         fd
 330                         (with-alien ((ptr (* char) sap))
 331                           (addr (deref ptr offset)))
 332                         len)))
 333     (etypecase buf
 334       ((simple-array * (*))
 335        (with-pinned-objects (buf)
 336          (%write (vector-sap buf))))
 337       (system-area-pointer
 338        (%write buf)))))
 339
 340 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 341 ;;; output pipe. Return two values: if no error occurred the first
 342 ;;; value is the pipe to be read from and the second is can be written
 343 ;;; to. If an error occurred the first value is NIL and the second the
 344 ;;; unix error code.
 345 #!-win32
 346 (defun unix-pipe ()
 347   (with-alien ((fds (array int 2)))
 348     (syscall ("pipe" (* int))
 349              (values (deref fds 0) (deref fds 1))
 350              (cast fds (* int)))))
 351 #!+win32
 352 (defun msvcrt-raw-pipe (fds size mode)
 353   (syscall ("_pipe" (* int) int int)
 354            (values (deref fds 0) (deref fds 1))
 355            (cast fds (* int)) size mode))
 356 #!+win32
 357 (defun unix-pipe ()
 358   (with-alien ((fds (array int 2)))
 359     (msvcrt-raw-pipe fds 256 o_binary)))
 360
 361 ;; Windows mkdir() doesn't take the mode argument. It's cdecl, so we could
 362 ;; actually call it passing the mode argument, but some sharp-eyed reader
 363 ;; would put five and twenty-seven together and ask us about it, so...
 364 ;;    -- AB, 2005-12-27
 365 #!-win32
 366 (defun unix-mkdir (name mode)
 367   (declare (type unix-pathname name)
 368            (type unix-file-mode mode)
 369            #!+win32 (ignore mode))
 370   (void-syscall ("mkdir" c-string #!-win32 int) name #!-win32 mode))
 371
 372 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 373 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 374 (defun newcharstar-string (newcharstar)
 375   (declare (type (alien (* char)) newcharstar))
 376   (if (null-alien newcharstar)
 377       nil
 378       (prog1
 379           (cast newcharstar c-string)
 380         (free-alien newcharstar))))
 381
 382 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 383 ;;; style returned by getcwd() (no trailing slash character).
 384 #!-win32
 385 (defun posix-getcwd ()
 386   ;; This implementation relies on a BSD/Linux extension to getcwd()
 387   ;; behavior, automatically allocating memory when a null buffer
 388   ;; pointer is used. On a system which doesn't support that
 389   ;; extension, it'll have to be rewritten somehow.
 390   ;;
 391   ;; SunOS and OSF/1 provide almost as useful an extension: if given a null
 392   ;; buffer pointer, it will automatically allocate size space. The
 393   ;; KLUDGE in this solution arises because we have just read off
 394   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 395   ;; a constant. Going the grovel_headers route doesn't seem to be
 396   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 397   ;; unistd.h.
 398   ;;
 399   ;; FIXME: The (,stub,) nastiness produces an error message about a
 400   ;; comma not inside a backquote. This error has absolutely nothing
 401   ;; to do with the actual meaning of the error (and little to do with
 402   ;; its location, either).
 403   #!-(or linux openbsd freebsd netbsd sunos osf1 darwin hpux win32) (,stub,)
 404   #!+(or linux openbsd freebsd netbsd sunos osf1 darwin hpux win32)
 405   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 406                                                        (function (* char)
 407                                                                  (* char)
 408                                                                  size-t))
 409                                          nil
 410                                          #!+(or linux openbsd freebsd netbsd darwin win32) 0
 411                                          #!+(or sunos osf1 hpux) 1025))
 412       (simple-perror "getcwd")))
 413
 414 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 415 ;;; by a slash character.
 416 (defun posix-getcwd/ ()
 417   (concatenate 'string (posix-getcwd) "/"))
 418
 419 ;;; Duplicate an existing file descriptor (given as the argument) and
 420 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 421 ;;; number are returned.
 422 (defun unix-dup (fd)
 423   (declare (type unix-fd fd))
 424   (int-syscall ("dup" int) fd))
 425
 426 ;;; Terminate the current process with an optional error code. If
 427 ;;; successful, the call doesn't return. If unsuccessful, the call
 428 ;;; returns NIL and an error number.
 429 (defun unix-exit (&optional (code 0))
 430   (declare (type (signed-byte 32) code))
 431   (void-syscall ("exit" int) code))
 432
 433 ;;; Return the process id of the current process.
 434 (define-alien-routine ("getpid" unix-getpid) int)
 435
 436 ;;; Return the real user id associated with the current process.
 437 #!-win32
 438 (define-alien-routine ("getuid" unix-getuid) int)
 439
 440 ;;; Translate a user id into a login name.
 441 #!-win32
 442 (defun uid-username (uid)
 443   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 444                                                        (function (* char) int))
 445                                          uid))
 446       (error "found no match for Unix uid=~S" uid)))
 447
 448 ;;; Return the namestring of the home directory, being careful to
 449 ;;; include a trailing #\/
 450 #!-win32
 451 (progn
 452   (defun uid-homedir (uid)
 453     (or (newcharstar-string (alien-funcall (extern-alien "uid_homedir"
 454                                                          (function (* char) int))
 455                                            uid))
 456         (error "failed to resolve home directory for Unix uid=~S" uid)))
 457
 458   (defun user-homedir (uid)
 459     (or (newcharstar-string (alien-funcall (extern-alien "user_homedir"
 460                                                          (function (* char) c-string))
 461                                            uid))
 462         (error "failed to resolve home directory for Unix uid=~S" uid))))
 463
 464 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 465 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 466 ;;; failure.
 467 #!-win32
 468 (defun unix-readlink (path)
 469   (declare (type unix-pathname path))
 470   (with-alien ((ptr (* char)
 471                     (alien-funcall (extern-alien
 472                                     "wrapped_readlink"
 473                                     (function (* char) c-string))
 474                                    path)))
 475     (if (null-alien ptr)
 476         (values nil (get-errno))
 477         (multiple-value-prog1
 478             (values (with-alien ((c-string c-string ptr)) c-string)
 479                     nil)
 480           (free-alien ptr)))))
 481 #!+win32
 482 ;; Win32 doesn't do links, but something likes to call this anyway.
 483 ;; Something in this file, no less. But it only takes one result, so...
 484 (defun unix-readlink (path)
 485   (declare (ignore path))
 486   nil)
 487
 488 (defun unix-realpath (path)
 489   (declare (type unix-pathname path))
 490   (with-alien ((ptr (* char)
 491                     (alien-funcall (extern-alien
 492                                     "sb_realpath"
 493                                     (function (* char) c-string))
 494                                    path)))
 495     (if (null-alien ptr)
 496         (values nil (get-errno))
 497         (multiple-value-prog1
 498             (values (with-alien ((c-string c-string ptr)) c-string)
 499                     nil)
 500           (free-alien ptr)))))
 501
 502 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 503 ;;; name and the file if this is the last link.
 504 (defun unix-unlink (name)
 505   (declare (type unix-pathname name))
 506   (void-syscall ("unlink" c-string) name))
 507
 508 ;;; Return the name of the host machine as a string.
 509 #!-win32
 510 (defun unix-gethostname ()
 511   (with-alien ((buf (array char 256)))
 512     (syscall ("gethostname" (* char) int)
 513              (cast buf c-string)
 514              (cast buf (* char)) 256)))
 515
 516 #!-win32
 517 (defun unix-setsid ()
 518   (int-syscall ("setsid")))
 519
 520 ;;;; sys/ioctl.h
 521
 522 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 523 ;;; descriptors. See the UNIX Programmer's Manual for more
 524 ;;; information.
 525 #!-win32
 526 (defun unix-ioctl (fd cmd arg)
 527   (declare (type unix-fd fd)
 528            (type (signed-byte 32) cmd))
 529   (void-syscall ("ioctl" int int (* char)) fd cmd arg))
 530 \f
 531 ;;;; sys/resource.h
 532
 533 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 534 ;;;
 535 ;;; This is like getrusage(2), except it returns only the system and
 536 ;;; user time, and returns the seconds and microseconds as separate
 537 ;;; values.
 538 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 539 #!-win32
 540 (defun unix-fast-getrusage (who)
 541   (declare (values (member t)
 542                    (unsigned-byte 31) (integer 0 1000000)
 543                    (unsigned-byte 31) (integer 0 1000000)))
 544   (with-alien ((usage (struct rusage)))
 545     (syscall* ("getrusage" int (* (struct rusage)))
 546               (values t
 547                       (slot (slot usage 'ru-utime) 'tv-sec)
 548                       (slot (slot usage 'ru-utime) 'tv-usec)
 549                       (slot (slot usage 'ru-stime) 'tv-sec)
 550                       (slot (slot usage 'ru-stime) 'tv-usec))
 551               who (addr usage))))
 552
 553 ;;; Return information about the resource usage of the process
 554 ;;; specified by WHO. WHO can be either the current process
 555 ;;; (rusage_self) or all of the terminated child processes
 556 ;;; (rusage_children). NIL and an error number is returned if the call
 557 ;;; fails.
 558 #!-win32
 559 (defun unix-getrusage (who)
 560   (with-alien ((usage (struct rusage)))
 561     (syscall ("getrusage" int (* (struct rusage)))
 562               (values t
 563                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 564                          (slot (slot usage 'ru-utime) 'tv-usec))
 565                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 566                          (slot (slot usage 'ru-stime) 'tv-usec))
 567                       (slot usage 'ru-maxrss)
 568                       (slot usage 'ru-ixrss)
 569                       (slot usage 'ru-idrss)
 570                       (slot usage 'ru-isrss)
 571                       (slot usage 'ru-minflt)
 572                       (slot usage 'ru-majflt)
 573                       (slot usage 'ru-nswap)
 574                       (slot usage 'ru-inblock)
 575                       (slot usage 'ru-oublock)
 576                       (slot usage 'ru-msgsnd)
 577                       (slot usage 'ru-msgrcv)
 578                       (slot usage 'ru-nsignals)
 579                       (slot usage 'ru-nvcsw)
 580                       (slot usage 'ru-nivcsw))
 581               who (addr usage))))
 582 \f
 583 (defvar *on-dangerous-wait* :warn)
 584
 585 ;;; Calling select in a bad place can hang in a nasty manner, so it's better
 586 ;;; to have some way to detect these.
 587 (defun note-dangerous-wait (type)
 588   (let ((action *on-dangerous-wait*)
 589         (*on-dangerous-wait* nil))
 590     (case action
 591       (:warn
 592        (warn "Starting a ~A without a timeout while interrupts are ~
 593              disabled."
 594              type))
 595       (:error
 596        (error "Starting a ~A without a timeout while interrupts are ~
 597               disabled."
 598               type))
 599       (:backtrace
 600        (format *debug-io*
 601                "~&=== Starting a ~A without a timeout while interrupts are disabled. ===~%"
 602                type)
 603        (sb!debug:backtrace)))
 604     nil))
 605 \f
 606 ;;;; poll.h
 607 #!+os-provides-poll
 608 (progn
 609   (define-alien-type nil
 610       (struct pollfd
 611               (fd      int)
 612               (events  short)           ; requested events
 613               (revents short)))         ; returned events
 614
 615   (defun unix-simple-poll (fd direction to-msec)
 616     (declare (fixnum fd to-msec))
 617     (when (and (minusp to-msec) (not *interrupts-enabled*))
 618       (note-dangerous-wait "poll(2)"))
 619     (let ((events (ecase direction
 620                     (:input (logior pollin pollpri))
 621                     (:output pollout))))
 622       (with-alien ((fds (struct pollfd)))
 623         (with-restarted-syscall (count errno)
 624           (progn
 625             (setf (slot fds 'fd) fd
 626                   (slot fds 'events) events
 627                   (slot fds 'revents) 0)
 628             (int-syscall ("poll" (* (struct pollfd)) int int)
 629                          (addr fds) 1 to-msec))
 630           (if (zerop errno)
 631               (let ((revents (slot fds 'revents)))
 632                 (or (and (eql 1 count) (logtest events revents))
 633                     (logtest pollhup revents)))
 634               (error "Syscall poll(2) failed: ~A" (strerror))))))))
 635 \f
 636 ;;;; sys/select.h
 637
 638 (defmacro with-fd-setsize ((n) &body body)
 639   `(let ((,n (if (< 0 ,n fd-setsize)
 640                  ,n
 641                  (error "Cannot select(2) on ~D: above FD_SETSIZE limit."
 642                         (1- num-descriptors)))))
 643      (declare (type (integer 0 #.fd-setsize) ,n))
 644      ,@body))
 645
 646 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 647
 648 ;;; Perform the UNIX select(2) system call.
 649 (declaim (inline unix-fast-select))
 650 (defun unix-fast-select (num-descriptors
 651                          read-fds write-fds exception-fds
 652                          timeout-secs timeout-usecs)
 653   (declare (type integer num-descriptors)
 654            (type (or (alien (* (struct fd-set))) null)
 655                  read-fds write-fds exception-fds)
 656            (type (or null (unsigned-byte 31)) timeout-secs timeout-usecs))
 657   (with-fd-setsize (num-descriptors)
 658     (flet ((select (tv-sap)
 659              (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 660                                     (* (struct fd-set)) (* (struct timeval)))
 661                           num-descriptors read-fds write-fds exception-fds
 662                           tv-sap)))
 663       (cond ((or timeout-secs timeout-usecs)
 664              (with-alien ((tv (struct timeval)))
 665                (setf (slot tv 'tv-sec) (or timeout-secs 0))
 666                (setf (slot tv 'tv-usec) (or timeout-usecs 0))
 667                (select (alien-sap (addr tv)))))
 668             (t
 669              (unless *interrupts-enabled*
 670                (note-dangerous-wait "select(2)"))
 671              (select (int-sap 0)))))))
 672
 673 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 674 ;;; to happen on one of them or to time out.
 675 (defmacro num-to-fd-set (fdset num)
 676   `(if (fixnump ,num)
 677        (progn
 678          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 679          ,@(loop for index upfrom 1 below (/ fd-setsize
 680                                              sb!vm:n-machine-word-bits)
 681              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 682        (progn
 683          ,@(loop for index upfrom 0 below (/ fd-setsize
 684                                              sb!vm:n-machine-word-bits)
 685              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 686                             (ldb (byte sb!vm:n-machine-word-bits
 687                                        ,(* index sb!vm:n-machine-word-bits))
 688                                  ,num))))))
 689
 690 (defmacro fd-set-to-num (nfds fdset)
 691   `(if (<= ,nfds sb!vm:n-machine-word-bits)
 692        (deref (slot ,fdset 'fds-bits) 0)
 693        (+ ,@(loop for index upfrom 0 below (/ fd-setsize
 694                                               sb!vm:n-machine-word-bits)
 695               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 696                             ,(* index sb!vm:n-machine-word-bits))))))
 697
 698 ;;; Examine the sets of descriptors passed as arguments to see whether
 699 ;;; they are ready for reading and writing. See the UNIX Programmer's
 700 ;;; Manual for more information.
 701 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 702   (declare (type integer nfds)
 703            (type unsigned-byte rdfds wrfds xpfds)
 704            (type (or (unsigned-byte 31) null) to-secs)
 705            (type (unsigned-byte 31) to-usecs)
 706            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 707   (with-fd-setsize (nfds)
 708     (with-alien ((tv (struct timeval))
 709                  (rdf (struct fd-set))
 710                  (wrf (struct fd-set))
 711                  (xpf (struct fd-set)))
 712       (cond (to-secs
 713              (setf (slot tv 'tv-sec) to-secs
 714                    (slot tv 'tv-usec) to-usecs))
 715             ((not *interrupts-enabled*)
 716              (note-dangerous-wait "select(2)")))
 717       (num-to-fd-set rdf rdfds)
 718       (num-to-fd-set wrf wrfds)
 719       (num-to-fd-set xpf xpfds)
 720       (macrolet ((frob (lispvar alienvar)
 721                    `(if (zerop ,lispvar)
 722                         (int-sap 0)
 723                         (alien-sap (addr ,alienvar)))))
 724         (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 725                            (* (struct fd-set)) (* (struct timeval)))
 726                  (values result
 727                          (fd-set-to-num nfds rdf)
 728                          (fd-set-to-num nfds wrf)
 729                          (fd-set-to-num nfds xpf))
 730                  nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 731                  (if to-secs (alien-sap (addr tv)) (int-sap 0)))))))
 732
 733 ;;; Lisp-side implmentations of FD_FOO macros. Abandon all hope who enters
 734 ;;; here...
 735 ;;;
 736 (defmacro fd-set (offset fd-set)
 737   (with-unique-names (word bit)
 738     `(multiple-value-bind (,word ,bit) (floor ,offset
 739                                               sb!vm:n-machine-word-bits)
 740        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 741              (logior (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
 742                                 (ash 1 ,bit))
 743                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 744
 745 (defmacro fd-clr (offset fd-set)
 746   (with-unique-names (word bit)
 747     `(multiple-value-bind (,word ,bit) (floor ,offset
 748                                               sb!vm:n-machine-word-bits)
 749        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 750              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 751                      (sb!kernel:word-logical-not
 752                       (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
 753                                  (ash 1 ,bit))))))))
 754
 755 (defmacro fd-isset (offset fd-set)
 756   (with-unique-names (word bit)
 757     `(multiple-value-bind (,word ,bit) (floor ,offset
 758                                               sb!vm:n-machine-word-bits)
 759        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 760
 761 (defmacro fd-zero (fd-set)
 762   `(progn
 763      ,@(loop for index upfrom 0 below (/ fd-setsize sb!vm:n-machine-word-bits)
 764          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 765
 766 #!-os-provides-poll
 767 (defun unix-simple-poll (fd direction to-msec)
 768   (multiple-value-bind (to-sec to-usec)
 769       (if (minusp to-msec)
 770           (values nil nil)
 771           (multiple-value-bind (to-sec to-msec2) (truncate to-msec 1000)
 772             (values to-sec (* to-msec2 1000))))
 773     (sb!unix:with-restarted-syscall (count errno)
 774       (sb!alien:with-alien ((fds (sb!alien:struct sb!unix:fd-set)))
 775         (sb!unix:fd-zero fds)
 776         (sb!unix:fd-set fd fds)
 777         (multiple-value-bind (read-fds write-fds)
 778             (ecase direction
 779               (:input
 780                (values (addr fds) nil))
 781               (:output
 782                (values nil (addr fds))))
 783           (sb!unix:unix-fast-select (1+ fd)
 784                                     read-fds write-fds nil
 785                                     to-sec to-usec)))
 786       (case count
 787         ((1) t)
 788         ((0) nil)
 789         (otherwise
 790          (error "Syscall select(2) failed on fd ~D: ~A" fd (strerror)))))))
 791 \f
 792 ;;;; sys/stat.h
 793
 794 ;;; This is a structure defined in src/runtime/wrap.c, to look
 795 ;;; basically like "struct stat" according to stat(2). It may not
 796 ;;; actually correspond to the real in-memory stat structure that the
 797 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 798 ;;; stat macros, and trying to keep Lisp code in correspondence with
 799 ;;; it is more pain than it's worth, so we just let our C runtime
 800 ;;; synthesize a nice consistent structure for us.
 801 ;;;
 802 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 803 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn't support
 804 ;;; those. We don't actually access that field anywhere, though, so
 805 ;;; until we can get 64 bit alien support it'll do. Also note that
 806 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 807 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 808 ;;; longer than 32 bits anyway, right?":-|
 809 ;;;
 810 ;;; The comment about alien and 64-bit quantities has not been kept in
 811 ;;; sync with the comment now in wrap.h (formerly wrap.c), but it's
 812 ;;; not clear whether either comment is correct.  -- RMK 2007-11-14.
 813 (define-alien-type nil
 814   (struct wrapped_stat
 815     (st-dev wst-dev-t)
 816     (st-ino ino-t)
 817     (st-mode mode-t)
 818     (st-nlink wst-nlink-t)
 819     (st-uid wst-uid-t)
 820     (st-gid wst-gid-t)
 821     (st-rdev wst-dev-t)
 822     (st-size wst-off-t)
 823     (st-blksize wst-blksize-t)
 824     (st-blocks wst-blkcnt-t)
 825     (st-atime time-t)
 826     (st-mtime time-t)
 827     (st-ctime time-t)))
 828
 829 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 830 ;;; family of Unix system calls
 831 ;;;
 832 ;;; FIXME: I think this should probably not be INLINE. However, when
 833 ;;; this was not inline, it seemed to cause memory corruption
 834 ;;; problems. My first guess is that it's a bug in the FFI code, where
 835 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 836 ;;; around a call to a function returning >10 values. But I didn't try
 837 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 838 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 839 ;;; output in the not-inlined case and see whether there's a problem,
 840 ;;; and maybe even find a fix..
 841 (declaim (inline %extract-stat-results))
 842 (defun %extract-stat-results (wrapped-stat)
 843   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 844   (values t
 845           (slot wrapped-stat 'st-dev)
 846           (slot wrapped-stat 'st-ino)
 847           (slot wrapped-stat 'st-mode)
 848           (slot wrapped-stat 'st-nlink)
 849           (slot wrapped-stat 'st-uid)
 850           (slot wrapped-stat 'st-gid)
 851           (slot wrapped-stat 'st-rdev)
 852           (slot wrapped-stat 'st-size)
 853           (slot wrapped-stat 'st-atime)
 854           (slot wrapped-stat 'st-mtime)
 855           (slot wrapped-stat 'st-ctime)
 856           (slot wrapped-stat 'st-blksize)
 857           (slot wrapped-stat 'st-blocks)))
 858
 859 ;;; Unix system calls in the stat(2) family are handled by calls to
 860 ;;; C-level wrapper functions which copy all the raw "struct stat"
 861 ;;; slots into the system-independent wrapped_stat format.
 862 ;;;    stat(2) <->  stat_wrapper()
 863 ;;;   fstat(2) <-> fstat_wrapper()
 864 ;;;   lstat(2) <-> lstat_wrapper()
 865 (defun unix-stat (name)
 866   (declare (type unix-pathname name))
 867   (with-alien ((buf (struct wrapped_stat)))
 868     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 869              (%extract-stat-results (addr buf))
 870              name (addr buf))))
 871 (defun unix-lstat (name)
 872   (declare (type unix-pathname name))
 873   (with-alien ((buf (struct wrapped_stat)))
 874     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 875              (%extract-stat-results (addr buf))
 876              name (addr buf))))
 877 (defun unix-fstat (fd)
 878   (declare (type unix-fd fd))
 879   (with-alien ((buf (struct wrapped_stat)))
 880     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 881              (%extract-stat-results (addr buf))
 882              fd (addr buf))))
 883
 884 #!-win32
 885 (defun fd-type (fd)
 886   (declare (type unix-fd fd))
 887   (let ((fmt (logand
 888               sb!unix:s-ifmt
 889               (or (with-alien ((buf (struct wrapped_stat)))
 890                     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 891                              (slot buf 'st-mode)
 892                              fd (addr buf)))
 893                   0))))
 894     (cond ((logtest sb!unix:s-ififo fmt)
 895            :fifo)
 896           ((logtest sb!unix:s-ifchr fmt)
 897            :character)
 898           ((logtest sb!unix:s-ifdir fmt)
 899            :directory)
 900           ((logtest sb!unix:s-ifblk fmt)
 901            :block)
 902           ((logtest sb!unix:s-ifreg fmt)
 903            :regular)
 904           ((logtest sb!unix:s-ifsock fmt)
 905            :socket)
 906           (t
 907            :unknown))))
 908 \f
 909 ;;;; time.h
 910
 911 ;; the POSIX.4 structure for a time value. This is like a "struct
 912 ;; timeval" but has nanoseconds instead of microseconds.
 913 #!-(or openbsd netbsd)
 914 (define-alien-type nil
 915     (struct timespec
 916             (tv-sec long)   ; seconds
 917             (tv-nsec long))) ; nanoseconds
 918
 919 ;; Just as with struct timeval, 64-bit OpenBSD has problems with the
 920 ;; above definition.  tv_sec is declared as time_t instead of long,
 921 ;; and time_t is a typedef for int.
 922 #!+(or openbsd netbsd)
 923 (define-alien-type nil
 924     (struct timespec
 925             (tv-sec time-t)  ; seconds
 926             (tv-nsec long))) ; nanoseconds
 927
 928 ;; used by other time functions
 929 (define-alien-type nil
 930     (struct tm
 931             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 932             (tm-min int)   ; Minutes.   [0-59]
 933             (tm-hour int)  ; Hours.     [0-23]
 934             (tm-mday int)  ; Day.       [1-31]
 935             (tm-mon int)   ; Month.     [0-11]
 936             (tm-year int)  ; Year - 1900.
 937             (tm-wday int)  ; Day of week. [0-6]
 938             (tm-yday int)  ; Days in year. [0-365]
 939             (tm-isdst int) ; DST.       [-1/0/1]
 940             (tm-gmtoff long) ;  Seconds east of UTC.
 941             (tm-zone c-string))) ; Timezone abbreviation.
 942
 943 (define-alien-routine get-timezone sb!alien:void
 944   (when time-t :in)
 945   (seconds-west sb!alien:int :out)
 946   (daylight-savings-p sb!alien:boolean :out))
 947
 948 #!-win32
 949 (defun nanosleep (secs nsecs)
 950   (with-alien ((req (struct timespec))
 951                (rem (struct timespec)))
 952     (setf (slot req 'tv-sec) secs)
 953     (setf (slot req 'tv-nsec) nsecs)
 954     (loop while (and (eql sb!unix:eintr
 955                           (nth-value 1
 956                                      (int-syscall ("nanosleep" (* (struct timespec))
 957                                                                (* (struct timespec)))
 958                                                   (addr req) (addr rem))))
 959                      ;; KLUDGE: On Darwin, if an interrupt cases nanosleep to
 960                      ;; take longer than the requested time, the call will
 961                      ;; return with EINT and (unsigned)-1 seconds in the
 962                      ;; remainder timespec, which would cause us to enter
 963                      ;; nanosleep again for ~136 years. So, we check that the
 964                      ;; remainder time is actually decreasing.
 965                      ;;
 966                      ;; It would be neat to do this bit of defensive
 967                      ;; programming on all platforms, but unfortunately on
 968                      ;; Linux, REM can be a little higher than REQ if the
 969                      ;; nanosleep() call is interrupted quickly enough,
 970                      ;; probably due to the request being rounded up to the
 971                      ;; nearest HZ. This would cause the sleep to return way
 972                      ;; too early.
 973                      #!+darwin
 974                      (let ((rem-sec (slot rem 'tv-sec))
 975                            (rem-nsec (slot rem 'tv-nsec)))
 976                        (when (or (> secs rem-sec)
 977                                  (and (= secs rem-sec) (>= nsecs rem-nsec)))
 978                          (setf secs rem-sec
 979                                nsecs rem-nsec)
 980                          t)))
 981           do (rotatef req rem))))
 982
 983 (defun unix-get-seconds-west (secs)
 984   (multiple-value-bind (ignore seconds dst) (get-timezone secs)
 985     (declare (ignore ignore) (ignore dst))
 986     (values seconds)))
 987 \f
 988 ;;;; sys/time.h
 989
 990 ;;; Structure crudely representing a timezone. KLUDGE: This is
 991 ;;; obsolete and should never be used.
 992 (define-alien-type nil
 993   (struct timezone
 994     (tz-minuteswest int)                ; minutes west of Greenwich
 995     (tz-dsttime int)))                  ; type of dst correction
 996 \f
 997
 998 ;; Type of the second argument to `getitimer' and
 999 ;; the second and third arguments `setitimer'.
1000 (define-alien-type nil
1001   (struct itimerval
1002     (it-interval (struct timeval))      ; timer interval
1003     (it-value (struct timeval))))       ; current value
1004
1005 (defconstant itimer-real 0)
1006 (defconstant itimer-virtual 1)
1007 (defconstant itimer-prof 2)
1008
1009 #!-win32
1010 (defun unix-getitimer (which)
1011   "Unix-getitimer returns the INTERVAL and VALUE slots of one of
1012    three system timers (:real :virtual or :profile). On success,
1013    unix-getitimer returns 5 values,
1014    T, it-interval-secs, it-interval-usec, it-value-secs, it-value-usec."
1015   (declare (type (member :real :virtual :profile) which)
1016            (values t
1017                    (unsigned-byte 29) (mod 1000000)
1018                    (unsigned-byte 29) (mod 1000000)))
1019   (let ((which (ecase which
1020                  (:real itimer-real)
1021                  (:virtual itimer-virtual)
1022                  (:profile itimer-prof))))
1023     (with-alien ((itv (struct itimerval)))
1024       (syscall* ("getitimer" int (* (struct itimerval)))
1025                 (values t
1026                         (slot (slot itv 'it-interval) 'tv-sec)
1027                         (slot (slot itv 'it-interval) 'tv-usec)
1028                         (slot (slot itv 'it-value) 'tv-sec)
1029                         (slot (slot itv 'it-value) 'tv-usec))
1030                 which (alien-sap (addr itv))))))
1031
1032 #!-win32
1033 (defun unix-setitimer (which int-secs int-usec val-secs val-usec)
1034   " Unix-setitimer sets the INTERVAL and VALUE slots of one of
1035    three system timers (:real :virtual or :profile). A SIGALRM signal
1036    will be delivered VALUE <seconds+microseconds> from now. INTERVAL,
1037    when non-zero, is <seconds+microseconds> to be loaded each time
1038    the timer expires. Setting INTERVAL and VALUE to zero disables
1039    the timer. See the Unix man page for more details. On success,
1040    unix-setitimer returns the old contents of the INTERVAL and VALUE
1041    slots as in unix-getitimer."
1042   (declare (type (member :real :virtual :profile) which)
1043            (type (unsigned-byte 29) int-secs val-secs)
1044            (type (integer 0 (1000000)) int-usec val-usec)
1045            (values t
1046                    (unsigned-byte 29) (mod 1000000)
1047                    (unsigned-byte 29) (mod 1000000)))
1048   (let ((which (ecase which
1049                  (:real itimer-real)
1050                  (:virtual itimer-virtual)
1051                  (:profile itimer-prof))))
1052     (with-alien ((itvn (struct itimerval))
1053                  (itvo (struct itimerval)))
1054       (setf (slot (slot itvn 'it-interval) 'tv-sec ) int-secs
1055             (slot (slot itvn 'it-interval) 'tv-usec) int-usec
1056             (slot (slot itvn 'it-value   ) 'tv-sec ) val-secs
1057             (slot (slot itvn 'it-value   ) 'tv-usec) val-usec)
1058       (syscall* ("setitimer" int (* (struct timeval))(* (struct timeval)))
1059                 (values t
1060                         (slot (slot itvo 'it-interval) 'tv-sec)
1061                         (slot (slot itvo 'it-interval) 'tv-usec)
1062                         (slot (slot itvo 'it-value) 'tv-sec)
1063                         (slot (slot itvo 'it-value) 'tv-usec))
1064                 which (alien-sap (addr itvn))(alien-sap (addr itvo))))))
1065
1066 \f
1067 ;;; FIXME: Many Unix error code definitions were deleted from the old
1068 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
1069 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
1070 ;;; unused symbols in package exports, but if I don't, there are
1071 ;;; enough of them all in one place here that they should probably be
1072 ;;; removed by hand.
1073 \f
1074 (defconstant micro-seconds-per-internal-time-unit
1075   (/ 1000000 sb!xc:internal-time-units-per-second))
1076
1077 ;;; UNIX specific code, that has been cleanly separated from the
1078 ;;; Windows build.
1079 #!-win32
1080 (progn
1081
1082   #!-sb-fluid (declaim (inline get-time-of-day))
1083   (defun get-time-of-day ()
1084     "Return the number of seconds and microseconds since the beginning of
1085 the UNIX epoch (January 1st 1970.)"
1086     #!+darwin
1087     (with-alien ((tv (struct timeval)))
1088       ;; CLH: FIXME! This seems to be a MacOS bug, but on x86-64/darwin,
1089       ;; gettimeofday occasionally fails. passing in a null pointer for the
1090       ;; timezone struct seems to work around the problem. NS notes: Darwin
1091       ;; manpage says the timezone is not used anymore in their implementation
1092       ;; at all.
1093       (syscall* ("gettimeofday" (* (struct timeval))
1094                                 (* (struct timezone)))
1095                 (values (slot tv 'tv-sec)
1096                         (slot tv 'tv-usec))
1097                 (addr tv)
1098                 nil))
1099     #!-(and x86-64 darwin)
1100     (with-alien ((tv (struct timeval))
1101                  (tz (struct timezone)))
1102       (syscall* ("gettimeofday" (* (struct timeval))
1103                                 (* (struct timezone)))
1104                 (values (slot tv 'tv-sec)
1105                         (slot tv 'tv-usec))
1106                 (addr tv)
1107                 (addr tz))))
1108
1109   (declaim (inline system-internal-run-time
1110                    system-real-time-values))
1111
1112   (defun system-real-time-values ()
1113     (multiple-value-bind (sec usec) (get-time-of-day)
1114       (declare (type (unsigned-byte 32) sec usec))
1115       (values sec (truncate usec micro-seconds-per-internal-time-unit))))
1116
1117   ;; There are two optimizations here that actually matter (on 32-bit
1118   ;; systems): substract the epoch from seconds and milliseconds
1119   ;; separately, as those should remain fixnums for the first 17 years
1120   ;; or so of runtime. Also, avoid doing consing a new bignum if the
1121   ;; result would be = to the last result given.
1122   ;;
1123   ;; Note: the next trick would be to spin a separate thread to update
1124   ;; a global value once per internal tick, so each individual call to
1125   ;; get-internal-real-time would be just a memory read... but that is
1126   ;; probably best left for user-level code. ;)
1127   ;;
1128   ;; Thanks to James Anderson for the optimization hint.
1129   ;;
1130   ;; Yes, it is possible to a computation to be GET-INTERNAL-REAL-TIME
1131   ;; bound.
1132   ;;
1133   ;; --NS 2007-04-05
1134   (let ((e-sec 0)
1135         (e-msec 0)
1136         (c-sec 0)
1137         (c-msec 0)
1138         (now 0))
1139     (declare (type (unsigned-byte 32) e-sec c-sec)
1140              (type fixnum e-msec c-msec)
1141              (type unsigned-byte now))
1142     (defun reinit-internal-real-time ()
1143       (setf (values e-sec e-msec) (system-real-time-values)
1144             c-sec 0
1145             c-msec 0))
1146     ;; If two threads call this at the same time, we're still safe, I
1147     ;; believe, as long as NOW is updated before either of C-MSEC or
1148     ;; C-SEC. Same applies to interrupts. --NS
1149     ;;
1150     ;; I believe this is almost correct with x86/x86-64 cache
1151     ;; coherency, but if the new value of C-SEC, C-MSEC can become
1152     ;; visible to another CPU without NOW doing the same then it's
1153     ;; unsafe. It's `almost' correct on x86 because writes by other
1154     ;; processors may become visible in any order provided transitity
1155     ;; holds. With at least three cpus, C-MSEC and C-SEC may be from
1156     ;; different threads and an incorrect value may be returned.
1157     ;; Considering that this failure is not detectable by the caller -
1158     ;; it looks like time passes a bit slowly - and that it should be
1159     ;; an extremely rare occurance I'm inclinded to leave it as it is.
1160     ;; --MG
1161     (defun get-internal-real-time ()
1162       (multiple-value-bind (sec msec) (system-real-time-values)
1163         (unless (and (= msec c-msec) (= sec c-sec))
1164           (setf now (+ (* (- sec e-sec)
1165                           sb!xc:internal-time-units-per-second)
1166                        (- msec e-msec))
1167                 c-msec msec
1168                 c-sec sec))
1169         now)))
1170
1171   (defun system-internal-run-time ()
1172     (multiple-value-bind (ignore utime-sec utime-usec stime-sec stime-usec)
1173         (unix-fast-getrusage rusage_self)
1174       (declare (ignore ignore)
1175                (type (unsigned-byte 31) utime-sec stime-sec)
1176                ;; (Classic CMU CL had these (MOD 1000000) instead, but
1177                ;; at least in Linux 2.2.12, the type doesn't seem to
1178                ;; be documented anywhere and the observed behavior is
1179                ;; to sometimes return 1000000 exactly.)
1180                (type (integer 0 1000000) utime-usec stime-usec))
1181       (let ((result (+ (* (+ utime-sec stime-sec)
1182                           sb!xc:internal-time-units-per-second)
1183                        (floor (+ utime-usec
1184                                  stime-usec
1185                                  (floor micro-seconds-per-internal-time-unit 2))
1186                               micro-seconds-per-internal-time-unit))))
1187         result))))
1188 \f
1189 ;;; FIXME, KLUDGE: GET-TIME-OF-DAY used to be UNIX-GETTIMEOFDAY, and had a
1190 ;;; primary return value indicating sucess, and also returned timezone
1191 ;;; information -- though the timezone data was not there on Darwin.
1192 ;;; Now we have GET-TIME-OF-DAY, but it turns out that despite SB-UNIX being
1193 ;;; an implementation package UNIX-GETTIMEOFDAY has users in the wild.
1194 ;;; So we're stuck with it for a while -- maybe delete it towards the end
1195 ;;; of 2009.
1196 (defun unix-gettimeofday ()
1197   (multiple-value-bind (sec usec) (get-time-of-day)
1198     (values t sec usec nil nil)))
1199 \f
1200 ;;;; opendir, readdir, closedir, and dirent-name
1201
1202 (declaim (inline unix-opendir))
1203 (defun unix-opendir (namestring &optional (errorp t))
1204   (let ((dir (alien-funcall
1205               (extern-alien "sb_opendir"
1206                             (function system-area-pointer c-string))
1207               namestring)))
1208     (if (zerop (sap-int dir))
1209         (when errorp (simple-perror
1210                       (format nil "Error opening directory ~S"
1211                               namestring)))
1212         dir)))
1213
1214 (declaim (inline unix-readdir))
1215 (defun unix-readdir (dir &optional (errorp t) namestring)
1216   (let ((ent (alien-funcall
1217               (extern-alien "sb_readdir"
1218                             (function system-area-pointer system-area-pointer))
1219                             dir)))
1220     (if (zerop (sap-int ent))
1221         (when errorp (simple-perror
1222                       (format nil "Error reading directory entry~@[ from ~S~]"
1223                               namestring)))
1224         ent)))
1225
1226 (declaim (inline unix-closedir))
1227 (defun unix-closedir (dir &optional (errorp t) namestring)
1228   (let ((r (alien-funcall
1229             (extern-alien "sb_closedir" (function int system-area-pointer))
1230             dir)))
1231     (if (minusp r)
1232         (when errorp (simple-perror
1233                       (format nil "Error closing directory~@[ ~S~]"
1234                               namestring)))
1235         r)))
1236
1237 (declaim (inline unix-dirent-name))
1238 (defun unix-dirent-name (ent)
1239   (alien-funcall
1240    (extern-alien "sb_dirent_name" (function c-string system-area-pointer))
1241    ent))
1242 \f
1243 ;;;; A magic constant for wait3().
1244 ;;;;
1245 ;;;; FIXME: This used to be defined in run-program.lisp as
1246 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
1247 ;;;; According to some of the man pages, the #o177 is part of the API
1248 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
1249 ;;;; the headers that may or may not be the same thing. To be
1250 ;;;; investigated. -- CSR, 2002-03-25
1251 (defconstant wstopped #o177)