src/compiler/constraint.lisp

   1 ;;;; This file implements the constraint propagation phase of the
   2 ;;;; compiler, which uses global flow analysis to obtain dynamic type
   3 ;;;; information.
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 (defstruct (constraint
  17             (:include sset-element)
  18             (:constructor make-constraint (number kind x y not-p))
  19             (:copier nil))
  20   ;; the kind of constraint we have:
  21   ;;
  22   ;; TYPEP
  23   ;;     X is a LAMBDA-VAR and Y is a CTYPE. The value of X is
  24   ;;     constrained to be of type Y.
  25   ;;
  26   ;; > or <
  27   ;;     X is a lambda-var and Y is a CTYPE. The relation holds
  28   ;;     between X and some object of type Y.
  29   ;;
  30   ;; EQL
  31   ;;     X is a LAMBDA-VAR Y is a LAMBDA-VAR or a CONSTANT. The
  32   ;;     relation is asserted to hold.
  33   (kind nil :type (member typep < > eql))
  34   ;; The operands to the relation.
  35   (x nil :type lambda-var)
  36   (y nil :type (or ctype lambda-var constant))
  37   ;; If true, negates the sense of the constraint, so the relation
  38   ;; does *not* hold.
  39   (not-p nil :type boolean))
  40
  41 (defvar *constraint-number*)
  42
  43 ;;; Return a constraint for the specified arguments. We only create a
  44 ;;; new constraint if there isn't already an equivalent old one,
  45 ;;; guaranteeing that all equivalent constraints are EQ. This
  46 ;;; shouldn't be called on LAMBDA-VARs with no CONSTRAINTS set.
  47 (defun find-constraint (kind x y not-p)
  48   (declare (type lambda-var x) (type (or constant lambda-var ctype) y)
  49            (type boolean not-p))
  50   (or (etypecase y
  51         (ctype
  52          (do-sset-elements (con (lambda-var-constraints x) nil)
  53            (when (and (eq (constraint-kind con) kind)
  54                       (eq (constraint-not-p con) not-p)
  55                       (type= (constraint-y con) y))
  56              (return con))))
  57         (constant
  58          (do-sset-elements (con (lambda-var-constraints x) nil)
  59            (when (and (eq (constraint-kind con) kind)
  60                       (eq (constraint-not-p con) not-p)
  61                       (eq (constraint-y con) y))
  62              (return con))))
  63         (lambda-var
  64          (do-sset-elements (con (lambda-var-constraints x) nil)
  65            (when (and (eq (constraint-kind con) kind)
  66                       (eq (constraint-not-p con) not-p)
  67                       (let ((cx (constraint-x con)))
  68                         (eq (if (eq cx x)
  69                                 (constraint-y con)
  70                                 cx)
  71                             y)))
  72              (return con)))))
  73       (let ((new (make-constraint (incf *constraint-number*) kind x y not-p)))
  74         (sset-adjoin new (lambda-var-constraints x))
  75         (when (lambda-var-p y)
  76           (sset-adjoin new (lambda-var-constraints y)))
  77         new)))
  78
  79 ;;; If REF is to a LAMBDA-VAR with CONSTRAINTs (i.e. we can do flow
  80 ;;; analysis on it), then return the LAMBDA-VAR, otherwise NIL.
  81 #!-sb-fluid (declaim (inline ok-ref-lambda-var))
  82 (defun ok-ref-lambda-var (ref)
  83   (declare (type ref ref))
  84   (let ((leaf (ref-leaf ref)))
  85     (when (and (lambda-var-p leaf)
  86                (lambda-var-constraints leaf))
  87       leaf)))
  88
  89 ;;; If CONT's USE is a REF, then return OK-REF-LAMBDA-VAR of the USE,
  90 ;;; otherwise NIL.
  91 #!-sb-fluid (declaim (inline ok-cont-lambda-var))
  92 (defun ok-cont-lambda-var (cont)
  93   (declare (type continuation cont))
  94   (let ((use (continuation-use cont)))
  95     (when (ref-p use)
  96       (ok-ref-lambda-var use))))
  97
  98 ;;; Add the indicated test constraint to BLOCK, marking the block as
  99 ;;; having a new assertion when the constriant was not already
 100 ;;; present. We don't add the constraint if the block has multiple
 101 ;;; predecessors, since it only holds on this particular path.
 102 (defun add-test-constraint (block fun x y not-p)
 103   (unless (rest (block-pred block))
 104     (let ((con (find-constraint fun x y not-p))
 105           (old (or (block-test-constraint block)
 106                    (setf (block-test-constraint block) (make-sset)))))
 107       (when (sset-adjoin con old)
 108         (setf (block-type-asserted block) t))))
 109   (values))
 110
 111 ;;; Add complementary constraints to the consequent and alternative
 112 ;;; blocks of IF. We do nothing if X is NIL.
 113 #!-sb-fluid (declaim (inline add-complement-constraints))
 114 (defun add-complement-constraints (if fun x y not-p)
 115   (when x
 116     (add-test-constraint (if-consequent if) fun x y not-p)
 117     (add-test-constraint (if-alternative if) fun x y (not not-p)))
 118   (values))
 119
 120 ;;; Add test constraints to the consequent and alternative blocks of
 121 ;;; the test represented by USE.
 122 (defun add-test-constraints (use if)
 123   (declare (type node use) (type cif if))
 124   (typecase use
 125     (ref
 126      (add-complement-constraints if 'typep (ok-ref-lambda-var use)
 127                                  (specifier-type 'null) t))
 128     (combination
 129      (unless (eq (combination-kind use)
 130                  :error)
 131        (let ((name (continuation-fun-name
 132                     (basic-combination-fun use)))
 133              (args (basic-combination-args use)))
 134          (case name
 135            ((%typep %instance-typep)
 136             (let ((type (second args)))
 137               (when (constant-continuation-p type)
 138                 (let ((val (continuation-value type)))
 139                   (add-complement-constraints if 'typep
 140                                               (ok-cont-lambda-var (first args))
 141                                               (if (ctype-p val)
 142                                                   val
 143                                                   (specifier-type val))
 144                                               nil)))))
 145            ((eq eql)
 146             (let* ((var1 (ok-cont-lambda-var (first args)))
 147                    (arg2 (second args))
 148                    (var2 (ok-cont-lambda-var arg2)))
 149               (cond ((not var1))
 150                     (var2
 151                      (add-complement-constraints if 'eql var1 var2 nil))
 152                     ((constant-continuation-p arg2)
 153                      (add-complement-constraints if 'eql var1
 154                                                  (ref-leaf
 155                                                   (continuation-use arg2))
 156                                                  nil)))))
 157            ((< >)
 158             (let* ((arg1 (first args))
 159                    (var1 (ok-cont-lambda-var arg1))
 160                    (arg2 (second args))
 161                    (var2 (ok-cont-lambda-var arg2)))
 162               (when var1
 163                 (add-complement-constraints if name var1 (continuation-type arg2)
 164                                             nil))
 165               (when var2
 166                 (add-complement-constraints if (if (eq name '<) '> '<)
 167                                             var2 (continuation-type arg1)
 168                                             nil))))
 169            (t
 170             (let ((ptype (gethash name *backend-predicate-types*)))
 171               (when ptype
 172                 (add-complement-constraints if 'typep
 173                                             (ok-cont-lambda-var (first args))
 174                                             ptype nil)))))))))
 175   (values))
 176
 177 ;;; Set the TEST-CONSTRAINT in the successors of BLOCK according to
 178 ;;; the condition it tests.
 179 (defun find-test-constraints (block)
 180   (declare (type cblock block))
 181   (let ((last (block-last block)))
 182     (when (if-p last)
 183       (let ((use (continuation-use (if-test last))))
 184         (when use
 185           (add-test-constraints use last)))))
 186
 187   (setf (block-test-modified block) nil)
 188   (values))
 189
 190 ;;; Compute the initial flow analysis sets for BLOCK:
 191 ;;; -- For any lambda-var ref with a type check, add that constraint.
 192 ;;; -- For any LAMBDA-VAR set, delete all constraints on that var, and add
 193 ;;;    those constraints to the set nuked by this block.
 194 (defun find-block-type-constraints (block)
 195   (declare (type cblock block))
 196   (let ((gen (make-sset)))
 197     (collect ((kill nil adjoin))
 198
 199       (let ((test (block-test-constraint block)))
 200         (when test
 201           (sset-union gen test)))
 202
 203       (do-nodes (node cont block)
 204         (typecase node
 205           (ref
 206            (when (continuation-type-check cont)
 207              (let ((var (ok-ref-lambda-var node)))
 208                (when var
 209                  (let* ((atype (continuation-derived-type cont))
 210                         (con (find-constraint 'typep var atype nil)))
 211                    (sset-adjoin con gen))))))
 212           (cset
 213            (let ((var (set-var node)))
 214              (when (lambda-var-p var)
 215                (kill var)
 216                (let ((cons (lambda-var-constraints var)))
 217                  (when cons
 218                    (sset-difference gen cons))))))))
 219
 220       (setf (block-in block) nil)
 221       (setf (block-gen block) gen)
 222       (setf (block-kill-list block) (kill))
 223       (setf (block-out block) (copy-sset gen))
 224       (setf (block-type-asserted block) nil)
 225       (values))))
 226
 227 ;;; Return true if X is an integer NUMERIC-TYPE.
 228 (defun integer-type-p (x)
 229   (declare (type ctype x))
 230   (and (numeric-type-p x)
 231        (eq (numeric-type-class x) 'integer)
 232        (eq (numeric-type-complexp x) :real)))
 233
 234 ;;; Given that an inequality holds on values of type X and Y, return a
 235 ;;; new type for X. If GREATER is true, then X was greater than Y,
 236 ;;; otherwise less. If OR-EQUAL is true, then the inequality was
 237 ;;; inclusive, i.e. >=.
 238 ;;;
 239 ;;; If GREATER (or not), then we max (or min) in Y's lower (or upper)
 240 ;;; bound into X and return that result. If not OR-EQUAL, we can go
 241 ;;; one greater (less) than Y's bound.
 242 (defun constrain-integer-type (x y greater or-equal)
 243   (declare (type numeric-type x y))
 244   (flet ((exclude (x)
 245            (cond ((not x) nil)
 246                  (or-equal x)
 247                  (greater (1+ x))
 248                  (t (1- x))))
 249          (bound (x)
 250            (if greater (numeric-type-low x) (numeric-type-high x))))
 251     (let* ((x-bound (bound x))
 252            (y-bound (exclude (bound y)))
 253            (new-bound (cond ((not x-bound) y-bound)
 254                             ((not y-bound) x-bound)
 255                             (greater (max x-bound y-bound))
 256                             (t (min x-bound y-bound)))))
 257       (if greater
 258           (modified-numeric-type x :low new-bound)
 259           (modified-numeric-type x :high new-bound)))))
 260
 261 ;;; Return true if X is a float NUMERIC-TYPE.
 262 (defun float-type-p (x)
 263   (declare (type ctype x))
 264   (and (numeric-type-p x)
 265        (eq (numeric-type-class x) 'float)
 266        (eq (numeric-type-complexp x) :real)))
 267
 268 ;;; Exactly the same as CONSTRAIN-INTEGER-TYPE, but for float numbers.
 269 (defun constrain-float-type (x y greater or-equal)
 270   (declare (type numeric-type x y))
 271   (declare (ignorable x y greater or-equal)) ; for CROSS-FLOAT-INFINITY-KLUDGE
 272
 273   (aver (eql (numeric-type-class x) 'float))
 274   (aver (eql (numeric-type-class y) 'float))
 275   #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 276   x
 277   #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 278   (labels ((exclude (x)
 279              (cond ((not x) nil)
 280                    (or-equal x)
 281                    (greater
 282                     (if (consp x)
 283                         (car x)
 284                         x))
 285                    (t
 286                     (if (consp x)
 287                         x
 288                         (list x)))))
 289            (bound (x)
 290              (if greater (numeric-type-low x) (numeric-type-high x)))
 291            (max-lower-bound (x y)
 292              ;; Both X and Y are not null. Find the max.
 293              (let ((res (max (type-bound-number x) (type-bound-number y))))
 294                ;; An open lower bound is greater than a close
 295                ;; lower bound because the open bound doesn't
 296                ;; contain the bound, so choose an open lower
 297                ;; bound.
 298                (set-bound res (or (consp x) (consp y)))))
 299            (min-upper-bound (x y)
 300              ;; Same as above, but for the min of upper bounds
 301              ;; Both X and Y are not null. Find the min.
 302              (let ((res (min (type-bound-number x) (type-bound-number y))))
 303                ;; An open upper bound is less than a closed
 304                ;; upper bound because the open bound doesn't
 305                ;; contain the bound, so choose an open lower
 306                ;; bound.
 307                (set-bound res (or (consp x) (consp y))))))
 308     (let* ((x-bound (bound x))
 309            (y-bound (exclude (bound y)))
 310            (new-bound (cond ((not x-bound)
 311                              y-bound)
 312                             ((not y-bound)
 313                              x-bound)
 314                             (greater
 315                              (max-lower-bound x-bound y-bound))
 316                             (t
 317                              (min-upper-bound x-bound y-bound)))))
 318       (if greater
 319           (modified-numeric-type x :low new-bound)
 320           (modified-numeric-type x :high new-bound)))))
 321
 322 ;;; Given the set of CONSTRAINTS for a variable and the current set of
 323 ;;; restrictions from flow analysis IN, set the type for REF
 324 ;;; accordingly.
 325 (defun constrain-ref-type (ref constraints in)
 326   (declare (type ref ref) (type sset constraints in))
 327   (let ((var-cons (copy-sset constraints)))
 328     (sset-intersection var-cons in)
 329     (let ((res (single-value-type (node-derived-type ref)))
 330           (not-res *empty-type*)
 331           (leaf (ref-leaf ref)))
 332       (do-sset-elements (con var-cons)
 333         (let* ((x (constraint-x con))
 334                (y (constraint-y con))
 335                (not-p (constraint-not-p con))
 336                (other (if (eq x leaf) y x))
 337                (kind (constraint-kind con)))
 338           (case kind
 339             (typep
 340              (if not-p
 341                  (setq not-res (type-union not-res other))
 342                  (setq res (type-approx-intersection2 res other))))
 343             (eql
 344              (let ((other-type (leaf-type other)))
 345                (if not-p
 346                    (when (and (constant-p other)
 347                               (member-type-p other-type))
 348                      (setq not-res (type-union not-res other-type)))
 349                    (let ((leaf-type (leaf-type leaf)))
 350                      (when (or (constant-p other)
 351                                (and (csubtypep other-type leaf-type)
 352                                     (not (type= other-type leaf-type))))
 353                        (change-ref-leaf ref other)
 354                        (when (constant-p other) (return)))))))
 355             ((< >)
 356              (cond ((and (integer-type-p res) (integer-type-p y))
 357                     (let ((greater (eq kind '>)))
 358                       (let ((greater (if not-p (not greater) greater)))
 359                         (setq res
 360                               (constrain-integer-type res y greater not-p)))))
 361                    ((and (float-type-p res) (float-type-p y))
 362                     (let ((greater (eq kind '>)))
 363                       (let ((greater (if not-p (not greater) greater)))
 364                         (setq res
 365                               (constrain-float-type res y greater not-p)))))
 366                    )))))
 367
 368       (let* ((cont (node-cont ref))
 369              (dest (continuation-dest cont)))
 370         (cond ((and (if-p dest)
 371                     (csubtypep (specifier-type 'null) not-res)
 372                     (eq (continuation-asserted-type cont) *wild-type*))
 373                (setf (node-derived-type ref) *wild-type*)
 374                (change-ref-leaf ref (find-constant t)))
 375               (t
 376                (derive-node-type ref (or (type-difference res not-res)
 377                                          res)))))))
 378
 379   (values))
 380
 381 ;;; Deliver the results of constraint propagation to REFs in BLOCK.
 382 ;;; During this pass, we also do local constraint propagation by
 383 ;;; adding in constraints as we seem them during the pass through the
 384 ;;; block.
 385 (defun use-result-constraints (block)
 386   (declare (type cblock block))
 387   (let ((in (block-in block)))
 388
 389     (let ((test (block-test-constraint block)))
 390       (when test
 391         (sset-union in test)))
 392
 393     (do-nodes (node cont block)
 394       (typecase node
 395         (ref
 396          (let ((var (ref-leaf node)))
 397            (when (lambda-var-p var)
 398              (let ((con (lambda-var-constraints var)))
 399                (when con
 400                  (constrain-ref-type node con in)
 401                  (when (continuation-type-check cont)
 402                    (sset-adjoin
 403                     (find-constraint 'typep var
 404                                      (continuation-asserted-type cont)
 405                                      nil)
 406                     in)))))))
 407         (cset
 408          (let ((var (set-var node)))
 409            (when (lambda-var-p var)
 410              (let ((cons (lambda-var-constraints var)))
 411                (when cons
 412                  (sset-difference in cons))))))))))
 413
 414 ;;; Return true if VAR would have to be closed over if environment
 415 ;;; analysis ran now (i.e. if there are any uses that have a different
 416 ;;; home lambda than VAR's home.)
 417 (defun closure-var-p (var)
 418   (declare (type lambda-var var))
 419   (let ((home (lambda-home (lambda-var-home var))))
 420     (flet ((frob (l)
 421              (dolist (node l nil)
 422                (unless (eq (node-home-lambda node) home)
 423                  (return t)))))
 424       (or (frob (leaf-refs var))
 425           (frob (basic-var-sets var))))))
 426
 427 ;;; Give an empty constraints set to any var that doesn't have one and
 428 ;;; isn't a set closure var. Since a var that we previously rejected
 429 ;;; looks identical to one that is new, so we optimistically keep
 430 ;;; hoping that vars stop being closed over or lose their sets.
 431 (defun init-var-constraints (component)
 432   (declare (type component component))
 433   (dolist (fun (component-lambdas component))
 434     (flet ((frob (x)
 435              (dolist (var (lambda-vars x))
 436                (unless (lambda-var-constraints var)
 437                  (when (or (null (lambda-var-sets var))
 438                            (not (closure-var-p var)))
 439                    (setf (lambda-var-constraints var) (make-sset)))))))
 440       (frob fun)
 441       (dolist (let (lambda-lets fun))
 442         (frob let)))))
 443
 444 ;;; BLOCK-IN becomes the intersection of the OUT of the predecessors.
 445 ;;; Our OUT is:
 446 ;;;     out U (in - kill)
 447 ;;;
 448 ;;; BLOCK-KILL-LIST is just a list of the LAMBDA-VARs killed, so we must
 449 ;;; compute the kill set when there are any vars killed. We bum this a
 450 ;;; bit by special-casing when only one var is killed, and just using
 451 ;;; that var's constraints as the kill set. This set could possibly be
 452 ;;; precomputed, but it would have to be invalidated whenever any
 453 ;;; constraint is added, which would be a pain.
 454 (defun flow-propagate-constraints (block)
 455   (let* ((pred (block-pred block))
 456          (in (cond (pred
 457                     (let ((res (copy-sset (block-out (first pred)))))
 458                       (dolist (b (rest pred))
 459                         (sset-intersection res (block-out b)))
 460                       res))
 461                    (t
 462                     (let ((*compiler-error-context* (block-last block)))
 463                       (compiler-warn
 464                        "unreachable code in constraint ~
 465                         propagation -- apparent compiler bug"))
 466                     (make-sset))))
 467          (kill-list (block-kill-list block))
 468          (out (block-out block)))
 469
 470     (setf (block-in block) in)
 471     (cond ((null kill-list)
 472            (sset-union (block-out block) in))
 473           ((null (rest kill-list))
 474            (let ((con (lambda-var-constraints (first kill-list))))
 475              (if con
 476                  (sset-union-of-difference out in con)
 477                  (sset-union out in))))
 478           (t
 479            (let ((kill-set (make-sset)))
 480              (dolist (var kill-list)
 481                (let ((con (lambda-var-constraints var)))
 482                  (when con
 483                    (sset-union kill-set con))))
 484              (sset-union-of-difference (block-out block) in kill-set))))))
 485
 486 ;;; How many blocks does COMPONENT have?
 487 (defun component-n-blocks (component)
 488   (let ((result 0))
 489     (declare (type index result))
 490     (do-blocks (block component :both)
 491       (incf result))
 492     result))
 493
 494 (defun constraint-propagate (component)
 495   (declare (type component component))
 496   (init-var-constraints component)
 497
 498   (do-blocks (block component)
 499     (when (block-test-modified block)
 500       (find-test-constraints block)))
 501
 502   (do-blocks (block component)
 503     (cond ((block-type-asserted block)
 504            (find-block-type-constraints block))
 505           (t
 506            (setf (block-in block) nil)
 507            (setf (block-out block) (copy-sset (block-gen block))))))
 508
 509   (setf (block-out (component-head component)) (make-sset))
 510
 511   (let (;; If we have to propagate changes more than this many times,
 512         ;; something is wrong.
 513         (max-n-changes-remaining (component-n-blocks component)))
 514     (declare (type fixnum max-n-changes-remaining))
 515     (loop (aver (plusp max-n-changes-remaining))
 516           (decf max-n-changes-remaining)
 517           (let ((did-something nil))
 518             (do-blocks (block component)
 519               (when (flow-propagate-constraints block)
 520                 (setq did-something t)))
 521             (unless did-something
 522               (return)))))
 523
 524   (do-blocks (block component)
 525     (use-result-constraints block))
 526
 527   (values))