src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (missing-arg) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance patholigies with objects for which EQUAL degnerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the ENTRY-INFO structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the ENTRY-INFO structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (missing-arg) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (missing-arg) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to inhibit table access when dumping forms to be read by the
  95 ;;; cold loader
  96 (defvar *cold-load-dump* nil)
  97
  98 ;;; used to turn off the structure validation during dumping of source
  99 ;;; info
 100 (defvar *dump-only-valid-structures* t)
 101 ;;;; utilities
 102
 103 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 104 (defun dump-byte (b fasl-output)
 105   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 106   (write-byte b (fasl-output-stream fasl-output)))
 107
 108 ;;; Dump a 4 byte unsigned integer.
 109 (defun dump-unsigned-32 (num fasl-output)
 110   (declare (type (unsigned-byte 32) num))
 111   (declare (type fasl-output fasl-output))
 112   (let ((stream (fasl-output-stream fasl-output)))
 113     (dotimes (i 4)
 114       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 115
 116 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 117 ;;; for either signed or unsigned integers. There's no range checking
 118 ;;; -- if you don't specify enough bytes for the number to fit, this
 119 ;;; function cheerfully outputs the low bytes.
 120 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 121   (declare (integer num) (type index bytes))
 122   (declare (type fasl-output fasl-output))
 123   (do ((n num (ash n -8))
 124        (i bytes (1- i)))
 125       ((= i 0))
 126     (declare (type index i))
 127     (dump-byte (logand n #xff) fasl-output))
 128   (values))
 129
 130 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 131 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 132 ;;; counter value before every ordinary fop. This can make it easier
 133 ;;; to follow the progress of LOAD-AS-FASL when
 134 ;;; debugging/testing/experimenting.
 135 #!+sb-show (defvar *fop-nop4-count* nil)
 136 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 137
 138 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 139 ;;;
 140 ;;; FIXME: This should be a function, with a compiler macro expansion
 141 ;;; for the common constant-FS case. (Among other things, that'll stop
 142 ;;; it from EVALing ,FILE multiple times.)
 143 ;;;
 144 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 145 ;;; optimizations should be conditional on #!+SB-FROZEN.
 146 (defmacro dump-fop (fs file)
 147   (let* ((fs (eval fs))
 148          (val (get fs 'fop-code)))
 149     (if val
 150       `(progn
 151          #!+sb-show
 152          (when *fop-nop4-count*
 153            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 154            (dump-unsigned-32 (mod (incf *fop-nop4-count*) (expt 2 32)) ,file))
 155          (dump-byte ',val ,file))
 156       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 157
 158 ;;; Dump a FOP-CODE along with an integer argument, choosing the FOP
 159 ;;; based on whether the argument will fit in a single byte.
 160 ;;;
 161 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 162 ;;; compiler-macro expansion.
 163 (defmacro dump-fop* (n byte-fop word-fop file)
 164   (once-only ((n-n n)
 165               (n-file file))
 166     `(cond ((< ,n-n 256)
 167             (dump-fop ',byte-fop ,n-file)
 168             (dump-byte ,n-n ,n-file))
 169            (t
 170             (dump-fop ',word-fop ,n-file)
 171             (dump-unsigned-32 ,n-n ,n-file)))))
 172
 173 ;;; Push the object at table offset Handle on the fasl stack.
 174 (defun dump-push (handle fasl-output)
 175   (declare (type index handle) (type fasl-output fasl-output))
 176   (dump-fop* handle fop-byte-push fop-push fasl-output)
 177   (values))
 178
 179 ;;; Pop the object currently on the fasl stack top into the table, and
 180 ;;; return the table index, incrementing the free pointer.
 181 (defun dump-pop (fasl-output)
 182   (prog1
 183       (fasl-output-table-free fasl-output)
 184     (dump-fop 'fop-pop fasl-output)
 185     (incf (fasl-output-table-free fasl-output))))
 186
 187 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 188 ;;; otherwise NIL. If *COLD-LOAD-DUMP* is true, then do nothing and
 189 ;;; return NIL.
 190 (defun equal-check-table (x fasl-output)
 191   (declare (type fasl-output fasl-output))
 192   (unless *cold-load-dump*
 193     (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 194       (cond (handle
 195              (dump-push handle fasl-output)
 196              t)
 197             (t
 198              nil)))))
 199
 200 ;;; These functions are called after dumping an object to save the
 201 ;;; object in the table. The object (also passed in as X) must already
 202 ;;; be on the top of the FOP stack. If *COLD-LOAD-DUMP* is true, then
 203 ;;; we don't do anything.
 204 (defun eq-save-object (x fasl-output)
 205   (declare (type fasl-output fasl-output))
 206   (unless *cold-load-dump*
 207     (let ((handle (dump-pop fasl-output)))
 208       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 209       (dump-push handle fasl-output)))
 210   (values))
 211 (defun equal-save-object (x fasl-output)
 212   (declare (type fasl-output fasl-output))
 213   (unless *cold-load-dump*
 214     (let ((handle (dump-pop fasl-output)))
 215       (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 216       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 217       (dump-push handle fasl-output)))
 218   (values))
 219
 220 ;;; Record X in File's CIRCULARITY-TABLE unless *COLD-LOAD-DUMP* is
 221 ;;; true. This is called on objects that we are about to dump might
 222 ;;; have a circular path through them.
 223 ;;;
 224 ;;; The object must not currently be in this table, since the dumper
 225 ;;; should never be recursively called on a circular reference.
 226 ;;; Instead, the dumping function must detect the circularity and
 227 ;;; arrange for the dumped object to be patched.
 228 (defun note-potential-circularity (x fasl-output)
 229   (unless *cold-load-dump*
 230     (let ((circ (fasl-output-circularity-table fasl-output)))
 231       (aver (not (gethash x circ)))
 232       (setf (gethash x circ) x)))
 233   (values))
 234
 235 ;;; Dump FORM to a fasl file so that it evaluated at load time in normal
 236 ;;; load and at cold-load time in cold load. This is used to dump package
 237 ;;; frobbing forms.
 238 (defun fasl-dump-cold-load-form (form fasl-output)
 239   (declare (type fasl-output fasl-output))
 240   (dump-fop 'fop-normal-load fasl-output)
 241   (let ((*cold-load-dump* t))
 242     (dump-object form fasl-output))
 243   (dump-fop 'fop-eval-for-effect fasl-output)
 244   (dump-fop 'fop-maybe-cold-load fasl-output)
 245   (values))
 246 \f
 247 ;;;; opening and closing fasl files
 248
 249 ;;; A utility function to write strings to (unsigned-byte 8) streams.
 250 ;;; We restrict this to ASCII (with the averrance) because of
 251 ;;; ambiguity of higher bytes: Unicode, some ISO-8859-x, or what? This
 252 ;;; could be revisited in the event of doing funky things with stream
 253 ;;; encodings -- CSR, 2002-04-25
 254 (defun fasl-write-string (string stream)
 255   (loop for char across string
 256         do (let ((code (char-code char)))
 257              (aver (<= 0 code 127))
 258              (write-byte code stream))))
 259
 260 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 261 ;;; object for dumping to it. Some human-readable information about
 262 ;;; the source code is given by the string WHERE. If BYTE-P is true,
 263 ;;; this file will contain no native code, and is thus largely
 264 ;;; implementation independent.
 265 (defun open-fasl-output (name where)
 266   (declare (type pathname name))
 267   (let* ((stream (open name
 268                        :direction :output
 269                        :if-exists :supersede
 270                        :element-type 'sb!assem:assembly-unit))
 271          (res (make-fasl-output :stream stream)))
 272
 273     ;; Begin the header with the constant machine-readable (and
 274     ;; semi-human-readable) string which is used to identify fasl files.
 275     (fasl-write-string *fasl-header-string-start-string* stream)
 276
 277     ;; The constant string which begins the header is followed by
 278     ;; arbitrary human-readable text, terminated by a special
 279     ;; character code.
 280     (fasl-write-string
 281      (with-standard-io-syntax
 282        (format nil
 283                "~%  ~
 284                 compiled from ~S~%  ~
 285                 at ~A~%  ~
 286                 on ~A~%  ~
 287                 using ~A version ~A~%"
 288                 where
 289                 (format-universal-time nil (get-universal-time))
 290                 (machine-instance)
 291                 (sb!xc:lisp-implementation-type)
 292                 (sb!xc:lisp-implementation-version)))
 293      stream)
 294     (dump-byte +fasl-header-string-stop-char-code+ res)
 295
 296     ;; Finish the header by outputting fasl file implementation,
 297     ;; version, and key *FEATURES*.
 298     (flet ((dump-counted-string (string)
 299              (dump-unsigned-32 (length string) res)
 300              (dotimes (i (length string))
 301                (dump-byte (char-code (aref string i)) res))))
 302       (dump-counted-string (symbol-name +backend-fasl-file-implementation+))
 303       (dump-unsigned-32 +fasl-file-version+ res)
 304       (dump-counted-string *features-affecting-fasl-format*))
 305
 306     res))
 307
 308 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 309 (defun close-fasl-output (fasl-output abort-p)
 310   (declare (type fasl-output fasl-output))
 311
 312   ;; sanity checks
 313   (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 314
 315   ;; End the group.
 316   (dump-fop 'fop-verify-empty-stack fasl-output)
 317   (dump-fop 'fop-verify-table-size fasl-output)
 318   (dump-unsigned-32 (fasl-output-table-free fasl-output)
 319                     fasl-output)
 320   (dump-fop 'fop-end-group fasl-output)
 321
 322   ;; That's all, folks.
 323   (close (fasl-output-stream fasl-output) :abort abort-p)
 324   (values))
 325 \f
 326 ;;;; main entries to object dumping
 327
 328 ;;; This function deals with dumping objects that are complex enough
 329 ;;; so that we want to cache them in the table, rather than repeatedly
 330 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 331 ;;; otherwise, we do a type dispatch to a type specific dumping
 332 ;;; function. The type specific branches do any appropriate
 333 ;;; EQUAL-TABLE check and table entry.
 334 ;;;
 335 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 336 (defun dump-non-immediate-object (x file)
 337   (let ((index (gethash x (fasl-output-eq-table file))))
 338     (cond ((and index (not *cold-load-dump*))
 339            (dump-push index file))
 340           (t
 341            (typecase x
 342              (symbol (dump-symbol x file))
 343              (list
 344               ;; KLUDGE: The code in this case has been hacked
 345               ;; to match Douglas Crosher's quick fix to CMU CL
 346               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 347               ;; with help from Martin Atzmueller. This is not an
 348               ;; ideal solution; to quote DTC,
 349               ;;   The compiler locks up trying to coalesce the
 350               ;;   constant lists. The hack below will disable the
 351               ;;   coalescing of lists while dumping and allows
 352               ;;   the code to compile. The real fix would be to
 353               ;;   take a little more care while dumping these.
 354               ;; So if better list coalescing is needed, start here.
 355               ;; -- WHN 2000-11-07
 356               (if (cyclic-list-p x)
 357                   (progn
 358                     (dump-list x file)
 359                     (eq-save-object x file))
 360                   (unless (equal-check-table x file)
 361                     (dump-list x file)
 362                     (equal-save-object x file))))
 363              (layout
 364               (dump-layout x file)
 365               (eq-save-object x file))
 366              (instance
 367               (dump-structure x file)
 368               (eq-save-object x file))
 369              (array
 370               ;; FIXME: The comment at the head of
 371               ;; DUMP-NON-IMMEDIATE-OBJECT says it's for objects which
 372               ;; we want to save, instead of repeatedly dumping them.
 373               ;; But then we dump arrays here without doing anything
 374               ;; like EQUAL-SAVE-OBJECT. What gives?
 375               (dump-array x file))
 376              (number
 377               (unless (equal-check-table x file)
 378                 (etypecase x
 379                   (ratio (dump-ratio x file))
 380                   (complex (dump-complex x file))
 381                   (float (dump-float x file))
 382                   (integer (dump-integer x file)))
 383                 (equal-save-object x file)))
 384              (t
 385               ;; This probably never happens, since bad things tend to
 386               ;; be detected during IR1 conversion.
 387               (error "This object cannot be dumped into a fasl file:~% ~S"
 388                      x))))))
 389   (values))
 390
 391 ;;; Dump an object of any type by dispatching to the correct
 392 ;;; type-specific dumping function. We pick off immediate objects,
 393 ;;; symbols and and magic lists here. Other objects are handled by
 394 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 395 ;;;
 396 ;;; This is the function used for recursive calls to the fasl dumper.
 397 ;;; We don't worry about creating circularities here, since it is
 398 ;;; assumed that there is a top level call to DUMP-OBJECT.
 399 (defun sub-dump-object (x file)
 400   (cond ((listp x)
 401          (if x
 402              (dump-non-immediate-object x file)
 403              (dump-fop 'fop-empty-list file)))
 404         ((symbolp x)
 405          (if (eq x t)
 406              (dump-fop 'fop-truth file)
 407              (dump-non-immediate-object x file)))
 408         ((fixnump x) (dump-integer x file))
 409         ((characterp x) (dump-character x file))
 410         (t
 411          (dump-non-immediate-object x file))))
 412
 413 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 414 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 415 ;;; take the value to store on the stack. We compute this value by
 416 ;;; fetching the enclosing object from the table, and then CDR'ing it
 417 ;;; if necessary.
 418 (defun dump-circularities (infos file)
 419   (let ((table (fasl-output-eq-table file)))
 420     (dolist (info infos)
 421
 422       (let* ((value (circularity-value info))
 423              (enclosing (circularity-enclosing-object info)))
 424         (dump-push (gethash enclosing table) file)
 425         (unless (eq enclosing value)
 426           (do ((current enclosing (cdr current))
 427                (i 0 (1+ i)))
 428               ((eq current value)
 429                (dump-fop 'fop-nthcdr file)
 430                (dump-unsigned-32 i file))
 431             (declare (type index i)))))
 432
 433       (ecase (circularity-type info)
 434         (:rplaca     (dump-fop 'fop-rplaca    file))
 435         (:rplacd     (dump-fop 'fop-rplacd    file))
 436         (:svset      (dump-fop 'fop-svset     file))
 437         (:struct-set (dump-fop 'fop-structset file)))
 438       (dump-unsigned-32 (gethash (circularity-object info) table) file)
 439       (dump-unsigned-32 (circularity-index info) file))))
 440
 441 ;;; Set up stuff for circularity detection, then dump an object. All
 442 ;;; shared and circular structure will be exactly preserved within a
 443 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 444 ;;; separate calls is only preserved when convenient.
 445 ;;;
 446 ;;; We peek at the object type so that we only pay the circular
 447 ;;; detection overhead on types of objects that might be circular.
 448 (defun dump-object (x file)
 449   (if (compound-object-p x)
 450       (let ((*circularities-detected* ())
 451             (circ (fasl-output-circularity-table file)))
 452         (clrhash circ)
 453         (sub-dump-object x file)
 454         (when *circularities-detected*
 455           (dump-circularities *circularities-detected* file)
 456           (clrhash circ)))
 457       (sub-dump-object x file)))
 458 \f
 459 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 460
 461 ;;; Emit a funcall of the function and return the handle for the
 462 ;;; result.
 463 (defun fasl-dump-load-time-value-lambda (fun file)
 464   (declare (type sb!c::clambda fun) (type fasl-output file))
 465   (let ((handle (gethash (sb!c::leaf-info fun)
 466                          (fasl-output-entry-table file))))
 467     (aver handle)
 468     (dump-push handle file)
 469     (dump-fop 'fop-funcall file)
 470     (dump-byte 0 file))
 471   (dump-pop file))
 472
 473 ;;; Return T iff CONSTANT has not already been dumped. It's been
 474 ;;; dumped if it's in the EQ table.
 475 (defun fasl-constant-already-dumped-p (constant file)
 476   (if (or (gethash constant (fasl-output-eq-table file))
 477           (gethash constant (fasl-output-valid-structures file)))
 478       t
 479       nil))
 480
 481 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 482 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 483 (defun fasl-note-handle-for-constant (constant handle file)
 484   (let ((table (fasl-output-eq-table file)))
 485     (when (gethash constant table)
 486       (error "~S already dumped?" constant))
 487     (setf (gethash constant table) handle))
 488   (values))
 489
 490 ;;; Note that the specified structure can just be dumped by
 491 ;;; enumerating the slots.
 492 (defun fasl-validate-structure (structure file)
 493   (setf (gethash structure (fasl-output-valid-structures file)) t)
 494   (values))
 495 \f
 496 ;;;; number dumping
 497
 498 ;;; Dump a ratio.
 499 (defun dump-ratio (x file)
 500   (sub-dump-object (numerator x) file)
 501   (sub-dump-object (denominator x) file)
 502   (dump-fop 'fop-ratio file))
 503
 504 ;;; Dump an integer.
 505 (defun dump-integer (n file)
 506   (typecase n
 507     ((signed-byte 8)
 508      (dump-fop 'fop-byte-integer file)
 509      (dump-byte (logand #xFF n) file))
 510     ((unsigned-byte 31)
 511      (dump-fop 'fop-word-integer file)
 512      (dump-unsigned-32 n file))
 513     ((signed-byte 32)
 514      (dump-fop 'fop-word-integer file)
 515      (dump-integer-as-n-bytes n 4 file))
 516     (t
 517      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 518        (dump-fop* bytes fop-small-integer fop-integer file)
 519        (dump-integer-as-n-bytes n bytes file)))))
 520
 521 (defun dump-float (x file)
 522   (etypecase x
 523     (single-float
 524      (dump-fop 'fop-single-float file)
 525      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 526     (double-float
 527      (dump-fop 'fop-double-float file)
 528      (let ((x x))
 529        (declare (double-float x))
 530        ;; FIXME: Why sometimes DUMP-UNSIGNED-32 and sometimes
 531        ;; DUMP-INTEGER-AS-N-BYTES .. 4?
 532        (dump-unsigned-32 (double-float-low-bits x) file)
 533        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 534     #!+long-float
 535     (long-float
 536      (dump-fop 'fop-long-float file)
 537      (dump-long-float x file))))
 538
 539 (defun dump-complex (x file)
 540   (typecase x
 541     #-sb-xc-host
 542     ((complex single-float)
 543      (dump-fop 'fop-complex-single-float file)
 544      (dump-integer-as-n-bytes (single-float-bits (realpart x)) 4 file)
 545      (dump-integer-as-n-bytes (single-float-bits (imagpart x)) 4 file))
 546     #-sb-xc-host
 547     ((complex double-float)
 548      (dump-fop 'fop-complex-double-float file)
 549      (let ((re (realpart x)))
 550        (declare (double-float re))
 551        (dump-unsigned-32 (double-float-low-bits re) file)
 552        (dump-integer-as-n-bytes (double-float-high-bits re) 4 file))
 553      (let ((im (imagpart x)))
 554        (declare (double-float im))
 555        (dump-unsigned-32 (double-float-low-bits im) file)
 556        (dump-integer-as-n-bytes (double-float-high-bits im) 4 file)))
 557     #!+long-float
 558     ((complex long-float)
 559      ;; (There's no easy way to mix #!+LONG-FLOAT and #-SB-XC-HOST
 560      ;; conditionalization at read time, so we do this SB-XC-HOST
 561      ;; conditional at runtime instead.)
 562      #+sb-xc-host (error "can't dump COMPLEX-LONG-FLOAT in cross-compiler")
 563      (dump-fop 'fop-complex-long-float file)
 564      (dump-long-float (realpart x) file)
 565      (dump-long-float (imagpart x) file))
 566     (t
 567      (sub-dump-object (realpart x) file)
 568      (sub-dump-object (imagpart x) file)
 569      (dump-fop 'fop-complex file))))
 570 \f
 571 ;;;; symbol dumping
 572
 573 ;;; Return the table index of PKG, adding the package to the table if
 574 ;;; necessary. During cold load, we read the string as a normal string
 575 ;;; so that we can do the package lookup at cold load time.
 576 ;;;
 577 ;;; FIXME: Despite the parallelism in names, the functionality of
 578 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 579 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 580 ;;; should be made more consistent.
 581 (declaim (ftype (function (package fasl-output) index) dump-package))
 582 (defun dump-package (pkg file)
 583   (declare (inline assoc))
 584   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 585         (t
 586          (unless *cold-load-dump*
 587            (dump-fop 'fop-normal-load file))
 588          (dump-simple-string (package-name pkg) file)
 589          (dump-fop 'fop-package file)
 590          (unless *cold-load-dump*
 591            (dump-fop 'fop-maybe-cold-load file))
 592          (let ((entry (dump-pop file)))
 593            (push (cons pkg entry) (fasl-output-packages file))
 594            entry))))
 595 \f
 596 ;;; dumper for lists
 597
 598 ;;; Dump a list, setting up patching information when there are
 599 ;;; circularities. We scan down the list, checking for CDR and CAR
 600 ;;; circularities.
 601 ;;;
 602 ;;; If there is a CDR circularity, we terminate the list with NIL and
 603 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 604 ;;;
 605 ;;; If there is no CDR circularity, then we mark the current cons and
 606 ;;; check for a CAR circularity. When there is a CAR circularity, we
 607 ;;; make the CAR NIL initially, arranging for the current cons to be
 608 ;;; patched later.
 609 ;;;
 610 ;;; Otherwise, we recursively call the dumper to dump the current
 611 ;;; element.
 612 ;;;
 613 ;;; Marking of the conses is inhibited when *COLD-LOAD-DUMP* is true.
 614 ;;; This inhibits all circularity detection.
 615 (defun dump-list (list file)
 616   (aver (and list
 617              (not (gethash list (fasl-output-circularity-table file)))))
 618   (do* ((l list (cdr l))
 619         (n 0 (1+ n))
 620         (circ (fasl-output-circularity-table file)))
 621        ((atom l)
 622         (cond ((null l)
 623                (terminate-undotted-list n file))
 624               (t
 625                (sub-dump-object l file)
 626                (terminate-dotted-list n file))))
 627     (declare (type index n))
 628     (let ((ref (gethash l circ)))
 629       (when ref
 630         (push (make-circularity :type :rplacd
 631                                 :object list
 632                                 :index (1- n)
 633                                 :value l
 634                                 :enclosing-object ref)
 635               *circularities-detected*)
 636         (terminate-undotted-list n file)
 637         (return)))
 638
 639     (unless *cold-load-dump*
 640       (setf (gethash l circ) list))
 641
 642     (let* ((obj (car l))
 643            (ref (gethash obj circ)))
 644       (cond (ref
 645              (push (make-circularity :type :rplaca
 646                                      :object list
 647                                      :index n
 648                                      :value obj
 649                                      :enclosing-object ref)
 650                    *circularities-detected*)
 651              (sub-dump-object nil file))
 652             (t
 653              (sub-dump-object obj file))))))
 654
 655 (defun terminate-dotted-list (n file)
 656   (declare (type index n) (type fasl-output file))
 657   (case n
 658     (1 (dump-fop 'fop-list*-1 file))
 659     (2 (dump-fop 'fop-list*-2 file))
 660     (3 (dump-fop 'fop-list*-3 file))
 661     (4 (dump-fop 'fop-list*-4 file))
 662     (5 (dump-fop 'fop-list*-5 file))
 663     (6 (dump-fop 'fop-list*-6 file))
 664     (7 (dump-fop 'fop-list*-7 file))
 665     (8 (dump-fop 'fop-list*-8 file))
 666     (T (do ((nn n (- nn 255)))
 667            ((< nn 256)
 668             (dump-fop 'fop-list* file)
 669             (dump-byte nn file))
 670          (declare (type index nn))
 671          (dump-fop 'fop-list* file)
 672          (dump-byte 255 file)))))
 673
 674 ;;; If N > 255, must build list with one LIST operator, then LIST*
 675 ;;; operators.
 676
 677 (defun terminate-undotted-list (n file)
 678   (declare (type index n) (type fasl-output file))
 679   (case n
 680     (1 (dump-fop 'fop-list-1 file))
 681     (2 (dump-fop 'fop-list-2 file))
 682     (3 (dump-fop 'fop-list-3 file))
 683     (4 (dump-fop 'fop-list-4 file))
 684     (5 (dump-fop 'fop-list-5 file))
 685     (6 (dump-fop 'fop-list-6 file))
 686     (7 (dump-fop 'fop-list-7 file))
 687     (8 (dump-fop 'fop-list-8 file))
 688     (T (cond ((< n 256)
 689               (dump-fop 'fop-list file)
 690               (dump-byte n file))
 691              (t (dump-fop 'fop-list file)
 692                 (dump-byte 255 file)
 693                 (do ((nn (- n 255) (- nn 255)))
 694                     ((< nn 256)
 695                      (dump-fop 'fop-list* file)
 696                      (dump-byte nn file))
 697                   (declare (type index nn))
 698                   (dump-fop 'fop-list* file)
 699                   (dump-byte 255 file)))))))
 700 \f
 701 ;;;; array dumping
 702
 703 ;;; Dump the array thing.
 704 (defun dump-array (x file)
 705   (if (vectorp x)
 706       (dump-vector x file)
 707       (dump-multi-dim-array x file)))
 708
 709 ;;; Dump the vector object. If it's not simple, then actually dump a
 710 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 711 ;;; tables.
 712 (defun dump-vector (x file)
 713   (let ((simple-version (if (array-header-p x)
 714                             (coerce x `(simple-array
 715                                         ,(array-element-type x)
 716                                         (*)))
 717                             x)))
 718     (typecase simple-version
 719       (simple-base-string
 720        (unless (equal-check-table x file)
 721          (dump-simple-string simple-version file)
 722          (equal-save-object x file)))
 723       (simple-vector
 724        (dump-simple-vector simple-version file)
 725        (eq-save-object x file))
 726       ((simple-array single-float (*))
 727        (dump-single-float-vector simple-version file)
 728        (eq-save-object x file))
 729       ((simple-array double-float (*))
 730        (dump-double-float-vector simple-version file)
 731        (eq-save-object x file))
 732       #!+long-float
 733       ((simple-array long-float (*))
 734        (dump-long-float-vector simple-version file)
 735        (eq-save-object x file))
 736       ((simple-array (complex single-float) (*))
 737        (dump-complex-single-float-vector simple-version file)
 738        (eq-save-object x file))
 739       ((simple-array (complex double-float) (*))
 740        (dump-complex-double-float-vector simple-version file)
 741        (eq-save-object x file))
 742       #!+long-float
 743       ((simple-array (complex long-float) (*))
 744        (dump-complex-long-float-vector simple-version file)
 745        (eq-save-object x file))
 746       (t
 747        (dump-i-vector simple-version file)
 748        (eq-save-object x file)))))
 749
 750 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 751 (defun dump-simple-vector (v file)
 752   (declare (type simple-vector v) (type fasl-output file))
 753   (note-potential-circularity v file)
 754   (do ((index 0 (1+ index))
 755        (length (length v))
 756        (circ (fasl-output-circularity-table file)))
 757       ((= index length)
 758        (dump-fop* length fop-small-vector fop-vector file))
 759     (let* ((obj (aref v index))
 760            (ref (gethash obj circ)))
 761       (cond (ref
 762              (push (make-circularity :type :svset
 763                                      :object v
 764                                      :index index
 765                                      :value obj
 766                                      :enclosing-object ref)
 767                    *circularities-detected*)
 768              (sub-dump-object nil file))
 769             (t
 770              (sub-dump-object obj file))))))
 771
 772 ;;; In the grand scheme of things I don't pretend to understand any
 773 ;;; more how this works, or indeed whether.  But to write out specialized
 774 ;;; vectors in the same format as fop-int-vector expects to read them
 775 ;;; we need to be target-endian.  dump-integer-as-n-bytes always writes
 776 ;;; little-endian (which is correct for all other integers) so for a bigendian
 777 ;;; target we need to swap octets -- CSR, after DB
 778
 779 (defun octet-swap (word bits)
 780   "BITS must be a multiple of 8"
 781   (do ((input word (ash input -8))
 782        (output 0 (logior (ash output 8) (logand input #xff)))
 783        (bits bits (- bits 8)))
 784       ((<= bits 0) output)))
 785
 786 (defun dump-i-vector (vec file &key data-only)
 787   (declare (type (simple-array * (*)) vec))
 788   (let ((len (length vec)))
 789     (labels ((dump-unsigned-vector (size bytes)
 790                (unless data-only
 791                  (dump-fop 'fop-int-vector file)
 792                  (dump-unsigned-32 len file)
 793                  (dump-byte size file))
 794                ;; The case which is easy to handle in a portable way is when
 795                ;; the element size is a multiple of the output byte size, and
 796                ;; happily that's the only case we need to be portable. (The
 797                ;; cross-compiler has to output debug information (including
 798                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 799                ;; needed in the target SBCL, so we let them be handled with
 800                ;; unportable bit bashing.
 801                (cond ((>= size 8) ; easy cases
 802                       (multiple-value-bind (floor rem) (floor size 8)
 803                         (aver (zerop rem))
 804                         (dovector (i vec)
 805                           (dump-integer-as-n-bytes
 806                            (ecase sb!c:*backend-byte-order*
 807                              (:little-endian i)
 808                              (:big-endian (octet-swap i size)))
 809                            floor file))))
 810                      (t ; harder cases, not supported in cross-compiler
 811                       (dump-raw-bytes vec bytes file))))
 812              (dump-signed-vector (size bytes)
 813                ;; Note: Dumping specialized signed vectors isn't
 814                ;; supported in the cross-compiler. (All cases here end
 815                ;; up trying to call DUMP-RAW-BYTES, which isn't
 816                ;; provided in the cross-compilation host, only on the
 817                ;; target machine.)
 818                (unless data-only
 819                  (dump-fop 'fop-signed-int-vector file)
 820                  (dump-unsigned-32 len file)
 821                  (dump-byte size file))
 822                (dump-raw-bytes vec bytes file)))
 823       (etypecase vec
 824         ;; KLUDGE: What exactly does the (ASH .. -3) stuff do? -- WHN 19990902
 825         (simple-bit-vector
 826          (dump-unsigned-vector 1 (ash (+ (the index len) 7) -3)))
 827         ;; KLUDGE: This isn't the best way of expressing that the host
 828         ;; may not have specializations for (unsigned-byte 2) and
 829         ;; (unsigned-byte 4), which means that these types are
 830         ;; type-equivalent to (simple-array (unsigned-byte 8) (*));
 831         ;; the workaround is to remove them from the etypecase, since
 832         ;; they can't be dumped from the cross-compiler anyway. --
 833         ;; CSR, 2002-05-07
 834         #-sb-xc-host
 835         ((simple-array (unsigned-byte 2) (*))
 836          (dump-unsigned-vector 2 (ash (+ (the index (ash len 1)) 7) -3)))
 837         #-sb-xc-host
 838         ((simple-array (unsigned-byte 4) (*))
 839          (dump-unsigned-vector 4 (ash (+ (the index (ash len 2)) 7) -3)))
 840         ((simple-array (unsigned-byte 8) (*))
 841          (dump-unsigned-vector 8 len))
 842         ((simple-array (unsigned-byte 16) (*))
 843          (dump-unsigned-vector 16 (* 2 len)))
 844         ((simple-array (unsigned-byte 32) (*))
 845          (dump-unsigned-vector 32 (* 4 len)))
 846         ((simple-array (signed-byte 8) (*))
 847          (dump-signed-vector 8 len))
 848         ((simple-array (signed-byte 16) (*))
 849          (dump-signed-vector 16 (* 2 len)))
 850         ((simple-array (signed-byte 30) (*))
 851          (dump-signed-vector 30 (* 4 len)))
 852         ((simple-array (signed-byte 32) (*))
 853          (dump-signed-vector 32 (* 4 len)))))))
 854 \f
 855 ;;; Dump characters and string-ish things.
 856
 857 (defun dump-character (ch file)
 858   (dump-fop 'fop-short-character file)
 859   (dump-byte (char-code ch) file))
 860
 861 ;;; a helper function shared by DUMP-SIMPLE-STRING and DUMP-SYMBOL
 862 (defun dump-characters-of-string (s fasl-output)
 863   (declare (type string s) (type fasl-output fasl-output))
 864   (dovector (c s)
 865     (dump-byte (char-code c) fasl-output))
 866   (values))
 867
 868 ;;; Dump a SIMPLE-BASE-STRING.
 869 ;;; FIXME: should be called DUMP-SIMPLE-BASE-STRING then
 870 (defun dump-simple-string (s file)
 871   (declare (type simple-base-string s))
 872   (dump-fop* (length s) fop-small-string fop-string file)
 873   (dump-characters-of-string s file)
 874   (values))
 875
 876 ;;; If we get here, it is assumed that the symbol isn't in the table,
 877 ;;; but we are responsible for putting it there when appropriate. To
 878 ;;; avoid too much special-casing, we always push the symbol in the
 879 ;;; table, but don't record that we have done so if *COLD-LOAD-DUMP*
 880 ;;; is true.
 881 (defun dump-symbol (s file)
 882   (declare (type fasl-output file))
 883   (let* ((pname (symbol-name s))
 884          (pname-length (length pname))
 885          (pkg (symbol-package s)))
 886
 887     (cond ((null pkg)
 888            (dump-fop* pname-length
 889                       fop-uninterned-small-symbol-save
 890                       fop-uninterned-symbol-save
 891                       file))
 892           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 893           ;; used the current value of *PACKAGE*. Unfortunately that's
 894           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 895           ;; from SBCL.
 896           ;;((eq pkg *package*)
 897           ;; (dump-fop* pname-length
 898           ;;        fop-small-symbol-save
 899           ;;        fop-symbol-save file))
 900           ((eq pkg sb!int:*cl-package*)
 901            (dump-fop* pname-length
 902                       fop-lisp-small-symbol-save
 903                       fop-lisp-symbol-save
 904                       file))
 905           ((eq pkg sb!int:*keyword-package*)
 906            (dump-fop* pname-length
 907                       fop-keyword-small-symbol-save
 908                       fop-keyword-symbol-save
 909                       file))
 910           ((< pname-length 256)
 911            (dump-fop* (dump-package pkg file)
 912                       fop-small-symbol-in-byte-package-save
 913                       fop-small-symbol-in-package-save
 914                       file)
 915            (dump-byte pname-length file))
 916           (t
 917            (dump-fop* (dump-package pkg file)
 918                       fop-symbol-in-byte-package-save
 919                       fop-symbol-in-package-save
 920                       file)
 921            (dump-unsigned-32 pname-length file)))
 922
 923     (dump-characters-of-string pname file)
 924
 925     (unless *cold-load-dump*
 926       (setf (gethash s (fasl-output-eq-table file))
 927             (fasl-output-table-free file)))
 928
 929     (incf (fasl-output-table-free file)))
 930
 931   (values))
 932 \f
 933 ;;;; component (function) dumping
 934
 935 (defun dump-segment (segment code-length fasl-output)
 936   (declare (type sb!assem:segment segment)
 937            (type fasl-output fasl-output))
 938   (let* ((stream (fasl-output-stream fasl-output))
 939          (n-written (write-segment-contents segment stream)))
 940     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
 941     ;; argument and the number of bytes actually written. I added this
 942     ;; assertion while trying to debug portable genesis. -- WHN 19990902
 943     (unless (= code-length n-written)
 944       (bug "code-length=~W, n-written=~W" code-length n-written)))
 945   (values))
 946
 947 ;;; Dump all the fixups. Currently there are three flavors of fixup:
 948 ;;;  - assembly routines: named by a symbol
 949 ;;;  - foreign (C) symbols: named by a string
 950 ;;;  - code object references: don't need a name.
 951 (defun dump-fixups (fixups fasl-output)
 952   (declare (list fixups) (type fasl-output fasl-output))
 953   (dolist (info fixups)
 954     ;; FIXME: Packing data with LIST in NOTE-FIXUP and unpacking them
 955     ;; with FIRST, SECOND, and THIRD here is hard to follow and
 956     ;; maintain. Perhaps we could define a FIXUP-INFO structure to use
 957     ;; instead, and rename *FIXUPS* to *FIXUP-INFO-LIST*?
 958     (let* ((kind (first info))
 959            (fixup (second info))
 960            (name (fixup-name fixup))
 961            (flavor (fixup-flavor fixup))
 962            (offset (third info)))
 963       ;; FIXME: This OFFSET is not what's called OFFSET in the FIXUP
 964       ;; structure, it's what's called POSN in NOTE-FIXUP. (As far as
 965       ;; I can tell, FIXUP-OFFSET is not actually an offset, it's an
 966       ;; internal label used instead of NAME for :CODE-OBJECT fixups.
 967       ;; Notice that in the :CODE-OBJECT case, NAME is ignored.)
 968       (dump-fop 'fop-normal-load fasl-output)
 969       (let ((*cold-load-dump* t))
 970         (dump-object kind fasl-output))
 971       (dump-fop 'fop-maybe-cold-load fasl-output)
 972       ;; Depending on the flavor, we may have various kinds of
 973       ;; noise before the offset.
 974       (ecase flavor
 975         (:assembly-routine
 976          (aver (symbolp name))
 977          (dump-fop 'fop-normal-load fasl-output)
 978          (let ((*cold-load-dump* t))
 979            (dump-object name fasl-output))
 980          (dump-fop 'fop-maybe-cold-load fasl-output)
 981          (dump-fop 'fop-assembler-fixup fasl-output))
 982         (:foreign
 983          (aver (stringp name))
 984          (dump-fop 'fop-foreign-fixup fasl-output)
 985          (let ((len (length name)))
 986            (aver (< len 256)) ; (limit imposed by fop definition)
 987            (dump-byte len fasl-output)
 988            (dotimes (i len)
 989              (dump-byte (char-code (schar name i)) fasl-output))))
 990         (:code-object
 991          (aver (null name))
 992          (dump-fop 'fop-code-object-fixup fasl-output)))
 993       ;; No matter what the flavor, we'll always dump the offset.
 994       (dump-unsigned-32 offset fasl-output)))
 995   (values))
 996
 997 ;;; Dump out the constant pool and code-vector for component, push the
 998 ;;; result in the table, and return the offset.
 999 ;;;
1000 ;;; The only tricky thing is handling constant-pool references to
1001 ;;; functions. If we have already dumped the function, then we just
1002 ;;; push the code pointer. Otherwise, we must create back-patching
1003 ;;; information so that the constant will be set when the function is
1004 ;;; eventually dumped. This is a bit awkward, since we don't have the
1005 ;;; handle for the code object being dumped while we are dumping its
1006 ;;; constants.
1007 ;;;
1008 ;;; We dump trap objects in any unused slots or forward referenced slots.
1009 (defun dump-code-object (component
1010                          code-segment
1011                          code-length
1012                          trace-table-as-list
1013                          fixups
1014                          fasl-output)
1015
1016   (declare (type component component)
1017            (list trace-table-as-list)
1018            (type index code-length)
1019            (type fasl-output fasl-output))
1020
1021   (let* ((2comp (component-info component))
1022          (constants (sb!c::ir2-component-constants 2comp))
1023          (header-length (length constants))
1024          (packed-trace-table (pack-trace-table trace-table-as-list))
1025          (total-length (+ code-length
1026                           (* (length packed-trace-table)
1027                              sb!c::tt-bytes-per-entry))))
1028
1029     (collect ((patches))
1030
1031       ;; Dump the offset of the trace table.
1032       (dump-object code-length fasl-output)
1033       ;; FIXME: As long as we don't have GENGC, the trace table is
1034       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
1035       ;; far as I know no modern CMU CL does either -- WHN
1036       ;; 2001-10-05). So might we be able to get rid of trace tables?
1037
1038       ;; Dump the constants, noting any :ENTRY constants that have to
1039       ;; be patched.
1040       (loop for i from sb!vm:code-constants-offset below header-length do
1041         (let ((entry (aref constants i)))
1042           (etypecase entry
1043             (constant
1044              (dump-object (sb!c::constant-value entry) fasl-output))
1045             (cons
1046              (ecase (car entry)
1047                (:entry
1048                 (let* ((info (sb!c::leaf-info (cdr entry)))
1049                        (handle (gethash info
1050                                         (fasl-output-entry-table
1051                                          fasl-output))))
1052                   (declare (type sb!c::entry-info info))
1053                   (cond
1054                    (handle
1055                     (dump-push handle fasl-output))
1056                    (t
1057                     (patches (cons info i))
1058                     (dump-fop 'fop-misc-trap fasl-output)))))
1059                (:load-time-value
1060                 (dump-push (cdr entry) fasl-output))
1061                (:fdefinition
1062                 (dump-object (cdr entry) fasl-output)
1063                 (dump-fop 'fop-fdefinition fasl-output))))
1064             (null
1065              (dump-fop 'fop-misc-trap fasl-output)))))
1066
1067       ;; Dump the debug info.
1068       (let ((info (sb!c::debug-info-for-component component))
1069             (*dump-only-valid-structures* nil))
1070         (dump-object info fasl-output)
1071         (let ((info-handle (dump-pop fasl-output)))
1072           (dump-push info-handle fasl-output)
1073           (push info-handle (fasl-output-debug-info fasl-output))))
1074
1075       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1076         (cond ((and (< num-consts #x100) (< total-length #x10000))
1077                (dump-fop 'fop-small-code fasl-output)
1078                (dump-byte num-consts fasl-output)
1079                (dump-integer-as-n-bytes total-length 2 fasl-output))
1080               (t
1081                (dump-fop 'fop-code fasl-output)
1082                (dump-unsigned-32 num-consts fasl-output)
1083                (dump-unsigned-32 total-length fasl-output))))
1084
1085       ;; These two dumps are only ones which contribute to our
1086       ;; TOTAL-LENGTH value.
1087       (dump-segment code-segment code-length fasl-output)
1088       (dump-i-vector packed-trace-table fasl-output :data-only t)
1089
1090       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1091       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1092       ;; FOP-CODE/FOP-SMALL-CODE fop.
1093       (dump-fixups fixups fasl-output)
1094
1095       (dump-fop 'fop-sanctify-for-execution fasl-output)
1096
1097       (let ((handle (dump-pop fasl-output)))
1098         (dolist (patch (patches))
1099           (push (cons handle (cdr patch))
1100                 (gethash (car patch)
1101                          (fasl-output-patch-table fasl-output))))
1102         handle))))
1103
1104 (defun dump-assembler-routines (code-segment length fixups routines file)
1105   (dump-fop 'fop-assembler-code file)
1106   (dump-unsigned-32 length file)
1107   (write-segment-contents code-segment (fasl-output-stream file))
1108   (dolist (routine routines)
1109     (dump-fop 'fop-normal-load file)
1110     (let ((*cold-load-dump* t))
1111       (dump-object (car routine) file))
1112     (dump-fop 'fop-maybe-cold-load file)
1113     (dump-fop 'fop-assembler-routine file)
1114     (dump-unsigned-32 (label-position (cdr routine)) file))
1115   (dump-fixups fixups file)
1116   (dump-fop 'fop-sanctify-for-execution file)
1117   (dump-pop file))
1118
1119 ;;; Dump a function entry data structure corresponding to ENTRY to
1120 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1121 ;;; component.
1122 (defun dump-one-entry (entry code-handle file)
1123   (declare (type sb!c::entry-info entry) (type index code-handle)
1124            (type fasl-output file))
1125   (let ((name (sb!c::entry-info-name entry)))
1126     (dump-push code-handle file)
1127     (dump-object name file)
1128     (dump-object (sb!c::entry-info-arguments entry) file)
1129     (dump-object (sb!c::entry-info-type entry) file)
1130     (dump-fop 'fop-fun-entry file)
1131     (dump-unsigned-32 (label-position (sb!c::entry-info-offset entry)) file)
1132     (dump-pop file)))
1133
1134 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1135 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1136 (defun dump-alter-code-object (code-handle offset entry-handle file)
1137   (declare (type index code-handle entry-handle offset))
1138   (declare (type fasl-output file))
1139   (dump-push code-handle file)
1140   (dump-push entry-handle file)
1141   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1142   (values))
1143
1144 ;;; Dump the code, constants, etc. for component. We pass in the
1145 ;;; assembler fixups, code vector and node info.
1146 (defun fasl-dump-component (component
1147                             code-segment
1148                             code-length
1149                             trace-table
1150                             fixups
1151                             file)
1152   (declare (type component component) (list trace-table))
1153   (declare (type fasl-output file))
1154
1155   (dump-fop 'fop-verify-empty-stack file)
1156   (dump-fop 'fop-verify-table-size file)
1157   (dump-unsigned-32 (fasl-output-table-free file) file)
1158
1159   #!+sb-dyncount
1160   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1161     (when info
1162       (fasl-validate-structure info file)))
1163
1164   (let ((code-handle (dump-code-object component
1165                                        code-segment
1166                                        code-length
1167                                        trace-table
1168                                        fixups
1169                                        file))
1170         (2comp (component-info component)))
1171     (dump-fop 'fop-verify-empty-stack file)
1172
1173     (dolist (entry (sb!c::ir2-component-entries 2comp))
1174       (let ((entry-handle (dump-one-entry entry code-handle file)))
1175         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1176         (let ((old (gethash entry (fasl-output-patch-table file))))
1177           (when old
1178             (dolist (patch old)
1179               (dump-alter-code-object (car patch)
1180                                       (cdr patch)
1181                                       entry-handle
1182                                       file))
1183             (remhash entry (fasl-output-patch-table file)))))))
1184   (values))
1185
1186 (defun dump-push-previously-dumped-fun (fun fasl-output)
1187   (declare (type sb!c::clambda fun))
1188   (let ((handle (gethash (sb!c::leaf-info fun)
1189                          (fasl-output-entry-table fasl-output))))
1190     (aver handle)
1191     (dump-push handle fasl-output))
1192   (values))
1193
1194 ;;; Dump a FOP-FUNCALL to call an already-dumped top level lambda at
1195 ;;; load time.
1196 (defun fasl-dump-toplevel-lambda-call (fun fasl-output)
1197   (declare (type sb!c::clambda fun))
1198   (dump-push-previously-dumped-fun fun fasl-output)
1199   (dump-fop 'fop-funcall-for-effect fasl-output)
1200   (dump-byte 0 fasl-output)
1201   (values))
1202
1203 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1204 ;;; FUN-NAME and the already-dumped function whose dump handle is
1205 ;;; FUN-DUMP-HANDLE.
1206 #+sb-xc-host
1207 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1208   (declare (type fixnum fun-dump-handle))
1209   (aver (legal-fun-name-p fun-name))
1210   (dump-non-immediate-object fun-name fasl-output)
1211   (dump-push fun-dump-handle fasl-output)
1212   (dump-fop 'fop-fset fasl-output)
1213   (values))
1214
1215 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1216 ;;; all of the dumped DEBUG-INFO structures. We clear the
1217 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1218 ;;; different source info may be dumped.
1219 (defun fasl-dump-source-info (info fasl-output)
1220   (declare (type sb!c::source-info info))
1221   (let ((res (sb!c::debug-source-for-info info))
1222         (*dump-only-valid-structures* nil))
1223     (dump-object res fasl-output)
1224     (let ((res-handle (dump-pop fasl-output)))
1225       (dolist (info-handle (fasl-output-debug-info fasl-output))
1226         (dump-push res-handle fasl-output)
1227         (dump-fop 'fop-structset fasl-output)
1228         (dump-unsigned-32 info-handle fasl-output)
1229         (dump-unsigned-32 2 fasl-output))))
1230   (setf (fasl-output-debug-info fasl-output) nil)
1231   (values))
1232 \f
1233 ;;;; dumping structures
1234
1235 (defun dump-structure (struct file)
1236   (when *dump-only-valid-structures*
1237     (unless (gethash struct (fasl-output-valid-structures file))
1238       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1239              struct)))
1240   (note-potential-circularity struct file)
1241   (do ((index 0 (1+ index))
1242        (length (%instance-length struct))
1243        (circ (fasl-output-circularity-table file)))
1244       ((= index length)
1245        (dump-fop* length fop-small-struct fop-struct file))
1246     (let* ((obj (%instance-ref struct index))
1247            (ref (gethash obj circ)))
1248       (cond (ref
1249              (push (make-circularity :type :struct-set
1250                                      :object struct
1251                                      :index index
1252                                      :value obj
1253                                      :enclosing-object ref)
1254                    *circularities-detected*)
1255              (sub-dump-object nil file))
1256             (t
1257              (sub-dump-object obj file))))))
1258
1259 (defun dump-layout (obj file)
1260   (when (layout-invalid obj)
1261     (compiler-error "attempt to dump reference to obsolete class: ~S"
1262                     (layout-class obj)))
1263   (let ((name (classoid-name (layout-classoid obj))))
1264     (unless name
1265       (compiler-error "dumping anonymous layout: ~S" obj))
1266     (dump-fop 'fop-normal-load file)
1267     (let ((*cold-load-dump* t))
1268       (dump-object name file))
1269     (dump-fop 'fop-maybe-cold-load file))
1270   (sub-dump-object (layout-inherits obj) file)
1271   (sub-dump-object (layout-depthoid obj) file)
1272   (sub-dump-object (layout-length obj) file)
1273   (dump-fop 'fop-layout file))