src/cold/warm.lisp

   1 ;;;; "warm initialization": initialization which comes after cold init
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "COMMON-LISP-USER")
  13 \f
  14 ;;;; general warm init compilation policy
  15
  16 (proclaim '(optimize (compilation-speed 1)
  17                      (debug #+sb-show 2 #-sb-show 1)
  18                      (inhibit-warnings 2)
  19                      (safety 2)
  20                      (space 1)
  21                      (speed 2)))
  22
  23 \f
  24 ;;;; package hacking
  25
  26 ;;; Our cross-compilation host is out of the picture now, so we no
  27 ;;; longer need to worry about collisions between our package names
  28 ;;; and cross-compilation host package names, so now is a good time to
  29 ;;; rename any package with a bootstrap-only name SB!FOO to its
  30 ;;; permanent name SB-FOO.
  31 ;;;
  32 ;;; (In principle it might be tidier to do this when dumping the cold
  33 ;;; image in genesis, but in practice the logic might be a little
  34 ;;; messier because genesis dumps both symbols and packages, and we'd
  35 ;;; need to make sure that dumped symbols were renamed in the same way
  36 ;;; as dumped packages. Or we could do it in cold init, but it's
  37 ;;; easier to experiment with and debug things here in warm init than
  38 ;;; in cold init, so we do it here instead.)
  39 (let ((boot-prefix "SB!")
  40       (perm-prefix "SB-"))
  41   (dolist (package (list-all-packages))
  42     (let ((old-package-name (package-name package)))
  43       (when (and (>= (length old-package-name) (length boot-prefix))
  44                  (string= boot-prefix old-package-name
  45                           :end2 (length boot-prefix)))
  46         (let ((new-package-name (concatenate 'string
  47                                              perm-prefix
  48                                              (subseq old-package-name
  49                                                      (length boot-prefix)))))
  50           (rename-package package
  51                           new-package-name
  52                           (package-nicknames package)))))))
  53
  54 ;;; FIXME: This nickname is a deprecated hack for backwards
  55 ;;; compatibility with code which assumed the CMU-CL-style
  56 ;;; SB-ALIEN/SB-C-CALL split. That split went away and was deprecated
  57 ;;; in 0.7.0, so we should get rid of this nickname after a while.
  58 (let ((package (find-package "SB-ALIEN")))
  59   (rename-package package
  60                   (package-name package)
  61                   (cons "SB-C-CALL" (package-nicknames package))))
  62
  63 (let ((package (find-package "SB-SEQUENCE")))
  64   (rename-package package (package-name package) (list "SEQUENCE")))
  65 \f
  66 ;;;; compiling and loading more of the system
  67
  68 (let* ((sys *default-pathname-defaults*)
  69        (src
  70         (merge-pathnames
  71          (make-pathname :directory '(:relative "src" :wild-inferiors)
  72                         :name :wild :type :wild)
  73          sys))
  74        (contrib
  75         (merge-pathnames
  76          (make-pathname :directory '(:relative "contrib" :wild-inferiors)
  77                         :name :wild :type :wild)
  78          sys)))
  79   (setf (logical-pathname-translations "SYS")
  80         `(("SYS:SRC;**;*.*.*" ,src)
  81           ("SYS:CONTRIB;**;*.*.*" ,contrib))))
  82
  83 ;;; FIXME: CMU CL's pclcom.lisp had extra optional stuff wrapped around
  84 ;;; COMPILE-PCL, at least some of which we should probably have too:
  85 ;;;
  86 ;;; (with-compilation-unit
  87 ;;;     (:optimize '(optimize (debug #+(and (not high-security) small) .5
  88 ;;;                               #-(or high-security small) 2
  89 ;;;                               #+high-security 3)
  90 ;;;                        (speed 2) (safety #+(and (not high-security) small) 0
  91 ;;;                                          #-(or high-security small) 2
  92 ;;;                                          #+high-security 3)
  93 ;;;                        (inhibit-warnings 2))
  94 ;;;      :optimize-interface '(optimize-interface #+(and (not high-security) small)
  95 ;;; (safety 1)
  96 ;;;                                            #+high-security (safety 3))
  97 ;;;      :context-declarations
  98 ;;;      '((:external (declare (optimize-interface (safety #-high-security 2 #+high-
  99 ;;; security 3)
 100 ;;;                                             (debug #-high-security 1 #+high-s
 101 ;;; ecurity 3))))
 102 ;;;     ((:or :macro (:match "$EARLY-") (:match "$BOOT-"))
 103 ;;;     (declare (optimize (speed 0))))))
 104 ;;;
 105 ;;; FIXME: This has mutated into a hack which crudely duplicates
 106 ;;; functionality from the existing mechanism to load files from
 107 ;;; build-order.lisp-expr, without being quite parallel. (E.g. object
 108 ;;; files end up alongside the source files instead of ending up in
 109 ;;; parallel directory trees.) Maybe we could merge the filenames here
 110 ;;; into build-order.lisp-expr with some new flag (perhaps :WARM) to
 111 ;;; indicate that the files should be handled not in cold load but
 112 ;;; afterwards.
 113 (dolist (stem '(;; CLOS, derived from the PCL reference implementation
 114                 ;;
 115                 ;; This PCL build order is based on a particular
 116                 ;; (arbitrary) linearization of the declared build
 117                 ;; order dependencies from the old PCL defsys.lisp
 118                 ;; dependency database.
 119                 #+nil "src/pcl/walk" ; #+NIL = moved to build-order.lisp-expr
 120                 "SRC;PCL;EARLY-LOW"
 121                 "SRC;PCL;MACROS"
 122                 "SRC;PCL;COMPILER-SUPPORT"
 123                 "SRC;PCL;LOW"
 124                 "SRC;PCL;SLOT-NAME"
 125                 "SRC;PCL;DEFCLASS"
 126                 "SRC;PCL;DEFS"
 127                 "SRC;PCL;FNGEN"
 128                 "SRC;PCL;WRAPPER"
 129                 "SRC;PCL;CACHE"
 130                 "SRC;PCL;DLISP"
 131                 "SRC;PCL;DLISP2"
 132                 "SRC;PCL;BOOT"
 133                 "SRC;PCL;VECTOR"
 134                 "SRC;PCL;SLOTS-BOOT"
 135                 "SRC;PCL;COMBIN"
 136                 "SRC;PCL;DFUN"
 137                 "SRC;PCL;CTOR"
 138                 "SRC;PCL;BRAID"
 139                 "SRC;PCL;DLISP3"
 140                 "SRC;PCL;GENERIC-FUNCTIONS"
 141                 "SRC;PCL;SLOTS"
 142                 "SRC;PCL;INIT"
 143                 "SRC;PCL;STD-CLASS"
 144                 "SRC;PCL;CPL"
 145                 "SRC;PCL;FSC"
 146                 "SRC;PCL;METHODS"
 147                 "SRC;PCL;FIXUP"
 148                 "SRC;PCL;DEFCOMBIN"
 149                 "SRC;PCL;CTYPES"
 150                 "SRC;PCL;ENV"
 151                 "SRC;PCL;DOCUMENTATION"
 152                 "SRC;PCL;PRINT-OBJECT"
 153                 "SRC;PCL;PRECOM1"
 154                 "SRC;PCL;PRECOM2"
 155
 156                 ;; miscellaneous functionality which depends on CLOS
 157                 "SRC;CODE;FORCE-DELAYED-DEFBANGMETHODS"
 158                 "SRC;CODE;LATE-CONDITION"
 159
 160                 ;; CLOS-level support for the Gray OO streams
 161                 ;; extension (which is also supported by various
 162                 ;; lower-level hooks elsewhere in the code)
 163                 "SRC;PCL;GRAY-STREAMS-CLASS"
 164                 "SRC;PCL;GRAY-STREAMS"
 165
 166                 ;; CLOS-level support for User-extensible sequences.
 167                 "SRC;PCL;SEQUENCE"
 168
 169                 ;; other functionality not needed for cold init, moved
 170                 ;; to warm init to reduce peak memory requirement in
 171                 ;; cold init
 172                 "SRC;CODE;DESCRIBE"
 173                 "SRC;CODE;DESCRIBE-POLICY"
 174                 "SRC;CODE;INSPECT"
 175                 "SRC;CODE;PROFILE"
 176                 "SRC;CODE;NTRACE"
 177                 "SRC;CODE;STEP"
 178                 "SRC;CODE;RUN-PROGRAM"
 179
 180                 ;; Code derived from PCL's pre-ANSI DESCRIBE-OBJECT
 181                 ;; facility is still used in our ANSI DESCRIBE
 182                 ;; facility, and should be compiled and loaded after
 183                 ;; our DESCRIBE facility is compiled and loaded.
 184                 "SRC;PCL;DESCRIBE"))
 185
 186   (let ((fullname (concatenate 'string "SYS:" stem ".LISP")))
 187     (sb-int:/show "about to compile" fullname)
 188     (flet ((report-recompile-restart (stream)
 189              (format stream "Recompile file ~S" fullname))
 190            (report-continue-restart (stream)
 191              (format stream
 192                      "Continue, using possibly bogus file ~S"
 193                      (compile-file-pathname fullname))))
 194       (tagbody
 195        retry-compile-file
 196          (multiple-value-bind (output-truename warnings-p failure-p)
 197              (if *compile-files-p*
 198                  (compile-file fullname)
 199                  (compile-file-pathname fullname))
 200            (declare (ignore warnings-p))
 201            (sb-int:/show "done compiling" fullname)
 202            (cond ((not output-truename)
 203                   (error "COMPILE-FILE of ~S failed." fullname))
 204                  (failure-p
 205                   (unwind-protect
 206                        (restart-case
 207                            (error "FAILURE-P was set when creating ~S."
 208                                   output-truename)
 209                          (recompile ()
 210                            :report report-recompile-restart
 211                            (go retry-compile-file))
 212                          (continue ()
 213                            :report report-continue-restart
 214                            (setf failure-p nil)))
 215                     ;; Don't leave failed object files lying around.
 216                     (when (and failure-p (probe-file output-truename))
 217                           (delete-file output-truename)
 218                           (format t "~&deleted ~S~%" output-truename))))
 219                  ;; Otherwise: success, just fall through.
 220                  (t nil))
 221            (unless (load output-truename)
 222              (error "LOAD of ~S failed." output-truename))
 223            (sb-int:/show "done loading" output-truename))))))
 224 \f
 225 ;;;; setting package documentation
 226
 227 ;;; While we were running on the cross-compilation host, we tried to
 228 ;;; be portable and not overwrite the doc strings for the standard
 229 ;;; packages. But now the cross-compilation host is only a receding
 230 ;;; memory, and we can have our way with the doc strings.
 231 (sb-int:/show "setting package documentation")
 232 #+sb-doc (setf (documentation (find-package "COMMON-LISP") t)
 233 "public: home of symbols defined by the ANSI language specification")
 234 #+sb-doc (setf (documentation (find-package "COMMON-LISP-USER") t)
 235                "public: the default package for user code and data")
 236 #+sb-doc (setf (documentation (find-package "KEYWORD") t)
 237                "public: home of keywords")
 238 \f
 239