src/compiler/constraint.lisp

   1 ;;;; This file implements the constraint propagation phase of the
   2 ;;;; compiler, which uses global flow analysis to obtain dynamic type
   3 ;;;; information.
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 ;;; TODO:
  15 ;;;
  16 ;;; -- documentation
  17 ;;;
  18 ;;; -- MV-BIND, :ASSIGNMENT
  19 ;;;
  20 ;;; Note: The functions in this file that accept constraint sets are
  21 ;;; actually receiving the constraint sets associated with nodes,
  22 ;;; blocks, and lambda-vars.  It might be make CP easier to understand
  23 ;;; and work on if these functions traded in nodes, blocks, and
  24 ;;; lambda-vars directly.
  25
  26 ;;; Problems:
  27 ;;;
  28 ;;; -- Constraint propagation badly interacts with bottom-up type
  29 ;;; inference. Consider
  30 ;;;
  31 ;;; (defun foo (n &aux (i 42))
  32 ;;;   (declare (optimize speed))
  33 ;;;   (declare (fixnum n)
  34 ;;;            #+nil (type (integer 0) i))
  35 ;;;   (tagbody
  36 ;;;      (setq i 0)
  37 ;;;    :loop
  38 ;;;      (when (>= i n) (go :exit))
  39 ;;;      (setq i (1+ i))
  40 ;;;      (go :loop)
  41 ;;;    :exit))
  42 ;;;
  43 ;;; In this case CP cannot even infer that I is of class INTEGER.
  44 ;;;
  45 ;;; -- In the above example if we place the check after SETQ, CP will
  46 ;;; fail to infer (< I FIXNUM): it does not understand that this
  47 ;;; constraint follows from (TYPEP I (INTEGER 0 0)).
  48
  49 (in-package "SB!C")
  50
  51 ;;; *CONSTRAINT-UNIVERSE* gets bound in IR1-PHASES to a fresh,
  52 ;;; zero-length, non-zero-total-size vector-with-fill-pointer.
  53 (declaim (type (and vector (not simple-vector)) *constraint-universe*))
  54 (defvar *constraint-universe*)
  55
  56 (deftype constraint-y () '(or ctype lvar lambda-var constant))
  57
  58 (defstruct (constraint
  59             (:include sset-element)
  60             (:constructor make-constraint (number kind x y not-p))
  61             (:copier nil))
  62   ;; the kind of constraint we have:
  63   ;;
  64   ;; TYPEP
  65   ;;     X is a LAMBDA-VAR and Y is a CTYPE. The value of X is
  66   ;;     constrained to be of type Y.
  67   ;;
  68   ;; > or <
  69   ;;     X is a lambda-var and Y is a CTYPE. The relation holds
  70   ;;     between X and some object of type Y.
  71   ;;
  72   ;; EQL
  73   ;;     X is a LAMBDA-VAR and Y is a LVAR, a LAMBDA-VAR or a CONSTANT.
  74   ;;     The relation is asserted to hold.
  75   (kind nil :type (member typep < > eql))
  76   ;; The operands to the relation.
  77   (x nil :type lambda-var)
  78   (y nil :type constraint-y)
  79   ;; If true, negates the sense of the constraint, so the relation
  80   ;; does *not* hold.
  81   (not-p nil :type boolean))
  82 \f
  83 ;;; Historically, CMUCL and SBCL have used a sparse set implementation
  84 ;;; for which most operations are O(n) (see sset.lisp), but at the
  85 ;;; cost of at least a full word of pointer for each constraint set
  86 ;;; element.  Using bit-vectors instead of pointer structures saves a
  87 ;;; lot of space and thus GC time (particularly on 64-bit machines),
  88 ;;; and saves time on copy, union, intersection, and difference
  89 ;;; operations; but makes iteration slower.  Circa September 2008,
  90 ;;; switching to bit-vectors gave a modest (5-10%) improvement in real
  91 ;;; compile time for most Lisp systems, and as much as 20-30% for some
  92 ;;; particularly CP-dependent systems.
  93
  94 ;;; It's bad to leave commented code in files, but if some clever
  95 ;;; person comes along and makes SSETs better than bit-vectors as sets
  96 ;;; for constraint propagation, or if bit-vectors on some XC host
  97 ;;; really lose compared to SSETs, here's the conset API as a wrapper
  98 ;;; around SSETs:
  99 #+nil
 100 (progn
 101   (deftype conset () 'sset)
 102   (declaim (ftype (sfunction (conset) boolean) conset-empty))
 103   (declaim (ftype (sfunction (conset) conset) copy-conset))
 104   (declaim (ftype (sfunction (constraint conset) boolean) conset-member))
 105   (declaim (ftype (sfunction (constraint conset) boolean) conset-adjoin))
 106   (declaim (ftype (sfunction (conset conset) boolean) conset=))
 107   (declaim (ftype (sfunction (conset conset) (values)) conset-union))
 108   (declaim (ftype (sfunction (conset conset) (values)) conset-intersection))
 109   (declaim (ftype (sfunction (conset conset) (values)) conset-difference))
 110   (defun make-conset () (make-sset))
 111   (defmacro do-conset-elements ((constraint conset &optional result) &body body)
 112     `(do-sset-elements (,constraint ,conset ,result) ,@body))
 113   (defmacro do-conset-intersection
 114       ((constraint conset1 conset2 &optional result) &body body)
 115     `(do-conset-elements (,constraint ,conset1 ,result)
 116        (when (conset-member ,constraint ,conset2)
 117          ,@body)))
 118   (defun conset-empty (conset) (sset-empty conset))
 119   (defun copy-conset (conset) (copy-sset conset))
 120   (defun conset-member (constraint conset) (sset-member constraint conset))
 121   (defun conset-adjoin (constraint conset) (sset-adjoin constraint conset))
 122   (defun conset= (conset1 conset2) (sset= conset1 conset2))
 123   ;; Note: CP doesn't ever care whether union, intersection, and
 124   ;; difference change the first set.  (This is an important degree of
 125   ;; freedom, since some ways of implementing sets lose a great deal
 126   ;; when these operations are required to track changes.)
 127   (defun conset-union (conset1 conset2)
 128     (sset-union conset1 conset2) (values))
 129   (defun conset-intersection (conset1 conset2)
 130     (sset-intersection conset1 conset2) (values))
 131   (defun conset-difference (conset1 conset2)
 132     (sset-difference conset1 conset2) (values)))
 133
 134 (locally
 135     ;; This is performance critical for the compiler, and benefits
 136     ;; from the following declarations.  Probably you'll want to
 137     ;; disable these declarations when debugging consets.
 138     (declare #-sb-xc-host (optimize (speed 3) (safety 0) (space 0)))
 139   (declaim (inline %constraint-number))
 140   (defun %constraint-number (constraint)
 141     (sset-element-number constraint))
 142   (defstruct (conset
 143               (:constructor make-conset ())
 144               (:copier %copy-conset))
 145     (vector (make-array
 146              ;; FIXME: make POWER-OF-TWO-CEILING available earlier?
 147              (ash 1 (integer-length (1- (length *constraint-universe*))))
 148              :element-type 'bit :initial-element 0)
 149             :type simple-bit-vector)
 150     ;; Bit-vectors win over lightweight hashes for copy, union,
 151     ;; intersection, difference, but lose for iteration if you iterate
 152     ;; over the whole vector.  Tracking extrema helps a bit.
 153     (min 0 :type fixnum)
 154     (max 0 :type fixnum))
 155
 156   (defun conset-empty (conset)
 157     (or (= (conset-min conset) (conset-max conset))
 158         ;; TODO: I bet FIND on bit-vectors can be optimized, if it
 159         ;; isn't.
 160         (not (find 1 (conset-vector conset)
 161                    :start (conset-min conset)
 162                    ;; By inspection, supplying :END here breaks the
 163                    ;; build with a "full call to
 164                    ;; DATA-VECTOR-REF-WITH-OFFSET" in the
 165                    ;; cross-compiler.  If that should change, add
 166                    ;; :end (conset-max conset)
 167                    ))))
 168
 169   (defun copy-conset (conset)
 170     (let ((ret (%copy-conset conset)))
 171       (setf (conset-vector ret) (copy-seq (conset-vector conset)))
 172       ret))
 173
 174   (defun %conset-grow (conset new-size)
 175     (declare (type index new-size))
 176     (setf (conset-vector conset)
 177           (replace (the simple-bit-vector
 178                      (make-array
 179                       (ash 1 (integer-length (1- new-size)))
 180                       :element-type 'bit
 181                       :initial-element 0))
 182                    (the simple-bit-vector
 183                      (conset-vector conset)))))
 184
 185   (declaim (inline conset-grow))
 186   (defun conset-grow (conset new-size)
 187     (declare (type index new-size))
 188     (when (< (length (conset-vector conset)) new-size)
 189       (%conset-grow conset new-size))
 190     (values))
 191
 192   (defun conset-member (constraint conset)
 193     (let ((number (%constraint-number constraint))
 194           (vector (conset-vector conset)))
 195       (when (< number (length vector))
 196         (plusp (sbit vector number)))))
 197
 198   (defun conset-adjoin (constraint conset)
 199     (let ((number (%constraint-number constraint)))
 200       (conset-grow conset (1+ number))
 201       (setf (sbit (conset-vector conset) number) 1)
 202       (setf (conset-min conset) (min number (conset-min conset)))
 203       (when (>= number (conset-max conset))
 204         (setf (conset-max conset) (1+ number))))
 205     conset)
 206
 207   (defun conset= (conset1 conset2)
 208     (let* ((vector1 (conset-vector conset1))
 209            (vector2 (conset-vector conset2))
 210            (length1 (length vector1))
 211            (length2 (length vector2)))
 212       (if (= length1 length2)
 213           ;; When the lengths are the same, we can rely on EQUAL being
 214           ;; nicely optimized on bit-vectors.
 215           (equal vector1 vector2)
 216           (multiple-value-bind (shorter longer)
 217               (if (< length1 length2)
 218                   (values vector1 vector2)
 219                   (values vector2 vector1))
 220             ;; FIXME: make MISMATCH fast on bit-vectors.
 221             (dotimes (index (length shorter))
 222               (when (/= (sbit vector1 index) (sbit vector2 index))
 223                 (return-from conset= nil)))
 224             (if (find 1 longer :start (length shorter))
 225                 nil
 226                 t)))))
 227
 228   (macrolet
 229       ((defconsetop (name bit-op)
 230            `(defun ,name (conset-1 conset-2)
 231               (declare (optimize (speed 3) (safety 0)))
 232               (let* ((size-1 (length (conset-vector conset-1)))
 233                      (size-2 (length (conset-vector conset-2)))
 234                      (new-size (max size-1 size-2)))
 235                 (conset-grow conset-1 new-size)
 236                 (conset-grow conset-2 new-size))
 237               (let ((vector1 (conset-vector conset-1))
 238                     (vector2 (conset-vector conset-2)))
 239                 (declare (simple-bit-vector vector1 vector2))
 240                 (setf (conset-vector conset-1) (,bit-op vector1 vector2 t))
 241                 ;; Update the extrema.
 242                 ,(ecase name
 243                    ((conset-union)
 244                     `(setf (conset-min conset-1)
 245                            (min (conset-min conset-1)
 246                                 (conset-min conset-2))
 247                            (conset-max conset-1)
 248                            (max (conset-max conset-1)
 249                                 (conset-max conset-2))))
 250                    ((conset-intersection)
 251                     `(let ((start (max (conset-min conset-1)
 252                                        (conset-min conset-2)))
 253                            (end (min (conset-max conset-1)
 254                                      (conset-max conset-2))))
 255                        (setf (conset-min conset-1)
 256                              (if (> start end)
 257                                  0
 258                                  (or (position 1 (conset-vector conset-1)
 259                                                :start start :end end)
 260                                      0))
 261                              (conset-max conset-1)
 262                              (if (> start end)
 263                                  0
 264                                  (let ((position
 265                                         (position
 266                                          1 (conset-vector conset-1)
 267                                          :start start :end end :from-end t)))
 268                                    (if position
 269                                        (1+ position)
 270                                        0))))))
 271                    ((conset-difference)
 272                     `(setf (conset-min conset-1)
 273                            (or (position 1 (conset-vector conset-1)
 274                                          :start (conset-min conset-1)
 275                                          :end (conset-max conset-1))
 276                                0)
 277                            (conset-max conset-1)
 278                            (let ((position
 279                                   (position
 280                                    1 (conset-vector conset-1)
 281                                    :start (conset-min conset-1)
 282                                    :end (conset-max conset-1)
 283                                    :from-end t)))
 284                              (if position
 285                                  (1+ position)
 286                                  0))))))
 287               (values))))
 288     (defconsetop conset-union bit-ior)
 289     (defconsetop conset-intersection bit-and)
 290     (defconsetop conset-difference bit-andc2)))
 291 \f
 292 ;;; Constraints are hash-consed. Unfortunately, types aren't, so we have
 293 ;;; to over-approximate and then linear search through the potential hits.
 294 ;;; LVARs can only be found in EQL (not-p = NIL) constraints, while constant
 295 ;;; and lambda-vars can only be found in EQL constraints.
 296 (defun find-constraint (kind x y not-p)
 297   (declare (type lambda-var x) (type constraint-y y) (type boolean not-p))
 298   (etypecase y
 299     (ctype
 300        (awhen (lambda-var-ctype-constraints x)
 301          (dolist (con (gethash (sb!kernel::type-class-info y) it) nil)
 302            (when (and (eq (constraint-kind con) kind)
 303                       (eq (constraint-not-p con) not-p)
 304                       (type= (constraint-y con) y))
 305              (return-from find-constraint con)))
 306          nil))
 307     (lvar
 308        (awhen (lambda-var-eq-constraints x)
 309          (gethash y it)))
 310     ((or constant lambda-var)
 311        (awhen (lambda-var-eq-constraints x)
 312          (let ((cache (gethash y it)))
 313            (declare (type list cache))
 314            (if not-p (cdr cache) (car cache)))))))
 315
 316 ;;; The most common operations on consets are iterating through the constraints
 317 ;;; that are related to a certain variable in a given conset.  Storing the
 318 ;;; constraints related to each variable in vectors allows us to easily iterate
 319 ;;; through the intersection of such constraints and the constraints in a conset.
 320 ;;;
 321 ;;; EQL-var constraints assert that two lambda-vars are EQL.
 322 ;;; Private constraints assert that a lambda-var is EQL or not EQL to a constant.
 323 ;;; Inheritable constraints are constraints that may be propagated to EQL
 324 ;;; lambda-vars (along with EQL-var constraints).
 325 ;;;
 326 ;;; Lambda-var -- lvar EQL constraints only serve one purpose: remember whether
 327 ;;; an lvar is (only) written to by a ref to that lambda-var, and aren't ever
 328 ;;; propagated.
 329 ;;;
 330 ;;; Finally, the lambda-var conset is only used to track the whole set of
 331 ;;; constraints associated with a given lambda-var, and thus easily delete
 332 ;;; such constraints from a conset.
 333 (defun register-constraint (x con y)
 334   (declare (type lambda-var x) (type constraint con) (type constraint-y y))
 335   (conset-adjoin con (lambda-var-constraints x))
 336   (macrolet ((ensuref (place default)
 337                `(or ,place (setf ,place ,default)))
 338              (ensure-hash (place)
 339                `(ensuref ,place (make-hash-table)))
 340              (ensure-vec (place)
 341                `(ensuref ,place (make-array 8 :adjustable t :fill-pointer 0))))
 342     (etypecase y
 343       (ctype
 344        (let ((index (ensure-hash (lambda-var-ctype-constraints x)))
 345              (vec   (ensure-vec  (lambda-var-inheritable-constraints x))))
 346          (push con (gethash (sb!kernel::type-class-info y) index))
 347          (vector-push-extend con vec)))
 348       (lvar
 349        (let ((index (ensure-hash (lambda-var-eq-constraints x))))
 350          (setf (gethash y index) con)))
 351       ((or constant lambda-var)
 352        (let* ((index (ensure-hash (lambda-var-eq-constraints x)))
 353               (cons  (ensuref (gethash y index) (list nil))))
 354          (if (constraint-not-p con)
 355              (setf (cdr cons) con)
 356              (setf (car cons) con)))
 357        (typecase y
 358          (constant
 359           (let ((vec (ensure-vec (lambda-var-private-constraints x))))
 360             (vector-push-extend con vec)))
 361          (lambda-var
 362           (let ((vec (if (constraint-not-p con)
 363                          (ensure-vec (lambda-var-inheritable-constraints x))
 364                          (ensure-vec (lambda-var-eql-var-constraints x)))))
 365             (vector-push-extend con vec)))))))
 366   nil)
 367
 368 ;;; Return a constraint for the specified arguments. We only create a
 369 ;;; new constraint if there isn't already an equivalent old one,
 370 ;;; guaranteeing that all equivalent constraints are EQ. This
 371 ;;; shouldn't be called on LAMBDA-VARs with no CONSTRAINTS set.
 372 (defun find-or-create-constraint (kind x y not-p)
 373   (declare (type lambda-var x) (type constraint-y y) (type boolean not-p))
 374   (or (find-constraint kind x y not-p)
 375       (let ((new (make-constraint (length *constraint-universe*)
 376                                   kind x y not-p)))
 377         (vector-push-extend new *constraint-universe*
 378                             (1+ (length *constraint-universe*)))
 379         (register-constraint x new y)
 380         (when (lambda-var-p y)
 381           (register-constraint y new x))
 382         new)))
 383 \f
 384 ;;; Actual conset interface
 385 ;;;
 386 ;;; Constraint propagation needs to iterate over the set of lambda-vars known to
 387 ;;; be EQL to a given variable (including itself), via DO-EQL-VARS.
 388 ;;;
 389 ;;; It also has to iterate through constraints that are inherited by EQL variables
 390 ;;; (DO-INHERITABLE-CONSTRAINTS), and through constraints used by
 391 ;;; CONSTRAIN-REF-TYPE (to derive the type of a REF to a lambda-var).
 392 ;;;
 393 ;;; Consets must keep track of which lvars are EQL to a given lambda-var (result
 394 ;;; from a REF to the lambda-var): CONSET-LVAR-LAMBDA-VAR-EQL-P and
 395 ;;; CONSET-ADD-LVAR-LAMBDA-VAR-EQL.  This, as all other constraints, must of
 396 ;;; course be cleared when a lambda-var's constraints are dropped because of
 397 ;;; assignment.
 398 ;;;
 399 ;;; Consets must be able to add constraints to a given lambda-var
 400 ;;; (CONSET-ADD-CONSTRAINT), and to the set of variables EQL to a given
 401 ;;; lambda-var (CONSET-ADD-CONSTRAINT-TO-EQL).
 402 ;;;
 403 ;;; When a lambda-var is assigned to, all the constraints involving that variable
 404 ;;; must be dropped: constraint propagation is flow-sensitive, so the constraints
 405 ;;; relate to the variable at a given range of program point.  In such cases,
 406 ;;; constraint propagation calls CONSET-CLEAR-LAMBDA-VAR.
 407 ;;;
 408 ;;; Finally, one of the main strengths of constraint propagation in SBCL is the
 409 ;;; tracking of EQL variables to help constraint propagation.  When two variables
 410 ;;; are known to be EQL (e.g. after a branch), ADD-EQL-VAR-VAR-CONSTRAINT is
 411 ;;; called to add the EQL constraint, but also have each equality class inherit
 412 ;;; the other's (inheritable) constraints.
 413 ;;;
 414 ;;; On top of that, we have the usual bulk set operations: intersection, copy,
 415 ;;; equality or emptiness testing.  There's also union, but that's only an
 416 ;;; optimisation to avoid useless copies in ADD-TEST-CONSTRAINTS and
 417 ;;; FIND-BLOCK-TYPE-CONSTRAINTS.
 418 (defmacro do-conset-constraints-intersection ((symbol (conset constraints) &optional result)
 419                                               &body body)
 420   (let ((min (gensym "MIN"))
 421         (max (gensym "MAX")))
 422     (once-only ((conset conset)
 423                 (constraints constraints))
 424       `(flet ((body (,symbol)
 425                 (declare (type constraint ,symbol))
 426                 ,@body))
 427          (when ,constraints
 428            (let ((,min (conset-min ,conset))
 429                  (,max (conset-max ,conset)))
 430              (declare (optimize speed))
 431              (map nil (lambda (constraint)
 432                         (declare (type constraint constraint))
 433                         (let ((number (constraint-number constraint)))
 434                           (when (and (<= ,min number)
 435                                      (< number ,max)
 436                                      (conset-member constraint ,conset))
 437                             (body constraint))))
 438                   ,constraints)))
 439          ,result))))
 440
 441 (defmacro do-eql-vars ((symbol (var constraints) &optional result) &body body)
 442   (once-only ((var         var)
 443               (constraints constraints))
 444     `(flet ((body-fun (,symbol)
 445               ,@body))
 446        (body-fun ,var)
 447        (do-conset-constraints-intersection
 448            (con (,constraints (lambda-var-eql-var-constraints ,var)) ,result)
 449          (let ((x (constraint-x con))
 450                (y (constraint-y con)))
 451            (body-fun (if (eq ,var x) y x)))))))
 452
 453 (defmacro do-inheritable-constraints ((symbol (conset variable) &optional result)
 454                                       &body body)
 455   (once-only ((conset   conset)
 456               (variable variable))
 457     `(block nil
 458        (flet ((body-fun (,symbol)
 459                 ,@body))
 460          (do-conset-constraints-intersection
 461              (con (,conset (lambda-var-inheritable-constraints ,variable)))
 462            (body-fun con))
 463          (do-conset-constraints-intersection
 464              (con (,conset (lambda-var-eql-var-constraints ,variable)) ,result)
 465            (body-fun con))))))
 466
 467 (defmacro do-propagatable-constraints ((symbol (conset variable) &optional result)
 468                                        &body body)
 469   (once-only ((conset conset)
 470               (variable variable))
 471     `(block nil
 472        (flet ((body-fun (,symbol)
 473                 ,@body))
 474          (do-conset-constraints-intersection
 475              (con (,conset (lambda-var-private-constraints ,variable)))
 476            (body-fun con))
 477          (do-conset-constraints-intersection
 478              (con (,conset (lambda-var-eql-var-constraints ,variable)))
 479            (body-fun con))
 480          (do-conset-constraints-intersection
 481              (con (,conset (lambda-var-inheritable-constraints ,variable)) ,result)
 482            (body-fun con))))))
 483
 484 (declaim (inline conset-lvar-lambda-var-eql-p conset-add-lvar-lambda-var-eql))
 485 (defun conset-lvar-lambda-var-eql-p (conset lvar lambda-var)
 486   (let ((constraint (find-constraint 'eql lambda-var lvar nil)))
 487     (and constraint
 488          (conset-member constraint conset))))
 489
 490 (defun conset-add-lvar-lambda-var-eql (conset lvar lambda-var)
 491   (let ((constraint (find-or-create-constraint 'eql lambda-var lvar nil)))
 492     (conset-adjoin constraint conset)))
 493
 494 (declaim (inline conset-add-constraint conset-add-constraint-to-eql))
 495 (defun conset-add-constraint (conset kind x y not-p)
 496   (declare (type conset conset)
 497            (type lambda-var x))
 498   (conset-adjoin (find-or-create-constraint kind x y not-p)
 499                  conset))
 500
 501 (defun conset-add-constraint-to-eql (conset kind x y not-p &optional (target conset))
 502   (declare (type conset target conset)
 503            (type lambda-var x))
 504   (do-eql-vars (x (x conset))
 505     (conset-add-constraint target kind x y not-p)))
 506
 507 (declaim (inline conset-clear-lambda-var))
 508 (defun conset-clear-lambda-var (conset var)
 509   (conset-difference conset (lambda-var-constraints var)))
 510
 511 ;;; Copy all CONSTRAINTS involving FROM-VAR - except the (EQL VAR
 512 ;;; LVAR) ones - to all of the variables in the VARS list.
 513 (defun inherit-constraints (vars from-var constraints target)
 514   (do-inheritable-constraints (con (constraints from-var))
 515     (let ((eq-x (eq from-var (constraint-x con)))
 516           (eq-y (eq from-var (constraint-y con))))
 517       (dolist (var vars)
 518         (conset-add-constraint target
 519                                (constraint-kind con)
 520                                (if eq-x var (constraint-x con))
 521                                (if eq-y var (constraint-y con))
 522                                (constraint-not-p con))))))
 523
 524 ;; Add an (EQL LAMBDA-VAR LAMBDA-VAR) constraint on VAR1 and VAR2 and
 525 ;; inherit each other's constraints.
 526 (defun add-eql-var-var-constraint (var1 var2 constraints
 527                                    &optional (target constraints))
 528   (let ((constraint (find-or-create-constraint 'eql var1 var2 nil)))
 529     (unless (conset-member constraint target)
 530       (conset-adjoin constraint target)
 531       (collect ((eql1) (eql2))
 532         (do-eql-vars (var1 (var1 constraints))
 533           (eql1 var1))
 534         (do-eql-vars (var2 (var2 constraints))
 535           (eql2 var2))
 536         (inherit-constraints (eql1) var2 constraints target)
 537         (inherit-constraints (eql2) var1 constraints target))
 538       t)))
 539 \f
 540 ;;; If REF is to a LAMBDA-VAR with CONSTRAINTs (i.e. we can do flow
 541 ;;; analysis on it), then return the LAMBDA-VAR, otherwise NIL.
 542 #!-sb-fluid (declaim (inline ok-ref-lambda-var))
 543 (defun ok-ref-lambda-var (ref)
 544   (declare (type ref ref))
 545   (let ((leaf (ref-leaf ref)))
 546     (when (and (lambda-var-p leaf)
 547                (lambda-var-constraints leaf))
 548       leaf)))
 549
 550 ;;; See if LVAR's single USE is a REF to a LAMBDA-VAR and they are EQL
 551 ;;; according to CONSTRAINTS. Return LAMBDA-VAR if so.
 552 (defun ok-lvar-lambda-var (lvar constraints)
 553   (declare (type lvar lvar))
 554   (let ((use (lvar-uses lvar)))
 555     (cond ((ref-p use)
 556            (let ((lambda-var (ok-ref-lambda-var use)))
 557              (and lambda-var
 558                   (conset-lvar-lambda-var-eql-p constraints lvar lambda-var)
 559                   lambda-var)))
 560           ((cast-p use)
 561            (ok-lvar-lambda-var (cast-value use) constraints)))))
 562 ;;;; Searching constraints
 563
 564 ;;; Add the indicated test constraint to BLOCK. We don't add the
 565 ;;; constraint if the block has multiple predecessors, since it only
 566 ;;; holds on this particular path.
 567 (defun precise-add-test-constraint (fun x y not-p constraints target)
 568   (if (and (eq 'eql fun) (lambda-var-p y) (not not-p))
 569       (add-eql-var-var-constraint x y constraints target)
 570       (conset-add-constraint-to-eql constraints fun x y not-p target))
 571   (values))
 572
 573 (defun add-test-constraint (quick-p fun x y not-p constraints target)
 574   (cond (quick-p
 575          (conset-add-constraint target fun x y not-p))
 576         (t
 577          (precise-add-test-constraint fun x y not-p constraints target))))
 578 ;;; Add complementary constraints to the consequent and alternative
 579 ;;; blocks of IF. We do nothing if X is NIL.
 580 (declaim (inline precise-add-test-constraint quick-add-complement-constraints))
 581 (defun precise-add-complement-constraints (fun x y not-p constraints
 582                                            consequent-constraints
 583                                            alternative-constraints)
 584   (when x
 585     (precise-add-test-constraint fun x y not-p constraints
 586                                 consequent-constraints)
 587     (precise-add-test-constraint fun x y (not not-p) constraints
 588                                  alternative-constraints))
 589   (values))
 590
 591 (defun quick-add-complement-constraints (fun x y not-p
 592                                          consequent-constraints
 593                                          alternative-constraints)
 594   (when x
 595     (conset-add-constraint consequent-constraints fun x y not-p)
 596     (conset-add-constraint alternative-constraints fun x y (not not-p)))
 597   (values))
 598
 599 (defun add-complement-constraints (quick-p fun x y not-p constraints
 600                                    consequent-constraints
 601                                    alternative-constraints)
 602   (if quick-p
 603       (quick-add-complement-constraints fun x y not-p
 604                                         consequent-constraints
 605                                         alternative-constraints)
 606       (precise-add-complement-constraints fun x y not-p constraints
 607                                           consequent-constraints
 608                                           alternative-constraints)))
 609
 610 ;;; Add test constraints to the consequent and alternative blocks of
 611 ;;; the test represented by USE.
 612 (defun add-test-constraints (use if constraints)
 613   (declare (type node use) (type cif if))
 614   ;; Note: Even if we do (IF test exp exp) => (PROGN test exp)
 615   ;; optimization, the *MAX-OPTIMIZE-ITERATIONS* cutoff means that we
 616   ;; can't guarantee that the optimization will be done, so we still
 617   ;; need to avoid barfing on this case.
 618   (unless (eq (if-consequent if) (if-alternative if))
 619     (let ((consequent-constraints (make-conset))
 620           (alternative-constraints (make-conset))
 621           (quick-p (policy if (> compilation-speed speed))))
 622       (macrolet ((add (fun x y not-p)
 623                    `(add-complement-constraints quick-p
 624                                                 ,fun ,x ,y ,not-p
 625                                                 constraints
 626                                                 consequent-constraints
 627                                                 alternative-constraints)))
 628         (typecase use
 629           (ref
 630            (add 'typep (ok-lvar-lambda-var (ref-lvar use) constraints)
 631                 (specifier-type 'null) t))
 632           (combination
 633            (unless (eq (combination-kind use)
 634                        :error)
 635              (let ((name (lvar-fun-name
 636                           (basic-combination-fun use)))
 637                    (args (basic-combination-args use)))
 638                (case name
 639                  ((%typep %instance-typep)
 640                   (let ((type (second args)))
 641                     (when (constant-lvar-p type)
 642                       (let ((val (lvar-value type)))
 643                         (add 'typep
 644                              (ok-lvar-lambda-var (first args) constraints)
 645                              (if (ctype-p val)
 646                                  val
 647                                  (let ((*compiler-error-context* use))
 648                                    (specifier-type val)))
 649                              nil)))))
 650                  ((eq eql)
 651                   (let* ((arg1 (first args))
 652                          (var1 (ok-lvar-lambda-var arg1 constraints))
 653                          (arg2 (second args))
 654                          (var2 (ok-lvar-lambda-var arg2 constraints)))
 655                     ;; The code below assumes that the constant is the
 656                     ;; second argument in case of variable to constant
 657                     ;; comparision which is sometimes true (see source
 658                     ;; transformations for EQ, EQL and CHAR=). Fixing
 659                     ;; that would result in more constant substitutions
 660                     ;; which is not a universally good thing, thus the
 661                     ;; unnatural asymmetry of the tests.
 662                     (cond ((not var1)
 663                            (when var2
 664                              (add-test-constraint quick-p
 665                                                   'typep var2 (lvar-type arg1)
 666                                                   nil constraints
 667                                                   consequent-constraints)))
 668                           (var2
 669                            (add 'eql var1 var2 nil))
 670                           ((constant-lvar-p arg2)
 671                            (add 'eql var1
 672                                 (find-constant (lvar-value arg2))
 673                                 nil))
 674                           (t
 675                            (add-test-constraint quick-p
 676                                                 'typep var1 (lvar-type arg2)
 677                                                 nil constraints
 678                                                 consequent-constraints)))))
 679                  ((< >)
 680                   (let* ((arg1 (first args))
 681                          (var1 (ok-lvar-lambda-var arg1 constraints))
 682                          (arg2 (second args))
 683                          (var2 (ok-lvar-lambda-var arg2 constraints)))
 684                     (when var1
 685                       (add name var1 (lvar-type arg2) nil))
 686                     (when var2
 687                       (add (if (eq name '<) '> '<) var2 (lvar-type arg1) nil))))
 688                  (t
 689                   (let ((ptype (gethash name *backend-predicate-types*)))
 690                     (when ptype
 691                       (add 'typep (ok-lvar-lambda-var (first args) constraints)
 692                            ptype nil))))))))))
 693       (values consequent-constraints alternative-constraints))))
 694
 695 ;;;; Applying constraints
 696
 697 ;;; Return true if X is an integer NUMERIC-TYPE.
 698 (defun integer-type-p (x)
 699   (declare (type ctype x))
 700   (and (numeric-type-p x)
 701        (eq (numeric-type-class x) 'integer)
 702        (eq (numeric-type-complexp x) :real)))
 703
 704 ;;; Given that an inequality holds on values of type X and Y, return a
 705 ;;; new type for X. If GREATER is true, then X was greater than Y,
 706 ;;; otherwise less. If OR-EQUAL is true, then the inequality was
 707 ;;; inclusive, i.e. >=.
 708 ;;;
 709 ;;; If GREATER (or not), then we max (or min) in Y's lower (or upper)
 710 ;;; bound into X and return that result. If not OR-EQUAL, we can go
 711 ;;; one greater (less) than Y's bound.
 712 (defun constrain-integer-type (x y greater or-equal)
 713   (declare (type numeric-type x y))
 714   (flet ((exclude (x)
 715            (cond ((not x) nil)
 716                  (or-equal x)
 717                  (greater (1+ x))
 718                  (t (1- x))))
 719          (bound (x)
 720            (if greater (numeric-type-low x) (numeric-type-high x))))
 721     (let* ((x-bound (bound x))
 722            (y-bound (exclude (bound y)))
 723            (new-bound (cond ((not x-bound) y-bound)
 724                             ((not y-bound) x-bound)
 725                             (greater (max x-bound y-bound))
 726                             (t (min x-bound y-bound)))))
 727       (if greater
 728           (modified-numeric-type x :low new-bound)
 729           (modified-numeric-type x :high new-bound)))))
 730
 731 ;;; Return true if X is a float NUMERIC-TYPE.
 732 (defun float-type-p (x)
 733   (declare (type ctype x))
 734   (and (numeric-type-p x)
 735        (eq (numeric-type-class x) 'float)
 736        (eq (numeric-type-complexp x) :real)))
 737
 738 ;;; Exactly the same as CONSTRAIN-INTEGER-TYPE, but for float numbers.
 739 ;;;
 740 ;;; In contrast to the integer version, here the input types can have
 741 ;;; open bounds in addition to closed ones and we don't increment or
 742 ;;; decrement a bound to honor OR-EQUAL being NIL but put an open bound
 743 ;;; into the result instead, if appropriate.
 744 (defun constrain-float-type (x y greater or-equal)
 745   (declare (type numeric-type x y))
 746   (declare (ignorable x y greater or-equal)) ; for CROSS-FLOAT-INFINITY-KLUDGE
 747
 748   (aver (eql (numeric-type-class x) 'float))
 749   (aver (eql (numeric-type-class y) 'float))
 750   #+sb-xc-host                    ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 751   x
 752   #-sb-xc-host                    ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 753   (labels ((exclude (x)
 754              (cond ((not x) nil)
 755                    (or-equal x)
 756                    (t
 757                     (if (consp x)
 758                         x
 759                         (list x)))))
 760            (bound (x)
 761              (if greater (numeric-type-low x) (numeric-type-high x)))
 762            (tighter-p (x ref)
 763              (cond ((null x) nil)
 764                    ((null ref) t)
 765                    ((= (type-bound-number x) (type-bound-number ref))
 766                     ;; X is tighter if X is an open bound and REF is not
 767                     (and (consp x) (not (consp ref))))
 768                    (greater
 769                     (< (type-bound-number ref) (type-bound-number x)))
 770                    (t
 771                     (> (type-bound-number ref) (type-bound-number x))))))
 772     (let* ((x-bound (bound x))
 773            (y-bound (exclude (bound y)))
 774            (new-bound (cond ((not x-bound)
 775                              y-bound)
 776                             ((not y-bound)
 777                              x-bound)
 778                             ((tighter-p y-bound x-bound)
 779                              y-bound)
 780                             (t
 781                              x-bound))))
 782       (if greater
 783           (modified-numeric-type x :low new-bound)
 784           (modified-numeric-type x :high new-bound)))))
 785
 786 ;;; Return true if LEAF is "visible" from NODE.
 787 (defun leaf-visible-from-node-p (leaf node)
 788   (cond
 789    ((lambda-var-p leaf)
 790     ;; A LAMBDA-VAR is visible iif it is homed in a CLAMBDA that is an
 791     ;; ancestor for NODE.
 792     (let ((leaf-lambda (lambda-var-home leaf)))
 793       (loop for lambda = (node-home-lambda node)
 794             then (lambda-parent lambda)
 795             while lambda
 796             when (eq lambda leaf-lambda)
 797             return t)))
 798    ;; FIXME: Check on FUNCTIONALs (CLAMBDAs and OPTIONAL-DISPATCHes),
 799    ;; not just LAMBDA-VARs.
 800    (t
 801     ;; Assume everything else is globally visible.
 802     t)))
 803
 804 ;;; Given the set of CONSTRAINTS for a variable and the current set of
 805 ;;; restrictions from flow analysis IN, set the type for REF
 806 ;;; accordingly.
 807 (defun constrain-ref-type (ref in)
 808   (declare (type ref ref) (type conset in))
 809   ;; KLUDGE: The NOT-SET and NOT-FPZ here are so that we don't need to
 810   ;; cons up endless union types when propagating large number of EQL
 811   ;; constraints -- eg. from large CASE forms -- instead we just
 812   ;; directly accumulate one XSET, and a set of fp zeroes, which we at
 813   ;; the end turn into a MEMBER-TYPE.
 814   ;;
 815   ;; Since massive symbol cases are an especially atrocious pattern
 816   ;; and the (NOT (MEMBER ...ton of symbols...)) will never turn into
 817   ;; a more useful type, don't propagate their negation except for NIL
 818   ;; unless SPEED > COMPILATION-SPEED.
 819   (let ((res (single-value-type (node-derived-type ref)))
 820         (constrain-symbols (policy ref (> speed compilation-speed)))
 821         (not-set (alloc-xset))
 822         (not-fpz nil)
 823         (not-res *empty-type*)
 824         (leaf (ref-leaf ref)))
 825     (declare (type lambda-var leaf))
 826     (flet ((note-not (x)
 827              (if (fp-zero-p x)
 828                  (push x not-fpz)
 829                  (when (or constrain-symbols (null x) (not (symbolp x)))
 830                    (add-to-xset x not-set)))))
 831       (do-propagatable-constraints (con (in leaf))
 832         (let* ((x (constraint-x con))
 833                (y (constraint-y con))
 834                (not-p (constraint-not-p con))
 835                (other (if (eq x leaf) y x))
 836                (kind (constraint-kind con)))
 837           (case kind
 838             (typep
 839              (if not-p
 840                  (if (member-type-p other)
 841                      (mapc-member-type-members #'note-not other)
 842                      (setq not-res (type-union not-res other)))
 843                  (setq res (type-approx-intersection2 res other))))
 844             (eql
 845              (let ((other-type (leaf-type other)))
 846                (if not-p
 847                    (when (and (constant-p other)
 848                               (member-type-p other-type))
 849                      (note-not (constant-value other)))
 850                    (let ((leaf-type (leaf-type leaf)))
 851                      (cond
 852                        ((or (constant-p other)
 853                             (and (leaf-refs other) ; protect from
 854                                         ; deleted vars
 855                                  (csubtypep other-type leaf-type)
 856                                  (not (type= other-type leaf-type))
 857                                  ;; Don't change to a LEAF not visible here.
 858                                  (leaf-visible-from-node-p other ref)))
 859                         (change-ref-leaf ref other)
 860                         (when (constant-p other) (return)))
 861                        (t
 862                         (setq res (type-approx-intersection2
 863                                    res other-type))))))))
 864             ((< >)
 865              (cond
 866                ((and (integer-type-p res) (integer-type-p y))
 867                 (let ((greater (eq kind '>)))
 868                   (let ((greater (if not-p (not greater) greater)))
 869                     (setq res
 870                           (constrain-integer-type res y greater not-p)))))
 871                ((and (float-type-p res) (float-type-p y))
 872                 (let ((greater (eq kind '>)))
 873                   (let ((greater (if not-p (not greater) greater)))
 874                     (setq res
 875                           (constrain-float-type res y greater not-p)))))))))))
 876     (cond ((and (if-p (node-dest ref))
 877                 (or (xset-member-p nil not-set)
 878                     (csubtypep (specifier-type 'null) not-res)))
 879            (setf (node-derived-type ref) *wild-type*)
 880            (change-ref-leaf ref (find-constant t)))
 881           (t
 882            (setf not-res
 883                  (type-union not-res (make-member-type :xset not-set :fp-zeroes not-fpz)))
 884            (derive-node-type ref
 885                              (make-single-value-type
 886                               (or (type-difference res not-res)
 887                                   res)))
 888            (maybe-terminate-block ref nil))))
 889   (values))
 890
 891 ;;;; Flow analysis
 892
 893 (defun maybe-add-eql-var-lvar-constraint (ref gen)
 894   (let ((lvar (ref-lvar ref))
 895         (leaf (ref-leaf ref)))
 896     (when (and (lambda-var-p leaf) lvar)
 897       (conset-add-lvar-lambda-var-eql gen lvar leaf))))
 898
 899 ;; Add an (EQL LAMBDA-VAR LAMBDA-VAR) constraint on VAR and LVAR's
 900 ;; LAMBDA-VAR if possible.
 901 (defun maybe-add-eql-var-var-constraint (var lvar constraints
 902                                          &optional (target constraints))
 903   (declare (type lambda-var var) (type lvar lvar))
 904   (let ((lambda-var (ok-lvar-lambda-var lvar constraints)))
 905     (when lambda-var
 906       (add-eql-var-var-constraint var lambda-var constraints target))))
 907
 908 ;;; Local propagation
 909 ;;; -- [TODO: For any LAMBDA-VAR ref with a type check, add that
 910 ;;;    constraint.]
 911 ;;; -- For any LAMBDA-VAR set, delete all constraints on that var; add
 912 ;;;    a type constraint based on the new value type.
 913 (declaim (ftype (function (cblock conset boolean)
 914                           conset)
 915                 constraint-propagate-in-block))
 916 (defun constraint-propagate-in-block (block gen preprocess-refs-p)
 917   (do-nodes (node lvar block)
 918     (typecase node
 919       (bind
 920        (let ((fun (bind-lambda node)))
 921          (when (eq (functional-kind fun) :let)
 922            (loop with call = (lvar-dest (node-lvar (first (lambda-refs fun))))
 923                  for var in (lambda-vars fun)
 924                  and val in (combination-args call)
 925                  when (and val (lambda-var-constraints var))
 926                  do (let ((type (lvar-type val)))
 927                       (unless (eq type *universal-type*)
 928                         (conset-add-constraint gen 'typep var type nil)))
 929                     (maybe-add-eql-var-var-constraint var val gen)))))
 930       (ref
 931        (when (ok-ref-lambda-var node)
 932          (maybe-add-eql-var-lvar-constraint node gen)
 933          (when preprocess-refs-p
 934            (constrain-ref-type node gen))))
 935       (cast
 936        (let ((lvar (cast-value node)))
 937          (let ((var (ok-lvar-lambda-var lvar gen)))
 938            (when var
 939              (let ((atype (single-value-type (cast-derived-type node)))) ;FIXME
 940                (unless (eq atype *universal-type*)
 941                  (conset-add-constraint-to-eql gen 'typep var atype nil)))))))
 942       (cset
 943        (binding* ((var (set-var node))
 944                   (nil (lambda-var-p var) :exit-if-null)
 945                   (nil (lambda-var-constraints var) :exit-if-null))
 946          (when (policy node (and (= speed 3) (> speed compilation-speed)))
 947            (let ((type (lambda-var-type var)))
 948              (unless (eql *universal-type* type)
 949                (do-eql-vars (other (var gen))
 950                  (unless (eql other var)
 951                    (conset-add-constraint gen 'typep other type nil))))))
 952          (conset-clear-lambda-var gen var)
 953          (let ((type (single-value-type (node-derived-type node))))
 954            (unless (eq type *universal-type*)
 955              (conset-add-constraint gen 'typep var type nil)))
 956          (unless (policy node (> compilation-speed speed))
 957            (maybe-add-eql-var-var-constraint var (set-value node) gen))))))
 958   gen)
 959
 960 (defun constraint-propagate-if (block gen)
 961   (let ((node (block-last block)))
 962     (when (if-p node)
 963       (let ((use (lvar-uses (if-test node))))
 964         (when (node-p use)
 965           (add-test-constraints use node gen))))))
 966
 967 ;;; Starting from IN compute OUT and (consequent/alternative
 968 ;;; constraints if the block ends with and IF). Return the list of
 969 ;;; successors that may need to be recomputed.
 970 (defun find-block-type-constraints (block final-pass-p)
 971   (declare (type cblock block))
 972   (let ((gen (constraint-propagate-in-block
 973               block
 974               (if final-pass-p
 975                   (block-in block)
 976                   (copy-conset (block-in block)))
 977               final-pass-p)))
 978     (setf (block-gen block) gen)
 979     (multiple-value-bind (consequent-constraints alternative-constraints)
 980         (constraint-propagate-if block gen)
 981       (if consequent-constraints
 982           (let* ((node (block-last block))
 983                  (old-consequent-constraints (if-consequent-constraints node))
 984                  (old-alternative-constraints (if-alternative-constraints node))
 985                  (succ ()))
 986             ;; Add the consequent and alternative constraints to GEN.
 987             (cond ((conset-empty consequent-constraints)
 988                    (setf (if-consequent-constraints node) gen)
 989                    (setf (if-alternative-constraints node) gen))
 990                   (t
 991                    (setf (if-consequent-constraints node) (copy-conset gen))
 992                    (conset-union (if-consequent-constraints node)
 993                                  consequent-constraints)
 994                    (setf (if-alternative-constraints node) gen)
 995                    (conset-union (if-alternative-constraints node)
 996                                  alternative-constraints)))
 997             ;; Has the consequent been changed?
 998             (unless (and old-consequent-constraints
 999                          (conset= (if-consequent-constraints node)
1000                                   old-consequent-constraints))
1001               (push (if-consequent node) succ))
1002             ;; Has the alternative been changed?
1003             (unless (and old-alternative-constraints
1004                          (conset= (if-alternative-constraints node)
1005                                   old-alternative-constraints))
1006               (push (if-alternative node) succ))
1007             succ)
1008           ;; There is no IF.
1009           (unless (and (block-out block)
1010                        (conset= gen (block-out block)))
1011             (setf (block-out block) gen)
1012             (block-succ block))))))
1013
1014 ;;; Deliver the results of constraint propagation to REFs in BLOCK.
1015 ;;; During this pass, we also do local constraint propagation by
1016 ;;; adding in constraints as we see them during the pass through the
1017 ;;; block.
1018 (defun use-result-constraints (block)
1019   (declare (type cblock block))
1020   (constraint-propagate-in-block block (block-in block) t))
1021
1022 ;;; Give an empty constraints set to any var that doesn't have one and
1023 ;;; isn't a set closure var. Since a var that we previously rejected
1024 ;;; looks identical to one that is new, so we optimistically keep
1025 ;;; hoping that vars stop being closed over or lose their sets.
1026 (defun init-var-constraints (component)
1027   (declare (type component component))
1028   (dolist (fun (component-lambdas component))
1029     (flet ((frob (x)
1030              (dolist (var (lambda-vars x))
1031                (unless (lambda-var-constraints var)
1032                  (when (or (null (lambda-var-sets var))
1033                            (not (closure-var-p var)))
1034                    (setf (lambda-var-constraints var) (make-conset)))))))
1035       (frob fun)
1036       (dolist (let (lambda-lets fun))
1037         (frob let)))))
1038
1039 ;;; Return the constraints that flow from PRED to SUCC. This is
1040 ;;; BLOCK-OUT unless PRED ends with an IF and test constraints were
1041 ;;; added.
1042 (defun block-out-for-successor (pred succ)
1043   (declare (type cblock pred succ))
1044   (let ((last (block-last pred)))
1045     (or (when (if-p last)
1046           (cond ((eq succ (if-consequent last))
1047                  (if-consequent-constraints last))
1048                 ((eq succ (if-alternative last))
1049                  (if-alternative-constraints last))))
1050         (block-out pred))))
1051
1052 (defun compute-block-in (block)
1053   (let ((in nil))
1054     (dolist (pred (block-pred block))
1055       ;; If OUT has not been calculated, assume it to be the universal
1056       ;; set.
1057       (let ((out (block-out-for-successor pred block)))
1058         (when out
1059           (if in
1060               (conset-intersection in out)
1061               (setq in (copy-conset out))))))
1062     (or in (make-conset))))
1063
1064 (defun update-block-in (block)
1065   (let ((in (compute-block-in block)))
1066     (cond ((and (block-in block) (conset= in (block-in block)))
1067            nil)
1068           (t
1069            (setf (block-in block) in)))))
1070
1071 ;;; Return two lists: one of blocks that precede all loops and
1072 ;;; therefore require only one constraint propagation pass and the
1073 ;;; rest. This implementation does not find all such blocks.
1074 ;;;
1075 ;;; A more complete implementation would be:
1076 ;;;
1077 ;;;     (do-blocks (block component)
1078 ;;;       (if (every #'(lambda (pred)
1079 ;;;                      (or (member pred leading-blocks)
1080 ;;;                          (eq pred head)))
1081 ;;;                  (block-pred block))
1082 ;;;           (push block leading-blocks)
1083 ;;;           (push block rest-of-blocks)))
1084 ;;;
1085 ;;; Trailing blocks that succeed all loops could be found and handled
1086 ;;; similarly. In practice though, these more complex solutions are
1087 ;;; slightly worse performancewise.
1088 (defun leading-component-blocks (component)
1089   (declare (type component component))
1090   (flet ((loopy-p (block)
1091            (let ((n (block-number block)))
1092              (dolist (pred (block-pred block))
1093                (unless (< n (block-number pred))
1094                  (return t))))))
1095     (let ((leading-blocks ())
1096           (rest-of-blocks ())
1097           (seen-loop-p ()))
1098       (do-blocks (block component)
1099         (when (and (not seen-loop-p) (loopy-p block))
1100           (setq seen-loop-p t))
1101         (if seen-loop-p
1102             (push block rest-of-blocks)
1103             (push block leading-blocks)))
1104       (values (nreverse leading-blocks) (nreverse rest-of-blocks)))))
1105
1106 ;;; Append OBJ to the end of LIST as if by NCONC but only if it is not
1107 ;;; a member already.
1108 (defun nconc-new (obj list)
1109   (do ((x list (cdr x))
1110        (prev nil x))
1111       ((endp x) (if prev
1112                     (progn
1113                       (setf (cdr prev) (list obj))
1114                       list)
1115                     (list obj)))
1116     (when (eql (car x) obj)
1117       (return-from nconc-new list))))
1118
1119 (defun find-and-propagate-constraints (component)
1120   (let ((blocks-to-process ()))
1121     (flet ((enqueue (blocks)
1122              (dolist (block blocks)
1123                (setq blocks-to-process (nconc-new block blocks-to-process)))))
1124       (multiple-value-bind (leading-blocks rest-of-blocks)
1125           (leading-component-blocks component)
1126         ;; Update every block once to account for changes in the
1127         ;; IR1. The constraints of the lead blocks cannot be changed
1128         ;; after the first pass so we might as well use them and skip
1129         ;; USE-RESULT-CONSTRAINTS later.
1130         (dolist (block leading-blocks)
1131           (setf (block-in block) (compute-block-in block))
1132           (find-block-type-constraints block t))
1133         (setq blocks-to-process (copy-list rest-of-blocks))
1134         ;; The rest of the blocks.
1135         (dolist (block rest-of-blocks)
1136           (aver (eq block (pop blocks-to-process)))
1137           (setf (block-in block) (compute-block-in block))
1138           (enqueue (find-block-type-constraints block nil)))
1139         ;; Propagate constraints
1140         (loop for block = (pop blocks-to-process)
1141               while block do
1142               (unless (eq block (component-tail component))
1143                 (when (update-block-in block)
1144                   (enqueue (find-block-type-constraints block nil)))))
1145         rest-of-blocks))))
1146
1147 (defun constraint-propagate (component)
1148   (declare (type component component))
1149   (init-var-constraints component)
1150
1151   (unless (block-out (component-head component))
1152     (setf (block-out (component-head component)) (make-conset)))
1153
1154   (dolist (block (find-and-propagate-constraints component))
1155     (unless (block-delete-p block)
1156       (use-result-constraints block)))
1157
1158   (values))