src/compiler/checkgen.lisp

   1 ;;;; This file implements type check generation. This is a phase that
   2 ;;;; runs at the very end of IR1. If a type check is too complex for
   3 ;;;; the back end to directly emit in-line, then we transform the check
   4 ;;;; into an explicit conditional using TYPEP.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16 \f
  17 ;;;; cost estimation
  18
  19 ;;; Return some sort of guess about the cost of a call to a function.
  20 ;;; If the function has some templates, we return the cost of the
  21 ;;; cheapest one, otherwise we return the cost of CALL-NAMED. Calling
  22 ;;; this with functions that have transforms can result in relatively
  23 ;;; meaningless results (exaggerated costs.)
  24 ;;;
  25 ;;; We special-case NULL, since it does have a source tranform and is
  26 ;;; interesting to us.
  27 (defun fun-guessed-cost (name)
  28   (declare (symbol name))
  29   (let ((info (info :function :info name))
  30         (call-cost (template-cost (template-or-lose 'call-named))))
  31     (if info
  32         (let ((templates (fun-info-templates info)))
  33           (if templates
  34               (template-cost (first templates))
  35               (case name
  36                 (null (template-cost (template-or-lose 'if-eq)))
  37                 (t call-cost))))
  38         call-cost)))
  39
  40 ;;; Return some sort of guess for the cost of doing a test against
  41 ;;; TYPE. The result need not be precise as long as it isn't way out
  42 ;;; in space. The units are based on the costs specified for various
  43 ;;; templates in the VM definition.
  44 (defun type-test-cost (type)
  45   (declare (type ctype type))
  46   (or (let ((check (type-check-template type)))
  47         (if check
  48             (template-cost check)
  49             (let ((found (cdr (assoc type *backend-type-predicates*
  50                                      :test #'type=))))
  51               (if found
  52                   (+ (fun-guessed-cost found) (fun-guessed-cost 'eq))
  53                   nil))))
  54       (typecase type
  55         (compound-type
  56          (reduce #'+ (compound-type-types type) :key 'type-test-cost))
  57         (member-type
  58          (* (length (member-type-members type))
  59             (fun-guessed-cost 'eq)))
  60         (numeric-type
  61          (* (if (numeric-type-complexp type) 2 1)
  62             (fun-guessed-cost
  63              (if (csubtypep type (specifier-type 'fixnum)) 'fixnump 'numberp))
  64             (+ 1
  65                (if (numeric-type-low type) 1 0)
  66                (if (numeric-type-high type) 1 0))))
  67         (cons-type
  68          (+ (type-test-cost (specifier-type 'cons))
  69             (fun-guessed-cost 'car)
  70             (type-test-cost (cons-type-car-type type))
  71             (fun-guessed-cost 'cdr)
  72             (type-test-cost (cons-type-cdr-type type))))
  73         (t
  74          (fun-guessed-cost 'typep)))))
  75 \f
  76 ;;;; checking strategy determination
  77
  78 ;;; Return the type we should test for when we really want to check
  79 ;;; for TYPE. If speed, space or compilation speed is more important
  80 ;;; than safety, then we return a weaker type if it is easier to
  81 ;;; check. First we try the defined type weakenings, then look for any
  82 ;;; predicate that is cheaper.
  83 ;;;
  84 ;;; If the supertype is equal in cost to the type, we prefer the
  85 ;;; supertype. This produces a closer approximation of the right thing
  86 ;;; in the presence of poor cost info.
  87 (defun maybe-weaken-check (type cont)
  88   (declare (type ctype type) (type continuation cont))
  89   (cond ((policy (continuation-dest cont)
  90                  (and (<= speed safety)
  91                       (<= space safety)
  92                       (<= compilation-speed safety)))
  93          type)
  94         (t
  95          (let ((min-cost (type-test-cost type))
  96                (min-type type)
  97                (found-super nil))
  98            (dolist (x *backend-type-predicates*)
  99              (let ((stype (car x)))
 100                (when (and (csubtypep type stype)
 101                           (not (union-type-p stype)))
 102                  (let ((stype-cost (type-test-cost stype)))
 103                    (when (or (< stype-cost min-cost)
 104                              (type= stype type))
 105                      (setq found-super t
 106                            min-type stype
 107                            min-cost stype-cost))))))
 108            (if found-super
 109                min-type
 110                *universal-type*)))))
 111
 112 ;;; This is like VALUES-TYPES, only we mash any complex function types
 113 ;;; to FUNCTION.
 114 (defun no-fun-values-types (type)
 115   (declare (type ctype type))
 116   (multiple-value-bind (res count) (values-types type)
 117     (values (mapcar (lambda (type)
 118                       (if (fun-type-p type)
 119                           (specifier-type 'function)
 120                           type))
 121                     res)
 122             count)))
 123
 124 ;;; Switch to disable check complementing, for evaluation.
 125 (defvar *complement-type-checks* t)
 126
 127 ;;; CONT is a continuation we are doing a type check on and TYPES is a
 128 ;;; list of types that we are checking its values against. If we have
 129 ;;; proven that CONT generates a fixed number of values, then for each
 130 ;;; value, we check whether it is cheaper to then difference between
 131 ;;; the proven type and the corresponding type in TYPES. If so, we opt
 132 ;;; for a :HAIRY check with that test negated. Otherwise, we try to do
 133 ;;; a simple test, and if that is impossible, we do a hairy test with
 134 ;;; non-negated types. If true, FORCE-HAIRY forces a hairy type check.
 135 ;;;
 136 ;;; When doing a non-negated check, we call MAYBE-WEAKEN-CHECK to
 137 ;;; weaken the test to a convenient supertype (conditional on policy.)
 138 ;;; If SPEED is 3, or DEBUG-INFO is not particularly important (DEBUG
 139 ;;; <= 1), then we allow weakened checks to be simple, resulting in
 140 ;;; less informative error messages, but saving space and possibly
 141 ;;; time.
 142 ;;;
 143 ;;; FIXME: I don't quite understand this, but it looks as though
 144 ;;; that means type checks are weakened when SPEED=3 regardless of
 145 ;;; the SAFETY level, which is not the right thing to do.
 146 (defun maybe-negate-check (cont types force-hairy)
 147   (declare (type continuation cont) (list types))
 148   (multiple-value-bind (ptypes count)
 149       (no-fun-values-types (continuation-proven-type cont))
 150     (if (eq count :unknown)
 151         (if (and (every #'type-check-template types) (not force-hairy))
 152             (values :simple types)
 153             (values :hairy
 154                     (mapcar (lambda (x)
 155                               (list nil (maybe-weaken-check x cont) x))
 156                             types)))
 157         (let ((res (mapcar (lambda (p c)
 158                              (let ((diff (type-difference p c))
 159                                    (weak (maybe-weaken-check c cont)))
 160                                (if (and diff
 161                                         (< (type-test-cost diff)
 162                                            (type-test-cost weak))
 163                                         *complement-type-checks*)
 164                                    (list t diff c)
 165                                    (list nil weak c))))
 166                            ptypes types)))
 167           (cond ((or force-hairy (find-if #'first res))
 168                  (values :hairy res))
 169                 ((every #'type-check-template types)
 170                  (values :simple types))
 171                 ((policy (continuation-dest cont)
 172                          (or (<= debug 1) (and (= speed 3) (/= debug 3))))
 173                  (let ((weakened (mapcar #'second res)))
 174                    (if (every #'type-check-template weakened)
 175                        (values :simple weakened)
 176                        (values :hairy res))))
 177                 (t
 178                  (values :hairy res)))))))
 179
 180 ;;; Determines whether CONT's assertion is:
 181 ;;;  -- checkable by the back end (:SIMPLE), or
 182 ;;;  -- not checkable by the back end, but checkable via an explicit
 183 ;;;     test in type check conversion (:HAIRY), or
 184 ;;;  -- not reasonably checkable at all (:TOO-HAIRY).
 185 ;;;
 186 ;;; A type is checkable if it either represents a fixed number of
 187 ;;; values (as determined by VALUES-TYPES), or it is the assertion for
 188 ;;; an MV-BIND. A type is simply checkable if all the type assertions
 189 ;;; have a TYPE-CHECK-TEMPLATE. In this :SIMPLE case, the second value
 190 ;;; is a list of the type restrictions specified for the leading
 191 ;;; positional values.
 192 ;;;
 193 ;;; We force a check to be hairy even when there are fixed values if
 194 ;;; we are in a context where we may be forced to use the unknown
 195 ;;; values convention anyway. This is because IR2tran can't generate
 196 ;;; type checks for unknown values continuations but people could
 197 ;;; still be depending on the check being done. We only care about
 198 ;;; EXIT and RETURN (not MV-COMBINATION) since these are the only
 199 ;;; contexts where the ultimate values receiver
 200 ;;;
 201 ;;; In the :HAIRY case, the second value is a list of triples of
 202 ;;; the form:
 203 ;;;    (NOT-P TYPE ORIGINAL-TYPE)
 204 ;;;
 205 ;;; If true, the NOT-P flag indicates a test that the corresponding
 206 ;;; value is *not* of the specified TYPE. ORIGINAL-TYPE is the type
 207 ;;; asserted on this value in the continuation, for use in error
 208 ;;; messages. When NOT-P is true, this will be different from TYPE.
 209 ;;;
 210 ;;; This allows us to take what has been proven about CONT's type into
 211 ;;; consideration. If it is cheaper to test for the difference between
 212 ;;; the derived type and the asserted type, then we check for the
 213 ;;; negation of this type instead.
 214 (defun continuation-check-types (cont)
 215   (declare (type continuation cont))
 216   (let ((type (continuation-asserted-type cont))
 217         (dest (continuation-dest cont)))
 218     (aver (not (eq type *wild-type*)))
 219     (multiple-value-bind (types count) (no-fun-values-types type)
 220       (cond ((not (eq count :unknown))
 221              (if (or (exit-p dest)
 222                      (and (return-p dest)
 223                           (multiple-value-bind (ignore count)
 224                               (values-types (return-result-type dest))
 225                             (declare (ignore ignore))
 226                             (eq count :unknown))))
 227                  (maybe-negate-check cont types t)
 228                  (maybe-negate-check cont types nil)))
 229             ((and (mv-combination-p dest)
 230                   (eq (basic-combination-kind dest) :local))
 231              (aver (values-type-p type))
 232              (maybe-negate-check cont (args-type-optional type) nil))
 233             (t
 234              (values :too-hairy nil))))))
 235
 236 ;;; Return true if CONT is a continuation whose type the back end is
 237 ;;; likely to want to check. Since we don't know what template the
 238 ;;; back end is going to choose to implement the continuation's DEST,
 239 ;;; we use a heuristic. We always return T unless:
 240 ;;;  -- nobody uses the value, or
 241 ;;;  -- safety is totally unimportant, or
 242 ;;;  -- the continuation is an argument to an unknown function, or
 243 ;;;  -- the continuation is an argument to a known function that has
 244 ;;;     no IR2-CONVERT method or :FAST-SAFE templates that are
 245 ;;;     compatible with the call's type.
 246 ;;;
 247 ;;; We must only return NIL when it is *certain* that a check will not
 248 ;;; be done, since if we pass up this chance to do the check, it will
 249 ;;; be too late. The penalty for being too conservative is duplicated
 250 ;;; type checks. The penalty for erring by being too speculative is
 251 ;;; much nastier, e.g. falling through without ever being able to find
 252 ;;; an appropriate VOP.
 253 (defun probable-type-check-p (cont)
 254   (declare (type continuation cont))
 255   (let ((dest (continuation-dest cont)))
 256     (cond ((or (not dest)
 257                (policy dest (zerop safety)))
 258            nil)
 259           ((basic-combination-p dest)
 260            (let ((kind (basic-combination-kind dest)))
 261              (cond ((eq cont (basic-combination-fun dest)) t)
 262                    ((eq kind :local) t)
 263                    ((not (eq (continuation-asserted-type cont)
 264                              (continuation-externally-checkable-type cont)))
 265                     ;; There is an explicit assertion.
 266                     t)
 267                    ((eq kind :full)
 268                     ;; The theory is that the type assertion is from a
 269                     ;; declaration in (or on) the callee, so the
 270                     ;; callee should be able to do the check. We want
 271                     ;; to let the callee do the check, because it is
 272                     ;; possible that by the time of call that
 273                     ;; declaration will be changed and we do not want
 274                     ;; to make people recompile all calls to a
 275                     ;; function when they were originally compiled
 276                     ;; with a bad declaration. (See also bug 35.)
 277                     nil)
 278
 279                    ((eq kind :error) nil)
 280                    ;; :ERROR means that we have an invalid syntax of
 281                    ;; the call and the callee will detect it before
 282                    ;; thinking about types.
 283
 284                    ((fun-info-ir2-convert kind) t)
 285                    (t
 286                     (dolist (template (fun-info-templates kind) nil)
 287                       (when (eq (template-ltn-policy template) :fast-safe)
 288                         (multiple-value-bind (val win)
 289                             (valid-fun-use dest (template-type template))
 290                           (when (or val (not win)) (return t)))))))))
 291           (t t))))
 292
 293 ;;; Return a form that we can convert to do a hairy type check of the
 294 ;;; specified TYPES. TYPES is a list of the format returned by
 295 ;;; CONTINUATION-CHECK-TYPES in the :HAIRY case. In place of the
 296 ;;; actual value(s) we are to check, we use 'DUMMY. This constant
 297 ;;; reference is later replaced with the actual values continuation.
 298 ;;;
 299 ;;; Note that we don't attempt to check for required values being
 300 ;;; unsupplied. Such checking is impossible to efficiently do at the
 301 ;;; source level because our fixed-values conventions are optimized
 302 ;;; for the common MV-BIND case.
 303 ;;;
 304 ;;; We can always use MULTIPLE-VALUE-BIND, since the macro is clever
 305 ;;; about binding a single variable.
 306 (defun make-type-check-form (types)
 307   (let ((temps (make-gensym-list (length types))))
 308     `(multiple-value-bind ,temps 'dummy
 309        ,@(mapcar (lambda (temp type)
 310                    (let* ((spec
 311                            (let ((*unparse-fun-type-simplify* t))
 312                              (type-specifier (second type))))
 313                           (test (if (first type) `(not ,spec) spec)))
 314                      `(unless (typep ,temp ',test)
 315                         (%type-check-error
 316                          ,temp
 317                          ',(type-specifier (third type))))))
 318                  temps
 319                  types)
 320        (values ,@temps))))
 321
 322 ;;; Splice in explicit type check code immediately before the node
 323 ;;; which is CONT's DEST. This code receives the value(s) that were
 324 ;;; being passed to CONT, checks the type(s) of the value(s), then
 325 ;;; passes them on to CONT.
 326 (defun convert-type-check (cont types)
 327   (declare (type continuation cont) (type list types))
 328   (with-ir1-environment-from-node (continuation-dest cont)
 329
 330     ;; Ensuring that CONT starts a block lets us freely manipulate its uses.
 331     (ensure-block-start cont)
 332
 333     ;; Make a new continuation and move CONT's uses to it.
 334     (let* ((new-start (make-continuation))
 335            (dest (continuation-dest cont))
 336            (prev (node-prev dest)))
 337       (continuation-starts-block new-start)
 338       (substitute-continuation-uses new-start cont)
 339
 340       ;; Setting TYPE-CHECK in CONT to :DELETED indicates that the
 341       ;; check has been done.
 342       (setf (continuation-%type-check cont) :deleted)
 343
 344       ;; Make the DEST node start its block so that we can splice in
 345       ;; the type check code.
 346       (when (continuation-use prev)
 347         (node-ends-block (continuation-use prev)))
 348
 349       (let* ((prev-block (continuation-block prev))
 350              (new-block (continuation-block new-start))
 351              (dummy (make-continuation)))
 352
 353         ;; Splice in the new block before DEST, giving the new block
 354         ;; all of DEST's predecessors.
 355         (dolist (block (block-pred prev-block))
 356           (change-block-successor block prev-block new-block))
 357
 358         ;; Convert the check form, using the new block start as START
 359         ;; and a dummy continuation as CONT.
 360         (ir1-convert new-start dummy (make-type-check-form types))
 361
 362         ;; TO DO: Why should this be true? -- WHN 19990601
 363         (aver (eq (continuation-block dummy) new-block))
 364
 365         ;; KLUDGE: Comments at the head of this function in CMU CL
 366         ;; said that somewhere in here we
 367         ;;   Set the new block's start and end cleanups to the *start*
 368         ;;   cleanup of PREV's block. This overrides the incorrect
 369         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 370         ;; Unfortunately I can't find any code which corresponds to this.
 371         ;; Perhaps it was a stale comment? Or perhaps I just don't
 372         ;; understand.. -- WHN 19990521
 373
 374         (let ((node (continuation-use dummy)))
 375           (setf (block-last new-block) node)
 376           ;; Change the use to a use of CONT. (We need to use the
 377           ;; dummy continuation to get the control transfer right,
 378           ;; because we want to go to PREV's block, not CONT's.)
 379           (delete-continuation-use node)
 380           (add-continuation-use node cont))
 381         ;; Link the new block to PREV's block.
 382         (link-blocks new-block prev-block))
 383
 384       ;; MAKE-TYPE-CHECK-FORM generated a form which checked the type
 385       ;; of 'DUMMY, not a real form. At this point we convert to the
 386       ;; real form by finding 'DUMMY and overwriting it with the new
 387       ;; continuation. (We can find 'DUMMY because no LET conversion
 388       ;; has been done yet.) The [mv-]combination code from the
 389       ;; mv-bind in the check form will be the use of the new check
 390       ;; continuation. We substitute for the first argument of this
 391       ;; node.
 392       (let* ((node (continuation-use cont))
 393              (args (basic-combination-args node))
 394              (victim (first args)))
 395         (aver (and (= (length args) 1)
 396                      (eq (constant-value
 397                           (ref-leaf
 398                            (continuation-use victim)))
 399                          'dummy)))
 400         (substitute-continuation new-start victim)))
 401
 402     ;; Invoking local call analysis converts this call to a LET.
 403     (locall-analyze-component *current-component*))
 404
 405   (values))
 406
 407 ;;; Emit a type warning for NODE. If the value of NODE is being used
 408 ;;; for a variable binding, we figure out which one for source
 409 ;;; context. If the value is a constant, we print it specially. We
 410 ;;; ignore nodes whose type is NIL, since they are supposed to never
 411 ;;; return.
 412 (defun emit-type-warning (node)
 413   (declare (type node node))
 414   (let* ((*compiler-error-context* node)
 415          (cont (node-cont node))
 416          (atype-spec (type-specifier (continuation-asserted-type cont)))
 417          (dtype (node-derived-type node))
 418          (dest (continuation-dest cont))
 419          (what (when (and (combination-p dest)
 420                           (eq (combination-kind dest) :local))
 421                  (let ((lambda (combination-lambda dest))
 422                        (pos (position-or-lose cont (combination-args dest))))
 423                    (format nil "~:[A possible~;The~] binding of ~S"
 424                            (and (continuation-use cont)
 425                                 (eq (functional-kind lambda) :let))
 426                            (leaf-source-name (elt (lambda-vars lambda)
 427                                                   pos)))))))
 428     (cond ((eq dtype *empty-type*))
 429           ((and (ref-p node) (constant-p (ref-leaf node)))
 430            (compiler-warn "~:[This~;~:*~A~] is not a ~<~%~9T~:;~S:~>~%  ~S"
 431                           what atype-spec (constant-value (ref-leaf node))))
 432           (t
 433            (compiler-warn
 434             "~:[Result~;~:*~A~] is a ~S, ~<~%~9T~:;not a ~S.~>"
 435             what (type-specifier dtype) atype-spec))))
 436   (values))
 437
 438 ;;; Loop over all blocks in COMPONENT that have TYPE-CHECK set,
 439 ;;; looking for continuations with TYPE-CHECK T. We do two mostly
 440 ;;; unrelated things: detect compile-time type errors and determine if
 441 ;;; and how to do run-time type checks.
 442 ;;;
 443 ;;; If there is a compile-time type error, then we mark the
 444 ;;; continuation and emit a warning if appropriate. This part loops
 445 ;;; over all the uses of the continuation, since after we convert the
 446 ;;; check, the :DELETED kind will inhibit warnings about the types of
 447 ;;; other uses.
 448 ;;;
 449 ;;; If a continuation is too complex to be checked by the back end, or
 450 ;;; is better checked with explicit code, then convert to an explicit
 451 ;;; test. Assertions that can checked by the back end are passed
 452 ;;; through. Assertions that can't be tested are flamed about and
 453 ;;; marked as not needing to be checked.
 454 ;;;
 455 ;;; If we determine that a type check won't be done, then we set
 456 ;;; TYPE-CHECK to :NO-CHECK. In the non-hairy cases, this is just to
 457 ;;; prevent us from wasting time coming to the same conclusion again
 458 ;;; on a later iteration. In the hairy case, we must indicate to LTN
 459 ;;; that it must choose a safe implementation, since IR2 conversion
 460 ;;; will choke on the check.
 461 ;;;
 462 ;;; The generation of the type checks is delayed until all the type
 463 ;;; check decisions have been made because the generation of the type
 464 ;;; checks creates new nodes whose derived types aren't always updated
 465 ;;; which may lead to inappropriate template choices due to the
 466 ;;; modification of argument types.
 467 (defun generate-type-checks (component)
 468   (collect ((conts))
 469     (do-blocks (block component)
 470       (when (block-type-check block)
 471         (do-nodes (node cont block)
 472           (let ((type-check (continuation-type-check cont)))
 473             (unless (member type-check '(nil :deleted))
 474               (let ((atype (continuation-asserted-type cont)))
 475                 (do-uses (use cont)
 476                   (unless (values-types-equal-or-intersect
 477                            (node-derived-type use) atype)
 478                     (unless (policy node (= inhibit-warnings 3))
 479                       (emit-type-warning use))))))
 480             (when (eq type-check t)
 481               (cond ((probable-type-check-p cont)
 482                      (conts cont))
 483                     (t
 484                      (setf (continuation-%type-check cont) :no-check))))))
 485         (setf (block-type-check block) nil)))
 486     (dolist (cont (conts))
 487       (multiple-value-bind (check types) (continuation-check-types cont)
 488         (ecase check
 489           (:simple)
 490           (:hairy
 491            (convert-type-check cont types))
 492           (:too-hairy
 493            (let* ((context (continuation-dest cont))
 494                   (*compiler-error-context* context))
 495              (when (policy context (>= safety inhibit-warnings))
 496                (compiler-note
 497                 "type assertion too complex to check:~% ~S."
 498                 (type-specifier (continuation-asserted-type cont)))))
 499            (setf (continuation-%type-check cont) :deleted))))))
 500   (values))