src/compiler/debug-dump.lisp

   1 ;;;; stuff that creates debugger information from the compiler's
   2 ;;;; internal data structures
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (deftype byte-buffer () '(vector (unsigned-byte 8)))
  16 (defvar *byte-buffer*)
  17 (declaim (type byte-buffer *byte-buffer*))
  18 \f
  19 ;;;; debug blocks
  20
  21 (deftype location-kind ()
  22   '(member :unknown-return :known-return :internal-error :non-local-exit
  23            :block-start :call-site :single-value-return :non-local-entry))
  24
  25 ;;; The LOCATION-INFO structure holds the information what we need
  26 ;;; about locations which code generation decided were "interesting".
  27 (defstruct (location-info
  28             (:constructor make-location-info (kind label vop))
  29             (:copier nil))
  30   ;; The kind of location noted.
  31   (kind nil :type location-kind)
  32   ;; The label pointing to the interesting code location.
  33   (label nil :type (or label index null))
  34   ;; The VOP that emitted this location (for node, save-set, ir2-block, etc.)
  35   (vop nil :type vop))
  36
  37 ;;; This is called during code generation in places where there is an
  38 ;;; "interesting" location: someplace where we are likely to end up
  39 ;;; in the debugger, and thus want debug info.
  40 (defun note-debug-location (vop label kind)
  41   (declare (type vop vop) (type (or label null) label)
  42            (type location-kind kind))
  43   (let ((location (make-location-info kind label vop)))
  44     (setf (ir2-block-locations (vop-block vop))
  45           (nconc (ir2-block-locations (vop-block vop))
  46                  (list location)))
  47     location))
  48
  49 #!-sb-fluid (declaim (inline ir2-block-environment))
  50 (defun ir2-block-environment (2block)
  51   (declare (type ir2-block 2block))
  52   (block-environment (ir2-block-block 2block)))
  53
  54 ;;; Given a local conflicts vector and an IR2 block to represent the
  55 ;;; set of live TNs, and the VAR-LOCS hash-table representing the
  56 ;;; variables dumped, compute a bit-vector representing the set of
  57 ;;; live variables. If the TN is environment-live, we only mark it as
  58 ;;; live when it is in scope at NODE.
  59 (defun compute-live-vars (live node block var-locs vop)
  60   (declare (type ir2-block block) (type local-tn-bit-vector live)
  61            (type hash-table var-locs) (type node node)
  62            (type (or vop null) vop))
  63   (let ((res (make-array (logandc2 (+ (hash-table-count var-locs) 7) 7)
  64                          :element-type 'bit
  65                          :initial-element 0))
  66         (spilled (gethash vop
  67                           (ir2-component-spilled-vops
  68                            (component-info *component-being-compiled*)))))
  69     (do-live-tns (tn live block)
  70       (let ((leaf (tn-leaf tn)))
  71         (when (and (lambda-var-p leaf)
  72                    (or (not (member (tn-kind tn)
  73                                     '(:environment :debug-environment)))
  74                        (rassoc leaf (lexenv-variables (node-lexenv node))))
  75                    (or (null spilled)
  76                        (not (member tn spilled))))
  77           (let ((num (gethash leaf var-locs)))
  78             (when num
  79               (setf (sbit res num) 1))))))
  80     res))
  81
  82 ;;; The PC for the location most recently dumped.
  83 (defvar *previous-location*)
  84 (declaim (type index *previous-location*))
  85
  86 ;;; Dump a compiled debug-location into *BYTE-BUFFER* that describes
  87 ;;; the code/source map and live info. If true, VOP is the VOP
  88 ;;; associated with this location, for use in determining whether TNs
  89 ;;; are spilled.
  90 (defun dump-1-location (node block kind tlf-num label live var-locs vop)
  91   (declare (type node node) (type ir2-block block)
  92            (type local-tn-bit-vector live)
  93            (type (or label index) label)
  94            (type location-kind kind) (type (or index null) tlf-num)
  95            (type hash-table var-locs) (type (or vop null) vop))
  96
  97   (vector-push-extend
  98    (dpb (position-or-lose kind *compiled-code-location-kinds*)
  99         compiled-code-location-kind-byte
 100         0)
 101    *byte-buffer*)
 102
 103   (let ((loc (if (target-fixnump label) label (label-position label))))
 104     (write-var-integer (- loc *previous-location*) *byte-buffer*)
 105     (setq *previous-location* loc))
 106
 107   (let ((path (node-source-path node)))
 108     (unless tlf-num
 109       (write-var-integer (source-path-tlf-number path) *byte-buffer*))
 110     (write-var-integer (source-path-form-number path) *byte-buffer*))
 111
 112   (write-packed-bit-vector (compute-live-vars live node block var-locs vop)
 113                            *byte-buffer*)
 114
 115   (values))
 116
 117 ;;; Extract context info from a Location-Info structure and use it to
 118 ;;; dump a compiled code-location.
 119 (defun dump-location-from-info (loc tlf-num var-locs)
 120   (declare (type location-info loc) (type (or index null) tlf-num)
 121            (type hash-table var-locs))
 122   (let ((vop (location-info-vop loc)))
 123     (dump-1-location (vop-node vop)
 124                      (vop-block vop)
 125                      (location-info-kind loc)
 126                      tlf-num
 127                      (location-info-label loc)
 128                      (vop-save-set vop)
 129                      var-locs
 130                      vop))
 131   (values))
 132
 133 ;;; Scan all the blocks, determining if all locations are in the same
 134 ;;; TLF, and returning it or NIL.
 135 (defun find-tlf-number (fun)
 136   (declare (type clambda fun))
 137   (let ((res (source-path-tlf-number (node-source-path (lambda-bind fun)))))
 138     (declare (type (or index null) res))
 139     (do-environment-ir2-blocks (2block (lambda-environment fun))
 140       (let ((block (ir2-block-block 2block)))
 141         (when (eq (block-info block) 2block)
 142           (unless (eql (source-path-tlf-number
 143                         (node-source-path
 144                          (continuation-next
 145                           (block-start block))))
 146                        res)
 147             (setq res nil)))
 148
 149         (dolist (loc (ir2-block-locations 2block))
 150           (unless (eql (source-path-tlf-number
 151                         (node-source-path
 152                          (vop-node (location-info-vop loc))))
 153                        res)
 154             (setq res nil)))))
 155     res))
 156
 157 ;;; Dump out the number of locations and the locations for Block.
 158 (defun dump-block-locations (block locations tlf-num var-locs)
 159   (declare (type cblock block) (list locations))
 160   (if (and locations
 161            (eq (location-info-kind (first locations))
 162                :non-local-entry))
 163       (write-var-integer (length locations) *byte-buffer*)
 164       (let ((2block (block-info block)))
 165         (write-var-integer (+ (length locations) 1) *byte-buffer*)
 166         (dump-1-location (continuation-next (block-start block))
 167                          2block :block-start tlf-num
 168                          (ir2-block-%label 2block)
 169                          (ir2-block-live-out 2block)
 170                          var-locs
 171                          nil)))
 172   (dolist (loc locations)
 173     (dump-location-from-info loc tlf-num var-locs))
 174   (values))
 175
 176 ;;; Dump the successors of Block, being careful not to fly into space on
 177 ;;; weird successors.
 178 (defun dump-block-successors (block env)
 179   (declare (type cblock block) (type environment env))
 180   (let* ((tail (component-tail (block-component block)))
 181          (succ (block-succ block))
 182          (valid-succ
 183           (if (and succ
 184                    (or (eq (car succ) tail)
 185                        (not (eq (block-environment (car succ)) env))))
 186               ()
 187               succ)))
 188     (vector-push-extend
 189      (dpb (length valid-succ) compiled-debug-block-nsucc-byte 0)
 190      *byte-buffer*)
 191     (let ((base (block-number
 192                  (node-block
 193                   (lambda-bind (environment-function env))))))
 194       (dolist (b valid-succ)
 195         (write-var-integer
 196          (the index (- (block-number b) base))
 197          *byte-buffer*))))
 198   (values))
 199
 200 ;;; Return a vector and an integer (or null) suitable for use as the
 201 ;;; BLOCKS and TLF-NUMBER in Fun's debug-function. This requires two
 202 ;;; passes to compute:
 203 ;;; -- Scan all blocks, dumping the header and successors followed
 204 ;;;    by all the non-elsewhere locations.
 205 ;;; -- Dump the elsewhere block header and all the elsewhere
 206 ;;;    locations (if any.)
 207 (defun compute-debug-blocks (fun var-locs)
 208   (declare (type clambda fun) (type hash-table var-locs))
 209   (setf (fill-pointer *byte-buffer*) 0)
 210   (let ((*previous-location* 0)
 211         (tlf-num (find-tlf-number fun))
 212         (env (lambda-environment fun))
 213         (prev-locs nil)
 214         (prev-block nil))
 215     (collect ((elsewhere))
 216       (do-environment-ir2-blocks (2block env)
 217         (let ((block (ir2-block-block 2block)))
 218           (when (eq (block-info block) 2block)
 219             (when prev-block
 220               (dump-block-locations prev-block prev-locs tlf-num var-locs))
 221             (setq prev-block block  prev-locs ())
 222             (dump-block-successors block env)))
 223
 224         (collect ((here prev-locs))
 225           (dolist (loc (ir2-block-locations 2block))
 226             (if (label-elsewhere-p (location-info-label loc))
 227                 (elsewhere loc)
 228                 (here loc)))
 229           (setq prev-locs (here))))
 230
 231       (dump-block-locations prev-block prev-locs tlf-num var-locs)
 232
 233       (when (elsewhere)
 234         (vector-push-extend compiled-debug-block-elsewhere-p *byte-buffer*)
 235         (write-var-integer (length (elsewhere)) *byte-buffer*)
 236         (dolist (loc (elsewhere))
 237           (dump-location-from-info loc tlf-num var-locs))))
 238
 239     (values (copy-seq *byte-buffer*) tlf-num)))
 240 \f
 241 ;;; Return a list of DEBUG-SOURCE structures containing information
 242 ;;; derived from INFO. Unless :BYTE-COMPILE T was specified, we always
 243 ;;; dump the Start-Positions, since it is too hard figure out whether
 244 ;;; we need them or not.
 245 (defun debug-source-for-info (info)
 246   (declare (type source-info info))
 247   (assert (not (source-info-current-file info)))
 248   (mapcar #'(lambda (x)
 249               (let ((res (make-debug-source
 250                           :from :file
 251                           :created (file-info-write-date x)
 252                           :compiled (source-info-start-time info)
 253                           :source-root (file-info-source-root x)
 254                           :start-positions
 255                           (unless (eq *byte-compile* 't)
 256                             (coerce-to-smallest-eltype
 257                              (file-info-positions x)))))
 258                     (name (file-info-name x)))
 259                 (etypecase name
 260                   ((member :lisp)
 261                    (setf (debug-source-from res) name)
 262                    (setf (debug-source-name res)
 263                          (coerce (file-info-forms x) 'simple-vector)))
 264                   (pathname
 265                    (let* ((untruename (file-info-untruename x))
 266                           (dir (pathname-directory untruename)))
 267                      (setf (debug-source-name res)
 268                            (namestring
 269                             (if (and dir (eq (first dir) :absolute))
 270                                 untruename
 271                                 name))))))
 272                 res))
 273           (source-info-files info)))
 274
 275 ;;; Given an arbitrary sequence, coerce it to an unsigned vector if
 276 ;;; possible. Ordinarily we coerce it to the smallest specialized
 277 ;;; vector we can. However, we also have a special hack for
 278 ;;; cross-compiling at bootstrap time, when arbitrarily-specialized
 279 ;;; aren't fully supported: in that case, we coerce it only to a
 280 ;;; vector whose element size is an integer multiple of output byte
 281 ;;; size.
 282 (defun coerce-to-smallest-eltype (seq)
 283   (let ((maxoid #-sb-xc-host 0
 284                 ;; An initial value value of 255 prevents us from
 285                 ;; specializing the array to anything smaller than
 286                 ;; (UNSIGNED-BYTE 8), which keeps the cross-compiler's
 287                 ;; portable specialized array output functions happy.
 288                 #+sb-xc-host 255))
 289     (flet ((frob (x)
 290              (if (typep x 'unsigned-byte)
 291                (when (>= x maxoid)
 292                  (setf maxoid x))
 293                (return-from coerce-to-smallest-eltype
 294                  (coerce seq 'simple-vector)))))
 295       (if (listp seq)
 296         (dolist (i seq)
 297           (frob i))
 298         (dovector (i seq)
 299           (frob i)))
 300       (coerce seq `(simple-array (integer 0 ,maxoid) (*))))))
 301 \f
 302 ;;;; variables
 303
 304 ;;; Return a SC-OFFSET describing TN's location.
 305 (defun tn-sc-offset (tn)
 306   (declare (type tn tn))
 307   (make-sc-offset (sc-number (tn-sc tn))
 308                   (tn-offset tn)))
 309
 310 ;;; Dump info to represent Var's location being TN. ID is an integer
 311 ;;; that makes Var's name unique in the function. Buffer is the vector
 312 ;;; we stick the result in. If Minimal is true, we suppress name
 313 ;;; dumping, and set the minimal flag.
 314 ;;;
 315 ;;; The debug-var is only marked as always-live if the TN is
 316 ;;; environment live and is an argument. If a :debug-environment TN,
 317 ;;; then we also exclude set variables, since the variable is not
 318 ;;; guaranteed to be live everywhere in that case.
 319 (defun dump-1-variable (fun var tn id minimal buffer)
 320   (declare (type lambda-var var) (type (or tn null) tn) (type index id)
 321            (type clambda fun))
 322   (let* ((name (leaf-name var))
 323          (save-tn (and tn (tn-save-tn tn)))
 324          (kind (and tn (tn-kind tn)))
 325          (flags 0))
 326     (declare (type index flags))
 327     (when minimal
 328       (setq flags (logior flags compiled-debug-var-minimal-p))
 329       (unless tn
 330         (setq flags (logior flags compiled-debug-var-deleted-p))))
 331     (when (and (or (eq kind :environment)
 332                    (and (eq kind :debug-environment)
 333                         (null (basic-var-sets var))))
 334                (not (gethash tn (ir2-component-spilled-tns
 335                                  (component-info *component-being-compiled*))))
 336                (eq (lambda-var-home var) fun))
 337       (setq flags (logior flags compiled-debug-var-environment-live)))
 338     (when save-tn
 339       (setq flags (logior flags compiled-debug-var-save-loc-p)))
 340     (unless (or (zerop id) minimal)
 341       (setq flags (logior flags compiled-debug-var-id-p)))
 342     (vector-push-extend flags buffer)
 343     (unless minimal
 344       (vector-push-extend name buffer)
 345       (unless (zerop id)
 346         (vector-push-extend id buffer)))
 347     (if tn
 348         (vector-push-extend (tn-sc-offset tn) buffer)
 349         (assert minimal))
 350     (when save-tn
 351       (vector-push-extend (tn-sc-offset save-tn) buffer)))
 352   (values))
 353
 354 ;;; Return a vector suitable for use as the DEBUG-FUNCTION-VARIABLES
 355 ;;; of FUN. LEVEL is the current DEBUG-INFO quality. VAR-LOCS is a
 356 ;;; hashtable in which we enter the translation from LAMBDA-VARS to
 357 ;;; the relative position of that variable's location in the resulting
 358 ;;; vector.
 359 (defun compute-variables (fun level var-locs)
 360   (declare (type clambda fun) (type hash-table var-locs))
 361   (collect ((vars))
 362     (labels ((frob-leaf (leaf tn gensym-p)
 363                (let ((name (leaf-name leaf)))
 364                  (when (and name (leaf-refs leaf) (tn-offset tn)
 365                             (or gensym-p (symbol-package name)))
 366                    (vars (cons leaf tn)))))
 367              (frob-lambda (x gensym-p)
 368                (dolist (leaf (lambda-vars x))
 369                  (frob-leaf leaf (leaf-info leaf) gensym-p))))
 370       (frob-lambda fun t)
 371       (when (>= level 2)
 372         (dolist (x (ir2-environment-environment
 373                     (environment-info (lambda-environment fun))))
 374           (let ((thing (car x)))
 375             (when (lambda-var-p thing)
 376               (frob-leaf thing (cdr x) (= level 3)))))
 377
 378         (dolist (let (lambda-lets fun))
 379           (frob-lambda let (= level 3)))))
 380
 381     (let ((sorted (sort (vars) #'string<
 382                         :key #'(lambda (x)
 383                                  (symbol-name (leaf-name (car x))))))
 384           (prev-name nil)
 385           (id 0)
 386           (i 0)
 387           (buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 388       (declare (type (or simple-string null) prev-name)
 389                (type index id i))
 390       (dolist (x sorted)
 391         (let* ((var (car x))
 392                (name (symbol-name (leaf-name var))))
 393           (cond ((and prev-name (string= prev-name name))
 394                  (incf id))
 395                 (t
 396                  (setq id 0  prev-name name)))
 397           (dump-1-variable fun var (cdr x) id nil buffer)
 398           (setf (gethash var var-locs) i))
 399         (incf i))
 400       (coerce buffer 'simple-vector))))
 401
 402 ;;; Return a vector suitable for use as the DEBUG-FUNCTION-VARIABLES of
 403 ;;; FUN, representing the arguments to FUN in minimal variable format.
 404 (defun compute-minimal-variables (fun)
 405   (declare (type clambda fun))
 406   (let ((buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 407     (dolist (var (lambda-vars fun))
 408       (dump-1-variable fun var (leaf-info var) 0 t buffer))
 409     (coerce buffer 'simple-vector)))
 410
 411 ;;; Return Var's relative position in the function's variables (determined
 412 ;;; from the Var-Locs hashtable.)  If Var is deleted, then return DELETED.
 413 (defun debug-location-for (var var-locs)
 414   (declare (type lambda-var var) (type hash-table var-locs))
 415   (let ((res (gethash var var-locs)))
 416     (cond (res)
 417           (t
 418            (assert (or (null (leaf-refs var))
 419                        (not (tn-offset (leaf-info var)))))
 420            'deleted))))
 421 \f
 422 ;;;; arguments/returns
 423
 424 ;;; Return a vector to be used as the
 425 ;;; COMPILED-DEBUG-FUNCTION-ARGUMENTS for Fun. If fun is the
 426 ;;; MAIN-ENTRY for an optional dispatch, then look at the ARGLIST to
 427 ;;; determine the syntax, otherwise pretend all arguments are fixed.
 428 ;;;
 429 ;;; ### This assumption breaks down in EPs other than the main-entry,
 430 ;;; since they may or may not have supplied-p vars, etc.
 431 (defun compute-arguments (fun var-locs)
 432   (declare (type clambda fun) (type hash-table var-locs))
 433   (collect ((res))
 434     (let ((od (lambda-optional-dispatch fun)))
 435       (if (and od (eq (optional-dispatch-main-entry od) fun))
 436           (let ((actual-vars (lambda-vars fun))
 437                 (saw-optional nil))
 438             (dolist (arg (optional-dispatch-arglist od))
 439               (let ((info (lambda-var-arg-info arg))
 440                     (actual (pop actual-vars)))
 441                 (cond (info
 442                        (case (arg-info-kind info)
 443                          (:keyword
 444                           (res (arg-info-key info)))
 445                          (:rest
 446                           (res 'rest-arg))
 447                          (:more-context
 448                           (res 'more-arg))
 449                          (:optional
 450                           (unless saw-optional
 451                             (res 'optional-args)
 452                             (setq saw-optional t))))
 453                        (res (debug-location-for actual var-locs))
 454                        (when (arg-info-supplied-p info)
 455                          (res 'supplied-p)
 456                          (res (debug-location-for (pop actual-vars) var-locs))))
 457                       (t
 458                        (res (debug-location-for actual var-locs)))))))
 459           (dolist (var (lambda-vars fun))
 460             (res (debug-location-for var var-locs)))))
 461
 462     (coerce-to-smallest-eltype (res))))
 463
 464 ;;; Return a vector of SC offsets describing Fun's return locations.
 465 ;;; (Must be known values return...)
 466 (defun compute-debug-returns (fun)
 467   (coerce-to-smallest-eltype
 468    (mapcar #'(lambda (loc)
 469                (tn-sc-offset loc))
 470            (return-info-locations (tail-set-info (lambda-tail-set fun))))))
 471 \f
 472 ;;;; debug functions
 473
 474 ;;; Return a C-D-F structure with all the mandatory slots filled in.
 475 (defun dfun-from-fun (fun)
 476   (declare (type clambda fun))
 477   (let* ((2env (environment-info (lambda-environment fun)))
 478          (dispatch (lambda-optional-dispatch fun))
 479          (main-p (and dispatch
 480                       (eq fun (optional-dispatch-main-entry dispatch)))))
 481     (make-compiled-debug-function
 482      :name (cond ((leaf-name fun))
 483                  ((let ((ef (functional-entry-function
 484                              fun)))
 485                     (and ef (leaf-name ef))))
 486                  ((and main-p (leaf-name dispatch)))
 487                  (t
 488                   (component-name
 489                    (block-component (node-block (lambda-bind fun))))))
 490      :kind (if main-p nil (functional-kind fun))
 491      :return-pc (tn-sc-offset (ir2-environment-return-pc 2env))
 492      :old-fp (tn-sc-offset (ir2-environment-old-fp 2env))
 493      :start-pc (label-position (ir2-environment-environment-start 2env))
 494      :elsewhere-pc (label-position (ir2-environment-elsewhere-start 2env)))))
 495
 496 ;;; Return a complete C-D-F structure for Fun. This involves
 497 ;;; determining the DEBUG-INFO level and filling in optional slots as
 498 ;;; appropriate.
 499 (defun compute-1-debug-function (fun var-locs)
 500   (declare (type clambda fun) (type hash-table var-locs))
 501   (let* ((dfun (dfun-from-fun fun))
 502          (actual-level (policy (lambda-bind fun) debug))
 503          (level (if #!+sb-dyncount *collect-dynamic-statistics*
 504                     #!-sb-dyncount nil
 505                     (max actual-level 2)
 506                     actual-level)))
 507     (cond ((zerop level))
 508           ((and (<= level 1)
 509                 (let ((od (lambda-optional-dispatch fun)))
 510                   (or (not od)
 511                       (not (eq (optional-dispatch-main-entry od) fun)))))
 512            (setf (compiled-debug-function-variables dfun)
 513                  (compute-minimal-variables fun))
 514            (setf (compiled-debug-function-arguments dfun) :minimal))
 515           (t
 516            (setf (compiled-debug-function-variables dfun)
 517                  (compute-variables fun level var-locs))
 518            (setf (compiled-debug-function-arguments dfun)
 519                  (compute-arguments fun var-locs))))
 520
 521     (when (>= level 2)
 522       (multiple-value-bind (blocks tlf-num) (compute-debug-blocks fun var-locs)
 523         (setf (compiled-debug-function-tlf-number dfun) tlf-num)
 524         (setf (compiled-debug-function-blocks dfun) blocks)))
 525
 526     (if (external-entry-point-p fun)
 527         (setf (compiled-debug-function-returns dfun) :standard)
 528         (let ((info (tail-set-info (lambda-tail-set fun))))
 529           (when info
 530             (cond ((eq (return-info-kind info) :unknown)
 531                    (setf (compiled-debug-function-returns dfun)
 532                          :standard))
 533                   ((/= level 0)
 534                    (setf (compiled-debug-function-returns dfun)
 535                          (compute-debug-returns fun)))))))
 536     dfun))
 537 \f
 538 ;;;; minimal debug functions
 539
 540 ;;; Return true if DFUN can be represented as a minimal debug
 541 ;;; function. DFUN is a cons (<start offset> . C-D-F).
 542 (defun debug-function-minimal-p (dfun)
 543   (declare (type cons dfun))
 544   (let ((dfun (cdr dfun)))
 545     (and (member (compiled-debug-function-arguments dfun) '(:minimal nil))
 546          (null (compiled-debug-function-blocks dfun)))))
 547
 548 ;;; Dump a packed binary representation of a DFUN into *BYTE-BUFFER*.
 549 ;;; PREV-START and START are the byte offsets in the code where the
 550 ;;; previous function started and where this one starts.
 551 ;;; PREV-ELSEWHERE is the previous function's elsewhere PC.
 552 (defun dump-1-minimal-dfun (dfun prev-start start prev-elsewhere)
 553   (declare (type compiled-debug-function dfun)
 554            (type index prev-start start prev-elsewhere))
 555   (let* ((name (compiled-debug-function-name dfun))
 556          (setf-p (and (consp name) (eq (car name) 'setf)
 557                       (consp (cdr name)) (symbolp (cadr name))))
 558          (base-name (if setf-p (cadr name) name))
 559          (pkg (when (symbolp base-name)
 560                 (symbol-package base-name)))
 561          (name-rep
 562           (cond ((stringp base-name)
 563                  minimal-debug-function-name-component)
 564                 ((not pkg)
 565                  minimal-debug-function-name-uninterned)
 566                 ((eq pkg (sane-package))
 567                  minimal-debug-function-name-symbol)
 568                 (t
 569                  minimal-debug-function-name-packaged))))
 570     (assert (or (atom name) setf-p))
 571     (let ((options 0))
 572       (setf (ldb minimal-debug-function-name-style-byte options) name-rep)
 573       (setf (ldb minimal-debug-function-kind-byte options)
 574             (position-or-lose (compiled-debug-function-kind dfun)
 575                               *minimal-debug-function-kinds*))
 576       (setf (ldb minimal-debug-function-returns-byte options)
 577             (etypecase (compiled-debug-function-returns dfun)
 578               ((member :standard) minimal-debug-function-returns-standard)
 579               ((member :fixed) minimal-debug-function-returns-fixed)
 580               (vector minimal-debug-function-returns-specified)))
 581       (vector-push-extend options *byte-buffer*))
 582
 583     (let ((flags 0))
 584       (when setf-p
 585         (setq flags (logior flags minimal-debug-function-setf-bit)))
 586       (when (compiled-debug-function-nfp dfun)
 587         (setq flags (logior flags minimal-debug-function-nfp-bit)))
 588       (when (compiled-debug-function-variables dfun)
 589         (setq flags (logior flags minimal-debug-function-variables-bit)))
 590       (vector-push-extend flags *byte-buffer*))
 591
 592     (when (eql name-rep minimal-debug-function-name-packaged)
 593       (write-var-string (package-name pkg) *byte-buffer*))
 594     (unless (stringp base-name)
 595       (write-var-string (symbol-name base-name) *byte-buffer*))
 596
 597     (let ((vars (compiled-debug-function-variables dfun)))
 598       (when vars
 599         (let ((len (length vars)))
 600           (write-var-integer len *byte-buffer*)
 601           (dotimes (i len)
 602             (vector-push-extend (aref vars i) *byte-buffer*)))))
 603
 604     (let ((returns (compiled-debug-function-returns dfun)))
 605       (when (vectorp returns)
 606         (let ((len (length returns)))
 607           (write-var-integer len *byte-buffer*)
 608           (dotimes (i len)
 609             (write-var-integer (aref returns i) *byte-buffer*)))))
 610
 611     (write-var-integer (compiled-debug-function-return-pc dfun)
 612                        *byte-buffer*)
 613     (write-var-integer (compiled-debug-function-old-fp dfun)
 614                        *byte-buffer*)
 615     (when (compiled-debug-function-nfp dfun)
 616       (write-var-integer (compiled-debug-function-nfp dfun)
 617                          *byte-buffer*))
 618     (write-var-integer (- start prev-start) *byte-buffer*)
 619     (write-var-integer (- (compiled-debug-function-start-pc dfun) start)
 620                        *byte-buffer*)
 621     (write-var-integer (- (compiled-debug-function-elsewhere-pc dfun)
 622                           prev-elsewhere)
 623                        *byte-buffer*)))
 624
 625 ;;; Return a byte-vector holding all the debug functions for a
 626 ;;; component in the packed binary minimal-debug-function format.
 627 (defun compute-minimal-debug-functions (dfuns)
 628   (declare (list dfuns))
 629   (setf (fill-pointer *byte-buffer*) 0)
 630   (let ((prev-start 0)
 631         (prev-elsewhere 0))
 632     (dolist (dfun dfuns)
 633       (let ((start (car dfun))
 634             (elsewhere (compiled-debug-function-elsewhere-pc (cdr dfun))))
 635         (dump-1-minimal-dfun (cdr dfun) prev-start start prev-elsewhere)
 636         (setq prev-start start  prev-elsewhere elsewhere))))
 637   (copy-seq *byte-buffer*))
 638 \f
 639 ;;;; full component dumping
 640
 641 ;;; Compute the full form (simple-vector) function map.
 642 (defun compute-debug-function-map (sorted)
 643   (declare (list sorted))
 644   (let* ((len (1- (* (length sorted) 2)))
 645          (funs-vec (make-array len)))
 646     (do ((i -1 (+ i 2))
 647          (sorted sorted (cdr sorted)))
 648         ((= i len))
 649       (declare (fixnum i))
 650       (let ((dfun (car sorted)))
 651         (unless (minusp i)
 652           (setf (svref funs-vec i) (car dfun)))
 653         (setf (svref funs-vec (1+ i)) (cdr dfun))))
 654     funs-vec))
 655
 656 ;;; Return a DEBUG-INFO structure describing COMPONENT. This has to be
 657 ;;; called after assembly so that source map information is available.
 658 (defun debug-info-for-component (component)
 659   (declare (type component component))
 660   (collect ((dfuns))
 661     (let ((var-locs (make-hash-table :test 'eq))
 662           ;; FIXME: What is *BYTE-BUFFER* for? Has it become dead code
 663           ;; now that we no longer use minimal-debug-function
 664           ;; representation?
 665           (*byte-buffer* (make-array 10
 666                                      :element-type '(unsigned-byte 8)
 667                                      :fill-pointer 0
 668                                      :adjustable t)))
 669       (dolist (fun (component-lambdas component))
 670         (clrhash var-locs)
 671         (dfuns (cons (label-position
 672                       (block-label (node-block (lambda-bind fun))))
 673                      (compute-1-debug-function fun var-locs))))
 674       (let* ((sorted (sort (dfuns) #'< :key #'car))
 675              ;; FIXME: CMU CL had
 676              ;;    (IF (EVERY #'DEBUG-FUNCTION-MINIMAL-P SORTED)
 677              ;;        (COMPUTE-MINIMAL-DEBUG-FUNCTIONS SORTED)
 678              ;;        (COMPUTE-DEBUG-FUNCTION-MAP SORTED))
 679              ;; here. We've gotten rid of the minimal-debug-function
 680              ;; case in SBCL because the minimal representation
 681              ;; couldn't be made to transform properly under package
 682              ;; renaming. Now that that case is gone, a lot of code is
 683              ;; dead, and once everything is known to work, the dead
 684              ;; code should be deleted.
 685              (function-map (compute-debug-function-map sorted)))
 686         (make-compiled-debug-info :name (component-name component)
 687                                   :function-map function-map)))))
 688 \f
 689 ;;; Write BITS out to BYTE-BUFFER in backend byte order. The length of
 690 ;;; BITS must be evenly divisible by eight.
 691 (defun write-packed-bit-vector (bits byte-buffer)
 692   (declare (type simple-bit-vector bits) (type byte-buffer byte-buffer))
 693   (multiple-value-bind (initial step done)
 694       (ecase *backend-byte-order*
 695         (:little-endian (values 0  1  8))
 696         (:big-endian    (values 7 -1 -1)))
 697     (let ((shift initial)
 698           (byte 0))
 699       (dotimes (i (length bits))
 700         (let ((int (aref bits i)))
 701           (setf byte (logior byte (ash int shift)))
 702           (incf shift step))
 703         (when (= shift done)
 704           (vector-push-extend byte byte-buffer)
 705           (setf shift initial
 706                 byte 0)))
 707       (unless (= shift initial)
 708         (vector-push-extend byte byte-buffer))))
 709   (values))