src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69      (if (minusp result)
  70          (values nil (get-errno))
  71          ,success-form)))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  78                                 ,@args)))
  79      (if (minusp result)
  80          (error "Syscall ~A failed: ~A" ,name (strerror))
  81          ,success-form)))
  82
  83 (/show0 "unix.lisp 109")
  84
  85 (defmacro void-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  87
  88 (defmacro int-syscall ((name &rest arg-types) &rest args)
  89   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  90 \f
  91 ;;;; hacking the Unix environment
  92
  93 (def-alien-routine ("getenv" posix-getenv) c-string
  94   "Return the environment string \"name=value\" which corresponds to NAME, or
  95    NIL if there is none."
  96   (name c-string))
  97 \f
  98 ;;; from stdio.h
  99
 100 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 101 ;;; error code is returned if an error occurs.
 102 (defun unix-rename (name1 name2)
 103   (declare (type unix-pathname name1 name2))
 104   (void-syscall ("rename" c-string c-string) name1 name2))
 105 \f
 106 ;;; from sys/types.h and gnu/types.h
 107
 108 (/show0 "unix.lisp 220")
 109
 110 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 111 ;;; like this unless we have extreme provocation. Reading directories
 112 ;;; is not extreme enough, since it doesn't need to be blindingly
 113 ;;; fast: we can just implement those functions in C as a wrapper
 114 ;;; layer.
 115 (def-alien-type fd-mask unsigned-long)
 116
 117 (eval-when (:compile-toplevel :load-toplevel :execute)
 118   (defconstant fd-setsize 1024))
 119
 120 (def-alien-type nil
 121   (struct fd-set
 122           (fds-bits (array fd-mask #.(/ fd-setsize 32)))))
 123
 124 (/show0 "unix.lisp 304")
 125 \f
 126 \f
 127 ;;;; fcntl.h
 128 ;;;;
 129 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 130
 131 ;;; Open the file whose pathname is specified by PATH for reading
 132 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 133 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 134 ;;;
 135 ;;; If the O_CREAT flag is specified, then the file is created with a
 136 ;;; permission of argument MODE if the file doesn't exist. An integer
 137 ;;; file descriptor is returned by UNIX-OPEN.
 138 (defun unix-open (path flags mode)
 139   (declare (type unix-pathname path)
 140            (type fixnum flags)
 141            (type unix-file-mode mode))
 142   (int-syscall ("open" c-string int int) path flags mode))
 143
 144 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 145 ;;; associated with it.
 146 (/show0 "unix.lisp 391")
 147 (defun unix-close (fd)
 148   (declare (type unix-fd fd))
 149   (void-syscall ("close" int) fd))
 150 \f
 151 ;;;; timebits.h
 152
 153 ;; A time value that is accurate to the nearest
 154 ;; microsecond but also has a range of years.
 155 (def-alien-type nil
 156   (struct timeval
 157           (tv-sec time-t)               ; seconds
 158           (tv-usec time-t)))            ; and microseconds
 159 \f
 160 ;;;; resourcebits.h
 161
 162 (defconstant rusage_self 0) ; the calling process
 163 (defconstant rusage_children -1) ; terminated child processes
 164 (defconstant rusage_both -2)
 165
 166 (def-alien-type nil
 167   (struct rusage
 168     (ru-utime (struct timeval))     ; user time used
 169     (ru-stime (struct timeval))     ; system time used.
 170     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 171     (ru-ixrss long)                 ; integral shared memory size
 172     (ru-idrss long)                 ; integral unshared data size
 173     (ru-isrss long)                 ; integral unshared stack size
 174     (ru-minflt long)                ; page reclaims
 175     (ru-majflt long)                ; page faults
 176     (ru-nswap long)                 ; swaps
 177     (ru-inblock long)               ; block input operations
 178     (ru-oublock long)               ; block output operations
 179     (ru-msgsnd long)                ; messages sent
 180     (ru-msgrcv long)                ; messages received
 181     (ru-nsignals long)              ; signals received
 182     (ru-nvcsw long)                 ; voluntary context switches
 183     (ru-nivcsw long)))              ; involuntary context switches
 184 \f
 185 ;;;; unistd.h
 186
 187 ;;; Given a file path (a string) and one of four constant modes,
 188 ;;; return T if the file is accessible with that mode and NIL if not.
 189 ;;; When NIL, also return an errno value with NIL which tells why the
 190 ;;; file was not accessible.
 191 ;;;
 192 ;;; The access modes are:
 193 ;;;   r_ok     Read permission.
 194 ;;;   w_ok     Write permission.
 195 ;;;   x_ok     Execute permission.
 196 ;;;   f_ok     Presence of file.
 197 (defun unix-access (path mode)
 198   (declare (type unix-pathname path)
 199            (type (mod 8) mode))
 200   (void-syscall ("access" c-string int) path mode))
 201
 202 ;;; values for the second argument to UNIX-LSEEK
 203 (defconstant l_set 0) ; to set the file pointer
 204 (defconstant l_incr 1) ; to increment the file pointer
 205 (defconstant l_xtnd 2) ; to extend the file size
 206
 207 ;;; Accept a file descriptor and move the file pointer ahead
 208 ;;; a certain offset for that file. WHENCE can be any of the following:
 209 ;;;  L_SET     Set the file pointer.
 210 ;;;  L_INCR    Increment the file pointer.
 211 ;;;  L_XTND    Extend the file size.
 212 (defun unix-lseek (fd offset whence)
 213   (declare (type unix-fd fd)
 214            (type (unsigned-byte 32) offset)
 215            (type (integer 0 2) whence))
 216   #!-(and x86 bsd)
 217   (int-syscall ("lseek" int off-t int) fd offset whence)
 218   ;; Need a 64-bit return value type for this. TBD. For now,
 219   ;; don't use this with any 2G+ partitions.
 220   #!+(and x86 bsd)
 221   (int-syscall ("lseek" int unsigned-long unsigned-long int)
 222                fd offset 0 whence))
 223
 224 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 225 ;;; It attempts to read len bytes from the device associated with fd
 226 ;;; and store them into the buffer. It returns the actual number of
 227 ;;; bytes read.
 228 (defun unix-read (fd buf len)
 229   (declare (type unix-fd fd)
 230            (type (unsigned-byte 32) len))
 231
 232   (int-syscall ("read" int (* char) int) fd buf len))
 233
 234 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 235 ;;; length to write. It attempts to write len bytes to the device
 236 ;;; associated with fd from the the buffer starting at offset. It returns
 237 ;;; the actual number of bytes written.
 238 (defun unix-write (fd buf offset len)
 239   (declare (type unix-fd fd)
 240            (type (unsigned-byte 32) offset len))
 241   (int-syscall ("write" int (* char) int)
 242                fd
 243                (with-alien ((ptr (* char) (etypecase buf
 244                                             ((simple-array * (*))
 245                                              (vector-sap buf))
 246                                             (system-area-pointer
 247                                              buf))))
 248                  (addr (deref ptr offset)))
 249                len))
 250
 251 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 252 ;;; output pipe. Return two values: if no error occurred the first
 253 ;;; value is the pipe to be read from and the second is can be written
 254 ;;; to. If an error occurred the first value is NIL and the second the
 255 ;;; unix error code.
 256 (defun unix-pipe ()
 257   (with-alien ((fds (array int 2)))
 258     (syscall ("pipe" (* int))
 259              (values (deref fds 0) (deref fds 1))
 260              (cast fds (* int)))))
 261
 262 (defun unix-mkdir (name mode)
 263   (declare (type unix-pathname name)
 264            (type unix-file-mode mode))
 265   (void-syscall ("mkdir" c-string int) name mode))
 266
 267 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 268 ;;; style returned by getcwd() (no trailing slash character).
 269 (defun posix-getcwd ()
 270   ;; This implementation relies on a BSD/Linux extension to getcwd()
 271   ;; behavior, automatically allocating memory when a null buffer
 272   ;; pointer is used. On a system which doesn't support that
 273   ;; extension, it'll have to be rewritten somehow.
 274   #!-(or linux openbsd freebsd) (,stub,)
 275   (let* ((raw-char-ptr (alien-funcall (extern-alien "getcwd"
 276                                                     (function (* char)
 277                                                               (* char) size-t))
 278                                       nil 0)))
 279     (if (null-alien raw-char-ptr)
 280         (simple-perror "getcwd")
 281         (prog1
 282             (cast raw-char-ptr c-string)
 283           (free-alien raw-char-ptr)))))
 284
 285 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 286 ;;; by a slash character.
 287 (defun posix-getcwd/ ()
 288   (concatenate 'string (posix-getcwd) "/"))
 289
 290 ;;; Convert at the UNIX level from a possibly relative filename to
 291 ;;; an absolute filename.
 292 ;;;
 293 ;;; FIXME: Do we still need this even as we switch to
 294 ;;; *DEFAULT-PATHNAME-DEFAULTS*? I think maybe we do, since it seems
 295 ;;; to be valid for the user to set *DEFAULT-PATHNAME-DEFAULTS* to
 296 ;;; have a NIL directory component, and then this'd be the only way to
 297 ;;; interpret a relative directory specification. But I don't find the
 298 ;;; ANSI pathname documentation to be a model of clarity. Maybe
 299 ;;; someone who understands it better can take a look at this.. -- WHN
 300 (defun unix-maybe-prepend-current-directory (name)
 301   (declare (simple-string name))
 302   (if (and (> (length name) 0) (char= (schar name 0) #\/))
 303       name
 304       (concatenate 'simple-string (posix-getcwd/) name)))
 305
 306 ;;; Duplicate an existing file descriptor (given as the argument) and
 307 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 308 ;;; number are returned.
 309 (defun unix-dup (fd)
 310   (declare (type unix-fd fd))
 311   (int-syscall ("dup" int) fd))
 312
 313 ;;; Terminate the current process with an optional error code. If
 314 ;;; successful, the call doesn't return. If unsuccessful, the call
 315 ;;; returns NIL and an error number.
 316 (defun unix-exit (&optional (code 0))
 317   (declare (type (signed-byte 32) code))
 318   (void-syscall ("exit" int) code))
 319
 320 ;;; Return the process id of the current process.
 321 (def-alien-routine ("getpid" unix-getpid) int)
 322
 323 ;;; Return the real user-id associated with the current process.
 324 (def-alien-routine ("getuid" unix-getuid) int)
 325
 326 ;;; Invoke readlink(2) on the file name specified by the simple string
 327 ;;; PATH. Return up to two values: the contents of the symbolic link
 328 ;;; if the call is successful, or NIL and the Unix error number.
 329 (defun unix-readlink (path)
 330   (declare (type unix-pathname path))
 331   (with-alien ((buf (array char 1024)))
 332     (syscall ("readlink" c-string (* char) int)
 333              (let ((string (make-string result)))
 334                (sb!kernel:copy-from-system-area
 335                 (alien-sap buf) 0
 336                 string (* sb!vm:vector-data-offset sb!vm:word-bits)
 337                 (* result sb!vm:byte-bits))
 338                string)
 339              path (cast buf (* char)) 1024)))
 340
 341 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 342 ;;; name and the file if this is the last link.
 343 (defun unix-unlink (name)
 344   (declare (type unix-pathname name))
 345   (void-syscall ("unlink" c-string) name))
 346
 347 ;;; Set the tty-process-group for the unix file-descriptor FD to PGRP.
 348 ;;; If not supplied, FD defaults to "/dev/tty".
 349 (defun %set-tty-process-group (pgrp &optional fd)
 350   (let ((old-sigs (unix-sigblock (sigmask :sigttou
 351                                           :sigttin
 352                                           :sigtstp
 353                                           :sigchld))))
 354     (declare (type (unsigned-byte 32) old-sigs))
 355     (unwind-protect
 356         (if fd
 357             (tcsetpgrp fd pgrp)
 358             (multiple-value-bind (tty-fd errno) (unix-open "/dev/tty" o_rdwr 0)
 359               (cond (tty-fd
 360                      (multiple-value-prog1
 361                          (tcsetpgrp tty-fd pgrp)
 362                        (unix-close tty-fd)))
 363                     (t
 364                      (values nil errno)))))
 365       (unix-sigsetmask old-sigs))))
 366
 367 ;;; Return the name of the host machine as a string.
 368 (defun unix-gethostname ()
 369   (with-alien ((buf (array char 256)))
 370     (syscall ("gethostname" (* char) int)
 371              (cast buf c-string)
 372              (cast buf (* char)) 256)))
 373
 374 ;;; Write the core image of the file described by FD to disk.
 375 (defun unix-fsync (fd)
 376   (declare (type unix-fd fd))
 377   (void-syscall ("fsync" int) fd))
 378 \f
 379 ;;;; sys/ioctl.h
 380
 381 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 382 ;;; descriptors. See the UNIX Programmer's Manual for more
 383 ;;; information.
 384 (defun unix-ioctl (fd cmd arg)
 385   (declare (type unix-fd fd)
 386            (type (unsigned-byte 32) cmd))
 387   (void-syscall ("ioctl" int unsigned-int (* char)) fd cmd arg))
 388 \f
 389 ;;;; sys/resource.h
 390
 391 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 392 ;;;
 393 ;;; Like getrusage(2), but return only the system and user time,
 394 ;;; and return the seconds and microseconds as separate values.
 395 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 396 (defun unix-fast-getrusage (who)
 397   (declare (values (member t)
 398                    (unsigned-byte 31) (mod 1000000)
 399                    (unsigned-byte 31) (mod 1000000)))
 400   (with-alien ((usage (struct rusage)))
 401     (syscall* ("getrusage" int (* (struct rusage)))
 402               (values t
 403                       (slot (slot usage 'ru-utime) 'tv-sec)
 404                       (slot (slot usage 'ru-utime) 'tv-usec)
 405                       (slot (slot usage 'ru-stime) 'tv-sec)
 406                       (slot (slot usage 'ru-stime) 'tv-usec))
 407               who (addr usage))))
 408
 409 ;;; Return information about the resource usage of the process
 410 ;;; specified by WHO. WHO can be either the current process
 411 ;;; (rusage_self) or all of the terminated child processes
 412 ;;; (rusage_children). NIL and an error number is returned if the call
 413 ;;; fails.
 414 (defun unix-getrusage (who)
 415   (with-alien ((usage (struct rusage)))
 416     (syscall ("getrusage" int (* (struct rusage)))
 417               (values t
 418                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 419                          (slot (slot usage 'ru-utime) 'tv-usec))
 420                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 421                          (slot (slot usage 'ru-stime) 'tv-usec))
 422                       (slot usage 'ru-maxrss)
 423                       (slot usage 'ru-ixrss)
 424                       (slot usage 'ru-idrss)
 425                       (slot usage 'ru-isrss)
 426                       (slot usage 'ru-minflt)
 427                       (slot usage 'ru-majflt)
 428                       (slot usage 'ru-nswap)
 429                       (slot usage 'ru-inblock)
 430                       (slot usage 'ru-oublock)
 431                       (slot usage 'ru-msgsnd)
 432                       (slot usage 'ru-msgrcv)
 433                       (slot usage 'ru-nsignals)
 434                       (slot usage 'ru-nvcsw)
 435                       (slot usage 'ru-nivcsw))
 436               who (addr usage))))
 437 \f
 438 ;;;; sys/select.h
 439
 440 (defmacro unix-fast-select (num-descriptors
 441                             read-fds write-fds exception-fds
 442                             timeout-secs &optional (timeout-usecs 0))
 443   #!+sb-doc
 444   "Perform the UNIX select(2) system call."
 445   (declare (type (integer 0 #.FD-SETSIZE) num-descriptors)
 446            (type (or (alien (* (struct fd-set))) null)
 447                  read-fds write-fds exception-fds)
 448            (type (or null (unsigned-byte 31)) timeout-secs)
 449            (type (unsigned-byte 31) timeout-usecs) )
 450   ;; FIXME: CMU CL had
 451   ;;   (optimize (speed 3) (safety 0) (inhibit-warnings 3))
 452   ;; in the declarations above. If they're important, they should
 453   ;; be in a declaration inside the LET expansion, not in the
 454   ;; macro compile-time code.
 455   `(let ((timeout-secs ,timeout-secs))
 456      (with-alien ((tv (struct timeval)))
 457        (when timeout-secs
 458          (setf (slot tv 'tv-sec) timeout-secs)
 459          (setf (slot tv 'tv-usec) ,timeout-usecs))
 460        (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 461                      (* (struct fd-set)) (* (struct timeval)))
 462                     ,num-descriptors ,read-fds ,write-fds ,exception-fds
 463                     (if timeout-secs (alien-sap (addr tv)) (int-sap 0))))))
 464
 465 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 466 ;;; to happen on one of them or to time out.
 467 (defmacro num-to-fd-set (fdset num)
 468   `(if (fixnump ,num)
 469        (progn
 470          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 471          ,@(loop for index upfrom 1 below (/ fd-setsize 32)
 472              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 473        (progn
 474          ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 475              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 476                             (ldb (byte 32 ,(* index 32)) ,num))))))
 477
 478 (defmacro fd-set-to-num (nfds fdset)
 479   `(if (<= ,nfds 32)
 480        (deref (slot ,fdset 'fds-bits) 0)
 481        (+ ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 482               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 483                             ,(* index 32))))))
 484
 485 ;;; Examine the sets of descriptors passed as arguments to see whether
 486 ;;; they are ready for reading and writing. See the UNIX Programmer's
 487 ;;; Manual for more information.
 488 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 489   (declare (type (integer 0 #.FD-SETSIZE) nfds)
 490            (type unsigned-byte rdfds wrfds xpfds)
 491            (type (or (unsigned-byte 31) null) to-secs)
 492            (type (unsigned-byte 31) to-usecs)
 493            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 494   (with-alien ((tv (struct timeval))
 495                (rdf (struct fd-set))
 496                (wrf (struct fd-set))
 497                (xpf (struct fd-set)))
 498     (when to-secs
 499       (setf (slot tv 'tv-sec) to-secs)
 500      (setf (slot tv 'tv-usec) to-usecs))
 501     (num-to-fd-set rdf rdfds)
 502     (num-to-fd-set wrf wrfds)
 503     (num-to-fd-set xpf xpfds)
 504     (macrolet ((frob (lispvar alienvar)
 505                  `(if (zerop ,lispvar)
 506                       (int-sap 0)
 507                       (alien-sap (addr ,alienvar)))))
 508       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 509                 (* (struct fd-set)) (* (struct timeval)))
 510                (values result
 511                        (fd-set-to-num nfds rdf)
 512                        (fd-set-to-num nfds wrf)
 513                        (fd-set-to-num nfds xpf))
 514                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 515                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 516 \f
 517 ;;;; sys/stat.h
 518
 519 ;;; This is a structure defined in src/runtime/wrap.c, to look
 520 ;;; basically like "struct stat" according to stat(2). It may not
 521 ;;; actually correspond to the real in-memory stat structure that the
 522 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 523 ;;; stat macros, and trying to keep Lisp code in correspondence with
 524 ;;; it is more pain than it's worth, so we just let our C runtime
 525 ;;; synthesize a nice consistent structure for us.
 526 ;;;
 527 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 528 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn's support
 529 ;;; those. We don't actually access that field anywhere, though, so
 530 ;;; until we can get 64 bit alien support it'll do. Also note that
 531 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 532 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 533 ;;; longer than 32 bits anyway, right?":-|
 534 (def-alien-type nil
 535   (struct wrapped_stat
 536     (st-dev unsigned-long)              ; would be dev-t in a real stat
 537     (st-ino ino-t)
 538     (st-mode mode-t)
 539     (st-nlink  nlink-t)
 540     (st-uid  uid-t)
 541     (st-gid  gid-t)
 542     (st-rdev unsigned-long)             ; would be dev-t in a real stat
 543     (st-size unsigned-long)             ; would be off-t in a real stat
 544     (st-blksize unsigned-long)
 545     (st-blocks unsigned-long)
 546     (st-atime time-t)
 547     (st-mtime time-t)
 548     (st-ctime time-t)))
 549
 550 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 551 ;;; family of Unix system calls
 552 ;;;
 553 ;;; FIXME: I think this should probably not be INLINE. However, when
 554 ;;; this was not inline, it seemed to cause memory corruption
 555 ;;; problems. My first guess is that it's a bug in the FFI code, where
 556 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 557 ;;; around a call to a function returning >10 values. But I didn't try
 558 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 559 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 560 ;;; output in the not-inlined case and see whether there's a problem,
 561 ;;; and maybe even find a fix..
 562 (declaim (inline %extract-stat-results))
 563 (defun %extract-stat-results (wrapped-stat)
 564   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 565   (values t
 566           (slot wrapped-stat 'st-dev)
 567           (slot wrapped-stat 'st-ino)
 568           (slot wrapped-stat 'st-mode)
 569           (slot wrapped-stat 'st-nlink)
 570           (slot wrapped-stat 'st-uid)
 571           (slot wrapped-stat 'st-gid)
 572           (slot wrapped-stat 'st-rdev)
 573           (slot wrapped-stat 'st-size)
 574           (slot wrapped-stat 'st-atime)
 575           (slot wrapped-stat 'st-mtime)
 576           (slot wrapped-stat 'st-ctime)
 577           (slot wrapped-stat 'st-blksize)
 578           (slot wrapped-stat 'st-blocks)))
 579
 580 ;;; Unix system calls in the stat(2) family are handled by calls to
 581 ;;; C-level wrapper functions which copy all the raw "struct stat"
 582 ;;; slots into the system-independent wrapped_stat format.
 583 ;;;    stat(2) <->  stat_wrapper()
 584 ;;;   fstat(2) <-> fstat_wrapper()
 585 ;;;   lstat(2) <-> lstat_wrapper()
 586 (defun unix-stat (name)
 587   (declare (type unix-pathname name))
 588   (with-alien ((buf (struct wrapped_stat)))
 589     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 590              (%extract-stat-results (addr buf))
 591              name (addr buf))))
 592 (defun unix-lstat (name)
 593   (declare (type unix-pathname name))
 594   (with-alien ((buf (struct wrapped_stat)))
 595     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 596              (%extract-stat-results (addr buf))
 597              name (addr buf))))
 598 (defun unix-fstat (fd)
 599   (declare (type unix-fd fd))
 600   (with-alien ((buf (struct wrapped_stat)))
 601     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 602              (%extract-stat-results (addr buf))
 603              fd (addr buf))))
 604 \f
 605 ;;;; time.h
 606
 607 ;; the POSIX.4 structure for a time value. This is like a "struct
 608 ;; timeval" but has nanoseconds instead of microseconds.
 609 (def-alien-type nil
 610     (struct timespec
 611             (tv-sec long)   ; seconds
 612             (tv-nsec long))) ; nanoseconds
 613
 614 ;; used by other time functions
 615 (def-alien-type nil
 616     (struct tm
 617             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 618             (tm-min int)   ; Minutes.   [0-59]
 619             (tm-hour int)  ; Hours.     [0-23]
 620             (tm-mday int)  ; Day.       [1-31]
 621             (tm-mon int)   ; Month.     [0-11]
 622             (tm-year int)  ; Year - 1900.
 623             (tm-wday int)  ; Day of week. [0-6]
 624             (tm-yday int)  ; Days in year. [0-365]
 625             (tm-isdst int) ; DST.       [-1/0/1]
 626             (tm-gmtoff long) ;  Seconds east of UTC.
 627             (tm-zone c-string))) ; Timezone abbreviation.
 628
 629 (def-alien-routine get-timezone sb!c-call:void
 630   (when sb!c-call:long :in)
 631   (minutes-west sb!c-call:int :out)
 632   (daylight-savings-p sb!alien:boolean :out))
 633
 634 (defun unix-get-minutes-west (secs)
 635   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 636     (declare (ignore ignore) (ignore dst))
 637     (values minutes)))
 638
 639 (defun unix-get-timezone (secs)
 640   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 641     (declare (ignore ignore) (ignore minutes))
 642     (values (deref unix-tzname (if dst 1 0)))))
 643
 644 \f
 645 ;;;; sys/time.h
 646
 647 ;;; Structure crudely representing a timezone. KLUDGE: This is
 648 ;;; obsolete and should never be used.
 649 (def-alien-type nil
 650   (struct timezone
 651     (tz-minuteswest int)                ; minutes west of Greenwich
 652     (tz-dsttime int)))                  ; type of dst correction
 653
 654 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 655 ;;; and microseconds of the current time of day, the timezone (in
 656 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 657 ;;; doesn't work, it returns NIL and the errno.
 658 #!-sb-fluid (declaim (inline unix-gettimeofday))
 659 (defun unix-gettimeofday ()
 660   (with-alien ((tv (struct timeval))
 661                (tz (struct timezone)))
 662     (syscall* ("gettimeofday" (* (struct timeval))
 663                               (* (struct timezone)))
 664               (values T
 665                       (slot tv 'tv-sec)
 666                       (slot tv 'tv-usec)
 667                       (slot tz 'tz-minuteswest)
 668                       (slot tz 'tz-dsttime))
 669               (addr tv)
 670               (addr tz))))
 671 \f
 672
 673 (defconstant ENOENT 2) ; Unix error code, "No such file or directory"
 674 (defconstant EINTR 4) ; Unix error code, "Interrupted system call"
 675 (defconstant EIO 5) ; Unix error code, "I/O error"
 676 (defconstant EEXIST 17) ; Unix error code, "File exists"
 677 (defconstant ESPIPE 29) ; Unix error code, "Illegal seek"
 678 (defconstant EWOULDBLOCK 11) ; Unix error code, "Operation would block"
 679 ;;; FIXME: Many Unix error code definitions were deleted from the old
 680 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 681 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 682 ;;; unused symbols in package exports, but if I don't, there are
 683 ;;; enough of them all in one place here that they should probably be
 684 ;;; removed by hand.
 685 \f
 686 \f
 687 ;;;; support routines for dealing with Unix pathnames
 688
 689 (defun unix-file-kind (name &optional check-for-links)
 690   #!+sb-doc
 691   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 692   (declare (simple-string name))
 693   (multiple-value-bind (res dev ino mode)
 694       (if check-for-links (unix-lstat name) (unix-stat name))
 695     (declare (type (or fixnum null) mode)
 696              (ignore dev ino))
 697     (when res
 698       (let ((kind (logand mode s-ifmt)))
 699         (cond ((eql kind s-ifdir) :directory)
 700               ((eql kind s-ifreg) :file)
 701               ((eql kind s-iflnk) :link)
 702               (t :special))))))
 703
 704 ;;; Return the pathname with all symbolic links resolved.
 705 ;;;
 706 ;;; FIXME: Could we just use Unix readlink(2) instead?
 707 (defun unix-resolve-links (pathname)
 708   (declare (simple-string pathname))
 709   (let ((len (length pathname))
 710         (pending pathname))
 711     (declare (fixnum len) (simple-string pending))
 712     (if (zerop len)
 713         pathname
 714         (let ((result (make-string 1024 :initial-element (code-char 0)))
 715               (fill-ptr 0)
 716               (name-start 0))
 717           (loop
 718             (let* ((name-end (or (position #\/ pending :start name-start) len))
 719                    (new-fill-ptr (+ fill-ptr (- name-end name-start))))
 720               (replace result pending
 721                        :start1 fill-ptr
 722                        :end1 new-fill-ptr
 723                        :start2 name-start
 724                        :end2 name-end)
 725               (let ((kind (unix-file-kind (if (zerop name-end) "/" result) t)))
 726                 (unless kind (return nil))
 727                 (cond ((eq kind :link)
 728                        (multiple-value-bind (link err) (unix-readlink result)
 729                          (unless link
 730                            (error 'simple-file-error
 731                                   :pathname pathname
 732                                   :format-control
 733                                   "~@<error reading link ~S: ~2I~_~A~:>"
 734                                   :format-arguments (list (subseq
 735                                                            result 0 fill-ptr)
 736                                                           (strerror err))))
 737                          (cond ((or (zerop (length link))
 738                                     (char/= (schar link 0) #\/))
 739                                 ;; It's a relative link.
 740                                 (fill result (code-char 0)
 741                                       :start fill-ptr
 742                                       :end new-fill-ptr))
 743                                ((string= result "/../" :end1 4)
 744                                 ;; It's across the super-root.
 745                                 (let ((slash (or (position #\/ result :start 4)
 746                                                  0)))
 747                                   (fill result (code-char 0)
 748                                         :start slash
 749                                         :end new-fill-ptr)
 750                                   (setf fill-ptr slash)))
 751                                (t
 752                                 ;; It's absolute.
 753                                 (and (> (length link) 0)
 754                                      (char= (schar link 0) #\/))
 755                                 (fill result (code-char 0) :end new-fill-ptr)
 756                                 (setf fill-ptr 0)))
 757                          (setf pending
 758                                (if (= name-end len)
 759                                    link
 760                                    (concatenate 'simple-string
 761                                                 link
 762                                                 (subseq pending name-end))))
 763                          (setf len (length pending))
 764                          (setf name-start 0)))
 765                       ((= name-end len)
 766                        (return (subseq result 0 new-fill-ptr)))
 767                       ((eq kind :directory)
 768                        (setf (schar result new-fill-ptr) #\/)
 769                        (setf fill-ptr (1+ new-fill-ptr))
 770                        (setf name-start (1+ name-end)))
 771                       (t
 772                        (return nil))))))))))
 773
 774 (defun unix-simplify-pathname (src)
 775   (declare (simple-string src))
 776   (let* ((src-len (length src))
 777          (dst (make-string src-len))
 778          (dst-len 0)
 779          (dots 0)
 780          (last-slash nil))
 781     (macrolet ((deposit (char)
 782                         `(progn
 783                            (setf (schar dst dst-len) ,char)
 784                            (incf dst-len))))
 785       (dotimes (src-index src-len)
 786         (let ((char (schar src src-index)))
 787           (cond ((char= char #\.)
 788                  (when dots
 789                    (incf dots))
 790                  (deposit char))
 791                 ((char= char #\/)
 792                  (case dots
 793                    (0
 794                     ;; Either ``/...' or ``...//...'
 795                     (unless last-slash
 796                       (setf last-slash dst-len)
 797                       (deposit char)))
 798                    (1
 799                     ;; Either ``./...'' or ``..././...''
 800                     (decf dst-len))
 801                    (2
 802                     ;; We've found ..
 803                     (cond
 804                      ((and last-slash (not (zerop last-slash)))
 805                       ;; There is something before this ..
 806                       (let ((prev-prev-slash
 807                              (position #\/ dst :end last-slash :from-end t)))
 808                         (cond ((and (= (+ (or prev-prev-slash 0) 2)
 809                                        last-slash)
 810                                     (char= (schar dst (- last-slash 2)) #\.)
 811                                     (char= (schar dst (1- last-slash)) #\.))
 812                                ;; The something before this .. is another ..
 813                                (deposit char)
 814                                (setf last-slash dst-len))
 815                               (t
 816                                ;; The something is some directory or other.
 817                                (setf dst-len
 818                                      (if prev-prev-slash
 819                                          (1+ prev-prev-slash)
 820                                          0))
 821                                (setf last-slash prev-prev-slash)))))
 822                      (t
 823                       ;; There is nothing before this .., so we need to keep it
 824                       (setf last-slash dst-len)
 825                       (deposit char))))
 826                    (t
 827                     ;; Something other than a dot between slashes.
 828                     (setf last-slash dst-len)
 829                     (deposit char)))
 830                  (setf dots 0))
 831                 (t
 832                  (setf dots nil)
 833                  (setf (schar dst dst-len) char)
 834                  (incf dst-len))))))
 835     (when (and last-slash (not (zerop last-slash)))
 836       (case dots
 837         (1
 838          ;; We've got  ``foobar/.''
 839          (decf dst-len))
 840         (2
 841          ;; We've got ``foobar/..''
 842          (unless (and (>= last-slash 2)
 843                       (char= (schar dst (1- last-slash)) #\.)
 844                       (char= (schar dst (- last-slash 2)) #\.)
 845                       (or (= last-slash 2)
 846                           (char= (schar dst (- last-slash 3)) #\/)))
 847            (let ((prev-prev-slash
 848                   (position #\/ dst :end last-slash :from-end t)))
 849              (if prev-prev-slash
 850                  (setf dst-len (1+ prev-prev-slash))
 851                  (return-from unix-simplify-pathname "./")))))))
 852     (cond ((zerop dst-len)
 853            "./")
 854           ((= dst-len src-len)
 855            dst)
 856           (t
 857            (subseq dst 0 dst-len)))))
 858 \f
 859 ;;;; stuff not yet found in the header files
 860 ;;;;
 861 ;;;; Abandon all hope who enters here...
 862
 863 ;;; not checked for linux...
 864 (defmacro fd-set (offset fd-set)
 865   (let ((word (gensym))
 866         (bit (gensym)))
 867     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 868        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 869              (logior (truly-the (unsigned-byte 32) (ash 1 ,bit))
 870                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 871
 872 ;;; not checked for linux...
 873 (defmacro fd-clr (offset fd-set)
 874   (let ((word (gensym))
 875         (bit (gensym)))
 876     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 877        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 878              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 879                      (sb!kernel:32bit-logical-not
 880                       (truly-the (unsigned-byte 32) (ash 1 ,bit))))))))
 881
 882 ;;; not checked for linux...
 883 (defmacro fd-isset (offset fd-set)
 884   (let ((word (gensym))
 885         (bit (gensym)))
 886     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 887        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 888
 889 ;;; not checked for linux...
 890 (defmacro fd-zero (fd-set)
 891   `(progn
 892      ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 893          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 894
 895