src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(locally
  68     (declare (optimize (sb!c::float-accuracy 0)))
  69     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  70                                 ,@args)))
  71       (if (minusp result)
  72           (values nil (get-errno))
  73           ,success-form))))
  74
  75 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  76 ;;; returning error codes. Should only be used for syscalls that will
  77 ;;; never really get an error.
  78 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  79   `(locally
  80     (declare (optimize (sb!c::float-accuracy 0)))
  81     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  82                                  ,@args)))
  83       (if (minusp result)
  84           (error "Syscall ~A failed: ~A" ,name (strerror))
  85           ,success-form))))
  86
  87 (/show0 "unix.lisp 109")
  88
  89 (defmacro void-syscall ((name &rest arg-types) &rest args)
  90   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  91
  92 (defmacro int-syscall ((name &rest arg-types) &rest args)
  93   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  94
  95 (defmacro with-restarted-syscall ((&optional (value (gensym))
  96                                              (errno (gensym)))
  97                                   syscall-form &rest body)
  98   #!+sb-doc
  99   "Evaluate BODY with VALUE and ERRNO bound to the return values of
 100 SYSCALL-FORM. Repeat evaluation of SYSCALL-FORM if it is interrupted."
 101   `(let (,value ,errno)
 102      (loop (multiple-value-setq (,value ,errno)
 103              ,syscall-form)
 104         (unless #!-win32 (eql ,errno sb!unix:eintr) #!+win32 nil
 105           (return (values ,value ,errno))))
 106      ,@body))
 107
 108 #!+win32
 109 (progn
 110   (defconstant espipe 29)
 111   ;; For stat-wrapper hack (different-type or non-existing win32 fields).
 112   (define-alien-type nlink-t short)
 113   (define-alien-type uid-t short)
 114   (define-alien-type gid-t short))
 115 \f
 116 ;;;; hacking the Unix environment
 117
 118 #!-win32
 119 (define-alien-routine ("getenv" posix-getenv) c-string
 120   "Return the \"value\" part of the environment string \"name=value\" which
 121    corresponds to NAME, or NIL if there is none."
 122   (name c-string))
 123 \f
 124 ;;; from stdio.h
 125
 126 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 127 ;;; error code is returned if an error occurs.
 128 #!-win32
 129 (defun unix-rename (name1 name2)
 130   (declare (type unix-pathname name1 name2))
 131   (void-syscall ("rename" c-string c-string) name1 name2))
 132 \f
 133 ;;; from sys/types.h and gnu/types.h
 134
 135 (/show0 "unix.lisp 220")
 136
 137 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 138 ;;; like this unless we have extreme provocation. Reading directories
 139 ;;; is not extreme enough, since it doesn't need to be blindingly
 140 ;;; fast: we can just implement those functions in C as a wrapper
 141 ;;; layer.
 142 (define-alien-type fd-mask unsigned-long)
 143
 144 (eval-when (:compile-toplevel :load-toplevel :execute)
 145   (defconstant fd-setsize 1024))
 146
 147 (define-alien-type nil
 148   (struct fd-set
 149           (fds-bits (array fd-mask #.(/ fd-setsize
 150                                         sb!vm:n-machine-word-bits)))))
 151
 152 (/show0 "unix.lisp 304")
 153 \f
 154 \f
 155 ;;;; fcntl.h
 156 ;;;;
 157 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 158
 159 ;;; Open the file whose pathname is specified by PATH for reading
 160 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 161 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 162 ;;;
 163 ;;; If the O_CREAT flag is specified, then the file is created with a
 164 ;;; permission of argument MODE if the file doesn't exist. An integer
 165 ;;; file descriptor is returned by UNIX-OPEN.
 166 (defun unix-open (path flags mode)
 167   (declare (type unix-pathname path)
 168            (type fixnum flags)
 169            (type unix-file-mode mode))
 170   (int-syscall ("open" c-string int int)
 171                path
 172                (logior #!+win32 o_binary
 173                        #!+largefile o_largefile
 174                        flags)
 175                mode))
 176
 177 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 178 ;;; associated with it.
 179 (/show0 "unix.lisp 391")
 180 (defun unix-close (fd)
 181   (declare (type unix-fd fd))
 182   (void-syscall ("close" int) fd))
 183 \f
 184 ;;;; timebits.h
 185
 186 ;; A time value that is accurate to the nearest
 187 ;; microsecond but also has a range of years.
 188 ;; CLH: Note that tv-usec used to be a time-t, but that this seems
 189 ;; problematic on Darwin x86-64 (and wrong). Trying suseconds-t.
 190 #!-win32
 191 (define-alien-type nil
 192   (struct timeval
 193           (tv-sec time-t)           ; seconds
 194           (tv-usec suseconds-t)))   ; and microseconds
 195
 196 #!+win32
 197 (define-alien-type nil
 198   (struct timeval
 199           (tv-sec time-t)           ; seconds
 200           (tv-usec long)))          ; and microseconds
 201 \f
 202 ;;;; resourcebits.h
 203
 204 (defconstant rusage_self 0) ; the calling process
 205 (defconstant rusage_children -1) ; terminated child processes
 206 (defconstant rusage_both -2)
 207
 208 (define-alien-type nil
 209   (struct rusage
 210     (ru-utime (struct timeval))     ; user time used
 211     (ru-stime (struct timeval))     ; system time used.
 212     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 213     (ru-ixrss long)                 ; integral shared memory size
 214     (ru-idrss long)                 ; integral unshared data size
 215     (ru-isrss long)                 ; integral unshared stack size
 216     (ru-minflt long)                ; page reclaims
 217     (ru-majflt long)                ; page faults
 218     (ru-nswap long)                 ; swaps
 219     (ru-inblock long)               ; block input operations
 220     (ru-oublock long)               ; block output operations
 221     (ru-msgsnd long)                ; messages sent
 222     (ru-msgrcv long)                ; messages received
 223     (ru-nsignals long)              ; signals received
 224     (ru-nvcsw long)                 ; voluntary context switches
 225     (ru-nivcsw long)))              ; involuntary context switches
 226 \f
 227 ;;;; unistd.h
 228
 229 ;;; Given a file path (a string) and one of four constant modes,
 230 ;;; return T if the file is accessible with that mode and NIL if not.
 231 ;;; When NIL, also return an errno value with NIL which tells why the
 232 ;;; file was not accessible.
 233 ;;;
 234 ;;; The access modes are:
 235 ;;;   r_ok     Read permission.
 236 ;;;   w_ok     Write permission.
 237 ;;;   x_ok     Execute permission.
 238 ;;;   f_ok     Presence of file.
 239
 240 ;;; In Windows, the MODE argument to access is defined in terms of
 241 ;;; literal magic numbers---there are no constants to grovel.  X_OK
 242 ;;; is not defined.
 243 #!+win32
 244 (progn
 245   (defconstant f_ok 0)
 246   (defconstant w_ok 2)
 247   (defconstant r_ok 4))
 248
 249 (defun unix-access (path mode)
 250   (declare (type unix-pathname path)
 251            (type (mod 8) mode))
 252   (void-syscall ("access" c-string int) path mode))
 253
 254 ;;; values for the second argument to UNIX-LSEEK
 255 (defconstant l_set 0) ; to set the file pointer
 256 (defconstant l_incr 1) ; to increment the file pointer
 257 (defconstant l_xtnd 2) ; to extend the file size
 258
 259 ;;; Is a stream interactive?
 260 (defun unix-isatty (fd)
 261   (declare (type unix-fd fd))
 262   (int-syscall ("isatty" int) fd))
 263
 264 (defun unix-lseek (fd offset whence)
 265   "Unix-lseek accepts a file descriptor and moves the file pointer by
 266    OFFSET octets.  Whence can be any of the following:
 267
 268    L_SET        Set the file pointer.
 269    L_INCR       Increment the file pointer.
 270    L_XTND       Extend the file size.
 271   "
 272   (declare (type unix-fd fd)
 273            (type (integer 0 2) whence))
 274   (let ((result (alien-funcall (extern-alien #!-largefile "lseek"
 275                                              #!+largefile "lseek_largefile"
 276                                              (function off-t int off-t int))
 277                  fd offset whence)))
 278     (if (minusp result )
 279         (values nil (get-errno))
 280       (values result 0))))
 281
 282 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 283 ;;; It attempts to read len bytes from the device associated with fd
 284 ;;; and store them into the buffer. It returns the actual number of
 285 ;;; bytes read.
 286 (defun unix-read (fd buf len)
 287   (declare (type unix-fd fd)
 288            (type (unsigned-byte 32) len))
 289
 290   (int-syscall ("read" int (* char) int) fd buf len))
 291
 292 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 293 ;;; length to write. It attempts to write len bytes to the device
 294 ;;; associated with fd from the buffer starting at offset. It returns
 295 ;;; the actual number of bytes written.
 296 (defun unix-write (fd buf offset len)
 297   (declare (type unix-fd fd)
 298            (type (unsigned-byte 32) offset len))
 299   (int-syscall ("write" int (* char) int)
 300                fd
 301                (with-alien ((ptr (* char) (etypecase buf
 302                                             ((simple-array * (*))
 303                                              (vector-sap buf))
 304                                             (system-area-pointer
 305                                              buf))))
 306                  (addr (deref ptr offset)))
 307                len))
 308
 309 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 310 ;;; output pipe. Return two values: if no error occurred the first
 311 ;;; value is the pipe to be read from and the second is can be written
 312 ;;; to. If an error occurred the first value is NIL and the second the
 313 ;;; unix error code.
 314 #!-win32
 315 (defun unix-pipe ()
 316   (with-alien ((fds (array int 2)))
 317     (syscall ("pipe" (* int))
 318              (values (deref fds 0) (deref fds 1))
 319              (cast fds (* int)))))
 320 #!+win32
 321 (defun msvcrt-raw-pipe (fds size mode)
 322   (syscall ("_pipe" (* int) int int)
 323            (values (deref fds 0) (deref fds 1))
 324            (cast fds (* int)) size mode))
 325 #!+win32
 326 (defun unix-pipe ()
 327   (with-alien ((fds (array int 2)))
 328     (msvcrt-raw-pipe fds 256 o_binary)))
 329
 330 ;; Windows mkdir() doesn't take the mode argument. It's cdecl, so we could
 331 ;; actually call it passing the mode argument, but some sharp-eyed reader
 332 ;; would put five and twenty-seven together and ask us about it, so...
 333 ;;    -- AB, 2005-12-27
 334 #!-win32
 335 (defun unix-mkdir (name mode)
 336   (declare (type unix-pathname name)
 337            (type unix-file-mode mode)
 338            #!+win32 (ignore mode))
 339   (void-syscall ("mkdir" c-string #!-win32 int) name #!-win32 mode))
 340
 341 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 342 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 343 (defun newcharstar-string (newcharstar)
 344   (declare (type (alien (* char)) newcharstar))
 345   (if (null-alien newcharstar)
 346       nil
 347       (prog1
 348           (cast newcharstar c-string)
 349         (free-alien newcharstar))))
 350
 351 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 352 ;;; style returned by getcwd() (no trailing slash character).
 353 #!-win32
 354 (defun posix-getcwd ()
 355   ;; This implementation relies on a BSD/Linux extension to getcwd()
 356   ;; behavior, automatically allocating memory when a null buffer
 357   ;; pointer is used. On a system which doesn't support that
 358   ;; extension, it'll have to be rewritten somehow.
 359   ;;
 360   ;; SunOS and OSF/1 provide almost as useful an extension: if given a null
 361   ;; buffer pointer, it will automatically allocate size space. The
 362   ;; KLUDGE in this solution arises because we have just read off
 363   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 364   ;; a constant. Going the grovel_headers route doesn't seem to be
 365   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 366   ;; unistd.h.
 367   ;;
 368   ;; FIXME: The (,stub,) nastiness produces an error message about a
 369   ;; comma not inside a backquote. This error has absolutely nothing
 370   ;; to do with the actual meaning of the error (and little to do with
 371   ;; its location, either).
 372   #!-(or linux openbsd freebsd netbsd sunos osf1 darwin win32) (,stub,)
 373   #!+(or linux openbsd freebsd netbsd sunos osf1 darwin win32)
 374   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 375                                                        (function (* char)
 376                                                                  (* char)
 377                                                                  size-t))
 378                                          nil
 379                                          #!+(or linux openbsd freebsd netbsd darwin win32) 0
 380                                          #!+(or sunos osf1) 1025))
 381       (simple-perror "getcwd")))
 382
 383 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 384 ;;; by a slash character.
 385 (defun posix-getcwd/ ()
 386   (concatenate 'string (posix-getcwd) "/"))
 387
 388 ;;; Duplicate an existing file descriptor (given as the argument) and
 389 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 390 ;;; number are returned.
 391 (defun unix-dup (fd)
 392   (declare (type unix-fd fd))
 393   (int-syscall ("dup" int) fd))
 394
 395 ;;; Terminate the current process with an optional error code. If
 396 ;;; successful, the call doesn't return. If unsuccessful, the call
 397 ;;; returns NIL and an error number.
 398 (defun unix-exit (&optional (code 0))
 399   (declare (type (signed-byte 32) code))
 400   (void-syscall ("exit" int) code))
 401
 402 ;;; Return the process id of the current process.
 403 (define-alien-routine ("getpid" unix-getpid) int)
 404
 405 ;;; Return the real user id associated with the current process.
 406 #!-win32
 407 (define-alien-routine ("getuid" unix-getuid) int)
 408
 409 ;;; Translate a user id into a login name.
 410 #!-win32
 411 (defun uid-username (uid)
 412   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 413                                                        (function (* char) int))
 414                                          uid))
 415       (error "found no match for Unix uid=~S" uid)))
 416
 417 ;;; Return the namestring of the home directory, being careful to
 418 ;;; include a trailing #\/
 419 #!-win32
 420 (defun uid-homedir (uid)
 421   (or (newcharstar-string (alien-funcall (extern-alien "uid_homedir"
 422                                                        (function (* char) int))
 423                                          uid))
 424       (error "failed to resolve home directory for Unix uid=~S" uid)))
 425
 426 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 427 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 428 ;;; failure.
 429 #!-win32
 430 (defun unix-readlink (path)
 431   (declare (type unix-pathname path))
 432   (with-alien ((ptr (* char)
 433                     (alien-funcall (extern-alien
 434                                     "wrapped_readlink"
 435                                     (function (* char) c-string))
 436                                    path)))
 437     (if (null-alien ptr)
 438         (values nil (get-errno))
 439         (multiple-value-prog1
 440             (values (with-alien ((c-string c-string ptr)) c-string)
 441                     nil)
 442           (free-alien ptr)))))
 443 #!+win32
 444 ;; Win32 doesn't do links, but something likes to call this anyway.
 445 ;; Something in this file, no less. But it only takes one result, so...
 446 (defun unix-readlink (path)
 447   (declare (ignore path))
 448   nil)
 449
 450 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 451 ;;; name and the file if this is the last link.
 452 (defun unix-unlink (name)
 453   (declare (type unix-pathname name))
 454   (void-syscall ("unlink" c-string) name))
 455
 456 ;;; Return the name of the host machine as a string.
 457 #!-win32
 458 (defun unix-gethostname ()
 459   (with-alien ((buf (array char 256)))
 460     (syscall ("gethostname" (* char) int)
 461              (cast buf c-string)
 462              (cast buf (* char)) 256)))
 463
 464 #!-win32
 465 (defun unix-setsid ()
 466   (int-syscall ("setsid")))
 467
 468 ;;;; sys/ioctl.h
 469
 470 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 471 ;;; descriptors. See the UNIX Programmer's Manual for more
 472 ;;; information.
 473 #!-win32
 474 (defun unix-ioctl (fd cmd arg)
 475   (declare (type unix-fd fd)
 476            (type (signed-byte 32) cmd))
 477   (void-syscall ("ioctl" int int (* char)) fd cmd arg))
 478 \f
 479 ;;;; sys/resource.h
 480
 481 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 482 ;;;
 483 ;;; This is like getrusage(2), except it returns only the system and
 484 ;;; user time, and returns the seconds and microseconds as separate
 485 ;;; values.
 486 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 487 #!-win32
 488 (defun unix-fast-getrusage (who)
 489   (declare (values (member t)
 490                    (unsigned-byte 31) (integer 0 1000000)
 491                    (unsigned-byte 31) (integer 0 1000000)))
 492   (with-alien ((usage (struct rusage)))
 493     (syscall* ("getrusage" int (* (struct rusage)))
 494               (values t
 495                       (slot (slot usage 'ru-utime) 'tv-sec)
 496                       (slot (slot usage 'ru-utime) 'tv-usec)
 497                       (slot (slot usage 'ru-stime) 'tv-sec)
 498                       (slot (slot usage 'ru-stime) 'tv-usec))
 499               who (addr usage))))
 500
 501 ;;; Return information about the resource usage of the process
 502 ;;; specified by WHO. WHO can be either the current process
 503 ;;; (rusage_self) or all of the terminated child processes
 504 ;;; (rusage_children). NIL and an error number is returned if the call
 505 ;;; fails.
 506 #!-win32
 507 (defun unix-getrusage (who)
 508   (with-alien ((usage (struct rusage)))
 509     (syscall ("getrusage" int (* (struct rusage)))
 510               (values t
 511                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 512                          (slot (slot usage 'ru-utime) 'tv-usec))
 513                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 514                          (slot (slot usage 'ru-stime) 'tv-usec))
 515                       (slot usage 'ru-maxrss)
 516                       (slot usage 'ru-ixrss)
 517                       (slot usage 'ru-idrss)
 518                       (slot usage 'ru-isrss)
 519                       (slot usage 'ru-minflt)
 520                       (slot usage 'ru-majflt)
 521                       (slot usage 'ru-nswap)
 522                       (slot usage 'ru-inblock)
 523                       (slot usage 'ru-oublock)
 524                       (slot usage 'ru-msgsnd)
 525                       (slot usage 'ru-msgrcv)
 526                       (slot usage 'ru-nsignals)
 527                       (slot usage 'ru-nvcsw)
 528                       (slot usage 'ru-nivcsw))
 529               who (addr usage))))
 530 \f
 531 ;;;; sys/select.h
 532
 533 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 534
 535 ;;; Perform the UNIX select(2) system call.
 536 (declaim (inline unix-fast-select)) ; (used to be a macro in CMU CL)
 537 (defun unix-fast-select (num-descriptors
 538                          read-fds write-fds exception-fds
 539                          timeout-secs &optional (timeout-usecs 0))
 540   (declare (type (integer 0 #.fd-setsize) num-descriptors)
 541            (type (or (alien (* (struct fd-set))) null)
 542                  read-fds write-fds exception-fds)
 543            (type (or null (unsigned-byte 31)) timeout-secs)
 544            (type (unsigned-byte 31) timeout-usecs))
 545   ;; FIXME: CMU CL had
 546   ;;   (declare (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 547   ;; here. Is that important for SBCL? If so, why? Profiling might tell us..
 548   (with-alien ((tv (struct timeval)))
 549     (when timeout-secs
 550       (setf (slot tv 'tv-sec) timeout-secs)
 551       (setf (slot tv 'tv-usec) timeout-usecs))
 552     (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 553                   (* (struct fd-set)) (* (struct timeval)))
 554                  num-descriptors read-fds write-fds exception-fds
 555                  (if timeout-secs (alien-sap (addr tv)) (int-sap 0)))))
 556
 557 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 558 ;;; to happen on one of them or to time out.
 559 (defmacro num-to-fd-set (fdset num)
 560   `(if (fixnump ,num)
 561        (progn
 562          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 563          ,@(loop for index upfrom 1 below (/ fd-setsize
 564                                              sb!vm:n-machine-word-bits)
 565              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 566        (progn
 567          ,@(loop for index upfrom 0 below (/ fd-setsize
 568                                              sb!vm:n-machine-word-bits)
 569              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 570                             (ldb (byte sb!vm:n-machine-word-bits
 571                                        ,(* index sb!vm:n-machine-word-bits))
 572                                  ,num))))))
 573
 574 (defmacro fd-set-to-num (nfds fdset)
 575   `(if (<= ,nfds sb!vm:n-machine-word-bits)
 576        (deref (slot ,fdset 'fds-bits) 0)
 577        (+ ,@(loop for index upfrom 0 below (/ fd-setsize
 578                                               sb!vm:n-machine-word-bits)
 579               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 580                             ,(* index sb!vm:n-machine-word-bits))))))
 581
 582 ;;; Examine the sets of descriptors passed as arguments to see whether
 583 ;;; they are ready for reading and writing. See the UNIX Programmer's
 584 ;;; Manual for more information.
 585 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 586   (declare (type (integer 0 #.fd-setsize) nfds)
 587            (type unsigned-byte rdfds wrfds xpfds)
 588            (type (or (unsigned-byte 31) null) to-secs)
 589            (type (unsigned-byte 31) to-usecs)
 590            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 591   (with-alien ((tv (struct timeval))
 592                (rdf (struct fd-set))
 593                (wrf (struct fd-set))
 594                (xpf (struct fd-set)))
 595     (when to-secs
 596       (setf (slot tv 'tv-sec) to-secs)
 597      (setf (slot tv 'tv-usec) to-usecs))
 598     (num-to-fd-set rdf rdfds)
 599     (num-to-fd-set wrf wrfds)
 600     (num-to-fd-set xpf xpfds)
 601     (macrolet ((frob (lispvar alienvar)
 602                  `(if (zerop ,lispvar)
 603                       (int-sap 0)
 604                       (alien-sap (addr ,alienvar)))))
 605       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 606                 (* (struct fd-set)) (* (struct timeval)))
 607                (values result
 608                        (fd-set-to-num nfds rdf)
 609                        (fd-set-to-num nfds wrf)
 610                        (fd-set-to-num nfds xpf))
 611                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 612                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 613 \f
 614 ;;;; sys/stat.h
 615
 616 ;;; This is a structure defined in src/runtime/wrap.c, to look
 617 ;;; basically like "struct stat" according to stat(2). It may not
 618 ;;; actually correspond to the real in-memory stat structure that the
 619 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 620 ;;; stat macros, and trying to keep Lisp code in correspondence with
 621 ;;; it is more pain than it's worth, so we just let our C runtime
 622 ;;; synthesize a nice consistent structure for us.
 623 ;;;
 624 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 625 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn't support
 626 ;;; those. We don't actually access that field anywhere, though, so
 627 ;;; until we can get 64 bit alien support it'll do. Also note that
 628 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 629 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 630 ;;; longer than 32 bits anyway, right?":-|
 631 (define-alien-type nil
 632   (struct wrapped_stat
 633     (st-dev #!-(or mips largefile) unsigned-int
 634             #!+mips unsigned-long
 635             #!+largefile dev-t)
 636     (st-ino ino-t)
 637     (st-mode mode-t)
 638     (st-nlink nlink-t)
 639     (st-uid uid-t)
 640     (st-gid gid-t)
 641     (st-rdev #!-(or mips largefile) unsigned-int
 642              #!+mips unsigned-long
 643              #!+largefile dev-t)
 644     (st-size #!-(or mips largefile) unsigned-int
 645              #!+(or mips largefile) off-t)
 646     (st-blksize unsigned-long)
 647     (st-blocks unsigned-long)
 648     (st-atime time-t)
 649     (st-mtime time-t)
 650     (st-ctime time-t)))
 651
 652 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 653 ;;; family of Unix system calls
 654 ;;;
 655 ;;; FIXME: I think this should probably not be INLINE. However, when
 656 ;;; this was not inline, it seemed to cause memory corruption
 657 ;;; problems. My first guess is that it's a bug in the FFI code, where
 658 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 659 ;;; around a call to a function returning >10 values. But I didn't try
 660 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 661 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 662 ;;; output in the not-inlined case and see whether there's a problem,
 663 ;;; and maybe even find a fix..
 664 (declaim (inline %extract-stat-results))
 665 (defun %extract-stat-results (wrapped-stat)
 666   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 667   (values t
 668           (slot wrapped-stat 'st-dev)
 669           (slot wrapped-stat 'st-ino)
 670           (slot wrapped-stat 'st-mode)
 671           (slot wrapped-stat 'st-nlink)
 672           (slot wrapped-stat 'st-uid)
 673           (slot wrapped-stat 'st-gid)
 674           (slot wrapped-stat 'st-rdev)
 675           (slot wrapped-stat 'st-size)
 676           (slot wrapped-stat 'st-atime)
 677           (slot wrapped-stat 'st-mtime)
 678           (slot wrapped-stat 'st-ctime)
 679           (slot wrapped-stat 'st-blksize)
 680           (slot wrapped-stat 'st-blocks)))
 681
 682 ;;; Unix system calls in the stat(2) family are handled by calls to
 683 ;;; C-level wrapper functions which copy all the raw "struct stat"
 684 ;;; slots into the system-independent wrapped_stat format.
 685 ;;;    stat(2) <->  stat_wrapper()
 686 ;;;   fstat(2) <-> fstat_wrapper()
 687 ;;;   lstat(2) <-> lstat_wrapper()
 688 (defun unix-stat (name)
 689   (declare (type unix-pathname name))
 690   (with-alien ((buf (struct wrapped_stat)))
 691     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 692              (%extract-stat-results (addr buf))
 693              name (addr buf))))
 694 (defun unix-lstat (name)
 695   (declare (type unix-pathname name))
 696   (with-alien ((buf (struct wrapped_stat)))
 697     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 698              (%extract-stat-results (addr buf))
 699              name (addr buf))))
 700 (defun unix-fstat (fd)
 701   (declare (type unix-fd fd))
 702   (with-alien ((buf (struct wrapped_stat)))
 703     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 704              (%extract-stat-results (addr buf))
 705              fd (addr buf))))
 706 \f
 707 ;;;; time.h
 708
 709 ;; the POSIX.4 structure for a time value. This is like a "struct
 710 ;; timeval" but has nanoseconds instead of microseconds.
 711 (define-alien-type nil
 712     (struct timespec
 713             (tv-sec long)   ; seconds
 714             (tv-nsec long))) ; nanoseconds
 715
 716 ;; used by other time functions
 717 (define-alien-type nil
 718     (struct tm
 719             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 720             (tm-min int)   ; Minutes.   [0-59]
 721             (tm-hour int)  ; Hours.     [0-23]
 722             (tm-mday int)  ; Day.       [1-31]
 723             (tm-mon int)   ; Month.     [0-11]
 724             (tm-year int)  ; Year - 1900.
 725             (tm-wday int)  ; Day of week. [0-6]
 726             (tm-yday int)  ; Days in year. [0-365]
 727             (tm-isdst int) ; DST.       [-1/0/1]
 728             (tm-gmtoff long) ;  Seconds east of UTC.
 729             (tm-zone c-string))) ; Timezone abbreviation.
 730
 731 (define-alien-routine get-timezone sb!alien:void
 732   (when sb!alien:long :in)
 733   (seconds-west sb!alien:int :out)
 734   (daylight-savings-p sb!alien:boolean :out))
 735
 736 #!-win32
 737 (defun nanosleep (secs nsecs)
 738   (with-alien ((req (struct timespec))
 739                (rem (struct timespec)))
 740     (setf (slot req 'tv-sec) secs)
 741     (setf (slot req 'tv-nsec) nsecs)
 742     (loop while (eql sb!unix:eintr
 743                      (nth-value 1
 744                                 (int-syscall ("nanosleep" (* (struct timespec))
 745                                                           (* (struct timespec)))
 746                                              (addr req) (addr rem))))
 747        do (rotatef req rem))))
 748
 749 (defun unix-get-seconds-west (secs)
 750   (multiple-value-bind (ignore seconds dst) (get-timezone secs)
 751     (declare (ignore ignore) (ignore dst))
 752     (values seconds)))
 753 \f
 754 ;;;; sys/time.h
 755
 756 ;;; Structure crudely representing a timezone. KLUDGE: This is
 757 ;;; obsolete and should never be used.
 758 (define-alien-type nil
 759   (struct timezone
 760     (tz-minuteswest int)                ; minutes west of Greenwich
 761     (tz-dsttime int)))                  ; type of dst correction
 762
 763 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 764 ;;; and microseconds of the current time of day, the timezone (in
 765 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 766 ;;; doesn't work, it returns NIL and the errno.
 767 #!-sb-fluid (declaim (inline unix-gettimeofday))
 768 (defun unix-gettimeofday ()
 769   (with-alien ((tv (struct timeval))
 770                (tz (struct timezone)))
 771     (syscall* ("gettimeofday" (* (struct timeval))
 772                               (* (struct timezone)))
 773               (values t
 774                       (slot tv 'tv-sec)
 775                       (slot tv 'tv-usec)
 776                       (slot tz 'tz-minuteswest)
 777                       (slot tz 'tz-dsttime))
 778               (addr tv)
 779               (addr tz))))
 780 \f
 781
 782 ;; Type of the second argument to `getitimer' and
 783 ;; the second and third arguments `setitimer'.
 784 (define-alien-type nil
 785   (struct itimerval
 786     (it-interval (struct timeval))      ; timer interval
 787     (it-value (struct timeval))))       ; current value
 788
 789 (defconstant itimer-real 0)
 790 (defconstant itimer-virtual 1)
 791 (defconstant itimer-prof 2)
 792
 793 #!-win32
 794 (defun unix-getitimer (which)
 795   "Unix-getitimer returns the INTERVAL and VALUE slots of one of
 796    three system timers (:real :virtual or :profile). On success,
 797    unix-getitimer returns 5 values,
 798    T, it-interval-secs, it-interval-usec, it-value-secs, it-value-usec."
 799   (declare (type (member :real :virtual :profile) which)
 800            (values t
 801                    (unsigned-byte 29) (mod 1000000)
 802                    (unsigned-byte 29) (mod 1000000)))
 803   (let ((which (ecase which
 804                  (:real itimer-real)
 805                  (:virtual itimer-virtual)
 806                  (:profile itimer-prof))))
 807     (with-alien ((itv (struct itimerval)))
 808       (syscall* ("getitimer" int (* (struct itimerval)))
 809                 (values t
 810                         (slot (slot itv 'it-interval) 'tv-sec)
 811                         (slot (slot itv 'it-interval) 'tv-usec)
 812                         (slot (slot itv 'it-value) 'tv-sec)
 813                         (slot (slot itv 'it-value) 'tv-usec))
 814                 which (alien-sap (addr itv))))))
 815
 816 #!-win32
 817 (defun unix-setitimer (which int-secs int-usec val-secs val-usec)
 818   " Unix-setitimer sets the INTERVAL and VALUE slots of one of
 819    three system timers (:real :virtual or :profile). A SIGALRM signal
 820    will be delivered VALUE <seconds+microseconds> from now. INTERVAL,
 821    when non-zero, is <seconds+microseconds> to be loaded each time
 822    the timer expires. Setting INTERVAL and VALUE to zero disables
 823    the timer. See the Unix man page for more details. On success,
 824    unix-setitimer returns the old contents of the INTERVAL and VALUE
 825    slots as in unix-getitimer."
 826   (declare (type (member :real :virtual :profile) which)
 827            (type (unsigned-byte 29) int-secs val-secs)
 828            (type (integer 0 (1000000)) int-usec val-usec)
 829            (values t
 830                    (unsigned-byte 29) (mod 1000000)
 831                    (unsigned-byte 29) (mod 1000000)))
 832   (let ((which (ecase which
 833                  (:real itimer-real)
 834                  (:virtual itimer-virtual)
 835                  (:profile itimer-prof))))
 836     (with-alien ((itvn (struct itimerval))
 837                  (itvo (struct itimerval)))
 838       (setf (slot (slot itvn 'it-interval) 'tv-sec ) int-secs
 839             (slot (slot itvn 'it-interval) 'tv-usec) int-usec
 840             (slot (slot itvn 'it-value   ) 'tv-sec ) val-secs
 841             (slot (slot itvn 'it-value   ) 'tv-usec) val-usec)
 842       (syscall* ("setitimer" int (* (struct timeval))(* (struct timeval)))
 843                 (values t
 844                         (slot (slot itvo 'it-interval) 'tv-sec)
 845                         (slot (slot itvo 'it-interval) 'tv-usec)
 846                         (slot (slot itvo 'it-value) 'tv-sec)
 847                         (slot (slot itvo 'it-value) 'tv-usec))
 848                 which (alien-sap (addr itvn))(alien-sap (addr itvo))))))
 849
 850 \f
 851 ;;; FIXME: Many Unix error code definitions were deleted from the old
 852 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 853 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 854 ;;; unused symbols in package exports, but if I don't, there are
 855 ;;; enough of them all in one place here that they should probably be
 856 ;;; removed by hand.
 857 \f
 858 ;;;; support routines for dealing with Unix pathnames
 859
 860 (defun unix-file-kind (name &optional check-for-links)
 861   #!+sb-doc
 862   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 863   (declare (simple-string name))
 864   (multiple-value-bind (res dev ino mode)
 865       (if check-for-links (unix-lstat name) (unix-stat name))
 866     (declare (type (or fixnum null) mode)
 867              (ignore dev ino))
 868     (when res
 869       (let ((kind (logand mode s-ifmt)))
 870         (cond ((eql kind s-ifdir) :directory)
 871               ((eql kind s-ifreg) :file)
 872               #!-win32
 873               ((eql kind s-iflnk) :link)
 874               (t :special))))))
 875
 876 ;;; Is the Unix pathname PATHNAME relative, instead of absolute? (E.g.
 877 ;;; "passwd" or "etc/passwd" instead of "/etc/passwd"?)
 878 (defun relative-unix-pathname? (pathname)
 879   (declare (type simple-string pathname))
 880   (or (zerop (length pathname))
 881       (char/= (schar pathname 0) #\/)))
 882
 883 ;;; Return PATHNAME with all symbolic links resolved. PATHNAME should
 884 ;;; already be a complete absolute Unix pathname, since at least in
 885 ;;; sbcl-0.6.12.36 we're called only from TRUENAME, and only after
 886 ;;; paths have been converted to absolute paths, so we don't need to
 887 ;;; try to handle any more generality than that.
 888 (defun unix-resolve-links (pathname)
 889   (declare (type simple-string pathname))
 890   ;; KLUDGE: The Win32 platform doesn't have symbolic links, so
 891   ;; short-cut this computation (and the check for being an absolute
 892   ;; unix pathname...)
 893   #!+win32 (return-from unix-resolve-links pathname)
 894   (aver (not (relative-unix-pathname? pathname)))
 895   ;; KLUDGE: readlink and lstat are unreliable if given symlinks
 896   ;; ending in slashes -- fix the issue here instead of waiting for
 897   ;; libc to change...
 898   ;;
 899   ;; but be careful!  Must not strip the final slash from "/".  (This
 900   ;; adjustment might be a candidate for being transferred into the C
 901   ;; code in a wrap_readlink() function, too.) CSR, 2006-01-18
 902   (let ((len (length pathname)))
 903     (when (and (> len 1) (eql #\/ (schar pathname (1- len))))
 904       (setf pathname (subseq pathname 0 (1- len)))))
 905   (/noshow "entering UNIX-RESOLVE-LINKS")
 906   (loop with previous-pathnames = nil do
 907        (/noshow pathname previous-pathnames)
 908        (let ((link (unix-readlink pathname)))
 909           (/noshow link)
 910           ;; Unlike the old CMU CL code, we handle a broken symlink by
 911           ;; returning the link itself. That way, CL:TRUENAME on a
 912           ;; broken link returns the link itself, so that CL:DIRECTORY
 913           ;; can return broken links, so that even without
 914           ;; Unix-specific extensions to do interesting things with
 915           ;; them, at least Lisp programs can see them and, if
 916           ;; necessary, delete them. (This is handy e.g. when your
 917           ;; managed-by-Lisp directories are visited by Emacs, which
 918           ;; creates broken links as notes to itself.)
 919           (if (null link)
 920               (return pathname)
 921               (let ((new-pathname
 922                      (simplify-namestring
 923                       (if (relative-unix-pathname? link)
 924                           (let* ((dir-len (1+ (position #\/
 925                                                         pathname
 926                                                         :from-end t)))
 927                                  (dir (subseq pathname 0 dir-len)))
 928                             (/noshow dir)
 929                             (concatenate 'string dir link))
 930                           link))))
 931                 (if (unix-file-kind new-pathname)
 932                     (setf pathname new-pathname)
 933                     (return pathname)))))
 934         ;; To generalize the principle that even if portable Lisp code
 935         ;; can't do anything interesting with a broken symlink, at
 936         ;; least it should be able to see and delete it, when we
 937         ;; detect a cyclic link, we return the link itself. (So even
 938         ;; though portable Lisp code can't do anything interesting
 939         ;; with a cyclic link, at least it can see it and delete it.)
 940         (if (member pathname previous-pathnames :test #'string=)
 941             (return pathname)
 942             (push pathname previous-pathnames))))
 943 \f
 944 ;;; UNIX specific code, that has been cleanly separated from the
 945 ;;; Windows build.
 946 #!-win32
 947 (progn
 948   (defconstant micro-seconds-per-internal-time-unit
 949     (/ 1000000 sb!xc:internal-time-units-per-second))
 950
 951   (declaim (inline system-internal-real-time system-internal-run-time))
 952   (defun system-internal-real-time ()
 953     (multiple-value-bind (ignore seconds useconds) (unix-gettimeofday)
 954       (declare (ignore ignore) (type (unsigned-byte 32) seconds useconds))
 955       (let ((uint (truncate useconds
 956                             micro-seconds-per-internal-time-unit)))
 957         (declare (type (unsigned-byte 32) uint))
 958         (+ (* seconds sb!xc:internal-time-units-per-second)
 959            uint))))
 960
 961   (defun system-internal-run-time ()
 962     (multiple-value-bind (ignore utime-sec utime-usec stime-sec stime-usec)
 963         (unix-fast-getrusage rusage_self)
 964       (declare (ignore ignore)
 965                (type (unsigned-byte 31) utime-sec stime-sec)
 966                ;; (Classic CMU CL had these (MOD 1000000) instead, but
 967                ;; at least in Linux 2.2.12, the type doesn't seem to
 968                ;; be documented anywhere and the observed behavior is
 969                ;; to sometimes return 1000000 exactly.)
 970                (type (integer 0 1000000) utime-usec stime-usec))
 971       (let ((result (+ (* (+ utime-sec stime-sec)
 972                           sb!xc:internal-time-units-per-second)
 973                        (floor (+ utime-usec
 974                                  stime-usec
 975                                  (floor micro-seconds-per-internal-time-unit 2))
 976                               micro-seconds-per-internal-time-unit))))
 977         result))))
 978 \f
 979 ;;;; A magic constant for wait3().
 980 ;;;;
 981 ;;;; FIXME: This used to be defined in run-program.lisp as
 982 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
 983 ;;;; According to some of the man pages, the #o177 is part of the API
 984 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
 985 ;;;; the headers that may or may not be the same thing. To be
 986 ;;;; investigated. -- CSR, 2002-03-25
 987 (defconstant wstopped #o177)
 988
 989 \f
 990 ;;;; stuff not yet found in the header files
 991 ;;;;
 992 ;;;; Abandon all hope who enters here...
 993
 994 ;;; not checked for linux...
 995 (defmacro fd-set (offset fd-set)
 996   (let ((word (gensym))
 997         (bit (gensym)))
 998     `(multiple-value-bind (,word ,bit) (floor ,offset
 999                                               sb!vm:n-machine-word-bits)
1000        (setf (deref (slot ,fd-set 'fds-bits) ,word)
1001              (logior (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
1002                                 (ash 1 ,bit))
1003                      (deref (slot ,fd-set 'fds-bits) ,word))))))
1004
1005 ;;; not checked for linux...
1006 (defmacro fd-clr (offset fd-set)
1007   (let ((word (gensym))
1008         (bit (gensym)))
1009     `(multiple-value-bind (,word ,bit) (floor ,offset
1010                                               sb!vm:n-machine-word-bits)
1011        (setf (deref (slot ,fd-set 'fds-bits) ,word)
1012              (logand (deref (slot ,fd-set 'fds-bits) ,word)
1013                      (sb!kernel:word-logical-not
1014                       (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
1015                                  (ash 1 ,bit))))))))
1016
1017 ;;; not checked for linux...
1018 (defmacro fd-isset (offset fd-set)
1019   (let ((word (gensym))
1020         (bit (gensym)))
1021     `(multiple-value-bind (,word ,bit) (floor ,offset
1022                                               sb!vm:n-machine-word-bits)
1023        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
1024
1025 ;;; not checked for linux...
1026 (defmacro fd-zero (fd-set)
1027   `(progn
1028      ,@(loop for index upfrom 0 below (/ fd-setsize sb!vm:n-machine-word-bits)
1029          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
1030