src/code/win32-pathname.lisp

   1 ;;;; pathname parsing for Win32 filesystems
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 (defun extract-device (namestr start end)
  15   (declare (type simple-string namestr)
  16            (type index start end))
  17   (if (and (>= end (+ start 2))
  18            (alpha-char-p (char namestr start))
  19            (eql (char namestr (1+ start)) #\:))
  20       (values (string (char namestr start)) (+ start 2))
  21       (values nil start)))
  22
  23 (defun split-at-slashes-and-backslashes (namestr start end)
  24   (declare (type simple-string namestr)
  25            (type index start end))
  26   (let ((absolute (and (/= start end)
  27                        (or (char= (schar namestr start) #\/)
  28                            (char= (schar namestr start) #\\)))))
  29     (when absolute
  30       (incf start))
  31     ;; Next, split the remainder into slash-separated chunks.
  32     (collect ((pieces))
  33       (loop
  34          (let ((slash (position-if (lambda (c)
  35                                      (or (char= c #\/)
  36                                          (char= c #\\)))
  37                                    namestr :start start :end end)))
  38            (pieces (cons start (or slash end)))
  39            (unless slash
  40              (return))
  41            (setf start (1+ slash))))
  42       (values absolute (pieces)))))
  43
  44 (defun parse-win32-namestring (namestring start end)
  45   (declare (type simple-string namestring)
  46            (type index start end))
  47   (setf namestring (coerce namestring 'simple-string))
  48   (multiple-value-bind (device new-start)
  49       (extract-device namestring start end)
  50     (multiple-value-bind (absolute pieces)
  51         (split-at-slashes-and-backslashes namestring new-start end)
  52       (multiple-value-bind (name type version)
  53           (let* ((tail (car (last pieces)))
  54                  (tail-start (car tail))
  55                  (tail-end (cdr tail)))
  56             (unless (= tail-start tail-end)
  57               (setf pieces (butlast pieces))
  58               (extract-name-type-and-version namestring tail-start tail-end)))
  59
  60         (when (stringp name)
  61           (let ((position (position-if (lambda (char)
  62                                          (or (char= char (code-char 0))
  63                                              (char= char #\/)))
  64                                        name)))
  65             (when position
  66               (error 'namestring-parse-error
  67                      :complaint "can't embed #\\Nul or #\\/ in Unix namestring"
  68                      :namestring namestring
  69                      :offset position))))
  70         ;; Now we have everything we want. So return it.
  71         (values nil ; no host for Win32 namestrings
  72                 device
  73                 (collect ((dirs))
  74                   (dolist (piece pieces)
  75                     (let ((piece-start (car piece))
  76                           (piece-end (cdr piece)))
  77                       (unless (= piece-start piece-end)
  78                         (cond ((string= namestring ".."
  79                                         :start1 piece-start
  80                                         :end1 piece-end)
  81                                (dirs :up))
  82                               ((string= namestring "**"
  83                                         :start1 piece-start
  84                                         :end1 piece-end)
  85                                (dirs :wild-inferiors))
  86                               (t
  87                                (dirs (maybe-make-pattern namestring
  88                                                          piece-start
  89                                                          piece-end)))))))
  90                   (cond (absolute
  91                          (cons :absolute (dirs)))
  92                         ((dirs)
  93                          (cons :relative (dirs)))
  94                         (t
  95                          nil)))
  96                 name
  97                 type
  98                 version)))))
  99
 100 (defun parse-native-win32-namestring (namestring start end as-directory)
 101   (declare (type simple-string namestring)
 102            (type index start end))
 103   (setf namestring (coerce namestring 'simple-string))
 104   (multiple-value-bind (device new-start)
 105       (extract-device namestring start end)
 106     (multiple-value-bind (absolute ranges)
 107         (split-at-slashes-and-backslashes namestring new-start end)
 108       (let* ((components (loop for ((start . end) . rest) on ranges
 109                                for piece = (subseq namestring start end)
 110                                collect (if (and (string= piece "..") rest)
 111                                            :up
 112                                            piece)))
 113              (directory (if (and as-directory
 114                                  (string/= "" (car (last components))))
 115                             components
 116                             (butlast components)))
 117              (name-and-type
 118               (unless as-directory
 119                 (let* ((end (first (last components)))
 120                        (dot (position #\. end :from-end t)))
 121                   ;; FIXME: can we get this dot-interpretation knowledge
 122                   ;; from existing code?  EXTRACT-NAME-TYPE-AND-VERSION
 123                   ;; does slightly more work than that.
 124                   (cond
 125                     ((string= end "")
 126                      (list nil nil))
 127                     ((and dot (> dot 0))
 128                      (list (subseq end 0 dot) (subseq end (1+ dot))))
 129                     (t
 130                      (list end nil)))))))
 131         (values nil
 132                 device
 133                 (cons (if absolute :absolute :relative) directory)
 134                 (first name-and-type)
 135                 (second name-and-type)
 136                 nil)))))
 137
 138
 139
 140 (defun unparse-win32-host (pathname)
 141   (declare (type pathname pathname)
 142            (ignore pathname))
 143   ;; FIXME: same as UNPARSE-UNIX-HOST.  That's probably not good.
 144   "")
 145
 146 (defun unparse-win32-device (pathname)
 147   (declare (type pathname pathname))
 148   (let ((device (pathname-device pathname)))
 149     (if (or (null device) (eq device :unspecific))
 150         ""
 151         (concatenate 'simple-string (string device) ":"))))
 152
 153 (defun unparse-win32-piece (thing)
 154   (etypecase thing
 155     ((member :wild) "*")
 156     (simple-string
 157      (let* ((srclen (length thing))
 158             (dstlen srclen))
 159        (dotimes (i srclen)
 160          (case (schar thing i)
 161            ((#\* #\? #\[)
 162             (incf dstlen))))
 163        (let ((result (make-string dstlen))
 164              (dst 0))
 165          (dotimes (src srclen)
 166            (let ((char (schar thing src)))
 167              (case char
 168                ((#\* #\? #\[)
 169                 (setf (schar result dst) #\\)
 170                 (incf dst)))
 171              (setf (schar result dst) char)
 172              (incf dst)))
 173          result)))
 174     (pattern
 175      (collect ((strings))
 176        (dolist (piece (pattern-pieces thing))
 177          (etypecase piece
 178            (simple-string
 179             (strings piece))
 180            (symbol
 181             (ecase piece
 182               (:multi-char-wild
 183                (strings "*"))
 184               (:single-char-wild
 185                (strings "?"))))
 186            (cons
 187             (case (car piece)
 188               (:character-set
 189                (strings "[")
 190                (strings (cdr piece))
 191                (strings "]"))
 192               (t
 193                (error "invalid pattern piece: ~S" piece))))))
 194        (apply #'concatenate
 195               'simple-string
 196               (strings))))))
 197
 198 (defun unparse-win32-directory-list (directory)
 199   (declare (type list directory))
 200   (collect ((pieces))
 201     (when directory
 202       (ecase (pop directory)
 203         (:absolute
 204          (pieces "\\"))
 205         (:relative
 206          ;; nothing special
 207          ))
 208       (dolist (dir directory)
 209         (typecase dir
 210           ((member :up)
 211            (pieces "..\\"))
 212           ((member :back)
 213            (error ":BACK cannot be represented in namestrings."))
 214           ((member :wild-inferiors)
 215            (pieces "**\\"))
 216           ((or simple-string pattern (member :wild))
 217            (pieces (unparse-unix-piece dir))
 218            (pieces "\\"))
 219           (t
 220            (error "invalid directory component: ~S" dir)))))
 221     (apply #'concatenate 'simple-string (pieces))))
 222
 223 (defun unparse-win32-directory (pathname)
 224   (declare (type pathname pathname))
 225   (unparse-win32-directory-list (%pathname-directory pathname)))
 226
 227 (defun unparse-win32-file (pathname)
 228   (declare (type pathname pathname))
 229   (collect ((strings))
 230     (let* ((name (%pathname-name pathname))
 231            (type (%pathname-type pathname))
 232            (type-supplied (not (or (null type) (eq type :unspecific)))))
 233       ;; Note: by ANSI 19.3.1.1.5, we ignore the version slot when
 234       ;; translating logical pathnames to a filesystem without
 235       ;; versions (like Win32).
 236       (when name
 237         (when (and (null type)
 238                    (typep name 'string)
 239                    (> (length name) 0)
 240                    (position #\. name :start 1))
 241           (error "too many dots in the name: ~S" pathname))
 242         (when (and (typep name 'string)
 243                    (string= name ""))
 244           (error "name is of length 0: ~S" pathname))
 245         (strings (unparse-unix-piece name)))
 246       (when type-supplied
 247         (unless name
 248           (error "cannot specify the type without a file: ~S" pathname))
 249         (when (typep type 'simple-string)
 250           (when (position #\. type)
 251             (error "type component can't have a #\. inside: ~S" pathname)))
 252         (strings ".")
 253         (strings (unparse-unix-piece type))))
 254     (apply #'concatenate 'simple-string (strings))))
 255
 256 (defun unparse-win32-namestring (pathname)
 257   (declare (type pathname pathname))
 258   (concatenate 'simple-string
 259                (unparse-win32-device pathname)
 260                (unparse-win32-directory pathname)
 261                (unparse-win32-file pathname)))
 262
 263 (defun unparse-native-win32-namestring (pathname as-file)
 264   (declare (type pathname pathname)
 265            ;; Windows doesn't like directory names with trailing slashes.
 266            (ignore as-file))
 267   (let* ((device (pathname-device pathname))
 268          (directory (pathname-directory pathname))
 269          (name (pathname-name pathname))
 270          (name-present-p (typep name '(not (member nil :unspecific))))
 271          (name-string (if name-present-p name ""))
 272          (type (pathname-type pathname))
 273          (type-present-p (typep type '(not (member nil :unspecific))))
 274          (type-string (if type-present-p type "")))
 275     (coerce
 276      (with-output-to-string (s)
 277        (when device
 278          (write-string device s)
 279          (write-char #\: s))
 280        (tagbody
 281           (when directory
 282             (ecase (pop directory)
 283               (:absolute (write-char #\\ s))
 284               (:relative)))
 285           (unless directory (go :done))
 286         :subdir
 287           (let ((piece (pop directory)))
 288             (typecase piece
 289               ((member :up) (write-string ".." s))
 290               (string (write-string piece s))
 291               (t (error "ungood directory segment in NATIVE-NAMESTRING: ~S"
 292                         piece)))
 293             (when (or directory name)
 294               (write-char #\\ s)))
 295           (when directory
 296             (go :subdir))
 297         :done)
 298        (if name-present-p
 299            (progn
 300              (unless (stringp name-string) ;some kind of wild field
 301                (error "ungood name component in NATIVE-NAMESTRING: ~S" name))
 302              (write-string name-string s)
 303              (when type-present-p
 304                (unless (stringp type-string) ;some kind of wild field
 305                  (error "ungood type component in NATIVE-NAMESTRING: ~S" type))
 306                (write-char #\. s)
 307                (write-string type-string s)))
 308            (when type-present-p ;
 309              (error
 310               "type component without a name component in NATIVE-NAMESTRING: ~S"
 311               type))))
 312      'simple-string)))
 313
 314 ;;; FIXME.
 315 (defun unparse-win32-enough (pathname defaults)
 316   (declare (type pathname pathname defaults))
 317   (flet ((lose ()
 318            (error "~S cannot be represented relative to ~S."
 319                   pathname defaults)))
 320     (collect ((strings))
 321       (let* ((pathname-directory (%pathname-directory pathname))
 322              (defaults-directory (%pathname-directory defaults))
 323              (prefix-len (length defaults-directory))
 324              (result-directory
 325               (cond ((null pathname-directory) '(:relative))
 326                     ((eq (car pathname-directory) :relative)
 327                      pathname-directory)
 328                     ((and (> prefix-len 0)
 329                           (>= (length pathname-directory) prefix-len)
 330                           (compare-component (subseq pathname-directory
 331                                                      0 prefix-len)
 332                                              defaults-directory))
 333                      ;; Pathname starts with a prefix of default. So
 334                      ;; just use a relative directory from then on out.
 335                      (cons :relative (nthcdr prefix-len pathname-directory)))
 336                     ((eq (car pathname-directory) :absolute)
 337                      ;; We are an absolute pathname, so we can just use it.
 338                      pathname-directory)
 339                     (t
 340                      (bug "Bad fallthrough in ~S" 'unparse-unix-enough)))))
 341         (strings (unparse-unix-directory-list result-directory)))
 342       (let* ((pathname-type (%pathname-type pathname))
 343              (type-needed (and pathname-type
 344                                (not (eq pathname-type :unspecific))))
 345              (pathname-name (%pathname-name pathname))
 346              (name-needed (or type-needed
 347                               (and pathname-name
 348                                    (not (compare-component pathname-name
 349                                                            (%pathname-name
 350                                                             defaults)))))))
 351         (when name-needed
 352           (unless pathname-name (lose))
 353           (when (and (null pathname-type)
 354                      (typep pathname-name 'simple-string)
 355                      (position #\. pathname-name :start 1))
 356             (error "too many dots in the name: ~S" pathname))
 357           (strings (unparse-unix-piece pathname-name)))
 358         (when type-needed
 359           (when (or (null pathname-type) (eq pathname-type :unspecific))
 360             (lose))
 361           (when (typep pathname-type 'simple-string)
 362             (when (position #\. pathname-type)
 363               (error "type component can't have a #\. inside: ~S" pathname)))
 364           (strings ".")
 365           (strings (unparse-unix-piece pathname-type))))
 366       (apply #'concatenate 'simple-string (strings)))))
 367
 368 ;; FIXME: This has been converted rather blindly from the Unix
 369 ;; version, with no reference to any Windows docs what so ever.
 370 (defun simplify-win32-namestring (src)
 371   (declare (type simple-string src))
 372   (let* ((src-len (length src))
 373          (dst (make-string src-len :element-type 'character))
 374          (dst-len 0)
 375          (dots 0)
 376          (last-slash nil))
 377     (flet ((deposit (char)
 378              (setf (schar dst dst-len) char)
 379              (incf dst-len))
 380            (slashp (char)
 381              (find char "\\/")))
 382       (dotimes (src-index src-len)
 383         (let ((char (schar src src-index)))
 384           (cond ((char= char #\.)
 385                  (when dots
 386                    (incf dots))
 387                  (deposit char))
 388                 ((slashp char)
 389                  (case dots
 390                    (0
 391                     ;; either ``/...' or ``...//...'
 392                     (unless last-slash
 393                       (setf last-slash dst-len)
 394                       (deposit char)))
 395                    (1
 396                     ;; either ``./...'' or ``..././...''
 397                     (decf dst-len))
 398                    (2
 399                     ;; We've found ..
 400                     (cond
 401                       ((and last-slash (not (zerop last-slash)))
 402                        ;; There is something before this ..
 403                        (let ((prev-prev-slash
 404                               (position-if #'slashp dst :end last-slash :from-end t)))
 405                          (cond ((and (= (+ (or prev-prev-slash 0) 2)
 406                                         last-slash)
 407                                      (char= (schar dst (- last-slash 2)) #\.)
 408                                      (char= (schar dst (1- last-slash)) #\.))
 409                                 ;; The something before this .. is another ..
 410                                 (deposit char)
 411                                 (setf last-slash dst-len))
 412                                (t
 413                                 ;; The something is some directory or other.
 414                                 (setf dst-len
 415                                       (if prev-prev-slash
 416                                           (1+ prev-prev-slash)
 417                                           0))
 418                                 (setf last-slash prev-prev-slash)))))
 419                       (t
 420                        ;; There is nothing before this .., so we need to keep it
 421                        (setf last-slash dst-len)
 422                        (deposit char))))
 423                    (t
 424                     ;; something other than a dot between slashes
 425                     (setf last-slash dst-len)
 426                     (deposit char)))
 427                  (setf dots 0))
 428                 (t
 429                  (setf dots nil)
 430                  (setf (schar dst dst-len) char)
 431                  (incf dst-len)))))
 432       ;; ...finish off
 433       (when (and last-slash (not (zerop last-slash)))
 434         (case dots
 435           (1
 436            ;; We've got  ``foobar/.''
 437            (decf dst-len))
 438           (2
 439            ;; We've got ``foobar/..''
 440            (unless (and (>= last-slash 2)
 441                         (char= (schar dst (1- last-slash)) #\.)
 442                         (char= (schar dst (- last-slash 2)) #\.)
 443                         (or (= last-slash 2)
 444                             (slashp (schar dst (- last-slash 3)))))
 445              (let ((prev-prev-slash
 446                     (position-if #'slashp dst :end last-slash :from-end t)))
 447                (if prev-prev-slash
 448                    (setf dst-len (1+ prev-prev-slash))
 449                    (return-from simplify-win32-namestring
 450                      (coerce ".\\" 'simple-string)))))))))
 451     (cond ((zerop dst-len)
 452            ".\\")
 453           ((= dst-len src-len)
 454            dst)
 455           (t
 456            (subseq dst 0 dst-len)))))