src/code/x86-vm.lisp

   1 ;;;; X86-specific runtime stuff
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; OS-CONTEXT-T
  15
  16 ;;; a POSIX signal context, i.e. the type passed as the third
  17 ;;; argument to an SA_SIGACTION-style signal handler
  18 ;;;
  19 ;;; The real type does have slots, but at Lisp level, we never
  20 ;;; access them, or care about the size of the object. Instead, we
  21 ;;; always refer to these objects by pointers handed to us by the C
  22 ;;; runtime library, and ask the runtime library any time we need
  23 ;;; information about the contents of one of these objects. Thus, it
  24 ;;; works to represent this as an object with no slots.
  25 ;;;
  26 ;;; KLUDGE: It would be nice to have a type definition analogous to
  27 ;;; C's "struct os_context_t;", for an incompletely specified object
  28 ;;; which can only be referred to by reference, but I don't know how
  29 ;;; to do that in the FFI, so instead we just this bogus no-slots
  30 ;;; representation. -- WHN 20000730
  31 ;;;
  32 ;;; FIXME: Since SBCL, unlike CMU CL, uses this as an opaque type,
  33 ;;; it's no longer architecture-dependent, and probably belongs in
  34 ;;; some other package, perhaps SB-KERNEL.
  35 (define-alien-type os-context-t (struct os-context-t-struct))
  36 \f
  37 ;;;; MACHINE-TYPE and MACHINE-VERSION
  38
  39 (defun machine-type ()
  40   #!+sb-doc
  41   "Return a string describing the type of the local machine."
  42   "X86")
  43
  44 (defun machine-version ()
  45   #!+sb-doc
  46   "Return a string describing the version of the local machine."
  47   "X86")
  48 \f
  49 ;;;; :CODE-OBJECT fixups
  50
  51 ;;; a counter to measure the storage overhead of these fixups
  52 (defvar *num-fixups* 0)
  53 ;;; FIXME: When the system runs, it'd be interesting to see what this is.
  54
  55 ;;; This gets called by LOAD to resolve newly positioned objects
  56 ;;; with things (like code instructions) that have to refer to them.
  57 ;;;
  58 ;;; Add a fixup offset to the vector of fixup offsets for the given
  59 ;;; code object.
  60 (defun fixup-code-object (code offset fixup kind)
  61   (declare (type index offset))
  62   (flet ((add-fixup (code offset)
  63            ;; (We check for and ignore fixups for code objects in the
  64            ;; read-only and static spaces. (In the old CMU CL code
  65            ;; this check was conditional on *ENABLE-DYNAMIC-SPACE-CODE*,
  66            ;; but in SBCL relocatable dynamic space code is always in
  67            ;; use, so we always do the check.)
  68            (incf *num-fixups*)
  69            (let ((fixups (code-header-ref code code-constants-offset)))
  70              (cond ((typep fixups '(simple-array (unsigned-byte 32) (*)))
  71                     (let ((new-fixups
  72                            (adjust-array fixups (1+ (length fixups))
  73                                          :element-type '(unsigned-byte 32))))
  74                       (setf (aref new-fixups (length fixups)) offset)
  75                       (setf (code-header-ref code code-constants-offset)
  76                             new-fixups)))
  77                    (t
  78                     (unless (or (eq (widetag-of fixups)
  79                                     unbound-marker-widetag)
  80                                 (zerop fixups))
  81                       (format t "** Init. code FU = ~S~%" fixups)) ; FIXME
  82                     (setf (code-header-ref code code-constants-offset)
  83                           (make-specializable-array
  84                            1
  85                            :element-type '(unsigned-byte 32)
  86                            :initial-element offset)))))))
  87     (sb!sys:without-gcing
  88      (let* ((sap (truly-the system-area-pointer
  89                             (sb!kernel:code-instructions code)))
  90             (obj-start-addr (logand (sb!kernel:get-lisp-obj-address code)
  91                                     #xfffffff8))
  92             #+nil (const-start-addr (+ obj-start-addr (* 5 4)))
  93             (code-start-addr (sb!sys:sap-int (sb!kernel:code-instructions
  94                                               code)))
  95             (ncode-words (sb!kernel:code-header-ref code 1))
  96             (code-end-addr (+ code-start-addr (* ncode-words 4))))
  97        (unless (member kind '(:absolute :relative))
  98          (error "Unknown code-object-fixup kind ~S." kind))
  99        (ecase kind
 100          (:absolute
 101           ;; Word at sap + offset contains a value to be replaced by
 102           ;; adding that value to fixup.
 103           (setf (sap-ref-32 sap offset) (+ fixup (sap-ref-32 sap offset)))
 104           ;; Record absolute fixups that point within the code object.
 105           (when (> code-end-addr (sap-ref-32 sap offset) obj-start-addr)
 106             (add-fixup code offset)))
 107          (:relative
 108           ;; Fixup is the actual address wanted.
 109           ;;
 110           ;; Record relative fixups that point outside the code
 111           ;; object.
 112           (when (or (< fixup obj-start-addr) (> fixup code-end-addr))
 113             (add-fixup code offset))
 114           ;; Replace word with value to add to that loc to get there.
 115           (let* ((loc-sap (+ (sap-int sap) offset))
 116                  (rel-val (- fixup loc-sap 4)))
 117             (declare (type (unsigned-byte 32) loc-sap)
 118                      (type (signed-byte 32) rel-val))
 119             (setf (signed-sap-ref-32 sap offset) rel-val))))))
 120     nil))
 121
 122 ;;; Add a code fixup to a code object generated by GENESIS. The fixup
 123 ;;; has already been applied, it's just a matter of placing the fixup
 124 ;;; in the code's fixup vector if necessary.
 125 ;;;
 126 ;;; KLUDGE: I'd like a good explanation of why this has to be done at
 127 ;;; load time instead of in GENESIS. It's probably simple, I just haven't
 128 ;;; figured it out, or found it written down anywhere. -- WHN 19990908
 129 #!+gencgc
 130 (defun !envector-load-time-code-fixup (code offset fixup kind)
 131   (flet ((frob (code offset)
 132            (let ((fixups (code-header-ref code code-constants-offset)))
 133              (cond ((typep fixups '(simple-array (unsigned-byte 32) (*)))
 134                     (let ((new-fixups
 135                            (adjust-array fixups (1+ (length fixups))
 136                                          :element-type '(unsigned-byte 32))))
 137                       (setf (aref new-fixups (length fixups)) offset)
 138                       (setf (code-header-ref code code-constants-offset)
 139                             new-fixups)))
 140                    (t
 141                     (unless (or (eq (widetag-of fixups)
 142                                     unbound-marker-widetag)
 143                                 (zerop fixups))
 144                       (sb!impl::!cold-lose "Argh! can't process fixup"))
 145                     (setf (code-header-ref code code-constants-offset)
 146                           (make-specializable-array
 147                            1
 148                            :element-type '(unsigned-byte 32)
 149                            :initial-element offset)))))))
 150     (let* ((sap (truly-the system-area-pointer
 151                            (sb!kernel:code-instructions code)))
 152            (obj-start-addr
 153             ;; FIXME: looks like (LOGANDC2 foo typebits)
 154             (logand (sb!kernel:get-lisp-obj-address code) #xfffffff8))
 155            (code-start-addr (sb!sys:sap-int (sb!kernel:code-instructions
 156                                              code)))
 157            (ncode-words (sb!kernel:code-header-ref code 1))
 158          (code-end-addr (+ code-start-addr (* ncode-words 4))))
 159       (ecase kind
 160         (:absolute
 161          ;; Record absolute fixups that point within the code object.
 162          (when (> code-end-addr (sap-ref-32 sap offset) obj-start-addr)
 163            (frob code offset)))
 164         (:relative
 165          ;; Record relative fixups that point outside the code object.
 166          (when (or (< fixup obj-start-addr) (> fixup code-end-addr))
 167            (frob code offset)))))))
 168 \f
 169 ;;;; low-level signal context access functions
 170 ;;;;
 171 ;;;; Note: In CMU CL, similar functions were hardwired to access
 172 ;;;; BSD-style sigcontext structures defined as alien objects. Our
 173 ;;;; approach is different in two ways:
 174 ;;;;   1. We use POSIX SA_SIGACTION-style signals, so our context is
 175 ;;;;      whatever the void pointer in the sigaction handler dereferences
 176 ;;;;      to, not necessarily a sigcontext.
 177 ;;;;   2. We don't try to maintain alien definitions of the context
 178 ;;;;      structure at Lisp level, but instead call alien C functions
 179 ;;;;      which take care of access for us. (Since the C functions can
 180 ;;;;      be defined in terms of system standard header files, they
 181 ;;;;      should be easier to maintain; and since Lisp code uses signal
 182 ;;;;      contexts only in interactive or exception code (like the debugger
 183 ;;;;      and internal error handling) the extra runtime cost should be
 184 ;;;;      negligible.
 185
 186 (define-alien-routine ("os_context_pc_addr" context-pc-addr) (* unsigned-int)
 187   ;; (Note: Just as in CONTEXT-REGISTER-ADDR, we intentionally use an
 188   ;; 'unsigned *' interpretation for the 32-bit word passed to us by
 189   ;; the C code, even though the C code may think it's an 'int *'.)
 190   (context (* os-context-t)))
 191
 192 (defun context-pc (context)
 193   (declare (type (alien (* os-context-t)) context))
 194   (let ((addr (context-pc-addr context)))
 195     (declare (type (alien (* unsigned-int)) addr))
 196     (int-sap (deref addr))))
 197
 198 (define-alien-routine ("os_context_register_addr" context-register-addr)
 199   (* unsigned-int)
 200   ;; (Note the mismatch here between the 'int *' value that the C code
 201   ;; may think it's giving us and the 'unsigned *' value that we
 202   ;; receive. It's intentional: the C header files may think of
 203   ;; register values as signed, but the CMU CL code tends to think of
 204   ;; register values as unsigned, and might get bewildered if we ask
 205   ;; it to work with signed values.)
 206   (context (* os-context-t))
 207   (index int))
 208
 209 (defun context-register (context index)
 210   (declare (type (alien (* os-context-t)) context))
 211   (let ((addr (context-register-addr context index)))
 212     (declare (type (alien (* unsigned-int)) addr))
 213     (deref addr)))
 214
 215 (defun %set-context-register (context index new)
 216   (declare (type (alien (* os-context-t)) context))
 217   (let ((addr (context-register-addr context index)))
 218     (declare (type (alien (* unsigned-int)) addr))
 219     (setf (deref addr) new)))
 220
 221 ;;; This is like CONTEXT-REGISTER, but returns the value of a float
 222 ;;; register. FORMAT is the type of float to return.
 223 ;;;
 224 ;;; As of sbcl-0.6.7, there is no working code which calls this code,
 225 ;;; so it's stubbed out. Someday, in order to make the debugger work
 226 ;;; better, it may be necessary to unstubify it.
 227 (defun context-float-register (context index format)
 228   (declare (ignore context index))
 229   (warn "stub CONTEXT-FLOAT-REGISTER")
 230   (coerce 0.0 format))
 231 (defun %set-context-float-register (context index format new-value)
 232   (declare (ignore context index))
 233   (warn "stub %SET-CONTEXT-FLOAT-REGISTER")
 234   (coerce new-value format))
 235
 236 ;;; Given a signal context, return the floating point modes word in
 237 ;;; the same format as returned by FLOATING-POINT-MODES.
 238 #!-linux
 239 (defun context-floating-point-modes (context)
 240   ;; FIXME: As of sbcl-0.6.7 and the big rewrite of signal handling for
 241   ;; POSIXness and (at the Lisp level) opaque signal contexts,
 242   ;; this is stubified. It needs to be rewritten as an
 243   ;; alien function.
 244   (declare (ignore context)) ; stub!
 245   (warn "stub CONTEXT-FLOATING-POINT-MODES")
 246
 247   ;; old code for Linux:
 248   #+nil
 249   (let ((cw (slot (deref (slot context 'fpstate) 0) 'cw))
 250         (sw (slot (deref (slot context 'fpstate) 0) 'sw)))
 251     ;;(format t "cw = ~4X~%sw = ~4X~%" cw sw)
 252     ;; NOT TESTED -- Clear sticky bits to clear interrupt condition.
 253     (setf (slot (deref (slot context 'fpstate) 0) 'sw) (logandc2 sw #x3f))
 254     ;;(format t "new sw = ~X~%" (slot (deref (slot context 'fpstate) 0) 'sw))
 255     ;; Simulate floating-point-modes VOP.
 256     (logior (ash (logand sw #xffff) 16) (logxor (logand cw #xffff) #x3f)))
 257
 258   0)
 259
 260 #!+linux
 261 (define-alien-routine ("os_context_fp_control" context-floating-point-modes)
 262     (sb!alien:unsigned 32)
 263   (context (* os-context-t)))
 264 \f
 265 ;;;; INTERNAL-ERROR-ARGS
 266
 267 ;;; Given a (POSIX) signal context, extract the internal error
 268 ;;; arguments from the instruction stream.
 269 (defun internal-error-args (context)
 270   (declare (type (alien (* os-context-t)) context))
 271   (/show0 "entering INTERNAL-ERROR-ARGS, CONTEXT=..")
 272   (/hexstr context)
 273   (let ((pc (context-pc context)))
 274     (declare (type system-area-pointer pc))
 275     (/show0 "got PC")
 276     ;; using INT3 the pc is .. INT3 <here> code length bytes...
 277     (let* ((length (sap-ref-8 pc 1))
 278            (vector (make-array length :element-type '(unsigned-byte 8))))
 279       (declare (type (unsigned-byte 8) length)
 280                (type (simple-array (unsigned-byte 8) (*)) vector))
 281       (/show0 "LENGTH,VECTOR,ERROR-NUMBER=..")
 282       (/hexstr length)
 283       (/hexstr vector)
 284       (copy-from-system-area pc (* n-byte-bits 2)
 285                              vector (* n-word-bits vector-data-offset)
 286                              (* length n-byte-bits))
 287       (let* ((index 0)
 288              (error-number (sb!c::read-var-integer vector index)))
 289         (/hexstr error-number)
 290         (collect ((sc-offsets))
 291           (loop
 292            (/show0 "INDEX=..")
 293            (/hexstr index)
 294            (when (>= index length)
 295              (return))
 296            (let ((sc-offset (sb!c::read-var-integer vector index)))
 297              (/show0 "SC-OFFSET=..")
 298              (/hexstr sc-offset)
 299              (sc-offsets sc-offset)))
 300           (values error-number (sc-offsets)))))))
 301 \f
 302 ;;; This is used in error.lisp to insure that floating-point exceptions
 303 ;;; are properly trapped. The compiler translates this to a VOP.
 304 (defun float-wait ()
 305   (float-wait))
 306
 307 ;;; float constants
 308 ;;;
 309 ;;; These are used by the FP MOVE-FROM-{SINGLE|DOUBLE} VOPs rather
 310 ;;; than the i387 load constant instructions to avoid consing in some
 311 ;;; cases. Note these are initialized by GENESIS as they are needed
 312 ;;; early.
 313 (defvar *fp-constant-0f0*)
 314 (defvar *fp-constant-1f0*)
 315 (defvar *fp-constant-0d0*)
 316 (defvar *fp-constant-1d0*)
 317 ;;; the long-float constants
 318 (defvar *fp-constant-0l0*)
 319 (defvar *fp-constant-1l0*)
 320 (defvar *fp-constant-pi*)
 321 (defvar *fp-constant-l2t*)
 322 (defvar *fp-constant-l2e*)
 323 (defvar *fp-constant-lg2*)
 324 (defvar *fp-constant-ln2*)
 325
 326 ;;; the current alien stack pointer; saved/restored for non-local exits
 327 (defvar *alien-stack*)
 328
 329 ;;; Support for the MT19937 random number generator. The update
 330 ;;; function is implemented as an assembly routine. This definition is
 331 ;;; transformed to a call to the assembly routine allowing its use in
 332 ;;; interpreted code.
 333 (defun random-mt19937 (state)
 334   (declare (type (simple-array (unsigned-byte 32) (627)) state))
 335   (random-mt19937 state))