src/compiler/array-tran.lisp

   1 ;;;; array-specific optimizers and transforms
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; utilities for optimizing array operations
  15
  16 ;;; Return UPGRADED-ARRAY-ELEMENT-TYPE for LVAR, or do
  17 ;;; GIVE-UP-IR1-TRANSFORM if the upgraded element type can't be
  18 ;;; determined.
  19 (defun upgraded-element-type-specifier-or-give-up (lvar)
  20   (let* ((element-ctype (extract-upgraded-element-type lvar))
  21          (element-type-specifier (type-specifier element-ctype)))
  22     (if (eq element-type-specifier '*)
  23         (give-up-ir1-transform
  24          "upgraded array element type not known at compile time")
  25         element-type-specifier)))
  26
  27 ;;; Array access functions return an object from the array, hence its
  28 ;;; type is going to be the array upgraded element type.
  29 (defun extract-upgraded-element-type (array)
  30   (let ((type (lvar-type array)))
  31     ;; Note that this IF mightn't be satisfied even if the runtime
  32     ;; value is known to be a subtype of some specialized ARRAY, because
  33     ;; we can have values declared e.g. (AND SIMPLE-VECTOR UNKNOWN-TYPE),
  34     ;; which are represented in the compiler as INTERSECTION-TYPE, not
  35     ;; array type.
  36     (if (array-type-p type)
  37         (array-type-specialized-element-type type)
  38         ;; KLUDGE: there is no good answer here, but at least
  39         ;; *wild-type* won't cause HAIRY-DATA-VECTOR-{REF,SET} to be
  40         ;; erroneously optimized (see generic/vm-tran.lisp) -- CSR,
  41         ;; 2002-08-21
  42         *wild-type*)))
  43
  44 (defun extract-declared-element-type (array)
  45   (let ((type (lvar-type array)))
  46     (if (array-type-p type)
  47         (array-type-element-type type)
  48         *wild-type*)))
  49
  50 ;;; The ``new-value'' for array setters must fit in the array, and the
  51 ;;; return type is going to be the same as the new-value for SETF
  52 ;;; functions.
  53 (defun assert-new-value-type (new-value array)
  54   (let ((type (lvar-type array)))
  55     (when (array-type-p type)
  56       (assert-lvar-type
  57        new-value
  58        (array-type-specialized-element-type type)
  59        (lexenv-policy (node-lexenv (lvar-dest new-value))))))
  60   (lvar-type new-value))
  61
  62 (defun assert-array-complex (array)
  63   (assert-lvar-type
  64    array
  65    (make-array-type :complexp t
  66                     :element-type *wild-type*)
  67    (lexenv-policy (node-lexenv (lvar-dest array))))
  68   nil)
  69
  70 ;;; Return true if ARG is NIL, or is a constant-lvar whose
  71 ;;; value is NIL, false otherwise.
  72 (defun unsupplied-or-nil (arg)
  73   (declare (type (or lvar null) arg))
  74   (or (not arg)
  75       (and (constant-lvar-p arg)
  76            (not (lvar-value arg)))))
  77 \f
  78 ;;;; DERIVE-TYPE optimizers
  79
  80 ;;; Array operations that use a specific number of indices implicitly
  81 ;;; assert that the array is of that rank.
  82 (defun assert-array-rank (array rank)
  83   (assert-lvar-type
  84    array
  85    (specifier-type `(array * ,(make-list rank :initial-element '*)))
  86    (lexenv-policy (node-lexenv (lvar-dest array)))))
  87
  88 (defoptimizer (array-in-bounds-p derive-type) ((array &rest indices))
  89   (assert-array-rank array (length indices))
  90   *universal-type*)
  91
  92 (defoptimizer (aref derive-type) ((array &rest indices) node)
  93   (assert-array-rank array (length indices))
  94   (extract-upgraded-element-type array))
  95
  96 (defoptimizer (%aset derive-type) ((array &rest stuff))
  97   (assert-array-rank array (1- (length stuff)))
  98   (assert-new-value-type (car (last stuff)) array))
  99
 100 (defoptimizer (hairy-data-vector-ref derive-type) ((array index))
 101   (extract-upgraded-element-type array))
 102 (defoptimizer (data-vector-ref derive-type) ((array index))
 103   (extract-upgraded-element-type array))
 104
 105 (defoptimizer (data-vector-set derive-type) ((array index new-value))
 106   (assert-new-value-type new-value array))
 107 (defoptimizer (hairy-data-vector-set derive-type) ((array index new-value))
 108   (assert-new-value-type new-value array))
 109
 110 ;;; Figure out the type of the data vector if we know the argument
 111 ;;; element type.
 112 (defoptimizer (%with-array-data derive-type) ((array start end))
 113   (let ((atype (lvar-type array)))
 114     (when (array-type-p atype)
 115       (specifier-type
 116        `(simple-array ,(type-specifier
 117                        (array-type-specialized-element-type atype))
 118                      (*))))))
 119
 120 (defoptimizer (array-row-major-index derive-type) ((array &rest indices))
 121   (assert-array-rank array (length indices))
 122   *universal-type*)
 123
 124 (defoptimizer (row-major-aref derive-type) ((array index))
 125   (extract-upgraded-element-type array))
 126
 127 (defoptimizer (%set-row-major-aref derive-type) ((array index new-value))
 128   (assert-new-value-type new-value array))
 129
 130 (defoptimizer (make-array derive-type)
 131               ((dims &key initial-element element-type initial-contents
 132                 adjustable fill-pointer displaced-index-offset displaced-to))
 133   (let ((simple (and (unsupplied-or-nil adjustable)
 134                      (unsupplied-or-nil displaced-to)
 135                      (unsupplied-or-nil fill-pointer))))
 136     (or (careful-specifier-type
 137          `(,(if simple 'simple-array 'array)
 138             ,(cond ((not element-type) t)
 139                    ((constant-lvar-p element-type)
 140                     (let ((ctype (careful-specifier-type
 141                                   (lvar-value element-type))))
 142                       (cond
 143                         ((or (null ctype) (unknown-type-p ctype)) '*)
 144                         (t (sb!xc:upgraded-array-element-type
 145                             (lvar-value element-type))))))
 146                    (t
 147                     '*))
 148             ,(cond ((constant-lvar-p dims)
 149                     (let* ((val (lvar-value dims))
 150                            (cdims (if (listp val) val (list val))))
 151                       (if simple
 152                           cdims
 153                           (length cdims))))
 154                    ((csubtypep (lvar-type dims)
 155                                (specifier-type 'integer))
 156                     '(*))
 157                    (t
 158                     '*))))
 159         (specifier-type 'array))))
 160
 161 ;;; Complex array operations should assert that their array argument
 162 ;;; is complex.  In SBCL, vectors with fill-pointers are complex.
 163 (defoptimizer (fill-pointer derive-type) ((vector))
 164   (assert-array-complex vector))
 165 (defoptimizer (%set-fill-pointer derive-type) ((vector index))
 166   (declare (ignorable index))
 167   (assert-array-complex vector))
 168
 169 (defoptimizer (vector-push derive-type) ((object vector))
 170   (declare (ignorable object))
 171   (assert-array-complex vector))
 172 (defoptimizer (vector-push-extend derive-type)
 173     ((object vector &optional index))
 174   (declare (ignorable object index))
 175   (assert-array-complex vector))
 176 (defoptimizer (vector-pop derive-type) ((vector))
 177   (assert-array-complex vector))
 178 \f
 179 ;;;; constructors
 180
 181 ;;; Convert VECTOR into a MAKE-ARRAY followed by SETFs of all the
 182 ;;; elements.
 183 (define-source-transform vector (&rest elements)
 184   (let ((len (length elements))
 185         (n -1))
 186     (once-only ((n-vec `(make-array ,len)))
 187       `(progn
 188          ,@(mapcar (lambda (el)
 189                      (once-only ((n-val el))
 190                        `(locally (declare (optimize (safety 0)))
 191                                  (setf (svref ,n-vec ,(incf n))
 192                                        ,n-val))))
 193                    elements)
 194          ,n-vec))))
 195
 196 ;;; Just convert it into a MAKE-ARRAY.
 197 (deftransform make-string ((length &key
 198                                    (element-type 'character)
 199                                    (initial-element
 200                                     #.*default-init-char-form*)))
 201   `(the simple-string (make-array (the index length)
 202                        :element-type element-type
 203                        ,@(when initial-element
 204                            '(:initial-element initial-element)))))
 205
 206 (deftransform make-array ((dims &key initial-element element-type
 207                                      adjustable fill-pointer)
 208                           (t &rest *))
 209   (when (null initial-element)
 210     (give-up-ir1-transform))
 211   (let* ((eltype (cond ((not element-type) t)
 212                        ((not (constant-lvar-p element-type))
 213                         (give-up-ir1-transform
 214                          "ELEMENT-TYPE is not constant."))
 215                        (t
 216                         (lvar-value element-type))))
 217          (eltype-type (ir1-transform-specifier-type eltype))
 218          (saetp (find-if (lambda (saetp)
 219                            (csubtypep eltype-type (sb!vm:saetp-ctype saetp)))
 220                          sb!vm:*specialized-array-element-type-properties*))
 221          (creation-form `(make-array dims
 222                           :element-type ',(type-specifier (sb!vm:saetp-ctype saetp))
 223                           ,@(when fill-pointer
 224                                   '(:fill-pointer fill-pointer))
 225                           ,@(when adjustable
 226                                   '(:adjustable adjustable)))))
 227
 228     (unless saetp
 229       (give-up-ir1-transform "ELEMENT-TYPE not found in *SAETP*: ~S" eltype))
 230
 231     (cond ((and (constant-lvar-p initial-element)
 232                 (eql (lvar-value initial-element)
 233                      (sb!vm:saetp-initial-element-default saetp)))
 234            creation-form)
 235           (t
 236            ;; error checking for target, disabled on the host because
 237            ;; (CTYPE-OF #\Null) is not possible.
 238            #-sb-xc-host
 239            (when (constant-lvar-p initial-element)
 240              (let ((value (lvar-value initial-element)))
 241                (cond
 242                  ((not (ctypep value (sb!vm:saetp-ctype saetp)))
 243                   ;; this case will cause an error at runtime, so we'd
 244                   ;; better WARN about it now.
 245                   (compiler-warn "~@<~S is not a ~S (which is the ~
 246                                  UPGRADED-ARRAY-ELEMENT-TYPE of ~S).~@:>"
 247                                  value
 248                                  (type-specifier (sb!vm:saetp-ctype saetp))
 249                                  eltype))
 250                  ((not (ctypep value eltype-type))
 251                   ;; this case will not cause an error at runtime, but
 252                   ;; it's still worth STYLE-WARNing about.
 253                   (compiler-style-warn "~S is not a ~S."
 254                                        value eltype)))))
 255            `(let ((array ,creation-form))
 256              (multiple-value-bind (vector)
 257                  (%data-vector-and-index array 0)
 258                (fill vector initial-element))
 259              array)))))
 260
 261 ;;; The integer type restriction on the length ensures that it will be
 262 ;;; a vector. The lack of :ADJUSTABLE, :FILL-POINTER, and
 263 ;;; :DISPLACED-TO keywords ensures that it will be simple; the lack of
 264 ;;; :INITIAL-ELEMENT relies on another transform to deal with that
 265 ;;; kind of initialization efficiently.
 266 (deftransform make-array ((length &key element-type)
 267                           (integer &rest *))
 268   (let* ((eltype (cond ((not element-type) t)
 269                        ((not (constant-lvar-p element-type))
 270                         (give-up-ir1-transform
 271                          "ELEMENT-TYPE is not constant."))
 272                        (t
 273                         (lvar-value element-type))))
 274          (len (if (constant-lvar-p length)
 275                   (lvar-value length)
 276                   '*))
 277          (eltype-type (ir1-transform-specifier-type eltype))
 278          (result-type-spec
 279           `(simple-array
 280             ,(if (unknown-type-p eltype-type)
 281                  (give-up-ir1-transform
 282                   "ELEMENT-TYPE is an unknown type: ~S" eltype)
 283                  (sb!xc:upgraded-array-element-type eltype))
 284             (,len)))
 285          (saetp (find-if (lambda (saetp)
 286                            (csubtypep eltype-type (sb!vm:saetp-ctype saetp)))
 287                          sb!vm:*specialized-array-element-type-properties*)))
 288     (unless saetp
 289       (give-up-ir1-transform
 290        "cannot open-code creation of ~S" result-type-spec))
 291     #-sb-xc-host
 292     (unless (csubtypep (ctype-of (sb!vm:saetp-initial-element-default saetp))
 293                        eltype-type)
 294       ;; This situation arises e.g. in (MAKE-ARRAY 4 :ELEMENT-TYPE
 295       ;; '(INTEGER 1 5)) ANSI's definition of MAKE-ARRAY says "If
 296       ;; INITIAL-ELEMENT is not supplied, the consequences of later
 297       ;; reading an uninitialized element of new-array are undefined,"
 298       ;; so this could be legal code as long as the user plans to
 299       ;; write before he reads, and if he doesn't we're free to do
 300       ;; anything we like. But in case the user doesn't know to write
 301       ;; elements before he reads elements (or to read manuals before
 302       ;; he writes code:-), we'll signal a STYLE-WARNING in case he
 303       ;; didn't realize this.
 304       (compiler-style-warn "The default initial element ~S is not a ~S."
 305                            (sb!vm:saetp-initial-element-default saetp)
 306                            eltype))
 307     (let* ((n-bits-per-element (sb!vm:saetp-n-bits saetp))
 308            (typecode (sb!vm:saetp-typecode saetp))
 309            (n-pad-elements (sb!vm:saetp-n-pad-elements saetp))
 310            (padded-length-form (if (zerop n-pad-elements)
 311                                    'length
 312                                    `(+ length ,n-pad-elements)))
 313            (n-words-form
 314             (cond
 315               ((= n-bits-per-element 0) 0)
 316               ((>= n-bits-per-element sb!vm:n-word-bits)
 317                `(* ,padded-length-form
 318                  (the fixnum ; i.e., not RATIO
 319                    ,(/ n-bits-per-element sb!vm:n-word-bits))))
 320               (t
 321                (let ((n-elements-per-word (/ sb!vm:n-word-bits
 322                                              n-bits-per-element)))
 323                  (declare (type index n-elements-per-word)) ; i.e., not RATIO
 324                  `(ceiling ,padded-length-form ,n-elements-per-word))))))
 325       (values
 326        `(truly-the ,result-type-spec
 327          (allocate-vector ,typecode length ,n-words-form))
 328        '((declare (type index length)))))))
 329
 330 ;;; The list type restriction does not ensure that the result will be a
 331 ;;; multi-dimensional array. But the lack of adjustable, fill-pointer,
 332 ;;; and displaced-to keywords ensures that it will be simple.
 333 ;;;
 334 ;;; FIXME: should we generalize this transform to non-simple (though
 335 ;;; non-displaced-to) arrays, given that we have %WITH-ARRAY-DATA to
 336 ;;; deal with those? Maybe when the DEFTRANSFORM
 337 ;;; %DATA-VECTOR-AND-INDEX in the VECTOR case problem is solved? --
 338 ;;; CSR, 2002-07-01
 339 (deftransform make-array ((dims &key element-type)
 340                           (list &rest *))
 341   (unless (or (null element-type) (constant-lvar-p element-type))
 342     (give-up-ir1-transform
 343      "The element-type is not constant; cannot open code array creation."))
 344   (unless (constant-lvar-p dims)
 345     (give-up-ir1-transform
 346      "The dimension list is not constant; cannot open code array creation."))
 347   (let ((dims (lvar-value dims)))
 348     (unless (every #'integerp dims)
 349       (give-up-ir1-transform
 350        "The dimension list contains something other than an integer: ~S"
 351        dims))
 352     (if (= (length dims) 1)
 353         `(make-array ',(car dims)
 354                      ,@(when element-type
 355                          '(:element-type element-type)))
 356         (let* ((total-size (reduce #'* dims))
 357                (rank (length dims))
 358                (spec `(simple-array
 359                        ,(cond ((null element-type) t)
 360                               ((and (constant-lvar-p element-type)
 361                                     (ir1-transform-specifier-type
 362                                      (lvar-value element-type)))
 363                                (sb!xc:upgraded-array-element-type
 364                                 (lvar-value element-type)))
 365                               (t '*))
 366                            ,(make-list rank :initial-element '*))))
 367           `(let ((header (make-array-header sb!vm:simple-array-widetag ,rank)))
 368              (setf (%array-fill-pointer header) ,total-size)
 369              (setf (%array-fill-pointer-p header) nil)
 370              (setf (%array-available-elements header) ,total-size)
 371              (setf (%array-data-vector header)
 372                    (make-array ,total-size
 373                                ,@(when element-type
 374                                    '(:element-type element-type))))
 375              (setf (%array-displaced-p header) nil)
 376              ,@(let ((axis -1))
 377                  (mapcar (lambda (dim)
 378                            `(setf (%array-dimension header ,(incf axis))
 379                                   ,dim))
 380                          dims))
 381              (truly-the ,spec header))))))
 382 \f
 383 ;;;; miscellaneous properties of arrays
 384
 385 ;;; Transforms for various array properties. If the property is know
 386 ;;; at compile time because of a type spec, use that constant value.
 387
 388 ;;; Most of this logic may end up belonging in code/late-type.lisp;
 389 ;;; however, here we also need the -OR-GIVE-UP for the transforms, and
 390 ;;; maybe this is just too sloppy for actual type logic.  -- CSR,
 391 ;;; 2004-02-18
 392 (defun array-type-dimensions-or-give-up (type)
 393   (typecase type
 394     (array-type (array-type-dimensions type))
 395     (union-type
 396      (let ((types (union-type-types type)))
 397        ;; there are at least two types, right?
 398        (aver (> (length types) 1))
 399        (let ((result (array-type-dimensions-or-give-up (car types))))
 400          (dolist (type (cdr types) result)
 401            (unless (equal (array-type-dimensions-or-give-up type) result)
 402              (give-up-ir1-transform))))))
 403     ;; FIXME: intersection type [e.g. (and (array * (*)) (satisfies foo)) ]
 404     (t (give-up-ir1-transform))))
 405
 406 (defun conservative-array-type-complexp (type)
 407   (typecase type
 408     (array-type (array-type-complexp type))
 409     (union-type
 410      (let ((types (union-type-types type)))
 411        (aver (> (length types) 1))
 412        (let ((result (conservative-array-type-complexp (car types))))
 413          (dolist (type (cdr types) result)
 414            (unless (eq (conservative-array-type-complexp type) result)
 415              (return-from conservative-array-type-complexp :maybe))))))
 416     ;; FIXME: intersection type
 417     (t :maybe)))
 418
 419 ;;; If we can tell the rank from the type info, use it instead.
 420 (deftransform array-rank ((array))
 421   (let ((array-type (lvar-type array)))
 422     (let ((dims (array-type-dimensions-or-give-up array-type)))
 423       (if (not (listp dims))
 424           (give-up-ir1-transform
 425            "The array rank is not known at compile time: ~S"
 426            dims)
 427           (length dims)))))
 428
 429 ;;; If we know the dimensions at compile time, just use it. Otherwise,
 430 ;;; if we can tell that the axis is in bounds, convert to
 431 ;;; %ARRAY-DIMENSION (which just indirects the array header) or length
 432 ;;; (if it's simple and a vector).
 433 (deftransform array-dimension ((array axis)
 434                                (array index))
 435   (unless (constant-lvar-p axis)
 436     (give-up-ir1-transform "The axis is not constant."))
 437   (let ((array-type (lvar-type array))
 438         (axis (lvar-value axis)))
 439     (let ((dims (array-type-dimensions-or-give-up array-type)))
 440       (unless (listp dims)
 441         (give-up-ir1-transform
 442          "The array dimensions are unknown; must call ARRAY-DIMENSION at runtime."))
 443       (unless (> (length dims) axis)
 444         (abort-ir1-transform "The array has dimensions ~S, ~W is too large."
 445                              dims
 446                              axis))
 447       (let ((dim (nth axis dims)))
 448         (cond ((integerp dim)
 449                dim)
 450               ((= (length dims) 1)
 451                (ecase (conservative-array-type-complexp array-type)
 452                  ((t)
 453                   '(%array-dimension array 0))
 454                  ((nil)
 455                   '(length array))
 456                  ((:maybe)
 457                   (give-up-ir1-transform
 458                    "can't tell whether array is simple"))))
 459               (t
 460                '(%array-dimension array axis)))))))
 461
 462 ;;; If the length has been declared and it's simple, just return it.
 463 (deftransform length ((vector)
 464                       ((simple-array * (*))))
 465   (let ((type (lvar-type vector)))
 466     (let ((dims (array-type-dimensions-or-give-up type)))
 467       (unless (and (listp dims) (integerp (car dims)))
 468         (give-up-ir1-transform
 469          "Vector length is unknown, must call LENGTH at runtime."))
 470       (car dims))))
 471
 472 ;;; All vectors can get their length by using VECTOR-LENGTH. If it's
 473 ;;; simple, it will extract the length slot from the vector. It it's
 474 ;;; complex, it will extract the fill pointer slot from the array
 475 ;;; header.
 476 (deftransform length ((vector) (vector))
 477   '(vector-length vector))
 478
 479 ;;; If a simple array with known dimensions, then VECTOR-LENGTH is a
 480 ;;; compile-time constant.
 481 (deftransform vector-length ((vector))
 482   (let ((vtype (lvar-type vector)))
 483     (let ((dim (first (array-type-dimensions-or-give-up vtype))))
 484       (when (eq dim '*)
 485         (give-up-ir1-transform))
 486       (when (conservative-array-type-complexp vtype)
 487         (give-up-ir1-transform))
 488       dim)))
 489
 490 ;;; Again, if we can tell the results from the type, just use it.
 491 ;;; Otherwise, if we know the rank, convert into a computation based
 492 ;;; on array-dimension. We can wrap a TRULY-THE INDEX around the
 493 ;;; multiplications because we know that the total size must be an
 494 ;;; INDEX.
 495 (deftransform array-total-size ((array)
 496                                 (array))
 497   (let ((array-type (lvar-type array)))
 498     (let ((dims (array-type-dimensions-or-give-up array-type)))
 499       (unless (listp dims)
 500         (give-up-ir1-transform "can't tell the rank at compile time"))
 501       (if (member '* dims)
 502           (do ((form 1 `(truly-the index
 503                                    (* (array-dimension array ,i) ,form)))
 504                (i 0 (1+ i)))
 505               ((= i (length dims)) form))
 506           (reduce #'* dims)))))
 507
 508 ;;; Only complex vectors have fill pointers.
 509 (deftransform array-has-fill-pointer-p ((array))
 510   (let ((array-type (lvar-type array)))
 511     (let ((dims (array-type-dimensions-or-give-up array-type)))
 512       (if (and (listp dims) (not (= (length dims) 1)))
 513           nil
 514           (ecase (conservative-array-type-complexp array-type)
 515             ((t)
 516              t)
 517             ((nil)
 518              nil)
 519             ((:maybe)
 520              (give-up-ir1-transform
 521               "The array type is ambiguous; must call ~
 522               ARRAY-HAS-FILL-POINTER-P at runtime.")))))))
 523
 524 ;;; Primitive used to verify indices into arrays. If we can tell at
 525 ;;; compile-time or we are generating unsafe code, don't bother with
 526 ;;; the VOP.
 527 (deftransform %check-bound ((array dimension index) * * :node node)
 528   (cond ((policy node (and (> speed safety) (= safety 0)))
 529          'index)
 530         ((not (constant-lvar-p dimension))
 531          (give-up-ir1-transform))
 532         (t
 533          (let ((dim (lvar-value dimension)))
 534            `(the (integer 0 (,dim)) index)))))
 535 \f
 536 ;;;; WITH-ARRAY-DATA
 537
 538 ;;; This checks to see whether the array is simple and the start and
 539 ;;; end are in bounds. If so, it proceeds with those values.
 540 ;;; Otherwise, it calls %WITH-ARRAY-DATA. Note that %WITH-ARRAY-DATA
 541 ;;; may be further optimized.
 542 ;;;
 543 ;;; Given any ARRAY, bind DATA-VAR to the array's data vector and
 544 ;;; START-VAR and END-VAR to the start and end of the designated
 545 ;;; portion of the data vector. SVALUE and EVALUE are any start and
 546 ;;; end specified to the original operation, and are factored into the
 547 ;;; bindings of START-VAR and END-VAR. OFFSET-VAR is the cumulative
 548 ;;; offset of all displacements encountered, and does not include
 549 ;;; SVALUE.
 550 ;;;
 551 ;;; When FORCE-INLINE is set, the underlying %WITH-ARRAY-DATA form is
 552 ;;; forced to be inline, overriding the ordinary judgment of the
 553 ;;; %WITH-ARRAY-DATA DEFTRANSFORMs. Ordinarily the DEFTRANSFORMs are
 554 ;;; fairly picky about their arguments, figuring that if you haven't
 555 ;;; bothered to get all your ducks in a row, you probably don't care
 556 ;;; that much about speed anyway! But in some cases it makes sense to
 557 ;;; do type testing inside %WITH-ARRAY-DATA instead of outside, and
 558 ;;; the DEFTRANSFORM can't tell that that's going on, so it can make
 559 ;;; sense to use FORCE-INLINE option in that case.
 560 (def!macro with-array-data (((data-var array &key offset-var)
 561                              (start-var &optional (svalue 0))
 562                              (end-var &optional (evalue nil))
 563                              &key force-inline)
 564                             &body forms)
 565   (once-only ((n-array array)
 566               (n-svalue `(the index ,svalue))
 567               (n-evalue `(the (or index null) ,evalue)))
 568     `(multiple-value-bind (,data-var
 569                            ,start-var
 570                            ,end-var
 571                            ,@(when offset-var `(,offset-var)))
 572          (if (not (array-header-p ,n-array))
 573              (let ((,n-array ,n-array))
 574                (declare (type (simple-array * (*)) ,n-array))
 575                ,(once-only ((n-len `(length ,n-array))
 576                             (n-end `(or ,n-evalue ,n-len)))
 577                   `(if (<= ,n-svalue ,n-end ,n-len)
 578                        ;; success
 579                        (values ,n-array ,n-svalue ,n-end 0)
 580                        (failed-%with-array-data ,n-array
 581                                                 ,n-svalue
 582                                                 ,n-evalue))))
 583              (,(if force-inline '%with-array-data-macro '%with-array-data)
 584               ,n-array ,n-svalue ,n-evalue))
 585        ,@forms)))
 586
 587 ;;; This is the fundamental definition of %WITH-ARRAY-DATA, for use in
 588 ;;; DEFTRANSFORMs and DEFUNs.
 589 (def!macro %with-array-data-macro (array
 590                                    start
 591                                    end
 592                                    &key
 593                                    (element-type '*)
 594                                    unsafe?
 595                                    fail-inline?)
 596   (with-unique-names (size defaulted-end data cumulative-offset)
 597     `(let* ((,size (array-total-size ,array))
 598             (,defaulted-end
 599               (cond (,end
 600                      (unless (or ,unsafe? (<= ,end ,size))
 601                        ,(if fail-inline?
 602                             `(error 'bounding-indices-bad-error
 603                               :datum (cons ,start ,end)
 604                               :expected-type `(cons (integer 0 ,',size)
 605                                                     (integer ,',start ,',size))
 606                               :object ,array)
 607                             `(failed-%with-array-data ,array ,start ,end)))
 608                      ,end)
 609                     (t ,size))))
 610        (unless (or ,unsafe? (<= ,start ,defaulted-end))
 611          ,(if fail-inline?
 612               `(error 'bounding-indices-bad-error
 613                 :datum (cons ,start ,end)
 614                 :expected-type `(cons (integer 0 ,',size)
 615                                       (integer ,',start ,',size))
 616                 :object ,array)
 617               `(failed-%with-array-data ,array ,start ,end)))
 618        (do ((,data ,array (%array-data-vector ,data))
 619             (,cumulative-offset 0
 620                                 (+ ,cumulative-offset
 621                                    (%array-displacement ,data))))
 622            ((not (array-header-p ,data))
 623             (values (the (simple-array ,element-type 1) ,data)
 624                     (the index (+ ,cumulative-offset ,start))
 625                     (the index (+ ,cumulative-offset ,defaulted-end))
 626                     (the index ,cumulative-offset)))
 627          (declare (type index ,cumulative-offset))))))
 628
 629 (deftransform %with-array-data ((array start end)
 630                                 ;; It might very well be reasonable to
 631                                 ;; allow general ARRAY here, I just
 632                                 ;; haven't tried to understand the
 633                                 ;; performance issues involved. --
 634                                 ;; WHN, and also CSR 2002-05-26
 635                                 ((or vector simple-array) index (or index null))
 636                                 *
 637                                 :important t
 638                                 :node node
 639                                 :policy (> speed space))
 640   "inline non-SIMPLE-vector-handling logic"
 641   (let ((element-type (upgraded-element-type-specifier-or-give-up array)))
 642     `(%with-array-data-macro array start end
 643                              :unsafe? ,(policy node (= safety 0))
 644                              :element-type ,element-type)))
 645 \f
 646 ;;;; array accessors
 647
 648 ;;; We convert all typed array accessors into AREF and %ASET with type
 649 ;;; assertions on the array.
 650 (macrolet ((define-frob (reffer setter type)
 651              `(progn
 652                 (define-source-transform ,reffer (a &rest i)
 653                   `(aref (the ,',type ,a) ,@i))
 654                 (define-source-transform ,setter (a &rest i)
 655                   `(%aset (the ,',type ,a) ,@i)))))
 656   (define-frob sbit %sbitset (simple-array bit))
 657   (define-frob bit %bitset (array bit)))
 658 (macrolet ((define-frob (reffer setter type)
 659              `(progn
 660                 (define-source-transform ,reffer (a i)
 661                   `(aref (the ,',type ,a) ,i))
 662                 (define-source-transform ,setter (a i v)
 663                   `(%aset (the ,',type ,a) ,i ,v)))))
 664   (define-frob svref %svset simple-vector)
 665   (define-frob schar %scharset simple-string)
 666   (define-frob char %charset string))
 667
 668 (macrolet (;; This is a handy macro for computing the row-major index
 669            ;; given a set of indices. We wrap each index with a call
 670            ;; to %CHECK-BOUND to ensure that everything works out
 671            ;; correctly. We can wrap all the interior arithmetic with
 672            ;; TRULY-THE INDEX because we know the the resultant
 673            ;; row-major index must be an index.
 674            (with-row-major-index ((array indices index &optional new-value)
 675                                   &rest body)
 676              `(let (n-indices dims)
 677                 (dotimes (i (length ,indices))
 678                   (push (make-symbol (format nil "INDEX-~D" i)) n-indices)
 679                   (push (make-symbol (format nil "DIM-~D" i)) dims))
 680                 (setf n-indices (nreverse n-indices))
 681                 (setf dims (nreverse dims))
 682                 `(lambda (,',array ,@n-indices
 683                                    ,@',(when new-value (list new-value)))
 684                    (let* (,@(let ((,index -1))
 685                               (mapcar (lambda (name)
 686                                         `(,name (array-dimension
 687                                                  ,',array
 688                                                  ,(incf ,index))))
 689                                       dims))
 690                             (,',index
 691                              ,(if (null dims)
 692                                   0
 693                                 (do* ((dims dims (cdr dims))
 694                                       (indices n-indices (cdr indices))
 695                                       (last-dim nil (car dims))
 696                                       (form `(%check-bound ,',array
 697                                                            ,(car dims)
 698                                                            ,(car indices))
 699                                             `(truly-the
 700                                               index
 701                                               (+ (truly-the index
 702                                                             (* ,form
 703                                                                ,last-dim))
 704                                                  (%check-bound
 705                                                   ,',array
 706                                                   ,(car dims)
 707                                                   ,(car indices))))))
 708                                     ((null (cdr dims)) form)))))
 709                      ,',@body)))))
 710
 711   ;; Just return the index after computing it.
 712   (deftransform array-row-major-index ((array &rest indices))
 713     (with-row-major-index (array indices index)
 714       index))
 715
 716   ;; Convert AREF and %ASET into a HAIRY-DATA-VECTOR-REF (or
 717   ;; HAIRY-DATA-VECTOR-SET) with the set of indices replaced with the an
 718   ;; expression for the row major index.
 719   (deftransform aref ((array &rest indices))
 720     (with-row-major-index (array indices index)
 721       (hairy-data-vector-ref array index)))
 722   (deftransform %aset ((array &rest stuff))
 723     (let ((indices (butlast stuff)))
 724       (with-row-major-index (array indices index new-value)
 725         (hairy-data-vector-set array index new-value)))))
 726
 727 ;;; Just convert into a HAIRY-DATA-VECTOR-REF (or
 728 ;;; HAIRY-DATA-VECTOR-SET) after checking that the index is inside the
 729 ;;; array total size.
 730 (deftransform row-major-aref ((array index))
 731   `(hairy-data-vector-ref array
 732                           (%check-bound array (array-total-size array) index)))
 733 (deftransform %set-row-major-aref ((array index new-value))
 734   `(hairy-data-vector-set array
 735                           (%check-bound array (array-total-size array) index)
 736                           new-value))
 737 \f
 738 ;;;; bit-vector array operation canonicalization
 739 ;;;;
 740 ;;;; We convert all bit-vector operations to have the result array
 741 ;;;; specified. This allows any result allocation to be open-coded,
 742 ;;;; and eliminates the need for any VM-dependent transforms to handle
 743 ;;;; these cases.
 744
 745 (macrolet ((def (fun)
 746              `(progn
 747                (deftransform ,fun ((bit-array-1 bit-array-2
 748                                                 &optional result-bit-array)
 749                                    (bit-vector bit-vector &optional null) *
 750                                    :policy (>= speed space))
 751                  `(,',fun bit-array-1 bit-array-2
 752                    (make-array (length bit-array-1) :element-type 'bit)))
 753                ;; If result is T, make it the first arg.
 754                (deftransform ,fun ((bit-array-1 bit-array-2 result-bit-array)
 755                                    (bit-vector bit-vector (eql t)) *)
 756                  `(,',fun bit-array-1 bit-array-2 bit-array-1)))))
 757   (def bit-and)
 758   (def bit-ior)
 759   (def bit-xor)
 760   (def bit-eqv)
 761   (def bit-nand)
 762   (def bit-nor)
 763   (def bit-andc1)
 764   (def bit-andc2)
 765   (def bit-orc1)
 766   (def bit-orc2))
 767
 768 ;;; Similar for BIT-NOT, but there is only one arg...
 769 (deftransform bit-not ((bit-array-1 &optional result-bit-array)
 770                        (bit-vector &optional null) *
 771                        :policy (>= speed space))
 772   '(bit-not bit-array-1
 773             (make-array (length bit-array-1) :element-type 'bit)))
 774 (deftransform bit-not ((bit-array-1 result-bit-array)
 775                        (bit-vector (eql t)))
 776   '(bit-not bit-array-1 bit-array-1))
 777 \f
 778 ;;; Pick off some constant cases.
 779 (defoptimizer (array-header-p derive-type) ((array))
 780   (let ((type (lvar-type array)))
 781     (cond ((not (array-type-p type))
 782            ;; FIXME: use analogue of ARRAY-TYPE-DIMENSIONS-OR-GIVE-UP
 783            nil)
 784           (t
 785            (let ((dims (array-type-dimensions type)))
 786              (cond ((csubtypep type (specifier-type '(simple-array * (*))))
 787                     ;; no array header
 788                     (specifier-type 'null))
 789                    ((and (listp dims) (/= (length dims) 1))
 790                     ;; multi-dimensional array, will have a header
 791                     (specifier-type '(eql t)))
 792                    (t
 793                     nil)))))))