src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(locally
  68     (declare (optimize (sb!c::float-accuracy 0)))
  69     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  70                                 ,@args)))
  71       (if (minusp result)
  72           (values nil (get-errno))
  73           ,success-form))))
  74
  75 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  76 ;;; returning error codes. Should only be used for syscalls that will
  77 ;;; never really get an error.
  78 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  79   `(locally
  80     (declare (optimize (sb!c::float-accuracy 0)))
  81     (let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  82                                  ,@args)))
  83       (if (minusp result)
  84           (error "Syscall ~A failed: ~A" ,name (strerror))
  85           ,success-form))))
  86
  87 (/show0 "unix.lisp 109")
  88
  89 (defmacro void-syscall ((name &rest arg-types) &rest args)
  90   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  91
  92 (defmacro int-syscall ((name &rest arg-types) &rest args)
  93   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  94
  95 (defmacro with-restarted-syscall ((&optional (value (gensym))
  96                                              (errno (gensym)))
  97                                   syscall-form &rest body)
  98   #!+sb-doc
  99   "Evaluate BODY with VALUE and ERRNO bound to the return values of
 100 SYSCALL-FORM. Repeat evaluation of SYSCALL-FORM if it is interrupted."
 101   `(let (,value ,errno)
 102      (loop (multiple-value-setq (,value ,errno)
 103              ,syscall-form)
 104         (unless #!-win32 (eql ,errno sb!unix:eintr) #!+win32 nil
 105           (return (values ,value ,errno))))
 106      ,@body))
 107
 108 #!+win32
 109 (progn
 110   (defconstant espipe 29))
 111 \f
 112 ;;;; hacking the Unix environment
 113
 114 #!-win32
 115 (define-alien-routine ("getenv" posix-getenv) c-string
 116   "Return the \"value\" part of the environment string \"name=value\" which
 117    corresponds to NAME, or NIL if there is none."
 118   (name c-string))
 119 \f
 120 ;;; from stdio.h
 121
 122 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 123 ;;; error code is returned if an error occurs.
 124 #!-win32
 125 (defun unix-rename (name1 name2)
 126   (declare (type unix-pathname name1 name2))
 127   (void-syscall ("rename" c-string c-string) name1 name2))
 128 \f
 129 ;;; from sys/types.h and gnu/types.h
 130
 131 (/show0 "unix.lisp 220")
 132
 133 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 134 ;;; like this unless we have extreme provocation. Reading directories
 135 ;;; is not extreme enough, since it doesn't need to be blindingly
 136 ;;; fast: we can just implement those functions in C as a wrapper
 137 ;;; layer.
 138 (define-alien-type fd-mask unsigned-long)
 139
 140 (eval-when (:compile-toplevel :load-toplevel :execute)
 141   (defconstant fd-setsize 1024))
 142
 143 (define-alien-type nil
 144   (struct fd-set
 145           (fds-bits (array fd-mask #.(/ fd-setsize
 146                                         sb!vm:n-machine-word-bits)))))
 147
 148 (/show0 "unix.lisp 304")
 149 \f
 150 \f
 151 ;;;; fcntl.h
 152 ;;;;
 153 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 154
 155 ;;; Open the file whose pathname is specified by PATH for reading
 156 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 157 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 158 ;;;
 159 ;;; If the O_CREAT flag is specified, then the file is created with a
 160 ;;; permission of argument MODE if the file doesn't exist. An integer
 161 ;;; file descriptor is returned by UNIX-OPEN.
 162 (defun unix-open (path flags mode)
 163   (declare (type unix-pathname path)
 164            (type fixnum flags)
 165            (type unix-file-mode mode))
 166   (int-syscall ("open" c-string int int)
 167                path
 168                (logior #!+win32 o_binary
 169                        #!+largefile o_largefile
 170                        flags)
 171                mode))
 172
 173 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 174 ;;; associated with it.
 175 (/show0 "unix.lisp 391")
 176 (defun unix-close (fd)
 177   (declare (type unix-fd fd))
 178   (void-syscall ("close" int) fd))
 179 \f
 180 ;;;; stdlib.h
 181
 182 ;;; There are good reasons to implement some OPEN options with an
 183 ;;; mkstemp(3) followed by a fchmod(2) followed by a rename(2), but we
 184 ;;; don't do that yet.  Instead, this function is used only to make a
 185 ;;; temporary file for RUN-PROGRAM.  sb_mkstemp() is a wrapper that
 186 ;;; lives in src/runtime/wrap.c.
 187 (defun unix-mkstemp (template-string)
 188   (let ((template-buffer (string-to-octets template-string)))
 189     (with-pinned-objects (template-buffer)
 190       (let ((fd (alien-funcall (extern-alien "sb_mkstemp"
 191                                              (function int (* char)))
 192                                (vector-sap template-buffer))))
 193         (if (minusp fd)
 194             (values nil (get-errno))
 195             (values fd (octets-to-string template-buffer)))))))
 196 \f
 197 ;;;; timebits.h
 198
 199 ;; A time value that is accurate to the nearest
 200 ;; microsecond but also has a range of years.
 201 ;; CLH: Note that tv-usec used to be a time-t, but that this seems
 202 ;; problematic on Darwin x86-64 (and wrong). Trying suseconds-t.
 203 #!-win32
 204 (define-alien-type nil
 205   (struct timeval
 206           (tv-sec time-t)           ; seconds
 207           (tv-usec suseconds-t)))   ; and microseconds
 208
 209 #!+win32
 210 (define-alien-type nil
 211   (struct timeval
 212           (tv-sec time-t)           ; seconds
 213           (tv-usec long)))          ; and microseconds
 214 \f
 215 ;;;; resourcebits.h
 216
 217 (defconstant rusage_self 0) ; the calling process
 218 (defconstant rusage_children -1) ; terminated child processes
 219 (defconstant rusage_both -2)
 220
 221 (define-alien-type nil
 222   (struct rusage
 223     (ru-utime (struct timeval))     ; user time used
 224     (ru-stime (struct timeval))     ; system time used.
 225     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 226     (ru-ixrss long)                 ; integral shared memory size
 227     (ru-idrss long)                 ; integral unshared data size
 228     (ru-isrss long)                 ; integral unshared stack size
 229     (ru-minflt long)                ; page reclaims
 230     (ru-majflt long)                ; page faults
 231     (ru-nswap long)                 ; swaps
 232     (ru-inblock long)               ; block input operations
 233     (ru-oublock long)               ; block output operations
 234     (ru-msgsnd long)                ; messages sent
 235     (ru-msgrcv long)                ; messages received
 236     (ru-nsignals long)              ; signals received
 237     (ru-nvcsw long)                 ; voluntary context switches
 238     (ru-nivcsw long)))              ; involuntary context switches
 239 \f
 240 ;;;; unistd.h
 241
 242 ;;; Given a file path (a string) and one of four constant modes,
 243 ;;; return T if the file is accessible with that mode and NIL if not.
 244 ;;; When NIL, also return an errno value with NIL which tells why the
 245 ;;; file was not accessible.
 246 ;;;
 247 ;;; The access modes are:
 248 ;;;   r_ok     Read permission.
 249 ;;;   w_ok     Write permission.
 250 ;;;   x_ok     Execute permission.
 251 ;;;   f_ok     Presence of file.
 252
 253 ;;; In Windows, the MODE argument to access is defined in terms of
 254 ;;; literal magic numbers---there are no constants to grovel.  X_OK
 255 ;;; is not defined.
 256 #!+win32
 257 (progn
 258   (defconstant f_ok 0)
 259   (defconstant w_ok 2)
 260   (defconstant r_ok 4))
 261
 262 (defun unix-access (path mode)
 263   (declare (type unix-pathname path)
 264            (type (mod 8) mode))
 265   (void-syscall ("access" c-string int) path mode))
 266
 267 ;;; values for the second argument to UNIX-LSEEK
 268 (defconstant l_set 0) ; to set the file pointer
 269 (defconstant l_incr 1) ; to increment the file pointer
 270 (defconstant l_xtnd 2) ; to extend the file size
 271
 272 ;;; Is a stream interactive?
 273 (defun unix-isatty (fd)
 274   (declare (type unix-fd fd))
 275   (int-syscall ("isatty" int) fd))
 276
 277 (defun unix-lseek (fd offset whence)
 278   "Unix-lseek accepts a file descriptor and moves the file pointer by
 279    OFFSET octets.  Whence can be any of the following:
 280
 281    L_SET        Set the file pointer.
 282    L_INCR       Increment the file pointer.
 283    L_XTND       Extend the file size.
 284   "
 285   (declare (type unix-fd fd)
 286            (type (integer 0 2) whence))
 287   (let ((result (alien-funcall (extern-alien #!-largefile "lseek"
 288                                              #!+largefile "lseek_largefile"
 289                                              (function off-t int off-t int))
 290                  fd offset whence)))
 291     (if (minusp result)
 292         (values nil (get-errno))
 293       (values result 0))))
 294
 295 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 296 ;;; It attempts to read len bytes from the device associated with fd
 297 ;;; and store them into the buffer. It returns the actual number of
 298 ;;; bytes read.
 299 (defun unix-read (fd buf len)
 300   (declare (type unix-fd fd)
 301            (type (unsigned-byte 32) len))
 302   (int-syscall ("read" int (* char) int) fd buf len))
 303
 304 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 305 ;;; length to write. It attempts to write len bytes to the device
 306 ;;; associated with fd from the buffer starting at offset. It returns
 307 ;;; the actual number of bytes written.
 308 (defun unix-write (fd buf offset len)
 309   (declare (type unix-fd fd)
 310            (type (unsigned-byte 32) offset len))
 311   (flet ((%write (sap)
 312            (declare (system-area-pointer sap))
 313            (int-syscall ("write" int (* char) int)
 314                         fd
 315                         (with-alien ((ptr (* char) sap))
 316                           (addr (deref ptr offset)))
 317                         len)))
 318     (etypecase buf
 319       ((simple-array * (*))
 320        (with-pinned-objects (buf)
 321          (%write (vector-sap buf))))
 322       (system-area-pointer
 323        (%write buf)))))
 324
 325 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 326 ;;; output pipe. Return two values: if no error occurred the first
 327 ;;; value is the pipe to be read from and the second is can be written
 328 ;;; to. If an error occurred the first value is NIL and the second the
 329 ;;; unix error code.
 330 #!-win32
 331 (defun unix-pipe ()
 332   (with-alien ((fds (array int 2)))
 333     (syscall ("pipe" (* int))
 334              (values (deref fds 0) (deref fds 1))
 335              (cast fds (* int)))))
 336 #!+win32
 337 (defun msvcrt-raw-pipe (fds size mode)
 338   (syscall ("_pipe" (* int) int int)
 339            (values (deref fds 0) (deref fds 1))
 340            (cast fds (* int)) size mode))
 341 #!+win32
 342 (defun unix-pipe ()
 343   (with-alien ((fds (array int 2)))
 344     (msvcrt-raw-pipe fds 256 o_binary)))
 345
 346 ;; Windows mkdir() doesn't take the mode argument. It's cdecl, so we could
 347 ;; actually call it passing the mode argument, but some sharp-eyed reader
 348 ;; would put five and twenty-seven together and ask us about it, so...
 349 ;;    -- AB, 2005-12-27
 350 #!-win32
 351 (defun unix-mkdir (name mode)
 352   (declare (type unix-pathname name)
 353            (type unix-file-mode mode)
 354            #!+win32 (ignore mode))
 355   (void-syscall ("mkdir" c-string #!-win32 int) name #!-win32 mode))
 356
 357 ;;; Given a C char* pointer allocated by malloc(), free it and return a
 358 ;;; corresponding Lisp string (or return NIL if the pointer is a C NULL).
 359 (defun newcharstar-string (newcharstar)
 360   (declare (type (alien (* char)) newcharstar))
 361   (if (null-alien newcharstar)
 362       nil
 363       (prog1
 364           (cast newcharstar c-string)
 365         (free-alien newcharstar))))
 366
 367 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 368 ;;; style returned by getcwd() (no trailing slash character).
 369 #!-win32
 370 (defun posix-getcwd ()
 371   ;; This implementation relies on a BSD/Linux extension to getcwd()
 372   ;; behavior, automatically allocating memory when a null buffer
 373   ;; pointer is used. On a system which doesn't support that
 374   ;; extension, it'll have to be rewritten somehow.
 375   ;;
 376   ;; SunOS and OSF/1 provide almost as useful an extension: if given a null
 377   ;; buffer pointer, it will automatically allocate size space. The
 378   ;; KLUDGE in this solution arises because we have just read off
 379   ;; PATH_MAX+1 from the Solaris header files and stuck it in here as
 380   ;; a constant. Going the grovel_headers route doesn't seem to be
 381   ;; helpful, either, as Solaris doesn't export PATH_MAX from
 382   ;; unistd.h.
 383   ;;
 384   ;; FIXME: The (,stub,) nastiness produces an error message about a
 385   ;; comma not inside a backquote. This error has absolutely nothing
 386   ;; to do with the actual meaning of the error (and little to do with
 387   ;; its location, either).
 388   #!-(or linux openbsd freebsd netbsd sunos osf1 darwin win32) (,stub,)
 389   #!+(or linux openbsd freebsd netbsd sunos osf1 darwin win32)
 390   (or (newcharstar-string (alien-funcall (extern-alien "getcwd"
 391                                                        (function (* char)
 392                                                                  (* char)
 393                                                                  size-t))
 394                                          nil
 395                                          #!+(or linux openbsd freebsd netbsd darwin win32) 0
 396                                          #!+(or sunos osf1) 1025))
 397       (simple-perror "getcwd")))
 398
 399 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 400 ;;; by a slash character.
 401 (defun posix-getcwd/ ()
 402   (concatenate 'string (posix-getcwd) "/"))
 403
 404 ;;; Duplicate an existing file descriptor (given as the argument) and
 405 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 406 ;;; number are returned.
 407 (defun unix-dup (fd)
 408   (declare (type unix-fd fd))
 409   (int-syscall ("dup" int) fd))
 410
 411 ;;; Terminate the current process with an optional error code. If
 412 ;;; successful, the call doesn't return. If unsuccessful, the call
 413 ;;; returns NIL and an error number.
 414 (defun unix-exit (&optional (code 0))
 415   (declare (type (signed-byte 32) code))
 416   (void-syscall ("exit" int) code))
 417
 418 ;;; Return the process id of the current process.
 419 (define-alien-routine ("getpid" unix-getpid) int)
 420
 421 ;;; Return the real user id associated with the current process.
 422 #!-win32
 423 (define-alien-routine ("getuid" unix-getuid) int)
 424
 425 ;;; Translate a user id into a login name.
 426 #!-win32
 427 (defun uid-username (uid)
 428   (or (newcharstar-string (alien-funcall (extern-alien "uid_username"
 429                                                        (function (* char) int))
 430                                          uid))
 431       (error "found no match for Unix uid=~S" uid)))
 432
 433 ;;; Return the namestring of the home directory, being careful to
 434 ;;; include a trailing #\/
 435 #!-win32
 436 (defun uid-homedir (uid)
 437   (or (newcharstar-string (alien-funcall (extern-alien "uid_homedir"
 438                                                        (function (* char) int))
 439                                          uid))
 440       (error "failed to resolve home directory for Unix uid=~S" uid)))
 441
 442 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 443 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 444 ;;; failure.
 445 #!-win32
 446 (defun unix-readlink (path)
 447   (declare (type unix-pathname path))
 448   (with-alien ((ptr (* char)
 449                     (alien-funcall (extern-alien
 450                                     "wrapped_readlink"
 451                                     (function (* char) c-string))
 452                                    path)))
 453     (if (null-alien ptr)
 454         (values nil (get-errno))
 455         (multiple-value-prog1
 456             (values (with-alien ((c-string c-string ptr)) c-string)
 457                     nil)
 458           (free-alien ptr)))))
 459 #!+win32
 460 ;; Win32 doesn't do links, but something likes to call this anyway.
 461 ;; Something in this file, no less. But it only takes one result, so...
 462 (defun unix-readlink (path)
 463   (declare (ignore path))
 464   nil)
 465
 466 (defun unix-realpath (path)
 467   (declare (type unix-pathname path))
 468   (with-alien ((ptr (* char)
 469                     (alien-funcall (extern-alien
 470                                     "sb_realpath"
 471                                     (function (* char) c-string))
 472                                    path)))
 473     (if (null-alien ptr)
 474         (values nil (get-errno))
 475         (multiple-value-prog1
 476             (values (with-alien ((c-string c-string ptr)) c-string)
 477                     nil)
 478           (free-alien ptr)))))
 479
 480 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 481 ;;; name and the file if this is the last link.
 482 (defun unix-unlink (name)
 483   (declare (type unix-pathname name))
 484   (void-syscall ("unlink" c-string) name))
 485
 486 ;;; Return the name of the host machine as a string.
 487 #!-win32
 488 (defun unix-gethostname ()
 489   (with-alien ((buf (array char 256)))
 490     (syscall ("gethostname" (* char) int)
 491              (cast buf c-string)
 492              (cast buf (* char)) 256)))
 493
 494 #!-win32
 495 (defun unix-setsid ()
 496   (int-syscall ("setsid")))
 497
 498 ;;;; sys/ioctl.h
 499
 500 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 501 ;;; descriptors. See the UNIX Programmer's Manual for more
 502 ;;; information.
 503 #!-win32
 504 (defun unix-ioctl (fd cmd arg)
 505   (declare (type unix-fd fd)
 506            (type (signed-byte 32) cmd))
 507   (void-syscall ("ioctl" int int (* char)) fd cmd arg))
 508 \f
 509 ;;;; sys/resource.h
 510
 511 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 512 ;;;
 513 ;;; This is like getrusage(2), except it returns only the system and
 514 ;;; user time, and returns the seconds and microseconds as separate
 515 ;;; values.
 516 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 517 #!-win32
 518 (defun unix-fast-getrusage (who)
 519   (declare (values (member t)
 520                    (unsigned-byte 31) (integer 0 1000000)
 521                    (unsigned-byte 31) (integer 0 1000000)))
 522   (with-alien ((usage (struct rusage)))
 523     (syscall* ("getrusage" int (* (struct rusage)))
 524               (values t
 525                       (slot (slot usage 'ru-utime) 'tv-sec)
 526                       (slot (slot usage 'ru-utime) 'tv-usec)
 527                       (slot (slot usage 'ru-stime) 'tv-sec)
 528                       (slot (slot usage 'ru-stime) 'tv-usec))
 529               who (addr usage))))
 530
 531 ;;; Return information about the resource usage of the process
 532 ;;; specified by WHO. WHO can be either the current process
 533 ;;; (rusage_self) or all of the terminated child processes
 534 ;;; (rusage_children). NIL and an error number is returned if the call
 535 ;;; fails.
 536 #!-win32
 537 (defun unix-getrusage (who)
 538   (with-alien ((usage (struct rusage)))
 539     (syscall ("getrusage" int (* (struct rusage)))
 540               (values t
 541                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 542                          (slot (slot usage 'ru-utime) 'tv-usec))
 543                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 544                          (slot (slot usage 'ru-stime) 'tv-usec))
 545                       (slot usage 'ru-maxrss)
 546                       (slot usage 'ru-ixrss)
 547                       (slot usage 'ru-idrss)
 548                       (slot usage 'ru-isrss)
 549                       (slot usage 'ru-minflt)
 550                       (slot usage 'ru-majflt)
 551                       (slot usage 'ru-nswap)
 552                       (slot usage 'ru-inblock)
 553                       (slot usage 'ru-oublock)
 554                       (slot usage 'ru-msgsnd)
 555                       (slot usage 'ru-msgrcv)
 556                       (slot usage 'ru-nsignals)
 557                       (slot usage 'ru-nvcsw)
 558                       (slot usage 'ru-nivcsw))
 559               who (addr usage))))
 560 \f
 561 ;;;; sys/select.h
 562
 563 (defvar *on-dangerous-select* :warn)
 564
 565 ;;; Calling select in a bad place can hang in a nasty manner, so it's better
 566 ;;; to have some way to detect these.
 567 (defun note-dangerous-select ()
 568   (let ((action *on-dangerous-select*)
 569         (*on-dangerous-select* nil))
 570     (case action
 571       (:warn
 572        (warn "Starting a select without a timeout while interrupts are ~
 573              disabled."))
 574       (:error
 575        (error "Starting a select without a timeout while interrupts are ~
 576               disabled."))
 577       (:backtrace
 578        (write-line
 579         "=== Starting a select without a timeout while interrupts are disabled. ==="
 580         *debug-io*)
 581        (sb!debug:backtrace)))
 582     nil))
 583
 584 ;;;; FIXME: Why have both UNIX-SELECT and UNIX-FAST-SELECT?
 585
 586 ;;; Perform the UNIX select(2) system call.
 587 (declaim (inline unix-fast-select))
 588 (defun unix-fast-select (num-descriptors
 589                          read-fds write-fds exception-fds
 590                          timeout-secs timeout-usecs)
 591   (declare (type (integer 0 #.fd-setsize) num-descriptors)
 592            (type (or (alien (* (struct fd-set))) null)
 593                  read-fds write-fds exception-fds)
 594            (type (or null (unsigned-byte 31)) timeout-secs timeout-usecs))
 595   (flet ((select (tv-sap)
 596            (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 597                                   (* (struct fd-set)) (* (struct timeval)))
 598                         num-descriptors read-fds write-fds exception-fds
 599                         tv-sap)))
 600     (cond ((or timeout-secs timeout-usecs)
 601            (with-alien ((tv (struct timeval)))
 602              (setf (slot tv 'tv-sec) (or timeout-secs 0))
 603              (setf (slot tv 'tv-usec) (or timeout-usecs 0))
 604              (select (alien-sap (addr tv)))))
 605           (t
 606            (unless *interrupts-enabled*
 607              (note-dangerous-select))
 608            (select (int-sap 0))))))
 609
 610 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 611 ;;; to happen on one of them or to time out.
 612 (defmacro num-to-fd-set (fdset num)
 613   `(if (fixnump ,num)
 614        (progn
 615          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 616          ,@(loop for index upfrom 1 below (/ fd-setsize
 617                                              sb!vm:n-machine-word-bits)
 618              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 619        (progn
 620          ,@(loop for index upfrom 0 below (/ fd-setsize
 621                                              sb!vm:n-machine-word-bits)
 622              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 623                             (ldb (byte sb!vm:n-machine-word-bits
 624                                        ,(* index sb!vm:n-machine-word-bits))
 625                                  ,num))))))
 626
 627 (defmacro fd-set-to-num (nfds fdset)
 628   `(if (<= ,nfds sb!vm:n-machine-word-bits)
 629        (deref (slot ,fdset 'fds-bits) 0)
 630        (+ ,@(loop for index upfrom 0 below (/ fd-setsize
 631                                               sb!vm:n-machine-word-bits)
 632               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 633                             ,(* index sb!vm:n-machine-word-bits))))))
 634
 635 ;;; Examine the sets of descriptors passed as arguments to see whether
 636 ;;; they are ready for reading and writing. See the UNIX Programmer's
 637 ;;; Manual for more information.
 638 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 639   (declare (type (integer 0 #.fd-setsize) nfds)
 640            (type unsigned-byte rdfds wrfds xpfds)
 641            (type (or (unsigned-byte 31) null) to-secs)
 642            (type (unsigned-byte 31) to-usecs)
 643            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 644   (with-alien ((tv (struct timeval))
 645                (rdf (struct fd-set))
 646                (wrf (struct fd-set))
 647                (xpf (struct fd-set)))
 648     (cond (to-secs
 649            (setf (slot tv 'tv-sec) to-secs
 650                  (slot tv 'tv-usec) to-usecs))
 651           ((not *interrupts-enabled*)
 652            (note-dangerous-select)))
 653     (num-to-fd-set rdf rdfds)
 654     (num-to-fd-set wrf wrfds)
 655     (num-to-fd-set xpf xpfds)
 656     (macrolet ((frob (lispvar alienvar)
 657                  `(if (zerop ,lispvar)
 658                       (int-sap 0)
 659                       (alien-sap (addr ,alienvar)))))
 660       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 661                          (* (struct fd-set)) (* (struct timeval)))
 662                (values result
 663                        (fd-set-to-num nfds rdf)
 664                        (fd-set-to-num nfds wrf)
 665                        (fd-set-to-num nfds xpf))
 666                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 667                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 668 \f
 669 ;;;; sys/stat.h
 670
 671 ;;; This is a structure defined in src/runtime/wrap.c, to look
 672 ;;; basically like "struct stat" according to stat(2). It may not
 673 ;;; actually correspond to the real in-memory stat structure that the
 674 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 675 ;;; stat macros, and trying to keep Lisp code in correspondence with
 676 ;;; it is more pain than it's worth, so we just let our C runtime
 677 ;;; synthesize a nice consistent structure for us.
 678 ;;;
 679 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 680 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn't support
 681 ;;; those. We don't actually access that field anywhere, though, so
 682 ;;; until we can get 64 bit alien support it'll do. Also note that
 683 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 684 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 685 ;;; longer than 32 bits anyway, right?":-|
 686 ;;;
 687 ;;; The comment about alien and 64-bit quantities has not been kept in
 688 ;;; sync with the comment now in wrap.h (formerly wrap.c), but it's
 689 ;;; not clear whether either comment is correct.  -- RMK 2007-11-14.
 690 (define-alien-type nil
 691   (struct wrapped_stat
 692     (st-dev wst-dev-t)
 693     (st-ino ino-t)
 694     (st-mode mode-t)
 695     (st-nlink wst-nlink-t)
 696     (st-uid wst-uid-t)
 697     (st-gid wst-gid-t)
 698     (st-rdev wst-dev-t)
 699     (st-size wst-off-t)
 700     (st-blksize wst-blksize-t)
 701     (st-blocks wst-blkcnt-t)
 702     (st-atime time-t)
 703     (st-mtime time-t)
 704     (st-ctime time-t)))
 705
 706 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 707 ;;; family of Unix system calls
 708 ;;;
 709 ;;; FIXME: I think this should probably not be INLINE. However, when
 710 ;;; this was not inline, it seemed to cause memory corruption
 711 ;;; problems. My first guess is that it's a bug in the FFI code, where
 712 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 713 ;;; around a call to a function returning >10 values. But I didn't try
 714 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 715 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 716 ;;; output in the not-inlined case and see whether there's a problem,
 717 ;;; and maybe even find a fix..
 718 (declaim (inline %extract-stat-results))
 719 (defun %extract-stat-results (wrapped-stat)
 720   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 721   (values t
 722           (slot wrapped-stat 'st-dev)
 723           (slot wrapped-stat 'st-ino)
 724           (slot wrapped-stat 'st-mode)
 725           (slot wrapped-stat 'st-nlink)
 726           (slot wrapped-stat 'st-uid)
 727           (slot wrapped-stat 'st-gid)
 728           (slot wrapped-stat 'st-rdev)
 729           (slot wrapped-stat 'st-size)
 730           (slot wrapped-stat 'st-atime)
 731           (slot wrapped-stat 'st-mtime)
 732           (slot wrapped-stat 'st-ctime)
 733           (slot wrapped-stat 'st-blksize)
 734           (slot wrapped-stat 'st-blocks)))
 735
 736 ;;; Unix system calls in the stat(2) family are handled by calls to
 737 ;;; C-level wrapper functions which copy all the raw "struct stat"
 738 ;;; slots into the system-independent wrapped_stat format.
 739 ;;;    stat(2) <->  stat_wrapper()
 740 ;;;   fstat(2) <-> fstat_wrapper()
 741 ;;;   lstat(2) <-> lstat_wrapper()
 742 (defun unix-stat (name)
 743   (declare (type unix-pathname name))
 744   (with-alien ((buf (struct wrapped_stat)))
 745     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 746              (%extract-stat-results (addr buf))
 747              name (addr buf))))
 748 (defun unix-lstat (name)
 749   (declare (type unix-pathname name))
 750   (with-alien ((buf (struct wrapped_stat)))
 751     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 752              (%extract-stat-results (addr buf))
 753              name (addr buf))))
 754 (defun unix-fstat (fd)
 755   (declare (type unix-fd fd))
 756   (with-alien ((buf (struct wrapped_stat)))
 757     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 758              (%extract-stat-results (addr buf))
 759              fd (addr buf))))
 760
 761 ;;; RUN-PROGRAM creates temporary files with mkstemp, but SUSv3
 762 ;;; doesn't specify the mode of a newly created file under mkstemp,
 763 ;;; and C libraries may vary, so we fix the mode ourselves.
 764 ;;; Eventually some OPEN actions should probably be implemented with
 765 ;;; mkstemp(3)/chmod(2)/rename(2) as well.
 766 #!-win32
 767 (defun unix-chmod (path mode)
 768   (declare (type unix-pathname path)
 769            (type unix-file-mode mode))
 770   (void-syscall ("chmod" c-string int) path mode))
 771 \f
 772 ;;;; time.h
 773
 774 ;; the POSIX.4 structure for a time value. This is like a "struct
 775 ;; timeval" but has nanoseconds instead of microseconds.
 776 (define-alien-type nil
 777     (struct timespec
 778             (tv-sec long)   ; seconds
 779             (tv-nsec long))) ; nanoseconds
 780
 781 ;; used by other time functions
 782 (define-alien-type nil
 783     (struct tm
 784             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 785             (tm-min int)   ; Minutes.   [0-59]
 786             (tm-hour int)  ; Hours.     [0-23]
 787             (tm-mday int)  ; Day.       [1-31]
 788             (tm-mon int)   ; Month.     [0-11]
 789             (tm-year int)  ; Year - 1900.
 790             (tm-wday int)  ; Day of week. [0-6]
 791             (tm-yday int)  ; Days in year. [0-365]
 792             (tm-isdst int) ; DST.       [-1/0/1]
 793             (tm-gmtoff long) ;  Seconds east of UTC.
 794             (tm-zone c-string))) ; Timezone abbreviation.
 795
 796 (define-alien-routine get-timezone sb!alien:void
 797   (when sb!alien:long :in)
 798   (seconds-west sb!alien:int :out)
 799   (daylight-savings-p sb!alien:boolean :out))
 800
 801 #!-win32
 802 (defun nanosleep (secs nsecs)
 803   (with-alien ((req (struct timespec))
 804                (rem (struct timespec)))
 805     (setf (slot req 'tv-sec) secs)
 806     (setf (slot req 'tv-nsec) nsecs)
 807     (loop while (eql sb!unix:eintr
 808                      (nth-value 1
 809                                 (int-syscall ("nanosleep" (* (struct timespec))
 810                                                           (* (struct timespec)))
 811                                              (addr req) (addr rem))))
 812        do (rotatef req rem))))
 813
 814 (defun unix-get-seconds-west (secs)
 815   (multiple-value-bind (ignore seconds dst) (get-timezone secs)
 816     (declare (ignore ignore) (ignore dst))
 817     (values seconds)))
 818 \f
 819 ;;;; sys/time.h
 820
 821 ;;; Structure crudely representing a timezone. KLUDGE: This is
 822 ;;; obsolete and should never be used.
 823 (define-alien-type nil
 824   (struct timezone
 825     (tz-minuteswest int)                ; minutes west of Greenwich
 826     (tz-dsttime int)))                  ; type of dst correction
 827
 828 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 829 ;;; and microseconds of the current time of day, the timezone (in
 830 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 831 ;;; doesn't work, it returns NIL and the errno.
 832 #!-sb-fluid (declaim (inline unix-gettimeofday))
 833 (defun unix-gettimeofday ()
 834   #!+(and x86-64 darwin)
 835   (with-alien ((tv (struct timeval)))
 836     ;; CLH: FIXME! This seems to be a MacOS bug, but on x86-64/darwin,
 837     ;; gettimeofday occasionally fails. passing in a null pointer for
 838     ;; the timezone struct seems to work around the problem. I can't
 839     ;; find any instances in the SBCL where we actually ues the
 840     ;; timezone values, so we just punt for the moment.
 841     (syscall* ("gettimeofday" (* (struct timeval))
 842                               (* (struct timezone)))
 843               (values t
 844                       (slot tv 'tv-sec)
 845                       (slot tv 'tv-usec))
 846               (addr tv)
 847               nil))
 848   #!-(and x86-64 darwin)
 849   (with-alien ((tv (struct timeval))
 850                (tz (struct timezone)))
 851     (syscall* ("gettimeofday" (* (struct timeval))
 852                               (* (struct timezone)))
 853               (values t
 854                       (slot tv 'tv-sec)
 855                       (slot tv 'tv-usec)
 856                       (slot tz 'tz-minuteswest)
 857                       (slot tz 'tz-dsttime))
 858               (addr tv)
 859               (addr tz))))
 860 \f
 861
 862 ;; Type of the second argument to `getitimer' and
 863 ;; the second and third arguments `setitimer'.
 864 (define-alien-type nil
 865   (struct itimerval
 866     (it-interval (struct timeval))      ; timer interval
 867     (it-value (struct timeval))))       ; current value
 868
 869 (defconstant itimer-real 0)
 870 (defconstant itimer-virtual 1)
 871 (defconstant itimer-prof 2)
 872
 873 #!-win32
 874 (defun unix-getitimer (which)
 875   "Unix-getitimer returns the INTERVAL and VALUE slots of one of
 876    three system timers (:real :virtual or :profile). On success,
 877    unix-getitimer returns 5 values,
 878    T, it-interval-secs, it-interval-usec, it-value-secs, it-value-usec."
 879   (declare (type (member :real :virtual :profile) which)
 880            (values t
 881                    (unsigned-byte 29) (mod 1000000)
 882                    (unsigned-byte 29) (mod 1000000)))
 883   (let ((which (ecase which
 884                  (:real itimer-real)
 885                  (:virtual itimer-virtual)
 886                  (:profile itimer-prof))))
 887     (with-alien ((itv (struct itimerval)))
 888       (syscall* ("getitimer" int (* (struct itimerval)))
 889                 (values t
 890                         (slot (slot itv 'it-interval) 'tv-sec)
 891                         (slot (slot itv 'it-interval) 'tv-usec)
 892                         (slot (slot itv 'it-value) 'tv-sec)
 893                         (slot (slot itv 'it-value) 'tv-usec))
 894                 which (alien-sap (addr itv))))))
 895
 896 #!-win32
 897 (defun unix-setitimer (which int-secs int-usec val-secs val-usec)
 898   " Unix-setitimer sets the INTERVAL and VALUE slots of one of
 899    three system timers (:real :virtual or :profile). A SIGALRM signal
 900    will be delivered VALUE <seconds+microseconds> from now. INTERVAL,
 901    when non-zero, is <seconds+microseconds> to be loaded each time
 902    the timer expires. Setting INTERVAL and VALUE to zero disables
 903    the timer. See the Unix man page for more details. On success,
 904    unix-setitimer returns the old contents of the INTERVAL and VALUE
 905    slots as in unix-getitimer."
 906   (declare (type (member :real :virtual :profile) which)
 907            (type (unsigned-byte 29) int-secs val-secs)
 908            (type (integer 0 (1000000)) int-usec val-usec)
 909            (values t
 910                    (unsigned-byte 29) (mod 1000000)
 911                    (unsigned-byte 29) (mod 1000000)))
 912   (let ((which (ecase which
 913                  (:real itimer-real)
 914                  (:virtual itimer-virtual)
 915                  (:profile itimer-prof))))
 916     (with-alien ((itvn (struct itimerval))
 917                  (itvo (struct itimerval)))
 918       (setf (slot (slot itvn 'it-interval) 'tv-sec ) int-secs
 919             (slot (slot itvn 'it-interval) 'tv-usec) int-usec
 920             (slot (slot itvn 'it-value   ) 'tv-sec ) val-secs
 921             (slot (slot itvn 'it-value   ) 'tv-usec) val-usec)
 922       (syscall* ("setitimer" int (* (struct timeval))(* (struct timeval)))
 923                 (values t
 924                         (slot (slot itvo 'it-interval) 'tv-sec)
 925                         (slot (slot itvo 'it-interval) 'tv-usec)
 926                         (slot (slot itvo 'it-value) 'tv-sec)
 927                         (slot (slot itvo 'it-value) 'tv-usec))
 928                 which (alien-sap (addr itvn))(alien-sap (addr itvo))))))
 929
 930 \f
 931 ;;; FIXME: Many Unix error code definitions were deleted from the old
 932 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 933 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 934 ;;; unused symbols in package exports, but if I don't, there are
 935 ;;; enough of them all in one place here that they should probably be
 936 ;;; removed by hand.
 937 \f
 938 ;;;; support routines for dealing with Unix pathnames
 939
 940 (defun unix-file-kind (name &optional check-for-links)
 941   #!+sb-doc
 942   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 943   (declare (simple-string name))
 944   (multiple-value-bind (res dev ino mode)
 945       (if check-for-links (unix-lstat name) (unix-stat name))
 946     (declare (type (or fixnum null) mode)
 947              (ignore dev ino))
 948     (when res
 949       (let ((kind (logand mode s-ifmt)))
 950         (cond ((eql kind s-ifdir) :directory)
 951               ((eql kind s-ifreg) :file)
 952               #!-win32
 953               ((eql kind s-iflnk) :link)
 954               (t :special))))))
 955 \f
 956 (defconstant micro-seconds-per-internal-time-unit
 957   (/ 1000000 sb!xc:internal-time-units-per-second))
 958
 959 ;;; UNIX specific code, that has been cleanly separated from the
 960 ;;; Windows build.
 961 #!-win32
 962 (progn
 963   (declaim (inline system-internal-run-time
 964                    system-real-time-values))
 965
 966   (defun system-real-time-values ()
 967     (multiple-value-bind (_ sec usec) (unix-gettimeofday)
 968       (declare (ignore _) (type (unsigned-byte 32) sec usec))
 969       (values sec (truncate usec micro-seconds-per-internal-time-unit))))
 970
 971   ;; There are two optimizations here that actually matter (on 32-bit
 972   ;; systems): substract the epoch from seconds and milliseconds
 973   ;; separately, as those should remain fixnums for the first 17 years
 974   ;; or so of runtime. Also, avoid doing consing a new bignum if the
 975   ;; result would be = to the last result given.
 976   ;;
 977   ;; Note: the next trick would be to spin a separate thread to update
 978   ;; a global value once per internal tick, so each individual call to
 979   ;; get-internal-real-time would be just a memory read... but that is
 980   ;; probably best left for user-level code. ;)
 981   ;;
 982   ;; Thanks to James Anderson for the optimization hint.
 983   ;;
 984   ;; Yes, it is possible to a computation to be GET-INTERNAL-REAL-TIME
 985   ;; bound.
 986   ;;
 987   ;; --NS 2007-04-05
 988   (let ((e-sec 0)
 989         (e-msec 0)
 990         (c-sec 0)
 991         (c-msec 0)
 992         (now 0))
 993     (declare (type (unsigned-byte 32) e-sec c-sec)
 994              (type fixnum e-msec c-msec)
 995              (type unsigned-byte now))
 996     (defun reinit-internal-real-time ()
 997       (setf (values e-sec e-msec) (system-real-time-values)
 998             c-sec 0
 999             c-msec 0))
1000     ;; If two threads call this at the same time, we're still safe, I believe,
1001     ;; as long as NOW is updated before either of C-MSEC or C-SEC. Same applies
1002     ;; to interrupts. --NS
1003     (defun get-internal-real-time ()
1004       (multiple-value-bind (sec msec) (system-real-time-values)
1005         (unless (and (= msec c-msec) (= sec c-sec))
1006           (setf now (+ (* (- sec e-sec)
1007                           sb!xc:internal-time-units-per-second)
1008                        (- msec e-msec))
1009                 c-msec msec
1010                 c-sec sec))
1011         now)))
1012
1013   (defun system-internal-run-time ()
1014     (multiple-value-bind (ignore utime-sec utime-usec stime-sec stime-usec)
1015         (unix-fast-getrusage rusage_self)
1016       (declare (ignore ignore)
1017                (type (unsigned-byte 31) utime-sec stime-sec)
1018                ;; (Classic CMU CL had these (MOD 1000000) instead, but
1019                ;; at least in Linux 2.2.12, the type doesn't seem to
1020                ;; be documented anywhere and the observed behavior is
1021                ;; to sometimes return 1000000 exactly.)
1022                (type (integer 0 1000000) utime-usec stime-usec))
1023       (let ((result (+ (* (+ utime-sec stime-sec)
1024                           sb!xc:internal-time-units-per-second)
1025                        (floor (+ utime-usec
1026                                  stime-usec
1027                                  (floor micro-seconds-per-internal-time-unit 2))
1028                               micro-seconds-per-internal-time-unit))))
1029         result))))
1030 \f
1031 ;;;; A magic constant for wait3().
1032 ;;;;
1033 ;;;; FIXME: This used to be defined in run-program.lisp as
1034 ;;;; (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
1035 ;;;; According to some of the man pages, the #o177 is part of the API
1036 ;;;; for wait3(); that said, under SunOS there is a WSTOPPED thing in
1037 ;;;; the headers that may or may not be the same thing. To be
1038 ;;;; investigated. -- CSR, 2002-03-25
1039 (defconstant wstopped #o177)
1040
1041 \f
1042 ;;;; stuff not yet found in the header files
1043 ;;;;
1044 ;;;; Abandon all hope who enters here...
1045
1046 ;;; not checked for linux...
1047 (defmacro fd-set (offset fd-set)
1048   (let ((word (gensym))
1049         (bit (gensym)))
1050     `(multiple-value-bind (,word ,bit) (floor ,offset
1051                                               sb!vm:n-machine-word-bits)
1052        (setf (deref (slot ,fd-set 'fds-bits) ,word)
1053              (logior (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
1054                                 (ash 1 ,bit))
1055                      (deref (slot ,fd-set 'fds-bits) ,word))))))
1056
1057 ;;; not checked for linux...
1058 (defmacro fd-clr (offset fd-set)
1059   (let ((word (gensym))
1060         (bit (gensym)))
1061     `(multiple-value-bind (,word ,bit) (floor ,offset
1062                                               sb!vm:n-machine-word-bits)
1063        (setf (deref (slot ,fd-set 'fds-bits) ,word)
1064              (logand (deref (slot ,fd-set 'fds-bits) ,word)
1065                      (sb!kernel:word-logical-not
1066                       (truly-the (unsigned-byte #.sb!vm:n-machine-word-bits)
1067                                  (ash 1 ,bit))))))))
1068
1069 ;;; not checked for linux...
1070 (defmacro fd-isset (offset fd-set)
1071   (let ((word (gensym))
1072         (bit (gensym)))
1073     `(multiple-value-bind (,word ,bit) (floor ,offset
1074                                               sb!vm:n-machine-word-bits)
1075        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
1076
1077 ;;; not checked for linux...
1078 (defmacro fd-zero (fd-set)
1079   `(progn
1080      ,@(loop for index upfrom 0 below (/ fd-setsize sb!vm:n-machine-word-bits)
1081          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
1082