src/compiler/debug.lisp

   1 ;;;; This file contains utilities for debugging the compiler --
   2 ;;;; currently only stuff for checking the consistency of the IR1.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (defvar *args* ()
  16   #!+sb-doc
  17   "This variable is bound to the format arguments when an error is signalled
  18   by BARF or BURP.")
  19
  20 (defvar *ignored-errors* (make-hash-table :test 'equal))
  21
  22 ;;; A definite inconsistency has been detected. Signal an error with
  23 ;;; *args* bound to the list of the format args.
  24 (declaim (ftype (function (string &rest t) (values)) barf))
  25 (defun barf (string &rest *args*)
  26   (unless (gethash string *ignored-errors*)
  27     (restart-case
  28         (apply #'error string *args*)
  29       (continue ()
  30         :report "Ignore this error.")
  31       (ignore-all ()
  32         :report "Ignore this and all future occurrences of this error."
  33         (setf (gethash string *ignored-errors*) t))))
  34   (values))
  35
  36 (defvar *burp-action* :warn
  37   #!+sb-doc
  38   "Action taken by the BURP function when a possible compiler bug is detected.
  39   One of :WARN, :ERROR or :NONE.")
  40 (declaim (type (member :warn :error :none) *burp-action*))
  41
  42 ;;; Called when something funny but possibly correct is noticed.
  43 ;;; Otherwise similar to BARF.
  44 (declaim (ftype (function (string &rest t) (values)) burp))
  45 (defun burp (string &rest *args*)
  46   (ecase *burp-action*
  47     (:warn (apply #'warn string *args*))
  48     (:error (apply #'cerror "press on anyway." string *args*))
  49     (:none))
  50   (values))
  51
  52 ;;; *SEEN-BLOCKS* is a hashtable with true values for all blocks which
  53 ;;; appear in the DFO for one of the specified components.
  54 ;;;
  55 ;;; *SEEN-FUNS* is similar, but records all the lambdas we
  56 ;;; reached by recursing on top level functions.
  57 ;;; FIXME: Is it really only LAMBDAs, not e.g. FUNCTIONALs? Then
  58 ;;; shouldn't it be *SEEN-LAMBDAS*?
  59 (defvar *seen-blocks* (make-hash-table :test 'eq))
  60 (defvar *seen-funs* (make-hash-table :test 'eq))
  61
  62 ;;; Barf if NODE is in a block which wasn't reached during the graph
  63 ;;; walk.
  64 (declaim (ftype (function (node) (values)) check-node-reached))
  65 (defun check-node-reached (node)
  66   (unless (gethash (continuation-block (node-prev node)) *seen-blocks*)
  67     (barf "~S was not reached." node))
  68   (values))
  69
  70 ;;; Check everything that we can think of for consistency. When a
  71 ;;; definite inconsistency is detected, we BARF. Possible problems
  72 ;;; just cause us to BURP. Our argument is a list of components, but
  73 ;;; we also look at the *FREE-VARS*, *FREE-FUNS* and *CONSTANTS*.
  74 ;;;
  75 ;;; First we do a pre-pass which finds all the CBLOCKs and CLAMBDAs,
  76 ;;; testing that they are linked together properly and entering them
  77 ;;; in hashtables. Next, we iterate over the blocks again, looking at
  78 ;;; the actual code and control flow. Finally, we scan the global leaf
  79 ;;; hashtables, looking for lossage.
  80 (declaim (ftype (function (list) (values)) check-ir1-consistency))
  81 (defun check-ir1-consistency (components)
  82   (clrhash *seen-blocks*)
  83   (clrhash *seen-funs*)
  84   (dolist (c components)
  85     (let* ((head (component-head c))
  86            (tail (component-tail c)))
  87       (unless (and (null (block-pred head))
  88                    (null (block-succ tail)))
  89         (barf "~S is malformed." c))
  90
  91       (do ((prev nil block)
  92            (block head (block-next block)))
  93           ((null block)
  94            (unless (eq prev tail)
  95              (barf "wrong TAIL for DFO, ~S in ~S" prev c)))
  96         (setf (gethash block *seen-blocks*) t)
  97         (unless (eq (block-prev block) prev)
  98           (barf "bad PREV for ~S, should be ~S" block prev))
  99         (unless (or (eq block tail)
 100                     (eq (block-component block) c))
 101           (barf "~S is not in ~S." block c)))
 102 #|
 103       (when (or (loop-blocks c) (loop-inferiors c))
 104         (do-blocks (block c :both)
 105           (setf (block-flag block) nil))
 106         (check-loop-consistency c nil)
 107         (do-blocks (block c :both)
 108           (unless (block-flag block)
 109             (barf "~S was not in any loop." block))))
 110 |#
 111     ))
 112
 113   (check-fun-consistency components)
 114
 115   (dolist (c components)
 116     (do ((block (block-next (component-head c)) (block-next block)))
 117         ((null (block-next block)))
 118       (check-block-consistency block)))
 119
 120   (maphash (lambda (k v)
 121              (declare (ignore k))
 122              (unless (or (constant-p v)
 123                          (and (global-var-p v)
 124                               (member (global-var-kind v)
 125                                       '(:global :special))))
 126                (barf "strange *FREE-VARS* entry: ~S" v))
 127              (dolist (n (leaf-refs v))
 128                (check-node-reached n))
 129              (when (basic-var-p v)
 130                (dolist (n (basic-var-sets v))
 131                  (check-node-reached n))))
 132            *free-vars*)
 133
 134   (maphash (lambda (k v)
 135              (declare (ignore k))
 136              (unless (constant-p v)
 137                (barf "strange *CONSTANTS* entry: ~S" v))
 138              (dolist (n (leaf-refs v))
 139                (check-node-reached n)))
 140            *constants*)
 141
 142   (maphash (lambda (k v)
 143              (declare (ignore k))
 144              (unless (or (functional-p v)
 145                          (and (global-var-p v)
 146                               (eq (global-var-kind v) :global-function)))
 147                (barf "strange *FREE-FUNS* entry: ~S" v))
 148              (dolist (n (leaf-refs v))
 149                (check-node-reached n)))
 150            *free-funs*)
 151   (clrhash *seen-funs*)
 152   (clrhash *seen-blocks*)
 153   (values))
 154 \f
 155 ;;;; function consistency checking
 156
 157 (defun observe-functional (x)
 158   (declare (type functional x))
 159   (when (gethash x *seen-funs*)
 160     (barf "~S was seen more than once." x))
 161   (unless (eq (functional-kind x) :deleted)
 162     (setf (gethash x *seen-funs*) t)))
 163
 164 ;;; Check that the specified function has been seen.
 165 (defun check-fun-reached (fun where)
 166   (declare (type functional fun))
 167   (unless (gethash fun *seen-funs*)
 168     (barf "unseen function ~S in ~S" fun where)))
 169
 170 ;;; In a CLAMBDA, check that the associated nodes are in seen blocks.
 171 ;;; In an OPTIONAL-DISPATCH, check that the entry points were seen. If
 172 ;;; the function is deleted, ignore it.
 173 (defun check-fun-stuff (functional)
 174   (ecase (functional-kind functional)
 175     (:external
 176      (let ((fun (functional-entry-fun functional)))
 177        (check-fun-reached fun functional)
 178        (when (functional-kind fun)
 179          (barf "The function for XEP ~S has kind." functional))
 180        (unless (eq (functional-entry-fun fun) functional)
 181          (barf "bad back-pointer in function for XEP ~S" functional))))
 182     ((:let :mv-let :assignment) ; i.e. SOMEWHAT-LETLIKE-P
 183      (check-fun-reached (lambda-home functional) functional)
 184      (when (functional-entry-fun functional)
 185        (barf "The LET ~S has entry function." functional))
 186      (unless (member functional (lambda-lets (lambda-home functional)))
 187        (barf "The LET ~S is not in LETs for HOME." functional))
 188      (unless (eq (functional-kind functional) :assignment)
 189        (when (rest (leaf-refs functional))
 190          (barf "The LET ~S has multiple references." functional)))
 191      (when (lambda-lets functional)
 192        (barf "LETs in a LET: ~S" functional)))
 193     (:optional
 194      (when (functional-entry-fun functional)
 195        (barf ":OPTIONAL ~S has an ENTRY-FUN." functional))
 196      (let ((ef (lambda-optional-dispatch functional)))
 197        (check-fun-reached ef functional)
 198        (unless (or (member functional (optional-dispatch-entry-points ef))
 199                    (eq functional (optional-dispatch-more-entry ef))
 200                    (eq functional (optional-dispatch-main-entry ef)))
 201          (barf ":OPTIONAL ~S is not an e-p for its OPTIONAL-DISPATCH ~S."
 202                functional ef))))
 203     (:toplevel
 204      (unless (eq (functional-entry-fun functional) functional)
 205        (barf "The ENTRY-FUN in ~S isn't a self-pointer." functional)))
 206     ((nil :escape :cleanup)
 207      (let ((ef (functional-entry-fun functional)))
 208        (when ef
 209          (check-fun-reached ef functional)
 210          (unless (eq (functional-kind ef) :external)
 211            (barf "The ENTRY-FUN in ~S isn't an XEP: ~S." functional ef)))))
 212     (:deleted
 213      (return-from check-fun-stuff)))
 214
 215   (case (functional-kind functional)
 216     ((nil :optional :external :toplevel :escape :cleanup)
 217      (when (lambda-p functional)
 218        (dolist (fun (lambda-lets functional))
 219          (unless (eq (lambda-home fun) functional)
 220            (barf "The home in ~S is not ~S." fun functional))
 221          (check-fun-reached fun functional))
 222        (unless (eq (lambda-home functional) functional)
 223          (barf "home not self-pointer in ~S" functional)))))
 224
 225   (etypecase functional
 226     (clambda
 227      (when (lambda-bind functional)
 228        (check-node-reached (lambda-bind functional)))
 229      (when (lambda-return functional)
 230        (check-node-reached (lambda-return functional)))
 231
 232      (dolist (var (lambda-vars functional))
 233        (dolist (ref (leaf-refs var))
 234          (check-node-reached ref))
 235        (dolist (set (basic-var-sets var))
 236          (check-node-reached set))
 237        (unless (eq (lambda-var-home var) functional)
 238          (barf "HOME in ~S should be ~S." var functional))))
 239     (optional-dispatch
 240      (dolist (ep (optional-dispatch-entry-points functional))
 241        (check-fun-reached ep functional))
 242      (let ((more (optional-dispatch-more-entry functional)))
 243        (when more (check-fun-reached more functional)))
 244      (check-fun-reached (optional-dispatch-main-entry functional)
 245                         functional))))
 246
 247 (defun check-fun-consistency (components)
 248   (dolist (c components)
 249     (dolist (new-fun (component-new-functionals c))
 250       (observe-functional new-fun))
 251     (dolist (fun (component-lambdas c))
 252       (when (eq (functional-kind fun) :external)
 253         (let ((ef (functional-entry-fun fun)))
 254           (when (optional-dispatch-p ef)
 255             (observe-functional ef))))
 256       (observe-functional fun)
 257       (dolist (let (lambda-lets fun))
 258         (observe-functional let))))
 259
 260   (dolist (c components)
 261     (dolist (new-fun (component-new-functionals c))
 262       (check-fun-stuff new-fun))
 263     (dolist (fun (component-lambdas c))
 264       (when (eq (functional-kind fun) :deleted)
 265         (barf "deleted lambda ~S in Lambdas for ~S" fun c))
 266       (check-fun-stuff fun)
 267       (dolist (let (lambda-lets fun))
 268         (check-fun-stuff let)))))
 269 \f
 270 ;;;; loop consistency checking
 271
 272 #|
 273 ;;; Descend through the loop nesting and check that the tree is well-formed
 274 ;;; and that all blocks in the loops are known blocks. We also mark each block
 275 ;;; that we see so that we can do a check later to detect blocks that weren't
 276 ;;; in any loop.
 277 (declaim (ftype (function (loop (or loop null)) (values)) check-loop-consistency))
 278 (defun check-loop-consistency (loop superior)
 279   (unless (eq (loop-superior loop) superior)
 280     (barf "wrong superior in ~S, should be ~S" loop superior))
 281   (when (and superior
 282              (/= (loop-depth loop) (1+ (loop-depth superior))))
 283     (barf "wrong depth in ~S" loop))
 284
 285   (dolist (tail (loop-tail loop))
 286     (check-loop-block tail loop))
 287   (dolist (exit (loop-exits loop))
 288     (check-loop-block exit loop))
 289   (check-loop-block (loop-head loop) loop)
 290   (unless (eq (block-loop (loop-head loop)) loop)
 291     (barf "The head of ~S is not directly in the loop." loop))
 292
 293   (do ((block (loop-blocks loop) (block-loop-next block)))
 294       ((null block))
 295     (setf (block-flag block) t)
 296     (unless (gethash block *seen-blocks*)
 297       (barf "unseen block ~S in Blocks for ~S" block loop))
 298     (unless (eq (block-loop block) loop)
 299       (barf "wrong loop in ~S, should be ~S" block loop)))
 300
 301   (dolist (inferior (loop-inferiors loop))
 302     (check-loop-consistency inferior loop))
 303   (values))
 304
 305 ;;; Check that Block is either in Loop or an inferior.
 306 (declaim (ftype (function (block loop) (values)) check-loop-block))
 307 (defun check-loop-block (block loop)
 308   (unless (gethash block *seen-blocks*)
 309     (barf "unseen block ~S in loop info for ~S" block loop))
 310   (labels ((walk (l)
 311              (if (eq (block-loop block) l)
 312                  t
 313                  (dolist (inferior (loop-inferiors l) nil)
 314                    (when (walk inferior) (return t))))))
 315     (unless (walk loop)
 316       (barf "~S is in loop info for ~S but not in the loop." block loop)))
 317   (values))
 318
 319 |#
 320
 321 ;;; Check a block for consistency at the general flow-graph level, and
 322 ;;; call CHECK-NODE-CONSISTENCY on each node to locally check for
 323 ;;; semantic consistency.
 324 (declaim (ftype (function (cblock) (values)) check-block-consistency))
 325 (defun check-block-consistency (block)
 326
 327   (dolist (pred (block-pred block))
 328     (unless (gethash pred *seen-blocks*)
 329       (barf "unseen predecessor ~S in ~S" pred block))
 330     (unless (member block (block-succ pred))
 331       (barf "bad predecessor link ~S in ~S" pred block)))
 332
 333   (let* ((fun (block-home-lambda block))
 334          (fun-deleted (eq (functional-kind fun) :deleted))
 335          (this-cont (block-start block))
 336          (last (block-last block)))
 337     (unless fun-deleted
 338       (check-fun-reached fun block))
 339     (when (not this-cont)
 340       (barf "~S has no START." block))
 341     (when (not last)
 342       (barf "~S has no LAST." block))
 343     (unless (eq (continuation-kind this-cont) :block-start)
 344       (barf "The START of ~S has the wrong kind." block))
 345
 346     (let ((use (continuation-use this-cont))
 347           (uses (block-start-uses block)))
 348       (when (and (null use) (= (length uses) 1))
 349         (barf "~S has a unique use, but no USE." this-cont))
 350       (dolist (node uses)
 351         (unless (eq (node-cont node) this-cont)
 352           (barf "The USE ~S for START in ~S has wrong CONT." node block))
 353         (check-node-reached node)))
 354
 355     (let* ((last-cont (node-cont last))
 356            (cont-block (continuation-block last-cont))
 357            (dest (continuation-dest last-cont)))
 358       (ecase (continuation-kind last-cont)
 359         (:deleted)
 360         (:deleted-block-start
 361          (let ((dest (continuation-dest last-cont)))
 362            (when dest
 363              (check-node-reached dest)))
 364          (unless (member last (block-start-uses cont-block))
 365            (barf "LAST in ~S is missing from uses of its Cont." block)))
 366         (:block-start
 367          (check-node-reached (continuation-next last-cont))
 368          (unless (member last (block-start-uses cont-block))
 369            (barf "LAST in ~S is missing from uses of its Cont." block)))
 370         (:inside-block
 371          (unless (eq cont-block block)
 372            (barf "CONT of LAST in ~S is in a different BLOCK." block))
 373          (unless (eq (continuation-use last-cont) last)
 374            (barf "USE is not LAST in CONT of LAST in ~S." block))
 375          (when (continuation-next last-cont)
 376            (barf "CONT of LAST has a NEXT in ~S." block))))
 377
 378       (when dest
 379         (check-node-reached dest)))
 380
 381     (loop
 382       (unless (eq (continuation-block this-cont) block)
 383         (barf "BLOCK in ~S should be ~S." this-cont block))
 384
 385       (let ((dest (continuation-dest this-cont)))
 386         (when dest
 387           (check-node-reached dest)))
 388
 389       (let ((node (continuation-next this-cont)))
 390         (unless (node-p node)
 391           (barf "~S has strange NEXT." this-cont))
 392         (unless (eq (node-prev node) this-cont)
 393           (barf "PREV in ~S should be ~S." node this-cont))
 394
 395         (unless fun-deleted
 396           (check-node-consistency node))
 397
 398         (let ((cont (node-cont node)))
 399           (when (not cont)
 400             (barf "~S has no CONT." node))
 401           (when (eq node last) (return))
 402           (unless (eq (continuation-kind cont) :inside-block)
 403             (barf "The interior continuation ~S in ~S has the wrong kind."
 404                   cont
 405                   block))
 406           (unless (continuation-next cont)
 407             (barf "~S has no NEXT." cont))
 408           (unless (eq (continuation-use cont) node)
 409             (barf "USE in ~S should be ~S." cont node))
 410           (setq this-cont cont))))
 411
 412     (check-block-successors block))
 413   (values))
 414
 415 ;;; Check that BLOCK is properly terminated. Each successor must be
 416 ;;; accounted for by the type of the last node.
 417 (declaim (ftype (function (cblock) (values)) check-block-successors))
 418 (defun check-block-successors (block)
 419   (let ((last (block-last block))
 420         (succ (block-succ block)))
 421
 422     (let* ((comp (block-component block)))
 423       (dolist (b succ)
 424         (unless (gethash b *seen-blocks*)
 425           (barf "unseen successor ~S in ~S" b block))
 426         (unless (member block (block-pred b))
 427           (barf "bad successor link ~S in ~S" b block))
 428         (unless (eq (block-component b) comp)
 429           (barf "The successor ~S in ~S is in a different component."
 430                 b
 431                 block))))
 432
 433     (typecase last
 434       (cif
 435        (unless (proper-list-of-length-p succ 1 2)
 436          (barf "~S ends in an IF, but doesn't have one or two succesors."
 437                block))
 438        (unless (member (if-consequent last) succ)
 439          (barf "The CONSEQUENT for ~S isn't in SUCC for ~S." last block))
 440        (unless (member (if-alternative last) succ)
 441          (barf "The ALTERNATIVE for ~S isn't in SUCC for ~S." last block)))
 442       (creturn
 443        (unless (if (eq (functional-kind (return-lambda last)) :deleted)
 444                    (null succ)
 445                    (and (= (length succ) 1)
 446                         (eq (first succ)
 447                             (component-tail (block-component block)))))
 448          (barf "strange successors for RETURN in ~S" block)))
 449       (exit
 450        (unless (proper-list-of-length-p succ 0 1)
 451          (barf "EXIT node with strange number of successors: ~S" last)))
 452       (t
 453        (unless (or (= (length succ) 1) (node-tail-p last)
 454                    (and (block-delete-p block) (null succ)))
 455          (barf "~S ends in normal node, but doesn't have one successor."
 456                block)))))
 457   (values))
 458 \f
 459 ;;;; node consistency checking
 460
 461 ;;; Check that the DEST for CONT is the specified NODE. We also mark
 462 ;;; the block CONT is in as SEEN.
 463 (declaim (ftype (function (continuation node) (values)) check-dest))
 464 (defun check-dest (cont node)
 465   (let ((kind (continuation-kind cont)))
 466     (ecase kind
 467       (:deleted
 468        (unless (block-delete-p (node-block node))
 469          (barf "DEST ~S of deleted continuation ~S is not DELETE-P."
 470                cont node)))
 471       (:deleted-block-start
 472        (unless (eq (continuation-dest cont) node)
 473          (barf "DEST for ~S should be ~S." cont node)))
 474       ((:inside-block :block-start)
 475        (unless (gethash (continuation-block cont) *seen-blocks*)
 476          (barf "~S receives ~S, which is in an unknown block." node cont))
 477        (unless (eq (continuation-dest cont) node)
 478          (barf "DEST for ~S should be ~S." cont node))
 479        (unless (find-uses cont)
 480          (barf "Continuation ~S has a destinatin, but no uses."
 481                cont)))))
 482   (values))
 483
 484 ;;; This function deals with checking for consistency of the
 485 ;;; type-dependent information in a node.
 486 (defun check-node-consistency (node)
 487   (declare (type node node))
 488   (etypecase node
 489     (ref
 490      (let ((leaf (ref-leaf node)))
 491        (when (functional-p leaf)
 492          (if (eq (functional-kind leaf) :toplevel-xep)
 493              (unless (eq (component-kind (block-component (node-block node)))
 494                          :toplevel)
 495                (barf ":TOPLEVEL-XEP ref in non-top-level component: ~S"
 496                      node))
 497              (check-fun-reached leaf node)))))
 498     (basic-combination
 499      (check-dest (basic-combination-fun node) node)
 500      (dolist (arg (basic-combination-args node))
 501        (cond
 502          (arg (check-dest arg node))
 503          ((not (and (eq (basic-combination-kind node) :local)
 504                     (combination-p node)))
 505           (barf "flushed arg not in local call: ~S" node))
 506          (t
 507           (locally
 508               ;; KLUDGE: In sbcl-0.6.11.37, the compiler doesn't like
 509               ;; (DECLARE (TYPE INDEX POS)) after the inline expansion of
 510               ;; POSITION. It compiles it correctly, but it issues a type
 511               ;; mismatch warning because it can't eliminate the
 512               ;; possibility that control will flow through the
 513               ;; NIL-returning branch. So we punt here. -- WHN 2001-04-15
 514               (declare (notinline position))
 515             (let ((fun (ref-leaf (continuation-use
 516                                   (basic-combination-fun node))))
 517                   (pos (position arg (basic-combination-args node))))
 518               (declare (type index pos))
 519               (when (leaf-refs (elt (lambda-vars fun) pos))
 520                 (barf "flushed arg for referenced var in ~S" node)))))))
 521      (let ((dest (continuation-dest (node-cont node))))
 522        (when (and (return-p dest)
 523                   (eq (basic-combination-kind node) :local)
 524                   (not (eq (lambda-tail-set (combination-lambda node))
 525                            (lambda-tail-set (return-lambda dest)))))
 526          (barf "tail local call to function with different tail set:~%  ~S"
 527                node))))
 528     (cif
 529      (check-dest (if-test node) node)
 530      (unless (eq (block-last (node-block node)) node)
 531        (barf "IF not at block end: ~S" node)))
 532     (cset
 533      (check-dest (set-value node) node))
 534     (cast
 535      (check-dest (cast-value node) node))
 536     (bind
 537      (check-fun-reached (bind-lambda node) node))
 538     (creturn
 539      (check-fun-reached (return-lambda node) node)
 540      (check-dest (return-result node) node)
 541      (unless (eq (block-last (node-block node)) node)
 542        (barf "RETURN not at block end: ~S" node)))
 543     (entry
 544      (unless (member node (lambda-entries (node-home-lambda node)))
 545        (barf "~S is not in ENTRIES for its home LAMBDA." node))
 546      (dolist (exit (entry-exits node))
 547        (unless (node-deleted exit)
 548          (check-node-reached node))))
 549     (exit
 550      (let ((entry (exit-entry node))
 551            (value (exit-value node)))
 552        (cond (entry
 553               (check-node-reached entry)
 554               (unless (member node (entry-exits entry))
 555                 (barf "~S is not in its ENTRY's EXITS." node))
 556               (when value
 557                 (check-dest value node)))
 558              (t
 559               (when value
 560                 (barf "~S has VALUE but no ENTRY." node)))))))
 561
 562   (values))
 563 \f
 564 ;;;; IR2 consistency checking
 565
 566 ;;; Check for some kind of consistency in some REFs linked together by
 567 ;;; TN-REF-ACROSS. VOP is the VOP that the references are in. WRITE-P
 568 ;;; is the value of WRITE-P that should be present. COUNT is the
 569 ;;; minimum number of operands expected. If MORE-P is true, then any
 570 ;;; larger number will also be accepted. WHAT is a string describing
 571 ;;; the kind of operand in error messages.
 572 (defun check-tn-refs (refs vop write-p count more-p what)
 573   (let ((vop-refs (vop-refs vop)))
 574     (do ((ref refs (tn-ref-across ref))
 575          (num 0 (1+ num)))
 576         ((null ref)
 577          (when (< num count)
 578            (barf "There should be at least ~W ~A in ~S, but there are only ~W."
 579                  count what vop num))
 580          (when (and (not more-p) (> num count))
 581            (barf "There should be ~W ~A in ~S, but are ~W."
 582                  count what vop num)))
 583       (unless (eq (tn-ref-vop ref) vop)
 584         (barf "VOP is ~S isn't ~S." ref vop))
 585       (unless (eq (tn-ref-write-p ref) write-p)
 586         (barf "The WRITE-P in ~S isn't ~S." vop write-p))
 587       (unless (find-in #'tn-ref-next-ref ref vop-refs)
 588         (barf "~S not found in REFS for ~S" ref vop))
 589       (unless (find-in #'tn-ref-next ref
 590                        (if (tn-ref-write-p ref)
 591                            (tn-writes (tn-ref-tn ref))
 592                            (tn-reads (tn-ref-tn ref))))
 593         (barf "~S not found in reads/writes for its TN" ref))
 594
 595       (let ((target (tn-ref-target ref)))
 596         (when target
 597           (unless (eq (tn-ref-write-p target) (not (tn-ref-write-p ref)))
 598             (barf "The target for ~S isn't complementary WRITE-P." ref))
 599           (unless (find-in #'tn-ref-next-ref target vop-refs)
 600             (barf "The target for ~S isn't in REFS for ~S." ref vop)))))))
 601
 602 ;;; Verify the sanity of the VOP-REFS slot in VOP. This involves checking
 603 ;;; that each referenced TN appears as an argument, result or temp, and also
 604 ;;; basic checks for the plausibility of the specified ordering of the refs.
 605 (defun check-vop-refs (vop)
 606   (declare (type vop vop))
 607   (do ((ref (vop-refs vop) (tn-ref-next-ref ref)))
 608       ((null ref))
 609     (cond
 610      ((find-in #'tn-ref-across ref (vop-args vop)))
 611      ((find-in #'tn-ref-across ref (vop-results vop)))
 612      ((not (eq (tn-ref-vop ref) vop))
 613       (barf "VOP in ~S isn't ~S." ref vop))
 614      ((find-in #'tn-ref-across ref (vop-temps vop)))
 615      ((tn-ref-write-p ref)
 616       (barf "stray ref that isn't a READ: ~S" ref))
 617      (t
 618       (let* ((tn (tn-ref-tn ref))
 619              (temp (find-in #'tn-ref-across tn (vop-temps vop)
 620                             :key #'tn-ref-tn)))
 621         (unless temp
 622           (barf "stray ref with no corresponding temp write: ~S" ref))
 623         (unless (find-in #'tn-ref-next-ref temp (tn-ref-next-ref ref))
 624           (barf "Read is after write for temp ~S in refs of ~S."
 625                 tn vop))))))
 626   (values))
 627
 628 ;;; Check the basic sanity of the VOP linkage, then call some other
 629 ;;; functions to check on the TN-REFS. We grab some info out of the
 630 ;;; VOP-INFO to tell us what to expect.
 631 ;;;
 632 ;;; [### Check that operand type restrictions are met?]
 633 (defun check-ir2-block-consistency (2block)
 634   (declare (type ir2-block 2block))
 635   (do ((vop (ir2-block-start-vop 2block)
 636             (vop-next vop))
 637        (prev nil vop))
 638       ((null vop)
 639        (unless (eq prev (ir2-block-last-vop 2block))
 640          (barf "The last VOP in ~S should be ~S." 2block prev)))
 641     (unless (eq (vop-prev vop) prev)
 642       (barf "PREV in ~S should be ~S." vop prev))
 643
 644     (unless (eq (vop-block vop) 2block)
 645       (barf "BLOCK in ~S should be ~S." vop 2block))
 646
 647     (check-vop-refs vop)
 648
 649     (let* ((info (vop-info vop))
 650            (atypes (template-arg-types info))
 651            (rtypes (template-result-types info)))
 652       (check-tn-refs (vop-args vop) vop nil
 653                      (count-if-not (lambda (x)
 654                                      (and (consp x)
 655                                           (eq (car x) :constant)))
 656                                    atypes)
 657                      (template-more-args-type info) "args")
 658       (check-tn-refs (vop-results vop) vop t
 659                      (if (eq rtypes :conditional) 0 (length rtypes))
 660                      (template-more-results-type info) "results")
 661       (check-tn-refs (vop-temps vop) vop t 0 t "temps")
 662       (unless (= (length (vop-codegen-info vop))
 663                  (template-info-arg-count info))
 664         (barf "wrong number of codegen info args in ~S" vop))))
 665   (values))
 666
 667 ;;; Check stuff about the IR2 representation of COMPONENT. This assumes the
 668 ;;; sanity of the basic flow graph.
 669 ;;;
 670 ;;; [### Also grovel global TN data structures?  Assume pack not
 671 ;;; done yet?  Have separate CHECK-TN-CONSISTENCY for pre-pack and
 672 ;;; CHECK-PACK-CONSISTENCY for post-pack?]
 673 (defun check-ir2-consistency (component)
 674   (declare (type component component))
 675   (do-ir2-blocks (block component)
 676     (check-ir2-block-consistency block))
 677   (values))
 678 \f
 679 ;;;; lifetime analysis checking
 680
 681 ;;; Dump some info about how many TNs there, and what the conflicts data
 682 ;;; structures are like.
 683 (defun pre-pack-tn-stats (component &optional (stream *error-output*))
 684   (declare (type component component))
 685   (let ((wired 0)
 686         (global 0)
 687         (local 0)
 688         (confs 0)
 689         (unused 0)
 690         (const 0)
 691         (temps 0)
 692         (environment 0)
 693         (comp 0))
 694     (do-packed-tns (tn component)
 695       (let ((reads (tn-reads tn))
 696             (writes (tn-writes tn)))
 697         (when (and reads writes
 698                    (not (tn-ref-next reads)) (not (tn-ref-next writes))
 699                    (eq (tn-ref-vop reads) (tn-ref-vop writes)))
 700           (incf temps)))
 701       (when (tn-offset tn)
 702         (incf wired))
 703       (unless (or (tn-reads tn) (tn-writes tn))
 704         (incf unused))
 705       (cond ((eq (tn-kind tn) :component)
 706              (incf comp))
 707             ((tn-global-conflicts tn)
 708              (case (tn-kind tn)
 709                ((:environment :debug-environment) (incf environment))
 710                (t (incf global)))
 711              (do ((conf (tn-global-conflicts tn)
 712                         (global-conflicts-next-tnwise conf)))
 713                  ((null conf))
 714                (incf confs)))
 715             (t
 716              (incf local))))
 717
 718     (do ((tn (ir2-component-constant-tns (component-info component))
 719              (tn-next tn)))
 720         ((null tn))
 721       (incf const))
 722
 723     (format stream
 724      "~%TNs: ~W local, ~W temps, ~W constant, ~W env, ~W comp, ~W global.~@
 725        Wired: ~W, Unused: ~W. ~W block~:P, ~W global conflict~:P.~%"
 726        local temps const environment comp global wired unused
 727        (ir2-block-count component)
 728        confs))
 729   (values))
 730
 731 ;;; If the entry in Local-TNs for TN in BLOCK is :MORE, then do some checks
 732 ;;; for the validity of the usage.
 733 (defun check-more-tn-entry (tn block)
 734   (let* ((vop (ir2-block-start-vop block))
 735          (info (vop-info vop)))
 736     (macrolet ((frob (more-p ops)
 737                  `(and (,more-p info)
 738                        (find-in #'tn-ref-across tn (,ops vop)
 739                                 :key #'tn-ref-tn))))
 740       (unless (and (eq vop (ir2-block-last-vop block))
 741                    (or (frob template-more-args-type vop-args)
 742                        (frob template-more-results-type vop-results)))
 743         (barf "strange :MORE LTN entry for ~S in ~S" tn block))))
 744   (values))
 745
 746 (defun check-tn-conflicts (component)
 747   (do-packed-tns (tn component)
 748     (unless (or (not (eq (tn-kind tn) :normal))
 749                 (tn-reads tn)
 750                 (tn-writes tn))
 751       (barf "no references to ~S" tn))
 752
 753     (unless (tn-sc tn) (barf "~S has no SC." tn))
 754
 755     (let ((conf (tn-global-conflicts tn))
 756           (kind (tn-kind tn)))
 757       (cond
 758        ((eq kind :component)
 759         (unless (member tn (ir2-component-component-tns
 760                             (component-info component)))
 761           (barf "~S not in COMPONENT-TNs for ~S" tn component)))
 762        (conf
 763         (do ((conf conf (global-conflicts-next-tnwise conf))
 764              (prev nil conf))
 765             ((null conf))
 766           (unless (eq (global-conflicts-tn conf) tn)
 767             (barf "TN in ~S should be ~S." conf tn))
 768
 769           (unless (eq (global-conflicts-kind conf) :live)
 770             (let* ((block (global-conflicts-block conf))
 771                    (ltn (svref (ir2-block-local-tns block)
 772                                (global-conflicts-number conf))))
 773               (cond ((eq ltn tn))
 774                     ((eq ltn :more) (check-more-tn-entry tn block))
 775                     (t
 776                      (barf "~S wrong in LTN map for ~S" conf tn)))))
 777
 778           (when prev
 779             (unless (> (ir2-block-number (global-conflicts-block conf))
 780                        (ir2-block-number (global-conflicts-block prev)))
 781               (barf "~s and ~s out of order" prev conf)))))
 782        ((member (tn-kind tn) '(:constant :specified-save)))
 783        (t
 784         (let ((local (tn-local tn)))
 785           (unless local
 786             (barf "~S has no global conflicts, but isn't local either." tn))
 787           (unless (eq (svref (ir2-block-local-tns local)
 788                              (tn-local-number tn))
 789                       tn)
 790             (barf "~S wrong in LTN map" tn))
 791           (do ((ref (tn-reads tn) (tn-ref-next ref)))
 792               ((null ref))
 793             (unless (eq (vop-block (tn-ref-vop ref)) local)
 794               (barf "~S has references in blocks other than its LOCAL block."
 795                     tn)))
 796           (do ((ref (tn-writes tn) (tn-ref-next ref)))
 797               ((null ref))
 798             (unless (eq (vop-block (tn-ref-vop ref)) local)
 799               (barf "~S has references in blocks other than its LOCAL block."
 800                     tn))))))))
 801   (values))
 802
 803 (defun check-block-conflicts (component)
 804   (do-ir2-blocks (block component)
 805     (do ((conf (ir2-block-global-tns block)
 806                (global-conflicts-next-blockwise conf))
 807          (prev nil conf))
 808         ((null conf))
 809       (when prev
 810         (unless (> (tn-number (global-conflicts-tn conf))
 811                    (tn-number (global-conflicts-tn prev)))
 812           (barf "~S and ~S out of order in ~S" prev conf block)))
 813
 814       (unless (find-in #'global-conflicts-next-tnwise
 815                        conf
 816                        (tn-global-conflicts
 817                         (global-conflicts-tn conf)))
 818         (barf "~S missing from global conflicts of its TN" conf)))
 819
 820     (let ((map (ir2-block-local-tns block)))
 821       (dotimes (i (ir2-block-local-tn-count block))
 822         (let ((tn (svref map i)))
 823           (unless (or (eq tn :more)
 824                       (null tn)
 825                       (tn-global-conflicts tn)
 826                       (eq (tn-local tn) block))
 827             (barf "strange TN ~S in LTN map for ~S" tn block)))))))
 828
 829 ;;; All TNs live at the beginning of an environment must be passing
 830 ;;; locations associated with that environment. We make an exception
 831 ;;; for wired TNs in XEP functions, since we randomly reference wired
 832 ;;; TNs to access the full call passing locations.
 833 (defun check-environment-lifetimes (component)
 834   (dolist (fun (component-lambdas component))
 835     (let* ((env (lambda-physenv fun))
 836            (2env (physenv-info env))
 837            (vars (lambda-vars fun))
 838            (closure (ir2-physenv-closure 2env))
 839            (pc (ir2-physenv-return-pc-pass 2env))
 840            (fp (ir2-physenv-old-fp 2env))
 841            (2block (block-info (lambda-block (physenv-lambda env)))))
 842       (do ((conf (ir2-block-global-tns 2block)
 843                  (global-conflicts-next-blockwise conf)))
 844           ((null conf))
 845         (let ((tn (global-conflicts-tn conf)))
 846           (unless (or (eq (global-conflicts-kind conf) :write)
 847                       (eq tn pc)
 848                       (eq tn fp)
 849                       (and (xep-p fun) (tn-offset tn))
 850                       (member (tn-kind tn) '(:environment :debug-environment))
 851                       (member tn vars :key #'leaf-info)
 852                       (member tn closure :key #'cdr))
 853             (barf "strange TN live at head of ~S: ~S" env tn))))))
 854   (values))
 855
 856 ;;; Check for some basic sanity in the TN conflict data structures,
 857 ;;; and also check that no TNs are unexpectedly live at environment
 858 ;;; entry.
 859 (defun check-life-consistency (component)
 860   (check-tn-conflicts component)
 861   (check-block-conflicts component)
 862   (check-environment-lifetimes component))
 863 \f
 864 ;;;; pack consistency checking
 865
 866 (defun check-pack-consistency (component)
 867   (flet ((check (scs ops)
 868            (do ((scs scs (cdr scs))
 869                 (op ops (tn-ref-across op)))
 870                ((null scs))
 871              (let ((load-tn (tn-ref-load-tn op)))
 872                (unless (eq (svref (car scs)
 873                                   (sc-number
 874                                    (tn-sc
 875                                     (or load-tn (tn-ref-tn op)))))
 876                            t)
 877                  (barf "operand restriction not satisfied: ~S" op))))))
 878     (do-ir2-blocks (block component)
 879       (do ((vop (ir2-block-last-vop block) (vop-prev vop)))
 880           ((null vop))
 881         (let ((info (vop-info vop)))
 882           (check (vop-info-result-load-scs info) (vop-results vop))
 883           (check (vop-info-arg-load-scs info) (vop-args vop))))))
 884   (values))
 885 \f
 886 ;;;; data structure dumping routines
 887
 888 ;;; When we print CONTINUATIONs and TNs, we assign them small numeric
 889 ;;; IDs so that we can get a handle on anonymous objects given a
 890 ;;; printout.
 891 ;;;
 892 ;;; FIXME:
 893 ;;;   * Perhaps this machinery should be #!+SB-SHOW.
 894 ;;;   * Probably the hash tables should either be weak hash tables,
 895 ;;;     or only allocated within a single compilation unit. Otherwise
 896 ;;;     there will be a tendency for them to grow without bound and
 897 ;;;     keep garbage from being collected.
 898 (macrolet ((def (counter vto vfrom fto ffrom)
 899              `(progn
 900                 (declaim (type hash-table ,vto ,vfrom))
 901                 (defvar ,vto (make-hash-table :test 'eq))
 902                 (defvar ,vfrom (make-hash-table :test 'eql))
 903                 (declaim (type fixnum ,counter))
 904                 (defvar ,counter 0)
 905
 906                 (defun ,fto (x)
 907                   (or (gethash x ,vto)
 908                       (let ((num (incf ,counter)))
 909                         (setf (gethash num ,vfrom) x)
 910                         (setf (gethash x ,vto) num))))
 911
 912                 (defun ,ffrom (num)
 913                   (values (gethash num ,vfrom))))))
 914   (def *continuation-number* *continuation-numbers* *number-continuations*
 915        cont-num num-cont)
 916   (def *tn-id* *tn-ids* *id-tns* tn-id id-tn)
 917   (def *label-id* *id-labels* *label-ids* label-id id-label))
 918
 919 ;;; Print a terse one-line description of LEAF.
 920 (defun print-leaf (leaf &optional (stream *standard-output*))
 921   (declare (type leaf leaf) (type stream stream))
 922   (etypecase leaf
 923     (lambda-var (prin1 (leaf-debug-name leaf) stream))
 924     (constant (format stream "'~S" (constant-value leaf)))
 925     (global-var
 926      (format stream "~S {~A}" (leaf-debug-name leaf) (global-var-kind leaf)))
 927     (functional
 928      (format stream "~S ~S" (type-of leaf) (functional-debug-name leaf)))))
 929
 930 ;;; Attempt to find a block given some thing that has to do with it.
 931 (declaim (ftype (sfunction (t) cblock) block-or-lose))
 932 (defun block-or-lose (thing)
 933   (ctypecase thing
 934     (cblock thing)
 935     (ir2-block (ir2-block-block thing))
 936     (vop (block-or-lose (vop-block thing)))
 937     (tn-ref (block-or-lose (tn-ref-vop thing)))
 938     (continuation (continuation-block thing))
 939     (node (node-block thing))
 940     (component (component-head thing))
 941 #|    (cloop (loop-head thing))|#
 942     (integer (continuation-block (num-cont thing)))
 943     (functional (lambda-block (main-entry thing)))
 944     (null (error "Bad thing: ~S." thing))
 945     (symbol (block-or-lose (gethash thing *free-funs*)))))
 946
 947 ;;; Print cN.
 948 (defun print-continuation (cont)
 949   (declare (type continuation cont))
 950   (format t " c~D" (cont-num cont))
 951   (values))
 952
 953 ;;; Print out the nodes in BLOCK in a format oriented toward
 954 ;;; representing what the code does.
 955 (defun print-nodes (block)
 956   (setq block (block-or-lose block))
 957   (pprint-logical-block (nil nil)
 958     (format t "~:@_IR1 block ~D start c~D"
 959            (block-number block) (cont-num (block-start block)))
 960     (when (block-delete-p block)
 961       (format t " <deleted>"))
 962
 963     (let ((last (block-last block)))
 964      (pprint-newline :mandatory)
 965      (do ((cont (block-start block) (node-cont (continuation-next cont))))
 966          ((not cont))
 967        (let ((node (continuation-next cont)))
 968          (format t "~3D: " (cont-num (node-cont node)))
 969          (etypecase node
 970            (ref (print-leaf (ref-leaf node)))
 971            (basic-combination
 972             (let ((kind (basic-combination-kind node)))
 973               (format t "~(~A~A ~A~) c~D"
 974                       (if (node-tail-p node) "tail " "")
 975                       (if (fun-info-p kind) "known" kind)
 976                       (type-of node)
 977                       (cont-num (basic-combination-fun node)))
 978               (dolist (arg (basic-combination-args node))
 979                 (if arg
 980                     (print-continuation arg)
 981                     (format t " <none>")))))
 982            (cset
 983             (write-string "set ")
 984             (print-leaf (set-var node))
 985             (print-continuation (set-value node)))
 986            (cif
 987             (format t "if c~D" (cont-num (if-test node)))
 988             (print-continuation (block-start (if-consequent node)))
 989             (print-continuation (block-start (if-alternative node))))
 990            (bind
 991             (write-string "bind ")
 992             (print-leaf (bind-lambda node))
 993             (when (functional-kind (bind-lambda node))
 994               (format t " ~S ~S" :kind (functional-kind (bind-lambda node)))))
 995            (creturn
 996             (format t "return c~D " (cont-num (return-result node)))
 997             (print-leaf (return-lambda node)))
 998            (entry
 999             (format t "entry ~S" (entry-exits node)))
1000            (exit
1001             (let ((value (exit-value node)))
1002               (cond (value
1003                      (format t "exit c~D" (cont-num value)))
1004                     ((exit-entry node)
1005                      (format t "exit <no value>"))
1006                     (t
1007                      (format t "exit <degenerate>")))))
1008            (cast
1009             (let ((value (cast-value node)))
1010               (format t "cast c~D ~A[~S -> ~S]" (cont-num value)
1011                       (if (cast-%type-check node) #\+ #\-)
1012                       (cast-type-to-check node)
1013                       (cast-asserted-type node)))))
1014          (pprint-newline :mandatory)
1015          (when (eq node last) (return)))))
1016
1017    (let ((succ (block-succ block)))
1018      (format t "successors~{ c~D~}~%"
1019              (mapcar (lambda (x) (cont-num (block-start x))) succ))))
1020   (values))
1021
1022 ;;; Print the guts of a TN. (logic shared between PRINT-OBJECT (TN T)
1023 ;;; and printers for compound objects which contain TNs)
1024 (defun print-tn-guts (tn &optional (stream *standard-output*))
1025   (declare (type tn tn))
1026   (let ((leaf (tn-leaf tn)))
1027     (cond (leaf
1028            (print-leaf leaf stream)
1029            (format stream "!~D" (tn-id tn)))
1030           (t
1031            (format stream "t~D" (tn-id tn))))
1032     (when (and (tn-sc tn) (tn-offset tn))
1033       (format stream "[~A]" (location-print-name tn)))))
1034
1035 ;;; Print the TN-REFs representing some operands to a VOP, linked by
1036 ;;; TN-REF-ACROSS.
1037 (defun print-operands (refs)
1038   (declare (type (or tn-ref null) refs))
1039   (pprint-logical-block (*standard-output* nil)
1040     (do ((ref refs (tn-ref-across ref)))
1041         ((null ref))
1042       (let ((tn (tn-ref-tn ref))
1043             (ltn (tn-ref-load-tn ref)))
1044         (cond ((not ltn)
1045                (print-tn-guts tn))
1046               (t
1047                (print-tn-guts tn)
1048                (princ (if (tn-ref-write-p ref) #\< #\>))
1049                (print-tn-guts ltn)))
1050         (princ #\space)
1051         (pprint-newline :fill)))))
1052
1053 ;;; Print the VOP, putting args, info and results on separate lines, if
1054 ;;; necessary.
1055 (defun print-vop (vop)
1056   (pprint-logical-block (*standard-output* nil)
1057     (princ (vop-info-name (vop-info vop)))
1058     (princ #\space)
1059     (pprint-indent :current 0)
1060     (print-operands (vop-args vop))
1061     (pprint-newline :linear)
1062     (when (vop-codegen-info vop)
1063       (princ (with-output-to-string (stream)
1064                (let ((*print-level* 1)
1065                      (*print-length* 3))
1066                  (format stream "{~{~S~^ ~}} " (vop-codegen-info vop)))))
1067       (pprint-newline :linear))
1068     (when (vop-results vop)
1069       (princ "=> ")
1070       (print-operands (vop-results vop))))
1071   (pprint-newline :mandatory))
1072
1073 ;;; Print the VOPs in the specified IR2 block.
1074 (defun print-ir2-block (block)
1075   (declare (type ir2-block block))
1076   (pprint-logical-block (*standard-output* nil)
1077     (cond
1078       ((eq (block-info (ir2-block-block block)) block)
1079        (format t "~:@_IR2 block ~D start c~D~:@_"
1080                (ir2-block-number block)
1081                (cont-num (block-start (ir2-block-block block))))
1082        (let ((label (ir2-block-%label block)))
1083          (when label
1084            (format t "L~D:~:@_" (label-id label)))))
1085       (t
1086        (format t "<overflow>~:@_")))
1087
1088     (do ((vop (ir2-block-start-vop block)
1089               (vop-next vop))
1090          (number 0 (1+ number)))
1091         ((null vop))
1092       (format t "~W: " number)
1093       (print-vop vop))))
1094
1095 ;;; This is like PRINT-NODES, but dumps the IR2 representation of the
1096 ;;; code in BLOCK.
1097 (defun print-vops (block)
1098   (setq block (block-or-lose block))
1099   (let ((2block (block-info block)))
1100     (print-ir2-block 2block)
1101     (do ((b (ir2-block-next 2block) (ir2-block-next b)))
1102         ((not (eq (ir2-block-block b) block)))
1103       (print-ir2-block b)))
1104   (values))
1105
1106 ;;; Scan the IR2 blocks in emission order.
1107 (defun print-ir2-blocks (thing &optional full)
1108   (let* ((block (component-head (block-component (block-or-lose thing))))
1109          (2block (block-info block)))
1110     (pprint-logical-block (nil nil)
1111       (loop while 2block
1112          do (setq block (ir2-block-block 2block))
1113          do (pprint-logical-block (*standard-output* nil)
1114               (if full
1115                   (print-nodes block)
1116                   (format t "IR1 block ~D start c~D"
1117                           (block-number block)
1118                           (cont-num (block-start block))))
1119               (pprint-indent :block 4)
1120               (pprint-newline :mandatory)
1121               (loop while (and 2block (eq (ir2-block-block 2block) block))
1122                  do (print-ir2-block 2block)
1123                  do (setq 2block (ir2-block-next 2block))))
1124          do (pprint-newline :mandatory))))
1125   (values))
1126
1127 ;;; Do a PRINT-NODES on BLOCK and all blocks reachable from it by
1128 ;;; successor links.
1129 (defun print-blocks (block)
1130   (setq block (block-or-lose block))
1131   (do-blocks (block (block-component block) :both)
1132     (setf (block-flag block) nil))
1133   (labels ((walk (block)
1134              (unless (block-flag block)
1135                (setf (block-flag block) t)
1136                (when (block-start block)
1137                  (print-nodes block))
1138                (dolist (block (block-succ block))
1139                  (walk block)))))
1140     (walk block))
1141   (values))
1142
1143 ;;; Print all blocks in BLOCK's component in DFO.
1144 (defun print-all-blocks (thing)
1145   (do-blocks (block (block-component (block-or-lose thing)))
1146     (handler-case (print-nodes block)
1147       (error (condition)
1148         (format t "~&~A...~%" condition))))
1149   (values))
1150
1151 (defvar *list-conflicts-table* (make-hash-table :test 'eq))
1152
1153 ;;; Add all ALWAYS-LIVE TNs in BLOCK to the conflicts. TN is ignored
1154 ;;; when it appears in the global conflicts.
1155 (defun add-always-live-tns (block tn)
1156   (declare (type ir2-block block) (type tn tn))
1157   (do ((conf (ir2-block-global-tns block)
1158              (global-conflicts-next-blockwise conf)))
1159       ((null conf))
1160     (when (eq (global-conflicts-kind conf) :live)
1161       (let ((btn (global-conflicts-tn conf)))
1162         (unless (eq btn tn)
1163           (setf (gethash btn *list-conflicts-table*) t)))))
1164   (values))
1165
1166 ;;; Add all local TNs in BLOCK to the conflicts.
1167 (defun add-all-local-tns (block)
1168   (declare (type ir2-block block))
1169   (let ((ltns (ir2-block-local-tns block)))
1170     (dotimes (i (ir2-block-local-tn-count block))
1171       (setf (gethash (svref ltns i) *list-conflicts-table*) t)))
1172   (values))
1173
1174 ;;; Make a list out of all of the recorded conflicts.
1175 (defun listify-conflicts-table ()
1176   (collect ((res))
1177     (maphash (lambda (k v)
1178                (declare (ignore v))
1179                (when k
1180                  (res k)))
1181              *list-conflicts-table*)
1182     (clrhash *list-conflicts-table*)
1183     (res)))
1184
1185 ;;; Return a list of a the TNs that conflict with TN. Sort of, kind
1186 ;;; of. For debugging use only. Probably doesn't work on :COMPONENT TNs.
1187 (defun list-conflicts (tn)
1188   (aver (member (tn-kind tn) '(:normal :environment :debug-environment)))
1189   (let ((confs (tn-global-conflicts tn)))
1190     (cond (confs
1191            (clrhash *list-conflicts-table*)
1192            (do ((conf confs (global-conflicts-next-tnwise conf)))
1193                ((null conf))
1194              (format t "~&#<block ~D kind ~S>~%"
1195                      (block-number (ir2-block-block (global-conflicts-block
1196                                                      conf)))
1197                      (global-conflicts-kind conf))
1198              (let ((block (global-conflicts-block conf)))
1199                (add-always-live-tns block tn)
1200                (if (eq (global-conflicts-kind conf) :live)
1201                    (add-all-local-tns block)
1202                    (let ((bconf (global-conflicts-conflicts conf))
1203                          (ltns (ir2-block-local-tns block)))
1204                      (dotimes (i (ir2-block-local-tn-count block))
1205                        (when (/= (sbit bconf i) 0)
1206                          (setf (gethash (svref ltns i) *list-conflicts-table*)
1207                                t)))))))
1208            (listify-conflicts-table))
1209           (t
1210            (let* ((block (tn-local tn))
1211                   (ltns (ir2-block-local-tns block))
1212                   (confs (tn-local-conflicts tn)))
1213              (collect ((res))
1214                (dotimes (i (ir2-block-local-tn-count block))
1215                  (when (/= (sbit confs i) 0)
1216                    (let ((tn (svref ltns i)))
1217                      (when (and tn (not (eq tn :more))
1218                                 (not (tn-global-conflicts tn)))
1219                        (res tn)))))
1220                (do ((gtn (ir2-block-global-tns block)
1221                          (global-conflicts-next-blockwise gtn)))
1222                    ((null gtn))
1223                  (when (or (eq (global-conflicts-kind gtn) :live)
1224                            (/= (sbit confs (global-conflicts-number gtn)) 0))
1225                    (res (global-conflicts-tn gtn))))
1226                (res)))))))
1227
1228 (defun nth-vop (thing n)
1229   #!+sb-doc
1230   "Return the Nth VOP in the IR2-BLOCK pointed to by THING."
1231   (let ((block (block-info (block-or-lose thing))))
1232     (do ((i 0 (1+ i))
1233          (vop (ir2-block-start-vop block) (vop-next vop)))
1234         ((= i n) vop))))