src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69      (if (minusp result)
  70          (values nil (get-errno))
  71          ,success-form)))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  78                                 ,@args)))
  79      (if (minusp result)
  80          (error "Syscall ~A failed: ~A" ,name (strerror))
  81          ,success-form)))
  82
  83 (/show0 "unix.lisp 109")
  84
  85 (defmacro void-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  87
  88 (defmacro int-syscall ((name &rest arg-types) &rest args)
  89   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  90 \f
  91 ;;;; hacking the Unix environment
  92
  93 (define-alien-routine ("getenv" posix-getenv) c-string
  94   "Return the \"value\" part of the environment string \"name=value\" which
  95    corresponds to NAME, or NIL if there is none."
  96   (name c-string))
  97 \f
  98 ;;; from stdio.h
  99
 100 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 101 ;;; error code is returned if an error occurs.
 102 (defun unix-rename (name1 name2)
 103   (declare (type unix-pathname name1 name2))
 104   (void-syscall ("rename" c-string c-string) name1 name2))
 105 \f
 106 ;;; from sys/types.h and gnu/types.h
 107
 108 (/show0 "unix.lisp 220")
 109
 110 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 111 ;;; like this unless we have extreme provocation. Reading directories
 112 ;;; is not extreme enough, since it doesn't need to be blindingly
 113 ;;; fast: we can just implement those functions in C as a wrapper
 114 ;;; layer.
 115 (define-alien-type fd-mask unsigned-long)
 116
 117 (eval-when (:compile-toplevel :load-toplevel :execute)
 118   (defconstant fd-setsize 1024))
 119
 120 (define-alien-type nil
 121   (struct fd-set
 122           (fds-bits (array fd-mask #.(/ fd-setsize 32)))))
 123
 124 (/show0 "unix.lisp 304")
 125 \f
 126 \f
 127 ;;;; fcntl.h
 128 ;;;;
 129 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 130
 131 ;;; Open the file whose pathname is specified by PATH for reading
 132 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 133 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 134 ;;;
 135 ;;; If the O_CREAT flag is specified, then the file is created with a
 136 ;;; permission of argument MODE if the file doesn't exist. An integer
 137 ;;; file descriptor is returned by UNIX-OPEN.
 138 (defun unix-open (path flags mode)
 139   (declare (type unix-pathname path)
 140            (type fixnum flags)
 141            (type unix-file-mode mode))
 142   (int-syscall ("open" c-string int int) path flags mode))
 143
 144 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 145 ;;; associated with it.
 146 (/show0 "unix.lisp 391")
 147 (defun unix-close (fd)
 148   (declare (type unix-fd fd))
 149   (void-syscall ("close" int) fd))
 150 \f
 151 ;;;; timebits.h
 152
 153 ;; A time value that is accurate to the nearest
 154 ;; microsecond but also has a range of years.
 155 (define-alien-type nil
 156   (struct timeval
 157           (tv-sec time-t)               ; seconds
 158           (tv-usec time-t)))            ; and microseconds
 159 \f
 160 ;;;; resourcebits.h
 161
 162 (defconstant rusage_self 0) ; the calling process
 163 (defconstant rusage_children -1) ; terminated child processes
 164 (defconstant rusage_both -2)
 165
 166 (define-alien-type nil
 167   (struct rusage
 168     (ru-utime (struct timeval))     ; user time used
 169     (ru-stime (struct timeval))     ; system time used.
 170     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 171     (ru-ixrss long)                 ; integral shared memory size
 172     (ru-idrss long)                 ; integral unshared data size
 173     (ru-isrss long)                 ; integral unshared stack size
 174     (ru-minflt long)                ; page reclaims
 175     (ru-majflt long)                ; page faults
 176     (ru-nswap long)                 ; swaps
 177     (ru-inblock long)               ; block input operations
 178     (ru-oublock long)               ; block output operations
 179     (ru-msgsnd long)                ; messages sent
 180     (ru-msgrcv long)                ; messages received
 181     (ru-nsignals long)              ; signals received
 182     (ru-nvcsw long)                 ; voluntary context switches
 183     (ru-nivcsw long)))              ; involuntary context switches
 184 \f
 185 ;;;; unistd.h
 186
 187 ;;; Given a file path (a string) and one of four constant modes,
 188 ;;; return T if the file is accessible with that mode and NIL if not.
 189 ;;; When NIL, also return an errno value with NIL which tells why the
 190 ;;; file was not accessible.
 191 ;;;
 192 ;;; The access modes are:
 193 ;;;   r_ok     Read permission.
 194 ;;;   w_ok     Write permission.
 195 ;;;   x_ok     Execute permission.
 196 ;;;   f_ok     Presence of file.
 197 (defun unix-access (path mode)
 198   (declare (type unix-pathname path)
 199            (type (mod 8) mode))
 200   (void-syscall ("access" c-string int) path mode))
 201
 202 ;;; values for the second argument to UNIX-LSEEK
 203 (defconstant l_set 0) ; to set the file pointer
 204 (defconstant l_incr 1) ; to increment the file pointer
 205 (defconstant l_xtnd 2) ; to extend the file size
 206
 207 ;;; Accept a file descriptor and move the file pointer ahead
 208 ;;; a certain offset for that file. WHENCE can be any of the following:
 209 ;;;  L_SET     Set the file pointer.
 210 ;;;  L_INCR    Increment the file pointer.
 211 ;;;  L_XTND    Extend the file size.
 212 (defun unix-lseek (fd offset whence)
 213   (declare (type unix-fd fd)
 214            (type (unsigned-byte 32) offset)
 215            (type (integer 0 2) whence))
 216   #!-(and x86 bsd)
 217   (int-syscall ("lseek" int off-t int) fd offset whence)
 218   ;; Need a 64-bit return value type for this. TBD. For now,
 219   ;; don't use this with any 2G+ partitions.
 220   #!+(and x86 bsd)
 221   (int-syscall ("lseek" int unsigned-long unsigned-long int)
 222                fd offset 0 whence))
 223
 224 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 225 ;;; It attempts to read len bytes from the device associated with fd
 226 ;;; and store them into the buffer. It returns the actual number of
 227 ;;; bytes read.
 228 (defun unix-read (fd buf len)
 229   (declare (type unix-fd fd)
 230            (type (unsigned-byte 32) len))
 231
 232   (int-syscall ("read" int (* char) int) fd buf len))
 233
 234 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 235 ;;; length to write. It attempts to write len bytes to the device
 236 ;;; associated with fd from the the buffer starting at offset. It returns
 237 ;;; the actual number of bytes written.
 238 (defun unix-write (fd buf offset len)
 239   (declare (type unix-fd fd)
 240            (type (unsigned-byte 32) offset len))
 241   (int-syscall ("write" int (* char) int)
 242                fd
 243                (with-alien ((ptr (* char) (etypecase buf
 244                                             ((simple-array * (*))
 245                                              (vector-sap buf))
 246                                             (system-area-pointer
 247                                              buf))))
 248                  (addr (deref ptr offset)))
 249                len))
 250
 251 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 252 ;;; output pipe. Return two values: if no error occurred the first
 253 ;;; value is the pipe to be read from and the second is can be written
 254 ;;; to. If an error occurred the first value is NIL and the second the
 255 ;;; unix error code.
 256 (defun unix-pipe ()
 257   (with-alien ((fds (array int 2)))
 258     (syscall ("pipe" (* int))
 259              (values (deref fds 0) (deref fds 1))
 260              (cast fds (* int)))))
 261
 262 (defun unix-mkdir (name mode)
 263   (declare (type unix-pathname name)
 264            (type unix-file-mode mode))
 265   (void-syscall ("mkdir" c-string int) name mode))
 266
 267 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 268 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 269 (defun newcharstar-string (newcharstar)
 270   (declare (type (alien (* char)) newcharstar))
 271   (if (null-alien newcharstar)
 272       nil
 273       (prog1
 274           (cast newcharstar c-string)
 275         (free-alien newcharstar))))
 276
 277 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 278 ;;; style returned by getcwd() (no trailing slash character).
 279 (defun posix-getcwd ()
 280   ;; This implementation relies on a BSD/Linux extension to getcwd()
 281   ;; behavior, automatically allocating memory when a null buffer
 282   ;; pointer is used. On a system which doesn't support that
 283   ;; extension, it'll have to be rewritten somehow.
 284   ;;
 285   ;; SunOS and OSF/1 provide almost as useful an extension: if given a null
 286   ;; buffer pointer, it will automatically allocate size space. The
 287   ;; KLUDGE in this solution arises because we have just read off
 288   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 289   ;; a constant. Going the grovel_headers route doesn't seem to be
 290   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 291   ;; unistd.h.
 292   #!-(or linux openbsd freebsd sunos osf1) (,stub,)
 293   #!+(or linux openbsd freebsd sunos osf1)
 294   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 295                                                        (function (* char)
 296                                                                  (* char)
 297                                                                  size-t))
 298                                          nil
 299                                          #!+(or linux openbsd freebsd) 0
 300                                          #!+(or sunos osf1) 1025))
 301       (simple-perror "getcwd")))
 302
 303 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 304 ;;; by a slash character.
 305 (defun posix-getcwd/ ()
 306   (concatenate 'string (posix-getcwd) "/"))
 307
 308 ;;; Convert at the UNIX level from a possibly relative filename to
 309 ;;; an absolute filename.
 310 ;;;
 311 ;;; FIXME: Do we still need this even as we switch to
 312 ;;; *DEFAULT-PATHNAME-DEFAULTS*? I think maybe we do, since it seems
 313 ;;; to be valid for the user to set *DEFAULT-PATHNAME-DEFAULTS* to
 314 ;;; have a NIL directory component, and then this'd be the only way to
 315 ;;; interpret a relative directory specification. But I don't find the
 316 ;;; ANSI pathname documentation to be a model of clarity. Maybe
 317 ;;; someone who understands it better can take a look at this.. -- WHN
 318 (defun unix-maybe-prepend-current-directory (name)
 319   (declare (simple-string name))
 320   (if (and (> (length name) 0) (char= (schar name 0) #\/))
 321       name
 322       (concatenate 'simple-string (posix-getcwd/) name)))
 323
 324 ;;; Duplicate an existing file descriptor (given as the argument) and
 325 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 326 ;;; number are returned.
 327 (defun unix-dup (fd)
 328   (declare (type unix-fd fd))
 329   (int-syscall ("dup" int) fd))
 330
 331 ;;; Terminate the current process with an optional error code. If
 332 ;;; successful, the call doesn't return. If unsuccessful, the call
 333 ;;; returns NIL and an error number.
 334 (defun unix-exit (&optional (code 0))
 335   (declare (type (signed-byte 32) code))
 336   (void-syscall ("exit" int) code))
 337
 338 ;;; Return the process id of the current process.
 339 (define-alien-routine ("getpid" unix-getpid) int)
 340
 341 ;;; Return the real user id associated with the current process.
 342 (define-alien-routine ("getuid" unix-getuid) int)
 343
 344 ;;; Translate a user id into a login name.
 345 (defun uid-username (uid)
 346   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 347                                                        (function (* char) int))
 348                                          uid))
 349       (error "found no match for Unix uid=~S" uid)))
 350
 351 ;;; Return the namestring of the home directory, being careful to
 352 ;;; include a trailing #\/
 353 (defun uid-homedir (uid)
 354   (or (newcharstar-string (alien-funcall (extern-alien "uid_homedir"
 355                                                        (function (* char) int))
 356                                          uid))
 357       (error "failed to resolve home directory for Unix uid=~S" uid)))
 358
 359 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 360 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 361 ;;; failure.
 362 (defun unix-readlink (path)
 363   (declare (type unix-pathname path))
 364   (with-alien ((ptr (* char)
 365                     (alien-funcall (extern-alien
 366                                     "wrapped_readlink"
 367                                     (function (* char) c-string))
 368                                    path)))
 369     (if (null-alien ptr)
 370         (values nil (get-errno))
 371         (multiple-value-prog1
 372             (values (with-alien ((c-string c-string ptr)) c-string)
 373                     nil)
 374           (free-alien ptr)))))
 375
 376 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 377 ;;; name and the file if this is the last link.
 378 (defun unix-unlink (name)
 379   (declare (type unix-pathname name))
 380   (void-syscall ("unlink" c-string) name))
 381
 382 ;;; Return the name of the host machine as a string.
 383 (defun unix-gethostname ()
 384   (with-alien ((buf (array char 256)))
 385     (syscall ("gethostname" (* char) int)
 386              (cast buf c-string)
 387              (cast buf (* char)) 256)))
 388
 389 ;;; Write the core image of the file described by FD to disk.
 390 (defun unix-fsync (fd)
 391   (declare (type unix-fd fd))
 392   (void-syscall ("fsync" int) fd))
 393 \f
 394 ;;;; sys/ioctl.h
 395
 396 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 397 ;;; descriptors. See the UNIX Programmer's Manual for more
 398 ;;; information.
 399 (defun unix-ioctl (fd cmd arg)
 400   (declare (type unix-fd fd)
 401            (type (unsigned-byte 32) cmd))
 402   (void-syscall ("ioctl" int unsigned-int (* char)) fd cmd arg))
 403 \f
 404 ;;;; sys/resource.h
 405
 406 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 407 ;;;
 408 ;;; This is like getrusage(2), except it returns only the system and
 409 ;;; user time, and returns the seconds and microseconds as separate
 410 ;;; values.
 411 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 412 (defun unix-fast-getrusage (who)
 413   (declare (values (member t)
 414                    (unsigned-byte 31) (integer 0 1000000)
 415                    (unsigned-byte 31) (integer 0 1000000)))
 416   (with-alien ((usage (struct rusage)))
 417     (syscall* ("getrusage" int (* (struct rusage)))
 418               (values t
 419                       (slot (slot usage 'ru-utime) 'tv-sec)
 420                       (slot (slot usage 'ru-utime) 'tv-usec)
 421                       (slot (slot usage 'ru-stime) 'tv-sec)
 422                       (slot (slot usage 'ru-stime) 'tv-usec))
 423               who (addr usage))))
 424
 425 ;;; Return information about the resource usage of the process
 426 ;;; specified by WHO. WHO can be either the current process
 427 ;;; (rusage_self) or all of the terminated child processes
 428 ;;; (rusage_children). NIL and an error number is returned if the call
 429 ;;; fails.
 430 (defun unix-getrusage (who)
 431   (with-alien ((usage (struct rusage)))
 432     (syscall ("getrusage" int (* (struct rusage)))
 433               (values t
 434                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 435                          (slot (slot usage 'ru-utime) 'tv-usec))
 436                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 437                          (slot (slot usage 'ru-stime) 'tv-usec))
 438                       (slot usage 'ru-maxrss)
 439                       (slot usage 'ru-ixrss)
 440                       (slot usage 'ru-idrss)
 441                       (slot usage 'ru-isrss)
 442                       (slot usage 'ru-minflt)
 443                       (slot usage 'ru-majflt)
 444                       (slot usage 'ru-nswap)
 445                       (slot usage 'ru-inblock)
 446                       (slot usage 'ru-oublock)
 447                       (slot usage 'ru-msgsnd)
 448                       (slot usage 'ru-msgrcv)
 449                       (slot usage 'ru-nsignals)
 450                       (slot usage 'ru-nvcsw)
 451                       (slot usage 'ru-nivcsw))
 452               who (addr usage))))
 453 \f
 454 ;;;; sys/select.h
 455
 456 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 457
 458 ;;; Perform the UNIX select(2) system call.
 459 (declaim (inline unix-fast-select)) ; (used to be a macro in CMU CL)
 460 (defun unix-fast-select (num-descriptors
 461                          read-fds write-fds exception-fds
 462                          timeout-secs &optional (timeout-usecs 0))
 463   (declare (type (integer 0 #.fd-setsize) num-descriptors)
 464            (type (or (alien (* (struct fd-set))) null)
 465                  read-fds write-fds exception-fds)
 466            (type (or null (unsigned-byte 31)) timeout-secs)
 467            (type (unsigned-byte 31) timeout-usecs))
 468   ;; FIXME: CMU CL had
 469   ;;   (declare (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 470   ;; here. Is that important for SBCL? If so, why? Profiling might tell us..
 471   (with-alien ((tv (struct timeval)))
 472     (when timeout-secs
 473       (setf (slot tv 'tv-sec) timeout-secs)
 474       (setf (slot tv 'tv-usec) timeout-usecs))
 475     (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 476                   (* (struct fd-set)) (* (struct timeval)))
 477                  num-descriptors read-fds write-fds exception-fds
 478                  (if timeout-secs (alien-sap (addr tv)) (int-sap 0)))))
 479
 480 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 481 ;;; to happen on one of them or to time out.
 482 (defmacro num-to-fd-set (fdset num)
 483   `(if (fixnump ,num)
 484        (progn
 485          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 486          ,@(loop for index upfrom 1 below (/ fd-setsize 32)
 487              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 488        (progn
 489          ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 490              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 491                             (ldb (byte 32 ,(* index 32)) ,num))))))
 492
 493 (defmacro fd-set-to-num (nfds fdset)
 494   `(if (<= ,nfds 32)
 495        (deref (slot ,fdset 'fds-bits) 0)
 496        (+ ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 497               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 498                             ,(* index 32))))))
 499
 500 ;;; Examine the sets of descriptors passed as arguments to see whether
 501 ;;; they are ready for reading and writing. See the UNIX Programmer's
 502 ;;; Manual for more information.
 503 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 504   (declare (type (integer 0 #.FD-SETSIZE) nfds)
 505            (type unsigned-byte rdfds wrfds xpfds)
 506            (type (or (unsigned-byte 31) null) to-secs)
 507            (type (unsigned-byte 31) to-usecs)
 508            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 509   (with-alien ((tv (struct timeval))
 510                (rdf (struct fd-set))
 511                (wrf (struct fd-set))
 512                (xpf (struct fd-set)))
 513     (when to-secs
 514       (setf (slot tv 'tv-sec) to-secs)
 515      (setf (slot tv 'tv-usec) to-usecs))
 516     (num-to-fd-set rdf rdfds)
 517     (num-to-fd-set wrf wrfds)
 518     (num-to-fd-set xpf xpfds)
 519     (macrolet ((frob (lispvar alienvar)
 520                  `(if (zerop ,lispvar)
 521                       (int-sap 0)
 522                       (alien-sap (addr ,alienvar)))))
 523       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 524                 (* (struct fd-set)) (* (struct timeval)))
 525                (values result
 526                        (fd-set-to-num nfds rdf)
 527                        (fd-set-to-num nfds wrf)
 528                        (fd-set-to-num nfds xpf))
 529                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 530                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 531 \f
 532 ;;;; sys/stat.h
 533
 534 ;;; This is a structure defined in src/runtime/wrap.c, to look
 535 ;;; basically like "struct stat" according to stat(2). It may not
 536 ;;; actually correspond to the real in-memory stat structure that the
 537 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 538 ;;; stat macros, and trying to keep Lisp code in correspondence with
 539 ;;; it is more pain than it's worth, so we just let our C runtime
 540 ;;; synthesize a nice consistent structure for us.
 541 ;;;
 542 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 543 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn's support
 544 ;;; those. We don't actually access that field anywhere, though, so
 545 ;;; until we can get 64 bit alien support it'll do. Also note that
 546 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 547 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 548 ;;; longer than 32 bits anyway, right?":-|
 549 (define-alien-type nil
 550   (struct wrapped_stat
 551     (st-dev unsigned-long)              ; would be dev-t in a real stat
 552     (st-ino ino-t)
 553     (st-mode mode-t)
 554     (st-nlink  nlink-t)
 555     (st-uid  uid-t)
 556     (st-gid  gid-t)
 557     (st-rdev unsigned-long)             ; would be dev-t in a real stat
 558     (st-size unsigned-long)             ; would be off-t in a real stat
 559     (st-blksize unsigned-long)
 560     (st-blocks unsigned-long)
 561     (st-atime time-t)
 562     (st-mtime time-t)
 563     (st-ctime time-t)))
 564
 565 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 566 ;;; family of Unix system calls
 567 ;;;
 568 ;;; FIXME: I think this should probably not be INLINE. However, when
 569 ;;; this was not inline, it seemed to cause memory corruption
 570 ;;; problems. My first guess is that it's a bug in the FFI code, where
 571 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 572 ;;; around a call to a function returning >10 values. But I didn't try
 573 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 574 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 575 ;;; output in the not-inlined case and see whether there's a problem,
 576 ;;; and maybe even find a fix..
 577 (declaim (inline %extract-stat-results))
 578 (defun %extract-stat-results (wrapped-stat)
 579   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 580   (values t
 581           (slot wrapped-stat 'st-dev)
 582           (slot wrapped-stat 'st-ino)
 583           (slot wrapped-stat 'st-mode)
 584           (slot wrapped-stat 'st-nlink)
 585           (slot wrapped-stat 'st-uid)
 586           (slot wrapped-stat 'st-gid)
 587           (slot wrapped-stat 'st-rdev)
 588           (slot wrapped-stat 'st-size)
 589           (slot wrapped-stat 'st-atime)
 590           (slot wrapped-stat 'st-mtime)
 591           (slot wrapped-stat 'st-ctime)
 592           (slot wrapped-stat 'st-blksize)
 593           (slot wrapped-stat 'st-blocks)))
 594
 595 ;;; Unix system calls in the stat(2) family are handled by calls to
 596 ;;; C-level wrapper functions which copy all the raw "struct stat"
 597 ;;; slots into the system-independent wrapped_stat format.
 598 ;;;    stat(2) <->  stat_wrapper()
 599 ;;;   fstat(2) <-> fstat_wrapper()
 600 ;;;   lstat(2) <-> lstat_wrapper()
 601 (defun unix-stat (name)
 602   (declare (type unix-pathname name))
 603   (with-alien ((buf (struct wrapped_stat)))
 604     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 605              (%extract-stat-results (addr buf))
 606              name (addr buf))))
 607 (defun unix-lstat (name)
 608   (declare (type unix-pathname name))
 609   (with-alien ((buf (struct wrapped_stat)))
 610     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 611              (%extract-stat-results (addr buf))
 612              name (addr buf))))
 613 (defun unix-fstat (fd)
 614   (declare (type unix-fd fd))
 615   (with-alien ((buf (struct wrapped_stat)))
 616     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 617              (%extract-stat-results (addr buf))
 618              fd (addr buf))))
 619 \f
 620 ;;;; time.h
 621
 622 ;; the POSIX.4 structure for a time value. This is like a "struct
 623 ;; timeval" but has nanoseconds instead of microseconds.
 624 (define-alien-type nil
 625     (struct timespec
 626             (tv-sec long)   ; seconds
 627             (tv-nsec long))) ; nanoseconds
 628
 629 ;; used by other time functions
 630 (define-alien-type nil
 631     (struct tm
 632             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 633             (tm-min int)   ; Minutes.   [0-59]
 634             (tm-hour int)  ; Hours.     [0-23]
 635             (tm-mday int)  ; Day.       [1-31]
 636             (tm-mon int)   ; Month.     [0-11]
 637             (tm-year int)  ; Year - 1900.
 638             (tm-wday int)  ; Day of week. [0-6]
 639             (tm-yday int)  ; Days in year. [0-365]
 640             (tm-isdst int) ; DST.       [-1/0/1]
 641             (tm-gmtoff long) ;  Seconds east of UTC.
 642             (tm-zone c-string))) ; Timezone abbreviation.
 643
 644 (define-alien-routine get-timezone sb!alien:void
 645   (when sb!alien:long :in)
 646   (minutes-west sb!alien:int :out)
 647   (daylight-savings-p sb!alien:boolean :out))
 648
 649 (defun unix-get-minutes-west (secs)
 650   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 651     (declare (ignore ignore) (ignore dst))
 652     (values minutes)))
 653
 654 (defun unix-get-timezone (secs)
 655   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 656     (declare (ignore ignore) (ignore minutes))
 657     (values (deref unix-tzname (if dst 1 0)))))
 658
 659 \f
 660 ;;;; sys/time.h
 661
 662 ;;; Structure crudely representing a timezone. KLUDGE: This is
 663 ;;; obsolete and should never be used.
 664 (define-alien-type nil
 665   (struct timezone
 666     (tz-minuteswest int)                ; minutes west of Greenwich
 667     (tz-dsttime int)))                  ; type of dst correction
 668
 669 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 670 ;;; and microseconds of the current time of day, the timezone (in
 671 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 672 ;;; doesn't work, it returns NIL and the errno.
 673 #!-sb-fluid (declaim (inline unix-gettimeofday))
 674 (defun unix-gettimeofday ()
 675   (with-alien ((tv (struct timeval))
 676                (tz (struct timezone)))
 677     (syscall* ("gettimeofday" (* (struct timeval))
 678                               (* (struct timezone)))
 679               (values T
 680                       (slot tv 'tv-sec)
 681                       (slot tv 'tv-usec)
 682                       (slot tz 'tz-minuteswest)
 683                       (slot tz 'tz-dsttime))
 684               (addr tv)
 685               (addr tz))))
 686 \f
 687
 688 (defconstant ENOENT 2) ; Unix error code, "No such file or directory"
 689 (defconstant EINTR 4) ; Unix error code, "Interrupted system call"
 690 (defconstant EIO 5) ; Unix error code, "I/O error"
 691 (defconstant EEXIST 17) ; Unix error code, "File exists"
 692 (defconstant ESPIPE 29) ; Unix error code, "Illegal seek"
 693 (defconstant EWOULDBLOCK 11) ; Unix error code, "Operation would block"
 694 ;;; FIXME: Many Unix error code definitions were deleted from the old
 695 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 696 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 697 ;;; unused symbols in package exports, but if I don't, there are
 698 ;;; enough of them all in one place here that they should probably be
 699 ;;; removed by hand.
 700 \f
 701 \f
 702 ;;;; support routines for dealing with Unix pathnames
 703
 704 (defun unix-file-kind (name &optional check-for-links)
 705   #!+sb-doc
 706   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 707   (declare (simple-string name))
 708   (multiple-value-bind (res dev ino mode)
 709       (if check-for-links (unix-lstat name) (unix-stat name))
 710     (declare (type (or fixnum null) mode)
 711              (ignore dev ino))
 712     (when res
 713       (let ((kind (logand mode s-ifmt)))
 714         (cond ((eql kind s-ifdir) :directory)
 715               ((eql kind s-ifreg) :file)
 716               ((eql kind s-iflnk) :link)
 717               (t :special))))))
 718
 719 ;;; Is the Unix pathname PATHNAME relative, instead of absolute? (E.g.
 720 ;;; "passwd" or "etc/passwd" instead of "/etc/passwd"?)
 721 (defun relative-unix-pathname? (pathname)
 722   (declare (type simple-string pathname))
 723   (or (zerop (length pathname))
 724       (char/= (schar pathname 0) #\/)))
 725
 726 ;;; Return PATHNAME with all symbolic links resolved. PATHNAME should
 727 ;;; already be a complete absolute Unix pathname, since at least in
 728 ;;; sbcl-0.6.12.36 we're called only from TRUENAME, and only after
 729 ;;; paths have been converted to absolute paths, so we don't need to
 730 ;;; try to handle any more generality than that.
 731 (defun unix-resolve-links (pathname)
 732   (declare (type simple-string pathname))
 733   (aver (not (relative-unix-pathname? pathname)))
 734   (/noshow "entering UNIX-RESOLVE-LINKS")
 735   (loop with previous-pathnames = nil do
 736         (/noshow pathname previous-pathnames)
 737         (let ((link (unix-readlink pathname)))
 738           (/noshow link)
 739           ;; Unlike the old CMU CL code, we handle a broken symlink by
 740           ;; returning the link itself. That way, CL:TRUENAME on a
 741           ;; broken link returns the link itself, so that CL:DIRECTORY
 742           ;; can return broken links, so that even without
 743           ;; Unix-specific extensions to do interesting things with
 744           ;; them, at least Lisp programs can see them and, if
 745           ;; necessary, delete them. (This is handy e.g. when your
 746           ;; managed-by-Lisp directories are visited by Emacs, which
 747           ;; creates broken links as notes to itself.)
 748           (if (null link)
 749               (return pathname)
 750               (let ((new-pathname
 751                      (unix-simplify-pathname
 752                       (if (relative-unix-pathname? link)
 753                           (let* ((dir-len (1+ (position #\/
 754                                                         pathname
 755                                                         :from-end t)))
 756                                  (dir (subseq pathname 0 dir-len)))
 757                             (/noshow dir)
 758                             (concatenate 'string dir link))
 759                           link))))
 760                 (if (unix-file-kind new-pathname)
 761                     (setf pathname new-pathname)
 762                     (return pathname)))))
 763         ;; To generalize the principle that even if portable Lisp code
 764         ;; can't do anything interesting with a broken symlink, at
 765         ;; least it should be able to see and delete it, when we
 766         ;; detect a cyclic link, we return the link itself. (So even
 767         ;; though portable Lisp code can't do anything interesting
 768         ;; with a cyclic link, at least it can see it and delete it.)
 769         (if (member pathname previous-pathnames :test #'string=)
 770             (return pathname)
 771             (push pathname previous-pathnames))))
 772
 773 (defun unix-simplify-pathname (src)
 774   (declare (type simple-string src))
 775   (let* ((src-len (length src))
 776          (dst (make-string src-len))
 777          (dst-len 0)
 778          (dots 0)
 779          (last-slash nil))
 780     (macrolet ((deposit (char)
 781                  `(progn
 782                     (setf (schar dst dst-len) ,char)
 783                     (incf dst-len))))
 784       (dotimes (src-index src-len)
 785         (let ((char (schar src src-index)))
 786           (cond ((char= char #\.)
 787                  (when dots
 788                    (incf dots))
 789                  (deposit char))
 790                 ((char= char #\/)
 791                  (case dots
 792                    (0
 793                     ;; either ``/...' or ``...//...'
 794                     (unless last-slash
 795                       (setf last-slash dst-len)
 796                       (deposit char)))
 797                    (1
 798                     ;; either ``./...'' or ``..././...''
 799                     (decf dst-len))
 800                    (2
 801                     ;; We've found ..
 802                     (cond
 803                      ((and last-slash (not (zerop last-slash)))
 804                       ;; There is something before this ..
 805                       (let ((prev-prev-slash
 806                              (position #\/ dst :end last-slash :from-end t)))
 807                         (cond ((and (= (+ (or prev-prev-slash 0) 2)
 808                                        last-slash)
 809                                     (char= (schar dst (- last-slash 2)) #\.)
 810                                     (char= (schar dst (1- last-slash)) #\.))
 811                                ;; The something before this .. is another ..
 812                                (deposit char)
 813                                (setf last-slash dst-len))
 814                               (t
 815                                ;; The something is some directory or other.
 816                                (setf dst-len
 817                                      (if prev-prev-slash
 818                                          (1+ prev-prev-slash)
 819                                          0))
 820                                (setf last-slash prev-prev-slash)))))
 821                      (t
 822                       ;; There is nothing before this .., so we need to keep it
 823                       (setf last-slash dst-len)
 824                       (deposit char))))
 825                    (t
 826                     ;; something other than a dot between slashes
 827                     (setf last-slash dst-len)
 828                     (deposit char)))
 829                  (setf dots 0))
 830                 (t
 831                  (setf dots nil)
 832                  (setf (schar dst dst-len) char)
 833                  (incf dst-len))))))
 834     (when (and last-slash (not (zerop last-slash)))
 835       (case dots
 836         (1
 837          ;; We've got  ``foobar/.''
 838          (decf dst-len))
 839         (2
 840          ;; We've got ``foobar/..''
 841          (unless (and (>= last-slash 2)
 842                       (char= (schar dst (1- last-slash)) #\.)
 843                       (char= (schar dst (- last-slash 2)) #\.)
 844                       (or (= last-slash 2)
 845                           (char= (schar dst (- last-slash 3)) #\/)))
 846            (let ((prev-prev-slash
 847                   (position #\/ dst :end last-slash :from-end t)))
 848              (if prev-prev-slash
 849                  (setf dst-len (1+ prev-prev-slash))
 850                  (return-from unix-simplify-pathname "./")))))))
 851     (cond ((zerop dst-len)
 852            "./")
 853           ((= dst-len src-len)
 854            dst)
 855           (t
 856            (subseq dst 0 dst-len)))))
 857 \f
 858 ;;;; A magic constant for wait3().
 859 ;;;;
 860 ;;;; FIXME: This used to be defined in run-program.lisp as
 861 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
 862 ;;;; According to some of the man pages, the #o177 is part of the API
 863 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
 864 ;;;; the headers that may or may not be the same thing. To be
 865 ;;;; investigated. -- CSR, 2002-03-25
 866 (defconstant wstopped #o177)
 867
 868 \f
 869 ;;;; stuff not yet found in the header files
 870 ;;;;
 871 ;;;; Abandon all hope who enters here...
 872
 873 ;;; not checked for linux...
 874 (defmacro fd-set (offset fd-set)
 875   (let ((word (gensym))
 876         (bit (gensym)))
 877     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 878        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 879              (logior (truly-the (unsigned-byte 32) (ash 1 ,bit))
 880                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 881
 882 ;;; not checked for linux...
 883 (defmacro fd-clr (offset fd-set)
 884   (let ((word (gensym))
 885         (bit (gensym)))
 886     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 887        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 888              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 889                      (sb!kernel:32bit-logical-not
 890                       (truly-the (unsigned-byte 32) (ash 1 ,bit))))))))
 891
 892 ;;; not checked for linux...
 893 (defmacro fd-isset (offset fd-set)
 894   (let ((word (gensym))
 895         (bit (gensym)))
 896     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 897        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 898
 899 ;;; not checked for linux...
 900 (defmacro fd-zero (fd-set)
 901   `(progn
 902      ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 903          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 904
 905