src/compiler/debug-dump.lisp

   1 ;;;; stuff that creates debugger information from the compiler's
   2 ;;;; internal data structures
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (deftype byte-buffer () '(vector (unsigned-byte 8)))
  16 (defvar *byte-buffer*)
  17 (declaim (type byte-buffer *byte-buffer*))
  18 \f
  19 ;;;; debug blocks
  20
  21 (deftype location-kind ()
  22   '(member :unknown-return :known-return :internal-error :non-local-exit
  23            :block-start :call-site :single-value-return :non-local-entry))
  24
  25 ;;; The LOCATION-INFO structure holds the information what we need
  26 ;;; about locations which code generation decided were "interesting".
  27 (defstruct (location-info
  28             (:constructor make-location-info (kind label vop))
  29             (:copier nil))
  30   ;; The kind of location noted.
  31   (kind nil :type location-kind)
  32   ;; The label pointing to the interesting code location.
  33   (label nil :type (or label index null))
  34   ;; The VOP that emitted this location (for node, save-set, ir2-block, etc.)
  35   (vop nil :type vop))
  36
  37 ;;; This is called during code generation in places where there is an
  38 ;;; "interesting" location: someplace where we are likely to end up
  39 ;;; in the debugger, and thus want debug info.
  40 (defun note-debug-location (vop label kind)
  41   (declare (type vop vop) (type (or label null) label)
  42            (type location-kind kind))
  43   (let ((location (make-location-info kind label vop)))
  44     (setf (ir2-block-locations (vop-block vop))
  45           (nconc (ir2-block-locations (vop-block vop))
  46                  (list location)))
  47     location))
  48
  49 #!-sb-fluid (declaim (inline ir2-block-physenv))
  50 (defun ir2-block-physenv (2block)
  51   (declare (type ir2-block 2block))
  52   (block-physenv (ir2-block-block 2block)))
  53
  54 ;;; Given a local conflicts vector and an IR2 block to represent the
  55 ;;; set of live TNs, and the VAR-LOCS hash-table representing the
  56 ;;; variables dumped, compute a bit-vector representing the set of
  57 ;;; live variables. If the TN is environment-live, we only mark it as
  58 ;;; live when it is in scope at NODE.
  59 (defun compute-live-vars (live node block var-locs vop)
  60   (declare (type ir2-block block) (type local-tn-bit-vector live)
  61            (type hash-table var-locs) (type node node)
  62            (type (or vop null) vop))
  63   (let ((res (make-array (logandc2 (+ (hash-table-count var-locs) 7) 7)
  64                          :element-type 'bit
  65                          :initial-element 0))
  66         (spilled (gethash vop
  67                           (ir2-component-spilled-vops
  68                            (component-info *component-being-compiled*)))))
  69     (do-live-tns (tn live block)
  70       (let ((leaf (tn-leaf tn)))
  71         (when (and (lambda-var-p leaf)
  72                    (or (not (member (tn-kind tn)
  73                                     '(:environment :debug-environment)))
  74                        (rassoc leaf (lexenv-vars (node-lexenv node))))
  75                    (or (null spilled)
  76                        (not (member tn spilled))))
  77           (let ((num (gethash leaf var-locs)))
  78             (when num
  79               (setf (sbit res num) 1))))))
  80     res))
  81
  82 ;;; The PC for the location most recently dumped.
  83 (defvar *previous-location*)
  84 (declaim (type index *previous-location*))
  85
  86 ;;; Dump a compiled debug-location into *BYTE-BUFFER* that describes
  87 ;;; the code/source map and live info. If true, VOP is the VOP
  88 ;;; associated with this location, for use in determining whether TNs
  89 ;;; are spilled.
  90 (defun dump-1-location (node block kind tlf-num label live var-locs vop)
  91   (declare (type node node) (type ir2-block block)
  92            (type local-tn-bit-vector live)
  93            (type (or label index) label)
  94            (type location-kind kind) (type (or index null) tlf-num)
  95            (type hash-table var-locs) (type (or vop null) vop))
  96
  97   (vector-push-extend
  98    (dpb (position-or-lose kind *compiled-code-location-kinds*)
  99         compiled-code-location-kind-byte
 100         0)
 101    *byte-buffer*)
 102
 103   (let ((loc (if (fixnump label) label (label-position label))))
 104     (write-var-integer (- loc *previous-location*) *byte-buffer*)
 105     (setq *previous-location* loc))
 106
 107   (let ((path (node-source-path node)))
 108     (unless tlf-num
 109       (write-var-integer (source-path-tlf-number path) *byte-buffer*))
 110     (write-var-integer (source-path-form-number path) *byte-buffer*))
 111
 112   (write-packed-bit-vector (compute-live-vars live node block var-locs vop)
 113                            *byte-buffer*)
 114
 115   (values))
 116
 117 ;;; Extract context info from a Location-Info structure and use it to
 118 ;;; dump a compiled code-location.
 119 (defun dump-location-from-info (loc tlf-num var-locs)
 120   (declare (type location-info loc) (type (or index null) tlf-num)
 121            (type hash-table var-locs))
 122   (let ((vop (location-info-vop loc)))
 123     (dump-1-location (vop-node vop)
 124                      (vop-block vop)
 125                      (location-info-kind loc)
 126                      tlf-num
 127                      (location-info-label loc)
 128                      (vop-save-set vop)
 129                      var-locs
 130                      vop))
 131   (values))
 132
 133 ;;; Scan all the blocks, determining if all locations are in the same
 134 ;;; TLF, and returning it or NIL.
 135 (defun find-tlf-number (fun)
 136   (declare (type clambda fun))
 137   (let ((res (source-path-tlf-number (node-source-path (lambda-bind fun)))))
 138     (declare (type (or index null) res))
 139     (do-physenv-ir2-blocks (2block (lambda-physenv fun))
 140       (let ((block (ir2-block-block 2block)))
 141         (when (eq (block-info block) 2block)
 142           (unless (eql (source-path-tlf-number
 143                         (node-source-path
 144                          (block-start-node block)))
 145                        res)
 146             (setq res nil)))
 147
 148         (dolist (loc (ir2-block-locations 2block))
 149           (unless (eql (source-path-tlf-number
 150                         (node-source-path
 151                          (vop-node (location-info-vop loc))))
 152                        res)
 153             (setq res nil)))))
 154     res))
 155
 156 ;;; Dump out the number of locations and the locations for Block.
 157 (defun dump-block-locations (block locations tlf-num var-locs)
 158   (declare (type cblock block) (list locations))
 159   (if (and locations
 160            (eq (location-info-kind (first locations))
 161                :non-local-entry))
 162       (write-var-integer (length locations) *byte-buffer*)
 163       (let ((2block (block-info block)))
 164         (write-var-integer (+ (length locations) 1) *byte-buffer*)
 165         (dump-1-location (block-start-node block)
 166                          2block :block-start tlf-num
 167                          (ir2-block-%label 2block)
 168                          (ir2-block-live-out 2block)
 169                          var-locs
 170                          nil)))
 171   (dolist (loc locations)
 172     (dump-location-from-info loc tlf-num var-locs))
 173   (values))
 174
 175 ;;; Dump the successors of Block, being careful not to fly into space
 176 ;;; on weird successors.
 177 (defun dump-block-successors (block physenv)
 178   (declare (type cblock block) (type physenv physenv))
 179   (let* ((tail (component-tail (block-component block)))
 180          (succ (block-succ block))
 181          (valid-succ
 182           (if (and succ
 183                    (or (eq (car succ) tail)
 184                        (not (eq (block-physenv (car succ)) physenv))))
 185               ()
 186               succ)))
 187     (vector-push-extend
 188      (dpb (length valid-succ) compiled-debug-block-nsucc-byte 0)
 189      *byte-buffer*)
 190     (let ((base (block-number
 191                  (node-block
 192                   (lambda-bind (physenv-lambda physenv))))))
 193       (dolist (b valid-succ)
 194         (write-var-integer
 195          (the index (- (block-number b) base))
 196          *byte-buffer*))))
 197   (values))
 198
 199 ;;; Return a vector and an integer (or null) suitable for use as the
 200 ;;; BLOCKS and TLF-NUMBER in FUN's DEBUG-FUN. This requires two
 201 ;;; passes to compute:
 202 ;;; -- Scan all blocks, dumping the header and successors followed
 203 ;;;    by all the non-elsewhere locations.
 204 ;;; -- Dump the elsewhere block header and all the elsewhere
 205 ;;;    locations (if any.)
 206 (defun compute-debug-blocks (fun var-locs)
 207   (declare (type clambda fun) (type hash-table var-locs))
 208   (setf (fill-pointer *byte-buffer*) 0)
 209   (let ((*previous-location* 0)
 210         (tlf-num (find-tlf-number fun))
 211         (physenv (lambda-physenv fun))
 212         (prev-locs nil)
 213         (prev-block nil))
 214     (collect ((elsewhere))
 215       (do-physenv-ir2-blocks (2block physenv)
 216         (let ((block (ir2-block-block 2block)))
 217           (when (eq (block-info block) 2block)
 218             (when prev-block
 219               (dump-block-locations prev-block prev-locs tlf-num var-locs))
 220             (setq prev-block block  prev-locs ())
 221             (dump-block-successors block physenv)))
 222
 223         (collect ((here prev-locs))
 224           (dolist (loc (ir2-block-locations 2block))
 225             (if (label-elsewhere-p (location-info-label loc))
 226                 (elsewhere loc)
 227                 (here loc)))
 228           (setq prev-locs (here))))
 229
 230       (dump-block-locations prev-block prev-locs tlf-num var-locs)
 231
 232       (when (elsewhere)
 233         (vector-push-extend compiled-debug-block-elsewhere-p *byte-buffer*)
 234         (write-var-integer (length (elsewhere)) *byte-buffer*)
 235         (dolist (loc (elsewhere))
 236           (dump-location-from-info loc tlf-num var-locs))))
 237
 238     (values (copy-seq *byte-buffer*) tlf-num)))
 239 \f
 240 ;;; Return DEBUG-SOURCE structure containing information derived from
 241 ;;; INFO.
 242 (defun debug-source-for-info (info)
 243   (declare (type source-info info))
 244   (let* ((file-info (source-info-file-info info))
 245          (res (make-debug-source
 246                :from :file
 247                :created (file-info-write-date file-info)
 248                :compiled (source-info-start-time info)
 249                :source-root (file-info-source-root file-info)
 250                :start-positions (coerce-to-smallest-eltype
 251                                  (file-info-positions file-info))))
 252          (name (file-info-name file-info)))
 253     (etypecase name
 254       ((member :lisp)
 255        (setf (debug-source-from res) name
 256              (debug-source-name res) (file-info-forms file-info)))
 257       (pathname
 258        (setf (debug-source-name res)
 259              (make-file-info-namestring name file-info))))
 260     res))
 261
 262 ;;; Given an arbitrary sequence, coerce it to an unsigned vector if
 263 ;;; possible. Ordinarily we coerce it to the smallest specialized
 264 ;;; vector we can. However, we also have a special hack for
 265 ;;; cross-compiling at bootstrap time, when arbitrarily-specialized
 266 ;;; vectors aren't fully supported: in that case, we coerce it only to
 267 ;;; a vector whose element size is an integer multiple of output byte
 268 ;;; size.
 269 (defun coerce-to-smallest-eltype (seq)
 270   (let ((maxoid 0))
 271     (flet ((frob (x)
 272              (if (typep x 'unsigned-byte)
 273                  (when (>= x maxoid)
 274                    (setf maxoid x))
 275                  (return-from coerce-to-smallest-eltype
 276                    (coerce seq 'simple-vector)))))
 277       (if (listp seq)
 278           (dolist (i seq)
 279             (frob i))
 280           (dovector (i seq)
 281             (frob i)))
 282       (let ((specializer `(unsigned-byte
 283                            ,(etypecase maxoid
 284                               ((unsigned-byte 8) 8)
 285                               ((unsigned-byte 16) 16)
 286                               ((unsigned-byte 32) 32)))))
 287         ;; cross-compilers beware! It would be possible for the
 288         ;; upgraded-array-element-type of (UNSIGNED-BYTE 16) to be
 289         ;; (SIGNED-BYTE 17) or (UNSIGNED-BYTE 23), and this is
 290         ;; completely valid by ANSI.  However, the cross-compiler
 291         ;; doesn't know how to dump (in practice) anything but the
 292         ;; above three specialized array types, so make it break here
 293         ;; if this is violated.
 294         #+sb-xc-host
 295         (aver
 296          ;; not SB!XC:UPGRADED-ARRAY-ELEMENT-TYPE, because we are
 297          ;; worried about whether the host's implementation of arrays.
 298          (let ((uaet (upgraded-array-element-type specializer)))
 299            (dolist (et '((unsigned-byte 8)
 300                          (unsigned-byte 16)
 301                          (unsigned-byte 32))
 302                     nil)
 303              (when (and (subtypep et uaet) (subtypep uaet et))
 304                (return t)))))
 305         (coerce seq `(simple-array ,specializer (*)))))))
 306 \f
 307 ;;;; variables
 308
 309 ;;; Return a SC-OFFSET describing TN's location.
 310 (defun tn-sc-offset (tn)
 311   (declare (type tn tn))
 312   (make-sc-offset (sc-number (tn-sc tn))
 313                   (tn-offset tn)))
 314
 315 ;;; Dump info to represent VAR's location being TN. ID is an integer
 316 ;;; that makes VAR's name unique in the function. BUFFER is the vector
 317 ;;; we stick the result in. If MINIMAL, we suppress name dumping, and
 318 ;;; set the minimal flag.
 319 ;;;
 320 ;;; The DEBUG-VAR is only marked as always-live if the TN is
 321 ;;; environment live and is an argument. If a :DEBUG-ENVIRONMENT TN,
 322 ;;; then we also exclude set variables, since the variable is not
 323 ;;; guaranteed to be live everywhere in that case.
 324 (defun dump-1-var (fun var tn id minimal buffer)
 325   (declare (type lambda-var var) (type (or tn null) tn) (type index id)
 326            (type clambda fun))
 327   (let* ((name (leaf-debug-name var))
 328          (save-tn (and tn (tn-save-tn tn)))
 329          (kind (and tn (tn-kind tn)))
 330          (flags 0))
 331     (declare (type index flags))
 332     (when minimal
 333       (setq flags (logior flags compiled-debug-var-minimal-p))
 334       (unless (and tn (tn-offset tn))
 335         (setq flags (logior flags compiled-debug-var-deleted-p))))
 336     (when (and (or (eq kind :environment)
 337                    (and (eq kind :debug-environment)
 338                         (null (basic-var-sets var))))
 339                (not (gethash tn (ir2-component-spilled-tns
 340                                  (component-info *component-being-compiled*))))
 341                (eq (lambda-var-home var) fun))
 342       (setq flags (logior flags compiled-debug-var-environment-live)))
 343     (when save-tn
 344       (setq flags (logior flags compiled-debug-var-save-loc-p)))
 345     (unless (or (zerop id) minimal)
 346       (setq flags (logior flags compiled-debug-var-id-p)))
 347     (vector-push-extend flags buffer)
 348     (unless minimal
 349       (vector-push-extend name buffer)
 350       (unless (zerop id)
 351         (vector-push-extend id buffer)))
 352     (if (and tn (tn-offset tn))
 353         (vector-push-extend (tn-sc-offset tn) buffer)
 354         (aver minimal))
 355     (when save-tn
 356       (vector-push-extend (tn-sc-offset save-tn) buffer)))
 357   (values))
 358
 359 ;;; Return a vector suitable for use as the DEBUG-FUN-VARS
 360 ;;; of FUN. LEVEL is the current DEBUG-INFO quality. VAR-LOCS is a
 361 ;;; hash table in which we enter the translation from LAMBDA-VARS to
 362 ;;; the relative position of that variable's location in the resulting
 363 ;;; vector.
 364 (defun compute-vars (fun level var-locs)
 365   (declare (type clambda fun) (type hash-table var-locs))
 366   (collect ((vars))
 367     (labels ((frob-leaf (leaf tn gensym-p)
 368                (let ((name (leaf-debug-name leaf)))
 369                  (when (and name (leaf-refs leaf) (tn-offset tn)
 370                             (or gensym-p (symbol-package name)))
 371                    (vars (cons leaf tn)))))
 372              (frob-lambda (x gensym-p)
 373                (dolist (leaf (lambda-vars x))
 374                  (frob-leaf leaf (leaf-info leaf) gensym-p))))
 375       (frob-lambda fun t)
 376       (when (>= level 2)
 377         (dolist (x (ir2-physenv-closure (physenv-info (lambda-physenv fun))))
 378           (let ((thing (car x)))
 379             (when (lambda-var-p thing)
 380               (frob-leaf thing (cdr x) (= level 3)))))
 381
 382         (dolist (let (lambda-lets fun))
 383           (frob-lambda let (= level 3)))))
 384
 385     (let ((sorted (sort (vars) #'string<
 386                         :key (lambda (x)
 387                                (symbol-name (leaf-debug-name (car x))))))
 388           (prev-name nil)
 389           (id 0)
 390           (i 0)
 391           (buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 392       (declare (type (or simple-string null) prev-name)
 393                (type index id i))
 394       (dolist (x sorted)
 395         (let* ((var (car x))
 396                (name (symbol-name (leaf-debug-name var))))
 397           (cond ((and prev-name (string= prev-name name))
 398                  (incf id))
 399                 (t
 400                  (setq id 0  prev-name name)))
 401           (dump-1-var fun var (cdr x) id nil buffer)
 402           (setf (gethash var var-locs) i))
 403         (incf i))
 404       (coerce buffer 'simple-vector))))
 405
 406 ;;; Return a vector suitable for use as the DEBUG-FUN-VARS of
 407 ;;; FUN, representing the arguments to FUN in minimal variable format.
 408 (defun compute-minimal-vars (fun)
 409   (declare (type clambda fun))
 410   (let ((buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 411     (dolist (var (lambda-vars fun))
 412       (dump-1-var fun var (leaf-info var) 0 t buffer))
 413     (coerce buffer 'simple-vector)))
 414
 415 ;;; Return VAR's relative position in the function's variables (determined
 416 ;;; from the VAR-LOCS hashtable).  If VAR is deleted, then return DELETED.
 417 (defun debug-location-for (var var-locs)
 418   (declare (type lambda-var var) (type hash-table var-locs))
 419   (let ((res (gethash var var-locs)))
 420     (cond (res)
 421           (t
 422            (aver (or (null (leaf-refs var))
 423                      (not (tn-offset (leaf-info var)))))
 424            'deleted))))
 425 \f
 426 ;;;; arguments/returns
 427
 428 ;;; Return a vector to be used as the COMPILED-DEBUG-FUN-ARGS for FUN.
 429 ;;; If FUN is the MAIN-ENTRY for an optional dispatch, then look at
 430 ;;; the ARGLIST to determine the syntax, otherwise pretend all
 431 ;;; arguments are fixed.
 432 ;;;
 433 ;;; ### This assumption breaks down in EPs other than the main-entry,
 434 ;;; since they may or may not have supplied-p vars, etc.
 435 (defun compute-args (fun var-locs)
 436   (declare (type clambda fun) (type hash-table var-locs))
 437   (collect ((res))
 438     (let ((od (lambda-optional-dispatch fun)))
 439       (if (and od (eq (optional-dispatch-main-entry od) fun))
 440           (let ((actual-vars (lambda-vars fun))
 441                 (saw-optional nil))
 442             (dolist (arg (optional-dispatch-arglist od))
 443               (let ((info (lambda-var-arg-info arg))
 444                     (actual (pop actual-vars)))
 445                 (cond (info
 446                        (case (arg-info-kind info)
 447                          (:keyword
 448                           (res (arg-info-key info)))
 449                          (:rest
 450                           (res 'rest-arg))
 451                          (:more-context
 452                           (res 'more-arg))
 453                          (:optional
 454                           (unless saw-optional
 455                             (res 'optional-args)
 456                             (setq saw-optional t))))
 457                        (res (debug-location-for actual var-locs))
 458                        (when (arg-info-supplied-p info)
 459                          (res 'supplied-p)
 460                          (res (debug-location-for (pop actual-vars) var-locs))))
 461                       (t
 462                        (res (debug-location-for actual var-locs)))))))
 463           (dolist (var (lambda-vars fun))
 464             (res (debug-location-for var var-locs)))))
 465
 466     (coerce-to-smallest-eltype (res))))
 467
 468 ;;; Return a vector of SC offsets describing FUN's return locations.
 469 ;;; (Must be known values return...)
 470 (defun compute-debug-returns (fun)
 471   (coerce-to-smallest-eltype
 472    (mapcar (lambda (loc)
 473              (tn-sc-offset loc))
 474            (return-info-locations (tail-set-info (lambda-tail-set fun))))))
 475 \f
 476 ;;;; debug functions
 477
 478 ;;; Return a C-D-F structure with all the mandatory slots filled in.
 479 (defun dfun-from-fun (fun)
 480   (declare (type clambda fun))
 481   (let* ((2env (physenv-info (lambda-physenv fun)))
 482          (dispatch (lambda-optional-dispatch fun))
 483          (main-p (and dispatch
 484                       (eq fun (optional-dispatch-main-entry dispatch)))))
 485     (make-compiled-debug-fun
 486      :name (leaf-debug-name fun)
 487      :kind (if main-p nil (functional-kind fun))
 488      :return-pc (tn-sc-offset (ir2-physenv-return-pc 2env))
 489      :old-fp (tn-sc-offset (ir2-physenv-old-fp 2env))
 490      :start-pc (label-position (ir2-physenv-environment-start 2env))
 491      :elsewhere-pc (label-position (ir2-physenv-elsewhere-start 2env)))))
 492
 493 ;;; Return a complete C-D-F structure for FUN. This involves
 494 ;;; determining the DEBUG-INFO level and filling in optional slots as
 495 ;;; appropriate.
 496 (defun compute-1-debug-fun (fun var-locs)
 497   (declare (type clambda fun) (type hash-table var-locs))
 498   (let* ((dfun (dfun-from-fun fun))
 499          (actual-level (policy (lambda-bind fun) compute-debug-fun))
 500          (level (if #!+sb-dyncount *collect-dynamic-statistics*
 501                     #!-sb-dyncount nil
 502                     (max actual-level 2)
 503                     actual-level)))
 504     (cond ((zerop level))
 505           ((and (<= level 1)
 506                 (let ((od (lambda-optional-dispatch fun)))
 507                   (or (not od)
 508                       (not (eq (optional-dispatch-main-entry od) fun)))))
 509            (setf (compiled-debug-fun-vars dfun)
 510                  (compute-minimal-vars fun))
 511            (setf (compiled-debug-fun-arguments dfun) :minimal))
 512           (t
 513            (setf (compiled-debug-fun-vars dfun)
 514                  (compute-vars fun level var-locs))
 515            (setf (compiled-debug-fun-arguments dfun)
 516                  (compute-args fun var-locs))))
 517
 518     (if (>= level 2)
 519         (multiple-value-bind (blocks tlf-num)
 520             (compute-debug-blocks fun var-locs)
 521           (setf (compiled-debug-fun-tlf-number dfun) tlf-num)
 522           (setf (compiled-debug-fun-blocks dfun) blocks))
 523         (setf (compiled-debug-fun-tlf-number dfun) (find-tlf-number fun)))
 524
 525     (if (xep-p fun)
 526         (setf (compiled-debug-fun-returns dfun) :standard)
 527         (let ((info (tail-set-info (lambda-tail-set fun))))
 528           (when info
 529             (cond ((eq (return-info-kind info) :unknown)
 530                    (setf (compiled-debug-fun-returns dfun)
 531                          :standard))
 532                   ((/= level 0)
 533                    (setf (compiled-debug-fun-returns dfun)
 534                          (compute-debug-returns fun)))))))
 535     dfun))
 536 \f
 537 ;;;; full component dumping
 538
 539 ;;; Compute the full form (simple-vector) function map.
 540 (defun compute-debug-fun-map (sorted)
 541   (declare (list sorted))
 542   (let* ((len (1- (* (length sorted) 2)))
 543          (funs-vec (make-array len)))
 544     (do ((i -1 (+ i 2))
 545          (sorted sorted (cdr sorted)))
 546         ((= i len))
 547       (declare (fixnum i))
 548       (let ((dfun (car sorted)))
 549         (unless (minusp i)
 550           (setf (svref funs-vec i) (car dfun)))
 551         (setf (svref funs-vec (1+ i)) (cdr dfun))))
 552     funs-vec))
 553
 554 ;;; Return a DEBUG-INFO structure describing COMPONENT. This has to be
 555 ;;; called after assembly so that source map information is available.
 556 (defun debug-info-for-component (component)
 557   (declare (type component component))
 558   (let ((dfuns nil)
 559         (var-locs (make-hash-table :test 'eq))
 560         (*byte-buffer* (make-array 10
 561                                    :element-type '(unsigned-byte 8)
 562                                    :fill-pointer 0
 563                                    :adjustable t)))
 564     (dolist (lambda (component-lambdas component))
 565       (clrhash var-locs)
 566       (push (cons (label-position (block-label (lambda-block lambda)))
 567                   (compute-1-debug-fun lambda var-locs))
 568             dfuns))
 569     (let* ((sorted (sort dfuns #'< :key #'car))
 570            (fun-map (compute-debug-fun-map sorted)))
 571       (make-compiled-debug-info :name (component-name component)
 572                                 :fun-map fun-map))))
 573 \f
 574 ;;; Write BITS out to BYTE-BUFFER in backend byte order. The length of
 575 ;;; BITS must be evenly divisible by eight.
 576 (defun write-packed-bit-vector (bits byte-buffer)
 577   (declare (type simple-bit-vector bits) (type byte-buffer byte-buffer))
 578
 579   ;; Enforce constraint from CMU-CL-era comment.
 580   (aver (zerop (mod (length bits) 8)))
 581
 582   (multiple-value-bind (initial step done)
 583       (ecase *backend-byte-order*
 584         (:little-endian (values 0  1  8))
 585         (:big-endian    (values 7 -1 -1)))
 586     (let ((shift initial)
 587           (byte 0))
 588       (dotimes (i (length bits))
 589         (let ((int (aref bits i)))
 590           (setf byte (logior byte (ash int shift)))
 591           (incf shift step))
 592         (when (= shift done)
 593           (vector-push-extend byte byte-buffer)
 594           (setf shift initial
 595                 byte 0)))
 596       (unless (= shift initial)
 597         (vector-push-extend byte byte-buffer))))
 598   (values))