src/compiler/control.lisp

   1 ;;;; This file contains the control analysis pass in the compiler.
   2 ;;;; This pass determines the order in which the IR2 blocks are to be
   3 ;;;; emitted, attempting to minimize the associated branching costs.
   4 ;;;;
   5 ;;;; At this point, we commit to generating IR2 (and ultimately
   6 ;;;; assembler) for reachable blocks. Before this phase there might be
   7 ;;;; blocks that are unreachable but still appear in the DFO, due in
   8 ;;;; inadequate optimization, etc.
   9
  10 ;;;; This software is part of the SBCL system. See the README file for
  11 ;;;; more information.
  12 ;;;;
  13 ;;;; This software is derived from the CMU CL system, which was
  14 ;;;; written at Carnegie Mellon University and released into the
  15 ;;;; public domain. The software is in the public domain and is
  16 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  17 ;;;; files for more information.
  18
  19 (in-package "SB!C")
  20
  21 ;;; Insert BLOCK in the emission order after the block AFTER.
  22 (defun add-to-emit-order (block after)
  23   (declare (type block-annotation block after))
  24   (let ((next (block-annotation-next after)))
  25     (setf (block-annotation-next after) block)
  26     (setf (block-annotation-prev block) after)
  27     (setf (block-annotation-next block) next)
  28     (setf (block-annotation-prev next) block))
  29   (values))
  30
  31 ;;; If BLOCK looks like the head of a loop, then attempt to rotate it.
  32 ;;; A block looks like a loop head if the number of some predecessor
  33 ;;; is less than the block's number. Since blocks are numbered in
  34 ;;; reverse DFN, this will identify loop heads in a reducible flow
  35 ;;; graph.
  36 ;;;
  37 ;;; When we find a suspected loop head, we scan back from the tail to
  38 ;;; find an alternate loop head. This substitution preserves the
  39 ;;; correctness of the walk, since the old head can be reached from
  40 ;;; the new head. We determine the new head by scanning as far back as
  41 ;;; we can find increasing block numbers. Beats me if this is in
  42 ;;; general optimal, but it works in simple cases.
  43 ;;;
  44 ;;; This optimization is inhibited in functions with NLX EPs, since it
  45 ;;; is hard to do this without possibly messing up the special-case
  46 ;;; walking from NLX EPs described in CONTROL-ANALYZE-1-FUN. We also
  47 ;;; suppress rotation of loop heads which are the start of a function
  48 ;;; (i.e. tail calls), as the debugger wants functions to start at the
  49 ;;; start.
  50 (defun find-rotated-loop-head (block)
  51   (declare (type cblock block))
  52   (let* ((num (block-number block))
  53          (env (block-environment block))
  54          (pred (dolist (pred (block-pred block) nil)
  55                  (when (and (not (block-flag pred))
  56                             (eq (block-environment pred) env)
  57                             (< (block-number pred) num))
  58                    (return pred)))))
  59     (cond
  60      ((and pred
  61            (not (environment-nlx-info env))
  62            (not (eq (node-block (lambda-bind (block-home-lambda block)))
  63                     block)))
  64       (let ((current pred)
  65             (current-num (block-number pred)))
  66         (block DONE
  67           (loop
  68             (dolist (pred (block-pred current) (return-from DONE))
  69               (when (eq pred block)
  70                 (return-from DONE))
  71               (when (and (not (block-flag pred))
  72                          (eq (block-environment pred) env)
  73                          (> (block-number pred) current-num))
  74                 (setq current pred   current-num (block-number pred))
  75                 (return)))))
  76         (aver (not (block-flag current)))
  77         current))
  78      (t
  79       block))))
  80
  81 ;;; Do a graph walk linking blocks into the emit order as we go. We
  82 ;;; call FIND-ROTATED-LOOP-HEAD to do while-loop optimization.
  83 ;;;
  84 ;;; We treat blocks ending in tail local calls to other environments
  85 ;;; specially. We can't walked the called function immediately, since
  86 ;;; it is in a different function and we must keep the code for a
  87 ;;; function contiguous. Instead, we return the function that we want
  88 ;;; to call so that it can be walked as soon as possible, which is
  89 ;;; hopefully immediately.
  90 ;;;
  91 ;;; If any of the recursive calls ends in a tail local call, then we
  92 ;;; return the last such function, since it is the only one we can
  93 ;;; possibly drop through to. (But it doesn't have to be from the last
  94 ;;; block walked, since that call might not have added anything.)
  95 ;;;
  96 ;;; We defer walking successors whose successor is the component tail
  97 ;;; (end in an error, NLX or tail full call.) This is to discourage
  98 ;;; making error code the drop-through.
  99 (defun control-analyze-block (block tail block-info-constructor)
 100   (declare (type cblock block) (type block-annotation tail))
 101   (unless (block-flag block)
 102     (let ((block (find-rotated-loop-head block)))
 103       (setf (block-flag block) t)
 104       (aver (and (block-component block) (not (block-delete-p block))))
 105       (add-to-emit-order (or (block-info block)
 106                              (setf (block-info block)
 107                                    (funcall block-info-constructor block)))
 108                          (block-annotation-prev tail))
 109
 110       (let ((last (block-last block)))
 111         (cond ((and (combination-p last) (node-tail-p last)
 112                     (eq (basic-combination-kind last) :local)
 113                     (not (eq (node-environment last)
 114                              (lambda-environment (combination-lambda last)))))
 115                (combination-lambda last))
 116               (t
 117                (let ((component-tail (component-tail (block-component block)))
 118                      (block-succ (block-succ block))
 119                      (fun nil))
 120                  (dolist (succ block-succ)
 121                    (unless (eq (first (block-succ succ)) component-tail)
 122                      (let ((res (control-analyze-block
 123                                  succ tail block-info-constructor)))
 124                        (when res (setq fun res)))))
 125                  (dolist (succ block-succ)
 126                    (control-analyze-block succ tail block-info-constructor))
 127                  fun)))))))
 128
 129 ;;; Analyze all of the NLX EPs first to ensure that code reachable
 130 ;;; only from a NLX is emitted contiguously with the code reachable
 131 ;;; from the Bind. Code reachable from the Bind is inserted *before*
 132 ;;; the NLX code so that the Bind marks the beginning of the code for
 133 ;;; the function. If the walks from NLX EPs reach the bind block, then
 134 ;;; we just move it to the beginning.
 135 ;;;
 136 ;;; If the walk from the bind node encountered a tail local call, then
 137 ;;; we start over again there to help the call drop through. Of
 138 ;;; course, it will never get a drop-through if either function has
 139 ;;; NLX code.
 140 (defun control-analyze-1-fun (fun component block-info-constructor)
 141   (declare (type clambda fun) (type component component))
 142   (let* ((tail-block (block-info (component-tail component)))
 143          (prev-block (block-annotation-prev tail-block))
 144          (bind-block (node-block (lambda-bind fun))))
 145     (unless (block-flag bind-block)
 146       (dolist (nlx (environment-nlx-info (lambda-environment fun)))
 147         (control-analyze-block (nlx-info-target nlx) tail-block
 148                                block-info-constructor))
 149       (cond
 150        ((block-flag bind-block)
 151         (let* ((block-note (block-info bind-block))
 152                (prev (block-annotation-prev block-note))
 153                (next (block-annotation-next block-note)))
 154           (setf (block-annotation-prev next) prev)
 155           (setf (block-annotation-next prev) next)
 156           (add-to-emit-order block-note prev-block)))
 157        (t
 158         (let ((new-fun (control-analyze-block bind-block
 159                                               (block-annotation-next
 160                                                prev-block)
 161                                               block-info-constructor)))
 162           (when new-fun
 163             (control-analyze-1-fun new-fun component
 164                                    block-info-constructor)))))))
 165   (values))
 166
 167 ;;; Do control analysis on Component, finding the emit order. Our only
 168 ;;; cleverness here is that we walk XEP's first to increase the
 169 ;;; probability that the tail call will be a drop-through.
 170 ;;;
 171 ;;; When we are done, we delete blocks that weren't reached by the
 172 ;;; walk. Some return blocks are made unreachable by LTN without
 173 ;;; setting COMPONENT-REANALYZE. We remove all deleted blocks from the
 174 ;;; IR2-COMPONENT VALUES-RECEIVERS to keep stack analysis from getting
 175 ;;; confused.
 176 (defevent control-deleted-block "control analysis deleted dead block")
 177 (defun control-analyze (component block-info-constructor)
 178   (declare (type component component)
 179            (type function block-info-constructor))
 180   (let* ((head (component-head component))
 181          (head-block (funcall block-info-constructor head))
 182          (tail (component-tail component))
 183          (tail-block (funcall block-info-constructor tail)))
 184     (setf (block-info head) head-block)
 185     (setf (block-info tail) tail-block)
 186     (setf (block-annotation-prev tail-block) head-block)
 187     (setf (block-annotation-next head-block) tail-block)
 188
 189     (clear-flags component)
 190
 191     (dolist (fun (component-lambdas component))
 192       (when (external-entry-point-p fun)
 193         (control-analyze-1-fun fun component block-info-constructor)))
 194
 195     (dolist (fun (component-lambdas component))
 196       (control-analyze-1-fun fun component block-info-constructor))
 197
 198     (do-blocks (block component)
 199       (unless (block-flag block)
 200         (event control-deleted-block (continuation-next (block-start block)))
 201         (delete-block block))))
 202
 203   (let ((2comp (component-info component)))
 204     (when (ir2-component-p 2comp)
 205       ;; If it's not an IR2-COMPONENT, don't worry about it.
 206       (setf (ir2-component-values-receivers 2comp)
 207             (delete-if-not #'block-component
 208                            (ir2-component-values-receivers 2comp)))))
 209
 210   (values))