src/compiler/debug-dump.lisp

   1 ;;;; stuff that creates debugger information from the compiler's
   2 ;;;; internal data structures
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (deftype byte-buffer () '(vector (unsigned-byte 8)))
  16 (defvar *byte-buffer*)
  17 (declaim (type byte-buffer *byte-buffer*))
  18 \f
  19 ;;;; debug blocks
  20
  21 (deftype location-kind ()
  22   '(member :unknown-return :known-return :internal-error :non-local-exit
  23            :block-start :call-site :single-value-return :non-local-entry))
  24
  25 ;;; The LOCATION-INFO structure holds the information what we need
  26 ;;; about locations which code generation decided were "interesting".
  27 (defstruct (location-info
  28             (:constructor make-location-info (kind label vop))
  29             (:copier nil))
  30   ;; The kind of location noted.
  31   (kind nil :type location-kind)
  32   ;; The label pointing to the interesting code location.
  33   (label nil :type (or label index null))
  34   ;; The VOP that emitted this location (for node, save-set, ir2-block, etc.)
  35   (vop nil :type vop))
  36
  37 ;;; This is called during code generation in places where there is an
  38 ;;; "interesting" location: someplace where we are likely to end up
  39 ;;; in the debugger, and thus want debug info.
  40 (defun note-debug-location (vop label kind)
  41   (declare (type vop vop) (type (or label null) label)
  42            (type location-kind kind))
  43   (let ((location (make-location-info kind label vop)))
  44     (setf (ir2-block-locations (vop-block vop))
  45           (nconc (ir2-block-locations (vop-block vop))
  46                  (list location)))
  47     location))
  48
  49 #!-sb-fluid (declaim (inline ir2-block-physenv))
  50 (defun ir2-block-physenv (2block)
  51   (declare (type ir2-block 2block))
  52   (block-physenv (ir2-block-block 2block)))
  53
  54 ;;; Given a local conflicts vector and an IR2 block to represent the
  55 ;;; set of live TNs, and the VAR-LOCS hash-table representing the
  56 ;;; variables dumped, compute a bit-vector representing the set of
  57 ;;; live variables. If the TN is environment-live, we only mark it as
  58 ;;; live when it is in scope at NODE.
  59 (defun compute-live-vars (live node block var-locs vop)
  60   (declare (type ir2-block block) (type local-tn-bit-vector live)
  61            (type hash-table var-locs) (type node node)
  62            (type (or vop null) vop))
  63   (let ((res (make-array (logandc2 (+ (hash-table-count var-locs) 7) 7)
  64                          :element-type 'bit
  65                          :initial-element 0))
  66         (spilled (gethash vop
  67                           (ir2-component-spilled-vops
  68                            (component-info *component-being-compiled*)))))
  69     (do-live-tns (tn live block)
  70       (let ((leaf (tn-leaf tn)))
  71         (when (and (lambda-var-p leaf)
  72                    (or (not (member (tn-kind tn)
  73                                     '(:environment :debug-environment)))
  74                        (rassoc leaf (lexenv-vars (node-lexenv node))))
  75                    (or (null spilled)
  76                        (not (member tn spilled))))
  77           (let ((num (gethash leaf var-locs)))
  78             (when num
  79               (setf (sbit res num) 1))))))
  80     res))
  81
  82 ;;; The PC for the location most recently dumped.
  83 (defvar *previous-location*)
  84 (declaim (type index *previous-location*))
  85
  86 ;;; Dump a compiled debug-location into *BYTE-BUFFER* that describes
  87 ;;; the code/source map and live info. If true, VOP is the VOP
  88 ;;; associated with this location, for use in determining whether TNs
  89 ;;; are spilled.
  90 (defun dump-1-location (node block kind tlf-num label live var-locs vop)
  91   (declare (type node node) (type ir2-block block)
  92            (type local-tn-bit-vector live)
  93            (type (or label index) label)
  94            (type location-kind kind) (type (or index null) tlf-num)
  95            (type hash-table var-locs) (type (or vop null) vop))
  96
  97   (vector-push-extend
  98    (dpb (position-or-lose kind *compiled-code-location-kinds*)
  99         compiled-code-location-kind-byte
 100         0)
 101    *byte-buffer*)
 102
 103   (let ((loc (if (fixnump label) label (label-position label))))
 104     (write-var-integer (- loc *previous-location*) *byte-buffer*)
 105     (setq *previous-location* loc))
 106
 107   (let ((path (node-source-path node)))
 108     (unless tlf-num
 109       (write-var-integer (source-path-tlf-number path) *byte-buffer*))
 110     (write-var-integer (source-path-form-number path) *byte-buffer*))
 111
 112   (write-packed-bit-vector (compute-live-vars live node block var-locs vop)
 113                            *byte-buffer*)
 114
 115   (values))
 116
 117 ;;; Extract context info from a Location-Info structure and use it to
 118 ;;; dump a compiled code-location.
 119 (defun dump-location-from-info (loc tlf-num var-locs)
 120   (declare (type location-info loc) (type (or index null) tlf-num)
 121            (type hash-table var-locs))
 122   (let ((vop (location-info-vop loc)))
 123     (dump-1-location (vop-node vop)
 124                      (vop-block vop)
 125                      (location-info-kind loc)
 126                      tlf-num
 127                      (location-info-label loc)
 128                      (vop-save-set vop)
 129                      var-locs
 130                      vop))
 131   (values))
 132
 133 ;;; Scan all the blocks, determining if all locations are in the same
 134 ;;; TLF, and returning it or NIL.
 135 (defun find-tlf-number (fun)
 136   (declare (type clambda fun))
 137   (let ((res (source-path-tlf-number (node-source-path (lambda-bind fun)))))
 138     (declare (type (or index null) res))
 139     (do-physenv-ir2-blocks (2block (lambda-physenv fun))
 140       (let ((block (ir2-block-block 2block)))
 141         (when (eq (block-info block) 2block)
 142           (unless (eql (source-path-tlf-number
 143                         (node-source-path
 144                          (block-start-node block)))
 145                        res)
 146             (setq res nil)))
 147
 148         (dolist (loc (ir2-block-locations 2block))
 149           (unless (eql (source-path-tlf-number
 150                         (node-source-path
 151                          (vop-node (location-info-vop loc))))
 152                        res)
 153             (setq res nil)))))
 154     res))
 155
 156 ;;; Dump out the number of locations and the locations for Block.
 157 (defun dump-block-locations (block locations tlf-num var-locs)
 158   (declare (type cblock block) (list locations))
 159   (if (and locations
 160            (eq (location-info-kind (first locations))
 161                :non-local-entry))
 162       (write-var-integer (length locations) *byte-buffer*)
 163       (let ((2block (block-info block)))
 164         (write-var-integer (+ (length locations) 1) *byte-buffer*)
 165         (dump-1-location (block-start-node block)
 166                          2block :block-start tlf-num
 167                          (ir2-block-%label 2block)
 168                          (ir2-block-live-out 2block)
 169                          var-locs
 170                          nil)))
 171   (dolist (loc locations)
 172     (dump-location-from-info loc tlf-num var-locs))
 173   (values))
 174
 175 ;;; Dump the successors of Block, being careful not to fly into space
 176 ;;; on weird successors.
 177 (defun dump-block-successors (block physenv)
 178   (declare (type cblock block) (type physenv physenv))
 179   (let* ((tail (component-tail (block-component block)))
 180          (succ (block-succ block))
 181          (valid-succ
 182           (if (and succ
 183                    (or (eq (car succ) tail)
 184                        (not (eq (block-physenv (car succ)) physenv))))
 185               ()
 186               succ)))
 187     (vector-push-extend
 188      (dpb (length valid-succ) compiled-debug-block-nsucc-byte 0)
 189      *byte-buffer*)
 190     (let ((base (block-number
 191                  (node-block
 192                   (lambda-bind (physenv-lambda physenv))))))
 193       (dolist (b valid-succ)
 194         (write-var-integer
 195          (the index (- (block-number b) base))
 196          *byte-buffer*))))
 197   (values))
 198
 199 ;;; Return a vector and an integer (or null) suitable for use as the
 200 ;;; BLOCKS and TLF-NUMBER in FUN's DEBUG-FUN. This requires two
 201 ;;; passes to compute:
 202 ;;; -- Scan all blocks, dumping the header and successors followed
 203 ;;;    by all the non-elsewhere locations.
 204 ;;; -- Dump the elsewhere block header and all the elsewhere
 205 ;;;    locations (if any.)
 206 (defun compute-debug-blocks (fun var-locs)
 207   (declare (type clambda fun) (type hash-table var-locs))
 208   (setf (fill-pointer *byte-buffer*) 0)
 209   (let ((*previous-location* 0)
 210         (tlf-num (find-tlf-number fun))
 211         (physenv (lambda-physenv fun))
 212         (prev-locs nil)
 213         (prev-block nil))
 214     (collect ((elsewhere))
 215       (do-physenv-ir2-blocks (2block physenv)
 216         (let ((block (ir2-block-block 2block)))
 217           (when (eq (block-info block) 2block)
 218             (when prev-block
 219               (dump-block-locations prev-block prev-locs tlf-num var-locs))
 220             (setq prev-block block  prev-locs ())
 221             (dump-block-successors block physenv)))
 222
 223         (collect ((here prev-locs))
 224           (dolist (loc (ir2-block-locations 2block))
 225             (if (label-elsewhere-p (location-info-label loc))
 226                 (elsewhere loc)
 227                 (here loc)))
 228           (setq prev-locs (here))))
 229
 230       (dump-block-locations prev-block prev-locs tlf-num var-locs)
 231
 232       (when (elsewhere)
 233         (vector-push-extend compiled-debug-block-elsewhere-p *byte-buffer*)
 234         (write-var-integer (length (elsewhere)) *byte-buffer*)
 235         (dolist (loc (elsewhere))
 236           (dump-location-from-info loc tlf-num var-locs))))
 237
 238     (values (copy-seq *byte-buffer*) tlf-num)))
 239 \f
 240 ;;; Return a list of DEBUG-SOURCE structures containing information
 241 ;;; derived from INFO. Unless :BYTE-COMPILE T was specified, we always
 242 ;;; dump the START-POSITIONS, since it is too hard figure out whether
 243 ;;; we need them or not.
 244 (defun debug-source-for-info (info)
 245   (declare (type source-info info))
 246   (let* ((file-info (source-info-file-info info))
 247          (res (make-debug-source
 248                :from :file
 249                :created (file-info-write-date file-info)
 250                :compiled (source-info-start-time info)
 251                :source-root (file-info-source-root file-info)
 252                :start-positions (coerce-to-smallest-eltype
 253                                  (file-info-positions file-info))))
 254          (name (file-info-name file-info)))
 255     (etypecase name
 256       ((member :lisp)
 257        (setf (debug-source-from res) name)
 258        (setf (debug-source-name res)
 259              (coerce (file-info-forms file-info) 'simple-vector)))
 260       (pathname
 261        (let* ((untruename (file-info-untruename file-info))
 262               (dir (pathname-directory untruename)))
 263          (setf (debug-source-name res)
 264                (namestring
 265                 (if (and dir (eq (first dir) :absolute))
 266                     untruename
 267                     name))))))
 268     (list res)))
 269
 270
 271 ;;; Given an arbitrary sequence, coerce it to an unsigned vector if
 272 ;;; possible. Ordinarily we coerce it to the smallest specialized
 273 ;;; vector we can. However, we also have a special hack for
 274 ;;; cross-compiling at bootstrap time, when arbitrarily-specialized
 275 ;;; vectors aren't fully supported: in that case, we coerce it only to
 276 ;;; a vector whose element size is an integer multiple of output byte
 277 ;;; size.
 278 (defun coerce-to-smallest-eltype (seq)
 279   (let ((maxoid 0))
 280     (flet ((frob (x)
 281              (if (typep x 'unsigned-byte)
 282                  (when (>= x maxoid)
 283                    (setf maxoid x))
 284                  (return-from coerce-to-smallest-eltype
 285                    (coerce seq 'simple-vector)))))
 286       (if (listp seq)
 287           (dolist (i seq)
 288             (frob i))
 289           (dovector (i seq)
 290             (frob i)))
 291       (let ((specializer `(unsigned-byte
 292                            ,(etypecase maxoid
 293                               ((unsigned-byte 8) 8)
 294                               ((unsigned-byte 16) 16)
 295                               ((unsigned-byte 32) 32)))))
 296         ;; cross-compilers beware! It would be possible for the
 297         ;; upgraded-array-element-type of (UNSIGNED-BYTE 16) to be
 298         ;; (SIGNED-BYTE 17) or (UNSIGNED-BYTE 23), and this is
 299         ;; completely valid by ANSI.  However, the cross-compiler
 300         ;; doesn't know how to dump (in practice) anything but the
 301         ;; above three specialized array types, so make it break here
 302         ;; if this is violated.
 303         #+sb-xc-host
 304         (aver
 305          ;; not SB!XC:UPGRADED-ARRAY-ELEMENT-TYPE, because we are
 306          ;; worried about whether the host's implementation of arrays.
 307          (let ((uaet (upgraded-array-element-type specializer)))
 308            (dolist (et '((unsigned-byte 8)
 309                          (unsigned-byte 16)
 310                          (unsigned-byte 32))
 311                     nil)
 312              (when (and (subtypep et uaet) (subtypep uaet et))
 313                (return t)))))
 314         (coerce seq `(simple-array ,specializer (*)))))))
 315 \f
 316 ;;;; variables
 317
 318 ;;; Return a SC-OFFSET describing TN's location.
 319 (defun tn-sc-offset (tn)
 320   (declare (type tn tn))
 321   (make-sc-offset (sc-number (tn-sc tn))
 322                   (tn-offset tn)))
 323
 324 ;;; Dump info to represent VAR's location being TN. ID is an integer
 325 ;;; that makes VAR's name unique in the function. BUFFER is the vector
 326 ;;; we stick the result in. If MINIMAL, we suppress name dumping, and
 327 ;;; set the minimal flag.
 328 ;;;
 329 ;;; The DEBUG-VAR is only marked as always-live if the TN is
 330 ;;; environment live and is an argument. If a :DEBUG-ENVIRONMENT TN,
 331 ;;; then we also exclude set variables, since the variable is not
 332 ;;; guaranteed to be live everywhere in that case.
 333 (defun dump-1-var (fun var tn id minimal buffer)
 334   (declare (type lambda-var var) (type (or tn null) tn) (type index id)
 335            (type clambda fun))
 336   (let* ((name (leaf-debug-name var))
 337          (save-tn (and tn (tn-save-tn tn)))
 338          (kind (and tn (tn-kind tn)))
 339          (flags 0))
 340     (declare (type index flags))
 341     (when minimal
 342       (setq flags (logior flags compiled-debug-var-minimal-p))
 343       (unless tn
 344         (setq flags (logior flags compiled-debug-var-deleted-p))))
 345     (when (and (or (eq kind :environment)
 346                    (and (eq kind :debug-environment)
 347                         (null (basic-var-sets var))))
 348                (not (gethash tn (ir2-component-spilled-tns
 349                                  (component-info *component-being-compiled*))))
 350                (eq (lambda-var-home var) fun))
 351       (setq flags (logior flags compiled-debug-var-environment-live)))
 352     (when save-tn
 353       (setq flags (logior flags compiled-debug-var-save-loc-p)))
 354     (unless (or (zerop id) minimal)
 355       (setq flags (logior flags compiled-debug-var-id-p)))
 356     (vector-push-extend flags buffer)
 357     (unless minimal
 358       (vector-push-extend name buffer)
 359       (unless (zerop id)
 360         (vector-push-extend id buffer)))
 361     (if tn
 362         (vector-push-extend (tn-sc-offset tn) buffer)
 363         (aver minimal))
 364     (when save-tn
 365       (vector-push-extend (tn-sc-offset save-tn) buffer)))
 366   (values))
 367
 368 ;;; Return a vector suitable for use as the DEBUG-FUN-VARS
 369 ;;; of FUN. LEVEL is the current DEBUG-INFO quality. VAR-LOCS is a
 370 ;;; hash table in which we enter the translation from LAMBDA-VARS to
 371 ;;; the relative position of that variable's location in the resulting
 372 ;;; vector.
 373 (defun compute-vars (fun level var-locs)
 374   (declare (type clambda fun) (type hash-table var-locs))
 375   (collect ((vars))
 376     (labels ((frob-leaf (leaf tn gensym-p)
 377                (let ((name (leaf-debug-name leaf)))
 378                  (when (and name (leaf-refs leaf) (tn-offset tn)
 379                             (or gensym-p (symbol-package name)))
 380                    (vars (cons leaf tn)))))
 381              (frob-lambda (x gensym-p)
 382                (dolist (leaf (lambda-vars x))
 383                  (frob-leaf leaf (leaf-info leaf) gensym-p))))
 384       (frob-lambda fun t)
 385       (when (>= level 2)
 386         (dolist (x (ir2-physenv-closure (physenv-info (lambda-physenv fun))))
 387           (let ((thing (car x)))
 388             (when (lambda-var-p thing)
 389               (frob-leaf thing (cdr x) (= level 3)))))
 390
 391         (dolist (let (lambda-lets fun))
 392           (frob-lambda let (= level 3)))))
 393
 394     (let ((sorted (sort (vars) #'string<
 395                         :key (lambda (x)
 396                                (symbol-name (leaf-debug-name (car x))))))
 397           (prev-name nil)
 398           (id 0)
 399           (i 0)
 400           (buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 401       (declare (type (or simple-string null) prev-name)
 402                (type index id i))
 403       (dolist (x sorted)
 404         (let* ((var (car x))
 405                (name (symbol-name (leaf-debug-name var))))
 406           (cond ((and prev-name (string= prev-name name))
 407                  (incf id))
 408                 (t
 409                  (setq id 0  prev-name name)))
 410           (dump-1-var fun var (cdr x) id nil buffer)
 411           (setf (gethash var var-locs) i))
 412         (incf i))
 413       (coerce buffer 'simple-vector))))
 414
 415 ;;; Return a vector suitable for use as the DEBUG-FUN-VARS of
 416 ;;; FUN, representing the arguments to FUN in minimal variable format.
 417 (defun compute-minimal-vars (fun)
 418   (declare (type clambda fun))
 419   (let ((buffer (make-array 0 :fill-pointer 0 :adjustable t)))
 420     (dolist (var (lambda-vars fun))
 421       (dump-1-var fun var (leaf-info var) 0 t buffer))
 422     (coerce buffer 'simple-vector)))
 423
 424 ;;; Return VAR's relative position in the function's variables (determined
 425 ;;; from the VAR-LOCS hashtable).  If VAR is deleted, then return DELETED.
 426 (defun debug-location-for (var var-locs)
 427   (declare (type lambda-var var) (type hash-table var-locs))
 428   (let ((res (gethash var var-locs)))
 429     (cond (res)
 430           (t
 431            (aver (or (null (leaf-refs var))
 432                      (not (tn-offset (leaf-info var)))))
 433            'deleted))))
 434 \f
 435 ;;;; arguments/returns
 436
 437 ;;; Return a vector to be used as the COMPILED-DEBUG-FUN-ARGS for FUN.
 438 ;;; If FUN is the MAIN-ENTRY for an optional dispatch, then look at
 439 ;;; the ARGLIST to determine the syntax, otherwise pretend all
 440 ;;; arguments are fixed.
 441 ;;;
 442 ;;; ### This assumption breaks down in EPs other than the main-entry,
 443 ;;; since they may or may not have supplied-p vars, etc.
 444 (defun compute-args (fun var-locs)
 445   (declare (type clambda fun) (type hash-table var-locs))
 446   (collect ((res))
 447     (let ((od (lambda-optional-dispatch fun)))
 448       (if (and od (eq (optional-dispatch-main-entry od) fun))
 449           (let ((actual-vars (lambda-vars fun))
 450                 (saw-optional nil))
 451             (dolist (arg (optional-dispatch-arglist od))
 452               (let ((info (lambda-var-arg-info arg))
 453                     (actual (pop actual-vars)))
 454                 (cond (info
 455                        (case (arg-info-kind info)
 456                          (:keyword
 457                           (res (arg-info-key info)))
 458                          (:rest
 459                           (res 'rest-arg))
 460                          (:more-context
 461                           (res 'more-arg))
 462                          (:optional
 463                           (unless saw-optional
 464                             (res 'optional-args)
 465                             (setq saw-optional t))))
 466                        (res (debug-location-for actual var-locs))
 467                        (when (arg-info-supplied-p info)
 468                          (res 'supplied-p)
 469                          (res (debug-location-for (pop actual-vars) var-locs))))
 470                       (t
 471                        (res (debug-location-for actual var-locs)))))))
 472           (dolist (var (lambda-vars fun))
 473             (res (debug-location-for var var-locs)))))
 474
 475     (coerce-to-smallest-eltype (res))))
 476
 477 ;;; Return a vector of SC offsets describing FUN's return locations.
 478 ;;; (Must be known values return...)
 479 (defun compute-debug-returns (fun)
 480   (coerce-to-smallest-eltype
 481    (mapcar (lambda (loc)
 482              (tn-sc-offset loc))
 483            (return-info-locations (tail-set-info (lambda-tail-set fun))))))
 484 \f
 485 ;;;; debug functions
 486
 487 ;;; Return a C-D-F structure with all the mandatory slots filled in.
 488 (defun dfun-from-fun (fun)
 489   (declare (type clambda fun))
 490   (let* ((2env (physenv-info (lambda-physenv fun)))
 491          (dispatch (lambda-optional-dispatch fun))
 492          (main-p (and dispatch
 493                       (eq fun (optional-dispatch-main-entry dispatch)))))
 494     (make-compiled-debug-fun
 495      :name (leaf-debug-name fun)
 496      :kind (if main-p nil (functional-kind fun))
 497      :return-pc (tn-sc-offset (ir2-physenv-return-pc 2env))
 498      :old-fp (tn-sc-offset (ir2-physenv-old-fp 2env))
 499      :start-pc (label-position (ir2-physenv-environment-start 2env))
 500      :elsewhere-pc (label-position (ir2-physenv-elsewhere-start 2env)))))
 501
 502 ;;; Return a complete C-D-F structure for FUN. This involves
 503 ;;; determining the DEBUG-INFO level and filling in optional slots as
 504 ;;; appropriate.
 505 (defun compute-1-debug-fun (fun var-locs)
 506   (declare (type clambda fun) (type hash-table var-locs))
 507   (let* ((dfun (dfun-from-fun fun))
 508          (actual-level (policy (lambda-bind fun) debug))
 509          (level (if #!+sb-dyncount *collect-dynamic-statistics*
 510                     #!-sb-dyncount nil
 511                     (max actual-level 2)
 512                     actual-level)))
 513     (cond ((zerop level))
 514           ((and (<= level 1)
 515                 (let ((od (lambda-optional-dispatch fun)))
 516                   (or (not od)
 517                       (not (eq (optional-dispatch-main-entry od) fun)))))
 518            (setf (compiled-debug-fun-vars dfun)
 519                  (compute-minimal-vars fun))
 520            (setf (compiled-debug-fun-arguments dfun) :minimal))
 521           (t
 522            (setf (compiled-debug-fun-vars dfun)
 523                  (compute-vars fun level var-locs))
 524            (setf (compiled-debug-fun-arguments dfun)
 525                  (compute-args fun var-locs))))
 526
 527     (when (>= level 2)
 528       (multiple-value-bind (blocks tlf-num) (compute-debug-blocks fun var-locs)
 529         (setf (compiled-debug-fun-tlf-number dfun) tlf-num)
 530         (setf (compiled-debug-fun-blocks dfun) blocks)))
 531
 532     (if (xep-p fun)
 533         (setf (compiled-debug-fun-returns dfun) :standard)
 534         (let ((info (tail-set-info (lambda-tail-set fun))))
 535           (when info
 536             (cond ((eq (return-info-kind info) :unknown)
 537                    (setf (compiled-debug-fun-returns dfun)
 538                          :standard))
 539                   ((/= level 0)
 540                    (setf (compiled-debug-fun-returns dfun)
 541                          (compute-debug-returns fun)))))))
 542     dfun))
 543 \f
 544 ;;;; full component dumping
 545
 546 ;;; Compute the full form (simple-vector) function map.
 547 (defun compute-debug-fun-map (sorted)
 548   (declare (list sorted))
 549   (let* ((len (1- (* (length sorted) 2)))
 550          (funs-vec (make-array len)))
 551     (do ((i -1 (+ i 2))
 552          (sorted sorted (cdr sorted)))
 553         ((= i len))
 554       (declare (fixnum i))
 555       (let ((dfun (car sorted)))
 556         (unless (minusp i)
 557           (setf (svref funs-vec i) (car dfun)))
 558         (setf (svref funs-vec (1+ i)) (cdr dfun))))
 559     funs-vec))
 560
 561 ;;; Return a DEBUG-INFO structure describing COMPONENT. This has to be
 562 ;;; called after assembly so that source map information is available.
 563 (defun debug-info-for-component (component)
 564   (declare (type component component))
 565   (let ((dfuns nil)
 566         (var-locs (make-hash-table :test 'eq))
 567         (*byte-buffer* (make-array 10
 568                                    :element-type '(unsigned-byte 8)
 569                                    :fill-pointer 0
 570                                    :adjustable t)))
 571     (dolist (lambda (component-lambdas component))
 572       (clrhash var-locs)
 573       (push (cons (label-position (block-label (lambda-block lambda)))
 574                   (compute-1-debug-fun lambda var-locs))
 575             dfuns))
 576     (let* ((sorted (sort dfuns #'< :key #'car))
 577            (fun-map (compute-debug-fun-map sorted)))
 578       (make-compiled-debug-info :name (component-name component)
 579                                 :fun-map fun-map))))
 580 \f
 581 ;;; Write BITS out to BYTE-BUFFER in backend byte order. The length of
 582 ;;; BITS must be evenly divisible by eight.
 583 (defun write-packed-bit-vector (bits byte-buffer)
 584   (declare (type simple-bit-vector bits) (type byte-buffer byte-buffer))
 585
 586   ;; Enforce constraint from CMU-CL-era comment.
 587   (aver (zerop (mod (length bits) 8)))
 588
 589   (multiple-value-bind (initial step done)
 590       (ecase *backend-byte-order*
 591         (:little-endian (values 0  1  8))
 592         (:big-endian    (values 7 -1 -1)))
 593     (let ((shift initial)
 594           (byte 0))
 595       (dotimes (i (length bits))
 596         (let ((int (aref bits i)))
 597           (setf byte (logior byte (ash int shift)))
 598           (incf shift step))
 599         (when (= shift done)
 600           (vector-push-extend byte byte-buffer)
 601           (setf shift initial
 602                 byte 0)))
 603       (unless (= shift initial)
 604         (vector-push-extend byte byte-buffer))))
 605   (values))