src/compiler/array-tran.lisp

   1 ;;;; array-specific optimizers and transforms
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; utilities for optimizing array operations
  15
  16 ;;; Return UPGRADED-ARRAY-ELEMENT-TYPE for LVAR, or do
  17 ;;; GIVE-UP-IR1-TRANSFORM if the upgraded element type can't be
  18 ;;; determined.
  19 (defun upgraded-element-type-specifier-or-give-up (lvar)
  20   (let* ((element-ctype (extract-upgraded-element-type lvar))
  21          (element-type-specifier (type-specifier element-ctype)))
  22     (if (eq element-type-specifier '*)
  23         (give-up-ir1-transform
  24          "upgraded array element type not known at compile time")
  25         element-type-specifier)))
  26
  27 ;;; Array access functions return an object from the array, hence its
  28 ;;; type is going to be the array upgraded element type.
  29 (defun extract-upgraded-element-type (array)
  30   (let ((type (lvar-type array)))
  31     ;; Note that this IF mightn't be satisfied even if the runtime
  32     ;; value is known to be a subtype of some specialized ARRAY, because
  33     ;; we can have values declared e.g. (AND SIMPLE-VECTOR UNKNOWN-TYPE),
  34     ;; which are represented in the compiler as INTERSECTION-TYPE, not
  35     ;; array type.
  36     (if (array-type-p type)
  37         (array-type-specialized-element-type type)
  38         ;; KLUDGE: there is no good answer here, but at least
  39         ;; *wild-type* won't cause HAIRY-DATA-VECTOR-{REF,SET} to be
  40         ;; erroneously optimized (see generic/vm-tran.lisp) -- CSR,
  41         ;; 2002-08-21
  42         *wild-type*)))
  43
  44 (defun extract-declared-element-type (array)
  45   (let ((type (lvar-type array)))
  46     (if (array-type-p type)
  47         (array-type-element-type type)
  48         *wild-type*)))
  49
  50 ;;; The ``new-value'' for array setters must fit in the array, and the
  51 ;;; return type is going to be the same as the new-value for SETF
  52 ;;; functions.
  53 (defun assert-new-value-type (new-value array)
  54   (let ((type (lvar-type array)))
  55     (when (array-type-p type)
  56       (assert-lvar-type
  57        new-value
  58        (array-type-specialized-element-type type)
  59        (lexenv-policy (node-lexenv (lvar-dest new-value))))))
  60   (lvar-type new-value))
  61
  62 (defun assert-array-complex (array)
  63   (assert-lvar-type
  64    array
  65    (make-array-type :complexp t
  66                     :element-type *wild-type*)
  67    (lexenv-policy (node-lexenv (lvar-dest array))))
  68   nil)
  69
  70 ;;; Return true if ARG is NIL, or is a constant-lvar whose
  71 ;;; value is NIL, false otherwise.
  72 (defun unsupplied-or-nil (arg)
  73   (declare (type (or lvar null) arg))
  74   (or (not arg)
  75       (and (constant-lvar-p arg)
  76            (not (lvar-value arg)))))
  77 \f
  78 ;;;; DERIVE-TYPE optimizers
  79
  80 ;;; Array operations that use a specific number of indices implicitly
  81 ;;; assert that the array is of that rank.
  82 (defun assert-array-rank (array rank)
  83   (assert-lvar-type
  84    array
  85    (specifier-type `(array * ,(make-list rank :initial-element '*)))
  86    (lexenv-policy (node-lexenv (lvar-dest array)))))
  87
  88 (defoptimizer (array-in-bounds-p derive-type) ((array &rest indices))
  89   (assert-array-rank array (length indices))
  90   *universal-type*)
  91
  92 (defoptimizer (aref derive-type) ((array &rest indices) node)
  93   (assert-array-rank array (length indices))
  94   (extract-upgraded-element-type array))
  95
  96 (defoptimizer (%aset derive-type) ((array &rest stuff))
  97   (assert-array-rank array (1- (length stuff)))
  98   (assert-new-value-type (car (last stuff)) array))
  99
 100 (defoptimizer (hairy-data-vector-ref derive-type) ((array index))
 101   (extract-upgraded-element-type array))
 102 (defoptimizer (data-vector-ref derive-type) ((array index))
 103   (extract-upgraded-element-type array))
 104
 105 (defoptimizer (data-vector-set derive-type) ((array index new-value))
 106   (assert-new-value-type new-value array))
 107 (defoptimizer (hairy-data-vector-set derive-type) ((array index new-value))
 108   (assert-new-value-type new-value array))
 109
 110 ;;; Figure out the type of the data vector if we know the argument
 111 ;;; element type.
 112 (defoptimizer (%with-array-data derive-type) ((array start end))
 113   (let ((atype (lvar-type array)))
 114     (when (array-type-p atype)
 115       (specifier-type
 116        `(simple-array ,(type-specifier
 117                        (array-type-specialized-element-type atype))
 118                      (*))))))
 119
 120 (defoptimizer (array-row-major-index derive-type) ((array &rest indices))
 121   (assert-array-rank array (length indices))
 122   *universal-type*)
 123
 124 (defoptimizer (row-major-aref derive-type) ((array index))
 125   (extract-upgraded-element-type array))
 126
 127 (defoptimizer (%set-row-major-aref derive-type) ((array index new-value))
 128   (assert-new-value-type new-value array))
 129
 130 (defoptimizer (make-array derive-type)
 131               ((dims &key initial-element element-type initial-contents
 132                 adjustable fill-pointer displaced-index-offset displaced-to))
 133   (let ((simple (and (unsupplied-or-nil adjustable)
 134                      (unsupplied-or-nil displaced-to)
 135                      (unsupplied-or-nil fill-pointer))))
 136     (or (careful-specifier-type
 137          `(,(if simple 'simple-array 'array)
 138             ,(cond ((not element-type) t)
 139                    ((constant-lvar-p element-type)
 140                     (let ((ctype (careful-specifier-type
 141                                   (lvar-value element-type))))
 142                       (cond
 143                         ((or (null ctype) (unknown-type-p ctype)) '*)
 144                         (t (sb!xc:upgraded-array-element-type
 145                             (lvar-value element-type))))))
 146                    (t
 147                     '*))
 148             ,(cond ((constant-lvar-p dims)
 149                     (let* ((val (lvar-value dims))
 150                            (cdims (if (listp val) val (list val))))
 151                       (if simple
 152                           cdims
 153                           (length cdims))))
 154                    ((csubtypep (lvar-type dims)
 155                                (specifier-type 'integer))
 156                     '(*))
 157                    (t
 158                     '*))))
 159         (specifier-type 'array))))
 160
 161 ;;; Complex array operations should assert that their array argument
 162 ;;; is complex.  In SBCL, vectors with fill-pointers are complex.
 163 (defoptimizer (fill-pointer derive-type) ((vector))
 164   (assert-array-complex vector))
 165 (defoptimizer (%set-fill-pointer derive-type) ((vector index))
 166   (declare (ignorable index))
 167   (assert-array-complex vector))
 168
 169 (defoptimizer (vector-push derive-type) ((object vector))
 170   (declare (ignorable object))
 171   (assert-array-complex vector))
 172 (defoptimizer (vector-push-extend derive-type)
 173     ((object vector &optional index))
 174   (declare (ignorable object index))
 175   (assert-array-complex vector))
 176 (defoptimizer (vector-pop derive-type) ((vector))
 177   (assert-array-complex vector))
 178 \f
 179 ;;;; constructors
 180
 181 ;;; Convert VECTOR into a MAKE-ARRAY followed by SETFs of all the
 182 ;;; elements.
 183 (define-source-transform vector (&rest elements)
 184   (let ((len (length elements))
 185         (n -1))
 186     (once-only ((n-vec `(make-array ,len)))
 187       `(progn
 188          ,@(mapcar (lambda (el)
 189                      (once-only ((n-val el))
 190                        `(locally (declare (optimize (safety 0)))
 191                                  (setf (svref ,n-vec ,(incf n))
 192                                        ,n-val))))
 193                    elements)
 194          ,n-vec))))
 195
 196 ;;; Just convert it into a MAKE-ARRAY.
 197 (deftransform make-string ((length &key
 198                                    (element-type 'character)
 199                                    (initial-element
 200                                     #.*default-init-char-form*)))
 201   `(the simple-string (make-array (the index length)
 202                        :element-type element-type
 203                        ,@(when initial-element
 204                            '(:initial-element initial-element)))))
 205
 206 (deftransform make-array ((dims &key initial-element element-type
 207                                      adjustable fill-pointer)
 208                           (t &rest *))
 209   (when (null initial-element)
 210     (give-up-ir1-transform))
 211   (let* ((eltype (cond ((not element-type) t)
 212                        ((not (constant-lvar-p element-type))
 213                         (give-up-ir1-transform
 214                          "ELEMENT-TYPE is not constant."))
 215                        (t
 216                         (lvar-value element-type))))
 217          (eltype-type (ir1-transform-specifier-type eltype))
 218          (saetp (find-if (lambda (saetp)
 219                            (csubtypep eltype-type (sb!vm:saetp-ctype saetp)))
 220                          sb!vm:*specialized-array-element-type-properties*))
 221          (creation-form `(make-array dims
 222                           :element-type ',(type-specifier (sb!vm:saetp-ctype saetp))
 223                           ,@(when fill-pointer
 224                                   '(:fill-pointer fill-pointer))
 225                           ,@(when adjustable
 226                                   '(:adjustable adjustable)))))
 227
 228     (unless saetp
 229       (give-up-ir1-transform "ELEMENT-TYPE not found in *SAETP*: ~S" eltype))
 230
 231     (cond ((and (constant-lvar-p initial-element)
 232                 (eql (lvar-value initial-element)
 233                      (sb!vm:saetp-initial-element-default saetp)))
 234            creation-form)
 235           (t
 236            ;; error checking for target, disabled on the host because
 237            ;; (CTYPE-OF #\Null) is not possible.
 238            #-sb-xc-host
 239            (when (constant-lvar-p initial-element)
 240              (let ((value (lvar-value initial-element)))
 241                (cond
 242                  ((not (ctypep value (sb!vm:saetp-ctype saetp)))
 243                   ;; this case will cause an error at runtime, so we'd
 244                   ;; better WARN about it now.
 245                   (warn 'array-initial-element-mismatch
 246                         :format-control "~@<~S is not a ~S (which is the ~
 247                                          ~S of ~S).~@:>"
 248                         :format-arguments
 249                         (list
 250                          value
 251                          (type-specifier (sb!vm:saetp-ctype saetp))
 252                          'upgraded-array-element-type
 253                          eltype)))
 254                  ((not (ctypep value eltype-type))
 255                   ;; this case will not cause an error at runtime, but
 256                   ;; it's still worth STYLE-WARNing about.
 257                   (compiler-style-warn "~S is not a ~S."
 258                                        value eltype)))))
 259            `(let ((array ,creation-form))
 260              (multiple-value-bind (vector)
 261                  (%data-vector-and-index array 0)
 262                (fill vector initial-element))
 263              array)))))
 264
 265 ;;; The integer type restriction on the length ensures that it will be
 266 ;;; a vector. The lack of :ADJUSTABLE, :FILL-POINTER, and
 267 ;;; :DISPLACED-TO keywords ensures that it will be simple; the lack of
 268 ;;; :INITIAL-ELEMENT relies on another transform to deal with that
 269 ;;; kind of initialization efficiently.
 270 (deftransform make-array ((length &key element-type)
 271                           (integer &rest *))
 272   (let* ((eltype (cond ((not element-type) t)
 273                        ((not (constant-lvar-p element-type))
 274                         (give-up-ir1-transform
 275                          "ELEMENT-TYPE is not constant."))
 276                        (t
 277                         (lvar-value element-type))))
 278          (len (if (constant-lvar-p length)
 279                   (lvar-value length)
 280                   '*))
 281          (eltype-type (ir1-transform-specifier-type eltype))
 282          (result-type-spec
 283           `(simple-array
 284             ,(if (unknown-type-p eltype-type)
 285                  (give-up-ir1-transform
 286                   "ELEMENT-TYPE is an unknown type: ~S" eltype)
 287                  (sb!xc:upgraded-array-element-type eltype))
 288             (,len)))
 289          (saetp (find-if (lambda (saetp)
 290                            (csubtypep eltype-type (sb!vm:saetp-ctype saetp)))
 291                          sb!vm:*specialized-array-element-type-properties*)))
 292     (unless saetp
 293       (give-up-ir1-transform
 294        "cannot open-code creation of ~S" result-type-spec))
 295     #-sb-xc-host
 296     (unless (csubtypep (ctype-of (sb!vm:saetp-initial-element-default saetp))
 297                        eltype-type)
 298       ;; This situation arises e.g. in (MAKE-ARRAY 4 :ELEMENT-TYPE
 299       ;; '(INTEGER 1 5)) ANSI's definition of MAKE-ARRAY says "If
 300       ;; INITIAL-ELEMENT is not supplied, the consequences of later
 301       ;; reading an uninitialized element of new-array are undefined,"
 302       ;; so this could be legal code as long as the user plans to
 303       ;; write before he reads, and if he doesn't we're free to do
 304       ;; anything we like. But in case the user doesn't know to write
 305       ;; elements before he reads elements (or to read manuals before
 306       ;; he writes code:-), we'll signal a STYLE-WARNING in case he
 307       ;; didn't realize this.
 308       (compiler-style-warn "The default initial element ~S is not a ~S."
 309                            (sb!vm:saetp-initial-element-default saetp)
 310                            eltype))
 311     (let* ((n-bits-per-element (sb!vm:saetp-n-bits saetp))
 312            (typecode (sb!vm:saetp-typecode saetp))
 313            (n-pad-elements (sb!vm:saetp-n-pad-elements saetp))
 314            (padded-length-form (if (zerop n-pad-elements)
 315                                    'length
 316                                    `(+ length ,n-pad-elements)))
 317            (n-words-form
 318             (cond
 319               ((= n-bits-per-element 0) 0)
 320               ((>= n-bits-per-element sb!vm:n-word-bits)
 321                `(* ,padded-length-form
 322                  (the fixnum ; i.e., not RATIO
 323                    ,(/ n-bits-per-element sb!vm:n-word-bits))))
 324               (t
 325                (let ((n-elements-per-word (/ sb!vm:n-word-bits
 326                                              n-bits-per-element)))
 327                  (declare (type index n-elements-per-word)) ; i.e., not RATIO
 328                  `(ceiling ,padded-length-form ,n-elements-per-word))))))
 329       (values
 330        `(truly-the ,result-type-spec
 331          (allocate-vector ,typecode length ,n-words-form))
 332        '((declare (type index length)))))))
 333
 334 ;;; The list type restriction does not ensure that the result will be a
 335 ;;; multi-dimensional array. But the lack of adjustable, fill-pointer,
 336 ;;; and displaced-to keywords ensures that it will be simple.
 337 ;;;
 338 ;;; FIXME: should we generalize this transform to non-simple (though
 339 ;;; non-displaced-to) arrays, given that we have %WITH-ARRAY-DATA to
 340 ;;; deal with those? Maybe when the DEFTRANSFORM
 341 ;;; %DATA-VECTOR-AND-INDEX in the VECTOR case problem is solved? --
 342 ;;; CSR, 2002-07-01
 343 (deftransform make-array ((dims &key element-type)
 344                           (list &rest *))
 345   (unless (or (null element-type) (constant-lvar-p element-type))
 346     (give-up-ir1-transform
 347      "The element-type is not constant; cannot open code array creation."))
 348   (unless (constant-lvar-p dims)
 349     (give-up-ir1-transform
 350      "The dimension list is not constant; cannot open code array creation."))
 351   (let ((dims (lvar-value dims)))
 352     (unless (every #'integerp dims)
 353       (give-up-ir1-transform
 354        "The dimension list contains something other than an integer: ~S"
 355        dims))
 356     (if (= (length dims) 1)
 357         `(make-array ',(car dims)
 358                      ,@(when element-type
 359                          '(:element-type element-type)))
 360         (let* ((total-size (reduce #'* dims))
 361                (rank (length dims))
 362                (spec `(simple-array
 363                        ,(cond ((null element-type) t)
 364                               ((and (constant-lvar-p element-type)
 365                                     (ir1-transform-specifier-type
 366                                      (lvar-value element-type)))
 367                                (sb!xc:upgraded-array-element-type
 368                                 (lvar-value element-type)))
 369                               (t '*))
 370                            ,(make-list rank :initial-element '*))))
 371           `(let ((header (make-array-header sb!vm:simple-array-widetag ,rank)))
 372              (setf (%array-fill-pointer header) ,total-size)
 373              (setf (%array-fill-pointer-p header) nil)
 374              (setf (%array-available-elements header) ,total-size)
 375              (setf (%array-data-vector header)
 376                    (make-array ,total-size
 377                                ,@(when element-type
 378                                    '(:element-type element-type))))
 379              (setf (%array-displaced-p header) nil)
 380              ,@(let ((axis -1))
 381                  (mapcar (lambda (dim)
 382                            `(setf (%array-dimension header ,(incf axis))
 383                                   ,dim))
 384                          dims))
 385              (truly-the ,spec header))))))
 386 \f
 387 ;;;; miscellaneous properties of arrays
 388
 389 ;;; Transforms for various array properties. If the property is know
 390 ;;; at compile time because of a type spec, use that constant value.
 391
 392 ;;; Most of this logic may end up belonging in code/late-type.lisp;
 393 ;;; however, here we also need the -OR-GIVE-UP for the transforms, and
 394 ;;; maybe this is just too sloppy for actual type logic.  -- CSR,
 395 ;;; 2004-02-18
 396 (defun array-type-dimensions-or-give-up (type)
 397   (typecase type
 398     (array-type (array-type-dimensions type))
 399     (union-type
 400      (let ((types (union-type-types type)))
 401        ;; there are at least two types, right?
 402        (aver (> (length types) 1))
 403        (let ((result (array-type-dimensions-or-give-up (car types))))
 404          (dolist (type (cdr types) result)
 405            (unless (equal (array-type-dimensions-or-give-up type) result)
 406              (give-up-ir1-transform))))))
 407     ;; FIXME: intersection type [e.g. (and (array * (*)) (satisfies foo)) ]
 408     (t (give-up-ir1-transform))))
 409
 410 (defun conservative-array-type-complexp (type)
 411   (typecase type
 412     (array-type (array-type-complexp type))
 413     (union-type
 414      (let ((types (union-type-types type)))
 415        (aver (> (length types) 1))
 416        (let ((result (conservative-array-type-complexp (car types))))
 417          (dolist (type (cdr types) result)
 418            (unless (eq (conservative-array-type-complexp type) result)
 419              (return-from conservative-array-type-complexp :maybe))))))
 420     ;; FIXME: intersection type
 421     (t :maybe)))
 422
 423 ;;; If we can tell the rank from the type info, use it instead.
 424 (deftransform array-rank ((array))
 425   (let ((array-type (lvar-type array)))
 426     (let ((dims (array-type-dimensions-or-give-up array-type)))
 427       (if (not (listp dims))
 428           (give-up-ir1-transform
 429            "The array rank is not known at compile time: ~S"
 430            dims)
 431           (length dims)))))
 432
 433 ;;; If we know the dimensions at compile time, just use it. Otherwise,
 434 ;;; if we can tell that the axis is in bounds, convert to
 435 ;;; %ARRAY-DIMENSION (which just indirects the array header) or length
 436 ;;; (if it's simple and a vector).
 437 (deftransform array-dimension ((array axis)
 438                                (array index))
 439   (unless (constant-lvar-p axis)
 440     (give-up-ir1-transform "The axis is not constant."))
 441   (let ((array-type (lvar-type array))
 442         (axis (lvar-value axis)))
 443     (let ((dims (array-type-dimensions-or-give-up array-type)))
 444       (unless (listp dims)
 445         (give-up-ir1-transform
 446          "The array dimensions are unknown; must call ARRAY-DIMENSION at runtime."))
 447       (unless (> (length dims) axis)
 448         (abort-ir1-transform "The array has dimensions ~S, ~W is too large."
 449                              dims
 450                              axis))
 451       (let ((dim (nth axis dims)))
 452         (cond ((integerp dim)
 453                dim)
 454               ((= (length dims) 1)
 455                (ecase (conservative-array-type-complexp array-type)
 456                  ((t)
 457                   '(%array-dimension array 0))
 458                  ((nil)
 459                   '(length array))
 460                  ((:maybe)
 461                   (give-up-ir1-transform
 462                    "can't tell whether array is simple"))))
 463               (t
 464                '(%array-dimension array axis)))))))
 465
 466 ;;; If the length has been declared and it's simple, just return it.
 467 (deftransform length ((vector)
 468                       ((simple-array * (*))))
 469   (let ((type (lvar-type vector)))
 470     (let ((dims (array-type-dimensions-or-give-up type)))
 471       (unless (and (listp dims) (integerp (car dims)))
 472         (give-up-ir1-transform
 473          "Vector length is unknown, must call LENGTH at runtime."))
 474       (car dims))))
 475
 476 ;;; All vectors can get their length by using VECTOR-LENGTH. If it's
 477 ;;; simple, it will extract the length slot from the vector. It it's
 478 ;;; complex, it will extract the fill pointer slot from the array
 479 ;;; header.
 480 (deftransform length ((vector) (vector))
 481   '(vector-length vector))
 482
 483 ;;; If a simple array with known dimensions, then VECTOR-LENGTH is a
 484 ;;; compile-time constant.
 485 (deftransform vector-length ((vector))
 486   (let ((vtype (lvar-type vector)))
 487     (let ((dim (first (array-type-dimensions-or-give-up vtype))))
 488       (when (eq dim '*)
 489         (give-up-ir1-transform))
 490       (when (conservative-array-type-complexp vtype)
 491         (give-up-ir1-transform))
 492       dim)))
 493
 494 ;;; Again, if we can tell the results from the type, just use it.
 495 ;;; Otherwise, if we know the rank, convert into a computation based
 496 ;;; on array-dimension. We can wrap a TRULY-THE INDEX around the
 497 ;;; multiplications because we know that the total size must be an
 498 ;;; INDEX.
 499 (deftransform array-total-size ((array)
 500                                 (array))
 501   (let ((array-type (lvar-type array)))
 502     (let ((dims (array-type-dimensions-or-give-up array-type)))
 503       (unless (listp dims)
 504         (give-up-ir1-transform "can't tell the rank at compile time"))
 505       (if (member '* dims)
 506           (do ((form 1 `(truly-the index
 507                                    (* (array-dimension array ,i) ,form)))
 508                (i 0 (1+ i)))
 509               ((= i (length dims)) form))
 510           (reduce #'* dims)))))
 511
 512 ;;; Only complex vectors have fill pointers.
 513 (deftransform array-has-fill-pointer-p ((array))
 514   (let ((array-type (lvar-type array)))
 515     (let ((dims (array-type-dimensions-or-give-up array-type)))
 516       (if (and (listp dims) (not (= (length dims) 1)))
 517           nil
 518           (ecase (conservative-array-type-complexp array-type)
 519             ((t)
 520              t)
 521             ((nil)
 522              nil)
 523             ((:maybe)
 524              (give-up-ir1-transform
 525               "The array type is ambiguous; must call ~
 526               ARRAY-HAS-FILL-POINTER-P at runtime.")))))))
 527
 528 ;;; Primitive used to verify indices into arrays. If we can tell at
 529 ;;; compile-time or we are generating unsafe code, don't bother with
 530 ;;; the VOP.
 531 (deftransform %check-bound ((array dimension index) * * :node node)
 532   (cond ((policy node (and (> speed safety) (= safety 0)))
 533          'index)
 534         ((not (constant-lvar-p dimension))
 535          (give-up-ir1-transform))
 536         (t
 537          (let ((dim (lvar-value dimension)))
 538            `(the (integer 0 (,dim)) index)))))
 539 \f
 540 ;;;; WITH-ARRAY-DATA
 541
 542 ;;; This checks to see whether the array is simple and the start and
 543 ;;; end are in bounds. If so, it proceeds with those values.
 544 ;;; Otherwise, it calls %WITH-ARRAY-DATA. Note that %WITH-ARRAY-DATA
 545 ;;; may be further optimized.
 546 ;;;
 547 ;;; Given any ARRAY, bind DATA-VAR to the array's data vector and
 548 ;;; START-VAR and END-VAR to the start and end of the designated
 549 ;;; portion of the data vector. SVALUE and EVALUE are any start and
 550 ;;; end specified to the original operation, and are factored into the
 551 ;;; bindings of START-VAR and END-VAR. OFFSET-VAR is the cumulative
 552 ;;; offset of all displacements encountered, and does not include
 553 ;;; SVALUE.
 554 ;;;
 555 ;;; When FORCE-INLINE is set, the underlying %WITH-ARRAY-DATA form is
 556 ;;; forced to be inline, overriding the ordinary judgment of the
 557 ;;; %WITH-ARRAY-DATA DEFTRANSFORMs. Ordinarily the DEFTRANSFORMs are
 558 ;;; fairly picky about their arguments, figuring that if you haven't
 559 ;;; bothered to get all your ducks in a row, you probably don't care
 560 ;;; that much about speed anyway! But in some cases it makes sense to
 561 ;;; do type testing inside %WITH-ARRAY-DATA instead of outside, and
 562 ;;; the DEFTRANSFORM can't tell that that's going on, so it can make
 563 ;;; sense to use FORCE-INLINE option in that case.
 564 (def!macro with-array-data (((data-var array &key offset-var)
 565                              (start-var &optional (svalue 0))
 566                              (end-var &optional (evalue nil))
 567                              &key force-inline)
 568                             &body forms)
 569   (once-only ((n-array array)
 570               (n-svalue `(the index ,svalue))
 571               (n-evalue `(the (or index null) ,evalue)))
 572     `(multiple-value-bind (,data-var
 573                            ,start-var
 574                            ,end-var
 575                            ,@(when offset-var `(,offset-var)))
 576          (if (not (array-header-p ,n-array))
 577              (let ((,n-array ,n-array))
 578                (declare (type (simple-array * (*)) ,n-array))
 579                ,(once-only ((n-len `(length ,n-array))
 580                             (n-end `(or ,n-evalue ,n-len)))
 581                   `(if (<= ,n-svalue ,n-end ,n-len)
 582                        ;; success
 583                        (values ,n-array ,n-svalue ,n-end 0)
 584                        (failed-%with-array-data ,n-array
 585                                                 ,n-svalue
 586                                                 ,n-evalue))))
 587              (,(if force-inline '%with-array-data-macro '%with-array-data)
 588               ,n-array ,n-svalue ,n-evalue))
 589        ,@forms)))
 590
 591 ;;; This is the fundamental definition of %WITH-ARRAY-DATA, for use in
 592 ;;; DEFTRANSFORMs and DEFUNs.
 593 (def!macro %with-array-data-macro (array
 594                                    start
 595                                    end
 596                                    &key
 597                                    (element-type '*)
 598                                    unsafe?
 599                                    fail-inline?)
 600   (with-unique-names (size defaulted-end data cumulative-offset)
 601     `(let* ((,size (array-total-size ,array))
 602             (,defaulted-end
 603               (cond (,end
 604                      (unless (or ,unsafe? (<= ,end ,size))
 605                        ,(if fail-inline?
 606                             `(error 'bounding-indices-bad-error
 607                               :datum (cons ,start ,end)
 608                               :expected-type `(cons (integer 0 ,',size)
 609                                                     (integer ,',start ,',size))
 610                               :object ,array)
 611                             `(failed-%with-array-data ,array ,start ,end)))
 612                      ,end)
 613                     (t ,size))))
 614        (unless (or ,unsafe? (<= ,start ,defaulted-end))
 615          ,(if fail-inline?
 616               `(error 'bounding-indices-bad-error
 617                 :datum (cons ,start ,end)
 618                 :expected-type `(cons (integer 0 ,',size)
 619                                       (integer ,',start ,',size))
 620                 :object ,array)
 621               `(failed-%with-array-data ,array ,start ,end)))
 622        (do ((,data ,array (%array-data-vector ,data))
 623             (,cumulative-offset 0
 624                                 (+ ,cumulative-offset
 625                                    (%array-displacement ,data))))
 626            ((not (array-header-p ,data))
 627             (values (the (simple-array ,element-type 1) ,data)
 628                     (the index (+ ,cumulative-offset ,start))
 629                     (the index (+ ,cumulative-offset ,defaulted-end))
 630                     (the index ,cumulative-offset)))
 631          (declare (type index ,cumulative-offset))))))
 632
 633 (deftransform %with-array-data ((array start end)
 634                                 ;; It might very well be reasonable to
 635                                 ;; allow general ARRAY here, I just
 636                                 ;; haven't tried to understand the
 637                                 ;; performance issues involved. --
 638                                 ;; WHN, and also CSR 2002-05-26
 639                                 ((or vector simple-array) index (or index null))
 640                                 *
 641                                 :important t
 642                                 :node node
 643                                 :policy (> speed space))
 644   "inline non-SIMPLE-vector-handling logic"
 645   (let ((element-type (upgraded-element-type-specifier-or-give-up array)))
 646     `(%with-array-data-macro array start end
 647                              :unsafe? ,(policy node (= safety 0))
 648                              :element-type ,element-type)))
 649 \f
 650 ;;;; array accessors
 651
 652 ;;; We convert all typed array accessors into AREF and %ASET with type
 653 ;;; assertions on the array.
 654 (macrolet ((define-frob (reffer setter type)
 655              `(progn
 656                 (define-source-transform ,reffer (a &rest i)
 657                   `(aref (the ,',type ,a) ,@i))
 658                 (define-source-transform ,setter (a &rest i)
 659                   `(%aset (the ,',type ,a) ,@i)))))
 660   (define-frob sbit %sbitset (simple-array bit))
 661   (define-frob bit %bitset (array bit)))
 662 (macrolet ((define-frob (reffer setter type)
 663              `(progn
 664                 (define-source-transform ,reffer (a i)
 665                   `(aref (the ,',type ,a) ,i))
 666                 (define-source-transform ,setter (a i v)
 667                   `(%aset (the ,',type ,a) ,i ,v)))))
 668   (define-frob svref %svset simple-vector)
 669   (define-frob schar %scharset simple-string)
 670   (define-frob char %charset string))
 671
 672 (macrolet (;; This is a handy macro for computing the row-major index
 673            ;; given a set of indices. We wrap each index with a call
 674            ;; to %CHECK-BOUND to ensure that everything works out
 675            ;; correctly. We can wrap all the interior arithmetic with
 676            ;; TRULY-THE INDEX because we know the the resultant
 677            ;; row-major index must be an index.
 678            (with-row-major-index ((array indices index &optional new-value)
 679                                   &rest body)
 680              `(let (n-indices dims)
 681                 (dotimes (i (length ,indices))
 682                   (push (make-symbol (format nil "INDEX-~D" i)) n-indices)
 683                   (push (make-symbol (format nil "DIM-~D" i)) dims))
 684                 (setf n-indices (nreverse n-indices))
 685                 (setf dims (nreverse dims))
 686                 `(lambda (,',array ,@n-indices
 687                                    ,@',(when new-value (list new-value)))
 688                    (let* (,@(let ((,index -1))
 689                               (mapcar (lambda (name)
 690                                         `(,name (array-dimension
 691                                                  ,',array
 692                                                  ,(incf ,index))))
 693                                       dims))
 694                             (,',index
 695                              ,(if (null dims)
 696                                   0
 697                                 (do* ((dims dims (cdr dims))
 698                                       (indices n-indices (cdr indices))
 699                                       (last-dim nil (car dims))
 700                                       (form `(%check-bound ,',array
 701                                                            ,(car dims)
 702                                                            ,(car indices))
 703                                             `(truly-the
 704                                               index
 705                                               (+ (truly-the index
 706                                                             (* ,form
 707                                                                ,last-dim))
 708                                                  (%check-bound
 709                                                   ,',array
 710                                                   ,(car dims)
 711                                                   ,(car indices))))))
 712                                     ((null (cdr dims)) form)))))
 713                      ,',@body)))))
 714
 715   ;; Just return the index after computing it.
 716   (deftransform array-row-major-index ((array &rest indices))
 717     (with-row-major-index (array indices index)
 718       index))
 719
 720   ;; Convert AREF and %ASET into a HAIRY-DATA-VECTOR-REF (or
 721   ;; HAIRY-DATA-VECTOR-SET) with the set of indices replaced with the an
 722   ;; expression for the row major index.
 723   (deftransform aref ((array &rest indices))
 724     (with-row-major-index (array indices index)
 725       (hairy-data-vector-ref array index)))
 726   (deftransform %aset ((array &rest stuff))
 727     (let ((indices (butlast stuff)))
 728       (with-row-major-index (array indices index new-value)
 729         (hairy-data-vector-set array index new-value)))))
 730
 731 ;;; Just convert into a HAIRY-DATA-VECTOR-REF (or
 732 ;;; HAIRY-DATA-VECTOR-SET) after checking that the index is inside the
 733 ;;; array total size.
 734 (deftransform row-major-aref ((array index))
 735   `(hairy-data-vector-ref array
 736                           (%check-bound array (array-total-size array) index)))
 737 (deftransform %set-row-major-aref ((array index new-value))
 738   `(hairy-data-vector-set array
 739                           (%check-bound array (array-total-size array) index)
 740                           new-value))
 741 \f
 742 ;;;; bit-vector array operation canonicalization
 743 ;;;;
 744 ;;;; We convert all bit-vector operations to have the result array
 745 ;;;; specified. This allows any result allocation to be open-coded,
 746 ;;;; and eliminates the need for any VM-dependent transforms to handle
 747 ;;;; these cases.
 748
 749 (macrolet ((def (fun)
 750              `(progn
 751                (deftransform ,fun ((bit-array-1 bit-array-2
 752                                                 &optional result-bit-array)
 753                                    (bit-vector bit-vector &optional null) *
 754                                    :policy (>= speed space))
 755                  `(,',fun bit-array-1 bit-array-2
 756                    (make-array (length bit-array-1) :element-type 'bit)))
 757                ;; If result is T, make it the first arg.
 758                (deftransform ,fun ((bit-array-1 bit-array-2 result-bit-array)
 759                                    (bit-vector bit-vector (eql t)) *)
 760                  `(,',fun bit-array-1 bit-array-2 bit-array-1)))))
 761   (def bit-and)
 762   (def bit-ior)
 763   (def bit-xor)
 764   (def bit-eqv)
 765   (def bit-nand)
 766   (def bit-nor)
 767   (def bit-andc1)
 768   (def bit-andc2)
 769   (def bit-orc1)
 770   (def bit-orc2))
 771
 772 ;;; Similar for BIT-NOT, but there is only one arg...
 773 (deftransform bit-not ((bit-array-1 &optional result-bit-array)
 774                        (bit-vector &optional null) *
 775                        :policy (>= speed space))
 776   '(bit-not bit-array-1
 777             (make-array (length bit-array-1) :element-type 'bit)))
 778 (deftransform bit-not ((bit-array-1 result-bit-array)
 779                        (bit-vector (eql t)))
 780   '(bit-not bit-array-1 bit-array-1))
 781 \f
 782 ;;; Pick off some constant cases.
 783 (defoptimizer (array-header-p derive-type) ((array))
 784   (let ((type (lvar-type array)))
 785     (cond ((not (array-type-p type))
 786            ;; FIXME: use analogue of ARRAY-TYPE-DIMENSIONS-OR-GIVE-UP
 787            nil)
 788           (t
 789            (let ((dims (array-type-dimensions type)))
 790              (cond ((csubtypep type (specifier-type '(simple-array * (*))))
 791                     ;; no array header
 792                     (specifier-type 'null))
 793                    ((and (listp dims) (/= (length dims) 1))
 794                     ;; multi-dimensional array, will have a header
 795                     (specifier-type '(eql t)))
 796                    (t
 797                     nil)))))))