src/compiler/array-tran.lisp

   1 ;;;; array-specific optimizers and transforms
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; utilities for optimizing array operations
  15
  16 ;;; Return UPGRADED-ARRAY-ELEMENT-TYPE for CONTINUATION, or do
  17 ;;; GIVE-UP-IR1-TRANSFORM if the upgraded element type can't be
  18 ;;; determined.
  19 (defun upgraded-element-type-specifier-or-give-up (continuation)
  20   (let* ((element-ctype (extract-upgraded-element-type continuation))
  21          (element-type-specifier (type-specifier element-ctype)))
  22     (if (eq element-type-specifier '*)
  23         (give-up-ir1-transform
  24          "upgraded array element type not known at compile time")
  25         element-type-specifier)))
  26
  27 ;;; Array access functions return an object from the array, hence its
  28 ;;; type is going to be the array upgraded element type.
  29 (defun extract-upgraded-element-type (array)
  30   (let ((type (continuation-type array)))
  31     ;; Note that this IF mightn't be satisfied even if the runtime
  32     ;; value is known to be a subtype of some specialized ARRAY, because
  33     ;; we can have values declared e.g. (AND SIMPLE-VECTOR UNKNOWN-TYPE),
  34     ;; which are represented in the compiler as INTERSECTION-TYPE, not
  35     ;; array type.
  36     (if (array-type-p type)
  37         (array-type-specialized-element-type type)
  38         ;; KLUDGE: there is no good answer here, but at least
  39         ;; *wild-type* won't cause HAIRY-DATA-VECTOR-{REF,SET} to be
  40         ;; erroneously optimized (see generic/vm-tran.lisp) -- CSR,
  41         ;; 2002-08-21
  42         *wild-type*)))
  43
  44 ;;; The ``new-value'' for array setters must fit in the array, and the
  45 ;;; return type is going to be the same as the new-value for SETF
  46 ;;; functions.
  47 (defun assert-new-value-type (new-value array)
  48   (let ((type (continuation-type array)))
  49     (when (array-type-p type)
  50       (assert-continuation-type
  51        new-value
  52        (array-type-specialized-element-type type)
  53        (lexenv-policy (node-lexenv (continuation-dest new-value))))))
  54   (continuation-type new-value))
  55
  56 (defun assert-array-complex (array)
  57   (assert-continuation-type
  58    array
  59    (make-array-type :complexp t
  60                     :element-type *wild-type*)
  61    (lexenv-policy (node-lexenv (continuation-dest array)))))
  62
  63 ;;; Return true if ARG is NIL, or is a constant-continuation whose
  64 ;;; value is NIL, false otherwise.
  65 (defun unsupplied-or-nil (arg)
  66   (declare (type (or continuation null) arg))
  67   (or (not arg)
  68       (and (constant-continuation-p arg)
  69            (not (continuation-value arg)))))
  70 \f
  71 ;;;; DERIVE-TYPE optimizers
  72
  73 ;;; Array operations that use a specific number of indices implicitly
  74 ;;; assert that the array is of that rank.
  75 (defun assert-array-rank (array rank)
  76   (assert-continuation-type
  77    array
  78    (specifier-type `(array * ,(make-list rank :initial-element '*)))
  79    (lexenv-policy (node-lexenv (continuation-dest array)))))
  80
  81 (defoptimizer (array-in-bounds-p derive-type) ((array &rest indices))
  82   (assert-array-rank array (length indices))
  83   *universal-type*)
  84
  85 (defoptimizer (aref derive-type) ((array &rest indices) node)
  86   (assert-array-rank array (length indices))
  87   ;; If the node continuation has a single use then assert its type.
  88   (let ((cont (node-cont node)))
  89     (when (= (length (find-uses cont)) 1)
  90       (assert-continuation-type cont (extract-upgraded-element-type array)
  91                                 (lexenv-policy (node-lexenv node)))))
  92   (extract-upgraded-element-type array))
  93
  94 (defoptimizer (%aset derive-type) ((array &rest stuff))
  95   (assert-array-rank array (1- (length stuff)))
  96   (assert-new-value-type (car (last stuff)) array))
  97
  98 (defoptimizer (hairy-data-vector-ref derive-type) ((array index))
  99   (extract-upgraded-element-type array))
 100 (defoptimizer (data-vector-ref derive-type) ((array index))
 101   (extract-upgraded-element-type array))
 102
 103 (defoptimizer (data-vector-set derive-type) ((array index new-value))
 104   (assert-new-value-type new-value array))
 105 (defoptimizer (hairy-data-vector-set derive-type) ((array index new-value))
 106   (assert-new-value-type new-value array))
 107
 108 ;;; Figure out the type of the data vector if we know the argument
 109 ;;; element type.
 110 (defoptimizer (%with-array-data derive-type) ((array start end))
 111   (let ((atype (continuation-type array)))
 112     (when (array-type-p atype)
 113       (values-specifier-type
 114        `(values (simple-array ,(type-specifier
 115                                 (array-type-specialized-element-type atype))
 116                               (*))
 117                 index index index)))))
 118
 119 (defoptimizer (array-row-major-index derive-type) ((array &rest indices))
 120   (assert-array-rank array (length indices))
 121   *universal-type*)
 122
 123 (defoptimizer (row-major-aref derive-type) ((array index))
 124   (extract-upgraded-element-type array))
 125
 126 (defoptimizer (%set-row-major-aref derive-type) ((array index new-value))
 127   (assert-new-value-type new-value array))
 128
 129 (defoptimizer (make-array derive-type)
 130               ((dims &key initial-element element-type initial-contents
 131                 adjustable fill-pointer displaced-index-offset displaced-to))
 132   (let ((simple (and (unsupplied-or-nil adjustable)
 133                      (unsupplied-or-nil displaced-to)
 134                      (unsupplied-or-nil fill-pointer))))
 135     (or (careful-specifier-type
 136          `(,(if simple 'simple-array 'array)
 137             ,(cond ((not element-type) t)
 138                    ((constant-continuation-p element-type)
 139                     (continuation-value element-type))
 140                    (t
 141                     '*))
 142             ,(cond ((not simple)
 143                     '*)
 144                    ((constant-continuation-p dims)
 145                     (let ((val (continuation-value dims)))
 146                       (if (listp val) val (list val))))
 147                    ((csubtypep (continuation-type dims)
 148                                (specifier-type 'integer))
 149                     '(*))
 150                    (t
 151                     '*))))
 152         (specifier-type 'array))))
 153
 154 ;;; Complex array operations should assert that their array argument
 155 ;;; is complex.  In SBCL, vectors with fill-pointers are complex.
 156 (defoptimizer (fill-pointer derive-type) ((vector))
 157   (assert-array-complex vector))
 158 (defoptimizer (%set-fill-pointer derive-type) ((vector index))
 159   (declare (ignorable index))
 160   (assert-array-complex vector))
 161
 162 (defoptimizer (vector-push derive-type) ((object vector))
 163   (declare (ignorable object))
 164   (assert-array-complex vector))
 165 (defoptimizer (vector-push-extend derive-type)
 166     ((object vector &optional index))
 167   (declare (ignorable object index))
 168   (assert-array-complex vector))
 169 (defoptimizer (vector-pop derive-type) ((vector))
 170   (assert-array-complex vector))
 171 \f
 172 ;;;; constructors
 173
 174 ;;; Convert VECTOR into a MAKE-ARRAY followed by SETFs of all the
 175 ;;; elements.
 176 (define-source-transform vector (&rest elements)
 177   (let ((len (length elements))
 178         (n -1))
 179     (once-only ((n-vec `(make-array ,len)))
 180       `(progn
 181          ,@(mapcar (lambda (el)
 182                      (once-only ((n-val el))
 183                        `(locally (declare (optimize (safety 0)))
 184                                  (setf (svref ,n-vec ,(incf n))
 185                                        ,n-val))))
 186                    elements)
 187          ,n-vec))))
 188
 189 ;;; Just convert it into a MAKE-ARRAY.
 190 (define-source-transform make-string (length &key
 191                                              (element-type ''base-char)
 192                                              (initial-element
 193                                               '#.*default-init-char-form*))
 194   `(make-array (the index ,length)
 195                :element-type ,element-type
 196                :initial-element ,initial-element))
 197
 198 (defstruct (specialized-array-element-type-properties
 199             (:conc-name saetp-)
 200             (:constructor !make-saetp (ctype
 201                                        initial-element-default
 202                                        n-bits
 203                                        typecode
 204                                        &key
 205                                        (n-pad-elements 0)))
 206             (:copier nil))
 207   ;; the element type, e.g. #<BUILT-IN-CLASS BASE-CHAR (sealed)> or
 208   ;; #<SB-KERNEL:NUMERIC-TYPE (UNSIGNED-BYTE 4)>
 209   (ctype (missing-arg) :type ctype :read-only t)
 210   ;; what we get when the low-level vector-creation logic zeroes all
 211   ;; the bits (which also serves as the default value of MAKE-ARRAY's
 212   ;; :INITIAL-ELEMENT keyword)
 213   (initial-element-default (missing-arg) :read-only t)
 214   ;; how many bits per element
 215   (n-bits (missing-arg) :type index :read-only t)
 216   ;; the low-level type code
 217   (typecode (missing-arg) :type index :read-only t)
 218   ;; the number of extra elements we use at the end of the array for
 219   ;; low level hackery (e.g., one element for arrays of BASE-CHAR,
 220   ;; which is used for a fixed #\NULL so that when we call out to C
 221   ;; we don't need to cons a new copy)
 222   (n-pad-elements (missing-arg) :type index :read-only t))
 223
 224 (defparameter *specialized-array-element-type-properties*
 225   (map 'simple-vector
 226        (lambda (args)
 227          (destructuring-bind (type-spec &rest rest) args
 228            (let ((ctype (specifier-type type-spec)))
 229              (apply #'!make-saetp ctype rest))))
 230        `((base-char ,(code-char 0) 8 ,sb!vm:simple-string-widetag
 231                     ;; (SIMPLE-STRINGs are stored with an extra trailing
 232                     ;; #\NULL for convenience in calling out to C.)
 233                     :n-pad-elements 1)
 234          (single-float 0.0f0 32 ,sb!vm:simple-array-single-float-widetag)
 235          (double-float 0.0d0 64 ,sb!vm:simple-array-double-float-widetag)
 236          #!+long-float (long-float 0.0L0 #!+x86 96 #!+sparc 128
 237                                    ,sb!vm:simple-array-long-float-widetag)
 238          (bit 0 1 ,sb!vm:simple-bit-vector-widetag)
 239          ;; KLUDGE: The fact that these UNSIGNED-BYTE entries come
 240          ;; before their SIGNED-BYTE partners is significant in the
 241          ;; implementation of the compiler; some of the cross-compiler
 242          ;; code (see e.g. COERCE-TO-SMALLEST-ELTYPE in
 243          ;; src/compiler/debug-dump.lisp) attempts to create an array
 244          ;; specialized on (UNSIGNED-BYTE FOO), where FOO could be 7;
 245          ;; (UNSIGNED-BYTE 7) is SUBTYPEP (SIGNED-BYTE 8), so if we're
 246          ;; not careful we could get the wrong specialized array when
 247          ;; we try to FIND-IF, below. -- CSR, 2002-07-08
 248          ((unsigned-byte 2) 0 2 ,sb!vm:simple-array-unsigned-byte-2-widetag)
 249          ((unsigned-byte 4) 0 4 ,sb!vm:simple-array-unsigned-byte-4-widetag)
 250          ((unsigned-byte 8) 0 8 ,sb!vm:simple-array-unsigned-byte-8-widetag)
 251          ((unsigned-byte 16) 0 16 ,sb!vm:simple-array-unsigned-byte-16-widetag)
 252          ((unsigned-byte 32) 0 32 ,sb!vm:simple-array-unsigned-byte-32-widetag)
 253          ((signed-byte 8) 0 8 ,sb!vm:simple-array-signed-byte-8-widetag)
 254          ((signed-byte 16) 0 16 ,sb!vm:simple-array-signed-byte-16-widetag)
 255          ((signed-byte 30) 0 32 ,sb!vm:simple-array-signed-byte-30-widetag)
 256          ((signed-byte 32) 0 32 ,sb!vm:simple-array-signed-byte-32-widetag)
 257          ((complex single-float) #C(0.0f0 0.0f0) 64
 258           ,sb!vm:simple-array-complex-single-float-widetag)
 259          ((complex double-float) #C(0.0d0 0.0d0) 128
 260           ,sb!vm:simple-array-complex-double-float-widetag)
 261          #!+long-float ((complex long-float) #C(0.0L0 0.0L0)
 262                         #!+x86 192 #!+sparc 256
 263                         ,sb!vm:simple-array-complex-long-float-widetag)
 264          (t 0 32 ,sb!vm:simple-vector-widetag))))
 265
 266 (deftransform make-array ((dims &key initial-element element-type
 267                                      adjustable fill-pointer)
 268                           (t &rest *))
 269   (when (null initial-element)
 270     (give-up-ir1-transform))
 271   (let* ((eltype (cond ((not element-type) t)
 272                        ((not (constant-continuation-p element-type))
 273                         (give-up-ir1-transform
 274                          "ELEMENT-TYPE is not constant."))
 275                        (t
 276                         (continuation-value element-type))))
 277          (eltype-type (ir1-transform-specifier-type eltype))
 278          (saetp (find-if (lambda (saetp)
 279                            (csubtypep eltype-type (saetp-ctype saetp)))
 280                          *specialized-array-element-type-properties*))
 281          (creation-form `(make-array dims :element-type ',eltype
 282                                      ,@(when fill-pointer
 283                                          '(:fill-pointer fill-pointer))
 284                                      ,@(when adjustable
 285                                          '(:adjustable adjustable)))))
 286
 287     (unless saetp
 288       (give-up-ir1-transform "ELEMENT-TYPE not found in *SAETP*: ~S" eltype))
 289
 290     (cond ((or (null initial-element)
 291                (and (constant-continuation-p initial-element)
 292                     (eql (continuation-value initial-element)
 293                          (saetp-initial-element-default saetp))))
 294            (unless (csubtypep (ctype-of (saetp-initial-element-default saetp))
 295                               eltype-type)
 296              ;; This situation arises e.g. in (MAKE-ARRAY 4
 297              ;; :ELEMENT-TYPE '(INTEGER 1 5)) ANSI's definition of
 298              ;; MAKE-ARRAY says "If INITIAL-ELEMENT is not supplied,
 299              ;; the consequences of later reading an uninitialized
 300              ;; element of new-array are undefined," so this could be
 301              ;; legal code as long as the user plans to write before
 302              ;; he reads, and if he doesn't we're free to do anything
 303              ;; we like. But in case the user doesn't know to write
 304              ;; elements before he reads elements (or to read manuals
 305              ;; before he writes code:-), we'll signal a STYLE-WARNING
 306              ;; in case he didn't realize this.
 307              (compiler-style-warn "The default initial element ~S is not a ~S."
 308                                   (saetp-initial-element-default saetp)
 309                                   eltype))
 310            creation-form)
 311           (t
 312            `(let ((array ,creation-form))
 313              (multiple-value-bind (vector)
 314                  (%data-vector-and-index array 0)
 315                (fill vector initial-element))
 316              array)))))
 317
 318 ;;; The integer type restriction on the length ensures that it will be
 319 ;;; a vector. The lack of :ADJUSTABLE, :FILL-POINTER, and
 320 ;;; :DISPLACED-TO keywords ensures that it will be simple; the lack of
 321 ;;; :INITIAL-ELEMENT relies on another transform to deal with that
 322 ;;; kind of initialization efficiently.
 323 (deftransform make-array ((length &key element-type)
 324                           (integer &rest *))
 325   (let* ((eltype (cond ((not element-type) t)
 326                        ((not (constant-continuation-p element-type))
 327                         (give-up-ir1-transform
 328                          "ELEMENT-TYPE is not constant."))
 329                        (t
 330                         (continuation-value element-type))))
 331          (len (if (constant-continuation-p length)
 332                   (continuation-value length)
 333                   '*))
 334          (result-type-spec `(simple-array ,eltype (,len)))
 335          (eltype-type (ir1-transform-specifier-type eltype))
 336          (saetp (find-if (lambda (saetp)
 337                            (csubtypep eltype-type (saetp-ctype saetp)))
 338                          *specialized-array-element-type-properties*)))
 339     (unless saetp
 340       (give-up-ir1-transform
 341        "cannot open-code creation of ~S" result-type-spec))
 342
 343     (let* ((n-bits-per-element (saetp-n-bits saetp))
 344            (typecode (saetp-typecode saetp))
 345            (n-pad-elements (saetp-n-pad-elements saetp))
 346            (padded-length-form (if (zerop n-pad-elements)
 347                                    'length
 348                                    `(+ length ,n-pad-elements)))
 349            (n-words-form
 350             (if (>= n-bits-per-element sb!vm:n-word-bits)
 351                 `(* ,padded-length-form
 352                     (the fixnum ; i.e., not RATIO
 353                       ,(/ n-bits-per-element sb!vm:n-word-bits)))
 354                 (let ((n-elements-per-word (/ sb!vm:n-word-bits
 355                                               n-bits-per-element)))
 356                   (declare (type index n-elements-per-word)) ; i.e., not RATIO
 357                   `(ceiling ,padded-length-form ,n-elements-per-word)))))
 358       (values
 359        `(truly-the ,result-type-spec
 360          (allocate-vector ,typecode length ,n-words-form))
 361        '((declare (type index length)))))))
 362
 363 ;;; The list type restriction does not ensure that the result will be a
 364 ;;; multi-dimensional array. But the lack of adjustable, fill-pointer,
 365 ;;; and displaced-to keywords ensures that it will be simple.
 366 ;;;
 367 ;;; FIXME: should we generalize this transform to non-simple (though
 368 ;;; non-displaced-to) arrays, given that we have %WITH-ARRAY-DATA to
 369 ;;; deal with those? Maybe when the DEFTRANSFORM
 370 ;;; %DATA-VECTOR-AND-INDEX in the VECTOR case problem is solved? --
 371 ;;; CSR, 2002-07-01
 372 (deftransform make-array ((dims &key element-type)
 373                           (list &rest *))
 374   (unless (or (null element-type) (constant-continuation-p element-type))
 375     (give-up-ir1-transform
 376      "The element-type is not constant; cannot open code array creation."))
 377   (unless (constant-continuation-p dims)
 378     (give-up-ir1-transform
 379      "The dimension list is not constant; cannot open code array creation."))
 380   (let ((dims (continuation-value dims)))
 381     (unless (every #'integerp dims)
 382       (give-up-ir1-transform
 383        "The dimension list contains something other than an integer: ~S"
 384        dims))
 385     (if (= (length dims) 1)
 386         `(make-array ',(car dims)
 387                      ,@(when element-type
 388                          '(:element-type element-type)))
 389         (let* ((total-size (reduce #'* dims))
 390                (rank (length dims))
 391                (spec `(simple-array
 392                        ,(cond ((null element-type) t)
 393                               ((constant-continuation-p element-type)
 394                                (continuation-value element-type))
 395                               (t '*))
 396                            ,(make-list rank :initial-element '*))))
 397           `(let ((header (make-array-header sb!vm:simple-array-widetag ,rank)))
 398              (setf (%array-fill-pointer header) ,total-size)
 399              (setf (%array-fill-pointer-p header) nil)
 400              (setf (%array-available-elements header) ,total-size)
 401              (setf (%array-data-vector header)
 402                    (make-array ,total-size
 403                                ,@(when element-type
 404                                    '(:element-type element-type))))
 405              (setf (%array-displaced-p header) nil)
 406              ,@(let ((axis -1))
 407                  (mapcar (lambda (dim)
 408                            `(setf (%array-dimension header ,(incf axis))
 409                                   ,dim))
 410                          dims))
 411              (truly-the ,spec header))))))
 412 \f
 413 ;;;; miscellaneous properties of arrays
 414
 415 ;;; Transforms for various array properties. If the property is know
 416 ;;; at compile time because of a type spec, use that constant value.
 417
 418 ;;; If we can tell the rank from the type info, use it instead.
 419 (deftransform array-rank ((array))
 420   (let ((array-type (continuation-type array)))
 421     (unless (array-type-p array-type)
 422       (give-up-ir1-transform))
 423     (let ((dims (array-type-dimensions array-type)))
 424       (if (not (listp dims))
 425           (give-up-ir1-transform
 426            "The array rank is not known at compile time: ~S"
 427            dims)
 428           (length dims)))))
 429
 430 ;;; If we know the dimensions at compile time, just use it. Otherwise,
 431 ;;; if we can tell that the axis is in bounds, convert to
 432 ;;; %ARRAY-DIMENSION (which just indirects the array header) or length
 433 ;;; (if it's simple and a vector).
 434 (deftransform array-dimension ((array axis)
 435                                (array index))
 436   (unless (constant-continuation-p axis)
 437     (give-up-ir1-transform "The axis is not constant."))
 438   (let ((array-type (continuation-type array))
 439         (axis (continuation-value axis)))
 440     (unless (array-type-p array-type)
 441       (give-up-ir1-transform))
 442     (let ((dims (array-type-dimensions array-type)))
 443       (unless (listp dims)
 444         (give-up-ir1-transform
 445          "The array dimensions are unknown; must call ARRAY-DIMENSION at runtime."))
 446       (unless (> (length dims) axis)
 447         (abort-ir1-transform "The array has dimensions ~S, ~W is too large."
 448                              dims
 449                              axis))
 450       (let ((dim (nth axis dims)))
 451         (cond ((integerp dim)
 452                dim)
 453               ((= (length dims) 1)
 454                (ecase (array-type-complexp array-type)
 455                  ((t)
 456                   '(%array-dimension array 0))
 457                  ((nil)
 458                   '(length array))
 459                  ((:maybe)
 460                   (give-up-ir1-transform
 461                    "can't tell whether array is simple"))))
 462               (t
 463                '(%array-dimension array axis)))))))
 464
 465 ;;; If the length has been declared and it's simple, just return it.
 466 (deftransform length ((vector)
 467                       ((simple-array * (*))))
 468   (let ((type (continuation-type vector)))
 469     (unless (array-type-p type)
 470       (give-up-ir1-transform))
 471     (let ((dims (array-type-dimensions type)))
 472       (unless (and (listp dims) (integerp (car dims)))
 473         (give-up-ir1-transform
 474          "Vector length is unknown, must call LENGTH at runtime."))
 475       (car dims))))
 476
 477 ;;; All vectors can get their length by using VECTOR-LENGTH. If it's
 478 ;;; simple, it will extract the length slot from the vector. It it's
 479 ;;; complex, it will extract the fill pointer slot from the array
 480 ;;; header.
 481 (deftransform length ((vector) (vector))
 482   '(vector-length vector))
 483
 484 ;;; If a simple array with known dimensions, then VECTOR-LENGTH is a
 485 ;;; compile-time constant.
 486 (deftransform vector-length ((vector) ((simple-array * (*))))
 487   (let ((vtype (continuation-type vector)))
 488     (if (array-type-p vtype)
 489         (let ((dim (first (array-type-dimensions vtype))))
 490           (when (eq dim '*) (give-up-ir1-transform))
 491           dim)
 492         (give-up-ir1-transform))))
 493
 494 ;;; Again, if we can tell the results from the type, just use it.
 495 ;;; Otherwise, if we know the rank, convert into a computation based
 496 ;;; on array-dimension. We can wrap a TRULY-THE INDEX around the
 497 ;;; multiplications because we know that the total size must be an
 498 ;;; INDEX.
 499 (deftransform array-total-size ((array)
 500                                 (array))
 501   (let ((array-type (continuation-type array)))
 502     (unless (array-type-p array-type)
 503       (give-up-ir1-transform))
 504     (let ((dims (array-type-dimensions array-type)))
 505       (unless (listp dims)
 506         (give-up-ir1-transform "can't tell the rank at compile time"))
 507       (if (member '* dims)
 508           (do ((form 1 `(truly-the index
 509                                    (* (array-dimension array ,i) ,form)))
 510                (i 0 (1+ i)))
 511               ((= i (length dims)) form))
 512           (reduce #'* dims)))))
 513
 514 ;;; Only complex vectors have fill pointers.
 515 (deftransform array-has-fill-pointer-p ((array))
 516   (let ((array-type (continuation-type array)))
 517     (unless (array-type-p array-type)
 518       (give-up-ir1-transform))
 519     (let ((dims (array-type-dimensions array-type)))
 520       (if (and (listp dims) (not (= (length dims) 1)))
 521           nil
 522           (ecase (array-type-complexp array-type)
 523             ((t)
 524              t)
 525             ((nil)
 526              nil)
 527             ((:maybe)
 528              (give-up-ir1-transform
 529               "The array type is ambiguous; must call ~
 530               ARRAY-HAS-FILL-POINTER-P at runtime.")))))))
 531
 532 ;;; Primitive used to verify indices into arrays. If we can tell at
 533 ;;; compile-time or we are generating unsafe code, don't bother with
 534 ;;; the VOP.
 535 (deftransform %check-bound ((array dimension index))
 536   (unless (constant-continuation-p dimension)
 537     (give-up-ir1-transform))
 538   (let ((dim (continuation-value dimension)))
 539     `(the (integer 0 ,dim) index)))
 540 (deftransform %check-bound ((array dimension index) * *
 541                             :policy (and (> speed safety) (= safety 0)))
 542   'index)
 543 \f
 544 ;;;; WITH-ARRAY-DATA
 545
 546 ;;; This checks to see whether the array is simple and the start and
 547 ;;; end are in bounds. If so, it proceeds with those values.
 548 ;;; Otherwise, it calls %WITH-ARRAY-DATA. Note that %WITH-ARRAY-DATA
 549 ;;; may be further optimized.
 550 ;;;
 551 ;;; Given any ARRAY, bind DATA-VAR to the array's data vector and
 552 ;;; START-VAR and END-VAR to the start and end of the designated
 553 ;;; portion of the data vector. SVALUE and EVALUE are any start and
 554 ;;; end specified to the original operation, and are factored into the
 555 ;;; bindings of START-VAR and END-VAR. OFFSET-VAR is the cumulative
 556 ;;; offset of all displacements encountered, and does not include
 557 ;;; SVALUE.
 558 ;;;
 559 ;;; When FORCE-INLINE is set, the underlying %WITH-ARRAY-DATA form is
 560 ;;; forced to be inline, overriding the ordinary judgment of the
 561 ;;; %WITH-ARRAY-DATA DEFTRANSFORMs. Ordinarily the DEFTRANSFORMs are
 562 ;;; fairly picky about their arguments, figuring that if you haven't
 563 ;;; bothered to get all your ducks in a row, you probably don't care
 564 ;;; that much about speed anyway! But in some cases it makes sense to
 565 ;;; do type testing inside %WITH-ARRAY-DATA instead of outside, and
 566 ;;; the DEFTRANSFORM can't tell that that's going on, so it can make
 567 ;;; sense to use FORCE-INLINE option in that case.
 568 (def!macro with-array-data (((data-var array &key offset-var)
 569                              (start-var &optional (svalue 0))
 570                              (end-var &optional (evalue nil))
 571                              &key force-inline)
 572                             &body forms)
 573   (once-only ((n-array array)
 574               (n-svalue `(the index ,svalue))
 575               (n-evalue `(the (or index null) ,evalue)))
 576     `(multiple-value-bind (,data-var
 577                            ,start-var
 578                            ,end-var
 579                            ,@(when offset-var `(,offset-var)))
 580          (if (not (array-header-p ,n-array))
 581              (let ((,n-array ,n-array))
 582                (declare (type (simple-array * (*)) ,n-array))
 583                ,(once-only ((n-len `(length ,n-array))
 584                             (n-end `(or ,n-evalue ,n-len)))
 585                   `(if (<= ,n-svalue ,n-end ,n-len)
 586                        ;; success
 587                        (values ,n-array ,n-svalue ,n-end 0)
 588                        (failed-%with-array-data ,n-array
 589                                                 ,n-svalue
 590                                                 ,n-evalue))))
 591              (,(if force-inline '%with-array-data-macro '%with-array-data)
 592               ,n-array ,n-svalue ,n-evalue))
 593        ,@forms)))
 594
 595 ;;; This is the fundamental definition of %WITH-ARRAY-DATA, for use in
 596 ;;; DEFTRANSFORMs and DEFUNs.
 597 (def!macro %with-array-data-macro (array
 598                                    start
 599                                    end
 600                                    &key
 601                                    (element-type '*)
 602                                    unsafe?
 603                                    fail-inline?)
 604   (let ((size (gensym "SIZE-"))
 605         (defaulted-end (gensym "DEFAULTED-END-"))
 606         (data (gensym "DATA-"))
 607         (cumulative-offset (gensym "CUMULATIVE-OFFSET-")))
 608     `(let* ((,size (array-total-size ,array))
 609             (,defaulted-end
 610               (cond (,end
 611                      (unless (or ,unsafe? (<= ,end ,size))
 612                        ,(if fail-inline?
 613                             `(error "End ~W is greater than total size ~W."
 614                                     ,end ,size)
 615                             `(failed-%with-array-data ,array ,start ,end)))
 616                      ,end)
 617                     (t ,size))))
 618        (unless (or ,unsafe? (<= ,start ,defaulted-end))
 619          ,(if fail-inline?
 620               `(error "Start ~W is greater than end ~W." ,start ,defaulted-end)
 621               `(failed-%with-array-data ,array ,start ,end)))
 622        (do ((,data ,array (%array-data-vector ,data))
 623             (,cumulative-offset 0
 624                                 (+ ,cumulative-offset
 625                                    (%array-displacement ,data))))
 626            ((not (array-header-p ,data))
 627             (values (the (simple-array ,element-type 1) ,data)
 628                     (the index (+ ,cumulative-offset ,start))
 629                     (the index (+ ,cumulative-offset ,defaulted-end))
 630                     (the index ,cumulative-offset)))
 631          (declare (type index ,cumulative-offset))))))
 632
 633 (deftransform %with-array-data ((array start end)
 634                                 ;; It might very well be reasonable to
 635                                 ;; allow general ARRAY here, I just
 636                                 ;; haven't tried to understand the
 637                                 ;; performance issues involved. --
 638                                 ;; WHN, and also CSR 2002-05-26
 639                                 ((or vector simple-array) index (or index null))
 640                                 *
 641                                 :important t
 642                                 :node node
 643                                 :policy (> speed space))
 644   "inline non-SIMPLE-vector-handling logic"
 645   (let ((element-type (upgraded-element-type-specifier-or-give-up array)))
 646     `(%with-array-data-macro array start end
 647                              :unsafe? ,(policy node (= safety 0))
 648                              :element-type ,element-type)))
 649 \f
 650 ;;;; array accessors
 651
 652 ;;; We convert all typed array accessors into AREF and %ASET with type
 653 ;;; assertions on the array.
 654 (macrolet ((define-frob (reffer setter type)
 655              `(progn
 656                 (define-source-transform ,reffer (a &rest i)
 657                   `(aref (the ,',type ,a) ,@i))
 658                 (define-source-transform ,setter (a &rest i)
 659                   `(%aset (the ,',type ,a) ,@i)))))
 660   (define-frob svref %svset simple-vector)
 661   (define-frob schar %scharset simple-string)
 662   (define-frob char %charset string)
 663   (define-frob sbit %sbitset (simple-array bit))
 664   (define-frob bit %bitset (array bit)))
 665
 666 (macrolet (;; This is a handy macro for computing the row-major index
 667            ;; given a set of indices. We wrap each index with a call
 668            ;; to %CHECK-BOUND to ensure that everything works out
 669            ;; correctly. We can wrap all the interior arithmetic with
 670            ;; TRULY-THE INDEX because we know the the resultant
 671            ;; row-major index must be an index.
 672            (with-row-major-index ((array indices index &optional new-value)
 673                                   &rest body)
 674              `(let (n-indices dims)
 675                 (dotimes (i (length ,indices))
 676                   (push (make-symbol (format nil "INDEX-~D" i)) n-indices)
 677                   (push (make-symbol (format nil "DIM-~D" i)) dims))
 678                 (setf n-indices (nreverse n-indices))
 679                 (setf dims (nreverse dims))
 680                 `(lambda (,',array ,@n-indices
 681                                    ,@',(when new-value (list new-value)))
 682                    (let* (,@(let ((,index -1))
 683                               (mapcar (lambda (name)
 684                                         `(,name (array-dimension
 685                                                  ,',array
 686                                                  ,(incf ,index))))
 687                                       dims))
 688                             (,',index
 689                              ,(if (null dims)
 690                                   0
 691                                 (do* ((dims dims (cdr dims))
 692                                       (indices n-indices (cdr indices))
 693                                       (last-dim nil (car dims))
 694                                       (form `(%check-bound ,',array
 695                                                            ,(car dims)
 696                                                            ,(car indices))
 697                                             `(truly-the
 698                                               index
 699                                               (+ (truly-the index
 700                                                             (* ,form
 701                                                                ,last-dim))
 702                                                  (%check-bound
 703                                                   ,',array
 704                                                   ,(car dims)
 705                                                   ,(car indices))))))
 706                                     ((null (cdr dims)) form)))))
 707                      ,',@body)))))
 708
 709   ;; Just return the index after computing it.
 710   (deftransform array-row-major-index ((array &rest indices))
 711     (with-row-major-index (array indices index)
 712       index))
 713
 714   ;; Convert AREF and %ASET into a HAIRY-DATA-VECTOR-REF (or
 715   ;; HAIRY-DATA-VECTOR-SET) with the set of indices replaced with the an
 716   ;; expression for the row major index.
 717   (deftransform aref ((array &rest indices))
 718     (with-row-major-index (array indices index)
 719       (hairy-data-vector-ref array index)))
 720   (deftransform %aset ((array &rest stuff))
 721     (let ((indices (butlast stuff)))
 722       (with-row-major-index (array indices index new-value)
 723         (hairy-data-vector-set array index new-value)))))
 724
 725 ;;; Just convert into a HAIRY-DATA-VECTOR-REF (or
 726 ;;; HAIRY-DATA-VECTOR-SET) after checking that the index is inside the
 727 ;;; array total size.
 728 (deftransform row-major-aref ((array index))
 729   `(hairy-data-vector-ref array
 730                           (%check-bound array (array-total-size array) index)))
 731 (deftransform %set-row-major-aref ((array index new-value))
 732   `(hairy-data-vector-set array
 733                           (%check-bound array (array-total-size array) index)
 734                           new-value))
 735 \f
 736 ;;;; bit-vector array operation canonicalization
 737 ;;;;
 738 ;;;; We convert all bit-vector operations to have the result array
 739 ;;;; specified. This allows any result allocation to be open-coded,
 740 ;;;; and eliminates the need for any VM-dependent transforms to handle
 741 ;;;; these cases.
 742
 743 (macrolet ((def (fun)
 744              `(progn
 745                (deftransform ,fun ((bit-array-1 bit-array-2
 746                                                 &optional result-bit-array)
 747                                    (bit-vector bit-vector &optional null) *
 748                                    :policy (>= speed space))
 749                  `(,',fun bit-array-1 bit-array-2
 750                    (make-array (length bit-array-1) :element-type 'bit)))
 751                ;; If result is T, make it the first arg.
 752                (deftransform ,fun ((bit-array-1 bit-array-2 result-bit-array)
 753                                    (bit-vector bit-vector (member t)) *)
 754                  `(,',fun bit-array-1 bit-array-2 bit-array-1)))))
 755   (def bit-and)
 756   (def bit-ior)
 757   (def bit-xor)
 758   (def bit-eqv)
 759   (def bit-nand)
 760   (def bit-nor)
 761   (def bit-andc1)
 762   (def bit-andc2)
 763   (def bit-orc1)
 764   (def bit-orc2))
 765
 766 ;;; Similar for BIT-NOT, but there is only one arg...
 767 (deftransform bit-not ((bit-array-1 &optional result-bit-array)
 768                        (bit-vector &optional null) *
 769                        :policy (>= speed space))
 770   '(bit-not bit-array-1
 771             (make-array (length bit-array-1) :element-type 'bit)))
 772 (deftransform bit-not ((bit-array-1 result-bit-array)
 773                        (bit-vector (constant-arg t)))
 774   '(bit-not bit-array-1 bit-array-1))
 775 ;;; FIXME: What does (CONSTANT-ARG T) mean? Is it the same thing
 776 ;;; as (CONSTANT-ARG (MEMBER T)), or does it mean any constant
 777 ;;; value?
 778 \f
 779 ;;; Pick off some constant cases.
 780 (deftransform array-header-p ((array) (array))
 781   (let ((type (continuation-type array)))
 782     (unless (array-type-p type)
 783       (give-up-ir1-transform))
 784     (let ((dims (array-type-dimensions type)))
 785       (cond ((csubtypep type (specifier-type '(simple-array * (*))))
 786              ;; no array header
 787              nil)
 788             ((and (listp dims) (> (length dims) 1))
 789              ;; multi-dimensional array, will have a header
 790              t)
 791             (t
 792              (give-up-ir1-transform))))))