src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (missing-arg) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance patholigies with objects for which EQUAL degnerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the ENTRY-INFO structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the ENTRY-INFO structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (missing-arg) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (missing-arg) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to inhibit table access when dumping forms to be read by the
  95 ;;; cold loader
  96 (defvar *cold-load-dump* nil)
  97
  98 ;;; used to turn off the structure validation during dumping of source
  99 ;;; info
 100 (defvar *dump-only-valid-structures* t)
 101 ;;;; utilities
 102
 103 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 104 (defun dump-byte (b fasl-output)
 105   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 106   (write-byte b (fasl-output-stream fasl-output)))
 107
 108 ;;; Dump a 4 byte unsigned integer.
 109 (defun dump-unsigned-32 (num fasl-output)
 110   (declare (type (unsigned-byte 32) num))
 111   (declare (type fasl-output fasl-output))
 112   (let ((stream (fasl-output-stream fasl-output)))
 113     (dotimes (i 4)
 114       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 115
 116 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 117 ;;; for either signed or unsigned integers. There's no range checking
 118 ;;; -- if you don't specify enough bytes for the number to fit, this
 119 ;;; function cheerfully outputs the low bytes.
 120 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 121   (declare (integer num) (type index bytes))
 122   (declare (type fasl-output fasl-output))
 123   (do ((n num (ash n -8))
 124        (i bytes (1- i)))
 125       ((= i 0))
 126     (declare (type index i))
 127     (dump-byte (logand n #xff) fasl-output))
 128   (values))
 129
 130 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 131 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 132 ;;; counter value before every ordinary fop. This can make it easier
 133 ;;; to follow the progress of LOAD-AS-FASL when
 134 ;;; debugging/testing/experimenting.
 135 #!+sb-show (defvar *fop-nop4-count* nil)
 136 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 137
 138 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 139 ;;;
 140 ;;; FIXME: This should be a function, with a compiler macro expansion
 141 ;;; for the common constant-FS case. (Among other things, that'll stop
 142 ;;; it from EVALing ,FILE multiple times.)
 143 ;;;
 144 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 145 ;;; optimizations should be conditional on #!+SB-FROZEN.
 146 (defmacro dump-fop (fs file)
 147   (let* ((fs (eval fs))
 148          (val (get fs 'fop-code)))
 149     (if val
 150       `(progn
 151          #!+sb-show
 152          (when *fop-nop4-count*
 153            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 154            (dump-unsigned-32 (mod (incf *fop-nop4-count*) (expt 2 32)) ,file))
 155          (dump-byte ',val ,file))
 156       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 157
 158 ;;; Dump a FOP-Code along with an integer argument, choosing the FOP
 159 ;;; based on whether the argument will fit in a single byte.
 160 ;;;
 161 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 162 ;;; compiler-macro expansion.
 163 (defmacro dump-fop* (n byte-fop word-fop file)
 164   (once-only ((n-n n)
 165               (n-file file))
 166     `(cond ((< ,n-n 256)
 167             (dump-fop ',byte-fop ,n-file)
 168             (dump-byte ,n-n ,n-file))
 169            (t
 170             (dump-fop ',word-fop ,n-file)
 171             (dump-unsigned-32 ,n-n ,n-file)))))
 172
 173 ;;; Push the object at table offset Handle on the fasl stack.
 174 (defun dump-push (handle fasl-output)
 175   (declare (type index handle) (type fasl-output fasl-output))
 176   (dump-fop* handle fop-byte-push fop-push fasl-output)
 177   (values))
 178
 179 ;;; Pop the object currently on the fasl stack top into the table, and
 180 ;;; return the table index, incrementing the free pointer.
 181 (defun dump-pop (fasl-output)
 182   (prog1
 183       (fasl-output-table-free fasl-output)
 184     (dump-fop 'fop-pop fasl-output)
 185     (incf (fasl-output-table-free fasl-output))))
 186
 187 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 188 ;;; otherwise NIL. If *COLD-LOAD-DUMP* is true, then do nothing and
 189 ;;; return NIL.
 190 (defun equal-check-table (x fasl-output)
 191   (declare (type fasl-output fasl-output))
 192   (unless *cold-load-dump*
 193     (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 194       (cond (handle
 195              (dump-push handle fasl-output)
 196              t)
 197             (t
 198              nil)))))
 199
 200 ;;; These functions are called after dumping an object to save the
 201 ;;; object in the table. The object (also passed in as X) must already
 202 ;;; be on the top of the FOP stack. If *COLD-LOAD-DUMP* is true, then
 203 ;;; we don't do anything.
 204 (defun eq-save-object (x fasl-output)
 205   (declare (type fasl-output fasl-output))
 206   (unless *cold-load-dump*
 207     (let ((handle (dump-pop fasl-output)))
 208       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 209       (dump-push handle fasl-output)))
 210   (values))
 211 (defun equal-save-object (x fasl-output)
 212   (declare (type fasl-output fasl-output))
 213   (unless *cold-load-dump*
 214     (let ((handle (dump-pop fasl-output)))
 215       (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 216       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 217       (dump-push handle fasl-output)))
 218   (values))
 219
 220 ;;; Record X in File's CIRCULARITY-TABLE unless *COLD-LOAD-DUMP* is
 221 ;;; true. This is called on objects that we are about to dump might
 222 ;;; have a circular path through them.
 223 ;;;
 224 ;;; The object must not currently be in this table, since the dumper
 225 ;;; should never be recursively called on a circular reference.
 226 ;;; Instead, the dumping function must detect the circularity and
 227 ;;; arrange for the dumped object to be patched.
 228 (defun note-potential-circularity (x fasl-output)
 229   (unless *cold-load-dump*
 230     (let ((circ (fasl-output-circularity-table fasl-output)))
 231       (aver (not (gethash x circ)))
 232       (setf (gethash x circ) x)))
 233   (values))
 234
 235 ;;; Dump FORM to a fasl file so that it evaluated at load time in normal
 236 ;;; load and at cold-load time in cold load. This is used to dump package
 237 ;;; frobbing forms.
 238 (defun fasl-dump-cold-load-form (form fasl-output)
 239   (declare (type fasl-output fasl-output))
 240   (dump-fop 'fop-normal-load fasl-output)
 241   (let ((*cold-load-dump* t))
 242     (dump-object form fasl-output))
 243   (dump-fop 'fop-eval-for-effect fasl-output)
 244   (dump-fop 'fop-maybe-cold-load fasl-output)
 245   (values))
 246 \f
 247 ;;;; opening and closing fasl files
 248
 249 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 250 ;;; object for dumping to it. Some human-readable information about
 251 ;;; the source code is given by the string WHERE. If BYTE-P is true,
 252 ;;; this file will contain no native code, and is thus largely
 253 ;;; implementation independent.
 254 (defun open-fasl-output (name where)
 255   (declare (type pathname name))
 256   (let* ((stream (open name
 257                        :direction :output
 258                        :if-exists :new-version
 259                        :element-type 'sb!assem:assembly-unit))
 260          (res (make-fasl-output :stream stream)))
 261
 262     ;; Begin the header with the constant machine-readable (and
 263     ;; semi-human-readable) string which is used to identify fasl files.
 264     (write-string *fasl-header-string-start-string* stream)
 265
 266     ;; The constant string which begins the header is followed by
 267     ;; arbitrary human-readable text, terminated by a special
 268     ;; character code.
 269     (with-standard-io-syntax
 270      (format stream
 271              "~%  ~
 272              compiled from ~S~%  ~
 273              at ~A~%  ~
 274              on ~A~%  ~
 275              using ~A version ~A~%"
 276              where
 277              (format-universal-time nil (get-universal-time))
 278              (machine-instance)
 279              (sb!xc:lisp-implementation-type)
 280              (sb!xc:lisp-implementation-version)))
 281     (dump-byte +fasl-header-string-stop-char-code+ res)
 282
 283     ;; Finish the header by outputting fasl file implementation and
 284     ;; version in machine-readable form.
 285     (let ((implementation +backend-fasl-file-implementation+))
 286       (dump-unsigned-32 (length (symbol-name implementation)) res)
 287       (dotimes (i (length (symbol-name implementation)))
 288         (dump-byte (char-code (aref (symbol-name implementation) i)) res)))
 289     (dump-unsigned-32 +fasl-file-version+ res)
 290
 291     res))
 292
 293 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 294 (defun close-fasl-output (fasl-output abort-p)
 295   (declare (type fasl-output fasl-output))
 296
 297   ;; sanity checks
 298   (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 299
 300   ;; End the group.
 301   (dump-fop 'fop-verify-empty-stack fasl-output)
 302   (dump-fop 'fop-verify-table-size fasl-output)
 303   (dump-unsigned-32 (fasl-output-table-free fasl-output)
 304                     fasl-output)
 305   (dump-fop 'fop-end-group fasl-output)
 306
 307   ;; That's all, folks.
 308   (close (fasl-output-stream fasl-output) :abort abort-p)
 309   (values))
 310 \f
 311 ;;;; main entries to object dumping
 312
 313 ;;; This function deals with dumping objects that are complex enough
 314 ;;; so that we want to cache them in the table, rather than repeatedly
 315 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 316 ;;; otherwise, we do a type dispatch to a type specific dumping
 317 ;;; function. The type specific branches do any appropriate
 318 ;;; EQUAL-TABLE check and table entry.
 319 ;;;
 320 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 321 (defun dump-non-immediate-object (x file)
 322   (let ((index (gethash x (fasl-output-eq-table file))))
 323     (cond ((and index (not *cold-load-dump*))
 324            (dump-push index file))
 325           (t
 326            (typecase x
 327              (symbol (dump-symbol x file))
 328              (list
 329               ;; KLUDGE: The code in this case has been hacked
 330               ;; to match Douglas Crosher's quick fix to CMU CL
 331               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 332               ;; with help from Martin Atzmueller. This is not an
 333               ;; ideal solution; to quote DTC,
 334               ;;   The compiler locks up trying to coalesce the
 335               ;;   constant lists. The hack below will disable the
 336               ;;   coalescing of lists while dumping and allows
 337               ;;   the code to compile. The real fix would be to
 338               ;;   take a little more care while dumping these.
 339               ;; So if better list coalescing is needed, start here.
 340               ;; -- WHN 2000-11-07
 341               (if (cyclic-list-p x)
 342                   (progn
 343                     (dump-list x file)
 344                     (eq-save-object x file))
 345                   (unless (equal-check-table x file)
 346                     (dump-list x file)
 347                     (equal-save-object x file))))
 348              (layout
 349               (dump-layout x file)
 350               (eq-save-object x file))
 351              (instance
 352               (dump-structure x file)
 353               (eq-save-object x file))
 354              (array
 355               ;; FIXME: The comment at the head of
 356               ;; DUMP-NON-IMMEDIATE-OBJECT says it's for objects which
 357               ;; we want to save, instead of repeatedly dumping them.
 358               ;; But then we dump arrays here without doing anything
 359               ;; like EQUAL-SAVE-OBJECT. What gives?
 360               (dump-array x file))
 361              (number
 362               (unless (equal-check-table x file)
 363                 (etypecase x
 364                   (ratio (dump-ratio x file))
 365                   (complex (dump-complex x file))
 366                   (float (dump-float x file))
 367                   (integer (dump-integer x file)))
 368                 (equal-save-object x file)))
 369              (t
 370               ;; This probably never happens, since bad things tend to
 371               ;; be detected during IR1 conversion.
 372               (error "This object cannot be dumped into a fasl file:~% ~S"
 373                      x))))))
 374   (values))
 375
 376 ;;; Dump an object of any type by dispatching to the correct
 377 ;;; type-specific dumping function. We pick off immediate objects,
 378 ;;; symbols and and magic lists here. Other objects are handled by
 379 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 380 ;;;
 381 ;;; This is the function used for recursive calls to the fasl dumper.
 382 ;;; We don't worry about creating circularities here, since it is
 383 ;;; assumed that there is a top level call to DUMP-OBJECT.
 384 (defun sub-dump-object (x file)
 385   (cond ((listp x)
 386          (if x
 387              (dump-non-immediate-object x file)
 388              (dump-fop 'fop-empty-list file)))
 389         ((symbolp x)
 390          (if (eq x t)
 391              (dump-fop 'fop-truth file)
 392              (dump-non-immediate-object x file)))
 393         ((fixnump x) (dump-integer x file))
 394         ((characterp x) (dump-character x file))
 395         (t
 396          (dump-non-immediate-object x file))))
 397
 398 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 399 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 400 ;;; take the value to store on the stack. We compute this value by
 401 ;;; fetching the enclosing object from the table, and then CDR'ing it
 402 ;;; if necessary.
 403 (defun dump-circularities (infos file)
 404   (let ((table (fasl-output-eq-table file)))
 405     (dolist (info infos)
 406
 407       (let* ((value (circularity-value info))
 408              (enclosing (circularity-enclosing-object info)))
 409         (dump-push (gethash enclosing table) file)
 410         (unless (eq enclosing value)
 411           (do ((current enclosing (cdr current))
 412                (i 0 (1+ i)))
 413               ((eq current value)
 414                (dump-fop 'fop-nthcdr file)
 415                (dump-unsigned-32 i file))
 416             (declare (type index i)))))
 417
 418       (ecase (circularity-type info)
 419         (:rplaca     (dump-fop 'fop-rplaca    file))
 420         (:rplacd     (dump-fop 'fop-rplacd    file))
 421         (:svset      (dump-fop 'fop-svset     file))
 422         (:struct-set (dump-fop 'fop-structset file)))
 423       (dump-unsigned-32 (gethash (circularity-object info) table) file)
 424       (dump-unsigned-32 (circularity-index info) file))))
 425
 426 ;;; Set up stuff for circularity detection, then dump an object. All
 427 ;;; shared and circular structure will be exactly preserved within a
 428 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 429 ;;; separate calls is only preserved when convenient.
 430 ;;;
 431 ;;; We peek at the object type so that we only pay the circular
 432 ;;; detection overhead on types of objects that might be circular.
 433 (defun dump-object (x file)
 434   (if (compound-object-p x)
 435       (let ((*circularities-detected* ())
 436             (circ (fasl-output-circularity-table file)))
 437         (clrhash circ)
 438         (sub-dump-object x file)
 439         (when *circularities-detected*
 440           (dump-circularities *circularities-detected* file)
 441           (clrhash circ)))
 442       (sub-dump-object x file)))
 443 \f
 444 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 445
 446 ;;; Emit a funcall of the function and return the handle for the
 447 ;;; result.
 448 (defun fasl-dump-load-time-value-lambda (fun file)
 449   (declare (type sb!c::clambda fun) (type fasl-output file))
 450   (let ((handle (gethash (sb!c::leaf-info fun)
 451                          (fasl-output-entry-table file))))
 452     (aver handle)
 453     (dump-push handle file)
 454     (dump-fop 'fop-funcall file)
 455     (dump-byte 0 file))
 456   (dump-pop file))
 457
 458 ;;; Return T iff CONSTANT has not already been dumped. It's been
 459 ;;; dumped if it's in the EQ table.
 460 (defun fasl-constant-already-dumped-p (constant file)
 461   (if (or (gethash constant (fasl-output-eq-table file))
 462           (gethash constant (fasl-output-valid-structures file)))
 463       t
 464       nil))
 465
 466 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 467 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 468 (defun fasl-note-handle-for-constant (constant handle file)
 469   (let ((table (fasl-output-eq-table file)))
 470     (when (gethash constant table)
 471       (error "~S already dumped?" constant))
 472     (setf (gethash constant table) handle))
 473   (values))
 474
 475 ;;; Note that the specified structure can just be dumped by
 476 ;;; enumerating the slots.
 477 (defun fasl-validate-structure (structure file)
 478   (setf (gethash structure (fasl-output-valid-structures file)) t)
 479   (values))
 480 \f
 481 ;;;; number dumping
 482
 483 ;;; Dump a ratio.
 484 (defun dump-ratio (x file)
 485   (sub-dump-object (numerator x) file)
 486   (sub-dump-object (denominator x) file)
 487   (dump-fop 'fop-ratio file))
 488
 489 ;;; Dump an integer.
 490 (defun dump-integer (n file)
 491   (typecase n
 492     ((signed-byte 8)
 493      (dump-fop 'fop-byte-integer file)
 494      (dump-byte (logand #xFF n) file))
 495     ((unsigned-byte 31)
 496      (dump-fop 'fop-word-integer file)
 497      (dump-unsigned-32 n file))
 498     ((signed-byte 32)
 499      (dump-fop 'fop-word-integer file)
 500      (dump-integer-as-n-bytes n 4 file))
 501     (t
 502      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 503        (dump-fop* bytes fop-small-integer fop-integer file)
 504        (dump-integer-as-n-bytes n bytes file)))))
 505
 506 (defun dump-float (x file)
 507   (etypecase x
 508     (single-float
 509      (dump-fop 'fop-single-float file)
 510      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 511     (double-float
 512      (dump-fop 'fop-double-float file)
 513      (let ((x x))
 514        (declare (double-float x))
 515        ;; FIXME: Why sometimes DUMP-UNSIGNED-32 and sometimes
 516        ;; DUMP-INTEGER-AS-N-BYTES .. 4?
 517        (dump-unsigned-32 (double-float-low-bits x) file)
 518        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 519     #!+long-float
 520     (long-float
 521      (dump-fop 'fop-long-float file)
 522      (dump-long-float x file))))
 523
 524 (defun dump-complex (x file)
 525   (typecase x
 526     #-sb-xc-host
 527     ((complex single-float)
 528      (dump-fop 'fop-complex-single-float file)
 529      (dump-integer-as-n-bytes (single-float-bits (realpart x)) 4 file)
 530      (dump-integer-as-n-bytes (single-float-bits (imagpart x)) 4 file))
 531     #-sb-xc-host
 532     ((complex double-float)
 533      (dump-fop 'fop-complex-double-float file)
 534      (let ((re (realpart x)))
 535        (declare (double-float re))
 536        (dump-unsigned-32 (double-float-low-bits re) file)
 537        (dump-integer-as-n-bytes (double-float-high-bits re) 4 file))
 538      (let ((im (imagpart x)))
 539        (declare (double-float im))
 540        (dump-unsigned-32 (double-float-low-bits im) file)
 541        (dump-integer-as-n-bytes (double-float-high-bits im) 4 file)))
 542     #!+long-float
 543     ((complex long-float)
 544      ;; (There's no easy way to mix #!+LONG-FLOAT and #-SB-XC-HOST
 545      ;; conditionalization at read time, so we do this SB-XC-HOST
 546      ;; conditional at runtime instead.)
 547      #+sb-xc-host (error "can't dump COMPLEX-LONG-FLOAT in cross-compiler")
 548      (dump-fop 'fop-complex-long-float file)
 549      (dump-long-float (realpart x) file)
 550      (dump-long-float (imagpart x) file))
 551     (t
 552      (sub-dump-object (realpart x) file)
 553      (sub-dump-object (imagpart x) file)
 554      (dump-fop 'fop-complex file))))
 555 \f
 556 ;;;; symbol dumping
 557
 558 ;;; Return the table index of PKG, adding the package to the table if
 559 ;;; necessary. During cold load, we read the string as a normal string
 560 ;;; so that we can do the package lookup at cold load time.
 561 ;;;
 562 ;;; FIXME: Despite the parallelism in names, the functionality of
 563 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 564 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 565 ;;; should be made more consistent.
 566 (defun dump-package (pkg file)
 567   (declare (type package pkg) (type fasl-output file))
 568   (declare (values index))
 569   (declare (inline assoc))
 570   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 571         (t
 572          (unless *cold-load-dump*
 573            (dump-fop 'fop-normal-load file))
 574          (dump-simple-string (package-name pkg) file)
 575          (dump-fop 'fop-package file)
 576          (unless *cold-load-dump*
 577            (dump-fop 'fop-maybe-cold-load file))
 578          (let ((entry (dump-pop file)))
 579            (push (cons pkg entry) (fasl-output-packages file))
 580            entry))))
 581 \f
 582 ;;; dumper for lists
 583
 584 ;;; Dump a list, setting up patching information when there are
 585 ;;; circularities. We scan down the list, checking for CDR and CAR
 586 ;;; circularities.
 587 ;;;
 588 ;;; If there is a CDR circularity, we terminate the list with NIL and
 589 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 590 ;;;
 591 ;;; If there is no CDR circularity, then we mark the current cons and
 592 ;;; check for a CAR circularity. When there is a CAR circularity, we
 593 ;;; make the CAR NIL initially, arranging for the current cons to be
 594 ;;; patched later.
 595 ;;;
 596 ;;; Otherwise, we recursively call the dumper to dump the current
 597 ;;; element.
 598 ;;;
 599 ;;; Marking of the conses is inhibited when *COLD-LOAD-DUMP* is true.
 600 ;;; This inhibits all circularity detection.
 601 (defun dump-list (list file)
 602   (aver (and list
 603              (not (gethash list (fasl-output-circularity-table file)))))
 604   (do* ((l list (cdr l))
 605         (n 0 (1+ n))
 606         (circ (fasl-output-circularity-table file)))
 607        ((atom l)
 608         (cond ((null l)
 609                (terminate-undotted-list n file))
 610               (t
 611                (sub-dump-object l file)
 612                (terminate-dotted-list n file))))
 613     (declare (type index n))
 614     (let ((ref (gethash l circ)))
 615       (when ref
 616         (push (make-circularity :type :rplacd
 617                                 :object list
 618                                 :index (1- n)
 619                                 :value l
 620                                 :enclosing-object ref)
 621               *circularities-detected*)
 622         (terminate-undotted-list n file)
 623         (return)))
 624
 625     (unless *cold-load-dump*
 626       (setf (gethash l circ) list))
 627
 628     (let* ((obj (car l))
 629            (ref (gethash obj circ)))
 630       (cond (ref
 631              (push (make-circularity :type :rplaca
 632                                      :object list
 633                                      :index n
 634                                      :value obj
 635                                      :enclosing-object ref)
 636                    *circularities-detected*)
 637              (sub-dump-object nil file))
 638             (t
 639              (sub-dump-object obj file))))))
 640
 641 (defun terminate-dotted-list (n file)
 642   (declare (type index n) (type fasl-output file))
 643   (case n
 644     (1 (dump-fop 'fop-list*-1 file))
 645     (2 (dump-fop 'fop-list*-2 file))
 646     (3 (dump-fop 'fop-list*-3 file))
 647     (4 (dump-fop 'fop-list*-4 file))
 648     (5 (dump-fop 'fop-list*-5 file))
 649     (6 (dump-fop 'fop-list*-6 file))
 650     (7 (dump-fop 'fop-list*-7 file))
 651     (8 (dump-fop 'fop-list*-8 file))
 652     (T (do ((nn n (- nn 255)))
 653            ((< nn 256)
 654             (dump-fop 'fop-list* file)
 655             (dump-byte nn file))
 656          (declare (type index nn))
 657          (dump-fop 'fop-list* file)
 658          (dump-byte 255 file)))))
 659
 660 ;;; If N > 255, must build list with one LIST operator, then LIST*
 661 ;;; operators.
 662
 663 (defun terminate-undotted-list (n file)
 664   (declare (type index n) (type fasl-output file))
 665   (case n
 666     (1 (dump-fop 'fop-list-1 file))
 667     (2 (dump-fop 'fop-list-2 file))
 668     (3 (dump-fop 'fop-list-3 file))
 669     (4 (dump-fop 'fop-list-4 file))
 670     (5 (dump-fop 'fop-list-5 file))
 671     (6 (dump-fop 'fop-list-6 file))
 672     (7 (dump-fop 'fop-list-7 file))
 673     (8 (dump-fop 'fop-list-8 file))
 674     (T (cond ((< n 256)
 675               (dump-fop 'fop-list file)
 676               (dump-byte n file))
 677              (t (dump-fop 'fop-list file)
 678                 (dump-byte 255 file)
 679                 (do ((nn (- n 255) (- nn 255)))
 680                     ((< nn 256)
 681                      (dump-fop 'fop-list* file)
 682                      (dump-byte nn file))
 683                   (declare (type index nn))
 684                   (dump-fop 'fop-list* file)
 685                   (dump-byte 255 file)))))))
 686 \f
 687 ;;;; array dumping
 688
 689 ;;; Dump the array thing.
 690 (defun dump-array (x file)
 691   (if (vectorp x)
 692       (dump-vector x file)
 693       (dump-multi-dim-array x file)))
 694
 695 ;;; Dump the vector object. If it's not simple, then actually dump a
 696 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 697 ;;; tables.
 698 (defun dump-vector (x file)
 699   (let ((simple-version (if (array-header-p x)
 700                             (coerce x 'simple-array)
 701                             x)))
 702     (typecase simple-version
 703       (simple-base-string
 704        (unless (equal-check-table x file)
 705          (dump-simple-string simple-version file)
 706          (equal-save-object x file)))
 707       (simple-vector
 708        (dump-simple-vector simple-version file)
 709        (eq-save-object x file))
 710       ((simple-array single-float (*))
 711        (dump-single-float-vector simple-version file)
 712        (eq-save-object x file))
 713       ((simple-array double-float (*))
 714        (dump-double-float-vector simple-version file)
 715        (eq-save-object x file))
 716       #!+long-float
 717       ((simple-array long-float (*))
 718        (dump-long-float-vector simple-version file)
 719        (eq-save-object x file))
 720       ((simple-array (complex single-float) (*))
 721        (dump-complex-single-float-vector simple-version file)
 722        (eq-save-object x file))
 723       ((simple-array (complex double-float) (*))
 724        (dump-complex-double-float-vector simple-version file)
 725        (eq-save-object x file))
 726       #!+long-float
 727       ((simple-array (complex long-float) (*))
 728        (dump-complex-long-float-vector simple-version file)
 729        (eq-save-object x file))
 730       (t
 731        (dump-i-vector simple-version file)
 732        (eq-save-object x file)))))
 733
 734 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 735 (defun dump-simple-vector (v file)
 736   (declare (type simple-vector v) (type fasl-output file))
 737   (note-potential-circularity v file)
 738   (do ((index 0 (1+ index))
 739        (length (length v))
 740        (circ (fasl-output-circularity-table file)))
 741       ((= index length)
 742        (dump-fop* length fop-small-vector fop-vector file))
 743     (let* ((obj (aref v index))
 744            (ref (gethash obj circ)))
 745       (cond (ref
 746              (push (make-circularity :type :svset
 747                                      :object v
 748                                      :index index
 749                                      :value obj
 750                                      :enclosing-object ref)
 751                    *circularities-detected*)
 752              (sub-dump-object nil file))
 753             (t
 754              (sub-dump-object obj file))))))
 755
 756 ;;; In the grand scheme of things I don't pretend to understand any
 757 ;;; more how this works, or indeed whether.  But to write out specialized
 758 ;;; vectors in the same format as fop-int-vector expects to read them
 759 ;;; we need to be target-endian.  dump-integer-as-n-bytes always writes
 760 ;;; little-endian (which is correct for all other integers) so for a bigendian
 761 ;;; target we need to swap octets -- CSR, after DB
 762
 763 (defun octet-swap (word bits)
 764   "BITS must be a multiple of 8"
 765   (do ((input word (ash input -8))
 766        (output 0 (logior (ash output 8) (logand input #xff)))
 767        (bits bits (- bits 8)))
 768       ((<= bits 0) output)))
 769
 770 (defun dump-i-vector (vec file &key data-only)
 771   (declare (type (simple-array * (*)) vec))
 772   (let ((len (length vec)))
 773     (labels ((dump-unsigned-vector (size bytes)
 774                (unless data-only
 775                  (dump-fop 'fop-int-vector file)
 776                  (dump-unsigned-32 len file)
 777                  (dump-byte size file))
 778                ;; The case which is easy to handle in a portable way is when
 779                ;; the element size is a multiple of the output byte size, and
 780                ;; happily that's the only case we need to be portable. (The
 781                ;; cross-compiler has to output debug information (including
 782                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 783                ;; needed in the target SBCL, so we let them be handled with
 784                ;; unportable bit bashing.
 785                (cond ((>= size 8) ; easy cases
 786                       (multiple-value-bind (floor rem) (floor size 8)
 787                         (aver (zerop rem))
 788                         (dovector (i vec)
 789                           (dump-integer-as-n-bytes
 790                            (ecase sb!c:*backend-byte-order*
 791                              (:little-endian i)
 792                              (:big-endian (octet-swap i size)))
 793                            floor file))))
 794                      (t ; harder cases, not supported in cross-compiler
 795                       (dump-raw-bytes vec bytes file))))
 796              (dump-signed-vector (size bytes)
 797                ;; Note: Dumping specialized signed vectors isn't
 798                ;; supported in the cross-compiler. (All cases here end
 799                ;; up trying to call DUMP-RAW-BYTES, which isn't
 800                ;; provided in the cross-compilation host, only on the
 801                ;; target machine.)
 802                (unless data-only
 803                  (dump-fop 'fop-signed-int-vector file)
 804                  (dump-unsigned-32 len file)
 805                  (dump-byte size file))
 806                (dump-raw-bytes vec bytes file)))
 807       (etypecase vec
 808         ;; KLUDGE: What exactly does the (ASH .. -3) stuff do? -- WHN 19990902
 809         (simple-bit-vector
 810          (dump-unsigned-vector 1 (ash (+ (the index len) 7) -3)))
 811         ((simple-array (unsigned-byte 2) (*))
 812          (dump-unsigned-vector 2 (ash (+ (the index (ash len 1)) 7) -3)))
 813         ((simple-array (unsigned-byte 4) (*))
 814          (dump-unsigned-vector 4 (ash (+ (the index (ash len 2)) 7) -3)))
 815         ((simple-array (unsigned-byte 8) (*))
 816          (dump-unsigned-vector 8 len))
 817         ((simple-array (unsigned-byte 16) (*))
 818          (dump-unsigned-vector 16 (* 2 len)))
 819         ((simple-array (unsigned-byte 32) (*))
 820          (dump-unsigned-vector 32 (* 4 len)))
 821         ((simple-array (signed-byte 8) (*))
 822          (dump-signed-vector 8 len))
 823         ((simple-array (signed-byte 16) (*))
 824          (dump-signed-vector 16 (* 2 len)))
 825         ((simple-array (signed-byte 30) (*))
 826          (dump-signed-vector 30 (* 4 len)))
 827         ((simple-array (signed-byte 32) (*))
 828          (dump-signed-vector 32 (* 4 len)))))))
 829 \f
 830 ;;; Dump characters and string-ish things.
 831
 832 (defun dump-character (ch file)
 833   (dump-fop 'fop-short-character file)
 834   (dump-byte (char-code ch) file))
 835
 836 ;;; a helper function shared by DUMP-SIMPLE-STRING and DUMP-SYMBOL
 837 (defun dump-characters-of-string (s fasl-output)
 838   (declare (type string s) (type fasl-output fasl-output))
 839   (dovector (c s)
 840     (dump-byte (char-code c) fasl-output))
 841   (values))
 842
 843 ;;; Dump a SIMPLE-BASE-STRING.
 844 ;;; FIXME: should be called DUMP-SIMPLE-BASE-STRING then
 845 (defun dump-simple-string (s file)
 846   (declare (type simple-base-string s))
 847   (dump-fop* (length s) fop-small-string fop-string file)
 848   (dump-characters-of-string s file)
 849   (values))
 850
 851 ;;; If we get here, it is assumed that the symbol isn't in the table,
 852 ;;; but we are responsible for putting it there when appropriate. To
 853 ;;; avoid too much special-casing, we always push the symbol in the
 854 ;;; table, but don't record that we have done so if *COLD-LOAD-DUMP*
 855 ;;; is true.
 856 (defun dump-symbol (s file)
 857   (declare (type fasl-output file))
 858   (let* ((pname (symbol-name s))
 859          (pname-length (length pname))
 860          (pkg (symbol-package s)))
 861
 862     (cond ((null pkg)
 863            (dump-fop* pname-length
 864                       fop-uninterned-small-symbol-save
 865                       fop-uninterned-symbol-save
 866                       file))
 867           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 868           ;; used the current value of *PACKAGE*. Unfortunately that's
 869           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 870           ;; from SBCL.
 871           ;;((eq pkg *package*)
 872           ;; (dump-fop* pname-length
 873           ;;        fop-small-symbol-save
 874           ;;        fop-symbol-save file))
 875           ((eq pkg sb!int:*cl-package*)
 876            (dump-fop* pname-length
 877                       fop-lisp-small-symbol-save
 878                       fop-lisp-symbol-save
 879                       file))
 880           ((eq pkg sb!int:*keyword-package*)
 881            (dump-fop* pname-length
 882                       fop-keyword-small-symbol-save
 883                       fop-keyword-symbol-save
 884                       file))
 885           ((< pname-length 256)
 886            (dump-fop* (dump-package pkg file)
 887                       fop-small-symbol-in-byte-package-save
 888                       fop-small-symbol-in-package-save
 889                       file)
 890            (dump-byte pname-length file))
 891           (t
 892            (dump-fop* (dump-package pkg file)
 893                       fop-symbol-in-byte-package-save
 894                       fop-symbol-in-package-save
 895                       file)
 896            (dump-unsigned-32 pname-length file)))
 897
 898     (dump-characters-of-string pname file)
 899
 900     (unless *cold-load-dump*
 901       (setf (gethash s (fasl-output-eq-table file))
 902             (fasl-output-table-free file)))
 903
 904     (incf (fasl-output-table-free file)))
 905
 906   (values))
 907 \f
 908 ;;;; component (function) dumping
 909
 910 (defun dump-segment (segment code-length fasl-output)
 911   (declare (type sb!assem:segment segment)
 912            (type fasl-output fasl-output))
 913   (let* ((stream (fasl-output-stream fasl-output))
 914          (n-written (write-segment-contents segment stream)))
 915     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
 916     ;; argument and the number of bytes actually written. I added this
 917     ;; assertion while trying to debug portable genesis. -- WHN 19990902
 918     (unless (= code-length n-written)
 919       (bug "code-length=~W, n-written=~W" code-length n-written)))
 920   (values))
 921
 922 ;;; Dump all the fixups. Currently there are three flavors of fixup:
 923 ;;;  - assembly routines: named by a symbol
 924 ;;;  - foreign (C) symbols: named by a string
 925 ;;;  - code object references: don't need a name.
 926 (defun dump-fixups (fixups fasl-output)
 927   (declare (list fixups) (type fasl-output fasl-output))
 928   (dolist (info fixups)
 929     ;; FIXME: Packing data with LIST in NOTE-FIXUP and unpacking them
 930     ;; with FIRST, SECOND, and THIRD here is hard to follow and
 931     ;; maintain. Perhaps we could define a FIXUP-INFO structure to use
 932     ;; instead, and rename *FIXUPS* to *FIXUP-INFO-LIST*?
 933     (let* ((kind (first info))
 934            (fixup (second info))
 935            (name (fixup-name fixup))
 936            (flavor (fixup-flavor fixup))
 937            (offset (third info)))
 938       ;; FIXME: This OFFSET is not what's called OFFSET in the FIXUP
 939       ;; structure, it's what's called POSN in NOTE-FIXUP. (As far as
 940       ;; I can tell, FIXUP-OFFSET is not actually an offset, it's an
 941       ;; internal label used instead of NAME for :CODE-OBJECT fixups.
 942       ;; Notice that in the :CODE-OBJECT case, NAME is ignored.)
 943       (dump-fop 'fop-normal-load fasl-output)
 944       (let ((*cold-load-dump* t))
 945         (dump-object kind fasl-output))
 946       (dump-fop 'fop-maybe-cold-load fasl-output)
 947       ;; Depending on the flavor, we may have various kinds of
 948       ;; noise before the offset.
 949       (ecase flavor
 950         (:assembly-routine
 951          (aver (symbolp name))
 952          (dump-fop 'fop-normal-load fasl-output)
 953          (let ((*cold-load-dump* t))
 954            (dump-object name fasl-output))
 955          (dump-fop 'fop-maybe-cold-load fasl-output)
 956          (dump-fop 'fop-assembler-fixup fasl-output))
 957         (:foreign
 958          (aver (stringp name))
 959          (dump-fop 'fop-foreign-fixup fasl-output)
 960          (let ((len (length name)))
 961            (aver (< len 256)) ; (limit imposed by fop definition)
 962            (dump-byte len fasl-output)
 963            (dotimes (i len)
 964              (dump-byte (char-code (schar name i)) fasl-output))))
 965         (:code-object
 966          (aver (null name))
 967          (dump-fop 'fop-code-object-fixup fasl-output)))
 968       ;; No matter what the flavor, we'll always dump the offset.
 969       (dump-unsigned-32 offset fasl-output)))
 970   (values))
 971
 972 ;;; Dump out the constant pool and code-vector for component, push the
 973 ;;; result in the table, and return the offset.
 974 ;;;
 975 ;;; The only tricky thing is handling constant-pool references to
 976 ;;; functions. If we have already dumped the function, then we just
 977 ;;; push the code pointer. Otherwise, we must create back-patching
 978 ;;; information so that the constant will be set when the function is
 979 ;;; eventually dumped. This is a bit awkward, since we don't have the
 980 ;;; handle for the code object being dumped while we are dumping its
 981 ;;; constants.
 982 ;;;
 983 ;;; We dump trap objects in any unused slots or forward referenced slots.
 984 (defun dump-code-object (component
 985                          code-segment
 986                          code-length
 987                          trace-table-as-list
 988                          fixups
 989                          fasl-output)
 990
 991   (declare (type component component)
 992            (list trace-table-as-list)
 993            (type index code-length)
 994            (type fasl-output fasl-output))
 995
 996   (let* ((2comp (component-info component))
 997          (constants (sb!c::ir2-component-constants 2comp))
 998          (header-length (length constants))
 999          (packed-trace-table (pack-trace-table trace-table-as-list))
1000          (total-length (+ code-length
1001                           (* (length packed-trace-table)
1002                              sb!c::tt-bytes-per-entry))))
1003
1004     (collect ((patches))
1005
1006       ;; Dump the offset of the trace table.
1007       (dump-object code-length fasl-output)
1008       ;; FIXME: As long as we don't have GENGC, the trace table is
1009       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
1010       ;; far as I know no modern CMU CL does either -- WHN
1011       ;; 2001-10-05). So might we be able to get rid of trace tables?
1012
1013       ;; Dump the constants, noting any :ENTRY constants that have to
1014       ;; be patched.
1015       (loop for i from sb!vm:code-constants-offset below header-length do
1016         (let ((entry (aref constants i)))
1017           (etypecase entry
1018             (constant
1019              (dump-object (sb!c::constant-value entry) fasl-output))
1020             (cons
1021              (ecase (car entry)
1022                (:entry
1023                 (let* ((info (sb!c::leaf-info (cdr entry)))
1024                        (handle (gethash info
1025                                         (fasl-output-entry-table
1026                                          fasl-output))))
1027                   (declare (type sb!c::entry-info info))
1028                   (cond
1029                    (handle
1030                     (dump-push handle fasl-output))
1031                    (t
1032                     (patches (cons info i))
1033                     (dump-fop 'fop-misc-trap fasl-output)))))
1034                (:load-time-value
1035                 (dump-push (cdr entry) fasl-output))
1036                (:fdefinition
1037                 (dump-object (cdr entry) fasl-output)
1038                 (dump-fop 'fop-fdefinition fasl-output))))
1039             (null
1040              (dump-fop 'fop-misc-trap fasl-output)))))
1041
1042       ;; Dump the debug info.
1043       (let ((info (sb!c::debug-info-for-component component))
1044             (*dump-only-valid-structures* nil))
1045         (dump-object info fasl-output)
1046         (let ((info-handle (dump-pop fasl-output)))
1047           (dump-push info-handle fasl-output)
1048           (push info-handle (fasl-output-debug-info fasl-output))))
1049
1050       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1051         (cond ((and (< num-consts #x100) (< total-length #x10000))
1052                (dump-fop 'fop-small-code fasl-output)
1053                (dump-byte num-consts fasl-output)
1054                (dump-integer-as-n-bytes total-length 2 fasl-output))
1055               (t
1056                (dump-fop 'fop-code fasl-output)
1057                (dump-unsigned-32 num-consts fasl-output)
1058                (dump-unsigned-32 total-length fasl-output))))
1059
1060       ;; These two dumps are only ones which contribute to our
1061       ;; TOTAL-LENGTH value.
1062       (dump-segment code-segment code-length fasl-output)
1063       (dump-i-vector packed-trace-table fasl-output :data-only t)
1064
1065       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1066       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1067       ;; FOP-CODE/FOP-SMALL-CODE fop.
1068       (dump-fixups fixups fasl-output)
1069
1070       (dump-fop 'fop-sanctify-for-execution fasl-output)
1071
1072       (let ((handle (dump-pop fasl-output)))
1073         (dolist (patch (patches))
1074           (push (cons handle (cdr patch))
1075                 (gethash (car patch)
1076                          (fasl-output-patch-table fasl-output))))
1077         handle))))
1078
1079 (defun dump-assembler-routines (code-segment length fixups routines file)
1080   (dump-fop 'fop-assembler-code file)
1081   (dump-unsigned-32 length file)
1082   (write-segment-contents code-segment (fasl-output-stream file))
1083   (dolist (routine routines)
1084     (dump-fop 'fop-normal-load file)
1085     (let ((*cold-load-dump* t))
1086       (dump-object (car routine) file))
1087     (dump-fop 'fop-maybe-cold-load file)
1088     (dump-fop 'fop-assembler-routine file)
1089     (dump-unsigned-32 (label-position (cdr routine)) file))
1090   (dump-fixups fixups file)
1091   (dump-fop 'fop-sanctify-for-execution file)
1092   (dump-pop file))
1093
1094 ;;; Dump a function entry data structure corresponding to ENTRY to
1095 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1096 ;;; component.
1097 (defun dump-one-entry (entry code-handle file)
1098   (declare (type sb!c::entry-info entry) (type index code-handle)
1099            (type fasl-output file))
1100   (let ((name (sb!c::entry-info-name entry)))
1101     (dump-push code-handle file)
1102     (dump-object name file)
1103     (dump-object (sb!c::entry-info-arguments entry) file)
1104     (dump-object (sb!c::entry-info-type entry) file)
1105     (dump-fop 'fop-fun-entry file)
1106     (dump-unsigned-32 (label-position (sb!c::entry-info-offset entry)) file)
1107     (dump-pop file)))
1108
1109 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1110 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1111 (defun dump-alter-code-object (code-handle offset entry-handle file)
1112   (declare (type index code-handle entry-handle offset))
1113   (declare (type fasl-output file))
1114   (dump-push code-handle file)
1115   (dump-push entry-handle file)
1116   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1117   (values))
1118
1119 ;;; Dump the code, constants, etc. for component. We pass in the
1120 ;;; assembler fixups, code vector and node info.
1121 (defun fasl-dump-component (component
1122                             code-segment
1123                             code-length
1124                             trace-table
1125                             fixups
1126                             file)
1127   (declare (type component component) (list trace-table))
1128   (declare (type fasl-output file))
1129
1130   (dump-fop 'fop-verify-empty-stack file)
1131   (dump-fop 'fop-verify-table-size file)
1132   (dump-unsigned-32 (fasl-output-table-free file) file)
1133
1134   #!+sb-dyncount
1135   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1136     (when info
1137       (fasl-validate-structure info file)))
1138
1139   (let ((code-handle (dump-code-object component
1140                                        code-segment
1141                                        code-length
1142                                        trace-table
1143                                        fixups
1144                                        file))
1145         (2comp (component-info component)))
1146     (dump-fop 'fop-verify-empty-stack file)
1147
1148     (dolist (entry (sb!c::ir2-component-entries 2comp))
1149       (let ((entry-handle (dump-one-entry entry code-handle file)))
1150         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1151         (let ((old (gethash entry (fasl-output-patch-table file))))
1152           (when old
1153             (dolist (patch old)
1154               (dump-alter-code-object (car patch)
1155                                       (cdr patch)
1156                                       entry-handle
1157                                       file))
1158             (remhash entry (fasl-output-patch-table file)))))))
1159   (values))
1160
1161 (defun dump-push-previously-dumped-fun (fun fasl-output)
1162   (declare (type sb!c::clambda fun))
1163   (let ((handle (gethash (sb!c::leaf-info fun)
1164                          (fasl-output-entry-table fasl-output))))
1165     (aver handle)
1166     (dump-push handle fasl-output))
1167   (values))
1168
1169 ;;; Dump a FOP-FUNCALL to call an already-dumped top level lambda at
1170 ;;; load time.
1171 (defun fasl-dump-toplevel-lambda-call (fun fasl-output)
1172   (declare (type sb!c::clambda fun))
1173   (dump-push-previously-dumped-fun fun fasl-output)
1174   (dump-fop 'fop-funcall-for-effect fasl-output)
1175   (dump-byte 0 fasl-output)
1176   (values))
1177
1178 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1179 ;;; FUN-NAME and the already-dumped function whose dump handle is
1180 ;;; FUN-DUMP-HANDLE.
1181 #+sb-xc-host
1182 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1183   (declare (type fixnum fun-dump-handle))
1184   (aver (legal-fun-name-p fun-name))
1185   (dump-non-immediate-object fun-name fasl-output)
1186   (dump-push fun-dump-handle fasl-output)
1187   (dump-fop 'fop-fset fasl-output)
1188   (values))
1189
1190 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1191 ;;; all of the dumped DEBUG-INFO structures. We clear the
1192 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1193 ;;; different source info may be dumped.
1194 (defun fasl-dump-source-info (info fasl-output)
1195   (declare (type sb!c::source-info info))
1196   (let ((res (sb!c::debug-source-for-info info))
1197         (*dump-only-valid-structures* nil))
1198     (dump-object res fasl-output)
1199     (let ((res-handle (dump-pop fasl-output)))
1200       (dolist (info-handle (fasl-output-debug-info fasl-output))
1201         (dump-push res-handle fasl-output)
1202         (dump-fop 'fop-structset fasl-output)
1203         (dump-unsigned-32 info-handle fasl-output)
1204         (dump-unsigned-32 2 fasl-output))))
1205   (setf (fasl-output-debug-info fasl-output) nil)
1206   (values))
1207 \f
1208 ;;;; dumping structures
1209
1210 (defun dump-structure (struct file)
1211   (when *dump-only-valid-structures*
1212     (unless (gethash struct (fasl-output-valid-structures file))
1213       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1214              struct)))
1215   (note-potential-circularity struct file)
1216   (do ((index 0 (1+ index))
1217        (length (%instance-length struct))
1218        (circ (fasl-output-circularity-table file)))
1219       ((= index length)
1220        (dump-fop* length fop-small-struct fop-struct file))
1221     (let* ((obj (%instance-ref struct index))
1222            (ref (gethash obj circ)))
1223       (cond (ref
1224              (push (make-circularity :type :struct-set
1225                                      :object struct
1226                                      :index index
1227                                      :value obj
1228                                      :enclosing-object ref)
1229                    *circularities-detected*)
1230              (sub-dump-object nil file))
1231             (t
1232              (sub-dump-object obj file))))))
1233
1234 (defun dump-layout (obj file)
1235   (when (layout-invalid obj)
1236     (compiler-error "attempt to dump reference to obsolete class: ~S"
1237                     (layout-class obj)))
1238   (let ((name (sb!xc:class-name (layout-class obj))))
1239     (unless name
1240       (compiler-error "dumping anonymous layout: ~S" obj))
1241     (dump-fop 'fop-normal-load file)
1242     (let ((*cold-load-dump* t))
1243       (dump-object name file))
1244     (dump-fop 'fop-maybe-cold-load file))
1245   (sub-dump-object (layout-inherits obj) file)
1246   (sub-dump-object (layout-depthoid obj) file)
1247   (sub-dump-object (layout-length obj) file)
1248   (dump-fop 'fop-layout file))