src/compiler/debug-dump.lisp

   1 ;;;; stuff that creates debugger information from the compiler's
   2 ;;;; internal data structures
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (deftype byte-buffer () '(vector (unsigned-byte 8)))
  16 (defvar *byte-buffer*)
  17 (declaim (type byte-buffer *byte-buffer*))
  18 \f
  19 ;;;; debug blocks
  20
  21 (deftype location-kind ()
  22   '(member :unknown-return :known-return :internal-error :non-local-exit
  23            :block-start :call-site :single-value-return :non-local-entry))
  24
  25 ;;; The LOCATION-INFO structure holds the information what we need
  26 ;;; about locations which code generation decided were "interesting".
  27 (defstruct (location-info
  28             (:constructor make-location-info (kind label vop)))
  29   ;; The kind of location noted.
  30   (kind nil :type location-kind)
  31   ;; The label pointing to the interesting code location.
  32   (label nil :type (or label index null))
  33   ;; The VOP that emitted this location (for node, save-set, ir2-block, etc.)
  34   (vop nil :type vop))
  35
  36 ;;; This is called during code generation in places where there is an
  37 ;;; "interesting" location: someplace where we are likely to end up
  38 ;;; in the debugger, and thus want debug info.
  39 (defun note-debug-location (vop label kind)
  40   (declare (type vop vop) (type (or label null) label)
  41            (type location-kind kind))
  42   (let ((location (make-location-info kind label vop)))
  43     (setf (ir2-block-locations (vop-block vop))
  44           (nconc (ir2-block-locations (vop-block vop))
  45                  (list location)))
  46     location))
  47
  48 #!-sb-fluid (declaim (inline ir2-block-environment))
  49 (defun ir2-block-environment (2block)
  50   (declare (type ir2-block 2block))
  51   (block-environment (ir2-block-block 2block)))
  52
  53 ;;; Given a local conflicts vector and an IR2 block to represent the
  54 ;;; set of live TNs, and the VAR-LOCS hash-table representing the
  55 ;;; variables dumped, compute a bit-vector representing the set of
  56 ;;; live variables. If the TN is environment-live, we only mark it as
  57 ;;; live when it is in scope at NODE.
  58 (defun compute-live-vars (live node block var-locs vop)
  59   (declare (type ir2-block block) (type local-tn-bit-vector live)
  60            (type hash-table var-locs) (type node node)
  61            (type (or vop null) vop))
  62   (let ((res (make-array (logandc2 (+ (hash-table-count var-locs) 7) 7)
  63                          :element-type 'bit
  64                          :initial-element 0))
  65         (spilled (gethash vop
  66                           (ir2-component-spilled-vops
  67                            (component-info *component-being-compiled*)))))
  68     (do-live-tns (tn live block)
  69       (let ((leaf (tn-leaf tn)))
  70         (when (and (lambda-var-p leaf)
  71                    (or (not (member (tn-kind tn)
  72                                     '(:environment :debug-environment)))
  73                        (rassoc leaf (lexenv-variables (node-lexenv node))))
  74                    (or (null spilled)
  75                        (not (member tn spilled))))
  76           (let ((num (gethash leaf var-locs)))
  77             (when num
  78               (setf (sbit res num) 1))))))
  79     res))
  80
  81 ;;; The PC for the location most recently dumped.
  82 (defvar *previous-location*)
  83 (declaim (type index *previous-location*))
  84
  85 ;;; Dump a compiled debug-location into *BYTE-BUFFER* that describes
  86 ;;; the code/source map and live info. If true, VOP is the VOP
  87 ;;; associated with this location, for use in determining whether TNs
  88 ;;; are spilled.
  89 (defun dump-1-location (node block kind tlf-num label live var-locs vop)
  90   (declare (type node node) (type ir2-block block)
  91            (type local-tn-bit-vector live)
  92            (type (or label index) label)
  93            (type location-kind kind) (type (or index null) tlf-num)
  94            (type hash-table var-locs) (type (or vop null) vop))
  95
  96   (vector-push-extend
  97    (dpb (position-or-lose kind *compiled-code-location-kinds*)
  98         compiled-code-location-kind-byte
  99         0)
 100    *byte-buffer*)
 101
 102   (let ((loc (if (target-fixnump label) label (label-position label))))
 103     (write-var-integer (- loc *previous-location*) *byte-buffer*)
 104     (setq *previous-location* loc))
 105
 106   (let ((path (node-source-path node)))
 107     (unless tlf-num
 108       (write-var-integer (source-path-tlf-number path) *byte-buffer*))
 109     (write-var-integer (source-path-form-number path) *byte-buffer*))
 110
 111   (write-packed-bit-vector (compute-live-vars live node block var-locs vop)
 112                            *byte-buffer*)
 113
 114   (values))
 115
 116 ;;; Extract context info from a Location-Info structure and use it to
 117 ;;; dump a compiled code-location.
 118 (defun dump-location-from-info (loc tlf-num var-locs)
 119   (declare (type location-info loc) (type (or index null) tlf-num)
 120            (type hash-table var-locs))
 121   (let ((vop (location-info-vop loc)))
 122     (dump-1-location (vop-node vop)
 123                      (vop-block vop)
 124                      (location-info-kind loc)
 125                      tlf-num
 126                      (location-info-label loc)
 127                      (vop-save-set vop)
 128                      var-locs
 129                      vop))
 130   (values))
 131
 132 ;;; Scan all the blocks, determining if all locations are in the same
 133 ;;; TLF, and returning it or NIL.
 134 (defun find-tlf-number (fun)
 135   (declare (type clambda fun))
 136   (let ((res (source-path-tlf-number (node-source-path (lambda-bind fun)))))
 137     (declare (type (or index null) res))
 138     (do-environment-ir2-blocks (2block (lambda-environment fun))
 139       (let ((block (ir2-block-block 2block)))
 140         (when (eq (block-info block) 2block)
 141           (unless (eql (source-path-tlf-number
 142                         (node-source-path
 143                          (continuation-next
 144                           (block-start block))))
 145                        res)
 146             (setq res nil)))
 147
 148         (dolist (loc (ir2-block-locations 2block))
 149           (unless (eql (source-path-tlf-number
 150                         (node-source-path
 151                          (vop-node (location-info-vop loc))))
 152                        res)
 153             (setq res nil)))))
 154     res))
 155
 156 ;;; Dump out the number of locations and the locations for Block.
 157 (defun dump-block-locations (block locations tlf-num var-locs)
 158   (declare (type cblock block) (list locations))
 159   (if (and locations
 160            (eq (location-info-kind (first locations))
 161                :non-local-entry))
 162       (write-var-integer (length locations) *byte-buffer*)
 163       (let ((2block (block-info block)))
 164         (write-var-integer (+ (length locations) 1) *byte-buffer*)
 165         (dump-1-location (continuation-next (block-start block))
 166                          2block :block-start tlf-num
 167                          (ir2-block-%label 2block)
 168                          (ir2-block-live-out 2block)
 169                          var-locs
 170                          nil)))
 171   (dolist (loc locations)
 172     (dump-location-from-info loc tlf-num var-locs))
 173   (values))
 174
 175 ;;; Dump the successors of Block, being careful not to fly into space on
 176 ;;; weird successors.
 177 (defun dump-block-successors (block env)
 178   (declare (type cblock block) (type environment env))
 179   (let* ((tail (component-tail (block-component block)))
 180          (succ (block-succ block))
 181          (valid-succ
 182           (if (and succ
 183                    (or (eq (car succ) tail)
 184                        (not (eq (block-environment (car succ)) env))))
 185               ()
 186               succ)))
 187     (vector-push-extend
 188      (dpb (length valid-succ) compiled-debug-block-nsucc-byte 0)
 189      *byte-buffer*)
 190     (let ((base (block-number
 191                  (node-block
 192                   (lambda-bind (environment-function env))))))
 193       (dolist (b valid-succ)
 194         (write-var-integer
 195          (the index (- (block-number b) base))
 196          *byte-buffer*))))
 197   (values))
 198
 199 ;;; Return a vector and an integer (or null) suitable for use as the
 200 ;;; BLOCKS and TLF-NUMBER in Fun's debug-function. This requires two
 201 ;;; passes to compute:
 202 ;;; -- Scan all blocks, dumping the header and successors followed
 203 ;;;    by all the non-elsewhere locations.
 204 ;;; -- Dump the elsewhere block header and all the elsewhere
 205 ;;;    locations (if any.)
 206 (defun compute-debug-blocks (fun var-locs)
 207   (declare (type clambda fun) (type hash-table var-locs))
 208   (setf (fill-pointer *byte-buffer*) 0)
 209   (let ((*previous-location* 0)
 210         (tlf-num (find-tlf-number fun))
 211         (env (lambda-environment fun))
 212         (prev-locs nil)
 213         (prev-block nil))
 214     (collect ((elsewhere))
 215       (do-environment-ir2-blocks (2block env)
 216         (let ((block (ir2-block-block 2block)))
 217           (when (eq (block-info block) 2block)
 218             (when prev-block
 219               (dump-block-locations prev-block prev-locs tlf-num var-locs))
 220             (setq prev-block block  prev-locs ())
 221             (dump-block-successors block env)))
 222
 223         (collect ((here prev-locs))
 224           (dolist (loc (ir2-block-locations 2block))
 225             (if (label-elsewhere-p (location-info-label loc))
 226                 (elsewhere loc)
 227                 (here loc)))
 228           (setq prev-locs (here))))
 229
 230       (dump-block-locations prev-block prev-locs tlf-num var-locs)
 231
 232       (when (elsewhere)
 233         (vector-push-extend compiled-debug-block-elsewhere-p *byte-buffer*)
 234         (write-var-integer (length (elsewhere)) *byte-buffer*)
 235         (dolist (loc (elsewhere))
 236           (dump-location-from-info loc tlf-num var-locs))))
 237
 238     (values (copy-seq *byte-buffer*) tlf-num)))
 239 \f
 240 ;;; Return a list of DEBUG-SOURCE structures containing information
 241 ;;; derived from INFO. Unless :BYTE-COMPILE T was specified, we always
 242 ;;; dump the Start-Positions, since it is too hard figure out whether
 243 ;;; we need them or not.
 244 (defun debug-source-for-info (info)
 245   (declare (type source-info info))
 246   (assert (not (source-info-current-file info)))
 247   (mapcar #'(lambda (x)
 248               (let ((res (make-debug-source
 249                           :from :file
 250                           :created (file-info-write-date x)
 251                           :compiled (source-info-start-time info)
 252                           :source-root (file-info-source-root x)
 253                           :start-positions
 254                           (unless (eq *byte-compile* 't)
 255                             (coerce-to-smallest-eltype
 256                              (file-info-positions x)))))
 257                     (name (file-info-name x)))
 258                 (etypecase name
 259                   ((member :lisp)
 260                    (setf (debug-source-from res) name)
 261                    (setf (debug-source-name res)
 262                          (coerce (file-info-forms x) 'simple-vector)))
 263                   (pathname
 264                    (let* ((untruename (file-info-untruename x))
 265                           (dir (pathname-directory untruename)))
 266                      (setf (debug-source-name res)
 267                            (namestring
 268                             (if (and dir (eq (first dir) :absolute))
 269                                 untruename
 270                                 name))))))
 271                 res))
 272           (source-info-files info)))
 273
 274 ;;; Given an arbitrary sequence, coerce it to an unsigned vector if
 275 ;;; possible. Ordinarily we coerce it to the smallest specialized
 276 ;;; vector we can. However, we also have a special hack for
 277 ;;; cross-compiling at bootstrap time, when arbitrarily-specialized
 278 ;;; aren't fully supported: in that case, we coerce it only to a
 279 ;;; vector whose element size is an integer multiple of output byte
 280 ;;; size.
 281 (defun coerce-to-smallest-eltype (seq)
 282   (let ((maxoid #-sb-xc-host 0
 283                 ;; An initial value value of 255 prevents us from
 284                 ;; specializing the array to anything smaller than
 285                 ;; (UNSIGNED-BYTE 8), which keeps the cross-compiler's
 286                 ;; portable specialized array output functions happy.
 287                 #+sb-xc-host 255))
 288     (flet ((frob (x)
 289              (if (typep x 'unsigned-byte)
 290                (when (>= x maxoid)
 291                  (setf maxoid x))
 292                (return-from coerce-to-smallest-eltype
 293                  (coerce seq 'simple-vector)))))
 294       (if (listp seq)
 295         (dolist (i seq)
 296           (frob i))
 297         (dovector (i seq)
 298           (frob i)))
 299       (coerce seq `(simple-array (integer 0 ,maxoid) (*))))))
 300 \f
 301 ;;;; variables
 302
 303 ;;; Return a SC-OFFSET describing TN's location.
 304 (defun tn-sc-offset (tn)
 305   (declare (type tn tn))
 306   (make-sc-offset (sc-number (tn-sc tn))
 307                   (tn-offset tn)))
 308
 309 ;;; Dump info to represent Var's location being TN. ID is an integer
 310 ;;; that makes Var's name unique in the function. Buffer is the vector
 311 ;;; we stick the result in. If Minimal is true, we suppress name
 312 ;;; dumping, and set the minimal flag.
 313 ;;;
 314 ;;; The debug-var is only marked as always-live if the TN is
 315 ;;; environment live and is an argument. If a :debug-environment TN,
 316 ;;; then we also exclude set variables, since the variable is not
 317 ;;; guaranteed to be live everywhere in that case.
 318 (defun dump-1-variable (fun var tn id minimal buffer)
 319   (declare (type lambda-var var) (type (or tn null) tn) (type index id)
 320            (type clambda fun))
 321   (let* ((name (leaf-name var))
 322          (save-tn (and tn (tn-save-tn tn)))
 323          (kind (and tn (tn-kind tn)))
 324          (flags 0))
 325     (declare (type index flags))
 326     (when minimal
 327       (setq flags (logior flags compiled-debug-var-minimal-p))
 328       (unless tn
 329         (setq flags (logior flags compiled-debug-var-deleted-p))))
 330     (when (and (or (eq kind :environment)
 331                    (and (eq kind :debug-environment)
 332                         (null (basic-var-sets var))))
 333                (not (gethash tn (ir2-component-spilled-tns
 334                                  (component-info *component-being-compiled*))))
 335                (eq (lambda-var-home var) fun))
 336       (setq flags (logior flags compiled-debug-var-environment-live)))
 337     (when save-tn
 338       (setq flags (logior flags compiled-debug-var-save-loc-p)))
 339     (unless (or (zerop id) minimal)
 340       (setq flags (logior flags compiled-debug-var-id-p)))
 341     (vector-push-extend flags buffer)
 342     (unless minimal
 343       (vector-push-extend name buffer)
 344       (unless (zerop id)
 345         (vector-push-extend id buffer)))
 346     (if tn
 347         (vector-push-extend (tn-sc-offset tn) buffer)
 348         (assert minimal))
 349     (when save-tn
 350       (vector-push-extend (tn-sc-offset save-tn) buffer)))
 351   (values))
 352
 353 ;;; Return a vector suitable for use as the DEBUG-FUNCTION-VARIABLES
 354 ;;; of FUN. LEVEL is the current DEBUG-INFO quality. VAR-LOCS is a
 355 ;;; hashtable in which we enter the translation from LAMBDA-VARS to
 356 ;;; the relative position of that variable's location in the resulting
 357 ;;; vector.
 358 (defun compute-variables (fun level var-locs)
 359   (declare (type clambda fun) (type hash-table var-locs))
 360   (collect ((vars))
 361     (labels ((frob-leaf (leaf tn gensym-p)
 362                (let ((name (leaf-name leaf)))
 363                  (when (and name (leaf-refs leaf) (tn-offset tn)
 364                             (or gensym-p (symbol-package name)))
 365                    (vars (cons leaf tn)))))
 366              (frob-lambda (x gensym-p)
 367                (dolist (leaf (lambda-vars x))
 368                  (frob-leaf leaf (leaf-info leaf) gensym-p))))
 369       (frob-lambda fun t)
 370       (when (>= level 2)
 371         (dolist (x (ir2-environment-environment
 372                     (environment-info (lambda-environment fun))))
 373           (let ((thing (car x)))
 374             (when (lambda-var-p thing)
 375               (frob-leaf thing (cdr x) (= level 3)))))
 376
 377         (dolist (let (lambda-lets fun))
 378           (frob-lambda let (= level 3)))))
 379
 380     (let ((sorted (sort (vars) #'string<
 381                         :key #'(lambda (x)
 382                                  (symbol-name (leaf-name (car x))))))
 383           (prev-name nil)
 384           (id 0)
 385           (i 0)
 386           (buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 387       (declare (type (or simple-string null) prev-name)
 388                (type index id i))
 389       (dolist (x sorted)
 390         (let* ((var (car x))
 391                (name (symbol-name (leaf-name var))))
 392           (cond ((and prev-name (string= prev-name name))
 393                  (incf id))
 394                 (t
 395                  (setq id 0  prev-name name)))
 396           (dump-1-variable fun var (cdr x) id nil buffer)
 397           (setf (gethash var var-locs) i))
 398         (incf i))
 399       (coerce buffer 'simple-vector))))
 400
 401 ;;; Return a vector suitable for use as the DEBUG-FUNCTION-VARIABLES of
 402 ;;; FUN, representing the arguments to FUN in minimal variable format.
 403 (defun compute-minimal-variables (fun)
 404   (declare (type clambda fun))
 405   (let ((buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 406     (dolist (var (lambda-vars fun))
 407       (dump-1-variable fun var (leaf-info var) 0 t buffer))
 408     (coerce buffer 'simple-vector)))
 409
 410 ;;; Return Var's relative position in the function's variables (determined
 411 ;;; from the Var-Locs hashtable.)  If Var is deleted, then return DELETED.
 412 (defun debug-location-for (var var-locs)
 413   (declare (type lambda-var var) (type hash-table var-locs))
 414   (let ((res (gethash var var-locs)))
 415     (cond (res)
 416           (t
 417            (assert (or (null (leaf-refs var))
 418                        (not (tn-offset (leaf-info var)))))
 419            'deleted))))
 420 \f
 421 ;;;; arguments/returns
 422
 423 ;;; Return a vector to be used as the
 424 ;;; COMPILED-DEBUG-FUNCTION-ARGUMENTS for Fun. If fun is the
 425 ;;; MAIN-ENTRY for an optional dispatch, then look at the ARGLIST to
 426 ;;; determine the syntax, otherwise pretend all arguments are fixed.
 427 ;;;
 428 ;;; ### This assumption breaks down in EPs other than the main-entry,
 429 ;;; since they may or may not have supplied-p vars, etc.
 430 (defun compute-arguments (fun var-locs)
 431   (declare (type clambda fun) (type hash-table var-locs))
 432   (collect ((res))
 433     (let ((od (lambda-optional-dispatch fun)))
 434       (if (and od (eq (optional-dispatch-main-entry od) fun))
 435           (let ((actual-vars (lambda-vars fun))
 436                 (saw-optional nil))
 437             (dolist (arg (optional-dispatch-arglist od))
 438               (let ((info (lambda-var-arg-info arg))
 439                     (actual (pop actual-vars)))
 440                 (cond (info
 441                        (case (arg-info-kind info)
 442                          (:keyword
 443                           (res (arg-info-keyword info)))
 444                          (:rest
 445                           (res 'rest-arg))
 446                          (:more-context
 447                           (res 'more-arg))
 448                          (:optional
 449                           (unless saw-optional
 450                             (res 'optional-args)
 451                             (setq saw-optional t))))
 452                        (res (debug-location-for actual var-locs))
 453                        (when (arg-info-supplied-p info)
 454                          (res 'supplied-p)
 455                          (res (debug-location-for (pop actual-vars) var-locs))))
 456                       (t
 457                        (res (debug-location-for actual var-locs)))))))
 458           (dolist (var (lambda-vars fun))
 459             (res (debug-location-for var var-locs)))))
 460
 461     (coerce-to-smallest-eltype (res))))
 462
 463 ;;; Return a vector of SC offsets describing Fun's return locations.
 464 ;;; (Must be known values return...)
 465 (defun compute-debug-returns (fun)
 466   (coerce-to-smallest-eltype
 467    (mapcar #'(lambda (loc)
 468                (tn-sc-offset loc))
 469            (return-info-locations (tail-set-info (lambda-tail-set fun))))))
 470 \f
 471 ;;;; debug functions
 472
 473 ;;; Return a C-D-F structure with all the mandatory slots filled in.
 474 (defun dfun-from-fun (fun)
 475   (declare (type clambda fun))
 476   (let* ((2env (environment-info (lambda-environment fun)))
 477          (dispatch (lambda-optional-dispatch fun))
 478          (main-p (and dispatch
 479                       (eq fun (optional-dispatch-main-entry dispatch)))))
 480     (make-compiled-debug-function
 481      :name (cond ((leaf-name fun))
 482                  ((let ((ef (functional-entry-function
 483                              fun)))
 484                     (and ef (leaf-name ef))))
 485                  ((and main-p (leaf-name dispatch)))
 486                  (t
 487                   (component-name
 488                    (block-component (node-block (lambda-bind fun))))))
 489      :kind (if main-p nil (functional-kind fun))
 490      :return-pc (tn-sc-offset (ir2-environment-return-pc 2env))
 491      :old-fp (tn-sc-offset (ir2-environment-old-fp 2env))
 492      :start-pc (label-position (ir2-environment-environment-start 2env))
 493      :elsewhere-pc (label-position (ir2-environment-elsewhere-start 2env)))))
 494
 495 ;;; Return a complete C-D-F structure for Fun. This involves
 496 ;;; determining the DEBUG-INFO level and filling in optional slots as
 497 ;;; appropriate.
 498 (defun compute-1-debug-function (fun var-locs)
 499   (declare (type clambda fun) (type hash-table var-locs))
 500   (let* ((dfun (dfun-from-fun fun))
 501          (actual-level (policy (lambda-bind fun) debug))
 502          (level (if #!+sb-dyncount *collect-dynamic-statistics*
 503                     #!-sb-dyncount nil
 504                     (max actual-level 2)
 505                     actual-level)))
 506     (cond ((zerop level))
 507           ((and (<= level 1)
 508                 (let ((od (lambda-optional-dispatch fun)))
 509                   (or (not od)
 510                       (not (eq (optional-dispatch-main-entry od) fun)))))
 511            (setf (compiled-debug-function-variables dfun)
 512                  (compute-minimal-variables fun))
 513            (setf (compiled-debug-function-arguments dfun) :minimal))
 514           (t
 515            (setf (compiled-debug-function-variables dfun)
 516                  (compute-variables fun level var-locs))
 517            (setf (compiled-debug-function-arguments dfun)
 518                  (compute-arguments fun var-locs))))
 519
 520     (when (>= level 2)
 521       (multiple-value-bind (blocks tlf-num) (compute-debug-blocks fun var-locs)
 522         (setf (compiled-debug-function-tlf-number dfun) tlf-num)
 523         (setf (compiled-debug-function-blocks dfun) blocks)))
 524
 525     (if (external-entry-point-p fun)
 526         (setf (compiled-debug-function-returns dfun) :standard)
 527         (let ((info (tail-set-info (lambda-tail-set fun))))
 528           (when info
 529             (cond ((eq (return-info-kind info) :unknown)
 530                    (setf (compiled-debug-function-returns dfun)
 531                          :standard))
 532                   ((/= level 0)
 533                    (setf (compiled-debug-function-returns dfun)
 534                          (compute-debug-returns fun)))))))
 535     dfun))
 536 \f
 537 ;;;; minimal debug functions
 538
 539 ;;; Return true if DFUN can be represented as a minimal debug
 540 ;;; function. DFUN is a cons (<start offset> . C-D-F).
 541 (defun debug-function-minimal-p (dfun)
 542   (declare (type cons dfun))
 543   (let ((dfun (cdr dfun)))
 544     (and (member (compiled-debug-function-arguments dfun) '(:minimal nil))
 545          (null (compiled-debug-function-blocks dfun)))))
 546
 547 ;;; Dump a packed binary representation of a DFUN into *BYTE-BUFFER*.
 548 ;;; PREV-START and START are the byte offsets in the code where the
 549 ;;; previous function started and where this one starts.
 550 ;;; PREV-ELSEWHERE is the previous function's elsewhere PC.
 551 (defun dump-1-minimal-dfun (dfun prev-start start prev-elsewhere)
 552   (declare (type compiled-debug-function dfun)
 553            (type index prev-start start prev-elsewhere))
 554   (let* ((name (compiled-debug-function-name dfun))
 555          (setf-p (and (consp name) (eq (car name) 'setf)
 556                       (consp (cdr name)) (symbolp (cadr name))))
 557          (base-name (if setf-p (cadr name) name))
 558          (pkg (when (symbolp base-name)
 559                 (symbol-package base-name)))
 560          (name-rep
 561           (cond ((stringp base-name)
 562                  minimal-debug-function-name-component)
 563                 ((not pkg)
 564                  minimal-debug-function-name-uninterned)
 565                 ((eq pkg (sane-package))
 566                  minimal-debug-function-name-symbol)
 567                 (t
 568                  minimal-debug-function-name-packaged))))
 569     (assert (or (atom name) setf-p))
 570     (let ((options 0))
 571       (setf (ldb minimal-debug-function-name-style-byte options) name-rep)
 572       (setf (ldb minimal-debug-function-kind-byte options)
 573             (position-or-lose (compiled-debug-function-kind dfun)
 574                               *minimal-debug-function-kinds*))
 575       (setf (ldb minimal-debug-function-returns-byte options)
 576             (etypecase (compiled-debug-function-returns dfun)
 577               ((member :standard) minimal-debug-function-returns-standard)
 578               ((member :fixed) minimal-debug-function-returns-fixed)
 579               (vector minimal-debug-function-returns-specified)))
 580       (vector-push-extend options *byte-buffer*))
 581
 582     (let ((flags 0))
 583       (when setf-p
 584         (setq flags (logior flags minimal-debug-function-setf-bit)))
 585       (when (compiled-debug-function-nfp dfun)
 586         (setq flags (logior flags minimal-debug-function-nfp-bit)))
 587       (when (compiled-debug-function-variables dfun)
 588         (setq flags (logior flags minimal-debug-function-variables-bit)))
 589       (vector-push-extend flags *byte-buffer*))
 590
 591     (when (eql name-rep minimal-debug-function-name-packaged)
 592       (write-var-string (package-name pkg) *byte-buffer*))
 593     (unless (stringp base-name)
 594       (write-var-string (symbol-name base-name) *byte-buffer*))
 595
 596     (let ((vars (compiled-debug-function-variables dfun)))
 597       (when vars
 598         (let ((len (length vars)))
 599           (write-var-integer len *byte-buffer*)
 600           (dotimes (i len)
 601             (vector-push-extend (aref vars i) *byte-buffer*)))))
 602
 603     (let ((returns (compiled-debug-function-returns dfun)))
 604       (when (vectorp returns)
 605         (let ((len (length returns)))
 606           (write-var-integer len *byte-buffer*)
 607           (dotimes (i len)
 608             (write-var-integer (aref returns i) *byte-buffer*)))))
 609
 610     (write-var-integer (compiled-debug-function-return-pc dfun)
 611                        *byte-buffer*)
 612     (write-var-integer (compiled-debug-function-old-fp dfun)
 613                        *byte-buffer*)
 614     (when (compiled-debug-function-nfp dfun)
 615       (write-var-integer (compiled-debug-function-nfp dfun)
 616                          *byte-buffer*))
 617     (write-var-integer (- start prev-start) *byte-buffer*)
 618     (write-var-integer (- (compiled-debug-function-start-pc dfun) start)
 619                        *byte-buffer*)
 620     (write-var-integer (- (compiled-debug-function-elsewhere-pc dfun)
 621                           prev-elsewhere)
 622                        *byte-buffer*)))
 623
 624 ;;; Return a byte-vector holding all the debug functions for a
 625 ;;; component in the packed binary minimal-debug-function format.
 626 (defun compute-minimal-debug-functions (dfuns)
 627   (declare (list dfuns))
 628   (setf (fill-pointer *byte-buffer*) 0)
 629   (let ((prev-start 0)
 630         (prev-elsewhere 0))
 631     (dolist (dfun dfuns)
 632       (let ((start (car dfun))
 633             (elsewhere (compiled-debug-function-elsewhere-pc (cdr dfun))))
 634         (dump-1-minimal-dfun (cdr dfun) prev-start start prev-elsewhere)
 635         (setq prev-start start  prev-elsewhere elsewhere))))
 636   (copy-seq *byte-buffer*))
 637 \f
 638 ;;;; full component dumping
 639
 640 ;;; Compute the full form (simple-vector) function map.
 641 (defun compute-debug-function-map (sorted)
 642   (declare (list sorted))
 643   (let* ((len (1- (* (length sorted) 2)))
 644          (funs-vec (make-array len)))
 645     (do ((i -1 (+ i 2))
 646          (sorted sorted (cdr sorted)))
 647         ((= i len))
 648       (declare (fixnum i))
 649       (let ((dfun (car sorted)))
 650         (unless (minusp i)
 651           (setf (svref funs-vec i) (car dfun)))
 652         (setf (svref funs-vec (1+ i)) (cdr dfun))))
 653     funs-vec))
 654
 655 ;;; Return a DEBUG-INFO structure describing COMPONENT. This has to be
 656 ;;; called after assembly so that source map information is available.
 657 (defun debug-info-for-component (component)
 658   (declare (type component component))
 659   (collect ((dfuns))
 660     (let ((var-locs (make-hash-table :test 'eq))
 661           ;; FIXME: What is *BYTE-BUFFER* for? Has it become dead code
 662           ;; now that we no longer use minimal-debug-function
 663           ;; representation?
 664           (*byte-buffer* (make-array 10
 665                                      :element-type '(unsigned-byte 8)
 666                                      :fill-pointer 0
 667                                      :adjustable t)))
 668       (dolist (fun (component-lambdas component))
 669         (clrhash var-locs)
 670         (dfuns (cons (label-position
 671                       (block-label (node-block (lambda-bind fun))))
 672                      (compute-1-debug-function fun var-locs))))
 673       (let* ((sorted (sort (dfuns) #'< :key #'car))
 674              ;; FIXME: CMU CL had
 675              ;;    (IF (EVERY #'DEBUG-FUNCTION-MINIMAL-P SORTED)
 676              ;;        (COMPUTE-MINIMAL-DEBUG-FUNCTIONS SORTED)
 677              ;;        (COMPUTE-DEBUG-FUNCTION-MAP SORTED))
 678              ;; here. We've gotten rid of the minimal-debug-function
 679              ;; case in SBCL because the minimal representation
 680              ;; couldn't be made to transform properly under package
 681              ;; renaming. Now that that case is gone, a lot of code is
 682              ;; dead, and once everything is known to work, the dead
 683              ;; code should be deleted.
 684              (function-map (compute-debug-function-map sorted)))
 685         (make-compiled-debug-info :name (component-name component)
 686                                   :function-map function-map)))))
 687 \f
 688 ;;; Write BITS out to BYTE-BUFFER in backend byte order. The length of
 689 ;;; BITS must be evenly divisible by eight.
 690 (defun write-packed-bit-vector (bits byte-buffer)
 691   (declare (type simple-bit-vector bits) (type byte-buffer byte-buffer))
 692   (multiple-value-bind (initial step done)
 693       (ecase *backend-byte-order*
 694         (:little-endian (values 0  1  8))
 695         (:big-endian    (values 7 -1 -1)))
 696     (let ((shift initial)
 697           (byte 0))
 698       (dotimes (i (length bits))
 699         (let ((int (aref bits i)))
 700           (setf byte (logior byte (ash int shift)))
 701           (incf shift step))
 702         (when (= shift done)
 703           (vector-push-extend byte byte-buffer)
 704           (setf shift initial
 705                 byte 0)))
 706       (unless (= shift initial)
 707         (vector-push-extend byte byte-buffer))))
 708   (values))