src/cold/shared.lisp

   1 ;;;; stuff which is not specific to any particular build phase, but
   2 ;;;; used by most of them
   3 ;;;;
   4 ;;;; Note: It's specifically not used when bootstrapping PCL, because
   5 ;;;; we do SAVE-LISP after that, and we don't want to save extraneous
   6 ;;;; bootstrapping machinery into the frozen image which will
   7 ;;;; subsequently be used as the mother of all Lisp sessions.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 ;;; SB-COLD holds stuff used to build the initial SBCL core file
  19 ;;; (including not only the final construction of the core file, but
  20 ;;; also the preliminary steps like e.g. building the cross-compiler
  21 ;;; and running the cross-compiler to produce target FASL files).
  22 (defpackage "SB-COLD" (:use "CL"))
  23
  24 (in-package "SB-COLD")
  25
  26 ;;; prefixes for filename stems when cross-compiling. These are quite arbitrary
  27 ;;; (although of course they shouldn't collide with anything we don't want to
  28 ;;; write over). In particular, they can be either relative path names (e.g.
  29 ;;; "host-objects/" or absolute pathnames (e.g. "/tmp/sbcl-xc-host-objects/").
  30 ;;;
  31 ;;; The cross-compilation process will force the creation of these directories
  32 ;;; by executing CL:ENSURE-DIRECTORIES-EXIST (on the xc host Common Lisp).
  33 (defvar *host-obj-prefix*)
  34 (defvar *target-obj-prefix*)
  35
  36 ;;; suffixes for filename stems when cross-compiling
  37 (defvar *host-obj-suffix*
  38   (or
  39    ;; On some xc hosts, it's impossible to LOAD a fasl file unless it
  40    ;; has the same extension that the host uses for COMPILE-FILE
  41    ;; output, so we have to be careful to use the xc host's preferred
  42    ;; extension.
  43    ;;
  44    ;; FIXME: This is a little ugly and annoying to maintain. And
  45    ;; there's very likely some way to rearrange the build process so
  46    ;; that we never explicitly refer to host object file suffixes,
  47    ;; only to the result of CL:COMPILE-FILE-PATHNAME.
  48    #+lispworks ".ufsl" ; as per Lieven Marchand sbcl-devel 2002-02-01
  49    #+openmcl ".pfsl"
  50    ;; On most xc hosts, any old extension works, so we use an
  51    ;; arbitrary one.
  52    ".lisp-obj"))
  53 (defvar *target-obj-suffix*
  54   ;; Target fasl files are LOADed (actually only quasi-LOADed, in
  55   ;; GENESIS) only by SBCL code, and it doesn't care about particular
  56   ;; extensions, so we can use something arbitrary.
  57   ".lisp-obj")
  58
  59 ;;; a function of one functional argument, which calls its functional argument
  60 ;;; in an environment suitable for compiling the target. (This environment
  61 ;;; includes e.g. a suitable *FEATURES* value.)
  62 (defvar *in-target-compilation-mode-fn*)
  63
  64 ;;; designator for a function with the same calling convention as
  65 ;;; CL:COMPILE-FILE, to be used to translate ordinary Lisp source files into
  66 ;;; target object files
  67 (defvar *target-compile-file*)
  68
  69 ;;; designator for a function with the same calling convention as
  70 ;;; SB-C:ASSEMBLE-FILE, to be used to translate assembly files into target
  71 ;;; object files
  72 (defvar *target-assemble-file*)
  73 \f
  74 ;;;; some tools
  75
  76 ;;; Take the file named X and make it into a file named Y. Sorta like
  77 ;;; UNIX, and unlike Common Lisp's bare RENAME-FILE, we don't allow
  78 ;;; information from the original filename to influence the final
  79 ;;; filename. (The reason that it's only sorta like UNIX is that in
  80 ;;; UNIX "mv foo bar/" will work, but the analogous
  81 ;;; (RENAME-FILE-A-LA-UNIX "foo" "bar/") should fail.)
  82 ;;;
  83 ;;; (This is a workaround for the weird behavior of Debian CMU CL
  84 ;;; 2.4.6, where (RENAME-FILE "dir/x" "dir/y") tries to create a file
  85 ;;; called "dir/dir/y". If that behavior goes away, then we should be
  86 ;;; able to get rid of this function and use plain RENAME-FILE in the
  87 ;;; COMPILE-STEM function above. -- WHN 19990321
  88 (defun rename-file-a-la-unix (x y)
  89
  90   (let ((path    ;; (Note that the TRUENAME expression here is lifted from an
  91                  ;; example in the ANSI spec for TRUENAME.)
  92          (with-open-file (stream y :direction :output)
  93            (close stream)
  94            ;; From the ANSI spec: "In this case, the file is closed
  95            ;; when the truename is tried, so the truename
  96            ;; information is reliable."
  97            (truename stream))))
  98     (delete-file path)
  99     (rename-file x path)))
 100 (compile 'rename-file-a-la-unix)
 101
 102 ;;; a wrapper for compilation/assembly, used mostly to centralize
 103 ;;; the procedure for finding full filenames from "stems"
 104 ;;;
 105 ;;; Compile the source file whose basic name is STEM, using some
 106 ;;; standard-for-the-SBCL-build-process procedures to generate the
 107 ;;; full pathnames of source file and object file. Return the pathname
 108 ;;; of the object file for STEM. Several &KEY arguments are accepted:
 109 ;;;   :SRC-PREFIX, :SRC-SUFFIX =
 110 ;;;      strings to be concatenated to STEM to produce source filename
 111 ;;;   :OBJ-PREFIX, :OBJ-SUFFIX =
 112 ;;;      strings to be concatenated to STEM to produce object filename
 113 ;;;   :TMP-OBJ-SUFFIX-SUFFIX =
 114 ;;;      string to be appended to the name of an object file to produce
 115 ;;;      the name of a temporary object file
 116 ;;;   :COMPILE-FILE, :IGNORE-FAILURE-P =
 117 ;;;     :COMPILE-FILE is a function to use for compiling the file
 118 ;;;     (with the same calling conventions as ANSI CL:COMPILE-FILE).
 119 ;;;     If the third return value (FAILURE-P) of this function is
 120 ;;;     true, a continuable error will be signalled, unless
 121 ;;;     :IGNORE-FAILURE-P is set, in which case only a warning will be
 122 ;;;     signalled.
 123 (defun compile-stem (stem
 124                      &key
 125                      (obj-prefix "")
 126                      (obj-suffix (error "missing OBJ-SUFFIX"))
 127                      (tmp-obj-suffix-suffix "-tmp")
 128                      (src-prefix "")
 129                      (src-suffix ".lisp")
 130                      (compile-file #'compile-file)
 131                      ignore-failure-p)
 132
 133   (let* (;; KLUDGE: Note that this CONCATENATE 'STRING stuff is not The Common
 134          ;; Lisp Way, although it works just fine for common UNIX environments.
 135          ;; Should it come to pass that the system is ported to environments
 136          ;; where version numbers and so forth become an issue, it might become
 137          ;; urgent to rewrite this using the fancy Common Lisp PATHNAME
 138          ;; machinery instead of just using strings. In the absence of such a
 139          ;; port, it might or might be a good idea to do the rewrite.
 140          ;; -- WHN 19990815
 141          (src (concatenate 'string src-prefix stem src-suffix))
 142          (obj (concatenate 'string obj-prefix stem obj-suffix))
 143          (tmp-obj (concatenate 'string obj tmp-obj-suffix-suffix)))
 144
 145     (ensure-directories-exist obj :verbose t)
 146
 147     ;; We're about to set about building a new object file. First, we
 148     ;; delete any preexisting object file in order to avoid confusing
 149     ;; ourselves later should we happen to bail out of compilation
 150     ;; with an error.
 151     (when (probe-file obj)
 152       (delete-file obj))
 153
 154     ;; Work around a bug in CLISP 1999-01-08 #'COMPILE-FILE: CLISP
 155     ;; mangles relative pathnames passed as :OUTPUT-FILE arguments,
 156     ;; but works OK with absolute pathnames.
 157     #+clisp
 158     (setf tmp-obj
 159           ;; (Note that this idiom is taken from the ANSI
 160           ;; documentation for TRUENAME.)
 161           (with-open-file (stream tmp-obj :direction :output)
 162             (close stream)
 163             (truename stream)))
 164
 165     ;; Try to use the compiler to generate a new temporary object file.
 166     (flet ((report-recompile-restart (stream)
 167              (format stream "Recompile file ~S" src))
 168            (report-continue-restart (stream)
 169              (format stream "Continue, using possibly bogus file ~S" obj)))
 170       (tagbody
 171        retry-compile-file
 172          (multiple-value-bind (output-truename warnings-p failure-p)
 173              (funcall compile-file src :output-file tmp-obj)
 174            (declare (ignore warnings-p))
 175            (cond ((not output-truename)
 176                   (error "couldn't compile ~S" src))
 177                  (failure-p
 178                   (if ignore-failure-p
 179                       (warn "ignoring FAILURE-P return value from compilation of ~S"
 180                             src)
 181                       (unwind-protect
 182                            (restart-case
 183                                (error "FAILURE-P was set when creating ~S."
 184                                       obj)
 185                              (recompile ()
 186                                :report report-recompile-restart
 187                                (go retry-compile-file))
 188                              (continue ()
 189                                :report report-continue-restart
 190                                (setf failure-p nil)))
 191                         ;; Don't leave failed object files lying around.
 192                         (when (and failure-p (probe-file tmp-obj))
 193                           (delete-file tmp-obj)
 194                           (format t "~&deleted ~S~%" tmp-obj)))))
 195                  ;; Otherwise: success, just fall through.
 196                  (t nil)))))
 197
 198     ;; If we get to here, compilation succeeded, so it's OK to rename
 199     ;; the temporary output file to the permanent object file.
 200     (rename-file-a-la-unix tmp-obj obj)
 201
 202     ;; nice friendly traditional return value
 203     (pathname obj)))
 204 (compile 'compile-stem)
 205
 206 ;;; other miscellaneous tools
 207 (load "src/cold/read-from-file.lisp")
 208 (load "src/cold/rename-package-carefully.lisp")
 209 (load "src/cold/with-stuff.lisp")
 210
 211 ;;; Try to minimize/conceal any non-standardness of the host Common Lisp.
 212 (load "src/cold/ansify.lisp")
 213 \f
 214 ;;;; special read-macros for building the cold system (and even for
 215 ;;;; building some of our tools for building the cold system)
 216
 217 (load "src/cold/shebang.lisp")
 218
 219 ;;; When cross-compiling, the *FEATURES* set for the target Lisp is
 220 ;;; not in general the same as the *FEATURES* set for the host Lisp.
 221 ;;; In order to refer to target features specifically, we refer to
 222 ;;; *SHEBANG-FEATURES* instead of *FEATURES*, and use the #!+ and #!-
 223 ;;; readmacros instead of the ordinary #+ and #- readmacros.
 224 (setf *shebang-features*
 225       (let* ((default-features
 226                (append (read-from-file "base-target-features.lisp-expr")
 227                        (read-from-file "local-target-features.lisp-expr")))
 228              (customizer-file-name "customize-target-features.lisp")
 229              (customizer (if (probe-file customizer-file-name)
 230                              (compile nil
 231                                       (read-from-file customizer-file-name))
 232                              #'identity)))
 233         (funcall customizer default-features)))
 234 (let ((*print-length* nil)
 235       (*print-level* nil))
 236   (format t
 237           "target features *SHEBANG-FEATURES*=~@<~S~:>~%"
 238           *shebang-features*))
 239
 240 (defvar *shebang-backend-subfeatures*
 241   (let* ((default-subfeatures nil)
 242          (customizer-file-name "customize-backend-subfeatures.lisp")
 243          (customizer (if (probe-file customizer-file-name)
 244                          (compile nil
 245                                   (read-from-file customizer-file-name))
 246                          #'identity)))
 247     (funcall customizer default-subfeatures)))
 248 (let ((*print-length* nil)
 249       (*print-level* nil))
 250   (format t
 251           "target backend-subfeatures *SHEBANG-BACKEND-FEATURES*=~@<~S~:>~%"
 252           *shebang-backend-subfeatures*))
 253 \f
 254 ;;;; cold-init-related PACKAGE and SYMBOL tools
 255
 256 ;;; Once we're done with possibly ANSIfying the COMMON-LISP package,
 257 ;;; it's probably a mistake if we change it (beyond changing the
 258 ;;; values of special variables such as *** and +, anyway). Set up
 259 ;;; machinery to warn us when/if we change it.
 260 ;;;
 261 ;;; All code depending on this is itself dependent on #!+SB-SHOW.
 262 #!+sb-show
 263 (progn
 264   (load "src/cold/snapshot.lisp")
 265   (defvar *cl-snapshot* (take-snapshot "COMMON-LISP")))
 266 \f
 267 ;;;; master list of source files and their properties
 268
 269 ;;; flags which can be used to describe properties of source files
 270 (defparameter
 271   *expected-stem-flags*
 272   '(;; meaning: This file is not to be compiled when building the
 273     ;; cross-compiler which runs on the host ANSI Lisp.
 274     :not-host
 275     ;; meaning: This file is not to be compiled as part of the target
 276     ;; SBCL.
 277     :not-target
 278     ;; meaning: This file is to be processed with the SBCL assembler,
 279     ;; not COMPILE-FILE. (Note that this doesn't make sense unless
 280     ;; :NOT-HOST is also set, since the SBCL assembler doesn't exist
 281     ;; while the cross-compiler is being built in the host ANSI Lisp.)
 282     :assem
 283     ;; meaning: The #'COMPILE-STEM argument called :IGNORE-FAILURE-P
 284     ;; should be true. (This is a KLUDGE: I'd like to get rid of it.
 285     ;; For now, it exists so that compilation can proceed through the
 286     ;; legacy warnings in src/compiler/x86/array.lisp, which I've
 287     ;; never figured out but which were apparently acceptable in CMU
 288     ;; CL. Eventually, it would be great to just get rid of all
 289     ;; warnings and remove support for this flag. -- WHN 19990323)
 290     :ignore-failure-p))
 291
 292 (defparameter *stems-and-flags* (read-from-file "build-order.lisp-expr"))
 293
 294 (defmacro do-stems-and-flags ((stem flags) &body body)
 295   (let ((stem-and-flags (gensym "STEM-AND-FLAGS-")))
 296     `(dolist (,stem-and-flags *stems-and-flags*)
 297        (let ((,stem (first ,stem-and-flags))
 298              (,flags (rest ,stem-and-flags)))
 299          ,@body))))
 300
 301 ;;; Check for stupid typos in FLAGS list keywords.
 302 (let ((stems (make-hash-table :test 'equal)))
 303   (do-stems-and-flags (stem flags)
 304     (if (gethash stem stems)
 305       (error "duplicate stem ~S in *STEMS-AND-FLAGS*" stem)
 306       (setf (gethash stem stems) t))
 307     (let ((set-difference (set-difference flags *expected-stem-flags*)))
 308       (when set-difference
 309         (error "found unexpected flag(s) in *STEMS-AND-FLAGS*: ~S"
 310                set-difference)))))
 311 \f
 312 ;;;; tools to compile SBCL sources to create the cross-compiler
 313
 314 ;;; Execute function FN in an environment appropriate for compiling the
 315 ;;; cross-compiler's source code in the cross-compilation host.
 316 (defun in-host-compilation-mode (fn)
 317   (let ((*features* (cons :sb-xc-host *features*))
 318         ;; the CROSS-FLOAT-INFINITY-KLUDGE, as documented in
 319         ;; base-target-features.lisp-expr:
 320         (*shebang-features* (set-difference *shebang-features*
 321                                             '(:sb-propagate-float-type
 322                                               :sb-propagate-fun-type))))
 323     (with-additional-nickname ("SB-XC" "SB!XC")
 324       (funcall fn))))
 325 (compile 'in-host-compilation-mode)
 326
 327 ;;; Process a file as source code for the cross-compiler, compiling it
 328 ;;; (if necessary) in the appropriate environment, then loading it
 329 ;;; into the cross-compilation host Common lisp.
 330 (defun host-cload-stem (stem &key ignore-failure-p)
 331   (let ((compiled-filename (in-host-compilation-mode
 332                             (lambda ()
 333                               (compile-stem
 334                                stem
 335                                :obj-prefix *host-obj-prefix*
 336                                :obj-suffix *host-obj-suffix*
 337                                :compile-file #'cl:compile-file
 338                                :ignore-failure-p ignore-failure-p)))))
 339     (load compiled-filename)))
 340 (compile 'host-cload-stem)
 341
 342 ;;; like HOST-CLOAD-STEM, except that we don't bother to compile
 343 (defun host-load-stem (stem &key ignore-failure-p)
 344   (declare (ignore ignore-failure-p)) ; (It's only relevant when
 345   ;; compiling.) KLUDGE: It's untidy to have the knowledge of how to
 346   ;; construct complete filenames from stems in here as well as in
 347   ;; COMPILE-STEM. It should probably be factored out somehow. -- WHN
 348   ;; 19990815
 349   (load (concatenate 'simple-string *host-obj-prefix* stem *host-obj-suffix*)))
 350 (compile 'host-load-stem)
 351 \f
 352 ;;;; tools to compile SBCL sources to create object files which will
 353 ;;;; be used to create the target SBCL .core file
 354
 355 ;;; Run the cross-compiler on a file in the source directory tree to
 356 ;;; produce a corresponding file in the target object directory tree.
 357 (defun target-compile-stem (stem &key assem-p ignore-failure-p)
 358   (funcall *in-target-compilation-mode-fn*
 359            (lambda ()
 360              (compile-stem stem
 361                            :obj-prefix *target-obj-prefix*
 362                            :obj-suffix *target-obj-suffix*
 363                            :ignore-failure-p ignore-failure-p
 364                            :compile-file (if assem-p
 365                                              *target-assemble-file*
 366                                              *target-compile-file*)))))
 367 (compile 'target-compile-stem)
 368
 369 ;;; (This function is not used by the build process, but is intended
 370 ;;; for interactive use when experimenting with the system. It runs
 371 ;;; the cross-compiler on test files with arbitrary filenames, not
 372 ;;; necessarily in the source tree, e.g. in "/tmp".)
 373 (defun target-compile-file (filename)
 374   (funcall *in-target-compilation-mode-fn*
 375            (lambda ()
 376              (funcall *target-compile-file* filename))))
 377 (compile 'target-compile-file)