src/compiler/ctype.lisp

   1 ;;;; This file contains code which knows about both the type
   2 ;;;; representation and the compiler IR1 representation. This stuff is
   3 ;;;; used for doing type checking.
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 ;;;; FIXME: This is a poor name for this file, since CTYPE is the name
  15 ;;;; of the type used internally to represent Lisp types. It'd
  16 ;;;; probably be good to rename this file to "call-type.lisp" or
  17 ;;;; "ir1-type.lisp" or something.
  18
  19 (in-package "SB!C")
  20
  21 ;;; These are the functions that are to be called when a problem is
  22 ;;; detected. They are passed format arguments. If null, we don't do
  23 ;;; anything. The error function is called when something is
  24 ;;; definitely incorrect. The warning function is called when it is
  25 ;;; somehow impossible to tell whether the call is correct.
  26 ;;;
  27 ;;; FIXME: *ERROR-FUNCTION* and *WARNING-FUNCTION* are now misnomers.
  28 ;;; As per the KLUDGE note below, what the Python compiler
  29 ;;; considered a "definite incompatibility" could easily be conforming
  30 ;;; ANSI Common Lisp (if the incompatibility is across a compilation
  31 ;;; unit boundary, and we don't keep track of whether it is..), so we
  32 ;;; have to just report STYLE-WARNINGs instead of ERRORs or full
  33 ;;; WARNINGs; and unlike CMU CL, we don't use the condition system
  34 ;;; at all when we're reporting notes.
  35 (defvar *error-function*)
  36 (defvar *warning-function*)
  37
  38 ;;; The function that we use for type checking. The derived type is
  39 ;;; the first argument and the type we are testing against is the
  40 ;;; second argument. The function should return values like CSUBTYPEP.
  41 (defvar *test-function*)
  42 ;;; FIXME: Why is this a variable? Explain.
  43
  44 (declaim (type (or function null) *error-function* *warning-function
  45                *test-function*))
  46
  47 ;;; *LOSSAGE-DETECTED* is set when a "definite incompatibility" is
  48 ;;; detected. *SLIME-DETECTED* is set when we can't tell whether the
  49 ;;; call is compatible or not.
  50 ;;;
  51 ;;; KLUDGE: Common Lisp is a dynamic language, even if CMU CL was not.
  52 ;;; As far as I can see, none of the "definite incompatibilities"
  53 ;;; detected in this file are actually definite under the ANSI spec.
  54 ;;; They would be incompatibilites if the use were within the same
  55 ;;; compilation unit as the contradictory definition (as per the spec
  56 ;;; section "3.2.2.3 Semantic Constraints") but the old Python code
  57 ;;; doesn't keep track of whether that's the case. So until/unless we
  58 ;;; upgrade the code to keep track of that, we have to handle all
  59 ;;; these as STYLE-WARNINGs. -- WHN 2001-02-10
  60 (defvar *lossage-detected*)
  61 (defvar *slime-detected*)
  62 ;;; FIXME: "SLIME" is vivid and concise, but "DEFINITE-CALL-LOSSAGE" and
  63 ;;; "POSSIBLE-CALL-LOSSAGE" would be more mnemonic.
  64
  65 ;;; Signal a warning if appropriate and set *LOSSAGE-DETECTED*.
  66 (declaim (ftype (function (string &rest t) (values)) note-lossage note-slime))
  67 (defun note-lossage (format-string &rest format-args)
  68   (setq *lossage-detected* t)
  69   (when *error-function*
  70     (apply *error-function* format-string format-args))
  71   (values))
  72 (defun note-slime (format-string &rest format-args)
  73   (setq *slime-detected* t)
  74   (when *warning-function*
  75     (apply *warning-function* format-string format-args))
  76   (values))
  77
  78 (declaim (special *compiler-error-context*))
  79 \f
  80 ;;;; stuff for checking a call against a function type
  81 ;;;;
  82 ;;;; FIXME: This is stuff to look at when I get around to fixing
  83 ;;;; function type inference and declarations.
  84
  85 ;;; A dummy version of SUBTYPEP useful when we want a functional like
  86 ;;; SUBTYPEP that always returns true.
  87 (defun always-subtypep (type1 type2)
  88   (declare (ignore type1 type2))
  89   (values t t))
  90
  91 ;;; Determine whether a use of a function is consistent with its type.
  92 ;;; These values are returned:
  93 ;;;    T, T: the call is definitely valid.
  94 ;;;    NIL, T: the call is definitely invalid.
  95 ;;;    NIL, NIL: unable to determine whether the call is valid.
  96 ;;;
  97 ;;; The ARGUMENT-TEST function is used to determine whether an
  98 ;;; argument type matches the type we are checking against. Similarly,
  99 ;;; the RESULT-TEST is used to determine whether the result type
 100 ;;; matches the specified result.
 101 ;;;
 102 ;;; Unlike the argument test, the result test may be called on values
 103 ;;; or function types. If STRICT-RESULT is true and SAFETY is
 104 ;;; non-zero, then the NODE-DERIVED-TYPE is always used. Otherwise, if
 105 ;;; CONT's TYPE-CHECK is true, then the NODE-DERIVED-TYPE is
 106 ;;; intersected with the CONT's ASSERTED-TYPE.
 107 ;;;
 108 ;;; The error and warning functions are functions that are called to
 109 ;;; explain the result. We bind *COMPILER-ERROR-CONTEXT* to the
 110 ;;; combination node so that COMPILER-WARNING and related functions
 111 ;;; will do the right thing if they are supplied.
 112 (defun valid-function-use (call type &key
 113                                 ((:argument-test *test-function*) #'csubtypep)
 114                                 (result-test #'values-subtypep)
 115                                 (strict-result nil)
 116                                 ((:error-function *error-function*))
 117                                 ((:warning-function *warning-function*)))
 118   (declare (type function result-test) (type combination call)
 119            (type fun-type type))
 120   (let* ((*lossage-detected* nil)
 121          (*slime-detected* nil)
 122          (*compiler-error-context* call)
 123          (args (combination-args call))
 124          (nargs (length args))
 125          (required (fun-type-required type))
 126          (min-args (length required))
 127          (optional (fun-type-optional type))
 128          (max-args (+ min-args (length optional)))
 129          (rest (fun-type-rest type))
 130          (keyp (fun-type-keyp type)))
 131
 132     (cond
 133      ((fun-type-wild-args type)
 134       (do ((i 1 (1+ i))
 135            (arg args (cdr arg)))
 136           ((null arg))
 137         (check-arg-type (car arg) *wild-type* i)))
 138      ((not (or optional keyp rest))
 139       (if (/= nargs min-args)
 140           (note-lossage
 141            "The function was called with ~R argument~:P, but wants exactly ~R."
 142            nargs min-args)
 143           (check-fixed-and-rest args required nil)))
 144      ((< nargs min-args)
 145       (note-lossage
 146        "The function was called with ~R argument~:P, but wants at least ~R."
 147        nargs min-args))
 148      ((<= nargs max-args)
 149       (check-fixed-and-rest args (append required optional) rest))
 150      ((not (or keyp rest))
 151       (note-lossage
 152        "The function was called with ~R argument~:P, but wants at most ~R."
 153        nargs max-args))
 154      ((and keyp (oddp (- nargs max-args)))
 155       (note-lossage
 156        "The function has an odd number of arguments in the keyword portion."))
 157      (t
 158       (check-fixed-and-rest args (append required optional) rest)
 159       (when keyp
 160         (check-key-args args max-args type))))
 161
 162     (let* ((dtype (node-derived-type call))
 163            (return-type (fun-type-returns type))
 164            (cont (node-cont call))
 165            (out-type
 166             (if (or (not (continuation-type-check cont))
 167                     (and strict-result (policy call (/= safety 0))))
 168                 dtype
 169                 (values-type-intersection (continuation-asserted-type cont)
 170                                           dtype))))
 171       (multiple-value-bind (int win) (funcall result-test out-type return-type)
 172         (cond ((not win)
 173                (note-slime "can't tell whether the result is a ~S"
 174                            (type-specifier return-type)))
 175               ((not int)
 176                (note-lossage "The result is a ~S, not a ~S."
 177                              (type-specifier out-type)
 178                              (type-specifier return-type))))))
 179
 180     (cond (*lossage-detected* (values nil t))
 181           (*slime-detected* (values nil nil))
 182           (t (values t t)))))
 183
 184 ;;; Check that the derived type of the continuation CONT is compatible
 185 ;;; with TYPE. N is the arg number, for error message purposes. We
 186 ;;; return true if arg is definitely o.k. If the type is a magic
 187 ;;; CONSTANT-TYPE, then we check for the argument being a constant
 188 ;;; value of the specified type. If there is a manifest type error
 189 ;;; (DERIVED-TYPE = NIL), then we flame about the asserted type even
 190 ;;; when our type is satisfied under the test.
 191 (defun check-arg-type (cont type n)
 192   (declare (type continuation cont) (type ctype type) (type index n))
 193   (cond
 194    ((not (constant-type-p type))
 195     (let ((ctype (continuation-type cont)))
 196       (multiple-value-bind (int win) (funcall *test-function* ctype type)
 197         (cond ((not win)
 198                (note-slime "can't tell whether the ~:R argument is a ~S"
 199                            n (type-specifier type))
 200                nil)
 201               ((not int)
 202                (note-lossage "The ~:R argument is a ~S, not a ~S."
 203                              n (type-specifier ctype) (type-specifier type))
 204                nil)
 205               ((eq ctype *empty-type*)
 206                (note-slime "The ~:R argument never returns a value." n)
 207                nil)
 208               (t t)))))
 209     ((not (constant-continuation-p cont))
 210      (note-slime "The ~:R argument is not a constant." n)
 211      nil)
 212     (t
 213      (let ((val (continuation-value cont))
 214            (type (constant-type-type type)))
 215        (multiple-value-bind (res win) (ctypep val type)
 216          (cond ((not win)
 217                 (note-slime "can't tell whether the ~:R argument is a ~
 218                              constant ~S:~%  ~S"
 219                             n (type-specifier type) val)
 220                 nil)
 221                ((not res)
 222                 (note-lossage "The ~:R argument is not a constant ~S:~%  ~S"
 223                               n (type-specifier type) val)
 224                 nil)
 225                (t t)))))))
 226
 227 ;;; Check that each of the type of each supplied argument intersects
 228 ;;; with the type specified for that argument. If we can't tell, then
 229 ;;; we complain about the slime.
 230 (declaim (ftype (function (list list (or ctype null)) (values)) check-fixed-and-rest))
 231 (defun check-fixed-and-rest (args types rest)
 232   (do ((arg args (cdr arg))
 233        (type types (cdr type))
 234        (n 1 (1+ n)))
 235       ((or (null type) (null arg))
 236        (when rest
 237          (dolist (arg arg)
 238            (check-arg-type arg rest n)
 239            (incf n))))
 240     (declare (fixnum n))
 241     (check-arg-type (car arg) (car type) n))
 242   (values))
 243
 244 ;;; Check that the &KEY args are of the correct type. Each key should
 245 ;;; be known and the corresponding argument should be of the correct
 246 ;;; type. If the key isn't a constant, then we can't tell, so we note
 247 ;;; slime.
 248 (declaim (ftype (function (list fixnum fun-type) (values)) check-key-args))
 249 (defun check-key-args (args pre-key type)
 250   (do ((key (nthcdr pre-key args) (cddr key))
 251        (n (1+ pre-key) (+ n 2)))
 252       ((null key))
 253     (declare (fixnum n))
 254     (let ((k (car key)))
 255       (cond
 256        ((not (check-arg-type k (specifier-type 'symbol) n)))
 257        ((not (constant-continuation-p k))
 258         (note-slime "The ~:R argument (in keyword position) is not a constant."
 259                     n))
 260        (t
 261         (let* ((name (continuation-value k))
 262                (info (find name (fun-type-keywords type)
 263                            :key #'key-info-name)))
 264           (cond ((not info)
 265                  (unless (fun-type-allowp type)
 266                    (note-lossage "~S is not a known argument keyword."
 267                                  name)))
 268                 (t
 269                  (check-arg-type (second key) (key-info-type info)
 270                                  (1+ n)))))))))
 271   (values))
 272
 273 ;;; Construct a function type from a definition.
 274 ;;;
 275 ;;; Due to the lack of a (LIST X) type specifier, we can't reconstruct
 276 ;;; the &REST type.
 277 (declaim (ftype (function (functional) fun-type) definition-type))
 278 (defun definition-type (functional)
 279   (if (lambda-p functional)
 280       (make-fun-type
 281        :required (mapcar #'leaf-type (lambda-vars functional))
 282        :returns (tail-set-type (lambda-tail-set functional)))
 283       (let ((rest nil))
 284         (collect ((req)
 285                   (opt)
 286                   (keys))
 287           (dolist (arg (optional-dispatch-arglist functional))
 288             (let ((info (lambda-var-arg-info arg))
 289                   (type (leaf-type arg)))
 290               (if info
 291                   (ecase (arg-info-kind info)
 292                     (:required (req type))
 293                     (:optional (opt type))
 294                     (:keyword
 295                      (keys (make-key-info :name (arg-info-key info)
 296                                           :type type)))
 297                     ((:rest :more-context)
 298                      (setq rest *universal-type*))
 299                     (:more-count))
 300                   (req type))))
 301
 302           (make-fun-type
 303            :required (req)
 304            :optional (opt)
 305            :rest rest
 306            :keywords (keys)
 307            :keyp (optional-dispatch-keyp functional)
 308            :allowp (optional-dispatch-allowp functional)
 309            :returns (tail-set-type
 310                      (lambda-tail-set
 311                       (optional-dispatch-main-entry functional))))))))
 312 \f
 313 ;;;; approximate function types
 314 ;;;;
 315 ;;;; FIXME: This is stuff to look at when I get around to fixing function
 316 ;;;; type inference and declarations.
 317 ;;;;
 318 ;;;; Approximate function types provide a condensed representation of all the
 319 ;;;; different ways that a function has been used. If we have no declared or
 320 ;;;; defined type for a function, then we build an approximate function type by
 321 ;;;; examining each use of the function. When we encounter a definition or
 322 ;;;; proclamation, we can check the actual type for compatibity with the
 323 ;;;; previous uses.
 324
 325 (defstruct (approximate-fun-type (:copier nil))
 326   ;; the smallest and largest numbers of arguments that this function
 327   ;; has been called with.
 328   (min-args sb!xc:call-arguments-limit :type fixnum)
 329   (max-args 0 :type fixnum)
 330   ;; a list of lists of the all the types that have been used in each
 331   ;; argument position
 332   (types () :type list)
 333   ;; A list of APPROXIMATE-KEY-INFO structures describing all the
 334   ;; things that looked like &KEY arguments. There are distinct
 335   ;; structures describing each argument position in which the keyword
 336   ;; appeared.
 337   (keys () :type list))
 338
 339 (defstruct (approximate-key-info (:copier nil))
 340   ;; The keyword name of this argument. Although keyword names don't
 341   ;; have to be keywords, we only match on keywords when figuring an
 342   ;; approximate type.
 343   (name (required-argument) :type keyword)
 344   ;; The position at which this keyword appeared. 0 if it appeared as the
 345   ;; first argument, etc.
 346   (position (required-argument) :type fixnum)
 347   ;; a list of all the argument types that have been used with this keyword
 348   (types nil :type list)
 349   ;; true if this keyword has appeared only in calls with an obvious
 350   ;; :ALLOW-OTHER-KEYS
 351   (allowp nil :type (member t nil)))
 352
 353 ;;; Return an APPROXIMATE-FUN-TYPE representing the context of
 354 ;;; CALL. If TYPE is supplied and not null, then we merge the
 355 ;;; information into the information already accumulated in TYPE.
 356 (declaim (ftype (function (combination
 357                            &optional (or approximate-fun-type null))
 358                           approximate-fun-type)
 359                 note-function-use))
 360 (defun note-function-use (call &optional type)
 361   (let* ((type (or type (make-approximate-fun-type)))
 362          (types (approximate-fun-type-types type))
 363          (args (combination-args call))
 364          (nargs (length args))
 365          (allowp (some #'(lambda (x)
 366                            (and (constant-continuation-p x)
 367                                 (eq (continuation-value x) :allow-other-keys)))
 368                           args)))
 369
 370     (setf (approximate-fun-type-min-args type)
 371           (min (approximate-fun-type-min-args type) nargs))
 372     (setf (approximate-fun-type-max-args type)
 373           (max (approximate-fun-type-max-args type) nargs))
 374
 375     (do ((old types (cdr old))
 376          (arg args (cdr arg)))
 377         ((null old)
 378          (setf (approximate-fun-type-types type)
 379                (nconc types
 380                       (mapcar #'(lambda (x)
 381                                   (list (continuation-type x)))
 382                               arg))))
 383       (when (null arg) (return))
 384       (pushnew (continuation-type (car arg))
 385                (car old)
 386                :test #'type=))
 387
 388     (collect ((keys (approximate-fun-type-keys type) cons))
 389       (do ((arg args (cdr arg))
 390            (pos 0 (1+ pos)))
 391           ((or (null arg) (null (cdr arg)))
 392            (setf (approximate-fun-type-keys type) (keys)))
 393         (let ((key (first arg))
 394               (val (second arg)))
 395           (when (constant-continuation-p key)
 396             (let ((name (continuation-value key)))
 397               (when (keywordp name)
 398                 (let ((old (find-if
 399                             #'(lambda (x)
 400                                 (and (eq (approximate-key-info-name x) name)
 401                                      (= (approximate-key-info-position x)
 402                                         pos)))
 403                             (keys)))
 404                       (val-type (continuation-type val)))
 405                   (cond (old
 406                          (pushnew val-type
 407                                   (approximate-key-info-types old)
 408                                   :test #'type=)
 409                          (unless allowp
 410                            (setf (approximate-key-info-allowp old) nil)))
 411                         (t
 412                          (keys (make-approximate-key-info
 413                                 :name name
 414                                 :position pos
 415                                 :allowp allowp
 416                                 :types (list val-type))))))))))))
 417     type))
 418
 419 ;;; This is similar to VALID-FUNCTION-USE, but checks an
 420 ;;; APPROXIMATE-FUN-TYPE against a real function type.
 421 (declaim (ftype (function (approximate-fun-type fun-type
 422                            &optional function function function)
 423                           (values boolean boolean))
 424                 valid-approximate-type))
 425 (defun valid-approximate-type (call-type type &optional
 426                                          (*test-function*
 427                                           #'types-equal-or-intersect)
 428                                          (*error-function*
 429                                           #'compiler-style-warning)
 430                                          (*warning-function* #'compiler-note))
 431   (let* ((*lossage-detected* nil)
 432          (*slime-detected* nil)
 433          (required (fun-type-required type))
 434          (min-args (length required))
 435          (optional (fun-type-optional type))
 436          (max-args (+ min-args (length optional)))
 437          (rest (fun-type-rest type))
 438          (keyp (fun-type-keyp type)))
 439
 440     (when (fun-type-wild-args type)
 441       (return-from valid-approximate-type (values t t)))
 442
 443     (let ((call-min (approximate-fun-type-min-args call-type)))
 444       (when (< call-min min-args)
 445         (note-lossage
 446          "~:@<The function was previously called with ~R argument~:P, ~
 447           but wants at least ~R.~:>"
 448          call-min min-args)))
 449
 450     (let ((call-max (approximate-fun-type-max-args call-type)))
 451       (cond ((<= call-max max-args))
 452             ((not (or keyp rest))
 453              (note-lossage
 454               "~:@<The function was previously called with ~R argument~:P, ~
 455                 but wants at most ~R.~:>"
 456               call-max max-args))
 457             ((and keyp (oddp (- call-max max-args)))
 458              (note-lossage
 459               "~:@<The function was previously called with an odd number of ~
 460                arguments in the keyword portion.~:>")))
 461
 462       (when (and keyp (> call-max max-args))
 463         (check-approximate-keywords call-type max-args type)))
 464
 465     (check-approximate-fixed-and-rest call-type (append required optional)
 466                                       rest)
 467
 468     (cond (*lossage-detected* (values nil t))
 469           (*slime-detected* (values nil nil))
 470           (t (values t t)))))
 471
 472 ;;; Check that each of the types used at each arg position is
 473 ;;; compatible with the actual type.
 474 (declaim (ftype (function (approximate-fun-type list (or ctype null))
 475                           (values))
 476                 check-approximate-fixed-and-rest))
 477 (defun check-approximate-fixed-and-rest (call-type fixed rest)
 478   (do ((types (approximate-fun-type-types call-type) (cdr types))
 479        (n 1 (1+ n))
 480        (arg fixed (cdr arg)))
 481       ((null types))
 482     (let ((decl-type (or (car arg) rest)))
 483       (unless decl-type (return))
 484       (check-approximate-arg-type (car types) decl-type "~:R" n)))
 485   (values))
 486
 487 ;;; Check that each of the call-types is compatible with DECL-TYPE,
 488 ;;; complaining if not or if we can't tell.
 489 (declaim (ftype (function (list ctype string &rest t) (values))
 490                 check-approximate-arg-type))
 491 (defun check-approximate-arg-type (call-types decl-type context &rest args)
 492   (let ((losers *empty-type*))
 493     (dolist (ctype call-types)
 494       (multiple-value-bind (int win) (funcall *test-function* ctype decl-type)
 495         (cond
 496          ((not win)
 497           (note-slime "can't tell whether previous ~? argument type ~S is a ~S"
 498                       context args (type-specifier ctype) (type-specifier decl-type)))
 499          ((not int)
 500           (setq losers (type-union ctype losers))))))
 501
 502     (unless (eq losers *empty-type*)
 503       (note-lossage "~:(~?~) argument should be a ~S but was a ~S in a previous call."
 504                     context args (type-specifier decl-type) (type-specifier losers))))
 505   (values))
 506
 507 ;;; Check the types of each manifest keyword that appears in a keyword
 508 ;;; argument position. Check the validity of all keys that appeared in
 509 ;;; valid keyword positions.
 510 ;;;
 511 ;;; ### We could check the APPROXIMATE-FUN-TYPE-TYPES to make
 512 ;;; sure that all arguments in keyword positions were manifest
 513 ;;; keywords.
 514 (defun check-approximate-keywords (call-type max-args type)
 515   (let ((call-keys (approximate-fun-type-keys call-type))
 516         (keys (fun-type-keywords type)))
 517     (dolist (key keys)
 518       (let ((name (key-info-name key)))
 519         (collect ((types nil append))
 520           (dolist (call-key call-keys)
 521             (let ((pos (approximate-key-info-position call-key)))
 522               (when (and (eq (approximate-key-info-name call-key) name)
 523                          (> pos max-args) (evenp (- pos max-args)))
 524                 (types (approximate-key-info-types call-key)))))
 525           (check-approximate-arg-type (types) (key-info-type key) "~S" name))))
 526
 527     (unless (fun-type-allowp type)
 528       (collect ((names () adjoin))
 529         (dolist (call-key call-keys)
 530           (let ((pos (approximate-key-info-position call-key)))
 531             (when (and (> pos max-args) (evenp (- pos max-args))
 532                        (not (approximate-key-info-allowp call-key)))
 533               (names (approximate-key-info-name call-key)))))
 534
 535         (dolist (name (names))
 536           (unless (find name keys :key #'key-info-name)
 537             (note-lossage "Function previously called with unknown argument keyword ~S."
 538                   name)))))))
 539 \f
 540 ;;;; ASSERT-DEFINITION-TYPE
 541
 542 ;;; Intersect LAMBDA's var types with TYPES, giving a warning if there
 543 ;;; is a mismatch. If all intersections are non-null, we return lists
 544 ;;; of the variables and intersections, otherwise we return NIL, NIL.
 545 (defun try-type-intersections (vars types where)
 546   (declare (list vars types) (string where))
 547   (collect ((res))
 548     (mapc (lambda (var type)
 549             (let* ((vtype (leaf-type var))
 550                    (int (type-approx-intersection2 vtype type)))
 551               (cond
 552                ((eq int *empty-type*)
 553                 (note-lossage
 554                  "Definition's declared type for variable ~A:~%  ~S~@
 555                    conflicts with this type from ~A:~%  ~S"
 556                  (leaf-name var) (type-specifier vtype)
 557                  where (type-specifier type))
 558                 (return-from try-type-intersections (values nil nil)))
 559                (t
 560                 (res int)))))
 561           vars types)
 562     (values vars (res))))
 563
 564 ;;; Check that the optional-dispatch OD conforms to Type. We return
 565 ;;; the values of TRY-TYPE-INTERSECTIONS if there are no syntax
 566 ;;; problems, otherwise NIL, NIL.
 567 ;;;
 568 ;;; Note that the variables in the returned list are the actual
 569 ;;; original variables (extracted from the optional dispatch arglist),
 570 ;;; rather than the variables that are arguments to the main entry.
 571 ;;; This difference is significant only for &KEY args with hairy
 572 ;;; defaults. Returning the actual vars allows us to use the right
 573 ;;; variable name in warnings.
 574 ;;;
 575 ;;; A slightly subtle point: with keywords and optionals, the type in
 576 ;;; the function type is only an assertion on calls --- it doesn't
 577 ;;; constrain the type of default values. So we have to union in the
 578 ;;; type of the default. With optionals, we can't do any assertion
 579 ;;; unless the default is constant.
 580 ;;;
 581 ;;; With keywords, we exploit our knowledge about how hairy keyword
 582 ;;; defaulting is done when computing the type assertion to put on the
 583 ;;; main-entry argument. In the case of hairy keywords, the default
 584 ;;; has been clobbered with NIL, which is the value of the main-entry
 585 ;;; arg in the unsupplied case, whatever the actual default value is.
 586 ;;; So we can just assume the default is constant, effectively
 587 ;;; unioning in NULL, and not totally blow off doing any type
 588 ;;; assertion.
 589 (defun find-optional-dispatch-types (od type where)
 590   (declare (type optional-dispatch od)
 591            (type fun-type type)
 592            (string where))
 593   (let* ((min (optional-dispatch-min-args od))
 594          (req (fun-type-required type))
 595          (opt (fun-type-optional type)))
 596     (flet ((frob (x y what)
 597              (unless (= x y)
 598                (note-lossage
 599                 "The definition has ~R ~A arg~P, but ~A has ~R."
 600                 x what x where y))))
 601       (frob min (length req) "fixed")
 602       (frob (- (optional-dispatch-max-args od) min) (length opt) "optional"))
 603     (flet ((frob (x y what)
 604              (unless (eq x y)
 605                (note-lossage
 606                 "The definition ~:[doesn't have~;has~] ~A, but ~
 607                 ~A ~:[doesn't~;does~]."
 608                 x what where y))))
 609       (frob (optional-dispatch-keyp od) (fun-type-keyp type)
 610             "&KEY arguments")
 611       (unless (optional-dispatch-keyp od)
 612         (frob (not (null (optional-dispatch-more-entry od)))
 613               (not (null (fun-type-rest type)))
 614               "&REST arguments"))
 615       (frob (optional-dispatch-allowp od) (fun-type-allowp type)
 616             "&ALLOW-OTHER-KEYS"))
 617
 618     (when *lossage-detected*
 619       (return-from find-optional-dispatch-types (values nil nil)))
 620
 621     (collect ((res)
 622               (vars))
 623       (let ((keys (fun-type-keywords type))
 624             (arglist (optional-dispatch-arglist od)))
 625         (dolist (arg arglist)
 626           (cond
 627            ((lambda-var-arg-info arg)
 628             (let* ((info (lambda-var-arg-info arg))
 629                    (default (arg-info-default info))
 630                    (def-type (when (constantp default)
 631                                (ctype-of (eval default)))))
 632               (ecase (arg-info-kind info)
 633                 (:keyword
 634                  (let* ((key (arg-info-key info))
 635                         (kinfo (find key keys :key #'key-info-name)))
 636                    (cond
 637                     (kinfo
 638                      (res (type-union (key-info-type kinfo)
 639                                       (or def-type (specifier-type 'null)))))
 640                     (t
 641                      (note-lossage
 642                       "Defining a ~S keyword not present in ~A."
 643                       key where)
 644                      (res *universal-type*)))))
 645                 (:required (res (pop req)))
 646                 (:optional
 647                  (res (type-union (pop opt) (or def-type *universal-type*))))
 648                 (:rest
 649                  (when (fun-type-rest type)
 650                    (res (specifier-type 'list))))
 651                 (:more-context
 652                  (when (fun-type-rest type)
 653                    (res *universal-type*)))
 654                 (:more-count
 655                  (when (fun-type-rest type)
 656                    (res (specifier-type 'fixnum)))))
 657               (vars arg)
 658               (when (arg-info-supplied-p info)
 659                 (res *universal-type*)
 660                 (vars (arg-info-supplied-p info)))))
 661            (t
 662             (res (pop req))
 663             (vars arg))))
 664
 665         (dolist (key keys)
 666           (unless (find (key-info-name key) arglist
 667                         :key #'(lambda (x)
 668                                  (let ((info (lambda-var-arg-info x)))
 669                                    (when info
 670                                      (arg-info-key info)))))
 671             (note-lossage
 672              "The definition lacks the ~S key present in ~A."
 673              (key-info-name key) where))))
 674
 675       (try-type-intersections (vars) (res) where))))
 676
 677 ;;; Check that Type doesn't specify any funny args, and do the
 678 ;;; intersection.
 679 (defun find-lambda-types (lambda type where)
 680   (declare (type clambda lambda) (type fun-type type) (string where))
 681   (flet ((frob (x what)
 682            (when x
 683              (note-lossage
 684               "The definition has no ~A, but the ~A did."
 685               what where))))
 686     (frob (fun-type-optional type) "&OPTIONAL arguments")
 687     (frob (fun-type-keyp type) "&KEY arguments")
 688     (frob (fun-type-rest type) "&REST argument"))
 689   (let* ((vars (lambda-vars lambda))
 690          (nvars (length vars))
 691          (req (fun-type-required type))
 692          (nreq (length req)))
 693     (unless (= nvars nreq)
 694       (note-lossage "The definition has ~R arg~:P, but the ~A has ~R."
 695                     nvars where nreq))
 696     (if *lossage-detected*
 697         (values nil nil)
 698         (try-type-intersections vars req where))))
 699
 700 ;;; Check for syntactic and type conformance between the definition
 701 ;;; FUNCTIONAL and the specified FUN-TYPE. If they are compatible
 702 ;;; and REALLY-ASSERT is T, then add type assertions to the definition
 703 ;;; from the FUN-TYPE.
 704 ;;;
 705 ;;; If there is a syntactic or type problem, then we call
 706 ;;; ERROR-FUNCTION with an error message using WHERE as context
 707 ;;; describing where FUN-TYPE came from.
 708 ;;;
 709 ;;; If there is no problem, we return T (even if REALLY-ASSERT was
 710 ;;; false). If there was a problem, we return NIL.
 711 (defun assert-definition-type
 712        (functional type &key (really-assert t)
 713                    ((:error-function *error-function*)
 714                     #'compiler-style-warning)
 715                    warning-function
 716                    (where "previous declaration"))
 717   (declare (type functional functional)
 718            (type function *error-function*)
 719            (string where))
 720   (unless (fun-type-p type)
 721     (return-from assert-definition-type t))
 722   (let ((*lossage-detected* nil))
 723     (multiple-value-bind (vars types)
 724         (if (fun-type-wild-args type)
 725             (values nil nil)
 726             (etypecase functional
 727               (optional-dispatch
 728                (find-optional-dispatch-types functional type where))
 729               (clambda
 730                (find-lambda-types functional type where))))
 731       (let* ((type-returns (fun-type-returns type))
 732              (return (lambda-return (main-entry functional)))
 733              (atype (when return
 734                       (continuation-asserted-type (return-result return)))))
 735         (cond
 736          ((and atype (not (values-types-equal-or-intersect atype
 737                                                            type-returns)))
 738           (note-lossage
 739            "The result type from ~A:~%  ~S~@
 740            conflicts with the definition's result type assertion:~%  ~S"
 741            where (type-specifier type-returns) (type-specifier atype))
 742           nil)
 743          (*lossage-detected* nil)
 744          ((not really-assert) t)
 745          (t
 746           (when atype
 747             (assert-continuation-type (return-result return) atype))
 748           (loop for var in vars and type in types do
 749             (cond ((basic-var-sets var)
 750                    (when (and warning-function
 751                               (not (csubtypep (leaf-type var) type)))
 752                      (funcall warning-function
 753                               "Assignment to argument: ~S~%  ~
 754                                prevents use of assertion from function ~
 755                                type ~A:~%  ~S~%"
 756                               (leaf-name var) where (type-specifier type))))
 757                   (t
 758                    (setf (leaf-type var) type)
 759                    (dolist (ref (leaf-refs var))
 760                      (derive-node-type ref type)))))
 761           t))))))