src/code/unix.lisp

   1 ;;;; This file contains Unix support that SBCL needs to implement
   2 ;;;; itself. It's derived from Peter Van Eynde's unix-glibc2.lisp for
   3 ;;;; CMU CL, which was derived from CMU CL unix.lisp 1.56. But those
   4 ;;;; files aspired to be complete Unix interfaces exported to the end
   5 ;;;; user, while this file aims to be as simple as possible and is not
   6 ;;;; intended for the end user.
   7 ;;;;
   8 ;;;; FIXME: The old CMU CL unix.lisp code was implemented as hand
   9 ;;;; transcriptions from Unix headers into Lisp. It appears that this was as
  10 ;;;; unmaintainable in practice as you'd expect in theory, so I really really
  11 ;;;; don't want to do that. It'd be good to implement the various system calls
  12 ;;;; as C code implemented using the Unix header files, and have their
  13 ;;;; interface back to SBCL code be characterized by things like "32-bit-wide
  14 ;;;; int" which are already in the interface between the runtime
  15 ;;;; executable and the SBCL lisp code.
  16
  17 ;;;; This software is part of the SBCL system. See the README file for
  18 ;;;; more information.
  19 ;;;;
  20 ;;;; This software is derived from the CMU CL system, which was
  21 ;;;; written at Carnegie Mellon University and released into the
  22 ;;;; public domain. The software is in the public domain and is
  23 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  24 ;;;; files for more information.
  25
  26 (in-package "SB!UNIX")
  27
  28 (/show0 "unix.lisp 21")
  29
  30 (defmacro def-enum (inc cur &rest names)
  31   (flet ((defform (name)
  32            (prog1 (when name `(defconstant ,name ,cur))
  33              (setf cur (funcall inc cur 1)))))
  34     `(progn ,@(mapcar #'defform names))))
  35
  36 ;;; Given a C-level zero-terminated array of C strings, return a
  37 ;;; corresponding Lisp-level list of SIMPLE-STRINGs.
  38 (defun c-strings->string-list (c-strings)
  39   (declare (type (alien (* c-string)) c-strings))
  40   (let ((reversed-result nil))
  41     (dotimes (i most-positive-fixnum (error "argh! can't happen"))
  42       (declare (type index i))
  43       (let ((c-string (deref c-strings i)))
  44         (if c-string
  45             (push c-string reversed-result)
  46             (return (nreverse reversed-result)))))))
  47 \f
  48 ;;;; Lisp types used by syscalls
  49
  50 (deftype unix-pathname () 'simple-string)
  51 (deftype unix-fd () `(integer 0 ,most-positive-fixnum))
  52
  53 (deftype unix-file-mode () '(unsigned-byte 32))
  54 (deftype unix-pid () '(unsigned-byte 32))
  55 (deftype unix-uid () '(unsigned-byte 32))
  56 (deftype unix-gid () '(unsigned-byte 32))
  57 \f
  58 ;;;; system calls
  59
  60 (/show0 "unix.lisp 74")
  61
  62 ;;; FIXME: The various FOO-SYSCALL-BAR macros, and perhaps some other
  63 ;;; macros in this file, are only used in this file, and could be
  64 ;;; implemented using SB!XC:DEFMACRO wrapped in EVAL-WHEN.
  65
  66 (defmacro syscall ((name &rest arg-types) success-form &rest args)
  67   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  68                                 ,@args)))
  69      (if (minusp result)
  70          (values nil (get-errno))
  71          ,success-form)))
  72
  73 ;;; This is like SYSCALL, but if it fails, signal an error instead of
  74 ;;; returning error codes. Should only be used for syscalls that will
  75 ;;; never really get an error.
  76 (defmacro syscall* ((name &rest arg-types) success-form &rest args)
  77   `(let ((result (alien-funcall (extern-alien ,name (function int ,@arg-types))
  78                                 ,@args)))
  79      (if (minusp result)
  80          (error "Syscall ~A failed: ~A" ,name (strerror))
  81          ,success-form)))
  82
  83 (/show0 "unix.lisp 109")
  84
  85 (defmacro void-syscall ((name &rest arg-types) &rest args)
  86   `(syscall (,name ,@arg-types) (values t 0) ,@args))
  87
  88 (defmacro int-syscall ((name &rest arg-types) &rest args)
  89   `(syscall (,name ,@arg-types) (values result 0) ,@args))
  90 \f
  91 ;;;; hacking the Unix environment
  92
  93 (def-alien-routine ("getenv" posix-getenv) c-string
  94   "Return the \"value\" part of the environment string \"name=value\" which
  95    corresponds to NAME, or NIL if there is none."
  96   (name c-string))
  97 \f
  98 ;;; from stdio.h
  99
 100 ;;; Rename the file with string NAME1 to the string NAME2. NIL and an
 101 ;;; error code is returned if an error occurs.
 102 (defun unix-rename (name1 name2)
 103   (declare (type unix-pathname name1 name2))
 104   (void-syscall ("rename" c-string c-string) name1 name2))
 105 \f
 106 ;;; from sys/types.h and gnu/types.h
 107
 108 (/show0 "unix.lisp 220")
 109
 110 ;;; FIXME: We shouldn't hand-copy types from header files into Lisp
 111 ;;; like this unless we have extreme provocation. Reading directories
 112 ;;; is not extreme enough, since it doesn't need to be blindingly
 113 ;;; fast: we can just implement those functions in C as a wrapper
 114 ;;; layer.
 115 (def-alien-type fd-mask unsigned-long)
 116
 117 (eval-when (:compile-toplevel :load-toplevel :execute)
 118   (defconstant fd-setsize 1024))
 119
 120 (def-alien-type nil
 121   (struct fd-set
 122           (fds-bits (array fd-mask #.(/ fd-setsize 32)))))
 123
 124 (/show0 "unix.lisp 304")
 125 \f
 126 \f
 127 ;;;; fcntl.h
 128 ;;;;
 129 ;;;; POSIX Standard: 6.5 File Control Operations        <fcntl.h>
 130
 131 ;;; Open the file whose pathname is specified by PATH for reading
 132 ;;; and/or writing as specified by the FLAGS argument. Various FLAGS
 133 ;;; masks (O_RDONLY etc.) are defined in fcntlbits.h.
 134 ;;;
 135 ;;; If the O_CREAT flag is specified, then the file is created with a
 136 ;;; permission of argument MODE if the file doesn't exist. An integer
 137 ;;; file descriptor is returned by UNIX-OPEN.
 138 (defun unix-open (path flags mode)
 139   (declare (type unix-pathname path)
 140            (type fixnum flags)
 141            (type unix-file-mode mode))
 142   (int-syscall ("open" c-string int int) path flags mode))
 143
 144 ;;; UNIX-CLOSE accepts a file descriptor and attempts to close the file
 145 ;;; associated with it.
 146 (/show0 "unix.lisp 391")
 147 (defun unix-close (fd)
 148   (declare (type unix-fd fd))
 149   (void-syscall ("close" int) fd))
 150 \f
 151 ;;;; timebits.h
 152
 153 ;; A time value that is accurate to the nearest
 154 ;; microsecond but also has a range of years.
 155 (def-alien-type nil
 156   (struct timeval
 157           (tv-sec time-t)               ; seconds
 158           (tv-usec time-t)))            ; and microseconds
 159 \f
 160 ;;;; resourcebits.h
 161
 162 (defconstant rusage_self 0) ; the calling process
 163 (defconstant rusage_children -1) ; terminated child processes
 164 (defconstant rusage_both -2)
 165
 166 (def-alien-type nil
 167   (struct rusage
 168     (ru-utime (struct timeval))     ; user time used
 169     (ru-stime (struct timeval))     ; system time used.
 170     (ru-maxrss long)                ; maximum resident set size (in kilobytes)
 171     (ru-ixrss long)                 ; integral shared memory size
 172     (ru-idrss long)                 ; integral unshared data size
 173     (ru-isrss long)                 ; integral unshared stack size
 174     (ru-minflt long)                ; page reclaims
 175     (ru-majflt long)                ; page faults
 176     (ru-nswap long)                 ; swaps
 177     (ru-inblock long)               ; block input operations
 178     (ru-oublock long)               ; block output operations
 179     (ru-msgsnd long)                ; messages sent
 180     (ru-msgrcv long)                ; messages received
 181     (ru-nsignals long)              ; signals received
 182     (ru-nvcsw long)                 ; voluntary context switches
 183     (ru-nivcsw long)))              ; involuntary context switches
 184 \f
 185 ;;;; unistd.h
 186
 187 ;;; Given a file path (a string) and one of four constant modes,
 188 ;;; return T if the file is accessible with that mode and NIL if not.
 189 ;;; When NIL, also return an errno value with NIL which tells why the
 190 ;;; file was not accessible.
 191 ;;;
 192 ;;; The access modes are:
 193 ;;;   r_ok     Read permission.
 194 ;;;   w_ok     Write permission.
 195 ;;;   x_ok     Execute permission.
 196 ;;;   f_ok     Presence of file.
 197 (defun unix-access (path mode)
 198   (declare (type unix-pathname path)
 199            (type (mod 8) mode))
 200   (void-syscall ("access" c-string int) path mode))
 201
 202 ;;; values for the second argument to UNIX-LSEEK
 203 (defconstant l_set 0) ; to set the file pointer
 204 (defconstant l_incr 1) ; to increment the file pointer
 205 (defconstant l_xtnd 2) ; to extend the file size
 206
 207 ;;; Accept a file descriptor and move the file pointer ahead
 208 ;;; a certain offset for that file. WHENCE can be any of the following:
 209 ;;;  L_SET     Set the file pointer.
 210 ;;;  L_INCR    Increment the file pointer.
 211 ;;;  L_XTND    Extend the file size.
 212 (defun unix-lseek (fd offset whence)
 213   (declare (type unix-fd fd)
 214            (type (unsigned-byte 32) offset)
 215            (type (integer 0 2) whence))
 216   #!-(and x86 bsd)
 217   (int-syscall ("lseek" int off-t int) fd offset whence)
 218   ;; Need a 64-bit return value type for this. TBD. For now,
 219   ;; don't use this with any 2G+ partitions.
 220   #!+(and x86 bsd)
 221   (int-syscall ("lseek" int unsigned-long unsigned-long int)
 222                fd offset 0 whence))
 223
 224 ;;; UNIX-READ accepts a file descriptor, a buffer, and the length to read.
 225 ;;; It attempts to read len bytes from the device associated with fd
 226 ;;; and store them into the buffer. It returns the actual number of
 227 ;;; bytes read.
 228 (defun unix-read (fd buf len)
 229   (declare (type unix-fd fd)
 230            (type (unsigned-byte 32) len))
 231
 232   (int-syscall ("read" int (* char) int) fd buf len))
 233
 234 ;;; UNIX-WRITE accepts a file descriptor, a buffer, an offset, and the
 235 ;;; length to write. It attempts to write len bytes to the device
 236 ;;; associated with fd from the the buffer starting at offset. It returns
 237 ;;; the actual number of bytes written.
 238 (defun unix-write (fd buf offset len)
 239   (declare (type unix-fd fd)
 240            (type (unsigned-byte 32) offset len))
 241   (int-syscall ("write" int (* char) int)
 242                fd
 243                (with-alien ((ptr (* char) (etypecase buf
 244                                             ((simple-array * (*))
 245                                              (vector-sap buf))
 246                                             (system-area-pointer
 247                                              buf))))
 248                  (addr (deref ptr offset)))
 249                len))
 250
 251 ;;; Set up a unix-piping mechanism consisting of an input pipe and an
 252 ;;; output pipe. Return two values: if no error occurred the first
 253 ;;; value is the pipe to be read from and the second is can be written
 254 ;;; to. If an error occurred the first value is NIL and the second the
 255 ;;; unix error code.
 256 (defun unix-pipe ()
 257   (with-alien ((fds (array int 2)))
 258     (syscall ("pipe" (* int))
 259              (values (deref fds 0) (deref fds 1))
 260              (cast fds (* int)))))
 261
 262 (defun unix-mkdir (name mode)
 263   (declare (type unix-pathname name)
 264            (type unix-file-mode mode))
 265   (void-syscall ("mkdir" c-string int) name mode))
 266
 267 ;;; Return the Unix current directory as a SIMPLE-STRING, in the
 268 ;;; style returned by getcwd() (no trailing slash character).
 269 (defun posix-getcwd ()
 270   ;; This implementation relies on a BSD/Linux extension to getcwd()
 271   ;; behavior, automatically allocating memory when a null buffer
 272   ;; pointer is used. On a system which doesn't support that
 273   ;; extension, it'll have to be rewritten somehow.
 274   #!-(or linux openbsd freebsd) (,stub,)
 275   (let* ((raw-char-ptr (alien-funcall (extern-alien "getcwd"
 276                                                     (function (* char)
 277                                                               (* char) size-t))
 278                                       nil 0)))
 279     (if (null-alien raw-char-ptr)
 280         (simple-perror "getcwd")
 281         (prog1
 282             (cast raw-char-ptr c-string)
 283           (free-alien raw-char-ptr)))))
 284
 285 ;;; Return the Unix current directory as a SIMPLE-STRING terminated
 286 ;;; by a slash character.
 287 (defun posix-getcwd/ ()
 288   (concatenate 'string (posix-getcwd) "/"))
 289
 290 ;;; Convert at the UNIX level from a possibly relative filename to
 291 ;;; an absolute filename.
 292 ;;;
 293 ;;; FIXME: Do we still need this even as we switch to
 294 ;;; *DEFAULT-PATHNAME-DEFAULTS*? I think maybe we do, since it seems
 295 ;;; to be valid for the user to set *DEFAULT-PATHNAME-DEFAULTS* to
 296 ;;; have a NIL directory component, and then this'd be the only way to
 297 ;;; interpret a relative directory specification. But I don't find the
 298 ;;; ANSI pathname documentation to be a model of clarity. Maybe
 299 ;;; someone who understands it better can take a look at this.. -- WHN
 300 (defun unix-maybe-prepend-current-directory (name)
 301   (declare (simple-string name))
 302   (if (and (> (length name) 0) (char= (schar name 0) #\/))
 303       name
 304       (concatenate 'simple-string (posix-getcwd/) name)))
 305
 306 ;;; Duplicate an existing file descriptor (given as the argument) and
 307 ;;; return it. If FD is not a valid file descriptor, NIL and an error
 308 ;;; number are returned.
 309 (defun unix-dup (fd)
 310   (declare (type unix-fd fd))
 311   (int-syscall ("dup" int) fd))
 312
 313 ;;; Terminate the current process with an optional error code. If
 314 ;;; successful, the call doesn't return. If unsuccessful, the call
 315 ;;; returns NIL and an error number.
 316 (defun unix-exit (&optional (code 0))
 317   (declare (type (signed-byte 32) code))
 318   (void-syscall ("exit" int) code))
 319
 320 ;;; Return the process id of the current process.
 321 (def-alien-routine ("getpid" unix-getpid) int)
 322
 323 ;;; Return the real user-id associated with the current process.
 324 (def-alien-routine ("getuid" unix-getuid) int)
 325
 326 ;;; Invoke readlink(2) on the file name specified by PATH. Return
 327 ;;; (VALUES LINKSTRING NIL) on success, or (VALUES NIL ERRNO) on
 328 ;;; failure.
 329 (defun unix-readlink (path)
 330   (declare (type unix-pathname path))
 331   (with-alien ((ptr (* char)
 332                     (alien-funcall (extern-alien
 333                                     "wrapped_readlink"
 334                                     (function (* char) c-string))
 335                                    path)))
 336     (if (null-alien ptr)
 337         (values nil (get-errno))
 338         (multiple-value-prog1
 339             (values (with-alien ((c-string c-string ptr)) c-string)
 340                     nil)
 341           (free-alien ptr)))))
 342
 343 ;;; UNIX-UNLINK accepts a name and deletes the directory entry for that
 344 ;;; name and the file if this is the last link.
 345 (defun unix-unlink (name)
 346   (declare (type unix-pathname name))
 347   (void-syscall ("unlink" c-string) name))
 348
 349 ;;; Set the tty-process-group for the unix file-descriptor FD to PGRP.
 350 ;;; If not supplied, FD defaults to "/dev/tty".
 351 (defun %set-tty-process-group (pgrp &optional fd)
 352   (let ((old-sigs (unix-sigblock (sigmask :sigttou
 353                                           :sigttin
 354                                           :sigtstp
 355                                           :sigchld))))
 356     (declare (type (unsigned-byte 32) old-sigs))
 357     (unwind-protect
 358         (if fd
 359             (tcsetpgrp fd pgrp)
 360             (multiple-value-bind (tty-fd errno) (unix-open "/dev/tty" o_rdwr 0)
 361               (cond (tty-fd
 362                      (multiple-value-prog1
 363                          (tcsetpgrp tty-fd pgrp)
 364                        (unix-close tty-fd)))
 365                     (t
 366                      (values nil errno)))))
 367       (unix-sigsetmask old-sigs))))
 368
 369 ;;; Return the name of the host machine as a string.
 370 (defun unix-gethostname ()
 371   (with-alien ((buf (array char 256)))
 372     (syscall ("gethostname" (* char) int)
 373              (cast buf c-string)
 374              (cast buf (* char)) 256)))
 375
 376 ;;; Write the core image of the file described by FD to disk.
 377 (defun unix-fsync (fd)
 378   (declare (type unix-fd fd))
 379   (void-syscall ("fsync" int) fd))
 380 \f
 381 ;;;; sys/ioctl.h
 382
 383 ;;; UNIX-IOCTL performs a variety of operations on open i/o
 384 ;;; descriptors. See the UNIX Programmer's Manual for more
 385 ;;; information.
 386 (defun unix-ioctl (fd cmd arg)
 387   (declare (type unix-fd fd)
 388            (type (unsigned-byte 32) cmd))
 389   (void-syscall ("ioctl" int unsigned-int (* char)) fd cmd arg))
 390 \f
 391 ;;;; sys/resource.h
 392
 393 ;;; FIXME: All we seem to need is the RUSAGE_SELF version of this.
 394 ;;;
 395 ;;; Like getrusage(2), but return only the system and user time,
 396 ;;; and return the seconds and microseconds as separate values.
 397 #!-sb-fluid (declaim (inline unix-fast-getrusage))
 398 (defun unix-fast-getrusage (who)
 399   (declare (values (member t)
 400                    (unsigned-byte 31) (integer 0 1000000)
 401                    (unsigned-byte 31) (integer 0 1000000)))
 402   (with-alien ((usage (struct rusage)))
 403     (syscall* ("getrusage" int (* (struct rusage)))
 404               (values t
 405                       (slot (slot usage 'ru-utime) 'tv-sec)
 406                       (slot (slot usage 'ru-utime) 'tv-usec)
 407                       (slot (slot usage 'ru-stime) 'tv-sec)
 408                       (slot (slot usage 'ru-stime) 'tv-usec))
 409               who (addr usage))))
 410
 411 ;;; Return information about the resource usage of the process
 412 ;;; specified by WHO. WHO can be either the current process
 413 ;;; (rusage_self) or all of the terminated child processes
 414 ;;; (rusage_children). NIL and an error number is returned if the call
 415 ;;; fails.
 416 (defun unix-getrusage (who)
 417   (with-alien ((usage (struct rusage)))
 418     (syscall ("getrusage" int (* (struct rusage)))
 419               (values t
 420                       (+ (* (slot (slot usage 'ru-utime) 'tv-sec) 1000000)
 421                          (slot (slot usage 'ru-utime) 'tv-usec))
 422                       (+ (* (slot (slot usage 'ru-stime) 'tv-sec) 1000000)
 423                          (slot (slot usage 'ru-stime) 'tv-usec))
 424                       (slot usage 'ru-maxrss)
 425                       (slot usage 'ru-ixrss)
 426                       (slot usage 'ru-idrss)
 427                       (slot usage 'ru-isrss)
 428                       (slot usage 'ru-minflt)
 429                       (slot usage 'ru-majflt)
 430                       (slot usage 'ru-nswap)
 431                       (slot usage 'ru-inblock)
 432                       (slot usage 'ru-oublock)
 433                       (slot usage 'ru-msgsnd)
 434                       (slot usage 'ru-msgrcv)
 435                       (slot usage 'ru-nsignals)
 436                       (slot usage 'ru-nvcsw)
 437                       (slot usage 'ru-nivcsw))
 438               who (addr usage))))
 439 \f
 440 ;;;; sys/select.h
 441
 442 (defmacro unix-fast-select (num-descriptors
 443                             read-fds write-fds exception-fds
 444                             timeout-secs &optional (timeout-usecs 0))
 445   #!+sb-doc
 446   "Perform the UNIX select(2) system call."
 447   ;; FIXME: These DECLAREs don't belong at macroexpansion time. They
 448   ;; should be done at runtime instead. Perhaps we could just redo
 449   ;; UNIX-FAST-SELECT as an inline function, and then all the
 450   ;; declarations would work nicely.
 451   #|
 452   (declare (type (integer 0 #.fd-setsize) num-descriptors)
 453            (type (or (alien (* (struct fd-set))) null)
 454                  read-fds write-fds exception-fds)
 455            (type (or null (unsigned-byte 31)) timeout-secs)
 456            (type (unsigned-byte 31) timeout-usecs))
 457   |#
 458   ;; FIXME: CMU CL had
 459   ;;   (optimize (speed 3) (safety 0) (inhibit-warnings 3))
 460   ;; in the declarations above. If they're important, they should
 461   ;; be in a declaration inside the LET expansion, not in the
 462   ;; macro compile-time code.
 463   `(let ((timeout-secs ,timeout-secs))
 464      (with-alien ((tv (struct timeval)))
 465        (when timeout-secs
 466          (setf (slot tv 'tv-sec) timeout-secs)
 467          (setf (slot tv 'tv-usec) ,timeout-usecs))
 468        (int-syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 469                      (* (struct fd-set)) (* (struct timeval)))
 470                     ,num-descriptors ,read-fds ,write-fds ,exception-fds
 471                     (if timeout-secs (alien-sap (addr tv)) (int-sap 0))))))
 472
 473 ;;; UNIX-SELECT accepts sets of file descriptors and waits for an event
 474 ;;; to happen on one of them or to time out.
 475 (defmacro num-to-fd-set (fdset num)
 476   `(if (fixnump ,num)
 477        (progn
 478          (setf (deref (slot ,fdset 'fds-bits) 0) ,num)
 479          ,@(loop for index upfrom 1 below (/ fd-setsize 32)
 480              collect `(setf (deref (slot ,fdset 'fds-bits) ,index) 0)))
 481        (progn
 482          ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 483              collect `(setf (deref (slot ,fdset 'fds-bits) ,index)
 484                             (ldb (byte 32 ,(* index 32)) ,num))))))
 485
 486 (defmacro fd-set-to-num (nfds fdset)
 487   `(if (<= ,nfds 32)
 488        (deref (slot ,fdset 'fds-bits) 0)
 489        (+ ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 490               collect `(ash (deref (slot ,fdset 'fds-bits) ,index)
 491                             ,(* index 32))))))
 492
 493 ;;; Examine the sets of descriptors passed as arguments to see whether
 494 ;;; they are ready for reading and writing. See the UNIX Programmer's
 495 ;;; Manual for more information.
 496 (defun unix-select (nfds rdfds wrfds xpfds to-secs &optional (to-usecs 0))
 497   (declare (type (integer 0 #.FD-SETSIZE) nfds)
 498            (type unsigned-byte rdfds wrfds xpfds)
 499            (type (or (unsigned-byte 31) null) to-secs)
 500            (type (unsigned-byte 31) to-usecs)
 501            (optimize (speed 3) (safety 0) (inhibit-warnings 3)))
 502   (with-alien ((tv (struct timeval))
 503                (rdf (struct fd-set))
 504                (wrf (struct fd-set))
 505                (xpf (struct fd-set)))
 506     (when to-secs
 507       (setf (slot tv 'tv-sec) to-secs)
 508      (setf (slot tv 'tv-usec) to-usecs))
 509     (num-to-fd-set rdf rdfds)
 510     (num-to-fd-set wrf wrfds)
 511     (num-to-fd-set xpf xpfds)
 512     (macrolet ((frob (lispvar alienvar)
 513                  `(if (zerop ,lispvar)
 514                       (int-sap 0)
 515                       (alien-sap (addr ,alienvar)))))
 516       (syscall ("select" int (* (struct fd-set)) (* (struct fd-set))
 517                 (* (struct fd-set)) (* (struct timeval)))
 518                (values result
 519                        (fd-set-to-num nfds rdf)
 520                        (fd-set-to-num nfds wrf)
 521                        (fd-set-to-num nfds xpf))
 522                nfds (frob rdfds rdf) (frob wrfds wrf) (frob xpfds xpf)
 523                (if to-secs (alien-sap (addr tv)) (int-sap 0))))))
 524 \f
 525 ;;;; sys/stat.h
 526
 527 ;;; This is a structure defined in src/runtime/wrap.c, to look
 528 ;;; basically like "struct stat" according to stat(2). It may not
 529 ;;; actually correspond to the real in-memory stat structure that the
 530 ;;; syscall uses, and that's OK. Linux in particular is packed full of
 531 ;;; stat macros, and trying to keep Lisp code in correspondence with
 532 ;;; it is more pain than it's worth, so we just let our C runtime
 533 ;;; synthesize a nice consistent structure for us.
 534 ;;;
 535 ;;; Note that st-dev is a long, not a dev-t. This is because dev-t on
 536 ;;; linux 32 bit archs is a 64 bit quantity, but alien doesn's support
 537 ;;; those. We don't actually access that field anywhere, though, so
 538 ;;; until we can get 64 bit alien support it'll do. Also note that
 539 ;;; st_size is a long, not an off-t, because off-t is a 64-bit
 540 ;;; quantity on Alpha. And FIXME: "No one would want a file length
 541 ;;; longer than 32 bits anyway, right?":-|
 542 (def-alien-type nil
 543   (struct wrapped_stat
 544     (st-dev unsigned-long)              ; would be dev-t in a real stat
 545     (st-ino ino-t)
 546     (st-mode mode-t)
 547     (st-nlink  nlink-t)
 548     (st-uid  uid-t)
 549     (st-gid  gid-t)
 550     (st-rdev unsigned-long)             ; would be dev-t in a real stat
 551     (st-size unsigned-long)             ; would be off-t in a real stat
 552     (st-blksize unsigned-long)
 553     (st-blocks unsigned-long)
 554     (st-atime time-t)
 555     (st-mtime time-t)
 556     (st-ctime time-t)))
 557
 558 ;;; shared C-struct-to-multiple-VALUES conversion for the stat(2)
 559 ;;; family of Unix system calls
 560 ;;;
 561 ;;; FIXME: I think this should probably not be INLINE. However, when
 562 ;;; this was not inline, it seemed to cause memory corruption
 563 ;;; problems. My first guess is that it's a bug in the FFI code, where
 564 ;;; the WITH-ALIEN expansion doesn't deal well with being wrapped
 565 ;;; around a call to a function returning >10 values. But I didn't try
 566 ;;; to figure it out, just inlined it as a quick fix. Perhaps someone
 567 ;;; who's motivated to debug the FFI code can go over the DISASSEMBLE
 568 ;;; output in the not-inlined case and see whether there's a problem,
 569 ;;; and maybe even find a fix..
 570 (declaim (inline %extract-stat-results))
 571 (defun %extract-stat-results (wrapped-stat)
 572   (declare (type (alien (* (struct wrapped_stat))) wrapped-stat))
 573   (values t
 574           (slot wrapped-stat 'st-dev)
 575           (slot wrapped-stat 'st-ino)
 576           (slot wrapped-stat 'st-mode)
 577           (slot wrapped-stat 'st-nlink)
 578           (slot wrapped-stat 'st-uid)
 579           (slot wrapped-stat 'st-gid)
 580           (slot wrapped-stat 'st-rdev)
 581           (slot wrapped-stat 'st-size)
 582           (slot wrapped-stat 'st-atime)
 583           (slot wrapped-stat 'st-mtime)
 584           (slot wrapped-stat 'st-ctime)
 585           (slot wrapped-stat 'st-blksize)
 586           (slot wrapped-stat 'st-blocks)))
 587
 588 ;;; Unix system calls in the stat(2) family are handled by calls to
 589 ;;; C-level wrapper functions which copy all the raw "struct stat"
 590 ;;; slots into the system-independent wrapped_stat format.
 591 ;;;    stat(2) <->  stat_wrapper()
 592 ;;;   fstat(2) <-> fstat_wrapper()
 593 ;;;   lstat(2) <-> lstat_wrapper()
 594 (defun unix-stat (name)
 595   (declare (type unix-pathname name))
 596   (with-alien ((buf (struct wrapped_stat)))
 597     (syscall ("stat_wrapper" c-string (* (struct wrapped_stat)))
 598              (%extract-stat-results (addr buf))
 599              name (addr buf))))
 600 (defun unix-lstat (name)
 601   (declare (type unix-pathname name))
 602   (with-alien ((buf (struct wrapped_stat)))
 603     (syscall ("lstat_wrapper" c-string (* (struct wrapped_stat)))
 604              (%extract-stat-results (addr buf))
 605              name (addr buf))))
 606 (defun unix-fstat (fd)
 607   (declare (type unix-fd fd))
 608   (with-alien ((buf (struct wrapped_stat)))
 609     (syscall ("fstat_wrapper" int (* (struct wrapped_stat)))
 610              (%extract-stat-results (addr buf))
 611              fd (addr buf))))
 612 \f
 613 ;;;; time.h
 614
 615 ;; the POSIX.4 structure for a time value. This is like a "struct
 616 ;; timeval" but has nanoseconds instead of microseconds.
 617 (def-alien-type nil
 618     (struct timespec
 619             (tv-sec long)   ; seconds
 620             (tv-nsec long))) ; nanoseconds
 621
 622 ;; used by other time functions
 623 (def-alien-type nil
 624     (struct tm
 625             (tm-sec int)   ; Seconds.   [0-60] (1 leap second)
 626             (tm-min int)   ; Minutes.   [0-59]
 627             (tm-hour int)  ; Hours.     [0-23]
 628             (tm-mday int)  ; Day.       [1-31]
 629             (tm-mon int)   ; Month.     [0-11]
 630             (tm-year int)  ; Year - 1900.
 631             (tm-wday int)  ; Day of week. [0-6]
 632             (tm-yday int)  ; Days in year. [0-365]
 633             (tm-isdst int) ; DST.       [-1/0/1]
 634             (tm-gmtoff long) ;  Seconds east of UTC.
 635             (tm-zone c-string))) ; Timezone abbreviation.
 636
 637 (def-alien-routine get-timezone sb!c-call:void
 638   (when sb!c-call:long :in)
 639   (minutes-west sb!c-call:int :out)
 640   (daylight-savings-p sb!alien:boolean :out))
 641
 642 (defun unix-get-minutes-west (secs)
 643   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 644     (declare (ignore ignore) (ignore dst))
 645     (values minutes)))
 646
 647 (defun unix-get-timezone (secs)
 648   (multiple-value-bind (ignore minutes dst) (get-timezone secs)
 649     (declare (ignore ignore) (ignore minutes))
 650     (values (deref unix-tzname (if dst 1 0)))))
 651
 652 \f
 653 ;;;; sys/time.h
 654
 655 ;;; Structure crudely representing a timezone. KLUDGE: This is
 656 ;;; obsolete and should never be used.
 657 (def-alien-type nil
 658   (struct timezone
 659     (tz-minuteswest int)                ; minutes west of Greenwich
 660     (tz-dsttime int)))                  ; type of dst correction
 661
 662 ;;; If it works, UNIX-GETTIMEOFDAY returns 5 values: T, the seconds
 663 ;;; and microseconds of the current time of day, the timezone (in
 664 ;;; minutes west of Greenwich), and a daylight-savings flag. If it
 665 ;;; doesn't work, it returns NIL and the errno.
 666 #!-sb-fluid (declaim (inline unix-gettimeofday))
 667 (defun unix-gettimeofday ()
 668   (with-alien ((tv (struct timeval))
 669                (tz (struct timezone)))
 670     (syscall* ("gettimeofday" (* (struct timeval))
 671                               (* (struct timezone)))
 672               (values T
 673                       (slot tv 'tv-sec)
 674                       (slot tv 'tv-usec)
 675                       (slot tz 'tz-minuteswest)
 676                       (slot tz 'tz-dsttime))
 677               (addr tv)
 678               (addr tz))))
 679 \f
 680
 681 (defconstant ENOENT 2) ; Unix error code, "No such file or directory"
 682 (defconstant EINTR 4) ; Unix error code, "Interrupted system call"
 683 (defconstant EIO 5) ; Unix error code, "I/O error"
 684 (defconstant EEXIST 17) ; Unix error code, "File exists"
 685 (defconstant ESPIPE 29) ; Unix error code, "Illegal seek"
 686 (defconstant EWOULDBLOCK 11) ; Unix error code, "Operation would block"
 687 ;;; FIXME: Many Unix error code definitions were deleted from the old
 688 ;;; CMU CL source code here, but not in the exports of SB-UNIX. I
 689 ;;; (WHN) hope that someday I'll figure out an automatic way to detect
 690 ;;; unused symbols in package exports, but if I don't, there are
 691 ;;; enough of them all in one place here that they should probably be
 692 ;;; removed by hand.
 693 \f
 694 \f
 695 ;;;; support routines for dealing with Unix pathnames
 696
 697 (defun unix-file-kind (name &optional check-for-links)
 698   #!+sb-doc
 699   "Return either :FILE, :DIRECTORY, :LINK, :SPECIAL, or NIL."
 700   (declare (simple-string name))
 701   (multiple-value-bind (res dev ino mode)
 702       (if check-for-links (unix-lstat name) (unix-stat name))
 703     (declare (type (or fixnum null) mode)
 704              (ignore dev ino))
 705     (when res
 706       (let ((kind (logand mode s-ifmt)))
 707         (cond ((eql kind s-ifdir) :directory)
 708               ((eql kind s-ifreg) :file)
 709               ((eql kind s-iflnk) :link)
 710               (t :special))))))
 711
 712 ;;; Is the Unix pathname PATHNAME relative, instead of absolute? (E.g.
 713 ;;; "passwd" or "etc/passwd" instead of "/etc/passwd"?)
 714 (defun relative-unix-pathname? (pathname)
 715   (declare (type simple-string pathname))
 716   (or (zerop (length pathname))
 717       (char/= (schar pathname 0) #\/)))
 718
 719 ;;; Return PATHNAME with all symbolic links resolved. PATHNAME should
 720 ;;; already be a complete absolute Unix pathname, since at least in
 721 ;;; sbcl-0.6.12.36 we're called only from TRUENAME, and only after
 722 ;;; paths have been converted to absolute paths, so we don't need to
 723 ;;; try to handle any more generality than that.
 724 (defun unix-resolve-links (pathname)
 725   (declare (type simple-string pathname))
 726   (aver (not (relative-unix-pathname? pathname)))
 727   (/show "entering UNIX-RESOLVE-LINKS")
 728   (loop with previous-pathnames = nil do
 729         (/show pathname previous-pathnames)
 730         (let ((link (unix-readlink pathname)))
 731           (/show link)
 732           ;; Unlike the old CMU CL code, we handle a broken symlink by
 733           ;; returning the link itself. That way, CL:TRUENAME on a
 734           ;; broken link returns the link itself, so that CL:DIRECTORY
 735           ;; can return broken links, so that even without
 736           ;; Unix-specific extensions to do interesting things with
 737           ;; them, at least Lisp programs can see them and, if
 738           ;; necessary, delete them. (This is handy e.g. when your
 739           ;; managed-by-Lisp directories are visited by Emacs, which
 740           ;; creates broken links as notes to itself.)
 741           (if (null link)
 742               (return pathname)
 743               (let ((new-pathname
 744                      (unix-simplify-pathname
 745                       (if (relative-unix-pathname? link)
 746                           (let* ((dir-len (1+ (position #\/
 747                                                         pathname
 748                                                         :from-end t)))
 749                                  (dir (subseq pathname 0 dir-len)))
 750                             (/show dir)
 751                             (concatenate 'string dir link))
 752                           link))))
 753                 (if (unix-file-kind new-pathname)
 754                     (setf pathname new-pathname)
 755                     (return pathname)))))
 756         ;; To generalize the principle that even if portable Lisp code
 757         ;; can't do anything interesting with a broken symlink, at
 758         ;; least it should be able to see and delete it, when we
 759         ;; detect a cyclic link, we return the link itself. (So even
 760         ;; though portable Lisp code can't do anything interesting
 761         ;; with a cyclic link, at least it can see it and delete it.)
 762         (if (member pathname previous-pathnames :test #'string=)
 763             (return pathname)
 764             (push pathname previous-pathnames))))
 765
 766 (defun unix-simplify-pathname (src)
 767   (declare (type simple-string src))
 768   (let* ((src-len (length src))
 769          (dst (make-string src-len))
 770          (dst-len 0)
 771          (dots 0)
 772          (last-slash nil))
 773     (macrolet ((deposit (char)
 774                  `(progn
 775                     (setf (schar dst dst-len) ,char)
 776                     (incf dst-len))))
 777       (dotimes (src-index src-len)
 778         (let ((char (schar src src-index)))
 779           (cond ((char= char #\.)
 780                  (when dots
 781                    (incf dots))
 782                  (deposit char))
 783                 ((char= char #\/)
 784                  (case dots
 785                    (0
 786                     ;; either ``/...' or ``...//...'
 787                     (unless last-slash
 788                       (setf last-slash dst-len)
 789                       (deposit char)))
 790                    (1
 791                     ;; either ``./...'' or ``..././...''
 792                     (decf dst-len))
 793                    (2
 794                     ;; We've found ..
 795                     (cond
 796                      ((and last-slash (not (zerop last-slash)))
 797                       ;; There is something before this ..
 798                       (let ((prev-prev-slash
 799                              (position #\/ dst :end last-slash :from-end t)))
 800                         (cond ((and (= (+ (or prev-prev-slash 0) 2)
 801                                        last-slash)
 802                                     (char= (schar dst (- last-slash 2)) #\.)
 803                                     (char= (schar dst (1- last-slash)) #\.))
 804                                ;; The something before this .. is another ..
 805                                (deposit char)
 806                                (setf last-slash dst-len))
 807                               (t
 808                                ;; The something is some directory or other.
 809                                (setf dst-len
 810                                      (if prev-prev-slash
 811                                          (1+ prev-prev-slash)
 812                                          0))
 813                                (setf last-slash prev-prev-slash)))))
 814                      (t
 815                       ;; There is nothing before this .., so we need to keep it
 816                       (setf last-slash dst-len)
 817                       (deposit char))))
 818                    (t
 819                     ;; something other than a dot between slashes
 820                     (setf last-slash dst-len)
 821                     (deposit char)))
 822                  (setf dots 0))
 823                 (t
 824                  (setf dots nil)
 825                  (setf (schar dst dst-len) char)
 826                  (incf dst-len))))))
 827     (when (and last-slash (not (zerop last-slash)))
 828       (case dots
 829         (1
 830          ;; We've got  ``foobar/.''
 831          (decf dst-len))
 832         (2
 833          ;; We've got ``foobar/..''
 834          (unless (and (>= last-slash 2)
 835                       (char= (schar dst (1- last-slash)) #\.)
 836                       (char= (schar dst (- last-slash 2)) #\.)
 837                       (or (= last-slash 2)
 838                           (char= (schar dst (- last-slash 3)) #\/)))
 839            (let ((prev-prev-slash
 840                   (position #\/ dst :end last-slash :from-end t)))
 841              (if prev-prev-slash
 842                  (setf dst-len (1+ prev-prev-slash))
 843                  (return-from unix-simplify-pathname "./")))))))
 844     (cond ((zerop dst-len)
 845            "./")
 846           ((= dst-len src-len)
 847            dst)
 848           (t
 849            (subseq dst 0 dst-len)))))
 850 \f
 851 ;;;; stuff not yet found in the header files
 852 ;;;;
 853 ;;;; Abandon all hope who enters here...
 854
 855 ;;; not checked for linux...
 856 (defmacro fd-set (offset fd-set)
 857   (let ((word (gensym))
 858         (bit (gensym)))
 859     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 860        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 861              (logior (truly-the (unsigned-byte 32) (ash 1 ,bit))
 862                      (deref (slot ,fd-set 'fds-bits) ,word))))))
 863
 864 ;;; not checked for linux...
 865 (defmacro fd-clr (offset fd-set)
 866   (let ((word (gensym))
 867         (bit (gensym)))
 868     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 869        (setf (deref (slot ,fd-set 'fds-bits) ,word)
 870              (logand (deref (slot ,fd-set 'fds-bits) ,word)
 871                      (sb!kernel:32bit-logical-not
 872                       (truly-the (unsigned-byte 32) (ash 1 ,bit))))))))
 873
 874 ;;; not checked for linux...
 875 (defmacro fd-isset (offset fd-set)
 876   (let ((word (gensym))
 877         (bit (gensym)))
 878     `(multiple-value-bind (,word ,bit) (floor ,offset 32)
 879        (logbitp ,bit (deref (slot ,fd-set 'fds-bits) ,word)))))
 880
 881 ;;; not checked for linux...
 882 (defmacro fd-zero (fd-set)
 883   `(progn
 884      ,@(loop for index upfrom 0 below (/ fd-setsize 32)
 885          collect `(setf (deref (slot ,fd-set 'fds-bits) ,index) 0))))
 886
 887