src/compiler/array-tran.lisp

   1 ;;;; array-specific optimizers and transforms
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; utilities for optimizing array operations
  15
  16 ;;; Return UPGRADED-ARRAY-ELEMENT-TYPE for LVAR, or do
  17 ;;; GIVE-UP-IR1-TRANSFORM if the upgraded element type can't be
  18 ;;; determined.
  19 (defun upgraded-element-type-specifier-or-give-up (lvar)
  20   (let* ((element-ctype (extract-upgraded-element-type lvar))
  21          (element-type-specifier (type-specifier element-ctype)))
  22     (if (eq element-type-specifier '*)
  23         (give-up-ir1-transform
  24          "upgraded array element type not known at compile time")
  25         element-type-specifier)))
  26
  27 ;;; Array access functions return an object from the array, hence its
  28 ;;; type is going to be the array upgraded element type.
  29 (defun extract-upgraded-element-type (array)
  30   (let ((type (lvar-type array)))
  31     ;; Note that this IF mightn't be satisfied even if the runtime
  32     ;; value is known to be a subtype of some specialized ARRAY, because
  33     ;; we can have values declared e.g. (AND SIMPLE-VECTOR UNKNOWN-TYPE),
  34     ;; which are represented in the compiler as INTERSECTION-TYPE, not
  35     ;; array type.
  36     (if (array-type-p type)
  37         (array-type-specialized-element-type type)
  38         ;; KLUDGE: there is no good answer here, but at least
  39         ;; *wild-type* won't cause HAIRY-DATA-VECTOR-{REF,SET} to be
  40         ;; erroneously optimized (see generic/vm-tran.lisp) -- CSR,
  41         ;; 2002-08-21
  42         *wild-type*)))
  43
  44 (defun extract-declared-element-type (array)
  45   (let ((type (lvar-type array)))
  46     (if (array-type-p type)
  47         (array-type-element-type type)
  48         *wild-type*)))
  49
  50 ;;; The ``new-value'' for array setters must fit in the array, and the
  51 ;;; return type is going to be the same as the new-value for SETF
  52 ;;; functions.
  53 (defun assert-new-value-type (new-value array)
  54   (let ((type (lvar-type array)))
  55     (when (array-type-p type)
  56       (assert-lvar-type
  57        new-value
  58        (array-type-specialized-element-type type)
  59        (lexenv-policy (node-lexenv (lvar-dest new-value))))))
  60   (lvar-type new-value))
  61
  62 (defun assert-array-complex (array)
  63   (assert-lvar-type
  64    array
  65    (make-array-type :complexp t
  66                     :element-type *wild-type*)
  67    (lexenv-policy (node-lexenv (lvar-dest array))))
  68   nil)
  69
  70 ;;; Return true if ARG is NIL, or is a constant-lvar whose
  71 ;;; value is NIL, false otherwise.
  72 (defun unsupplied-or-nil (arg)
  73   (declare (type (or lvar null) arg))
  74   (or (not arg)
  75       (and (constant-lvar-p arg)
  76            (not (lvar-value arg)))))
  77 \f
  78 ;;;; DERIVE-TYPE optimizers
  79
  80 ;;; Array operations that use a specific number of indices implicitly
  81 ;;; assert that the array is of that rank.
  82 (defun assert-array-rank (array rank)
  83   (assert-lvar-type
  84    array
  85    (specifier-type `(array * ,(make-list rank :initial-element '*)))
  86    (lexenv-policy (node-lexenv (lvar-dest array)))))
  87
  88 (defoptimizer (array-in-bounds-p derive-type) ((array &rest indices))
  89   (assert-array-rank array (length indices))
  90   *universal-type*)
  91
  92 (defoptimizer (aref derive-type) ((array &rest indices) node)
  93   (assert-array-rank array (length indices))
  94   (extract-upgraded-element-type array))
  95
  96 (defoptimizer (%aset derive-type) ((array &rest stuff))
  97   (assert-array-rank array (1- (length stuff)))
  98   (assert-new-value-type (car (last stuff)) array))
  99
 100 (defoptimizer (hairy-data-vector-ref derive-type) ((array index))
 101   (extract-upgraded-element-type array))
 102 (defoptimizer (data-vector-ref derive-type) ((array index))
 103   (extract-upgraded-element-type array))
 104
 105 (defoptimizer (data-vector-set derive-type) ((array index new-value))
 106   (assert-new-value-type new-value array))
 107 (defoptimizer (hairy-data-vector-set derive-type) ((array index new-value))
 108   (assert-new-value-type new-value array))
 109
 110 ;;; Figure out the type of the data vector if we know the argument
 111 ;;; element type.
 112 (defoptimizer (%with-array-data derive-type) ((array start end))
 113   (let ((atype (lvar-type array)))
 114     (when (array-type-p atype)
 115       (specifier-type
 116        `(simple-array ,(type-specifier
 117                        (array-type-specialized-element-type atype))
 118                      (*))))))
 119
 120 (defoptimizer (array-row-major-index derive-type) ((array &rest indices))
 121   (assert-array-rank array (length indices))
 122   *universal-type*)
 123
 124 (defoptimizer (row-major-aref derive-type) ((array index))
 125   (extract-upgraded-element-type array))
 126
 127 (defoptimizer (%set-row-major-aref derive-type) ((array index new-value))
 128   (assert-new-value-type new-value array))
 129
 130 (defoptimizer (make-array derive-type)
 131               ((dims &key initial-element element-type initial-contents
 132                 adjustable fill-pointer displaced-index-offset displaced-to))
 133   (let ((simple (and (unsupplied-or-nil adjustable)
 134                      (unsupplied-or-nil displaced-to)
 135                      (unsupplied-or-nil fill-pointer))))
 136     (or (careful-specifier-type
 137          `(,(if simple 'simple-array 'array)
 138             ,(cond ((not element-type) t)
 139                    ((constant-lvar-p element-type)
 140                     (let ((ctype (careful-specifier-type
 141                                   (lvar-value element-type))))
 142                       (cond
 143                         ((or (null ctype) (unknown-type-p ctype)) '*)
 144                         (t (sb!xc:upgraded-array-element-type
 145                             (lvar-value element-type))))))
 146                    (t
 147                     '*))
 148             ,(cond ((constant-lvar-p dims)
 149                     (let* ((val (lvar-value dims))
 150                            (cdims (if (listp val) val (list val))))
 151                       (if simple
 152                           cdims
 153                           (length cdims))))
 154                    ((csubtypep (lvar-type dims)
 155                                (specifier-type 'integer))
 156                     '(*))
 157                    (t
 158                     '*))))
 159         (specifier-type 'array))))
 160
 161 ;;; Complex array operations should assert that their array argument
 162 ;;; is complex.  In SBCL, vectors with fill-pointers are complex.
 163 (defoptimizer (fill-pointer derive-type) ((vector))
 164   (assert-array-complex vector))
 165 (defoptimizer (%set-fill-pointer derive-type) ((vector index))
 166   (declare (ignorable index))
 167   (assert-array-complex vector))
 168
 169 (defoptimizer (vector-push derive-type) ((object vector))
 170   (declare (ignorable object))
 171   (assert-array-complex vector))
 172 (defoptimizer (vector-push-extend derive-type)
 173     ((object vector &optional index))
 174   (declare (ignorable object index))
 175   (assert-array-complex vector))
 176 (defoptimizer (vector-pop derive-type) ((vector))
 177   (assert-array-complex vector))
 178 \f
 179 ;;;; constructors
 180
 181 ;;; Convert VECTOR into a MAKE-ARRAY followed by SETFs of all the
 182 ;;; elements.
 183 (define-source-transform vector (&rest elements)
 184   (let ((len (length elements))
 185         (n -1))
 186     (once-only ((n-vec `(make-array ,len)))
 187       `(progn
 188          ,@(mapcar (lambda (el)
 189                      (once-only ((n-val el))
 190                        `(locally (declare (optimize (safety 0)))
 191                                  (setf (svref ,n-vec ,(incf n))
 192                                        ,n-val))))
 193                    elements)
 194          ,n-vec))))
 195
 196 ;;; Just convert it into a MAKE-ARRAY.
 197 (deftransform make-string ((length &key
 198                                    (element-type 'character)
 199                                    (initial-element
 200                                     #.*default-init-char-form*)))
 201   `(the simple-string (make-array (the index length)
 202                        :element-type element-type
 203                        ,@(when initial-element
 204                            '(:initial-element initial-element)))))
 205
 206 (deftransform make-array ((dims &key initial-element element-type
 207                                      adjustable fill-pointer)
 208                           (t &rest *))
 209   (when (null initial-element)
 210     (give-up-ir1-transform))
 211   (let* ((eltype (cond ((not element-type) t)
 212                        ((not (constant-lvar-p element-type))
 213                         (give-up-ir1-transform
 214                          "ELEMENT-TYPE is not constant."))
 215                        (t
 216                         (lvar-value element-type))))
 217          (eltype-type (ir1-transform-specifier-type eltype))
 218          (saetp (find-if (lambda (saetp)
 219                            (csubtypep eltype-type (sb!vm:saetp-ctype saetp)))
 220                          sb!vm:*specialized-array-element-type-properties*))
 221          (creation-form `(make-array dims
 222                           :element-type ',(type-specifier (sb!vm:saetp-ctype saetp))
 223                           ,@(when fill-pointer
 224                                   '(:fill-pointer fill-pointer))
 225                           ,@(when adjustable
 226                                   '(:adjustable adjustable)))))
 227
 228     (unless saetp
 229       (give-up-ir1-transform "ELEMENT-TYPE not found in *SAETP*: ~S" eltype))
 230
 231     (cond ((and (constant-lvar-p initial-element)
 232                 (eql (lvar-value initial-element)
 233                      (sb!vm:saetp-initial-element-default saetp)))
 234            creation-form)
 235           (t
 236            ;; error checking for target, disabled on the host because
 237            ;; (CTYPE-OF #\Null) is not possible.
 238            #-sb-xc-host
 239            (when (constant-lvar-p initial-element)
 240              (let ((value (lvar-value initial-element)))
 241                (cond
 242                  ((not (ctypep value (sb!vm:saetp-ctype saetp)))
 243                   ;; this case will cause an error at runtime, so we'd
 244                   ;; better WARN about it now.
 245                   (compiler-warn "~@<~S is not a ~S (which is the ~
 246                                  UPGRADED-ARRAY-ELEMENT-TYPE of ~S).~@:>"
 247                                  value
 248                                  (type-specifier (sb!vm:saetp-ctype saetp))
 249                                  eltype))
 250                  ((not (ctypep value eltype-type))
 251                   ;; this case will not cause an error at runtime, but
 252                   ;; it's still worth STYLE-WARNing about.
 253                   (compiler-style-warn "~S is not a ~S."
 254                                        value eltype)))))
 255            `(let ((array ,creation-form))
 256              (multiple-value-bind (vector)
 257                  (%data-vector-and-index array 0)
 258                (fill vector initial-element))
 259              array)))))
 260
 261 ;;; The integer type restriction on the length ensures that it will be
 262 ;;; a vector. The lack of :ADJUSTABLE, :FILL-POINTER, and
 263 ;;; :DISPLACED-TO keywords ensures that it will be simple; the lack of
 264 ;;; :INITIAL-ELEMENT relies on another transform to deal with that
 265 ;;; kind of initialization efficiently.
 266 (deftransform make-array ((length &key element-type)
 267                           (integer &rest *))
 268   (let* ((eltype (cond ((not element-type) t)
 269                        ((not (constant-lvar-p element-type))
 270                         (give-up-ir1-transform
 271                          "ELEMENT-TYPE is not constant."))
 272                        (t
 273                         (lvar-value element-type))))
 274          (len (if (constant-lvar-p length)
 275                   (lvar-value length)
 276                   '*))
 277          (eltype-type (ir1-transform-specifier-type eltype))
 278          (result-type-spec
 279           `(simple-array
 280             ,(if (unknown-type-p eltype-type)
 281                  (give-up-ir1-transform
 282                   "ELEMENT-TYPE is an unknown type: ~S" eltype)
 283                  (sb!xc:upgraded-array-element-type eltype))
 284             (,len)))
 285          (saetp (find-if (lambda (saetp)
 286                            (csubtypep eltype-type (sb!vm:saetp-ctype saetp)))
 287                          sb!vm:*specialized-array-element-type-properties*)))
 288     (unless saetp
 289       (give-up-ir1-transform
 290        "cannot open-code creation of ~S" result-type-spec))
 291     #-sb-xc-host
 292     (unless (csubtypep (ctype-of (sb!vm:saetp-initial-element-default saetp))
 293                        eltype-type)
 294       ;; This situation arises e.g. in (MAKE-ARRAY 4 :ELEMENT-TYPE
 295       ;; '(INTEGER 1 5)) ANSI's definition of MAKE-ARRAY says "If
 296       ;; INITIAL-ELEMENT is not supplied, the consequences of later
 297       ;; reading an uninitialized element of new-array are undefined,"
 298       ;; so this could be legal code as long as the user plans to
 299       ;; write before he reads, and if he doesn't we're free to do
 300       ;; anything we like. But in case the user doesn't know to write
 301       ;; elements before he reads elements (or to read manuals before
 302       ;; he writes code:-), we'll signal a STYLE-WARNING in case he
 303       ;; didn't realize this.
 304       (compiler-style-warn "The default initial element ~S is not a ~S."
 305                            (sb!vm:saetp-initial-element-default saetp)
 306                            eltype))
 307     (let* ((n-bits-per-element (sb!vm:saetp-n-bits saetp))
 308            (typecode (sb!vm:saetp-typecode saetp))
 309            (n-pad-elements (sb!vm:saetp-n-pad-elements saetp))
 310            (padded-length-form (if (zerop n-pad-elements)
 311                                    'length
 312                                    `(+ length ,n-pad-elements)))
 313            (n-words-form
 314             (cond
 315               ((= n-bits-per-element 0) 0)
 316               ((>= n-bits-per-element sb!vm:n-word-bits)
 317                `(* ,padded-length-form
 318                  (the fixnum ; i.e., not RATIO
 319                    ,(/ n-bits-per-element sb!vm:n-word-bits))))
 320               (t
 321                (let ((n-elements-per-word (/ sb!vm:n-word-bits
 322                                              n-bits-per-element)))
 323                  (declare (type index n-elements-per-word)) ; i.e., not RATIO
 324                  `(ceiling ,padded-length-form ,n-elements-per-word))))))
 325       (values
 326        `(truly-the ,result-type-spec
 327          (allocate-vector ,typecode length ,n-words-form))
 328        '((declare (type index length)))))))
 329
 330 ;;; The list type restriction does not ensure that the result will be a
 331 ;;; multi-dimensional array. But the lack of adjustable, fill-pointer,
 332 ;;; and displaced-to keywords ensures that it will be simple.
 333 ;;;
 334 ;;; FIXME: should we generalize this transform to non-simple (though
 335 ;;; non-displaced-to) arrays, given that we have %WITH-ARRAY-DATA to
 336 ;;; deal with those? Maybe when the DEFTRANSFORM
 337 ;;; %DATA-VECTOR-AND-INDEX in the VECTOR case problem is solved? --
 338 ;;; CSR, 2002-07-01
 339 (deftransform make-array ((dims &key element-type)
 340                           (list &rest *))
 341   (unless (or (null element-type) (constant-lvar-p element-type))
 342     (give-up-ir1-transform
 343      "The element-type is not constant; cannot open code array creation."))
 344   (unless (constant-lvar-p dims)
 345     (give-up-ir1-transform
 346      "The dimension list is not constant; cannot open code array creation."))
 347   (let ((dims (lvar-value dims)))
 348     (unless (every #'integerp dims)
 349       (give-up-ir1-transform
 350        "The dimension list contains something other than an integer: ~S"
 351        dims))
 352     (if (= (length dims) 1)
 353         `(make-array ',(car dims)
 354                      ,@(when element-type
 355                          '(:element-type element-type)))
 356         (let* ((total-size (reduce #'* dims))
 357                (rank (length dims))
 358                (spec `(simple-array
 359                        ,(cond ((null element-type) t)
 360                               ((and (constant-lvar-p element-type)
 361                                     (ir1-transform-specifier-type
 362                                      (lvar-value element-type)))
 363                                (sb!xc:upgraded-array-element-type
 364                                 (lvar-value element-type)))
 365                               (t '*))
 366                            ,(make-list rank :initial-element '*))))
 367           `(let ((header (make-array-header sb!vm:simple-array-widetag ,rank)))
 368              (setf (%array-fill-pointer header) ,total-size)
 369              (setf (%array-fill-pointer-p header) nil)
 370              (setf (%array-available-elements header) ,total-size)
 371              (setf (%array-data-vector header)
 372                    (make-array ,total-size
 373                                ,@(when element-type
 374                                    '(:element-type element-type))))
 375              (setf (%array-displaced-p header) nil)
 376              ,@(let ((axis -1))
 377                  (mapcar (lambda (dim)
 378                            `(setf (%array-dimension header ,(incf axis))
 379                                   ,dim))
 380                          dims))
 381              (truly-the ,spec header))))))
 382 \f
 383 ;;;; miscellaneous properties of arrays
 384
 385 ;;; Transforms for various array properties. If the property is know
 386 ;;; at compile time because of a type spec, use that constant value.
 387
 388 ;;; If we can tell the rank from the type info, use it instead.
 389 (deftransform array-rank ((array))
 390   (let ((array-type (lvar-type array)))
 391     (unless (array-type-p array-type)
 392       (give-up-ir1-transform))
 393     (let ((dims (array-type-dimensions array-type)))
 394       (if (not (listp dims))
 395           (give-up-ir1-transform
 396            "The array rank is not known at compile time: ~S"
 397            dims)
 398           (length dims)))))
 399
 400 ;;; If we know the dimensions at compile time, just use it. Otherwise,
 401 ;;; if we can tell that the axis is in bounds, convert to
 402 ;;; %ARRAY-DIMENSION (which just indirects the array header) or length
 403 ;;; (if it's simple and a vector).
 404 (deftransform array-dimension ((array axis)
 405                                (array index))
 406   (unless (constant-lvar-p axis)
 407     (give-up-ir1-transform "The axis is not constant."))
 408   (let ((array-type (lvar-type array))
 409         (axis (lvar-value axis)))
 410     (unless (array-type-p array-type)
 411       (give-up-ir1-transform))
 412     (let ((dims (array-type-dimensions array-type)))
 413       (unless (listp dims)
 414         (give-up-ir1-transform
 415          "The array dimensions are unknown; must call ARRAY-DIMENSION at runtime."))
 416       (unless (> (length dims) axis)
 417         (abort-ir1-transform "The array has dimensions ~S, ~W is too large."
 418                              dims
 419                              axis))
 420       (let ((dim (nth axis dims)))
 421         (cond ((integerp dim)
 422                dim)
 423               ((= (length dims) 1)
 424                (ecase (array-type-complexp array-type)
 425                  ((t)
 426                   '(%array-dimension array 0))
 427                  ((nil)
 428                   '(length array))
 429                  ((:maybe)
 430                   (give-up-ir1-transform
 431                    "can't tell whether array is simple"))))
 432               (t
 433                '(%array-dimension array axis)))))))
 434
 435 ;;; If the length has been declared and it's simple, just return it.
 436 (deftransform length ((vector)
 437                       ((simple-array * (*))))
 438   (let ((type (lvar-type vector)))
 439     (unless (array-type-p type)
 440       (give-up-ir1-transform))
 441     (let ((dims (array-type-dimensions type)))
 442       (unless (and (listp dims) (integerp (car dims)))
 443         (give-up-ir1-transform
 444          "Vector length is unknown, must call LENGTH at runtime."))
 445       (car dims))))
 446
 447 ;;; All vectors can get their length by using VECTOR-LENGTH. If it's
 448 ;;; simple, it will extract the length slot from the vector. It it's
 449 ;;; complex, it will extract the fill pointer slot from the array
 450 ;;; header.
 451 (deftransform length ((vector) (vector))
 452   '(vector-length vector))
 453
 454 ;;; If a simple array with known dimensions, then VECTOR-LENGTH is a
 455 ;;; compile-time constant.
 456 (deftransform vector-length ((vector))
 457   (let ((vtype (lvar-type vector)))
 458     (if (and (array-type-p vtype)
 459              (not (array-type-complexp vtype)))
 460         (let ((dim (first (array-type-dimensions vtype))))
 461           (when (eq dim '*) (give-up-ir1-transform))
 462           dim)
 463         (give-up-ir1-transform))))
 464
 465 ;;; Again, if we can tell the results from the type, just use it.
 466 ;;; Otherwise, if we know the rank, convert into a computation based
 467 ;;; on array-dimension. We can wrap a TRULY-THE INDEX around the
 468 ;;; multiplications because we know that the total size must be an
 469 ;;; INDEX.
 470 (deftransform array-total-size ((array)
 471                                 (array))
 472   (let ((array-type (lvar-type array)))
 473     (unless (array-type-p array-type)
 474       (give-up-ir1-transform))
 475     (let ((dims (array-type-dimensions array-type)))
 476       (unless (listp dims)
 477         (give-up-ir1-transform "can't tell the rank at compile time"))
 478       (if (member '* dims)
 479           (do ((form 1 `(truly-the index
 480                                    (* (array-dimension array ,i) ,form)))
 481                (i 0 (1+ i)))
 482               ((= i (length dims)) form))
 483           (reduce #'* dims)))))
 484
 485 ;;; Only complex vectors have fill pointers.
 486 (deftransform array-has-fill-pointer-p ((array))
 487   (let ((array-type (lvar-type array)))
 488     (unless (array-type-p array-type)
 489       (give-up-ir1-transform))
 490     (let ((dims (array-type-dimensions array-type)))
 491       (if (and (listp dims) (not (= (length dims) 1)))
 492           nil
 493           (ecase (array-type-complexp array-type)
 494             ((t)
 495              t)
 496             ((nil)
 497              nil)
 498             ((:maybe)
 499              (give-up-ir1-transform
 500               "The array type is ambiguous; must call ~
 501               ARRAY-HAS-FILL-POINTER-P at runtime.")))))))
 502
 503 ;;; Primitive used to verify indices into arrays. If we can tell at
 504 ;;; compile-time or we are generating unsafe code, don't bother with
 505 ;;; the VOP.
 506 (deftransform %check-bound ((array dimension index) * * :node node)
 507   (cond ((policy node (and (> speed safety) (= safety 0)))
 508          'index)
 509         ((not (constant-lvar-p dimension))
 510          (give-up-ir1-transform))
 511         (t
 512          (let ((dim (lvar-value dimension)))
 513            `(the (integer 0 (,dim)) index)))))
 514 \f
 515 ;;;; WITH-ARRAY-DATA
 516
 517 ;;; This checks to see whether the array is simple and the start and
 518 ;;; end are in bounds. If so, it proceeds with those values.
 519 ;;; Otherwise, it calls %WITH-ARRAY-DATA. Note that %WITH-ARRAY-DATA
 520 ;;; may be further optimized.
 521 ;;;
 522 ;;; Given any ARRAY, bind DATA-VAR to the array's data vector and
 523 ;;; START-VAR and END-VAR to the start and end of the designated
 524 ;;; portion of the data vector. SVALUE and EVALUE are any start and
 525 ;;; end specified to the original operation, and are factored into the
 526 ;;; bindings of START-VAR and END-VAR. OFFSET-VAR is the cumulative
 527 ;;; offset of all displacements encountered, and does not include
 528 ;;; SVALUE.
 529 ;;;
 530 ;;; When FORCE-INLINE is set, the underlying %WITH-ARRAY-DATA form is
 531 ;;; forced to be inline, overriding the ordinary judgment of the
 532 ;;; %WITH-ARRAY-DATA DEFTRANSFORMs. Ordinarily the DEFTRANSFORMs are
 533 ;;; fairly picky about their arguments, figuring that if you haven't
 534 ;;; bothered to get all your ducks in a row, you probably don't care
 535 ;;; that much about speed anyway! But in some cases it makes sense to
 536 ;;; do type testing inside %WITH-ARRAY-DATA instead of outside, and
 537 ;;; the DEFTRANSFORM can't tell that that's going on, so it can make
 538 ;;; sense to use FORCE-INLINE option in that case.
 539 (def!macro with-array-data (((data-var array &key offset-var)
 540                              (start-var &optional (svalue 0))
 541                              (end-var &optional (evalue nil))
 542                              &key force-inline)
 543                             &body forms)
 544   (once-only ((n-array array)
 545               (n-svalue `(the index ,svalue))
 546               (n-evalue `(the (or index null) ,evalue)))
 547     `(multiple-value-bind (,data-var
 548                            ,start-var
 549                            ,end-var
 550                            ,@(when offset-var `(,offset-var)))
 551          (if (not (array-header-p ,n-array))
 552              (let ((,n-array ,n-array))
 553                (declare (type (simple-array * (*)) ,n-array))
 554                ,(once-only ((n-len `(length ,n-array))
 555                             (n-end `(or ,n-evalue ,n-len)))
 556                   `(if (<= ,n-svalue ,n-end ,n-len)
 557                        ;; success
 558                        (values ,n-array ,n-svalue ,n-end 0)
 559                        (failed-%with-array-data ,n-array
 560                                                 ,n-svalue
 561                                                 ,n-evalue))))
 562              (,(if force-inline '%with-array-data-macro '%with-array-data)
 563               ,n-array ,n-svalue ,n-evalue))
 564        ,@forms)))
 565
 566 ;;; This is the fundamental definition of %WITH-ARRAY-DATA, for use in
 567 ;;; DEFTRANSFORMs and DEFUNs.
 568 (def!macro %with-array-data-macro (array
 569                                    start
 570                                    end
 571                                    &key
 572                                    (element-type '*)
 573                                    unsafe?
 574                                    fail-inline?)
 575   (with-unique-names (size defaulted-end data cumulative-offset)
 576     `(let* ((,size (array-total-size ,array))
 577             (,defaulted-end
 578               (cond (,end
 579                      (unless (or ,unsafe? (<= ,end ,size))
 580                        ,(if fail-inline?
 581                             `(error 'bounding-indices-bad-error
 582                               :datum (cons ,start ,end)
 583                               :expected-type `(cons (integer 0 ,',size)
 584                                                     (integer ,',start ,',size))
 585                               :object ,array)
 586                             `(failed-%with-array-data ,array ,start ,end)))
 587                      ,end)
 588                     (t ,size))))
 589        (unless (or ,unsafe? (<= ,start ,defaulted-end))
 590          ,(if fail-inline?
 591               `(error 'bounding-indices-bad-error
 592                 :datum (cons ,start ,end)
 593                 :expected-type `(cons (integer 0 ,',size)
 594                                       (integer ,',start ,',size))
 595                 :object ,array)
 596               `(failed-%with-array-data ,array ,start ,end)))
 597        (do ((,data ,array (%array-data-vector ,data))
 598             (,cumulative-offset 0
 599                                 (+ ,cumulative-offset
 600                                    (%array-displacement ,data))))
 601            ((not (array-header-p ,data))
 602             (values (the (simple-array ,element-type 1) ,data)
 603                     (the index (+ ,cumulative-offset ,start))
 604                     (the index (+ ,cumulative-offset ,defaulted-end))
 605                     (the index ,cumulative-offset)))
 606          (declare (type index ,cumulative-offset))))))
 607
 608 (deftransform %with-array-data ((array start end)
 609                                 ;; It might very well be reasonable to
 610                                 ;; allow general ARRAY here, I just
 611                                 ;; haven't tried to understand the
 612                                 ;; performance issues involved. --
 613                                 ;; WHN, and also CSR 2002-05-26
 614                                 ((or vector simple-array) index (or index null))
 615                                 *
 616                                 :important t
 617                                 :node node
 618                                 :policy (> speed space))
 619   "inline non-SIMPLE-vector-handling logic"
 620   (let ((element-type (upgraded-element-type-specifier-or-give-up array)))
 621     `(%with-array-data-macro array start end
 622                              :unsafe? ,(policy node (= safety 0))
 623                              :element-type ,element-type)))
 624 \f
 625 ;;;; array accessors
 626
 627 ;;; We convert all typed array accessors into AREF and %ASET with type
 628 ;;; assertions on the array.
 629 (macrolet ((define-frob (reffer setter type)
 630              `(progn
 631                 (define-source-transform ,reffer (a &rest i)
 632                   `(aref (the ,',type ,a) ,@i))
 633                 (define-source-transform ,setter (a &rest i)
 634                   `(%aset (the ,',type ,a) ,@i)))))
 635   (define-frob sbit %sbitset (simple-array bit))
 636   (define-frob bit %bitset (array bit)))
 637 (macrolet ((define-frob (reffer setter type)
 638              `(progn
 639                 (define-source-transform ,reffer (a i)
 640                   `(aref (the ,',type ,a) ,i))
 641                 (define-source-transform ,setter (a i v)
 642                   `(%aset (the ,',type ,a) ,i ,v)))))
 643   (define-frob svref %svset simple-vector)
 644   (define-frob schar %scharset simple-string)
 645   (define-frob char %charset string))
 646
 647 (macrolet (;; This is a handy macro for computing the row-major index
 648            ;; given a set of indices. We wrap each index with a call
 649            ;; to %CHECK-BOUND to ensure that everything works out
 650            ;; correctly. We can wrap all the interior arithmetic with
 651            ;; TRULY-THE INDEX because we know the the resultant
 652            ;; row-major index must be an index.
 653            (with-row-major-index ((array indices index &optional new-value)
 654                                   &rest body)
 655              `(let (n-indices dims)
 656                 (dotimes (i (length ,indices))
 657                   (push (make-symbol (format nil "INDEX-~D" i)) n-indices)
 658                   (push (make-symbol (format nil "DIM-~D" i)) dims))
 659                 (setf n-indices (nreverse n-indices))
 660                 (setf dims (nreverse dims))
 661                 `(lambda (,',array ,@n-indices
 662                                    ,@',(when new-value (list new-value)))
 663                    (let* (,@(let ((,index -1))
 664                               (mapcar (lambda (name)
 665                                         `(,name (array-dimension
 666                                                  ,',array
 667                                                  ,(incf ,index))))
 668                                       dims))
 669                             (,',index
 670                              ,(if (null dims)
 671                                   0
 672                                 (do* ((dims dims (cdr dims))
 673                                       (indices n-indices (cdr indices))
 674                                       (last-dim nil (car dims))
 675                                       (form `(%check-bound ,',array
 676                                                            ,(car dims)
 677                                                            ,(car indices))
 678                                             `(truly-the
 679                                               index
 680                                               (+ (truly-the index
 681                                                             (* ,form
 682                                                                ,last-dim))
 683                                                  (%check-bound
 684                                                   ,',array
 685                                                   ,(car dims)
 686                                                   ,(car indices))))))
 687                                     ((null (cdr dims)) form)))))
 688                      ,',@body)))))
 689
 690   ;; Just return the index after computing it.
 691   (deftransform array-row-major-index ((array &rest indices))
 692     (with-row-major-index (array indices index)
 693       index))
 694
 695   ;; Convert AREF and %ASET into a HAIRY-DATA-VECTOR-REF (or
 696   ;; HAIRY-DATA-VECTOR-SET) with the set of indices replaced with the an
 697   ;; expression for the row major index.
 698   (deftransform aref ((array &rest indices))
 699     (with-row-major-index (array indices index)
 700       (hairy-data-vector-ref array index)))
 701   (deftransform %aset ((array &rest stuff))
 702     (let ((indices (butlast stuff)))
 703       (with-row-major-index (array indices index new-value)
 704         (hairy-data-vector-set array index new-value)))))
 705
 706 ;;; Just convert into a HAIRY-DATA-VECTOR-REF (or
 707 ;;; HAIRY-DATA-VECTOR-SET) after checking that the index is inside the
 708 ;;; array total size.
 709 (deftransform row-major-aref ((array index))
 710   `(hairy-data-vector-ref array
 711                           (%check-bound array (array-total-size array) index)))
 712 (deftransform %set-row-major-aref ((array index new-value))
 713   `(hairy-data-vector-set array
 714                           (%check-bound array (array-total-size array) index)
 715                           new-value))
 716 \f
 717 ;;;; bit-vector array operation canonicalization
 718 ;;;;
 719 ;;;; We convert all bit-vector operations to have the result array
 720 ;;;; specified. This allows any result allocation to be open-coded,
 721 ;;;; and eliminates the need for any VM-dependent transforms to handle
 722 ;;;; these cases.
 723
 724 (macrolet ((def (fun)
 725              `(progn
 726                (deftransform ,fun ((bit-array-1 bit-array-2
 727                                                 &optional result-bit-array)
 728                                    (bit-vector bit-vector &optional null) *
 729                                    :policy (>= speed space))
 730                  `(,',fun bit-array-1 bit-array-2
 731                    (make-array (length bit-array-1) :element-type 'bit)))
 732                ;; If result is T, make it the first arg.
 733                (deftransform ,fun ((bit-array-1 bit-array-2 result-bit-array)
 734                                    (bit-vector bit-vector (eql t)) *)
 735                  `(,',fun bit-array-1 bit-array-2 bit-array-1)))))
 736   (def bit-and)
 737   (def bit-ior)
 738   (def bit-xor)
 739   (def bit-eqv)
 740   (def bit-nand)
 741   (def bit-nor)
 742   (def bit-andc1)
 743   (def bit-andc2)
 744   (def bit-orc1)
 745   (def bit-orc2))
 746
 747 ;;; Similar for BIT-NOT, but there is only one arg...
 748 (deftransform bit-not ((bit-array-1 &optional result-bit-array)
 749                        (bit-vector &optional null) *
 750                        :policy (>= speed space))
 751   '(bit-not bit-array-1
 752             (make-array (length bit-array-1) :element-type 'bit)))
 753 (deftransform bit-not ((bit-array-1 result-bit-array)
 754                        (bit-vector (eql t)))
 755   '(bit-not bit-array-1 bit-array-1))
 756 \f
 757 ;;; Pick off some constant cases.
 758 (defoptimizer (array-header-p derive-type) ((array))
 759   (let ((type (lvar-type array)))
 760     (cond ((not (array-type-p type))
 761            nil)
 762           (t
 763            (let ((dims (array-type-dimensions type)))
 764              (cond ((csubtypep type (specifier-type '(simple-array * (*))))
 765                     ;; no array header
 766                     (specifier-type 'null))
 767                    ((and (listp dims) (/= (length dims) 1))
 768                     ;; multi-dimensional array, will have a header
 769                     (specifier-type '(eql t)))
 770                    (t
 771                     nil)))))))