src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (missing-arg) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance patholigies with objects for which EQUAL degnerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the ENTRY-INFO structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the ENTRY-INFO structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (missing-arg) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (missing-arg) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to inhibit table access when dumping forms to be read by the
  95 ;;; cold loader
  96 (defvar *cold-load-dump* nil)
  97
  98 ;;; used to turn off the structure validation during dumping of source
  99 ;;; info
 100 (defvar *dump-only-valid-structures* t)
 101 ;;;; utilities
 102
 103 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 104 (defun dump-byte (b fasl-output)
 105   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 106   (write-byte b (fasl-output-stream fasl-output)))
 107
 108 ;;; Dump a 4 byte unsigned integer.
 109 (defun dump-unsigned-32 (num fasl-output)
 110   (declare (type (unsigned-byte 32) num))
 111   (declare (type fasl-output fasl-output))
 112   (let ((stream (fasl-output-stream fasl-output)))
 113     (dotimes (i 4)
 114       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 115
 116 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 117 ;;; for either signed or unsigned integers. There's no range checking
 118 ;;; -- if you don't specify enough bytes for the number to fit, this
 119 ;;; function cheerfully outputs the low bytes.
 120 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 121   (declare (integer num) (type index bytes))
 122   (declare (type fasl-output fasl-output))
 123   (do ((n num (ash n -8))
 124        (i bytes (1- i)))
 125       ((= i 0))
 126     (declare (type index i))
 127     (dump-byte (logand n #xff) fasl-output))
 128   (values))
 129
 130 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 131 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 132 ;;; counter value before every ordinary fop. This can make it easier
 133 ;;; to follow the progress of LOAD-AS-FASL when
 134 ;;; debugging/testing/experimenting.
 135 #!+sb-show (defvar *fop-nop4-count* nil)
 136 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 137
 138 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 139 ;;;
 140 ;;; FIXME: This should be a function, with a compiler macro expansion
 141 ;;; for the common constant-FS case. (Among other things, that'll stop
 142 ;;; it from EVALing ,FILE multiple times.)
 143 ;;;
 144 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 145 ;;; optimizations should be conditional on #!+SB-FROZEN.
 146 (defmacro dump-fop (fs file)
 147   (let* ((fs (eval fs))
 148          (val (get fs 'fop-code)))
 149     (if val
 150       `(progn
 151          #!+sb-show
 152          (when *fop-nop4-count*
 153            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 154            (dump-unsigned-32 (mod (incf *fop-nop4-count*) (expt 2 32)) ,file))
 155          (dump-byte ',val ,file))
 156       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 157
 158 ;;; Dump a FOP-Code along with an integer argument, choosing the FOP
 159 ;;; based on whether the argument will fit in a single byte.
 160 ;;;
 161 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 162 ;;; compiler-macro expansion.
 163 (defmacro dump-fop* (n byte-fop word-fop file)
 164   (once-only ((n-n n)
 165               (n-file file))
 166     `(cond ((< ,n-n 256)
 167             (dump-fop ',byte-fop ,n-file)
 168             (dump-byte ,n-n ,n-file))
 169            (t
 170             (dump-fop ',word-fop ,n-file)
 171             (dump-unsigned-32 ,n-n ,n-file)))))
 172
 173 ;;; Push the object at table offset Handle on the fasl stack.
 174 (defun dump-push (handle fasl-output)
 175   (declare (type index handle) (type fasl-output fasl-output))
 176   (dump-fop* handle fop-byte-push fop-push fasl-output)
 177   (values))
 178
 179 ;;; Pop the object currently on the fasl stack top into the table, and
 180 ;;; return the table index, incrementing the free pointer.
 181 (defun dump-pop (fasl-output)
 182   (prog1
 183       (fasl-output-table-free fasl-output)
 184     (dump-fop 'fop-pop fasl-output)
 185     (incf (fasl-output-table-free fasl-output))))
 186
 187 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 188 ;;; otherwise NIL. If *COLD-LOAD-DUMP* is true, then do nothing and
 189 ;;; return NIL.
 190 (defun equal-check-table (x fasl-output)
 191   (declare (type fasl-output fasl-output))
 192   (unless *cold-load-dump*
 193     (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 194       (cond (handle
 195              (dump-push handle fasl-output)
 196              t)
 197             (t
 198              nil)))))
 199
 200 ;;; These functions are called after dumping an object to save the
 201 ;;; object in the table. The object (also passed in as X) must already
 202 ;;; be on the top of the FOP stack. If *COLD-LOAD-DUMP* is true, then
 203 ;;; we don't do anything.
 204 (defun eq-save-object (x fasl-output)
 205   (declare (type fasl-output fasl-output))
 206   (unless *cold-load-dump*
 207     (let ((handle (dump-pop fasl-output)))
 208       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 209       (dump-push handle fasl-output)))
 210   (values))
 211 (defun equal-save-object (x fasl-output)
 212   (declare (type fasl-output fasl-output))
 213   (unless *cold-load-dump*
 214     (let ((handle (dump-pop fasl-output)))
 215       (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 216       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 217       (dump-push handle fasl-output)))
 218   (values))
 219
 220 ;;; Record X in File's CIRCULARITY-TABLE unless *COLD-LOAD-DUMP* is
 221 ;;; true. This is called on objects that we are about to dump might
 222 ;;; have a circular path through them.
 223 ;;;
 224 ;;; The object must not currently be in this table, since the dumper
 225 ;;; should never be recursively called on a circular reference.
 226 ;;; Instead, the dumping function must detect the circularity and
 227 ;;; arrange for the dumped object to be patched.
 228 (defun note-potential-circularity (x fasl-output)
 229   (unless *cold-load-dump*
 230     (let ((circ (fasl-output-circularity-table fasl-output)))
 231       (aver (not (gethash x circ)))
 232       (setf (gethash x circ) x)))
 233   (values))
 234
 235 ;;; Dump FORM to a fasl file so that it evaluated at load time in normal
 236 ;;; load and at cold-load time in cold load. This is used to dump package
 237 ;;; frobbing forms.
 238 (defun fasl-dump-cold-load-form (form fasl-output)
 239   (declare (type fasl-output fasl-output))
 240   (dump-fop 'fop-normal-load fasl-output)
 241   (let ((*cold-load-dump* t))
 242     (dump-object form fasl-output))
 243   (dump-fop 'fop-eval-for-effect fasl-output)
 244   (dump-fop 'fop-maybe-cold-load fasl-output)
 245   (values))
 246 \f
 247 ;;;; opening and closing fasl files
 248
 249 ;;; A utility function to write strings to (unsigned-byte 8) streams.
 250 ;;; We restrict this to ASCII (with the averrance) because of
 251 ;;; ambiguity of higher bytes: Unicode, some ISO-8859-x, or what? This
 252 ;;; could be revisited in the event of doing funky things with stream
 253 ;;; encodings -- CSR, 2002-04-25
 254 (defun fasl-write-string (string stream)
 255   (loop for char across string
 256         do (let ((code (char-code char)))
 257              (aver (<= 0 code 127))
 258              (write-byte code stream))))
 259
 260 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 261 ;;; object for dumping to it. Some human-readable information about
 262 ;;; the source code is given by the string WHERE. If BYTE-P is true,
 263 ;;; this file will contain no native code, and is thus largely
 264 ;;; implementation independent.
 265 (defun open-fasl-output (name where)
 266   (declare (type pathname name))
 267   (let* ((stream (open name
 268                        :direction :output
 269                        :if-exists :new-version
 270                        :element-type 'sb!assem:assembly-unit))
 271          (res (make-fasl-output :stream stream)))
 272
 273     ;; Begin the header with the constant machine-readable (and
 274     ;; semi-human-readable) string which is used to identify fasl files.
 275     (fasl-write-string *fasl-header-string-start-string* stream)
 276
 277     ;; The constant string which begins the header is followed by
 278     ;; arbitrary human-readable text, terminated by a special
 279     ;; character code.
 280     (fasl-write-string
 281      (with-standard-io-syntax
 282        (format nil
 283                "~%  ~
 284                 compiled from ~S~%  ~
 285                 at ~A~%  ~
 286                 on ~A~%  ~
 287                 using ~A version ~A~%"
 288                 where
 289                 (format-universal-time nil (get-universal-time))
 290                 (machine-instance)
 291                 (sb!xc:lisp-implementation-type)
 292                 (sb!xc:lisp-implementation-version)))
 293      stream)
 294     (dump-byte +fasl-header-string-stop-char-code+ res)
 295
 296     ;; Finish the header by outputting fasl file implementation and
 297     ;; version in machine-readable form.
 298     (let ((implementation +backend-fasl-file-implementation+))
 299       (dump-unsigned-32 (length (symbol-name implementation)) res)
 300       (dotimes (i (length (symbol-name implementation)))
 301         (dump-byte (char-code (aref (symbol-name implementation) i)) res)))
 302     (dump-unsigned-32 +fasl-file-version+ res)
 303
 304     res))
 305
 306 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 307 (defun close-fasl-output (fasl-output abort-p)
 308   (declare (type fasl-output fasl-output))
 309
 310   ;; sanity checks
 311   (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 312
 313   ;; End the group.
 314   (dump-fop 'fop-verify-empty-stack fasl-output)
 315   (dump-fop 'fop-verify-table-size fasl-output)
 316   (dump-unsigned-32 (fasl-output-table-free fasl-output)
 317                     fasl-output)
 318   (dump-fop 'fop-end-group fasl-output)
 319
 320   ;; That's all, folks.
 321   (close (fasl-output-stream fasl-output) :abort abort-p)
 322   (values))
 323 \f
 324 ;;;; main entries to object dumping
 325
 326 ;;; This function deals with dumping objects that are complex enough
 327 ;;; so that we want to cache them in the table, rather than repeatedly
 328 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 329 ;;; otherwise, we do a type dispatch to a type specific dumping
 330 ;;; function. The type specific branches do any appropriate
 331 ;;; EQUAL-TABLE check and table entry.
 332 ;;;
 333 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 334 (defun dump-non-immediate-object (x file)
 335   (let ((index (gethash x (fasl-output-eq-table file))))
 336     (cond ((and index (not *cold-load-dump*))
 337            (dump-push index file))
 338           (t
 339            (typecase x
 340              (symbol (dump-symbol x file))
 341              (list
 342               ;; KLUDGE: The code in this case has been hacked
 343               ;; to match Douglas Crosher's quick fix to CMU CL
 344               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 345               ;; with help from Martin Atzmueller. This is not an
 346               ;; ideal solution; to quote DTC,
 347               ;;   The compiler locks up trying to coalesce the
 348               ;;   constant lists. The hack below will disable the
 349               ;;   coalescing of lists while dumping and allows
 350               ;;   the code to compile. The real fix would be to
 351               ;;   take a little more care while dumping these.
 352               ;; So if better list coalescing is needed, start here.
 353               ;; -- WHN 2000-11-07
 354               (if (cyclic-list-p x)
 355                   (progn
 356                     (dump-list x file)
 357                     (eq-save-object x file))
 358                   (unless (equal-check-table x file)
 359                     (dump-list x file)
 360                     (equal-save-object x file))))
 361              (layout
 362               (dump-layout x file)
 363               (eq-save-object x file))
 364              (instance
 365               (dump-structure x file)
 366               (eq-save-object x file))
 367              (array
 368               ;; FIXME: The comment at the head of
 369               ;; DUMP-NON-IMMEDIATE-OBJECT says it's for objects which
 370               ;; we want to save, instead of repeatedly dumping them.
 371               ;; But then we dump arrays here without doing anything
 372               ;; like EQUAL-SAVE-OBJECT. What gives?
 373               (dump-array x file))
 374              (number
 375               (unless (equal-check-table x file)
 376                 (etypecase x
 377                   (ratio (dump-ratio x file))
 378                   (complex (dump-complex x file))
 379                   (float (dump-float x file))
 380                   (integer (dump-integer x file)))
 381                 (equal-save-object x file)))
 382              (t
 383               ;; This probably never happens, since bad things tend to
 384               ;; be detected during IR1 conversion.
 385               (error "This object cannot be dumped into a fasl file:~% ~S"
 386                      x))))))
 387   (values))
 388
 389 ;;; Dump an object of any type by dispatching to the correct
 390 ;;; type-specific dumping function. We pick off immediate objects,
 391 ;;; symbols and and magic lists here. Other objects are handled by
 392 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 393 ;;;
 394 ;;; This is the function used for recursive calls to the fasl dumper.
 395 ;;; We don't worry about creating circularities here, since it is
 396 ;;; assumed that there is a top level call to DUMP-OBJECT.
 397 (defun sub-dump-object (x file)
 398   (cond ((listp x)
 399          (if x
 400              (dump-non-immediate-object x file)
 401              (dump-fop 'fop-empty-list file)))
 402         ((symbolp x)
 403          (if (eq x t)
 404              (dump-fop 'fop-truth file)
 405              (dump-non-immediate-object x file)))
 406         ((fixnump x) (dump-integer x file))
 407         ((characterp x) (dump-character x file))
 408         (t
 409          (dump-non-immediate-object x file))))
 410
 411 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 412 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 413 ;;; take the value to store on the stack. We compute this value by
 414 ;;; fetching the enclosing object from the table, and then CDR'ing it
 415 ;;; if necessary.
 416 (defun dump-circularities (infos file)
 417   (let ((table (fasl-output-eq-table file)))
 418     (dolist (info infos)
 419
 420       (let* ((value (circularity-value info))
 421              (enclosing (circularity-enclosing-object info)))
 422         (dump-push (gethash enclosing table) file)
 423         (unless (eq enclosing value)
 424           (do ((current enclosing (cdr current))
 425                (i 0 (1+ i)))
 426               ((eq current value)
 427                (dump-fop 'fop-nthcdr file)
 428                (dump-unsigned-32 i file))
 429             (declare (type index i)))))
 430
 431       (ecase (circularity-type info)
 432         (:rplaca     (dump-fop 'fop-rplaca    file))
 433         (:rplacd     (dump-fop 'fop-rplacd    file))
 434         (:svset      (dump-fop 'fop-svset     file))
 435         (:struct-set (dump-fop 'fop-structset file)))
 436       (dump-unsigned-32 (gethash (circularity-object info) table) file)
 437       (dump-unsigned-32 (circularity-index info) file))))
 438
 439 ;;; Set up stuff for circularity detection, then dump an object. All
 440 ;;; shared and circular structure will be exactly preserved within a
 441 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 442 ;;; separate calls is only preserved when convenient.
 443 ;;;
 444 ;;; We peek at the object type so that we only pay the circular
 445 ;;; detection overhead on types of objects that might be circular.
 446 (defun dump-object (x file)
 447   (if (compound-object-p x)
 448       (let ((*circularities-detected* ())
 449             (circ (fasl-output-circularity-table file)))
 450         (clrhash circ)
 451         (sub-dump-object x file)
 452         (when *circularities-detected*
 453           (dump-circularities *circularities-detected* file)
 454           (clrhash circ)))
 455       (sub-dump-object x file)))
 456 \f
 457 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 458
 459 ;;; Emit a funcall of the function and return the handle for the
 460 ;;; result.
 461 (defun fasl-dump-load-time-value-lambda (fun file)
 462   (declare (type sb!c::clambda fun) (type fasl-output file))
 463   (let ((handle (gethash (sb!c::leaf-info fun)
 464                          (fasl-output-entry-table file))))
 465     (aver handle)
 466     (dump-push handle file)
 467     (dump-fop 'fop-funcall file)
 468     (dump-byte 0 file))
 469   (dump-pop file))
 470
 471 ;;; Return T iff CONSTANT has not already been dumped. It's been
 472 ;;; dumped if it's in the EQ table.
 473 (defun fasl-constant-already-dumped-p (constant file)
 474   (if (or (gethash constant (fasl-output-eq-table file))
 475           (gethash constant (fasl-output-valid-structures file)))
 476       t
 477       nil))
 478
 479 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 480 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 481 (defun fasl-note-handle-for-constant (constant handle file)
 482   (let ((table (fasl-output-eq-table file)))
 483     (when (gethash constant table)
 484       (error "~S already dumped?" constant))
 485     (setf (gethash constant table) handle))
 486   (values))
 487
 488 ;;; Note that the specified structure can just be dumped by
 489 ;;; enumerating the slots.
 490 (defun fasl-validate-structure (structure file)
 491   (setf (gethash structure (fasl-output-valid-structures file)) t)
 492   (values))
 493 \f
 494 ;;;; number dumping
 495
 496 ;;; Dump a ratio.
 497 (defun dump-ratio (x file)
 498   (sub-dump-object (numerator x) file)
 499   (sub-dump-object (denominator x) file)
 500   (dump-fop 'fop-ratio file))
 501
 502 ;;; Dump an integer.
 503 (defun dump-integer (n file)
 504   (typecase n
 505     ((signed-byte 8)
 506      (dump-fop 'fop-byte-integer file)
 507      (dump-byte (logand #xFF n) file))
 508     ((unsigned-byte 31)
 509      (dump-fop 'fop-word-integer file)
 510      (dump-unsigned-32 n file))
 511     ((signed-byte 32)
 512      (dump-fop 'fop-word-integer file)
 513      (dump-integer-as-n-bytes n 4 file))
 514     (t
 515      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 516        (dump-fop* bytes fop-small-integer fop-integer file)
 517        (dump-integer-as-n-bytes n bytes file)))))
 518
 519 (defun dump-float (x file)
 520   (etypecase x
 521     (single-float
 522      (dump-fop 'fop-single-float file)
 523      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 524     (double-float
 525      (dump-fop 'fop-double-float file)
 526      (let ((x x))
 527        (declare (double-float x))
 528        ;; FIXME: Why sometimes DUMP-UNSIGNED-32 and sometimes
 529        ;; DUMP-INTEGER-AS-N-BYTES .. 4?
 530        (dump-unsigned-32 (double-float-low-bits x) file)
 531        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 532     #!+long-float
 533     (long-float
 534      (dump-fop 'fop-long-float file)
 535      (dump-long-float x file))))
 536
 537 (defun dump-complex (x file)
 538   (typecase x
 539     #-sb-xc-host
 540     ((complex single-float)
 541      (dump-fop 'fop-complex-single-float file)
 542      (dump-integer-as-n-bytes (single-float-bits (realpart x)) 4 file)
 543      (dump-integer-as-n-bytes (single-float-bits (imagpart x)) 4 file))
 544     #-sb-xc-host
 545     ((complex double-float)
 546      (dump-fop 'fop-complex-double-float file)
 547      (let ((re (realpart x)))
 548        (declare (double-float re))
 549        (dump-unsigned-32 (double-float-low-bits re) file)
 550        (dump-integer-as-n-bytes (double-float-high-bits re) 4 file))
 551      (let ((im (imagpart x)))
 552        (declare (double-float im))
 553        (dump-unsigned-32 (double-float-low-bits im) file)
 554        (dump-integer-as-n-bytes (double-float-high-bits im) 4 file)))
 555     #!+long-float
 556     ((complex long-float)
 557      ;; (There's no easy way to mix #!+LONG-FLOAT and #-SB-XC-HOST
 558      ;; conditionalization at read time, so we do this SB-XC-HOST
 559      ;; conditional at runtime instead.)
 560      #+sb-xc-host (error "can't dump COMPLEX-LONG-FLOAT in cross-compiler")
 561      (dump-fop 'fop-complex-long-float file)
 562      (dump-long-float (realpart x) file)
 563      (dump-long-float (imagpart x) file))
 564     (t
 565      (sub-dump-object (realpart x) file)
 566      (sub-dump-object (imagpart x) file)
 567      (dump-fop 'fop-complex file))))
 568 \f
 569 ;;;; symbol dumping
 570
 571 ;;; Return the table index of PKG, adding the package to the table if
 572 ;;; necessary. During cold load, we read the string as a normal string
 573 ;;; so that we can do the package lookup at cold load time.
 574 ;;;
 575 ;;; FIXME: Despite the parallelism in names, the functionality of
 576 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 577 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 578 ;;; should be made more consistent.
 579 (defun dump-package (pkg file)
 580   (declare (type package pkg) (type fasl-output file))
 581   #+nil (declare (values index))
 582   (declare (inline assoc))
 583   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 584         (t
 585          (unless *cold-load-dump*
 586            (dump-fop 'fop-normal-load file))
 587          (dump-simple-string (package-name pkg) file)
 588          (dump-fop 'fop-package file)
 589          (unless *cold-load-dump*
 590            (dump-fop 'fop-maybe-cold-load file))
 591          (let ((entry (dump-pop file)))
 592            (push (cons pkg entry) (fasl-output-packages file))
 593            entry))))
 594 \f
 595 ;;; dumper for lists
 596
 597 ;;; Dump a list, setting up patching information when there are
 598 ;;; circularities. We scan down the list, checking for CDR and CAR
 599 ;;; circularities.
 600 ;;;
 601 ;;; If there is a CDR circularity, we terminate the list with NIL and
 602 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 603 ;;;
 604 ;;; If there is no CDR circularity, then we mark the current cons and
 605 ;;; check for a CAR circularity. When there is a CAR circularity, we
 606 ;;; make the CAR NIL initially, arranging for the current cons to be
 607 ;;; patched later.
 608 ;;;
 609 ;;; Otherwise, we recursively call the dumper to dump the current
 610 ;;; element.
 611 ;;;
 612 ;;; Marking of the conses is inhibited when *COLD-LOAD-DUMP* is true.
 613 ;;; This inhibits all circularity detection.
 614 (defun dump-list (list file)
 615   (aver (and list
 616              (not (gethash list (fasl-output-circularity-table file)))))
 617   (do* ((l list (cdr l))
 618         (n 0 (1+ n))
 619         (circ (fasl-output-circularity-table file)))
 620        ((atom l)
 621         (cond ((null l)
 622                (terminate-undotted-list n file))
 623               (t
 624                (sub-dump-object l file)
 625                (terminate-dotted-list n file))))
 626     (declare (type index n))
 627     (let ((ref (gethash l circ)))
 628       (when ref
 629         (push (make-circularity :type :rplacd
 630                                 :object list
 631                                 :index (1- n)
 632                                 :value l
 633                                 :enclosing-object ref)
 634               *circularities-detected*)
 635         (terminate-undotted-list n file)
 636         (return)))
 637
 638     (unless *cold-load-dump*
 639       (setf (gethash l circ) list))
 640
 641     (let* ((obj (car l))
 642            (ref (gethash obj circ)))
 643       (cond (ref
 644              (push (make-circularity :type :rplaca
 645                                      :object list
 646                                      :index n
 647                                      :value obj
 648                                      :enclosing-object ref)
 649                    *circularities-detected*)
 650              (sub-dump-object nil file))
 651             (t
 652              (sub-dump-object obj file))))))
 653
 654 (defun terminate-dotted-list (n file)
 655   (declare (type index n) (type fasl-output file))
 656   (case n
 657     (1 (dump-fop 'fop-list*-1 file))
 658     (2 (dump-fop 'fop-list*-2 file))
 659     (3 (dump-fop 'fop-list*-3 file))
 660     (4 (dump-fop 'fop-list*-4 file))
 661     (5 (dump-fop 'fop-list*-5 file))
 662     (6 (dump-fop 'fop-list*-6 file))
 663     (7 (dump-fop 'fop-list*-7 file))
 664     (8 (dump-fop 'fop-list*-8 file))
 665     (T (do ((nn n (- nn 255)))
 666            ((< nn 256)
 667             (dump-fop 'fop-list* file)
 668             (dump-byte nn file))
 669          (declare (type index nn))
 670          (dump-fop 'fop-list* file)
 671          (dump-byte 255 file)))))
 672
 673 ;;; If N > 255, must build list with one LIST operator, then LIST*
 674 ;;; operators.
 675
 676 (defun terminate-undotted-list (n file)
 677   (declare (type index n) (type fasl-output file))
 678   (case n
 679     (1 (dump-fop 'fop-list-1 file))
 680     (2 (dump-fop 'fop-list-2 file))
 681     (3 (dump-fop 'fop-list-3 file))
 682     (4 (dump-fop 'fop-list-4 file))
 683     (5 (dump-fop 'fop-list-5 file))
 684     (6 (dump-fop 'fop-list-6 file))
 685     (7 (dump-fop 'fop-list-7 file))
 686     (8 (dump-fop 'fop-list-8 file))
 687     (T (cond ((< n 256)
 688               (dump-fop 'fop-list file)
 689               (dump-byte n file))
 690              (t (dump-fop 'fop-list file)
 691                 (dump-byte 255 file)
 692                 (do ((nn (- n 255) (- nn 255)))
 693                     ((< nn 256)
 694                      (dump-fop 'fop-list* file)
 695                      (dump-byte nn file))
 696                   (declare (type index nn))
 697                   (dump-fop 'fop-list* file)
 698                   (dump-byte 255 file)))))))
 699 \f
 700 ;;;; array dumping
 701
 702 ;;; Dump the array thing.
 703 (defun dump-array (x file)
 704   (if (vectorp x)
 705       (dump-vector x file)
 706       (dump-multi-dim-array x file)))
 707
 708 ;;; Dump the vector object. If it's not simple, then actually dump a
 709 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 710 ;;; tables.
 711 (defun dump-vector (x file)
 712   (let ((simple-version (if (array-header-p x)
 713                             (coerce x 'simple-array)
 714                             x)))
 715     (typecase simple-version
 716       (simple-base-string
 717        (unless (equal-check-table x file)
 718          (dump-simple-string simple-version file)
 719          (equal-save-object x file)))
 720       (simple-vector
 721        (dump-simple-vector simple-version file)
 722        (eq-save-object x file))
 723       ((simple-array single-float (*))
 724        (dump-single-float-vector simple-version file)
 725        (eq-save-object x file))
 726       ((simple-array double-float (*))
 727        (dump-double-float-vector simple-version file)
 728        (eq-save-object x file))
 729       #!+long-float
 730       ((simple-array long-float (*))
 731        (dump-long-float-vector simple-version file)
 732        (eq-save-object x file))
 733       ((simple-array (complex single-float) (*))
 734        (dump-complex-single-float-vector simple-version file)
 735        (eq-save-object x file))
 736       ((simple-array (complex double-float) (*))
 737        (dump-complex-double-float-vector simple-version file)
 738        (eq-save-object x file))
 739       #!+long-float
 740       ((simple-array (complex long-float) (*))
 741        (dump-complex-long-float-vector simple-version file)
 742        (eq-save-object x file))
 743       (t
 744        (dump-i-vector simple-version file)
 745        (eq-save-object x file)))))
 746
 747 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 748 (defun dump-simple-vector (v file)
 749   (declare (type simple-vector v) (type fasl-output file))
 750   (note-potential-circularity v file)
 751   (do ((index 0 (1+ index))
 752        (length (length v))
 753        (circ (fasl-output-circularity-table file)))
 754       ((= index length)
 755        (dump-fop* length fop-small-vector fop-vector file))
 756     (let* ((obj (aref v index))
 757            (ref (gethash obj circ)))
 758       (cond (ref
 759              (push (make-circularity :type :svset
 760                                      :object v
 761                                      :index index
 762                                      :value obj
 763                                      :enclosing-object ref)
 764                    *circularities-detected*)
 765              (sub-dump-object nil file))
 766             (t
 767              (sub-dump-object obj file))))))
 768
 769 ;;; In the grand scheme of things I don't pretend to understand any
 770 ;;; more how this works, or indeed whether.  But to write out specialized
 771 ;;; vectors in the same format as fop-int-vector expects to read them
 772 ;;; we need to be target-endian.  dump-integer-as-n-bytes always writes
 773 ;;; little-endian (which is correct for all other integers) so for a bigendian
 774 ;;; target we need to swap octets -- CSR, after DB
 775
 776 (defun octet-swap (word bits)
 777   "BITS must be a multiple of 8"
 778   (do ((input word (ash input -8))
 779        (output 0 (logior (ash output 8) (logand input #xff)))
 780        (bits bits (- bits 8)))
 781       ((<= bits 0) output)))
 782
 783 (defun dump-i-vector (vec file &key data-only)
 784   (declare (type (simple-array * (*)) vec))
 785   (let ((len (length vec)))
 786     (labels ((dump-unsigned-vector (size bytes)
 787                (unless data-only
 788                  (dump-fop 'fop-int-vector file)
 789                  (dump-unsigned-32 len file)
 790                  (dump-byte size file))
 791                ;; The case which is easy to handle in a portable way is when
 792                ;; the element size is a multiple of the output byte size, and
 793                ;; happily that's the only case we need to be portable. (The
 794                ;; cross-compiler has to output debug information (including
 795                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 796                ;; needed in the target SBCL, so we let them be handled with
 797                ;; unportable bit bashing.
 798                (cond ((>= size 8) ; easy cases
 799                       (multiple-value-bind (floor rem) (floor size 8)
 800                         (aver (zerop rem))
 801                         (dovector (i vec)
 802                           (dump-integer-as-n-bytes
 803                            (ecase sb!c:*backend-byte-order*
 804                              (:little-endian i)
 805                              (:big-endian (octet-swap i size)))
 806                            floor file))))
 807                      (t ; harder cases, not supported in cross-compiler
 808                       (dump-raw-bytes vec bytes file))))
 809              (dump-signed-vector (size bytes)
 810                ;; Note: Dumping specialized signed vectors isn't
 811                ;; supported in the cross-compiler. (All cases here end
 812                ;; up trying to call DUMP-RAW-BYTES, which isn't
 813                ;; provided in the cross-compilation host, only on the
 814                ;; target machine.)
 815                (unless data-only
 816                  (dump-fop 'fop-signed-int-vector file)
 817                  (dump-unsigned-32 len file)
 818                  (dump-byte size file))
 819                (dump-raw-bytes vec bytes file)))
 820       (etypecase vec
 821         ;; KLUDGE: What exactly does the (ASH .. -3) stuff do? -- WHN 19990902
 822         (simple-bit-vector
 823          (dump-unsigned-vector 1 (ash (+ (the index len) 7) -3)))
 824         ((simple-array (unsigned-byte 2) (*))
 825          (dump-unsigned-vector 2 (ash (+ (the index (ash len 1)) 7) -3)))
 826         ((simple-array (unsigned-byte 4) (*))
 827          (dump-unsigned-vector 4 (ash (+ (the index (ash len 2)) 7) -3)))
 828         ((simple-array (unsigned-byte 8) (*))
 829          (dump-unsigned-vector 8 len))
 830         ((simple-array (unsigned-byte 16) (*))
 831          (dump-unsigned-vector 16 (* 2 len)))
 832         ((simple-array (unsigned-byte 32) (*))
 833          (dump-unsigned-vector 32 (* 4 len)))
 834         ((simple-array (signed-byte 8) (*))
 835          (dump-signed-vector 8 len))
 836         ((simple-array (signed-byte 16) (*))
 837          (dump-signed-vector 16 (* 2 len)))
 838         ((simple-array (signed-byte 30) (*))
 839          (dump-signed-vector 30 (* 4 len)))
 840         ((simple-array (signed-byte 32) (*))
 841          (dump-signed-vector 32 (* 4 len)))))))
 842 \f
 843 ;;; Dump characters and string-ish things.
 844
 845 (defun dump-character (ch file)
 846   (dump-fop 'fop-short-character file)
 847   (dump-byte (char-code ch) file))
 848
 849 ;;; a helper function shared by DUMP-SIMPLE-STRING and DUMP-SYMBOL
 850 (defun dump-characters-of-string (s fasl-output)
 851   (declare (type string s) (type fasl-output fasl-output))
 852   (dovector (c s)
 853     (dump-byte (char-code c) fasl-output))
 854   (values))
 855
 856 ;;; Dump a SIMPLE-BASE-STRING.
 857 ;;; FIXME: should be called DUMP-SIMPLE-BASE-STRING then
 858 (defun dump-simple-string (s file)
 859   (declare (type simple-base-string s))
 860   (dump-fop* (length s) fop-small-string fop-string file)
 861   (dump-characters-of-string s file)
 862   (values))
 863
 864 ;;; If we get here, it is assumed that the symbol isn't in the table,
 865 ;;; but we are responsible for putting it there when appropriate. To
 866 ;;; avoid too much special-casing, we always push the symbol in the
 867 ;;; table, but don't record that we have done so if *COLD-LOAD-DUMP*
 868 ;;; is true.
 869 (defun dump-symbol (s file)
 870   (declare (type fasl-output file))
 871   (let* ((pname (symbol-name s))
 872          (pname-length (length pname))
 873          (pkg (symbol-package s)))
 874
 875     (cond ((null pkg)
 876            (dump-fop* pname-length
 877                       fop-uninterned-small-symbol-save
 878                       fop-uninterned-symbol-save
 879                       file))
 880           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 881           ;; used the current value of *PACKAGE*. Unfortunately that's
 882           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 883           ;; from SBCL.
 884           ;;((eq pkg *package*)
 885           ;; (dump-fop* pname-length
 886           ;;        fop-small-symbol-save
 887           ;;        fop-symbol-save file))
 888           ((eq pkg sb!int:*cl-package*)
 889            (dump-fop* pname-length
 890                       fop-lisp-small-symbol-save
 891                       fop-lisp-symbol-save
 892                       file))
 893           ((eq pkg sb!int:*keyword-package*)
 894            (dump-fop* pname-length
 895                       fop-keyword-small-symbol-save
 896                       fop-keyword-symbol-save
 897                       file))
 898           ((< pname-length 256)
 899            (dump-fop* (dump-package pkg file)
 900                       fop-small-symbol-in-byte-package-save
 901                       fop-small-symbol-in-package-save
 902                       file)
 903            (dump-byte pname-length file))
 904           (t
 905            (dump-fop* (dump-package pkg file)
 906                       fop-symbol-in-byte-package-save
 907                       fop-symbol-in-package-save
 908                       file)
 909            (dump-unsigned-32 pname-length file)))
 910
 911     (dump-characters-of-string pname file)
 912
 913     (unless *cold-load-dump*
 914       (setf (gethash s (fasl-output-eq-table file))
 915             (fasl-output-table-free file)))
 916
 917     (incf (fasl-output-table-free file)))
 918
 919   (values))
 920 \f
 921 ;;;; component (function) dumping
 922
 923 (defun dump-segment (segment code-length fasl-output)
 924   (declare (type sb!assem:segment segment)
 925            (type fasl-output fasl-output))
 926   (let* ((stream (fasl-output-stream fasl-output))
 927          (n-written (write-segment-contents segment stream)))
 928     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
 929     ;; argument and the number of bytes actually written. I added this
 930     ;; assertion while trying to debug portable genesis. -- WHN 19990902
 931     (unless (= code-length n-written)
 932       (bug "code-length=~W, n-written=~W" code-length n-written)))
 933   (values))
 934
 935 ;;; Dump all the fixups. Currently there are three flavors of fixup:
 936 ;;;  - assembly routines: named by a symbol
 937 ;;;  - foreign (C) symbols: named by a string
 938 ;;;  - code object references: don't need a name.
 939 (defun dump-fixups (fixups fasl-output)
 940   (declare (list fixups) (type fasl-output fasl-output))
 941   (dolist (info fixups)
 942     ;; FIXME: Packing data with LIST in NOTE-FIXUP and unpacking them
 943     ;; with FIRST, SECOND, and THIRD here is hard to follow and
 944     ;; maintain. Perhaps we could define a FIXUP-INFO structure to use
 945     ;; instead, and rename *FIXUPS* to *FIXUP-INFO-LIST*?
 946     (let* ((kind (first info))
 947            (fixup (second info))
 948            (name (fixup-name fixup))
 949            (flavor (fixup-flavor fixup))
 950            (offset (third info)))
 951       ;; FIXME: This OFFSET is not what's called OFFSET in the FIXUP
 952       ;; structure, it's what's called POSN in NOTE-FIXUP. (As far as
 953       ;; I can tell, FIXUP-OFFSET is not actually an offset, it's an
 954       ;; internal label used instead of NAME for :CODE-OBJECT fixups.
 955       ;; Notice that in the :CODE-OBJECT case, NAME is ignored.)
 956       (dump-fop 'fop-normal-load fasl-output)
 957       (let ((*cold-load-dump* t))
 958         (dump-object kind fasl-output))
 959       (dump-fop 'fop-maybe-cold-load fasl-output)
 960       ;; Depending on the flavor, we may have various kinds of
 961       ;; noise before the offset.
 962       (ecase flavor
 963         (:assembly-routine
 964          (aver (symbolp name))
 965          (dump-fop 'fop-normal-load fasl-output)
 966          (let ((*cold-load-dump* t))
 967            (dump-object name fasl-output))
 968          (dump-fop 'fop-maybe-cold-load fasl-output)
 969          (dump-fop 'fop-assembler-fixup fasl-output))
 970         (:foreign
 971          (aver (stringp name))
 972          (dump-fop 'fop-foreign-fixup fasl-output)
 973          (let ((len (length name)))
 974            (aver (< len 256)) ; (limit imposed by fop definition)
 975            (dump-byte len fasl-output)
 976            (dotimes (i len)
 977              (dump-byte (char-code (schar name i)) fasl-output))))
 978         (:code-object
 979          (aver (null name))
 980          (dump-fop 'fop-code-object-fixup fasl-output)))
 981       ;; No matter what the flavor, we'll always dump the offset.
 982       (dump-unsigned-32 offset fasl-output)))
 983   (values))
 984
 985 ;;; Dump out the constant pool and code-vector for component, push the
 986 ;;; result in the table, and return the offset.
 987 ;;;
 988 ;;; The only tricky thing is handling constant-pool references to
 989 ;;; functions. If we have already dumped the function, then we just
 990 ;;; push the code pointer. Otherwise, we must create back-patching
 991 ;;; information so that the constant will be set when the function is
 992 ;;; eventually dumped. This is a bit awkward, since we don't have the
 993 ;;; handle for the code object being dumped while we are dumping its
 994 ;;; constants.
 995 ;;;
 996 ;;; We dump trap objects in any unused slots or forward referenced slots.
 997 (defun dump-code-object (component
 998                          code-segment
 999                          code-length
1000                          trace-table-as-list
1001                          fixups
1002                          fasl-output)
1003
1004   (declare (type component component)
1005            (list trace-table-as-list)
1006            (type index code-length)
1007            (type fasl-output fasl-output))
1008
1009   (let* ((2comp (component-info component))
1010          (constants (sb!c::ir2-component-constants 2comp))
1011          (header-length (length constants))
1012          (packed-trace-table (pack-trace-table trace-table-as-list))
1013          (total-length (+ code-length
1014                           (* (length packed-trace-table)
1015                              sb!c::tt-bytes-per-entry))))
1016
1017     (collect ((patches))
1018
1019       ;; Dump the offset of the trace table.
1020       (dump-object code-length fasl-output)
1021       ;; FIXME: As long as we don't have GENGC, the trace table is
1022       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
1023       ;; far as I know no modern CMU CL does either -- WHN
1024       ;; 2001-10-05). So might we be able to get rid of trace tables?
1025
1026       ;; Dump the constants, noting any :ENTRY constants that have to
1027       ;; be patched.
1028       (loop for i from sb!vm:code-constants-offset below header-length do
1029         (let ((entry (aref constants i)))
1030           (etypecase entry
1031             (constant
1032              (dump-object (sb!c::constant-value entry) fasl-output))
1033             (cons
1034              (ecase (car entry)
1035                (:entry
1036                 (let* ((info (sb!c::leaf-info (cdr entry)))
1037                        (handle (gethash info
1038                                         (fasl-output-entry-table
1039                                          fasl-output))))
1040                   (declare (type sb!c::entry-info info))
1041                   (cond
1042                    (handle
1043                     (dump-push handle fasl-output))
1044                    (t
1045                     (patches (cons info i))
1046                     (dump-fop 'fop-misc-trap fasl-output)))))
1047                (:load-time-value
1048                 (dump-push (cdr entry) fasl-output))
1049                (:fdefinition
1050                 (dump-object (cdr entry) fasl-output)
1051                 (dump-fop 'fop-fdefinition fasl-output))))
1052             (null
1053              (dump-fop 'fop-misc-trap fasl-output)))))
1054
1055       ;; Dump the debug info.
1056       (let ((info (sb!c::debug-info-for-component component))
1057             (*dump-only-valid-structures* nil))
1058         (dump-object info fasl-output)
1059         (let ((info-handle (dump-pop fasl-output)))
1060           (dump-push info-handle fasl-output)
1061           (push info-handle (fasl-output-debug-info fasl-output))))
1062
1063       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1064         (cond ((and (< num-consts #x100) (< total-length #x10000))
1065                (dump-fop 'fop-small-code fasl-output)
1066                (dump-byte num-consts fasl-output)
1067                (dump-integer-as-n-bytes total-length 2 fasl-output))
1068               (t
1069                (dump-fop 'fop-code fasl-output)
1070                (dump-unsigned-32 num-consts fasl-output)
1071                (dump-unsigned-32 total-length fasl-output))))
1072
1073       ;; These two dumps are only ones which contribute to our
1074       ;; TOTAL-LENGTH value.
1075       (dump-segment code-segment code-length fasl-output)
1076       (dump-i-vector packed-trace-table fasl-output :data-only t)
1077
1078       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1079       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1080       ;; FOP-CODE/FOP-SMALL-CODE fop.
1081       (dump-fixups fixups fasl-output)
1082
1083       (dump-fop 'fop-sanctify-for-execution fasl-output)
1084
1085       (let ((handle (dump-pop fasl-output)))
1086         (dolist (patch (patches))
1087           (push (cons handle (cdr patch))
1088                 (gethash (car patch)
1089                          (fasl-output-patch-table fasl-output))))
1090         handle))))
1091
1092 (defun dump-assembler-routines (code-segment length fixups routines file)
1093   (dump-fop 'fop-assembler-code file)
1094   (dump-unsigned-32 length file)
1095   (write-segment-contents code-segment (fasl-output-stream file))
1096   (dolist (routine routines)
1097     (dump-fop 'fop-normal-load file)
1098     (let ((*cold-load-dump* t))
1099       (dump-object (car routine) file))
1100     (dump-fop 'fop-maybe-cold-load file)
1101     (dump-fop 'fop-assembler-routine file)
1102     (dump-unsigned-32 (label-position (cdr routine)) file))
1103   (dump-fixups fixups file)
1104   (dump-fop 'fop-sanctify-for-execution file)
1105   (dump-pop file))
1106
1107 ;;; Dump a function entry data structure corresponding to ENTRY to
1108 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1109 ;;; component.
1110 (defun dump-one-entry (entry code-handle file)
1111   (declare (type sb!c::entry-info entry) (type index code-handle)
1112            (type fasl-output file))
1113   (let ((name (sb!c::entry-info-name entry)))
1114     (dump-push code-handle file)
1115     (dump-object name file)
1116     (dump-object (sb!c::entry-info-arguments entry) file)
1117     (dump-object (sb!c::entry-info-type entry) file)
1118     (dump-fop 'fop-fun-entry file)
1119     (dump-unsigned-32 (label-position (sb!c::entry-info-offset entry)) file)
1120     (dump-pop file)))
1121
1122 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1123 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1124 (defun dump-alter-code-object (code-handle offset entry-handle file)
1125   (declare (type index code-handle entry-handle offset))
1126   (declare (type fasl-output file))
1127   (dump-push code-handle file)
1128   (dump-push entry-handle file)
1129   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1130   (values))
1131
1132 ;;; Dump the code, constants, etc. for component. We pass in the
1133 ;;; assembler fixups, code vector and node info.
1134 (defun fasl-dump-component (component
1135                             code-segment
1136                             code-length
1137                             trace-table
1138                             fixups
1139                             file)
1140   (declare (type component component) (list trace-table))
1141   (declare (type fasl-output file))
1142
1143   (dump-fop 'fop-verify-empty-stack file)
1144   (dump-fop 'fop-verify-table-size file)
1145   (dump-unsigned-32 (fasl-output-table-free file) file)
1146
1147   #!+sb-dyncount
1148   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1149     (when info
1150       (fasl-validate-structure info file)))
1151
1152   (let ((code-handle (dump-code-object component
1153                                        code-segment
1154                                        code-length
1155                                        trace-table
1156                                        fixups
1157                                        file))
1158         (2comp (component-info component)))
1159     (dump-fop 'fop-verify-empty-stack file)
1160
1161     (dolist (entry (sb!c::ir2-component-entries 2comp))
1162       (let ((entry-handle (dump-one-entry entry code-handle file)))
1163         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1164         (let ((old (gethash entry (fasl-output-patch-table file))))
1165           (when old
1166             (dolist (patch old)
1167               (dump-alter-code-object (car patch)
1168                                       (cdr patch)
1169                                       entry-handle
1170                                       file))
1171             (remhash entry (fasl-output-patch-table file)))))))
1172   (values))
1173
1174 (defun dump-push-previously-dumped-fun (fun fasl-output)
1175   (declare (type sb!c::clambda fun))
1176   (let ((handle (gethash (sb!c::leaf-info fun)
1177                          (fasl-output-entry-table fasl-output))))
1178     (aver handle)
1179     (dump-push handle fasl-output))
1180   (values))
1181
1182 ;;; Dump a FOP-FUNCALL to call an already-dumped top level lambda at
1183 ;;; load time.
1184 (defun fasl-dump-toplevel-lambda-call (fun fasl-output)
1185   (declare (type sb!c::clambda fun))
1186   (dump-push-previously-dumped-fun fun fasl-output)
1187   (dump-fop 'fop-funcall-for-effect fasl-output)
1188   (dump-byte 0 fasl-output)
1189   (values))
1190
1191 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1192 ;;; FUN-NAME and the already-dumped function whose dump handle is
1193 ;;; FUN-DUMP-HANDLE.
1194 #+sb-xc-host
1195 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1196   (declare (type fixnum fun-dump-handle))
1197   (aver (legal-fun-name-p fun-name))
1198   (dump-non-immediate-object fun-name fasl-output)
1199   (dump-push fun-dump-handle fasl-output)
1200   (dump-fop 'fop-fset fasl-output)
1201   (values))
1202
1203 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1204 ;;; all of the dumped DEBUG-INFO structures. We clear the
1205 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1206 ;;; different source info may be dumped.
1207 (defun fasl-dump-source-info (info fasl-output)
1208   (declare (type sb!c::source-info info))
1209   (let ((res (sb!c::debug-source-for-info info))
1210         (*dump-only-valid-structures* nil))
1211     (dump-object res fasl-output)
1212     (let ((res-handle (dump-pop fasl-output)))
1213       (dolist (info-handle (fasl-output-debug-info fasl-output))
1214         (dump-push res-handle fasl-output)
1215         (dump-fop 'fop-structset fasl-output)
1216         (dump-unsigned-32 info-handle fasl-output)
1217         (dump-unsigned-32 2 fasl-output))))
1218   (setf (fasl-output-debug-info fasl-output) nil)
1219   (values))
1220 \f
1221 ;;;; dumping structures
1222
1223 (defun dump-structure (struct file)
1224   (when *dump-only-valid-structures*
1225     (unless (gethash struct (fasl-output-valid-structures file))
1226       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1227              struct)))
1228   (note-potential-circularity struct file)
1229   (do ((index 0 (1+ index))
1230        (length (%instance-length struct))
1231        (circ (fasl-output-circularity-table file)))
1232       ((= index length)
1233        (dump-fop* length fop-small-struct fop-struct file))
1234     (let* ((obj (%instance-ref struct index))
1235            (ref (gethash obj circ)))
1236       (cond (ref
1237              (push (make-circularity :type :struct-set
1238                                      :object struct
1239                                      :index index
1240                                      :value obj
1241                                      :enclosing-object ref)
1242                    *circularities-detected*)
1243              (sub-dump-object nil file))
1244             (t
1245              (sub-dump-object obj file))))))
1246
1247 (defun dump-layout (obj file)
1248   (when (layout-invalid obj)
1249     (compiler-error "attempt to dump reference to obsolete class: ~S"
1250                     (layout-class obj)))
1251   (let ((name (sb!xc:class-name (layout-class obj))))
1252     (unless name
1253       (compiler-error "dumping anonymous layout: ~S" obj))
1254     (dump-fop 'fop-normal-load file)
1255     (let ((*cold-load-dump* t))
1256       (dump-object name file))
1257     (dump-fop 'fop-maybe-cold-load file))
1258   (sub-dump-object (layout-inherits obj) file)
1259   (sub-dump-object (layout-depthoid obj) file)
1260   (sub-dump-object (layout-length obj) file)
1261   (dump-fop 'fop-layout file))