src/compiler/debug-dump.lisp

   1 ;;;; stuff that creates debugger information from the compiler's
   2 ;;;; internal data structures
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (deftype byte-buffer () '(vector (unsigned-byte 8)))
  16 (defvar *byte-buffer*)
  17 (declaim (type byte-buffer *byte-buffer*))
  18 \f
  19 ;;;; debug blocks
  20
  21 (deftype location-kind ()
  22   '(member :unknown-return :known-return :internal-error :non-local-exit
  23            :block-start :call-site :single-value-return :non-local-entry
  24            :step-before-vop))
  25
  26 ;;; The LOCATION-INFO structure holds the information what we need
  27 ;;; about locations which code generation decided were "interesting".
  28 (defstruct (location-info
  29             (:constructor make-location-info (kind label vop))
  30             (:copier nil))
  31   ;; The kind of location noted.
  32   (kind nil :type location-kind)
  33   ;; The label pointing to the interesting code location.
  34   (label nil :type (or label index null))
  35   ;; The VOP that emitted this location (for node, save-set, ir2-block, etc.)
  36   (vop nil :type vop))
  37
  38 ;;; This is called during code generation in places where there is an
  39 ;;; "interesting" location: someplace where we are likely to end up
  40 ;;; in the debugger, and thus want debug info.
  41 (defun note-debug-location (vop label kind)
  42   (declare (type vop vop) (type (or label null) label)
  43            (type location-kind kind))
  44   (let ((location (make-location-info kind label vop)))
  45     (setf (ir2-block-locations (vop-block vop))
  46           (nconc (ir2-block-locations (vop-block vop))
  47                  (list location)))
  48     location))
  49
  50 #!-sb-fluid (declaim (inline ir2-block-physenv))
  51 (defun ir2-block-physenv (2block)
  52   (declare (type ir2-block 2block))
  53   (block-physenv (ir2-block-block 2block)))
  54
  55 ;;; Given a local conflicts vector and an IR2 block to represent the
  56 ;;; set of live TNs, and the VAR-LOCS hash-table representing the
  57 ;;; variables dumped, compute a bit-vector representing the set of
  58 ;;; live variables. If the TN is environment-live, we only mark it as
  59 ;;; live when it is in scope at NODE.
  60 (defun compute-live-vars (live node block var-locs vop)
  61   (declare (type ir2-block block) (type local-tn-bit-vector live)
  62            (type hash-table var-locs) (type node node)
  63            (type (or vop null) vop))
  64   (let ((res (make-array (logandc2 (+ (hash-table-count var-locs) 7) 7)
  65                          :element-type 'bit
  66                          :initial-element 0))
  67         (spilled (gethash vop
  68                           (ir2-component-spilled-vops
  69                            (component-info *component-being-compiled*)))))
  70     (do-live-tns (tn live block)
  71       (let ((leaf (tn-leaf tn)))
  72         (when (and (lambda-var-p leaf)
  73                    (or (not (member (tn-kind tn)
  74                                     '(:environment :debug-environment)))
  75                        (rassoc leaf (lexenv-vars (node-lexenv node))))
  76                    (or (null spilled)
  77                        (not (member tn spilled))))
  78           (let ((num (gethash leaf var-locs)))
  79             (when num
  80               (setf (sbit res num) 1))))))
  81     res))
  82
  83 ;;; The PC for the location most recently dumped.
  84 (defvar *previous-location*)
  85 (declaim (type index *previous-location*))
  86
  87 ;;; Dump a compiled debug-location into *BYTE-BUFFER* that describes
  88 ;;; the code/source map and live info. If true, VOP is the VOP
  89 ;;; associated with this location, for use in determining whether TNs
  90 ;;; are spilled.
  91 (defun dump-1-location (node block kind tlf-num label live var-locs vop)
  92   (declare (type node node) (type ir2-block block)
  93            (type (or null local-tn-bit-vector) live)
  94            (type (or label index) label)
  95            (type location-kind kind) (type (or index null) tlf-num)
  96            (type hash-table var-locs) (type (or vop null) vop))
  97
  98   (vector-push-extend
  99    (dpb (position-or-lose kind *compiled-code-location-kinds*)
 100         compiled-code-location-kind-byte
 101         0)
 102    *byte-buffer*)
 103
 104   (let ((loc (if (fixnump label) label (label-position label))))
 105     (write-var-integer (- loc *previous-location*) *byte-buffer*)
 106     (setq *previous-location* loc))
 107
 108   (let ((path (node-source-path node)))
 109     (unless tlf-num
 110       (write-var-integer (source-path-tlf-number path) *byte-buffer*))
 111     (write-var-integer (source-path-form-number path) *byte-buffer*))
 112
 113   (if live
 114       (write-packed-bit-vector (compute-live-vars live node block var-locs vop)
 115                                *byte-buffer*)
 116       (write-packed-bit-vector
 117        (make-array (logandc2 (+ (hash-table-count var-locs) 7) 7)
 118                    :initial-element 0
 119                    :element-type 'bit)
 120        *byte-buffer*))
 121
 122   (write-var-string (or (and (typep node 'combination)
 123                              (combination-step-info node))
 124                         "")
 125                     *byte-buffer*)
 126   (values))
 127
 128 ;;; Extract context info from a Location-Info structure and use it to
 129 ;;; dump a compiled code-location.
 130 (defun dump-location-from-info (loc tlf-num var-locs)
 131   (declare (type location-info loc) (type (or index null) tlf-num)
 132            (type hash-table var-locs))
 133   (let ((vop (location-info-vop loc)))
 134     (dump-1-location (vop-node vop)
 135                      (vop-block vop)
 136                      (location-info-kind loc)
 137                      tlf-num
 138                      (location-info-label loc)
 139                      (vop-save-set vop)
 140                      var-locs
 141                      vop))
 142   (values))
 143
 144 ;;; Scan all the blocks, determining if all locations are in the same
 145 ;;; TLF, and returning it or NIL.
 146 (defun find-tlf-number (fun)
 147   (declare (type clambda fun))
 148   (let ((res (source-path-tlf-number (node-source-path (lambda-bind fun)))))
 149     (declare (type (or index null) res))
 150     (do-physenv-ir2-blocks (2block (lambda-physenv fun))
 151       (let ((block (ir2-block-block 2block)))
 152         (when (eq (block-info block) 2block)
 153           (unless (eql (source-path-tlf-number
 154                         (node-source-path
 155                          (block-start-node block)))
 156                        res)
 157             (setq res nil)))
 158
 159         (dolist (loc (ir2-block-locations 2block))
 160           (unless (eql (source-path-tlf-number
 161                         (node-source-path
 162                          (vop-node (location-info-vop loc))))
 163                        res)
 164             (setq res nil)))))
 165     res))
 166
 167 ;;; Dump out the number of locations and the locations for Block.
 168 (defun dump-block-locations (block locations tlf-num var-locs)
 169   (declare (type cblock block) (list locations))
 170   (if (and locations
 171            (eq (location-info-kind (first locations))
 172                :non-local-entry))
 173       (write-var-integer (length locations) *byte-buffer*)
 174       (let ((2block (block-info block)))
 175         (write-var-integer (+ (length locations) 1) *byte-buffer*)
 176         (dump-1-location (block-start-node block)
 177                          2block :block-start tlf-num
 178                          (ir2-block-%label 2block)
 179                          (ir2-block-live-out 2block)
 180                          var-locs
 181                          nil)))
 182   (dolist (loc locations)
 183     (dump-location-from-info loc tlf-num var-locs))
 184   (values))
 185
 186 ;;; Dump the successors of Block, being careful not to fly into space
 187 ;;; on weird successors.
 188 (defun dump-block-successors (block physenv)
 189   (declare (type cblock block) (type physenv physenv))
 190   (let* ((tail (component-tail (block-component block)))
 191          (succ (block-succ block))
 192          (valid-succ
 193           (if (and succ
 194                    (or (eq (car succ) tail)
 195                        (not (eq (block-physenv (car succ)) physenv))))
 196               ()
 197               succ)))
 198     (vector-push-extend
 199      (dpb (length valid-succ) compiled-debug-block-nsucc-byte 0)
 200      *byte-buffer*)
 201     (let ((base (block-number
 202                  (node-block
 203                   (lambda-bind (physenv-lambda physenv))))))
 204       (dolist (b valid-succ)
 205         (write-var-integer
 206          (the index (- (block-number b) base))
 207          *byte-buffer*))))
 208   (values))
 209
 210 ;;; Return a vector and an integer (or null) suitable for use as the
 211 ;;; BLOCKS and TLF-NUMBER in FUN's DEBUG-FUN. This requires two
 212 ;;; passes to compute:
 213 ;;; -- Scan all blocks, dumping the header and successors followed
 214 ;;;    by all the non-elsewhere locations.
 215 ;;; -- Dump the elsewhere block header and all the elsewhere
 216 ;;;    locations (if any.)
 217 (defun compute-debug-blocks (fun var-locs)
 218   (declare (type clambda fun) (type hash-table var-locs))
 219   (setf (fill-pointer *byte-buffer*) 0)
 220   (let ((*previous-location* 0)
 221         (tlf-num (find-tlf-number fun))
 222         (physenv (lambda-physenv fun))
 223         (prev-locs nil)
 224         (prev-block nil))
 225     (collect ((elsewhere))
 226       (do-physenv-ir2-blocks (2block physenv)
 227         (let ((block (ir2-block-block 2block)))
 228           (when (eq (block-info block) 2block)
 229             (when prev-block
 230               (dump-block-locations prev-block prev-locs tlf-num var-locs))
 231             (setq prev-block block  prev-locs ())
 232             (dump-block-successors block physenv)))
 233
 234         (collect ((here prev-locs))
 235           (dolist (loc (ir2-block-locations 2block))
 236             (if (label-elsewhere-p (location-info-label loc))
 237                 (elsewhere loc)
 238                 (here loc)))
 239           (setq prev-locs (here))))
 240
 241       (dump-block-locations prev-block prev-locs tlf-num var-locs)
 242
 243       (when (elsewhere)
 244         (vector-push-extend compiled-debug-block-elsewhere-p *byte-buffer*)
 245         (write-var-integer (length (elsewhere)) *byte-buffer*)
 246         (dolist (loc (elsewhere))
 247           (dump-location-from-info loc tlf-num var-locs))))
 248
 249     (values (copy-seq *byte-buffer*) tlf-num)))
 250 \f
 251 ;;; Return DEBUG-SOURCE structure containing information derived from
 252 ;;; INFO.
 253 (defun debug-source-for-info (info &key function)
 254   (declare (type source-info info))
 255   (let ((file-info (get-toplevelish-file-info info)))
 256     (make-debug-source
 257      :compiled (source-info-start-time info)
 258
 259      :namestring (make-file-info-namestring
 260                   (if (pathnamep (file-info-name file-info))
 261                       (file-info-name file-info))
 262                   file-info)
 263      :created (file-info-write-date file-info)
 264      :source-root (file-info-source-root file-info)
 265      :start-positions (coerce-to-smallest-eltype
 266                        (file-info-positions file-info))
 267
 268      :form (let ((direct-file-info (source-info-file-info info)))
 269              (if (eq :lisp (file-info-name direct-file-info))
 270                  (elt (file-info-forms direct-file-info) 0)))
 271      :function function)))
 272
 273 ;;; Given an arbitrary sequence, coerce it to an unsigned vector if
 274 ;;; possible. Ordinarily we coerce it to the smallest specialized
 275 ;;; vector we can. However, we also have a special hack for
 276 ;;; cross-compiling at bootstrap time, when arbitrarily-specialized
 277 ;;; vectors aren't fully supported: in that case, we coerce it only to
 278 ;;; a vector whose element size is an integer multiple of output byte
 279 ;;; size.
 280 (defun coerce-to-smallest-eltype (seq)
 281   (let ((maxoid 0))
 282     (flet ((frob (x)
 283              (if (typep x 'unsigned-byte)
 284                  (when (>= x maxoid)
 285                    (setf maxoid x))
 286                  (return-from coerce-to-smallest-eltype
 287                    (coerce seq 'simple-vector)))))
 288       (if (listp seq)
 289           (dolist (i seq)
 290             (frob i))
 291           (dovector (i seq)
 292             (frob i)))
 293       (let ((specializer `(unsigned-byte
 294                            ,(etypecase maxoid
 295                               ((unsigned-byte 8) 8)
 296                               ((unsigned-byte 16) 16)
 297                               ((unsigned-byte 32) 32)))))
 298         ;; cross-compilers beware! It would be possible for the
 299         ;; upgraded-array-element-type of (UNSIGNED-BYTE 16) to be
 300         ;; (SIGNED-BYTE 17) or (UNSIGNED-BYTE 23), and this is
 301         ;; completely valid by ANSI.  However, the cross-compiler
 302         ;; doesn't know how to dump (in practice) anything but the
 303         ;; above three specialized array types, so make it break here
 304         ;; if this is violated.
 305         #+sb-xc-host
 306         (aver
 307          ;; not SB!XC:UPGRADED-ARRAY-ELEMENT-TYPE, because we are
 308          ;; worried about whether the host's implementation of arrays.
 309          (let ((uaet (upgraded-array-element-type specializer)))
 310            (dolist (et '((unsigned-byte 8)
 311                          (unsigned-byte 16)
 312                          (unsigned-byte 32))
 313                     nil)
 314              (when (and (subtypep et uaet) (subtypep uaet et))
 315                (return t)))))
 316         (coerce seq `(simple-array ,specializer (*)))))))
 317 \f
 318 ;;;; variables
 319
 320 ;;; Return a SC-OFFSET describing TN's location.
 321 (defun tn-sc-offset (tn)
 322   (declare (type tn tn))
 323   (make-sc-offset (sc-number (tn-sc tn))
 324                   (tn-offset tn)))
 325
 326 (defun lambda-ancestor-p (maybe-ancestor maybe-descendant)
 327   (declare (type clambda maybe-ancestor)
 328            (type (or clambda null) maybe-descendant))
 329   (loop
 330      (when (eq maybe-ancestor maybe-descendant)
 331        (return t))
 332      (setf maybe-descendant (lambda-parent maybe-descendant))
 333      (when (null maybe-descendant)
 334        (return nil))))
 335
 336 ;;; Dump info to represent VAR's location being TN. ID is an integer
 337 ;;; that makes VAR's name unique in the function. BUFFER is the vector
 338 ;;; we stick the result in. If MINIMAL, we suppress name dumping, and
 339 ;;; set the minimal flag.
 340 ;;;
 341 ;;; The DEBUG-VAR is only marked as always-live if the TN is
 342 ;;; environment live and is an argument. If a :DEBUG-ENVIRONMENT TN,
 343 ;;; then we also exclude set variables, since the variable is not
 344 ;;; guaranteed to be live everywhere in that case.
 345 (defun dump-1-var (fun var tn id minimal buffer)
 346   (declare (type lambda-var var) (type (or tn null) tn) (type index id)
 347            (type clambda fun))
 348   (let* ((name (leaf-debug-name var))
 349          (save-tn (and tn (tn-save-tn tn)))
 350          (kind (and tn (tn-kind tn)))
 351          (flags 0))
 352     (declare (type index flags))
 353     (when minimal
 354       (setq flags (logior flags compiled-debug-var-minimal-p))
 355       (unless (and tn (tn-offset tn))
 356         (setq flags (logior flags compiled-debug-var-deleted-p))))
 357     (when (and (or (eq kind :environment)
 358                    (and (eq kind :debug-environment)
 359                         (null (basic-var-sets var))))
 360                (not (gethash tn (ir2-component-spilled-tns
 361                                  (component-info *component-being-compiled*))))
 362                (lambda-ancestor-p (lambda-var-home var) fun))
 363       (setq flags (logior flags compiled-debug-var-environment-live)))
 364     (when save-tn
 365       (setq flags (logior flags compiled-debug-var-save-loc-p)))
 366     (unless (or (zerop id) minimal)
 367       (setq flags (logior flags compiled-debug-var-id-p)))
 368     (vector-push-extend flags buffer)
 369     (unless minimal
 370       (vector-push-extend name buffer)
 371       (unless (zerop id)
 372         (vector-push-extend id buffer)))
 373     (if (and tn (tn-offset tn))
 374         (vector-push-extend (tn-sc-offset tn) buffer)
 375         (aver minimal))
 376     (when save-tn
 377       (vector-push-extend (tn-sc-offset save-tn) buffer)))
 378   (values))
 379
 380 ;;; Return a vector suitable for use as the DEBUG-FUN-VARS
 381 ;;; of FUN. LEVEL is the current DEBUG-INFO quality. VAR-LOCS is a
 382 ;;; hash table in which we enter the translation from LAMBDA-VARS to
 383 ;;; the relative position of that variable's location in the resulting
 384 ;;; vector.
 385 (defun compute-vars (fun level var-locs)
 386   (declare (type clambda fun) (type hash-table var-locs))
 387   (collect ((vars))
 388     (labels ((frob-leaf (leaf tn gensym-p)
 389                (let ((name (leaf-debug-name leaf)))
 390                  (when (and name (leaf-refs leaf) (tn-offset tn)
 391                             (or gensym-p (symbol-package name)))
 392                    (vars (cons leaf tn)))))
 393              (frob-lambda (x gensym-p)
 394                (dolist (leaf (lambda-vars x))
 395                  (frob-leaf leaf (leaf-info leaf) gensym-p))))
 396       (frob-lambda fun t)
 397       (when (>= level 2)
 398         (dolist (x (ir2-physenv-closure (physenv-info (lambda-physenv fun))))
 399           (let ((thing (car x)))
 400             (when (lambda-var-p thing)
 401               (frob-leaf thing (cdr x) (= level 3)))))
 402
 403         (dolist (let (lambda-lets fun))
 404           (frob-lambda let (= level 3)))))
 405
 406     (let ((sorted (sort (vars) #'string<
 407                         :key (lambda (x)
 408                                (symbol-name (leaf-debug-name (car x))))))
 409           (prev-name nil)
 410           (id 0)
 411           (i 0)
 412           (buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 413       (declare (type (or simple-string null) prev-name)
 414                (type index id i))
 415       (dolist (x sorted)
 416         (let* ((var (car x))
 417                (name (symbol-name (leaf-debug-name var))))
 418           (cond ((and prev-name (string= prev-name name))
 419                  (incf id))
 420                 (t
 421                  (setq id 0  prev-name name)))
 422           (dump-1-var fun var (cdr x) id nil buffer)
 423           (setf (gethash var var-locs) i)
 424           (incf i)))
 425       (coerce buffer 'simple-vector))))
 426
 427 ;;; Return a vector suitable for use as the DEBUG-FUN-VARS of
 428 ;;; FUN, representing the arguments to FUN in minimal variable format.
 429 (defun compute-minimal-vars (fun)
 430   (declare (type clambda fun))
 431   (let ((buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 432     (dolist (var (lambda-vars fun))
 433       (dump-1-var fun var (leaf-info var) 0 t buffer))
 434     (coerce buffer 'simple-vector)))
 435
 436 ;;; Return VAR's relative position in the function's variables (determined
 437 ;;; from the VAR-LOCS hashtable).  If VAR is deleted, then return DELETED.
 438 (defun debug-location-for (var var-locs)
 439   (declare (type lambda-var var) (type hash-table var-locs))
 440   (let ((res (gethash var var-locs)))
 441     (cond (res)
 442           (t
 443            (aver (or (null (leaf-refs var))
 444                      (not (tn-offset (leaf-info var)))))
 445            'deleted))))
 446 \f
 447 ;;;; arguments/returns
 448
 449 ;;; Return a vector to be used as the COMPILED-DEBUG-FUN-ARGS for FUN.
 450 ;;; If FUN is the MAIN-ENTRY for an optional dispatch, then look at
 451 ;;; the ARGLIST to determine the syntax, otherwise pretend all
 452 ;;; arguments are fixed.
 453 ;;;
 454 ;;; ### This assumption breaks down in EPs other than the main-entry,
 455 ;;; since they may or may not have supplied-p vars, etc.
 456 (defun compute-args (fun var-locs)
 457   (declare (type clambda fun) (type hash-table var-locs))
 458   (collect ((res))
 459     (let ((od (lambda-optional-dispatch fun)))
 460       (if (and od (eq (optional-dispatch-main-entry od) fun))
 461           (let ((actual-vars (lambda-vars fun))
 462                 (saw-optional nil))
 463             (dolist (arg (optional-dispatch-arglist od))
 464               (let ((info (lambda-var-arg-info arg))
 465                     (actual (pop actual-vars)))
 466                 (cond (info
 467                        (case (arg-info-kind info)
 468                          (:keyword
 469                           (res (arg-info-key info)))
 470                          (:rest
 471                           (res 'rest-arg))
 472                          (:more-context
 473                           (res 'more-arg))
 474                          (:optional
 475                           (unless saw-optional
 476                             (res 'optional-args)
 477                             (setq saw-optional t))))
 478                        (res (debug-location-for actual var-locs))
 479                        (when (arg-info-supplied-p info)
 480                          (res 'supplied-p)
 481                          (res (debug-location-for (pop actual-vars) var-locs))))
 482                       (t
 483                        (res (debug-location-for actual var-locs)))))))
 484           (dolist (var (lambda-vars fun))
 485             (res (debug-location-for var var-locs)))))
 486
 487     (coerce-to-smallest-eltype (res))))
 488
 489 ;;; Return a vector of SC offsets describing FUN's return locations.
 490 ;;; (Must be known values return...)
 491 (defun compute-debug-returns (fun)
 492   (coerce-to-smallest-eltype
 493    (mapcar (lambda (loc)
 494              (tn-sc-offset loc))
 495            (return-info-locations (tail-set-info (lambda-tail-set fun))))))
 496 \f
 497 ;;;; debug functions
 498
 499 ;;; Return a C-D-F structure with all the mandatory slots filled in.
 500 (defun dfun-from-fun (fun)
 501   (declare (type clambda fun))
 502   (let* ((2env (physenv-info (lambda-physenv fun)))
 503          (dispatch (lambda-optional-dispatch fun))
 504          (main-p (and dispatch
 505                       (eq fun (optional-dispatch-main-entry dispatch)))))
 506     (make-compiled-debug-fun
 507      :name (leaf-debug-name fun)
 508      :kind (if main-p nil (functional-kind fun))
 509      :return-pc (tn-sc-offset (ir2-physenv-return-pc 2env))
 510      :old-fp (tn-sc-offset (ir2-physenv-old-fp 2env))
 511      :start-pc (label-position (ir2-physenv-environment-start 2env))
 512      :elsewhere-pc (label-position (ir2-physenv-elsewhere-start 2env)))))
 513
 514 ;;; Return a complete C-D-F structure for FUN. This involves
 515 ;;; determining the DEBUG-INFO level and filling in optional slots as
 516 ;;; appropriate.
 517 (defun compute-1-debug-fun (fun var-locs)
 518   (declare (type clambda fun) (type hash-table var-locs))
 519   (let* ((dfun (dfun-from-fun fun))
 520          (actual-level (policy (lambda-bind fun) compute-debug-fun))
 521          (level (if #!+sb-dyncount *collect-dynamic-statistics*
 522                     #!-sb-dyncount nil
 523                     (max actual-level 2)
 524                     actual-level)))
 525     (cond ((zerop level))
 526           ((and (<= level 1)
 527                 (let ((od (lambda-optional-dispatch fun)))
 528                   (or (not od)
 529                       (not (eq (optional-dispatch-main-entry od) fun)))))
 530            (setf (compiled-debug-fun-vars dfun)
 531                  (compute-minimal-vars fun))
 532            (setf (compiled-debug-fun-arguments dfun) :minimal))
 533           (t
 534            (setf (compiled-debug-fun-vars dfun)
 535                  (compute-vars fun level var-locs))
 536            (setf (compiled-debug-fun-arguments dfun)
 537                  (compute-args fun var-locs))))
 538
 539     (if (>= level 2)
 540         (multiple-value-bind (blocks tlf-num)
 541             (compute-debug-blocks fun var-locs)
 542           (setf (compiled-debug-fun-tlf-number dfun) tlf-num)
 543           (setf (compiled-debug-fun-blocks dfun) blocks))
 544         (setf (compiled-debug-fun-tlf-number dfun) (find-tlf-number fun)))
 545
 546     (if (xep-p fun)
 547         (setf (compiled-debug-fun-returns dfun) :standard)
 548         (let ((info (tail-set-info (lambda-tail-set fun))))
 549           (when info
 550             (cond ((eq (return-info-kind info) :unknown)
 551                    (setf (compiled-debug-fun-returns dfun)
 552                          :standard))
 553                   ((/= level 0)
 554                    (setf (compiled-debug-fun-returns dfun)
 555                          (compute-debug-returns fun)))))))
 556     dfun))
 557 \f
 558 ;;;; full component dumping
 559
 560 ;;; Compute the full form (simple-vector) function map.
 561 (defun compute-debug-fun-map (sorted)
 562   (declare (list sorted))
 563   (let* ((len (1- (* (length sorted) 2)))
 564          (funs-vec (make-array len)))
 565     (do ((i -1 (+ i 2))
 566          (sorted sorted (cdr sorted)))
 567         ((= i len))
 568       (declare (fixnum i))
 569       (let ((dfun (car sorted)))
 570         (unless (minusp i)
 571           (setf (svref funs-vec i) (car dfun)))
 572         (setf (svref funs-vec (1+ i)) (cdr dfun))))
 573     funs-vec))
 574
 575 ;;; Return a DEBUG-INFO structure describing COMPONENT. This has to be
 576 ;;; called after assembly so that source map information is available.
 577 (defun debug-info-for-component (component)
 578   (declare (type component component))
 579   (let ((dfuns nil)
 580         (var-locs (make-hash-table :test 'eq))
 581         (*byte-buffer* (make-array 10
 582                                    :element-type '(unsigned-byte 8)
 583                                    :fill-pointer 0
 584                                    :adjustable t)))
 585     (dolist (lambda (component-lambdas component))
 586       (clrhash var-locs)
 587       (push (cons (label-position (block-label (lambda-block lambda)))
 588                   (compute-1-debug-fun lambda var-locs))
 589             dfuns))
 590     (let* ((sorted (sort dfuns #'< :key #'car))
 591            (fun-map (compute-debug-fun-map sorted)))
 592       (make-compiled-debug-info :name (component-name component)
 593                                 :fun-map fun-map))))
 594 \f
 595 ;;; Write BITS out to BYTE-BUFFER in backend byte order. The length of
 596 ;;; BITS must be evenly divisible by eight.
 597 (defun write-packed-bit-vector (bits byte-buffer)
 598   (declare (type simple-bit-vector bits) (type byte-buffer byte-buffer))
 599
 600   ;; Enforce constraint from CMU-CL-era comment.
 601   (aver (zerop (mod (length bits) 8)))
 602
 603   (multiple-value-bind (initial step done)
 604       (ecase *backend-byte-order*
 605         (:little-endian (values 0  1  8))
 606         (:big-endian    (values 7 -1 -1)))
 607     (let ((shift initial)
 608           (byte 0))
 609       (dotimes (i (length bits))
 610         (let ((int (aref bits i)))
 611           (setf byte (logior byte (ash int shift)))
 612           (incf shift step))
 613         (when (= shift done)
 614           (vector-push-extend byte byte-buffer)
 615           (setf shift initial
 616                 byte 0)))
 617       (unless (= shift initial)
 618         (vector-push-extend byte byte-buffer))))
 619   (values))