src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 ;;; Given a C-level zero-terminated array of C strings, return a
  31 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  32 (defun c-strings->string-list (c-strings)
  33   (declare (type (alien (* c-string)) c-strings))
  34   (let ((reversed-result nil))
  35     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  36       (declare (type index i))
  37       (let ((c-string (deref c-strings i)))
  38         (if c-string
  39             (push c-string reversed-result)
  40             (return (nreverse reversed-result)))))))
  41 \f
  42 ;;;; Lisp types used by syscalls
  43
  44 (deftype unix-pathname () 'simple-string)
  45 (deftype unix-fd () `(integer 0 ,sb!xc:most-positive-fixnum))
  46
  47 (deftype unix-file-mode () '(unsigned-byte 32))
  48 (deftype unix-pid () '(unsigned-byte 32))
  49 (deftype unix-uid () '(unsigned-byte 32))
  50 (deftype unix-gid () '(unsigned-byte 32))
  51 \f
  52 ;;;; system calls
  53
  54 (/show0 "unix.lisp 74")
  55
  56 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  57 ;;; macros in this file, are only used in this file, and could be
  58 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  59 ;;;
  60 ;;; SB-EXECUTABLE, at least, uses one of these macros; other libraries
  61 ;;; and programs have been known to use them as well.  Perhaps they
  62 ;;; should live in SB-SYS or even SB-EXT?
  63
  64 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  65   (when (eql 3 (mismatch "[_]" name))
  66     (setf name
  67           (concatenate 'string #!+win32 "_" (subseq name 3))))
  68   `(locally
  69     (declare (optimize (sb!c::float-accuracy 0)))
  70     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  71                                 ,@args)))
  72       (if (minusp result)
  73           (values nil (get-errno))
  74           ,success-form))))
  75
  76 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  77 ;;; returning error codes. Should only be used for syscalls that will
  78 ;;; never really get an error.
  79 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  80   `(locally
  81     (declare (optimize (sb!c::float-accuracy 0)))
  82     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  83                                  ,@args)))
  84       (if (minusp result)
  85           (error "Syscall ~A failed: ~A" ,name (strerror))
  86           ,success-form))))
  87
  88 (defmacro int-syscall ((name &rest arg-types) &rest args)
  89   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  90
  91 (defmacro with-restarted-syscall ((&optional (value (gensym))
  92                                              (errno (gensym)))
  93                                   syscall-form &rest body)
  94   #!+sb-doc
  95   "Evaluate BODY with VALUE and ERRNO bound to the return values of
  96 SYSCALL-FORM. Repeat evaluation of SYSCALL-FORM if it is interrupted."
  97   `(let (,value ,errno)
  98      (loop (multiple-value-setq (,value ,errno)
  99              ,syscall-form)
 100         (unless #!-win32 (eql ,errno sb!unix:eintr) #!+win32 nil
 101           (return (values ,value ,errno))))
 102      ,@body))
 103
 104 (defmacro void-syscall ((name &rest arg-types) &rest args)
 105   `(syscall (,name ,@arg-types) (values t 0) ,@args))
 106
 107 #!+win32
 108 (progn
 109   (defconstant espipe 29))
 110 \f
 111 ;;;; hacking the Unix environment
 112
 113 #!-win32
 114 (define-alien-routine ("getenv" posix-getenv) c-string
 115   "Return the \"value\" part of the environment string \"name=value\" which
 116 corresponds to NAME, or NIL if there is none."
 117   (name (c-string :not-null t)))
 118 \f
 119 ;;; from stdio.h
 120
 121 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 122 ;;; error code is returned if an error occurs.
 123 #!-win32
 124 (defun unix-rename (name1 name2)
 125   (declare (type unix-pathname name1 name2))
 126   (void-syscall ("rename" (c-string :not-null t)
 127                           (c-string :not-null t))
 128                 name1 name2))
 129 \f
 130 ;;; from sys/types.h and gnu/types.h
 131
 132 (/show0 "unix.lisp 220")
 133
 134 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 135 ;;; like this unless we have extreme provocation. Reading directories
 136 ;;; is not extreme enough, since it doesn't need to be blindingly
 137 ;;; fast: we can just implement those functions in C as a wrapper
 138 ;;; layer.
 139 (define-alien-type fd-mask unsigned-long)
 140
 141 (define-alien-type nil
 142   (struct fd-set
 143           (fds-bits (array fd-mask #.(/ fd-setsize
 144                                         sb!vm:n-machine-word-bits)))))
 145
 146 (/show0 "unix.lisp 304")
 147 \f
 148 \f
 149 ;;;; fcntl.h
 150 ;;;;
 151 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 152
 153 ;;; Open the file whose pathname is specified by PATH for reading
 154 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 155 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 156 ;;;
 157 ;;; If the O_CREAT flag is specified, then the file is created with a
 158 ;;; permission of argument MODE if the file doesn't exist. An integer
 159 ;;; file descriptor is returned by UNIX-OPEN.
 160 (defun unix-open (path flags mode)
 161   (declare (type unix-pathname path)
 162            (type fixnum flags)
 163            (type unix-file-mode mode))
 164   #!+win32 (sb!win32:unixlike-open path flags mode)
 165   #!-win32
 166   (with-restarted-syscall (value errno)
 167     (int-syscall ("open" c-string int int)
 168                  path
 169                  (logior #!+win32 o_binary
 170                          #!+largefile o_largefile
 171                          flags)
 172                  mode)))
 173
 174 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 175 ;;; associated with it.
 176 (/show0 "unix.lisp 391")
 177 (defun unix-close (fd)
 178   #!+win32 (sb!win32:unixlike-close fd)
 179   #!-win32 (declare (type unix-fd fd))
 180   #!-win32 (void-syscall ("close" int) fd))
 181 \f
 182 ;;;; stdlib.h
 183
 184 ;;; There are good reasons to implement some OPEN options with an
 185 ;;; mkstemp(3)-like routine, but we don't do that yet.  Instead, this
 186 ;;; function is used only to make a temporary file for RUN-PROGRAM.
 187 ;;; sb_mkstemp() is a wrapper that lives in src/runtime/wrap.c.  Since
 188 ;;; SUSv3 mkstemp() doesn't specify the mode of the created file and
 189 ;;; since we have to implement most of this ourselves for Windows
 190 ;;; anyway, it seems worthwhile to depart from the mkstemp()
 191 ;;; specification by taking a mode to use when creating the new file.
 192 (defun sb-mkstemp (template-string mode)
 193   (declare (type string template-string)
 194            (type unix-file-mode mode))
 195   (let ((template-buffer (string-to-octets template-string :null-terminate t)))
 196     (with-pinned-objects (template-buffer)
 197       (let ((fd (alien-funcall (extern-alien "sb_mkstemp"
 198                                              (function int (* char) int))
 199                                (vector-sap template-buffer)
 200                                mode)))
 201         (if (minusp fd)
 202             (values nil (get-errno))
 203             (values fd (octets-to-string template-buffer)))))))
 204 \f
 205 ;;;; timebits.h
 206
 207 ;; A time value that is accurate to the nearest
 208 ;; microsecond but also has a range of years.
 209 ;; CLH: Note that tv-usec used to be a time-t, but that this seems
 210 ;; problematic on Darwin x86-64 (and wrong). Trying suseconds-t.
 211 #!-(or win32 openbsd netbsd)
 212 (define-alien-type nil
 213   (struct timeval
 214           (tv-sec time-t)           ; seconds
 215           (tv-usec suseconds-t)))   ; and microseconds
 216
 217 ;; The above definition doesn't work on 64-bit OpenBSD platforms.
 218 ;; Both tv_sec and tv_usec are declared as long instead of time_t, and
 219 ;; time_t is a typedef for int.
 220 #!+(or openbsd netbsd)
 221 (define-alien-type nil
 222   (struct timeval
 223           (tv-sec long)             ; seconds
 224           (tv-usec long)))          ; and microseconds
 225
 226 #!+win32
 227 (define-alien-type nil
 228   (struct timeval
 229           (tv-sec time-t)           ; seconds
 230           (tv-usec long)))          ; and microseconds
 231 \f
 232 ;;;; resourcebits.h
 233
 234 (defconstant rusage_self 0) ; the calling process
 235 (defconstant rusage_children -1) ; terminated child processes
 236 (defconstant rusage_both -2)
 237
 238 (define-alien-type nil
 239   (struct rusage
 240     (ru-utime (struct timeval))     ; user time used
 241     (ru-stime (struct timeval))     ; system time used.
 242     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 243     (ru-ixrss long)                 ; integral shared memory size
 244     (ru-idrss long)                 ; integral unshared data size
 245     (ru-isrss long)                 ; integral unshared stack size
 246     (ru-minflt long)                ; page reclaims
 247     (ru-majflt long)                ; page faults
 248     (ru-nswap long)                 ; swaps
 249     (ru-inblock long)               ; block input operations
 250     (ru-oublock long)               ; block output operations
 251     (ru-msgsnd long)                ; messages sent
 252     (ru-msgrcv long)                ; messages received
 253     (ru-nsignals long)              ; signals received
 254     (ru-nvcsw long)                 ; voluntary context switches
 255     (ru-nivcsw long)))              ; involuntary context switches
 256 \f
 257 ;;;; unistd.h
 258
 259 ;;; Given a file path (a string) and one of four constant modes,
 260 ;;; return T if the file is accessible with that mode and NIL if not.
 261 ;;; When NIL, also return an errno value with NIL which tells why the
 262 ;;; file was not accessible.
 263 ;;;
 264 ;;; The access modes are:
 265 ;;;   r_ok     Read permission.
 266 ;;;   w_ok     Write permission.
 267 ;;;   x_ok     Execute permission.
 268 ;;;   f_ok     Presence of file.
 269
 270 ;;; In Windows, the MODE argument to access is defined in terms of
 271 ;;; literal magic numbers---there are no constants to grovel.  X_OK
 272 ;;; is not defined.
 273 #!+win32
 274 (progn
 275   (defconstant f_ok 0)
 276   (defconstant w_ok 2)
 277   (defconstant r_ok 4))
 278
 279 (defun unix-access (path mode)
 280   (declare (type unix-pathname path)
 281            (type (mod 8) mode))
 282   (void-syscall ("[_]access" c-string int) path mode))
 283
 284 ;;; values for the second argument to UNIX-LSEEK
 285 ;;; Note that nowadays these are called SEEK_SET, SEEK_CUR, and SEEK_END
 286 (defconstant l_set 0) ; to set the file pointer
 287 (defconstant l_incr 1) ; to increment the file pointer
 288 (defconstant l_xtnd 2) ; to extend the file size
 289
 290 ;;; Is a stream interactive?
 291 (defun unix-isatty (fd)
 292   (declare (type unix-fd fd))
 293   (int-syscall ("[_]isatty" int) fd))
 294
 295 (defun unix-lseek (fd offset whence)
 296   "Unix-lseek accepts a file descriptor and moves the file pointer by
 297    OFFSET octets.  Whence can be any of the following:
 298
 299    L_SET        Set the file pointer.
 300    L_INCR       Increment the file pointer.
 301    L_XTND       Extend the file size.
 302   "
 303   (declare (type unix-fd fd)
 304            (type (integer 0 2) whence))
 305   (let ((result #!-win32
 306                 (alien-funcall (extern-alien #!-largefile "lseek"
 307                                              #!+largefile "lseek_largefile"
 308                                              (function off-t int off-t int))
 309                  fd offset whence)
 310                 #!+win32 (sb!win32:lseeki64 fd offset whence)))
 311     (if (minusp result)
 312         (values nil (get-errno))
 313       (values result 0))))
 314
 315 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 316 ;;; It attempts to read len bytes from the device associated with fd
 317 ;;; and store them into the buffer. It returns the actual number of
 318 ;;; bytes read.
 319
 320 #!-sb!fluid
 321 (declaim (maybe-inline unix-read))
 322
 323 (defun unix-read (fd buf len)
 324   (declare (type unix-fd fd)
 325            (type (unsigned-byte 32) len))
 326   (int-syscall (#!-win32 "read" #!+win32 "win32_unix_read"
 327                 int (* char) int) fd buf len))
 328
 329 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 330 ;;; length to write. It attempts to write len bytes to the device
 331 ;;; associated with fd from the buffer starting at offset. It returns
 332 ;;; the actual number of bytes written.
 333 (defun unix-write (fd buf offset len)
 334   (declare (type unix-fd fd)
 335            (type (unsigned-byte 32) offset len))
 336   (flet ((%write (sap)
 337            (declare (system-area-pointer sap))
 338            (int-syscall (#!-win32 "write" #!+win32 "win32_unix_write"
 339                          int (* char) int)
 340                         fd
 341                         (with-alien ((ptr (* char) sap))
 342                           (addr (deref ptr offset)))
 343                         len)))
 344     (etypecase buf
 345       ((simple-array * (*))
 346        (with-pinned-objects (buf)
 347          (%write (vector-sap buf))))
 348       (system-area-pointer
 349        (%write buf)))))
 350
 351 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 352 ;;; output pipe. Return two values: if no error occurred the first
 353 ;;; value is the pipe to be read from and the second is can be written
 354 ;;; to. If an error occurred the first value is NIL and the second the
 355 ;;; unix error code.
 356 #!-win32
 357 (defun unix-pipe ()
 358   (with-alien ((fds (array int 2)))
 359     (syscall ("pipe" (* int))
 360              (values (deref fds 0) (deref fds 1))
 361              (cast fds (* int)))))
 362 #!+win32
 363 (defun msvcrt-raw-pipe (fds size mode)
 364   (syscall ("_pipe" (* int) int int)
 365            (values (deref fds 0) (deref fds 1))
 366            (cast fds (* int)) size mode))
 367 #!+win32
 368 (defun unix-pipe ()
 369   (with-alien ((fds (array int 2)))
 370     (msvcrt-raw-pipe fds 256 o_binary)))
 371
 372 ;; Windows mkdir() doesn't take the mode argument. It's cdecl, so we could
 373 ;; actually call it passing the mode argument, but some sharp-eyed reader
 374 ;; would put five and twenty-seven together and ask us about it, so...
 375 ;;    -- AB, 2005-12-27
 376 #!-win32
 377 (defun unix-mkdir (name mode)
 378   (declare (type unix-pathname name)
 379            (type unix-file-mode mode)
 380            #!+win32 (ignore mode))
 381   (void-syscall ("mkdir" c-string #!-win32 int) name #!-win32 mode))
 382
 383 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 384 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 385 (defun newcharstar-string (newcharstar)
 386   (declare (type (alien (* char)) newcharstar))
 387   (if (null-alien newcharstar)
 388       nil
 389       (prog1
 390           (cast newcharstar c-string)
 391         (free-alien newcharstar))))
 392
 393 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 394 ;;; style returned by getcwd() (no trailing slash character).
 395 #!-win32
 396 (defun posix-getcwd ()
 397   ;; This implementation relies on a BSD/Linux extension to getcwd()
 398   ;; behavior, automatically allocating memory when a null buffer
 399   ;; pointer is used. On a system which doesn't support that
 400   ;; extension, it'll have to be rewritten somehow.
 401   ;;
 402   ;; SunOS and OSF/1 provide almost as useful an extension: if given a null
 403   ;; buffer pointer, it will automatically allocate size space. The
 404   ;; KLUDGE in this solution arises because we have just read off
 405   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 406   ;; a constant. Going the grovel_headers route doesn't seem to be
 407   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 408   ;; unistd.h.
 409   ;;
 410   ;; FIXME: The (,stub,) nastiness produces an error message about a
 411   ;; comma not inside a backquote. This error has absolutely nothing
 412   ;; to do with the actual meaning of the error (and little to do with
 413   ;; its location, either).
 414   #!-(or linux openbsd freebsd netbsd sunos osf1 darwin hpux win32) (,stub,)
 415   #!+(or linux openbsd freebsd netbsd sunos osf1 darwin hpux win32)
 416   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 417                                                        (function (* char)
 418                                                                  (* char)
 419                                                                  size-t))
 420                                          nil
 421                                          #!+(or linux openbsd freebsd netbsd darwin win32) 0
 422                                          #!+(or sunos osf1 hpux) 1025))
 423       (simple-perror "getcwd")))
 424
 425 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 426 ;;; by a slash character.
 427 (defun posix-getcwd/ ()
 428   (concatenate 'string (posix-getcwd) "/"))
 429
 430 ;;; Duplicate an existing file descriptor (given as the argument) and
 431 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 432 ;;; number are returned.
 433 (defun unix-dup (fd)
 434   (declare (type unix-fd fd))
 435   (int-syscall ("[_]dup" int) fd))
 436
 437 ;;; Terminate the current process with an optional error code. If
 438 ;;; successful, the call doesn't return. If unsuccessful, the call
 439 ;;; returns NIL and an error number.
 440 (deftype exit-code ()
 441   `(signed-byte 32))
 442 (defun os-exit (code &key abort)
 443   #!+sb-doc
 444   "Exit the process with CODE. If ABORT is true, exit is performed using _exit(2),
 445 avoiding atexit(3) hooks, etc. Otherwise exit(2) is called."
 446   (unless (typep code 'exit-code)
 447     (setf code (if abort 1 0)))
 448   (if abort
 449       (void-syscall ("_exit" int) code)
 450       (void-syscall ("exit" int) code)))
 451
 452 (define-deprecated-function :early "1.0.56.55" unix-exit os-exit (code)
 453   (os-exit code))
 454
 455 ;;; Return the process id of the current process.
 456 (define-alien-routine (#!+win32 "_getpid" #!-win32 "getpid" unix-getpid) int)
 457
 458 ;;; Return the real user id associated with the current process.
 459 #!-win32
 460 (define-alien-routine ("getuid" unix-getuid) int)
 461
 462 ;;; Translate a user id into a login name.
 463 #!-win32
 464 (defun uid-username (uid)
 465   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 466                                                        (function (* char) int))
 467                                          uid))
 468       (error "found no match for Unix uid=~S" uid)))
 469
 470 ;;; Return the namestring of the home directory, being careful to
 471 ;;; include a trailing #\/
 472 #!-win32
 473 (progn
 474   (defun uid-homedir (uid)
 475     (or (newcharstar-string (alien-funcall (extern-alien "uid_homedir"
 476                                                          (function (* char) int))
 477                                            uid))
 478         (error "failed to resolve home directory for Unix uid=~S" uid)))
 479
 480   (defun user-homedir (uid)
 481     (or (newcharstar-string (alien-funcall (extern-alien "user_homedir"
 482                                                          (function (* char) c-string))
 483                                            uid))
 484         (error "failed to resolve home directory for Unix uid=~S" uid))))
 485
 486 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 487 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 488 ;;; failure.
 489 #!-win32
 490 (defun unix-readlink (path)
 491   (declare (type unix-pathname path))
 492   (with-alien ((ptr (* char)
 493                     (alien-funcall (extern-alien
 494                                     "wrapped_readlink"
 495                                     (function (* char) c-string))
 496                                    path)))
 497     (if (null-alien ptr)
 498         (values nil (get-errno))
 499         (multiple-value-prog1
 500             (values (with-alien ((c-string c-string ptr)) c-string)
 501                     nil)
 502           (free-alien ptr)))))
 503 #!+win32
 504 ;; Win32 doesn't do links, but something likes to call this anyway.
 505 ;; Something in this file, no less. But it only takes one result, so...
 506 (defun unix-readlink (path)
 507   (declare (ignore path))
 508   nil)
 509
 510 (defun unix-realpath (path)
 511   (declare (type unix-pathname path))
 512   (with-alien ((ptr (* char)
 513                     (alien-funcall (extern-alien
 514                                     "sb_realpath"
 515                                     (function (* char) c-string))
 516                                    path)))
 517     (if (null-alien ptr)
 518         (values nil (get-errno))
 519         (multiple-value-prog1
 520             (values (with-alien ((c-string c-string ptr)) c-string)
 521                     nil)
 522           (free-alien ptr)))))
 523
 524 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 525 ;;; name and the file if this is the last link.
 526 (defun unix-unlink (name)
 527   (declare (type unix-pathname name))
 528   (void-syscall ("[_]unlink" c-string) name))
 529
 530 ;;; Return the name of the host machine as a string.
 531 #!-win32
 532 (defun unix-gethostname ()
 533   (with-alien ((buf (array char 256)))
 534     (syscall ("gethostname" (* char) int)
 535              (cast buf c-string)
 536              (cast buf (* char)) 256)))
 537
 538 #!-win32
 539 (defun unix-setsid ()
 540   (int-syscall ("setsid")))
 541
 542 ;;;; sys/ioctl.h
 543
 544 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 545 ;;; descriptors. See the UNIX Programmer's Manual for more
 546 ;;; information.
 547 #!-win32
 548 (defun unix-ioctl (fd cmd arg)
 549   (declare (type unix-fd fd)
 550            (type (signed-byte 32) cmd))
 551   (void-syscall ("ioctl" int int (* char)) fd cmd arg))
 552 \f
 553 ;;;; sys/resource.h
 554
 555 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 556 ;;;
 557 ;;; This is like getrusage(2), except it returns only the system and
 558 ;;; user time, and returns the seconds and microseconds as separate
 559 ;;; values.
 560 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 561 #!-win32
 562 (defun unix-fast-getrusage (who)
 563   (declare (values (member t)
 564                    (unsigned-byte 31) (integer 0 1000000)
 565                    (unsigned-byte 31) (integer 0 1000000)))
 566   (with-alien ((usage (struct rusage)))
 567     (syscall* ("getrusage" int (* (struct rusage)))
 568               (values t
 569                       (slot (slot usage 'ru-utime) 'tv-sec)
 570                       (slot (slot usage 'ru-utime) 'tv-usec)
 571                       (slot (slot usage 'ru-stime) 'tv-sec)
 572                       (slot (slot usage 'ru-stime) 'tv-usec))
 573               who (addr usage))))
 574
 575 ;;; Return information about the resource usage of the process
 576 ;;; specified by WHO. WHO can be either the current process
 577 ;;; (rusage_self) or all of the terminated child processes
 578 ;;; (rusage_children). NIL and an error number is returned if the call
 579 ;;; fails.
 580 #!-win32
 581 (defun unix-getrusage (who)
 582   (with-alien ((usage (struct rusage)))
 583     (syscall ("getrusage" int (* (struct rusage)))
 584               (values t
 585                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 586                          (slot (slot usage 'ru-utime) 'tv-usec))
 587                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 588                          (slot (slot usage 'ru-stime) 'tv-usec))
 589                       (slot usage 'ru-maxrss)
 590                       (slot usage 'ru-ixrss)
 591                       (slot usage 'ru-idrss)
 592                       (slot usage 'ru-isrss)
 593                       (slot usage 'ru-minflt)
 594                       (slot usage 'ru-majflt)
 595                       (slot usage 'ru-nswap)
 596                       (slot usage 'ru-inblock)
 597                       (slot usage 'ru-oublock)
 598                       (slot usage 'ru-msgsnd)
 599                       (slot usage 'ru-msgrcv)
 600                       (slot usage 'ru-nsignals)
 601                       (slot usage 'ru-nvcsw)
 602                       (slot usage 'ru-nivcsw))
 603               who (addr usage))))
 604 \f
 605 (defvar *on-dangerous-wait* :warn)
 606
 607 ;;; Calling select in a bad place can hang in a nasty manner, so it's better
 608 ;;; to have some way to detect these.
 609 (defun note-dangerous-wait (type)
 610   (let ((action *on-dangerous-wait*)
 611         (*on-dangerous-wait* nil))
 612     (case action
 613       (:warn
 614        (warn "Starting a ~A without a timeout while interrupts are ~
 615              disabled."
 616              type))
 617       (:error
 618        (error "Starting a ~A without a timeout while interrupts are ~
 619               disabled."
 620               type))
 621       (:backtrace
 622        (format *debug-io*
 623                "~&=== Starting a ~A without a timeout while interrupts are disabled. ===~%"
 624                type)
 625        (sb!debug:backtrace)))
 626     nil))
 627 \f
 628 ;;;; poll.h
 629 #!+os-provides-poll
 630 (progn
 631   (define-alien-type nil
 632       (struct pollfd
 633               (fd      int)
 634               (events  short)           ; requested events
 635               (revents short)))         ; returned events
 636
 637   (defun unix-simple-poll (fd direction to-msec)
 638     (declare (fixnum fd to-msec))
 639     (when (and (minusp to-msec) (not *interrupts-enabled*))
 640       (note-dangerous-wait "poll(2)"))
 641     (let ((events (ecase direction
 642                     (:input (logior pollin pollpri))
 643                     (:output pollout))))
 644       (with-alien ((fds (struct pollfd)))
 645         (with-restarted-syscall (count errno)
 646           (progn
 647             (setf (slot fds 'fd) fd
 648                   (slot fds 'events) events
 649                   (slot fds 'revents) 0)
 650             (int-syscall ("poll" (* (struct pollfd)) int int)
 651                          (addr fds) 1 to-msec))
 652           (if (zerop errno)
 653               (let ((revents (slot fds 'revents)))
 654                 (or (and (eql 1 count) (logtest events revents))
 655                     (logtest pollhup revents)))
 656               (error "Syscall poll(2) failed: ~A" (strerror))))))))
 657 \f
 658 ;;;; sys/select.h
 659
 660 (defmacro with-fd-setsize ((n) &body body)
 661   `(let ((,n (if (< 0 ,n fd-setsize)
 662                  ,n
 663                  (error "Cannot select(2) on ~D: above FD_SETSIZE limit."
 664                         (1- num-descriptors)))))
 665      (declare (type (integer 0 #.fd-setsize) ,n))
 666      ,@body))
 667
 668 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 669
 670 ;;; Perform the UNIX select(2) system call.
 671 (declaim (inline unix-fast-select))
 672 (defun unix-fast-select (num-descriptors
 673                          read-fds write-fds exception-fds
 674                          timeout-secs timeout-usecs)
 675   (declare (type integer num-descriptors)
 676            (type (or (alien (* (struct fd-set))) null)
 677                  read-fds write-fds exception-fds)
 678            (type (or null (unsigned-byte 31)) timeout-secs timeout-usecs))
 679   (with-fd-setsize (num-descriptors)
 680     (flet ((select (tv-sap)
 681              (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 682                                     (* (struct fd-set)) (* (struct timeval)))
 683                           num-descriptors read-fds write-fds exception-fds
 684                           tv-sap)))
 685       (cond ((or timeout-secs timeout-usecs)
 686              (with-alien ((tv (struct timeval)))
 687                (setf (slot tv 'tv-sec) (or timeout-secs 0))
 688                (setf (slot tv 'tv-usec) (or timeout-usecs 0))
 689                (select (alien-sap (addr tv)))))
 690             (t
 691              (unless *interrupts-enabled*
 692                (note-dangerous-wait "select(2)"))
 693              (select (int-sap 0)))))))
 694
 695 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 696 ;;; to happen on one of them or to time out.
 697 (defmacro num-to-fd-set (fdset num)
 698   `(if (fixnump ,num)
 699        (progn
 700          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 701          ,@(loop for index upfrom 1 below (/ fd-setsize
 702                                              sb!vm:n-machine-word-bits)
 703              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 704        (progn
 705          ,@(loop for index upfrom 0 below (/ fd-setsize
 706                                              sb!vm:n-machine-word-bits)
 707              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 708                             (ldb (byte sb!vm:n-machine-word-bits
 709                                        ,(* index sb!vm:n-machine-word-bits))
 710                                  ,num))))))
 711
 712 (defmacro fd-set-to-num (nfds fdset)
 713   `(if (<= ,nfds sb!vm:n-machine-word-bits)
 714        (deref (slot ,fdset 'fds-bits) 0)
 715        (+ ,@(loop for index upfrom 0 below (/ fd-setsize
 716                                               sb!vm:n-machine-word-bits)
 717               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 718                             ,(* index sb!vm:n-machine-word-bits))))))
 719
 720 ;;; Examine the sets of descriptors passed as arguments to see whether
 721 ;;; they are ready for reading and writing. See the UNIX Programmer's
 722 ;;; Manual for more information.
 723 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 724   (declare (type integer nfds)
 725            (type unsigned-byte rdfds wrfds xpfds)
 726            (type (or (unsigned-byte 31) null) to-secs)
 727            (type (unsigned-byte 31) to-usecs)
 728            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 729   (with-fd-setsize (nfds)
 730     (with-alien ((tv (struct timeval))
 731                  (rdf (struct fd-set))
 732                  (wrf (struct fd-set))
 733                  (xpf (struct fd-set)))
 734       (cond (to-secs
 735              (setf (slot tv 'tv-sec) to-secs
 736                    (slot tv 'tv-usec) to-usecs))
 737             ((not *interrupts-enabled*)
 738              (note-dangerous-wait "select(2)")))
 739       (num-to-fd-set rdf rdfds)
 740       (num-to-fd-set wrf wrfds)
 741       (num-to-fd-set xpf xpfds)
 742       (macrolet ((frob (lispvar alienvar)
 743                    `(if (zerop ,lispvar)
 744                         (int-sap 0)
 745                         (alien-sap (addr ,alienvar)))))
 746         (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 747                            (* (struct fd-set)) (* (struct timeval)))
 748                  (values result
 749                          (fd-set-to-num nfds rdf)
 750                          (fd-set-to-num nfds wrf)
 751                          (fd-set-to-num nfds xpf))
 752                  nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 753                  (if to-secs (alien-sap (addr tv)) (int-sap 0)))))))
 754
 755 ;;; Lisp-side implmentations of FD_FOO macros. Abandon all hope who enters
 756 ;;; here...
 757 ;;;
 758 (defmacro fd-set (offset fd-set)
 759   (with-unique-names (word bit)
 760     `(multiple-value-bind (,word ,bit) (floor ,offset
 761                                               sb!vm:n-machine-word-bits)
 762        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 763              (logior (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
 764                                 (ash 1 ,bit))
 765                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 766
 767 (defmacro fd-clr (offset fd-set)
 768   (with-unique-names (word bit)
 769     `(multiple-value-bind (,word ,bit) (floor ,offset
 770                                               sb!vm:n-machine-word-bits)
 771        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 772              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 773                      (sb!kernel:word-logical-not
 774                       (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
 775                                  (ash 1 ,bit))))))))
 776
 777 (defmacro fd-isset (offset fd-set)
 778   (with-unique-names (word bit)
 779     `(multiple-value-bind (,word ,bit) (floor ,offset
 780                                               sb!vm:n-machine-word-bits)
 781        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 782
 783 (defmacro fd-zero (fd-set)
 784   `(progn
 785      ,@(loop for index upfrom 0 below (/ fd-setsize sb!vm:n-machine-word-bits)
 786          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 787
 788 #!-os-provides-poll
 789 (defun unix-simple-poll (fd direction to-msec)
 790   (multiple-value-bind (to-sec to-usec)
 791       (if (minusp to-msec)
 792           (values nil nil)
 793           (multiple-value-bind (to-sec to-msec2) (truncate to-msec 1000)
 794             (values to-sec (* to-msec2 1000))))
 795     (sb!unix:with-restarted-syscall (count errno)
 796       (sb!alien:with-alien ((fds (sb!alien:struct sb!unix:fd-set)))
 797         (sb!unix:fd-zero fds)
 798         (sb!unix:fd-set fd fds)
 799         (multiple-value-bind (read-fds write-fds)
 800             (ecase direction
 801               (:input
 802                (values (addr fds) nil))
 803               (:output
 804                (values nil (addr fds))))
 805           (sb!unix:unix-fast-select (1+ fd)
 806                                     read-fds write-fds nil
 807                                     to-sec to-usec)))
 808       (case count
 809         ((1) t)
 810         ((0) nil)
 811         (otherwise
 812          (error "Syscall select(2) failed on fd ~D: ~A" fd (strerror)))))))
 813 \f
 814 ;;;; sys/stat.h
 815
 816 ;;; This is a structure defined in src/runtime/wrap.c, to look
 817 ;;; basically like "struct stat" according to stat(2). It may not
 818 ;;; actually correspond to the real in-memory stat structure that the
 819 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 820 ;;; stat macros, and trying to keep Lisp code in correspondence with
 821 ;;; it is more pain than it's worth, so we just let our C runtime
 822 ;;; synthesize a nice consistent structure for us.
 823 ;;;
 824 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 825 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn't support
 826 ;;; those. We don't actually access that field anywhere, though, so
 827 ;;; until we can get 64 bit alien support it'll do. Also note that
 828 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 829 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 830 ;;; longer than 32 bits anyway, right?":-|
 831 ;;;
 832 ;;; The comment about alien and 64-bit quantities has not been kept in
 833 ;;; sync with the comment now in wrap.h (formerly wrap.c), but it's
 834 ;;; not clear whether either comment is correct.  -- RMK 2007-11-14.
 835 (define-alien-type nil
 836   (struct wrapped_stat
 837     (st-dev wst-dev-t)
 838     (st-ino ino-t)
 839     (st-mode mode-t)
 840     (st-nlink wst-nlink-t)
 841     (st-uid wst-uid-t)
 842     (st-gid wst-gid-t)
 843     (st-rdev wst-dev-t)
 844     (st-size wst-off-t)
 845     (st-blksize wst-blksize-t)
 846     (st-blocks wst-blkcnt-t)
 847     (st-atime time-t)
 848     (st-mtime time-t)
 849     (st-ctime time-t)))
 850
 851 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 852 ;;; family of Unix system calls
 853 ;;;
 854 ;;; FIXME: I think this should probably not be INLINE. However, when
 855 ;;; this was not inline, it seemed to cause memory corruption
 856 ;;; problems. My first guess is that it's a bug in the FFI code, where
 857 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 858 ;;; around a call to a function returning >10 values. But I didn't try
 859 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 860 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 861 ;;; output in the not-inlined case and see whether there's a problem,
 862 ;;; and maybe even find a fix..
 863 (declaim (inline %extract-stat-results))
 864 (defun %extract-stat-results (wrapped-stat)
 865   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 866   (values t
 867           (slot wrapped-stat 'st-dev)
 868           (slot wrapped-stat 'st-ino)
 869           (slot wrapped-stat 'st-mode)
 870           (slot wrapped-stat 'st-nlink)
 871           (slot wrapped-stat 'st-uid)
 872           (slot wrapped-stat 'st-gid)
 873           (slot wrapped-stat 'st-rdev)
 874           (slot wrapped-stat 'st-size)
 875           (slot wrapped-stat 'st-atime)
 876           (slot wrapped-stat 'st-mtime)
 877           (slot wrapped-stat 'st-ctime)
 878           (slot wrapped-stat 'st-blksize)
 879           (slot wrapped-stat 'st-blocks)))
 880
 881 ;;; Unix system calls in the stat(2) family are handled by calls to
 882 ;;; C-level wrapper functions which copy all the raw "struct stat"
 883 ;;; slots into the system-independent wrapped_stat format.
 884 ;;;    stat(2) <->  stat_wrapper()
 885 ;;;   fstat(2) <-> fstat_wrapper()
 886 ;;;   lstat(2) <-> lstat_wrapper()
 887 (defun unix-stat (name)
 888   (declare (type unix-pathname name))
 889   (with-alien ((buf (struct wrapped_stat)))
 890     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 891              (%extract-stat-results (addr buf))
 892              name (addr buf))))
 893 (defun unix-lstat (name)
 894   (declare (type unix-pathname name))
 895   (with-alien ((buf (struct wrapped_stat)))
 896     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 897              (%extract-stat-results (addr buf))
 898              name (addr buf))))
 899 (defun unix-fstat (fd)
 900   (declare (type unix-fd fd))
 901   (with-alien ((buf (struct wrapped_stat)))
 902     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 903              (%extract-stat-results (addr buf))
 904              fd (addr buf))))
 905
 906 #!-win32
 907 (defun fd-type (fd)
 908   (declare (type unix-fd fd))
 909   (let ((fmt (logand
 910               sb!unix:s-ifmt
 911               (or (with-alien ((buf (struct wrapped_stat)))
 912                     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 913                              (slot buf 'st-mode)
 914                              fd (addr buf)))
 915                   0))))
 916     (cond ((logtest sb!unix:s-ififo fmt)
 917            :fifo)
 918           ((logtest sb!unix:s-ifchr fmt)
 919            :character)
 920           ((logtest sb!unix:s-ifdir fmt)
 921            :directory)
 922           ((logtest sb!unix:s-ifblk fmt)
 923            :block)
 924           ((logtest sb!unix:s-ifreg fmt)
 925            :regular)
 926           ((logtest sb!unix:s-ifsock fmt)
 927            :socket)
 928           (t
 929            :unknown))))
 930 \f
 931 ;;;; time.h
 932
 933 ;; the POSIX.4 structure for a time value. This is like a "struct
 934 ;; timeval" but has nanoseconds instead of microseconds.
 935 #!-(or openbsd netbsd)
 936 (define-alien-type nil
 937     (struct timespec
 938             (tv-sec long)   ; seconds
 939             (tv-nsec long))) ; nanoseconds
 940
 941 ;; Just as with struct timeval, 64-bit OpenBSD has problems with the
 942 ;; above definition.  tv_sec is declared as time_t instead of long,
 943 ;; and time_t is a typedef for int.
 944 #!+(or openbsd netbsd)
 945 (define-alien-type nil
 946     (struct timespec
 947             (tv-sec time-t)  ; seconds
 948             (tv-nsec long))) ; nanoseconds
 949
 950 ;; used by other time functions
 951 (define-alien-type nil
 952     (struct tm
 953             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 954             (tm-min int)   ; Minutes.   [0-59]
 955             (tm-hour int)  ; Hours.     [0-23]
 956             (tm-mday int)  ; Day.       [1-31]
 957             (tm-mon int)   ; Month.     [0-11]
 958             (tm-year int)  ; Year - 1900.
 959             (tm-wday int)  ; Day of week. [0-6]
 960             (tm-yday int)  ; Days in year. [0-365]
 961             (tm-isdst int) ; DST.       [-1/0/1]
 962             (tm-gmtoff long) ;  Seconds east of UTC.
 963             (tm-zone c-string))) ; Timezone abbreviation.
 964
 965 (define-alien-routine get-timezone sb!alien:void
 966   (when time-t :in)
 967   (seconds-west sb!alien:int :out)
 968   (daylight-savings-p sb!alien:boolean :out))
 969
 970 #!-win32
 971 (defun nanosleep (secs nsecs)
 972   (with-alien ((req (struct timespec))
 973                (rem (struct timespec)))
 974     (setf (slot req 'tv-sec) secs
 975           (slot req 'tv-nsec) nsecs)
 976     (loop while (and (eql sb!unix:eintr
 977                           (nth-value 1
 978                                      (int-syscall ("nanosleep" (* (struct timespec))
 979                                                                (* (struct timespec)))
 980                                                   (addr req) (addr rem))))
 981                      ;; KLUDGE: On Darwin, if an interrupt cases nanosleep to
 982                      ;; take longer than the requested time, the call will
 983                      ;; return with EINT and (unsigned)-1 seconds in the
 984                      ;; remainder timespec, which would cause us to enter
 985                      ;; nanosleep again for ~136 years. So, we check that the
 986                      ;; remainder time is actually decreasing.
 987                      ;;
 988                      ;; It would be neat to do this bit of defensive
 989                      ;; programming on all platforms, but unfortunately on
 990                      ;; Linux, REM can be a little higher than REQ if the
 991                      ;; nanosleep() call is interrupted quickly enough,
 992                      ;; probably due to the request being rounded up to the
 993                      ;; nearest HZ. This would cause the sleep to return way
 994                      ;; too early.
 995                      #!+darwin
 996                      (let ((rem-sec (slot rem 'tv-sec))
 997                            (rem-nsec (slot rem 'tv-nsec)))
 998                        (when (or (> secs rem-sec)
 999                                  (and (= secs rem-sec) (>= nsecs rem-nsec)))
1000                          ;; Update for next round.
1001                          (setf secs  rem-sec
1002                                nsecs rem-nsec)
1003                          t)))
1004           do (setf (slot req 'tv-sec) (slot rem 'tv-sec)
1005                    (slot req 'tv-nsec) (slot rem 'tv-nsec)))))
1006
1007 (defun unix-get-seconds-west (secs)
1008   (multiple-value-bind (ignore seconds dst) (get-timezone secs)
1009     (declare (ignore ignore) (ignore dst))
1010     (values seconds)))
1011 \f
1012 ;;;; sys/time.h
1013
1014 ;;; Structure crudely representing a timezone. KLUDGE: This is
1015 ;;; obsolete and should never be used.
1016 (define-alien-type nil
1017   (struct timezone
1018     (tz-minuteswest int)                ; minutes west of Greenwich
1019     (tz-dsttime int)))                  ; type of dst correction
1020 \f
1021
1022 ;; Type of the second argument to `getitimer' and
1023 ;; the second and third arguments `setitimer'.
1024 (define-alien-type nil
1025   (struct itimerval
1026     (it-interval (struct timeval))      ; timer interval
1027     (it-value (struct timeval))))       ; current value
1028
1029 (defconstant itimer-real 0)
1030 (defconstant itimer-virtual 1)
1031 (defconstant itimer-prof 2)
1032
1033 #!-win32
1034 (defun unix-getitimer (which)
1035   "Unix-getitimer returns the INTERVAL and VALUE slots of one of
1036    three system timers (:real :virtual or :profile). On success,
1037    unix-getitimer returns 5 values,
1038    T, it-interval-secs, it-interval-usec, it-value-secs, it-value-usec."
1039   (declare (type (member :real :virtual :profile) which)
1040            (values t
1041                    (unsigned-byte 29) (mod 1000000)
1042                    (unsigned-byte 29) (mod 1000000)))
1043   (let ((which (ecase which
1044                  (:real itimer-real)
1045                  (:virtual itimer-virtual)
1046                  (:profile itimer-prof))))
1047     (with-alien ((itv (struct itimerval)))
1048       (syscall* ("getitimer" int (* (struct itimerval)))
1049                 (values t
1050                         (slot (slot itv 'it-interval) 'tv-sec)
1051                         (slot (slot itv 'it-interval) 'tv-usec)
1052                         (slot (slot itv 'it-value) 'tv-sec)
1053                         (slot (slot itv 'it-value) 'tv-usec))
1054                 which (alien-sap (addr itv))))))
1055
1056 #!-win32
1057 (defun unix-setitimer (which int-secs int-usec val-secs val-usec)
1058   " Unix-setitimer sets the INTERVAL and VALUE slots of one of
1059    three system timers (:real :virtual or :profile). A SIGALRM signal
1060    will be delivered VALUE <seconds+microseconds> from now. INTERVAL,
1061    when non-zero, is <seconds+microseconds> to be loaded each time
1062    the timer expires. Setting INTERVAL and VALUE to zero disables
1063    the timer. See the Unix man page for more details. On success,
1064    unix-setitimer returns the old contents of the INTERVAL and VALUE
1065    slots as in unix-getitimer."
1066   (declare (type (member :real :virtual :profile) which)
1067            (type (unsigned-byte 29) int-secs val-secs)
1068            (type (integer 0 (1000000)) int-usec val-usec)
1069            (values t
1070                    (unsigned-byte 29) (mod 1000000)
1071                    (unsigned-byte 29) (mod 1000000)))
1072   (let ((which (ecase which
1073                  (:real itimer-real)
1074                  (:virtual itimer-virtual)
1075                  (:profile itimer-prof))))
1076     (with-alien ((itvn (struct itimerval))
1077                  (itvo (struct itimerval)))
1078       (setf (slot (slot itvn 'it-interval) 'tv-sec ) int-secs
1079             (slot (slot itvn 'it-interval) 'tv-usec) int-usec
1080             (slot (slot itvn 'it-value   ) 'tv-sec ) val-secs
1081             (slot (slot itvn 'it-value   ) 'tv-usec) val-usec)
1082       (syscall* ("setitimer" int (* (struct timeval))(* (struct timeval)))
1083                 (values t
1084                         (slot (slot itvo 'it-interval) 'tv-sec)
1085                         (slot (slot itvo 'it-interval) 'tv-usec)
1086                         (slot (slot itvo 'it-value) 'tv-sec)
1087                         (slot (slot itvo 'it-value) 'tv-usec))
1088                 which (alien-sap (addr itvn))(alien-sap (addr itvo))))))
1089
1090 \f
1091 ;;; FIXME: Many Unix error code definitions were deleted from the old
1092 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
1093 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
1094 ;;; unused symbols in package exports, but if I don't, there are
1095 ;;; enough of them all in one place here that they should probably be
1096 ;;; removed by hand.
1097 \f
1098 (defconstant micro-seconds-per-internal-time-unit
1099   (/ 1000000 sb!xc:internal-time-units-per-second))
1100
1101 ;;; UNIX specific code, that has been cleanly separated from the
1102 ;;; Windows build.
1103 #!-win32
1104 (progn
1105
1106   #!-sb-fluid (declaim (inline get-time-of-day))
1107   (defun get-time-of-day ()
1108     "Return the number of seconds and microseconds since the beginning of
1109 the UNIX epoch (January 1st 1970.)"
1110     #!+darwin
1111     (with-alien ((tv (struct timeval)))
1112       ;; CLH: FIXME! This seems to be a MacOS bug, but on x86-64/darwin,
1113       ;; gettimeofday occasionally fails. passing in a null pointer for the
1114       ;; timezone struct seems to work around the problem. NS notes: Darwin
1115       ;; manpage says the timezone is not used anymore in their implementation
1116       ;; at all.
1117       (syscall* ("gettimeofday" (* (struct timeval))
1118                                 (* (struct timezone)))
1119                 (values (slot tv 'tv-sec)
1120                         (slot tv 'tv-usec))
1121                 (addr tv)
1122                 nil))
1123     #!-(and x86-64 darwin)
1124     (with-alien ((tv (struct timeval))
1125                  (tz (struct timezone)))
1126       (syscall* ("gettimeofday" (* (struct timeval))
1127                                 (* (struct timezone)))
1128                 (values (slot tv 'tv-sec)
1129                         (slot tv 'tv-usec))
1130                 (addr tv)
1131                 (addr tz))))
1132
1133   (declaim (inline system-internal-run-time
1134                    system-real-time-values))
1135
1136   (defun system-real-time-values ()
1137     (multiple-value-bind (sec usec) (get-time-of-day)
1138       (declare (type (unsigned-byte 32) sec usec))
1139       (values sec (truncate usec micro-seconds-per-internal-time-unit))))
1140
1141   ;; There are two optimizations here that actually matter (on 32-bit
1142   ;; systems): substract the epoch from seconds and milliseconds
1143   ;; separately, as those should remain fixnums for the first 17 years
1144   ;; or so of runtime. Also, avoid doing consing a new bignum if the
1145   ;; result would be = to the last result given.
1146   ;;
1147   ;; Note: the next trick would be to spin a separate thread to update
1148   ;; a global value once per internal tick, so each individual call to
1149   ;; get-internal-real-time would be just a memory read... but that is
1150   ;; probably best left for user-level code. ;)
1151   ;;
1152   ;; Thanks to James Anderson for the optimization hint.
1153   ;;
1154   ;; Yes, it is possible to a computation to be GET-INTERNAL-REAL-TIME
1155   ;; bound.
1156   ;;
1157   ;; --NS 2007-04-05
1158   (let ((e-sec 0)
1159         (e-msec 0)
1160         (c-sec 0)
1161         (c-msec 0)
1162         (now 0))
1163     (declare (type (unsigned-byte 32) e-sec c-sec)
1164              (type fixnum e-msec c-msec)
1165              (type unsigned-byte now))
1166     (defun reinit-internal-real-time ()
1167       (setf (values e-sec e-msec) (system-real-time-values)
1168             c-sec 0
1169             c-msec 0))
1170     ;; If two threads call this at the same time, we're still safe, I
1171     ;; believe, as long as NOW is updated before either of C-MSEC or
1172     ;; C-SEC. Same applies to interrupts. --NS
1173     ;;
1174     ;; I believe this is almost correct with x86/x86-64 cache
1175     ;; coherency, but if the new value of C-SEC, C-MSEC can become
1176     ;; visible to another CPU without NOW doing the same then it's
1177     ;; unsafe. It's `almost' correct on x86 because writes by other
1178     ;; processors may become visible in any order provided transitity
1179     ;; holds. With at least three cpus, C-MSEC and C-SEC may be from
1180     ;; different threads and an incorrect value may be returned.
1181     ;; Considering that this failure is not detectable by the caller -
1182     ;; it looks like time passes a bit slowly - and that it should be
1183     ;; an extremely rare occurance I'm inclinded to leave it as it is.
1184     ;; --MG
1185     (defun get-internal-real-time ()
1186       (multiple-value-bind (sec msec) (system-real-time-values)
1187         (unless (and (= msec c-msec) (= sec c-sec))
1188           (setf now (+ (* (- sec e-sec)
1189                           sb!xc:internal-time-units-per-second)
1190                        (- msec e-msec))
1191                 c-msec msec
1192                 c-sec sec))
1193         now)))
1194
1195   (defun system-internal-run-time ()
1196     (multiple-value-bind (ignore utime-sec utime-usec stime-sec stime-usec)
1197         (unix-fast-getrusage rusage_self)
1198       (declare (ignore ignore)
1199                (type (unsigned-byte 31) utime-sec stime-sec)
1200                ;; (Classic CMU CL had these (MOD 1000000) instead, but
1201                ;; at least in Linux 2.2.12, the type doesn't seem to
1202                ;; be documented anywhere and the observed behavior is
1203                ;; to sometimes return 1000000 exactly.)
1204                (type (integer 0 1000000) utime-usec stime-usec))
1205       (let ((result (+ (* (+ utime-sec stime-sec)
1206                           sb!xc:internal-time-units-per-second)
1207                        (floor (+ utime-usec
1208                                  stime-usec
1209                                  (floor micro-seconds-per-internal-time-unit 2))
1210                               micro-seconds-per-internal-time-unit))))
1211         result))))
1212 \f
1213 ;;; FIXME, KLUDGE: GET-TIME-OF-DAY used to be UNIX-GETTIMEOFDAY, and had a
1214 ;;; primary return value indicating sucess, and also returned timezone
1215 ;;; information -- though the timezone data was not there on Darwin.
1216 ;;; Now we have GET-TIME-OF-DAY, but it turns out that despite SB-UNIX being
1217 ;;; an implementation package UNIX-GETTIMEOFDAY has users in the wild.
1218 ;;; So we're stuck with it for a while -- maybe delete it towards the end
1219 ;;; of 2009.
1220 (defun unix-gettimeofday ()
1221   (multiple-value-bind (sec usec) (get-time-of-day)
1222     (values t sec usec nil nil)))
1223 \f
1224 ;;;; opendir, readdir, closedir, and dirent-name
1225
1226 (declaim (inline unix-opendir))
1227 (defun unix-opendir (namestring &optional (errorp t))
1228   (let ((dir (alien-funcall
1229               (extern-alien "sb_opendir"
1230                             (function system-area-pointer c-string))
1231               namestring)))
1232     (if (zerop (sap-int dir))
1233         (when errorp (simple-perror
1234                       (format nil "Error opening directory ~S"
1235                               namestring)))
1236         dir)))
1237
1238 (declaim (inline unix-readdir))
1239 (defun unix-readdir (dir &optional (errorp t) namestring)
1240   (let ((ent (alien-funcall
1241               (extern-alien "sb_readdir"
1242                             (function system-area-pointer system-area-pointer))
1243                             dir)))
1244     (if (zerop (sap-int ent))
1245         (when errorp (simple-perror
1246                       (format nil "Error reading directory entry~@[ from ~S~]"
1247                               namestring)))
1248         ent)))
1249
1250 (declaim (inline unix-closedir))
1251 (defun unix-closedir (dir &optional (errorp t) namestring)
1252   (let ((r (alien-funcall
1253             (extern-alien "sb_closedir" (function int system-area-pointer))
1254             dir)))
1255     (if (minusp r)
1256         (when errorp (simple-perror
1257                       (format nil "Error closing directory~@[ ~S~]"
1258                               namestring)))
1259         r)))
1260
1261 (declaim (inline unix-dirent-name))
1262 (defun unix-dirent-name (ent)
1263   (alien-funcall
1264    (extern-alien "sb_dirent_name" (function c-string system-area-pointer))
1265    ent))
1266 \f
1267 ;;;; A magic constant for wait3().
1268 ;;;;
1269 ;;;; FIXME: This used to be defined in run-program.lisp as
1270 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
1271 ;;;; According to some of the man pages, the #o177 is part of the API
1272 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
1273 ;;;; the headers that may or may not be the same thing. To be
1274 ;;;; investigated. -- CSR, 2002-03-25
1275 (defconstant wstopped #o177)