src/compiler/checkgen.lisp

   1 ;;;; This file implements type check generation. This is a phase that
   2 ;;;; runs at the very end of IR1. If a type check is too complex for
   3 ;;;; the back end to directly emit in-line, then we transform the check
   4 ;;;; into an explicit conditional using TYPEP.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16 \f
  17 ;;;; cost estimation
  18
  19 ;;; Return some sort of guess about the cost of a call to a function.
  20 ;;; If the function has some templates, we return the cost of the
  21 ;;; cheapest one, otherwise we return the cost of CALL-NAMED. Calling
  22 ;;; this with functions that have transforms can result in relatively
  23 ;;; meaningless results (exaggerated costs.)
  24 ;;;
  25 ;;; We special-case NULL, since it does have a source tranform and is
  26 ;;; interesting to us.
  27 (defun function-cost (name)
  28   (declare (symbol name))
  29   (let ((info (info :function :info name))
  30         (call-cost (template-cost (template-or-lose 'call-named))))
  31     (if info
  32         (let ((templates (function-info-templates info)))
  33           (if templates
  34               (template-cost (first templates))
  35               (case name
  36                 (null (template-cost (template-or-lose 'if-eq)))
  37                 (t call-cost))))
  38         call-cost)))
  39
  40 ;;; Return some sort of guess for the cost of doing a test against
  41 ;;; TYPE. The result need not be precise as long as it isn't way out
  42 ;;; in space. The units are based on the costs specified for various
  43 ;;; templates in the VM definition.
  44 (defun type-test-cost (type)
  45   (declare (type ctype type))
  46   (or (let ((check (type-check-template type)))
  47         (if check
  48             (template-cost check)
  49             (let ((found (cdr (assoc type *backend-type-predicates*
  50                                      :test #'type=))))
  51               (if found
  52                   (+ (function-cost found) (function-cost 'eq))
  53                   nil))))
  54       (typecase type
  55         (union-type
  56          (collect ((res 0 +))
  57            (dolist (mem (union-type-types type))
  58              (res (type-test-cost mem)))
  59            (res)))
  60         (member-type
  61          (* (length (member-type-members type))
  62             (function-cost 'eq)))
  63         (numeric-type
  64          (* (if (numeric-type-complexp type) 2 1)
  65             (function-cost
  66              (if (csubtypep type (specifier-type 'fixnum)) 'fixnump 'numberp))
  67             (+ 1
  68                (if (numeric-type-low type) 1 0)
  69                (if (numeric-type-high type) 1 0))))
  70         (cons-type
  71          (+ (type-test-cost (specifier-type 'cons))
  72             (function-cost 'car)
  73             (type-test-cost (cons-type-car-type type))
  74             (function-cost 'cdr)
  75             (type-test-cost (cons-type-cdr-type type))))
  76         (t
  77          (function-cost 'typep)))))
  78 \f
  79 ;;;; checking strategy determination
  80
  81 ;;; Return the type we should test for when we really want to check
  82 ;;; for TYPE. If speed, space or compilation speed is more important
  83 ;;; than safety, then we return a weaker type if it is easier to
  84 ;;; check. First we try the defined type weakenings, then look for any
  85 ;;; predicate that is cheaper.
  86 ;;;
  87 ;;; If the supertype is equal in cost to the type, we prefer the
  88 ;;; supertype. This produces a closer approximation of the right thing
  89 ;;; in the presence of poor cost info.
  90 (defun maybe-weaken-check (type cont)
  91   (declare (type ctype type) (type continuation cont))
  92   (cond ((policy (continuation-dest cont)
  93                  (and (<= speed safety)
  94                       (<= space safety)
  95                       (<= cspeed safety)))
  96          type)
  97         (t
  98          (let ((min-cost (type-test-cost type))
  99                (min-type type)
 100                (found-super nil))
 101            (dolist (x *backend-type-predicates*)
 102              (let ((stype (car x)))
 103                (when (and (csubtypep type stype)
 104                           (not (union-type-p stype)))
 105                  (let ((stype-cost (type-test-cost stype)))
 106                    (when (or (< stype-cost min-cost)
 107                              (type= stype type))
 108                      (setq found-super t
 109                            min-type stype
 110                            min-cost stype-cost))))))
 111            (if found-super
 112                min-type
 113                *universal-type*)))))
 114
 115 ;;; Like VALUES-TYPES, only mash any complex function types to FUNCTION.
 116 (defun no-function-values-types (type)
 117   (declare (type ctype type))
 118   (multiple-value-bind (res count) (values-types type)
 119     (values (mapcar #'(lambda (type)
 120                         (if (function-type-p type)
 121                             (specifier-type 'function)
 122                             type))
 123                     res)
 124             count)))
 125
 126 ;;; Switch to disable check complementing, for evaluation.
 127 (defvar *complement-type-checks* t)
 128
 129 ;;; CONT is a continuation we are doing a type check on and TYPES is a
 130 ;;; list of types that we are checking its values against. If we have
 131 ;;; proven that CONT generates a fixed number of values, then for each
 132 ;;; value, we check whether it is cheaper to then difference between
 133 ;;; the proven type and the corresponding type in TYPES. If so, we opt
 134 ;;; for a :HAIRY check with that test negated. Otherwise, we try to do
 135 ;;; a simple test, and if that is impossible, we do a hairy test with
 136 ;;; non-negated types. If true, Force-Hairy forces a hairy type check.
 137 ;;;
 138 ;;; When doing a non-negated check, we call MAYBE-WEAKEN-CHECK to
 139 ;;; weaken the test to a convenient supertype (conditional on policy.)
 140 ;;; If SPEED is 3, or DEBUG-INFO is not particularly important (DEBUG
 141 ;;; <= 1), then we allow weakened checks to be simple, resulting in
 142 ;;; less informative error messages, but saving space and possibly
 143 ;;; time.
 144 ;;;
 145 ;;; FIXME: I don't quite understand this, but it looks as though
 146 ;;; that means type checks are weakened when SPEED=3 regardless of
 147 ;;; the SAFETY level, which is not the right thing to do.
 148 (defun maybe-negate-check (cont types force-hairy)
 149   (declare (type continuation cont) (list types))
 150   (multiple-value-bind (ptypes count)
 151       (no-function-values-types (continuation-proven-type cont))
 152     (if (eq count :unknown)
 153         (if (and (every #'type-check-template types) (not force-hairy))
 154             (values :simple types)
 155             (values :hairy
 156                     (mapcar #'(lambda (x)
 157                                 (list nil (maybe-weaken-check x cont) x))
 158                             types)))
 159         (let ((res (mapcar #'(lambda (p c)
 160                                (let ((diff (type-difference p c))
 161                                      (weak (maybe-weaken-check c cont)))
 162                                  (if (and diff
 163                                           (< (type-test-cost diff)
 164                                              (type-test-cost weak))
 165                                           *complement-type-checks*)
 166                                      (list t diff c)
 167                                      (list nil weak c))))
 168                            ptypes types)))
 169           (cond ((or force-hairy (find-if #'first res))
 170                  (values :hairy res))
 171                 ((every #'type-check-template types)
 172                  (values :simple types))
 173                 ((policy (continuation-dest cont)
 174                          (or (<= debug 1) (and (= speed 3) (/= debug 3))))
 175                  (let ((weakened (mapcar #'second res)))
 176                    (if (every #'type-check-template weakened)
 177                        (values :simple weakened)
 178                        (values :hairy res))))
 179                 (t
 180                  (values :hairy res)))))))
 181
 182 ;;; Determines whether CONT's assertion is:
 183 ;;;  -- checkable by the back end (:SIMPLE), or
 184 ;;;  -- not checkable by the back end, but checkable via an explicit
 185 ;;;     test in type check conversion (:HAIRY), or
 186 ;;;  -- not reasonably checkable at all (:TOO-HAIRY).
 187 ;;;
 188 ;;; A type is checkable if it either represents a fixed number of
 189 ;;; values (as determined by VALUES-TYPES), or it is the assertion for
 190 ;;; an MV-Bind. A type is simply checkable if all the type assertions
 191 ;;; have a TYPE-CHECK-TEMPLATE. In this :SIMPLE case, the second value
 192 ;;; is a list of the type restrictions specified for the leading
 193 ;;; positional values.
 194 ;;;
 195 ;;; We force a check to be hairy even when there are fixed values if
 196 ;;; we are in a context where we may be forced to use the unknown
 197 ;;; values convention anyway. This is because IR2tran can't generate
 198 ;;; type checks for unknown values continuations but people could
 199 ;;; still be depending on the check being done. We only care about
 200 ;;; EXIT and RETURN (not MV-COMBINATION) since these are the only
 201 ;;; contexts where the ultimate values receiver
 202 ;;;
 203 ;;; In the :HAIRY case, the second value is a list of triples of
 204 ;;; the form:
 205 ;;;    (NOT-P TYPE ORIGINAL-TYPE)
 206 ;;;
 207 ;;; If true, the NOT-P flag indicates a test that the corresponding
 208 ;;; value is *not* of the specified TYPE. ORIGINAL-TYPE is the type
 209 ;;; asserted on this value in the continuation, for use in error
 210 ;;; messages. When NOT-P is true, this will be different from TYPE.
 211 ;;;
 212 ;;; This allows us to take what has been proven about CONT's type into
 213 ;;; consideration. If it is cheaper to test for the difference between
 214 ;;; the derived type and the asserted type, then we check for the
 215 ;;; negation of this type instead.
 216 (defun continuation-check-types (cont)
 217   (declare (type continuation cont))
 218   (let ((type (continuation-asserted-type cont))
 219         (dest (continuation-dest cont)))
 220     (assert (not (eq type *wild-type*)))
 221     (multiple-value-bind (types count) (no-function-values-types type)
 222       (cond ((not (eq count :unknown))
 223              (if (or (exit-p dest)
 224                      (and (return-p dest)
 225                           (multiple-value-bind (ignore count)
 226                               (values-types (return-result-type dest))
 227                             (declare (ignore ignore))
 228                             (eq count :unknown))))
 229                  (maybe-negate-check cont types t)
 230                  (maybe-negate-check cont types nil)))
 231             ((and (mv-combination-p dest)
 232                   (eq (basic-combination-kind dest) :local))
 233              (assert (values-type-p type))
 234              (maybe-negate-check cont (args-type-optional type) nil))
 235             (t
 236              (values :too-hairy nil))))))
 237
 238 ;;; Return true if CONT is a continuation whose type the back end is
 239 ;;; likely to want to check. Since we don't know what template the
 240 ;;; back end is going to choose to implement the continuation's DEST,
 241 ;;; we use a heuristic. We always return T unless:
 242 ;;;  -- nobody uses the value, or
 243 ;;;  -- safety is totally unimportant, or
 244 ;;;  -- the continuation is an argument to an unknown function, or
 245 ;;;  -- the continuation is an argument to a known function that has
 246 ;;;     no IR2-Convert method or :FAST-SAFE templates that are
 247 ;;;     compatible with the call's type.
 248 ;;;
 249 ;;; We must only return NIL when it is *certain* that a check will not
 250 ;;; be done, since if we pass up this chance to do the check, it will
 251 ;;; be too late. The penalty for being too conservative is duplicated
 252 ;;; type checks.
 253 ;;;
 254 ;;; If there is a compile-time type error, then we always return true
 255 ;;; unless the DEST is a full call. With a full call, the theory is
 256 ;;; that the type error is probably from a declaration in (or on) the
 257 ;;; callee, so the callee should be able to do the check. We want to
 258 ;;; let the callee do the check, because it is possible that the error
 259 ;;; is really in the callee, not the caller. We don't want to make
 260 ;;; people recompile all calls to a function when they were originally
 261 ;;; compiled with a bad declaration (or an old type assertion derived
 262 ;;; from a definition appearing after the call.)
 263 (defun probable-type-check-p (cont)
 264   (declare (type continuation cont))
 265   (let ((dest (continuation-dest cont)))
 266     (cond ((eq (continuation-type-check cont) :error)
 267            (if (and (combination-p dest) (eq (combination-kind dest) :error))
 268                nil
 269                t))
 270           ((or (not dest)
 271                (policy dest (zerop safety)))
 272            nil)
 273           ((basic-combination-p dest)
 274            (let ((kind (basic-combination-kind dest)))
 275              (cond ((eq cont (basic-combination-fun dest)) t)
 276                    ((eq kind :local) t)
 277                    ((member kind '(:full :error)) nil)
 278                    ((function-info-ir2-convert kind) t)
 279                    (t
 280                     (dolist (template (function-info-templates kind) nil)
 281                       (when (eq (template-policy template) :fast-safe)
 282                         (multiple-value-bind (val win)
 283                             (valid-function-use dest (template-type template))
 284                           (when (or val (not win)) (return t)))))))))
 285           (t t))))
 286
 287 ;;; Return a form that we can convert to do a hairy type check of the
 288 ;;; specified TYPES. TYPES is a list of the format returned by
 289 ;;; CONTINUATION-CHECK-TYPES in the :HAIRY case. In place of the
 290 ;;; actual value(s) we are to check, we use 'DUMMY. This constant
 291 ;;; reference is later replaced with the actual values continuation.
 292 ;;;
 293 ;;; Note that we don't attempt to check for required values being
 294 ;;; unsupplied. Such checking is impossible to efficiently do at the
 295 ;;; source level because our fixed-values conventions are optimized
 296 ;;; for the common MV-BIND case.
 297 ;;;
 298 ;;; We can always use MULTIPLE-VALUE-BIND, since the macro is clever
 299 ;;; about binding a single variable.
 300 (defun make-type-check-form (types)
 301   (let ((temps (make-gensym-list (length types))))
 302     `(multiple-value-bind ,temps 'dummy
 303        ,@(mapcar #'(lambda (temp type)
 304                      (let* ((spec
 305                              (let ((*unparse-function-type-simplify* t))
 306                                (type-specifier (second type))))
 307                             (test (if (first type) `(not ,spec) spec)))
 308                        `(unless (typep ,temp ',test)
 309                           (%type-check-error
 310                            ,temp
 311                            ',(type-specifier (third type))))))
 312                  temps
 313                  types)
 314        (values ,@temps))))
 315
 316 ;;; Splice in explicit type check code immediately before the node
 317 ;;; which is CONT's DEST. This code receives the value(s) that were
 318 ;;; being passed to CONT, checks the type(s) of the value(s), then
 319 ;;; passes them on to CONT.
 320 (defun convert-type-check (cont types)
 321   (declare (type continuation cont) (type list types))
 322   (with-ir1-environment (continuation-dest cont)
 323
 324     ;; Ensuring that CONT starts a block lets us freely manipulate its uses.
 325     (ensure-block-start cont)
 326
 327     ;; Make a new continuation and move CONT's uses to it.
 328     (let* ((new-start (make-continuation))
 329            (dest (continuation-dest cont))
 330            (prev (node-prev dest)))
 331       (continuation-starts-block new-start)
 332       (substitute-continuation-uses new-start cont)
 333
 334       ;; Setting TYPE-CHECK in CONT to :DELETED indicates that the
 335       ;; check has been done.
 336       (setf (continuation-%type-check cont) :deleted)
 337
 338       ;; Make the DEST node start its block so that we can splice in
 339       ;; the type check code.
 340       (when (continuation-use prev)
 341         (node-ends-block (continuation-use prev)))
 342
 343       (let* ((prev-block (continuation-block prev))
 344              (new-block (continuation-block new-start))
 345              (dummy (make-continuation)))
 346
 347         ;; Splice in the new block before DEST, giving the new block
 348         ;; all of DEST's predecessors.
 349         (dolist (block (block-pred prev-block))
 350           (change-block-successor block prev-block new-block))
 351
 352         ;; Convert the check form, using the new block start as START
 353         ;; and a dummy continuation as CONT.
 354         (ir1-convert new-start dummy (make-type-check-form types))
 355
 356         ;; TO DO: Why should this be true? -- WHN 19990601
 357         (assert (eq (continuation-block dummy) new-block))
 358
 359         ;; KLUDGE: Comments at the head of this function in CMU CL
 360         ;; said that somewhere in here we
 361         ;;   Set the new block's start and end cleanups to the *start*
 362         ;;   cleanup of PREV's block. This overrides the incorrect
 363         ;;   default from WITH-IR1-ENVIRONMENT.
 364         ;; Unfortunately I can't find any code which corresponds to this.
 365         ;; Perhaps it was a stale comment? Or perhaps I just don't
 366         ;; understand.. -- WHN 19990521
 367
 368         (let ((node (continuation-use dummy)))
 369           (setf (block-last new-block) node)
 370           ;; Change the use to a use of CONT. (We need to use the
 371           ;; dummy continuation to get the control transfer right,
 372           ;; because we want to go to PREV's block, not CONT's.)
 373           (delete-continuation-use node)
 374           (add-continuation-use node cont))
 375         ;; Link the new block to PREV's block.
 376         (link-blocks new-block prev-block))
 377
 378       ;; MAKE-TYPE-CHECK-FORM generated a form which checked the type
 379       ;; of 'DUMMY, not a real form. At this point we convert to the
 380       ;; real form by finding 'DUMMY and overwriting it with the new
 381       ;; continuation. (We can find 'DUMMY because no LET conversion
 382       ;; has been done yet.) The [mv-]combination code from the
 383       ;; mv-bind in the check form will be the use of the new check
 384       ;; continuation. We substitute for the first argument of this
 385       ;; node.
 386       (let* ((node (continuation-use cont))
 387              (args (basic-combination-args node))
 388              (victim (first args)))
 389         (assert (and (= (length args) 1)
 390                      (eq (constant-value
 391                           (ref-leaf
 392                            (continuation-use victim)))
 393                          'dummy)))
 394         (substitute-continuation new-start victim)))
 395
 396     ;; Invoking local call analysis converts this call to a LET.
 397     (local-call-analyze *current-component*))
 398
 399   (values))
 400
 401 ;;; Emit a type warning for NODE. If the value of NODE is being used
 402 ;;; for a variable binding, we figure out which one for source
 403 ;;; context. If the value is a constant, we print it specially. We
 404 ;;; ignore nodes whose type is NIL, since they are supposed to never
 405 ;;; return.
 406 (defun do-type-warning (node)
 407   (declare (type node node))
 408   (let* ((*compiler-error-context* node)
 409          (cont (node-cont node))
 410          (atype-spec (type-specifier (continuation-asserted-type cont)))
 411          (dtype (node-derived-type node))
 412          (dest (continuation-dest cont))
 413          (what (when (and (combination-p dest)
 414                           (eq (combination-kind dest) :local))
 415                  (let ((lambda (combination-lambda dest))
 416                        (pos (position-or-lose cont (combination-args dest))))
 417                    (format nil "~:[A possible~;The~] binding of ~S"
 418                            (and (continuation-use cont)
 419                                 (eq (functional-kind lambda) :let))
 420                            (leaf-name (elt (lambda-vars lambda) pos)))))))
 421     (cond ((eq dtype *empty-type*))
 422           ((and (ref-p node) (constant-p (ref-leaf node)))
 423            (compiler-warning "~:[This~;~:*~A~] is not a ~<~%~9T~:;~S:~>~%  ~S"
 424                              what atype-spec (constant-value (ref-leaf node))))
 425           (t
 426            (compiler-warning
 427             "~:[Result~;~:*~A~] is a ~S, ~<~%~9T~:;not a ~S.~>"
 428             what (type-specifier dtype) atype-spec))))
 429   (values))
 430
 431 ;;; Mark CONT as being a continuation with a manifest type error. We
 432 ;;; set the kind to :ERROR, and clear any FUNCTION-INFO if the
 433 ;;; continuation is an argument to a known call. The last is done so
 434 ;;; that the back end doesn't have to worry about type errors in
 435 ;;; arguments to known functions. This clearing is inhibited for
 436 ;;; things with IR2-CONVERT methods, since we can't do a full call to
 437 ;;; funny functions.
 438 (defun mark-error-continuation (cont)
 439   (declare (type continuation cont))
 440   (setf (continuation-%type-check cont) :error)
 441   (let ((dest (continuation-dest cont)))
 442     (when (and (combination-p dest)
 443                (let ((kind (basic-combination-kind dest)))
 444                  (or (eq kind :full)
 445                      (and (function-info-p kind)
 446                           (not (function-info-ir2-convert kind))))))
 447       (setf (basic-combination-kind dest) :error)))
 448   (values))
 449
 450 ;;; Loop over all blocks in Component that have TYPE-CHECK set,
 451 ;;; looking for continuations with TYPE-CHECK T. We do two mostly
 452 ;;; unrelated things: detect compile-time type errors and determine if
 453 ;;; and how to do run-time type checks.
 454 ;;;
 455 ;;; If there is a compile-time type error, then we mark the
 456 ;;; continuation and emit a warning if appropriate. This part loops
 457 ;;; over all the uses of the continuation, since after we convert the
 458 ;;; check, the :DELETED kind will inhibit warnings about the types of
 459 ;;; other uses.
 460 ;;;
 461 ;;; If a continuation is too complex to be checked by the back end, or
 462 ;;; is better checked with explicit code, then convert to an explicit
 463 ;;; test. Assertions that can checked by the back end are passed
 464 ;;; through. Assertions that can't be tested are flamed about and
 465 ;;; marked as not needing to be checked.
 466 ;;;
 467 ;;; If we determine that a type check won't be done, then we set
 468 ;;; TYPE-CHECK to :NO-CHECK. In the non-hairy cases, this is just to
 469 ;;; prevent us from wasting time coming to the same conclusion again
 470 ;;; on a later iteration. In the hairy case, we must indicate to LTN
 471 ;;; that it must choose a safe implementation, since IR2 conversion
 472 ;;; will choke on the check.
 473 ;;;
 474 ;;; The generation of the type checks is delayed until all the type
 475 ;;; check decisions have been made because the generation of the type
 476 ;;; checks creates new nodes whose derived types aren't always updated
 477 ;;; which may lead to inappropriate template choices due to the
 478 ;;; modification of argument types.
 479 (defun generate-type-checks (component)
 480   (collect ((conts))
 481     (do-blocks (block component)
 482       (when (block-type-check block)
 483         (do-nodes (node cont block)
 484           (let ((type-check (continuation-type-check cont)))
 485             (unless (member type-check '(nil :error :deleted))
 486               (let ((atype (continuation-asserted-type cont)))
 487                 (do-uses (use cont)
 488                   (unless (values-types-intersect (node-derived-type use)
 489                                                   atype)
 490                     (mark-error-continuation cont)
 491                     (unless (policy node (= brevity 3))
 492                       (do-type-warning use))))))
 493             (when (and (eq type-check t)
 494                        (not *byte-compiling*))
 495               (cond ((probable-type-check-p cont)
 496                      (conts cont))
 497                     (t
 498                      (setf (continuation-%type-check cont) :no-check))))))
 499         (setf (block-type-check block) nil)))
 500     (dolist (cont (conts))
 501       (multiple-value-bind (check types) (continuation-check-types cont)
 502         (ecase check
 503           (:simple)
 504           (:hairy
 505            (convert-type-check cont types))
 506           (:too-hairy
 507            (let* ((context (continuation-dest cont))
 508                   (*compiler-error-context* context))
 509              (when (policy context (>= safety brevity))
 510                (compiler-note
 511                 "type assertion too complex to check:~% ~S."
 512                 (type-specifier (continuation-asserted-type cont)))))
 513            (setf (continuation-%type-check cont) :deleted))))))
 514   (values))