src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (required-argument) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance patholigies with objects for which EQUAL degnerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the Entry-Info structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the Entry-Info structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (required-argument) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (required-argument) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top-level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to inhibit table access when dumping forms to be read by the
  95 ;;; cold loader
  96 (defvar *cold-load-dump* nil)
  97
  98 ;;; used to turn off the structure validation during dumping of source
  99 ;;; info
 100 (defvar *dump-only-valid-structures* t)
 101 ;;;; utilities
 102
 103 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 104 (defun dump-byte (b fasl-output)
 105   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 106   (write-byte b (fasl-output-stream fasl-output)))
 107
 108 ;;; Dump a 4 byte unsigned integer.
 109 (defun dump-unsigned-32 (num fasl-output)
 110   (declare (type (unsigned-byte 32) num))
 111   (declare (type fasl-output fasl-output))
 112   (let ((stream (fasl-output-stream fasl-output)))
 113     (dotimes (i 4)
 114       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 115
 116 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 117 ;;; for either signed or unsigned integers. There's no range checking
 118 ;;; -- if you don't specify enough bytes for the number to fit, this
 119 ;;; function cheerfully outputs the low bytes.
 120 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 121   (declare (integer num) (type index bytes))
 122   (declare (type fasl-output fasl-output))
 123   (do ((n num (ash n -8))
 124        (i bytes (1- i)))
 125       ((= i 0))
 126     (declare (type index i))
 127     (dump-byte (logand n #xff) fasl-output))
 128   (values))
 129
 130 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 131 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 132 ;;; counter value before every ordinary fop. This can make it easier
 133 ;;; to follow the progress of LOAD-AS-FASL when
 134 ;;; debugging/testing/experimenting.
 135 #!+sb-show (defvar *fop-nop4-count* nil)
 136 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 137
 138 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 139 ;;;
 140 ;;; FIXME: This should be a function, with a compiler macro expansion
 141 ;;; for the common constant-FS case. (Among other things, that'll stop
 142 ;;; it from EVALing ,FILE multiple times.)
 143 ;;;
 144 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 145 ;;; optimizations should be conditional on #!+SB-FROZEN.
 146 (defmacro dump-fop (fs file)
 147   (let* ((fs (eval fs))
 148          (val (get fs 'fop-code)))
 149     (if val
 150       `(progn
 151          #!+sb-show
 152          (when *fop-nop4-count*
 153            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 154            (dump-unsigned-32 (mod (incf *fop-nop4-count*) (expt 2 32)) ,file))
 155          (dump-byte ',val ,file))
 156       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 157
 158 ;;; Dump a FOP-Code along with an integer argument, choosing the FOP
 159 ;;; based on whether the argument will fit in a single byte.
 160 ;;;
 161 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 162 ;;; compiler-macro expansion.
 163 (defmacro dump-fop* (n byte-fop word-fop file)
 164   (once-only ((n-n n)
 165               (n-file file))
 166     `(cond ((< ,n-n 256)
 167             (dump-fop ',byte-fop ,n-file)
 168             (dump-byte ,n-n ,n-file))
 169            (t
 170             (dump-fop ',word-fop ,n-file)
 171             (dump-unsigned-32 ,n-n ,n-file)))))
 172
 173 ;;; Push the object at table offset Handle on the fasl stack.
 174 (defun dump-push (handle fasl-output)
 175   (declare (type index handle) (type fasl-output fasl-output))
 176   (dump-fop* handle fop-byte-push fop-push fasl-output)
 177   (values))
 178
 179 ;;; Pop the object currently on the fasl stack top into the table, and
 180 ;;; return the table index, incrementing the free pointer.
 181 (defun dump-pop (fasl-output)
 182   (prog1
 183       (fasl-output-table-free fasl-output)
 184     (dump-fop 'fop-pop fasl-output)
 185     (incf (fasl-output-table-free fasl-output))))
 186
 187 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 188 ;;; otherwise NIL. If *COLD-LOAD-DUMP* is true, then do nothing and
 189 ;;; return NIL.
 190 (defun equal-check-table (x fasl-output)
 191   (declare (type fasl-output fasl-output))
 192   (unless *cold-load-dump*
 193     (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 194       (cond (handle
 195              (dump-push handle fasl-output)
 196              t)
 197             (t
 198              nil)))))
 199
 200 ;;; These functions are called after dumping an object to save the
 201 ;;; object in the table. The object (also passed in as X) must already
 202 ;;; be on the top of the FOP stack. If *COLD-LOAD-DUMP* is true, then
 203 ;;; we don't do anything.
 204 (defun eq-save-object (x fasl-output)
 205   (declare (type fasl-output fasl-output))
 206   (unless *cold-load-dump*
 207     (let ((handle (dump-pop fasl-output)))
 208       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 209       (dump-push handle fasl-output)))
 210   (values))
 211 (defun equal-save-object (x fasl-output)
 212   (declare (type fasl-output fasl-output))
 213   (unless *cold-load-dump*
 214     (let ((handle (dump-pop fasl-output)))
 215       (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 216       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 217       (dump-push handle fasl-output)))
 218   (values))
 219
 220 ;;; Record X in File's CIRCULARITY-TABLE unless *COLD-LOAD-DUMP* is
 221 ;;; true. This is called on objects that we are about to dump might
 222 ;;; have a circular path through them.
 223 ;;;
 224 ;;; The object must not currently be in this table, since the dumper
 225 ;;; should never be recursively called on a circular reference.
 226 ;;; Instead, the dumping function must detect the circularity and
 227 ;;; arrange for the dumped object to be patched.
 228 (defun note-potential-circularity (x fasl-output)
 229   (unless *cold-load-dump*
 230     (let ((circ (fasl-output-circularity-table fasl-output)))
 231       (aver (not (gethash x circ)))
 232       (setf (gethash x circ) x)))
 233   (values))
 234
 235 ;;; Dump FORM to a fasl file so that it evaluated at load time in normal
 236 ;;; load and at cold-load time in cold load. This is used to dump package
 237 ;;; frobbing forms.
 238 (defun fasl-dump-cold-load-form (form fasl-output)
 239   (declare (type fasl-output fasl-output))
 240   (dump-fop 'fop-normal-load fasl-output)
 241   (let ((*cold-load-dump* t))
 242     (dump-object form fasl-output))
 243   (dump-fop 'fop-eval-for-effect fasl-output)
 244   (dump-fop 'fop-maybe-cold-load fasl-output)
 245   (values))
 246 \f
 247 ;;;; opening and closing fasl files
 248
 249 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 250 ;;; object for dumping to it. Some human-readable information about
 251 ;;; the source code is given by the string WHERE. If BYTE-P is true,
 252 ;;; this file will contain no native code, and is thus largely
 253 ;;; implementation independent.
 254 (defun open-fasl-output (name where &optional byte-p)
 255   (declare (type pathname name))
 256   (let* ((stream (open name
 257                        :direction :output
 258                        :if-exists :new-version
 259                        :element-type 'sb!assem:assembly-unit))
 260          (res (make-fasl-output :stream stream)))
 261
 262     ;; Begin the header with the constant machine-readable (and
 263     ;; semi-human-readable) string which is used to identify fasl files.
 264     (write-string *fasl-header-string-start-string* stream)
 265
 266     ;; The constant string which begins the header is followed by
 267     ;; arbitrary human-readable text, terminated by a special
 268     ;; character code.
 269     (with-standard-io-syntax
 270      (format stream
 271              "~%  ~
 272              compiled from ~S~%  ~
 273              at ~A~%  ~
 274              on ~A~%  ~
 275              using ~A version ~A~%"
 276              where
 277              (format-universal-time nil (get-universal-time))
 278              (machine-instance)
 279              (sb!xc:lisp-implementation-type)
 280              (sb!xc:lisp-implementation-version)))
 281     (dump-byte +fasl-header-string-stop-char-code+ res)
 282
 283     ;; Finish the header by outputting fasl file implementation and
 284     ;; version in machine-readable form.
 285     (let ((implementation (if byte-p
 286                               (backend-byte-fasl-file-implementation)
 287                               +backend-fasl-file-implementation+)))
 288       (dump-unsigned-32 (length (symbol-name implementation)) res)
 289       (dotimes (i (length (symbol-name implementation)))
 290         (dump-byte (char-code (aref (symbol-name implementation) i)) res)))
 291     (dump-unsigned-32 +fasl-file-version+ res)
 292
 293     res))
 294
 295 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 296 (defun close-fasl-output (fasl-output abort-p)
 297   (declare (type fasl-output fasl-output))
 298
 299   ;; sanity checks
 300   (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 301
 302   ;; End the group.
 303   (dump-fop 'fop-verify-empty-stack fasl-output)
 304   (dump-fop 'fop-verify-table-size fasl-output)
 305   (dump-unsigned-32 (fasl-output-table-free fasl-output)
 306                     fasl-output)
 307   (dump-fop 'fop-end-group fasl-output)
 308
 309   ;; That's all, folks.
 310   (close (fasl-output-stream fasl-output) :abort abort-p)
 311   (values))
 312 \f
 313 ;;;; main entries to object dumping
 314
 315 ;;; This function deals with dumping objects that are complex enough
 316 ;;; so that we want to cache them in the table, rather than repeatedly
 317 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 318 ;;; otherwise, we do a type dispatch to a type specific dumping
 319 ;;; function. The type specific branches do any appropriate
 320 ;;; EQUAL-TABLE check and table entry.
 321 ;;;
 322 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 323 (defun dump-non-immediate-object (x file)
 324   (let ((index (gethash x (fasl-output-eq-table file))))
 325     (cond ((and index (not *cold-load-dump*))
 326            (dump-push index file))
 327           (t
 328            (typecase x
 329              (symbol (dump-symbol x file))
 330              (list
 331               ;; KLUDGE: The code in this case has been hacked
 332               ;; to match Douglas Crosher's quick fix to CMU CL
 333               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 334               ;; with help from Martin Atzmueller. This is not an
 335               ;; ideal solution; to quote DTC,
 336               ;;   The compiler locks up trying to coalesce the
 337               ;;   constant lists. The hack below will disable the
 338               ;;   coalescing of lists while dumping and allows
 339               ;;   the code to compile. The real fix would be to
 340               ;;   take a little more care while dumping these.
 341               ;; So if better list coalescing is needed, start here.
 342               ;; -- WHN 2000-11-07
 343               (if (circular-list-p x)
 344                   (progn
 345                     (dump-list x file)
 346                     (eq-save-object x file))
 347                   (unless (equal-check-table x file)
 348                     (dump-list x file)
 349                     (equal-save-object x file))))
 350              (layout
 351               (dump-layout x file)
 352               (eq-save-object x file))
 353              (instance
 354               (dump-structure x file)
 355               (eq-save-object x file))
 356              (array
 357               ;; FIXME: The comment at the head of
 358               ;; DUMP-NON-IMMEDIATE-OBJECT says it's for objects which
 359               ;; we want to save, instead of repeatedly dumping them.
 360               ;; But then we dump arrays here without doing anything
 361               ;; like EQUAL-SAVE-OBJECT. What gives?
 362               (dump-array x file))
 363              (number
 364               (unless (equal-check-table x file)
 365                 (etypecase x
 366                   (ratio (dump-ratio x file))
 367                   (complex (dump-complex x file))
 368                   (float (dump-float x file))
 369                   (integer (dump-integer x file)))
 370                 (equal-save-object x file)))
 371              (t
 372               ;; This probably never happens, since bad things tend to
 373               ;; be detected during IR1 conversion.
 374               (error "This object cannot be dumped into a fasl file:~% ~S"
 375                      x))))))
 376   (values))
 377
 378 ;;; Dump an object of any type by dispatching to the correct
 379 ;;; type-specific dumping function. We pick off immediate objects,
 380 ;;; symbols and and magic lists here. Other objects are handled by
 381 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 382 ;;;
 383 ;;; This is the function used for recursive calls to the fasl dumper.
 384 ;;; We don't worry about creating circularities here, since it is
 385 ;;; assumed that there is a top-level call to DUMP-OBJECT.
 386 (defun sub-dump-object (x file)
 387   (cond ((listp x)
 388          (if x
 389              (dump-non-immediate-object x file)
 390              (dump-fop 'fop-empty-list file)))
 391         ((symbolp x)
 392          (if (eq x t)
 393              (dump-fop 'fop-truth file)
 394              (dump-non-immediate-object x file)))
 395         ((fixnump x) (dump-integer x file))
 396         ((characterp x) (dump-character x file))
 397         (t
 398          (dump-non-immediate-object x file))))
 399
 400 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 401 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 402 ;;; take the value to store on the stack. We compute this value by
 403 ;;; fetching the enclosing object from the table, and then CDR'ing it
 404 ;;; if necessary.
 405 (defun dump-circularities (infos file)
 406   (let ((table (fasl-output-eq-table file)))
 407     (dolist (info infos)
 408
 409       (let* ((value (circularity-value info))
 410              (enclosing (circularity-enclosing-object info)))
 411         (dump-push (gethash enclosing table) file)
 412         (unless (eq enclosing value)
 413           (do ((current enclosing (cdr current))
 414                (i 0 (1+ i)))
 415               ((eq current value)
 416                (dump-fop 'fop-nthcdr file)
 417                (dump-unsigned-32 i file))
 418             (declare (type index i)))))
 419
 420       (ecase (circularity-type info)
 421         (:rplaca     (dump-fop 'fop-rplaca    file))
 422         (:rplacd     (dump-fop 'fop-rplacd    file))
 423         (:svset      (dump-fop 'fop-svset     file))
 424         (:struct-set (dump-fop 'fop-structset file)))
 425       (dump-unsigned-32 (gethash (circularity-object info) table) file)
 426       (dump-unsigned-32 (circularity-index info) file))))
 427
 428 ;;; Set up stuff for circularity detection, then dump an object. All
 429 ;;; shared and circular structure will be exactly preserved within a
 430 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 431 ;;; separate calls is only preserved when convenient.
 432 ;;;
 433 ;;; We peek at the object type so that we only pay the circular
 434 ;;; detection overhead on types of objects that might be circular.
 435 (defun dump-object (x file)
 436   (if (or (array-header-p x)
 437           (simple-vector-p x)
 438           (consp x)
 439           (typep x 'instance))
 440       (let ((*circularities-detected* ())
 441             (circ (fasl-output-circularity-table file)))
 442         (clrhash circ)
 443         (sub-dump-object x file)
 444         (when *circularities-detected*
 445           (dump-circularities *circularities-detected* file)
 446           (clrhash circ)))
 447       (sub-dump-object x file)))
 448 \f
 449 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 450
 451 ;;; Emit a funcall of the function and return the handle for the
 452 ;;; result.
 453 (defun fasl-dump-load-time-value-lambda (fun file)
 454   (declare (type sb!c::clambda fun) (type fasl-output file))
 455   (let ((handle (gethash (sb!c::leaf-info fun)
 456                          (fasl-output-entry-table file))))
 457     (aver handle)
 458     (dump-push handle file)
 459     (dump-fop 'fop-funcall file)
 460     (dump-byte 0 file))
 461   (dump-pop file))
 462
 463 ;;; Return T iff CONSTANT has not already been dumped. It's been
 464 ;;; dumped if it's in the EQ table.
 465 (defun fasl-constant-already-dumped-p (constant file)
 466   (if (or (gethash constant (fasl-output-eq-table file))
 467           (gethash constant (fasl-output-valid-structures file)))
 468       t
 469       nil))
 470
 471 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 472 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 473 (defun fasl-note-handle-for-constant (constant handle file)
 474   (let ((table (fasl-output-eq-table file)))
 475     (when (gethash constant table)
 476       (error "~S already dumped?" constant))
 477     (setf (gethash constant table) handle))
 478   (values))
 479
 480 ;;; Note that the specified structure can just be dumped by
 481 ;;; enumerating the slots.
 482 (defun fasl-validate-structure (structure file)
 483   (setf (gethash structure (fasl-output-valid-structures file)) t)
 484   (values))
 485 \f
 486 ;;;; number dumping
 487
 488 ;;; Dump a ratio.
 489 (defun dump-ratio (x file)
 490   (sub-dump-object (numerator x) file)
 491   (sub-dump-object (denominator x) file)
 492   (dump-fop 'fop-ratio file))
 493
 494 ;;; Dump an integer.
 495 (defun dump-integer (n file)
 496   (typecase n
 497     ((signed-byte 8)
 498      (dump-fop 'fop-byte-integer file)
 499      (dump-byte (logand #xFF n) file))
 500     ((unsigned-byte 31)
 501      (dump-fop 'fop-word-integer file)
 502      (dump-unsigned-32 n file))
 503     ((signed-byte 32)
 504      (dump-fop 'fop-word-integer file)
 505      (dump-integer-as-n-bytes n 4 file))
 506     (t
 507      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 508        (dump-fop* bytes fop-small-integer fop-integer file)
 509        (dump-integer-as-n-bytes n bytes file)))))
 510
 511 (defun dump-float (x file)
 512   (etypecase x
 513     (single-float
 514      (dump-fop 'fop-single-float file)
 515      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 516     (double-float
 517      (dump-fop 'fop-double-float file)
 518      (let ((x x))
 519        (declare (double-float x))
 520        ;; FIXME: Why sometimes DUMP-UNSIGNED-32 and sometimes
 521        ;; DUMP-INTEGER-AS-N-BYTES .. 4?
 522        (dump-unsigned-32 (double-float-low-bits x) file)
 523        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 524     #!+long-float
 525     (long-float
 526      (dump-fop 'fop-long-float file)
 527      (dump-long-float x file))))
 528
 529 (defun dump-complex (x file)
 530   (typecase x
 531     #-sb-xc-host
 532     ((complex single-float)
 533      (dump-fop 'fop-complex-single-float file)
 534      (dump-integer-as-n-bytes (single-float-bits (realpart x)) 4 file)
 535      (dump-integer-as-n-bytes (single-float-bits (imagpart x)) 4 file))
 536     #-sb-xc-host
 537     ((complex double-float)
 538      (dump-fop 'fop-complex-double-float file)
 539      (let ((re (realpart x)))
 540        (declare (double-float re))
 541        (dump-unsigned-32 (double-float-low-bits re) file)
 542        (dump-integer-as-n-bytes (double-float-high-bits re) 4 file))
 543      (let ((im (imagpart x)))
 544        (declare (double-float im))
 545        (dump-unsigned-32 (double-float-low-bits im) file)
 546        (dump-integer-as-n-bytes (double-float-high-bits im) 4 file)))
 547     #!+long-float
 548     ((complex long-float)
 549      ;; (There's no easy way to mix #!+LONG-FLOAT and #-SB-XC-HOST
 550      ;; conditionalization at read time, so we do this SB-XC-HOST
 551      ;; conditional at runtime instead.)
 552      #+sb-xc-host (error "can't dump COMPLEX-LONG-FLOAT in cross-compiler")
 553      (dump-fop 'fop-complex-long-float file)
 554      (dump-long-float (realpart x) file)
 555      (dump-long-float (imagpart x) file))
 556     (t
 557      (sub-dump-object (realpart x) file)
 558      (sub-dump-object (imagpart x) file)
 559      (dump-fop 'fop-complex file))))
 560 \f
 561 ;;;; symbol dumping
 562
 563 ;;; Return the table index of PKG, adding the package to the table if
 564 ;;; necessary. During cold load, we read the string as a normal string
 565 ;;; so that we can do the package lookup at cold load time.
 566 ;;;
 567 ;;; FIXME: Despite the parallelism in names, the functionality of
 568 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 569 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 570 ;;; should be made more consistent.
 571 (defun dump-package (pkg file)
 572   (declare (type package pkg) (type fasl-output file))
 573   (declare (values index))
 574   (declare (inline assoc))
 575   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 576         (t
 577          (unless *cold-load-dump*
 578            (dump-fop 'fop-normal-load file))
 579          (dump-simple-string (package-name pkg) file)
 580          (dump-fop 'fop-package file)
 581          (unless *cold-load-dump*
 582            (dump-fop 'fop-maybe-cold-load file))
 583          (let ((entry (dump-pop file)))
 584            (push (cons pkg entry) (fasl-output-packages file))
 585            entry))))
 586 \f
 587 ;;; dumper for lists
 588
 589 ;;; Dump a list, setting up patching information when there are
 590 ;;; circularities. We scan down the list, checking for CDR and CAR
 591 ;;; circularities.
 592 ;;;
 593 ;;; If there is a CDR circularity, we terminate the list with NIL and
 594 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 595 ;;;
 596 ;;; If there is no CDR circularity, then we mark the current cons and
 597 ;;; check for a CAR circularity. When there is a CAR circularity, we
 598 ;;; make the CAR NIL initially, arranging for the current cons to be
 599 ;;; patched later.
 600 ;;;
 601 ;;; Otherwise, we recursively call the dumper to dump the current
 602 ;;; element.
 603 ;;;
 604 ;;; Marking of the conses is inhibited when *COLD-LOAD-DUMP* is true.
 605 ;;; This inhibits all circularity detection.
 606 (defun dump-list (list file)
 607   (aver (and list
 608              (not (gethash list (fasl-output-circularity-table file)))))
 609   (do* ((l list (cdr l))
 610         (n 0 (1+ n))
 611         (circ (fasl-output-circularity-table file)))
 612        ((atom l)
 613         (cond ((null l)
 614                (terminate-undotted-list n file))
 615               (t
 616                (sub-dump-object l file)
 617                (terminate-dotted-list n file))))
 618     (declare (type index n))
 619     (let ((ref (gethash l circ)))
 620       (when ref
 621         (push (make-circularity :type :rplacd
 622                                 :object list
 623                                 :index (1- n)
 624                                 :value l
 625                                 :enclosing-object ref)
 626               *circularities-detected*)
 627         (terminate-undotted-list n file)
 628         (return)))
 629
 630     (unless *cold-load-dump*
 631       (setf (gethash l circ) list))
 632
 633     (let* ((obj (car l))
 634            (ref (gethash obj circ)))
 635       (cond (ref
 636              (push (make-circularity :type :rplaca
 637                                      :object list
 638                                      :index n
 639                                      :value obj
 640                                      :enclosing-object ref)
 641                    *circularities-detected*)
 642              (sub-dump-object nil file))
 643             (t
 644              (sub-dump-object obj file))))))
 645
 646 (defun terminate-dotted-list (n file)
 647   (declare (type index n) (type fasl-output file))
 648   (case n
 649     (1 (dump-fop 'fop-list*-1 file))
 650     (2 (dump-fop 'fop-list*-2 file))
 651     (3 (dump-fop 'fop-list*-3 file))
 652     (4 (dump-fop 'fop-list*-4 file))
 653     (5 (dump-fop 'fop-list*-5 file))
 654     (6 (dump-fop 'fop-list*-6 file))
 655     (7 (dump-fop 'fop-list*-7 file))
 656     (8 (dump-fop 'fop-list*-8 file))
 657     (T (do ((nn n (- nn 255)))
 658            ((< nn 256)
 659             (dump-fop 'fop-list* file)
 660             (dump-byte nn file))
 661          (declare (type index nn))
 662          (dump-fop 'fop-list* file)
 663          (dump-byte 255 file)))))
 664
 665 ;;; If N > 255, must build list with one LIST operator, then LIST*
 666 ;;; operators.
 667
 668 (defun terminate-undotted-list (n file)
 669   (declare (type index n) (type fasl-output file))
 670   (case n
 671     (1 (dump-fop 'fop-list-1 file))
 672     (2 (dump-fop 'fop-list-2 file))
 673     (3 (dump-fop 'fop-list-3 file))
 674     (4 (dump-fop 'fop-list-4 file))
 675     (5 (dump-fop 'fop-list-5 file))
 676     (6 (dump-fop 'fop-list-6 file))
 677     (7 (dump-fop 'fop-list-7 file))
 678     (8 (dump-fop 'fop-list-8 file))
 679     (T (cond ((< n 256)
 680               (dump-fop 'fop-list file)
 681               (dump-byte n file))
 682              (t (dump-fop 'fop-list file)
 683                 (dump-byte 255 file)
 684                 (do ((nn (- n 255) (- nn 255)))
 685                     ((< nn 256)
 686                      (dump-fop 'fop-list* file)
 687                      (dump-byte nn file))
 688                   (declare (type index nn))
 689                   (dump-fop 'fop-list* file)
 690                   (dump-byte 255 file)))))))
 691 \f
 692 ;;;; array dumping
 693
 694 ;;; Dump the array thing.
 695 (defun dump-array (x file)
 696   (if (vectorp x)
 697       (dump-vector x file)
 698       (dump-multi-dim-array x file)))
 699
 700 ;;; Dump the vector object. If it's not simple, then actually dump a
 701 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 702 ;;; tables.
 703 (defun dump-vector (x file)
 704   (let ((simple-version (if (array-header-p x)
 705                             (coerce x 'simple-array)
 706                             x)))
 707     (typecase simple-version
 708       (simple-base-string
 709        (unless (equal-check-table x file)
 710          (dump-simple-string simple-version file)
 711          (equal-save-object x file)))
 712       (simple-vector
 713        (dump-simple-vector simple-version file)
 714        (eq-save-object x file))
 715       ((simple-array single-float (*))
 716        (dump-single-float-vector simple-version file)
 717        (eq-save-object x file))
 718       ((simple-array double-float (*))
 719        (dump-double-float-vector simple-version file)
 720        (eq-save-object x file))
 721       #!+long-float
 722       ((simple-array long-float (*))
 723        (dump-long-float-vector simple-version file)
 724        (eq-save-object x file))
 725       ((simple-array (complex single-float) (*))
 726        (dump-complex-single-float-vector simple-version file)
 727        (eq-save-object x file))
 728       ((simple-array (complex double-float) (*))
 729        (dump-complex-double-float-vector simple-version file)
 730        (eq-save-object x file))
 731       #!+long-float
 732       ((simple-array (complex long-float) (*))
 733        (dump-complex-long-float-vector simple-version file)
 734        (eq-save-object x file))
 735       (t
 736        (dump-i-vector simple-version file)
 737        (eq-save-object x file)))))
 738
 739 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 740 (defun dump-simple-vector (v file)
 741   (declare (type simple-vector v) (type fasl-output file))
 742   (note-potential-circularity v file)
 743   (do ((index 0 (1+ index))
 744        (length (length v))
 745        (circ (fasl-output-circularity-table file)))
 746       ((= index length)
 747        (dump-fop* length fop-small-vector fop-vector file))
 748     (let* ((obj (aref v index))
 749            (ref (gethash obj circ)))
 750       (cond (ref
 751              (push (make-circularity :type :svset
 752                                      :object v
 753                                      :index index
 754                                      :value obj
 755                                      :enclosing-object ref)
 756                    *circularities-detected*)
 757              (sub-dump-object nil file))
 758             (t
 759              (sub-dump-object obj file))))))
 760
 761 (defun dump-i-vector (vec file &key data-only)
 762   (declare (type (simple-array * (*)) vec))
 763   (let ((len (length vec)))
 764     (labels ((dump-unsigned-vector (size bytes)
 765                (unless data-only
 766                  (dump-fop 'fop-int-vector file)
 767                  (dump-unsigned-32 len file)
 768                  (dump-byte size file))
 769                ;; The case which is easy to handle in a portable way is when
 770                ;; the element size is a multiple of the output byte size, and
 771                ;; happily that's the only case we need to be portable. (The
 772                ;; cross-compiler has to output debug information (including
 773                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 774                ;; needed in the target SBCL, so we let them be handled with
 775                ;; unportable bit bashing.
 776                (cond ((>= size 8) ; easy cases
 777                       (multiple-value-bind (floor rem) (floor size 8)
 778                         (aver (zerop rem))
 779                         (dovector (i vec)
 780                           (dump-integer-as-n-bytes i floor file))))
 781                      (t ; harder cases, not supported in cross-compiler
 782                       (dump-raw-bytes vec bytes file))))
 783              (dump-signed-vector (size bytes)
 784                ;; Note: Dumping specialized signed vectors isn't
 785                ;; supported in the cross-compiler. (All cases here end
 786                ;; up trying to call DUMP-RAW-BYTES, which isn't
 787                ;; provided in the cross-compilation host, only on the
 788                ;; target machine.)
 789                (unless data-only
 790                  (dump-fop 'fop-signed-int-vector file)
 791                  (dump-unsigned-32 len file)
 792                  (dump-byte size file))
 793                (dump-raw-bytes vec bytes file)))
 794       (etypecase vec
 795         ;; KLUDGE: What exactly does the (ASH .. -3) stuff do? -- WHN 19990902
 796         (simple-bit-vector
 797          (dump-unsigned-vector 1 (ash (+ (the index len) 7) -3)))
 798         ((simple-array (unsigned-byte 2) (*))
 799          (dump-unsigned-vector 2 (ash (+ (the index (ash len 1)) 7) -3)))
 800         ((simple-array (unsigned-byte 4) (*))
 801          (dump-unsigned-vector 4 (ash (+ (the index (ash len 2)) 7) -3)))
 802         ((simple-array (unsigned-byte 8) (*))
 803          (dump-unsigned-vector 8 len))
 804         ((simple-array (unsigned-byte 16) (*))
 805          (dump-unsigned-vector 16 (* 2 len)))
 806         ((simple-array (unsigned-byte 32) (*))
 807          (dump-unsigned-vector 32 (* 4 len)))
 808         ((simple-array (signed-byte 8) (*))
 809          (dump-signed-vector 8 len))
 810         ((simple-array (signed-byte 16) (*))
 811          (dump-signed-vector 16 (* 2 len)))
 812         ((simple-array (signed-byte 30) (*))
 813          (dump-signed-vector 30 (* 4 len)))
 814         ((simple-array (signed-byte 32) (*))
 815          (dump-signed-vector 32 (* 4 len)))))))
 816 \f
 817 ;;; Dump characters and string-ish things.
 818
 819 (defun dump-character (ch file)
 820   (dump-fop 'fop-short-character file)
 821   (dump-byte (char-code ch) file))
 822
 823 ;;; a helper function shared by DUMP-SIMPLE-STRING and DUMP-SYMBOL
 824 (defun dump-characters-of-string (s fasl-output)
 825   (declare (type string s) (type fasl-output fasl-output))
 826   (dovector (c s)
 827     (dump-byte (char-code c) fasl-output))
 828   (values))
 829
 830 ;;; Dump a SIMPLE-BASE-STRING.
 831 ;;; FIXME: should be called DUMP-SIMPLE-BASE-STRING then
 832 (defun dump-simple-string (s file)
 833   (declare (type simple-base-string s))
 834   (dump-fop* (length s) fop-small-string fop-string file)
 835   (dump-characters-of-string s file)
 836   (values))
 837
 838 ;;; If we get here, it is assumed that the symbol isn't in the table,
 839 ;;; but we are responsible for putting it there when appropriate. To
 840 ;;; avoid too much special-casing, we always push the symbol in the
 841 ;;; table, but don't record that we have done so if *COLD-LOAD-DUMP*
 842 ;;; is true.
 843 (defun dump-symbol (s file)
 844   (declare (type fasl-output file))
 845   (let* ((pname (symbol-name s))
 846          (pname-length (length pname))
 847          (pkg (symbol-package s)))
 848
 849     (cond ((null pkg)
 850            (dump-fop* pname-length
 851                       fop-uninterned-small-symbol-save
 852                       fop-uninterned-symbol-save
 853                       file))
 854           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 855           ;; used the current value of *PACKAGE*. Unfortunately that's
 856           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 857           ;; from SBCL.
 858           ;;((eq pkg *package*)
 859           ;; (dump-fop* pname-length
 860           ;;        fop-small-symbol-save
 861           ;;        fop-symbol-save file))
 862           ((eq pkg sb!int:*cl-package*)
 863            (dump-fop* pname-length
 864                       fop-lisp-small-symbol-save
 865                       fop-lisp-symbol-save
 866                       file))
 867           ((eq pkg sb!int:*keyword-package*)
 868            (dump-fop* pname-length
 869                       fop-keyword-small-symbol-save
 870                       fop-keyword-symbol-save
 871                       file))
 872           ((< pname-length 256)
 873            (dump-fop* (dump-package pkg file)
 874                       fop-small-symbol-in-byte-package-save
 875                       fop-small-symbol-in-package-save
 876                       file)
 877            (dump-byte pname-length file))
 878           (t
 879            (dump-fop* (dump-package pkg file)
 880                       fop-symbol-in-byte-package-save
 881                       fop-symbol-in-package-save
 882                       file)
 883            (dump-unsigned-32 pname-length file)))
 884
 885     (dump-characters-of-string pname file)
 886
 887     (unless *cold-load-dump*
 888       (setf (gethash s (fasl-output-eq-table file))
 889             (fasl-output-table-free file)))
 890
 891     (incf (fasl-output-table-free file)))
 892
 893   (values))
 894 \f
 895 ;;;; component (function) dumping
 896
 897 (defun dump-segment (segment code-length fasl-output)
 898   (declare (type sb!assem:segment segment)
 899            (type fasl-output fasl-output))
 900   (let* ((stream (fasl-output-stream fasl-output))
 901          (nwritten (write-segment-contents segment stream)))
 902     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
 903     ;; argument and the number of bytes actually written. I added this
 904     ;; assertion while trying to debug portable genesis. -- WHN 19990902
 905     (unless (= code-length nwritten)
 906       (error "internal error, code-length=~D, nwritten=~D"
 907              code-length
 908              nwritten)))
 909   (values))
 910
 911 ;;; Dump all the fixups. Currently there are three flavors of fixup:
 912 ;;;  - assembly routines: named by a symbol
 913 ;;;  - foreign (C) symbols: named by a string
 914 ;;;  - code object references: don't need a name.
 915 (defun dump-fixups (fixups fasl-output)
 916   (declare (list fixups) (type fasl-output fasl-output))
 917   (dolist (info fixups)
 918     ;; FIXME: Packing data with LIST in NOTE-FIXUP and unpacking them
 919     ;; with FIRST, SECOND, and THIRD here is hard to follow and
 920     ;; maintain. Perhaps we could define a FIXUP-INFO structure to use
 921     ;; instead, and rename *FIXUPS* to *FIXUP-INFO-LIST*?
 922     (let* ((kind (first info))
 923            (fixup (second info))
 924            (name (fixup-name fixup))
 925            (flavor (fixup-flavor fixup))
 926            (offset (third info)))
 927       ;; FIXME: This OFFSET is not what's called OFFSET in the FIXUP
 928       ;; structure, it's what's called POSN in NOTE-FIXUP. (As far as
 929       ;; I can tell, FIXUP-OFFSET is not actually an offset, it's an
 930       ;; internal label used instead of NAME for :CODE-OBJECT fixups.
 931       ;; Notice that in the :CODE-OBJECT case, NAME is ignored.)
 932       (dump-fop 'fop-normal-load fasl-output)
 933       (let ((*cold-load-dump* t))
 934         (dump-object kind fasl-output))
 935       (dump-fop 'fop-maybe-cold-load fasl-output)
 936       ;; Depending on the flavor, we may have various kinds of
 937       ;; noise before the offset.
 938       (ecase flavor
 939         (:assembly-routine
 940          (aver (symbolp name))
 941          (dump-fop 'fop-normal-load fasl-output)
 942          (let ((*cold-load-dump* t))
 943            (dump-object name fasl-output))
 944          (dump-fop 'fop-maybe-cold-load fasl-output)
 945          (dump-fop 'fop-assembler-fixup fasl-output))
 946         (:foreign
 947          (aver (stringp name))
 948          (dump-fop 'fop-foreign-fixup fasl-output)
 949          (let ((len (length name)))
 950            (aver (< len 256)) ; (limit imposed by fop definition)
 951            (dump-byte len fasl-output)
 952            (dotimes (i len)
 953              (dump-byte (char-code (schar name i)) fasl-output))))
 954         (:code-object
 955          (aver (null name))
 956          (dump-fop 'fop-code-object-fixup fasl-output)))
 957       ;; No matter what the flavor, we'll always dump the offset.
 958       (dump-unsigned-32 offset fasl-output)))
 959   (values))
 960
 961 ;;; Dump out the constant pool and code-vector for component, push the
 962 ;;; result in the table, and return the offset.
 963 ;;;
 964 ;;; The only tricky thing is handling constant-pool references to
 965 ;;; functions. If we have already dumped the function, then we just
 966 ;;; push the code pointer. Otherwise, we must create back-patching
 967 ;;; information so that the constant will be set when the function is
 968 ;;; eventually dumped. This is a bit awkward, since we don't have the
 969 ;;; handle for the code object being dumped while we are dumping its
 970 ;;; constants.
 971 ;;;
 972 ;;; We dump trap objects in any unused slots or forward referenced slots.
 973 (defun dump-code-object (component
 974                          code-segment
 975                          code-length
 976                          trace-table-as-list
 977                          fixups
 978                          fasl-output)
 979
 980   (declare (type component component)
 981            (list trace-table-as-list)
 982            (type index code-length)
 983            (type fasl-output fasl-output))
 984
 985   (let* ((2comp (component-info component))
 986          (constants (sb!c::ir2-component-constants 2comp))
 987          (header-length (length constants))
 988          (packed-trace-table (pack-trace-table trace-table-as-list))
 989          (total-length (+ code-length
 990                           (* (length packed-trace-table)
 991                              sb!c::tt-bytes-per-entry))))
 992
 993     (collect ((patches))
 994
 995       ;; Dump the offset of the trace table.
 996       (dump-object code-length fasl-output)
 997       ;; FIXME: As long as we don't have GENGC, the trace table is
 998       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
 999       ;; far as I know no modern CMU CL does either -- WHN
1000       ;; 2001-10-05). So might we be able to get rid of trace tables?
1001
1002       ;; Dump the constants, noting any :entries that have to be fixed up.
1003       (do ((i sb!vm:code-constants-offset (1+ i)))
1004           ((>= i header-length))
1005         (let ((entry (aref constants i)))
1006           (etypecase entry
1007             (constant
1008              (dump-object (sb!c::constant-value entry) fasl-output))
1009             (cons
1010              (ecase (car entry)
1011                (:entry
1012                 (let* ((info (sb!c::leaf-info (cdr entry)))
1013                        (handle (gethash info
1014                                         (fasl-output-entry-table
1015                                          fasl-output))))
1016                   (cond
1017                    (handle
1018                     (dump-push handle fasl-output))
1019                    (t
1020                     (patches (cons info i))
1021                     (dump-fop 'fop-misc-trap fasl-output)))))
1022                (:load-time-value
1023                 (dump-push (cdr entry) fasl-output))
1024                (:fdefinition
1025                 (dump-object (cdr entry) fasl-output)
1026                 (dump-fop 'fop-fdefinition fasl-output))))
1027             (null
1028              (dump-fop 'fop-misc-trap fasl-output)))))
1029
1030       ;; Dump the debug info.
1031       (let ((info (sb!c::debug-info-for-component component))
1032             (*dump-only-valid-structures* nil))
1033         (dump-object info fasl-output)
1034         (let ((info-handle (dump-pop fasl-output)))
1035           (dump-push info-handle fasl-output)
1036           (push info-handle (fasl-output-debug-info fasl-output))))
1037
1038       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1039         (cond ((and (< num-consts #x100) (< total-length #x10000))
1040                (dump-fop 'fop-small-code fasl-output)
1041                (dump-byte num-consts fasl-output)
1042                (dump-integer-as-n-bytes total-length 2 fasl-output))
1043               (t
1044                (dump-fop 'fop-code fasl-output)
1045                (dump-unsigned-32 num-consts fasl-output)
1046                (dump-unsigned-32 total-length fasl-output))))
1047
1048       ;; These two dumps are only ones which contribute to our
1049       ;; TOTAL-LENGTH value.
1050       (dump-segment code-segment code-length fasl-output)
1051       (dump-i-vector packed-trace-table fasl-output :data-only t)
1052
1053       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1054       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1055       ;; FOP-CODE/FOP-SMALL-CODE fop.
1056       (dump-fixups fixups fasl-output)
1057
1058       (dump-fop 'fop-sanctify-for-execution fasl-output)
1059       (let ((handle (dump-pop fasl-output)))
1060         (dolist (patch (patches))
1061           (push (cons handle (cdr patch))
1062                 (gethash (car patch)
1063                          (fasl-output-patch-table fasl-output))))
1064         handle))))
1065
1066 (defun dump-assembler-routines (code-segment length fixups routines file)
1067   (dump-fop 'fop-assembler-code file)
1068   (dump-unsigned-32 length file)
1069   (write-segment-contents code-segment (fasl-output-stream file))
1070   (dolist (routine routines)
1071     (dump-fop 'fop-normal-load file)
1072     (let ((*cold-load-dump* t))
1073       (dump-object (car routine) file))
1074     (dump-fop 'fop-maybe-cold-load file)
1075     (dump-fop 'fop-assembler-routine file)
1076     (dump-unsigned-32 (label-position (cdr routine)) file))
1077   (dump-fixups fixups file)
1078   (dump-fop 'fop-sanctify-for-execution file)
1079   (dump-pop file))
1080
1081 ;;; Dump a function-entry data structure corresponding to ENTRY to
1082 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1083 ;;; component.
1084 (defun dump-one-entry (entry code-handle file)
1085   (declare (type sb!c::entry-info entry) (type index code-handle)
1086            (type fasl-output file))
1087   (let ((name (sb!c::entry-info-name entry)))
1088     (dump-push code-handle file)
1089     (dump-object name file)
1090     (dump-object (sb!c::entry-info-arguments entry) file)
1091     (dump-object (sb!c::entry-info-type entry) file)
1092     (dump-fop 'fop-function-entry file)
1093     (dump-unsigned-32 (label-position (sb!c::entry-info-offset entry)) file)
1094     (dump-pop file)))
1095
1096 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1097 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1098 (defun dump-alter-code-object (code-handle offset entry-handle file)
1099   (declare (type index code-handle entry-handle offset))
1100   (declare (type fasl-output file))
1101   (dump-push code-handle file)
1102   (dump-push entry-handle file)
1103   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1104   (values))
1105
1106 ;;; Dump the code, constants, etc. for component. We pass in the
1107 ;;; assembler fixups, code vector and node info.
1108 (defun fasl-dump-component (component
1109                             code-segment
1110                             code-length
1111                             trace-table
1112                             fixups
1113                             file)
1114   (declare (type component component) (list trace-table))
1115   (declare (type fasl-output file))
1116
1117   (dump-fop 'fop-verify-empty-stack file)
1118   (dump-fop 'fop-verify-table-size file)
1119   (dump-unsigned-32 (fasl-output-table-free file) file)
1120
1121   #!+sb-dyncount
1122   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1123     (when info
1124       (fasl-validate-structure info file)))
1125
1126   (let ((code-handle (dump-code-object component
1127                                        code-segment
1128                                        code-length
1129                                        trace-table
1130                                        fixups
1131                                        file))
1132         (2comp (component-info component)))
1133     (dump-fop 'fop-verify-empty-stack file)
1134
1135     (dolist (entry (sb!c::ir2-component-entries 2comp))
1136       (let ((entry-handle (dump-one-entry entry code-handle file)))
1137         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1138
1139         (let ((old (gethash entry (fasl-output-patch-table file))))
1140           ;; FIXME: All this code is shared with
1141           ;; FASL-DUMP-BYTE-COMPONENT, and should probably be gathered
1142           ;; up into a named function (DUMP-PATCHES?) called from both
1143           ;; functions.
1144           (when old
1145             (dolist (patch old)
1146               (dump-alter-code-object (car patch)
1147                                       (cdr patch)
1148                                       entry-handle
1149                                       file))
1150             (remhash entry (fasl-output-patch-table file)))))))
1151   (values))
1152
1153 (defun dump-push-previously-dumped-fun (fun fasl-output)
1154   (declare (type sb!c::clambda fun))
1155   (let ((handle (gethash (sb!c::leaf-info fun)
1156                          (fasl-output-entry-table fasl-output))))
1157     (aver handle)
1158     (dump-push handle fasl-output))
1159   (values))
1160
1161 ;;; Dump a FOP-FUNCALL to call an already-dumped top-level lambda at
1162 ;;; load time.
1163 (defun fasl-dump-top-level-lambda-call (fun fasl-output)
1164   (declare (type sb!c::clambda fun))
1165   (dump-push-previously-dumped-fun fun fasl-output)
1166   (dump-fop 'fop-funcall-for-effect fasl-output)
1167   (dump-byte 0 fasl-output)
1168   (values))
1169
1170 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1171 ;;; FUN-NAME and the already-dumped function whose dump handle is
1172 ;;; FUN-DUMP-HANDLE.
1173 #+sb-xc-host
1174 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1175   (declare (type fixnum fun-dump-handle))
1176   (aver (legal-function-name-p fun-name))
1177   (dump-non-immediate-object fun-name fasl-output)
1178   (dump-push fun-dump-handle fasl-output)
1179   (dump-fop 'fop-fset fasl-output)
1180   (values))
1181
1182 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1183 ;;; all of the dumped DEBUG-INFO structures. We clear the
1184 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1185 ;;; different source info may be dumped.
1186 (defun fasl-dump-source-info (info fasl-output)
1187   (declare (type sb!c::source-info info))
1188   (let ((res (sb!c::debug-source-for-info info))
1189         (*dump-only-valid-structures* nil))
1190     (dump-object res fasl-output)
1191     (let ((res-handle (dump-pop fasl-output)))
1192       (dolist (info-handle (fasl-output-debug-info fasl-output))
1193         (dump-push res-handle fasl-output)
1194         (dump-fop 'fop-structset fasl-output)
1195         (dump-unsigned-32 info-handle fasl-output)
1196         (dump-unsigned-32 2 fasl-output))))
1197   (setf (fasl-output-debug-info fasl-output) nil)
1198   (values))
1199 \f
1200 ;;;; dumping structures
1201
1202 (defun dump-structure (struct file)
1203   (when *dump-only-valid-structures*
1204     (unless (gethash struct (fasl-output-valid-structures file))
1205       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1206              struct)))
1207   (note-potential-circularity struct file)
1208   (do ((index 0 (1+ index))
1209        (length (%instance-length struct))
1210        (circ (fasl-output-circularity-table file)))
1211       ((= index length)
1212        (dump-fop* length fop-small-struct fop-struct file))
1213     (let* ((obj (%instance-ref struct index))
1214            (ref (gethash obj circ)))
1215       (cond (ref
1216              (push (make-circularity :type :struct-set
1217                                      :object struct
1218                                      :index index
1219                                      :value obj
1220                                      :enclosing-object ref)
1221                    *circularities-detected*)
1222              (sub-dump-object nil file))
1223             (t
1224              (sub-dump-object obj file))))))
1225
1226 (defun dump-layout (obj file)
1227   (when (layout-invalid obj)
1228     (compiler-error "attempt to dump reference to obsolete class: ~S"
1229                     (layout-class obj)))
1230   (let ((name (sb!xc:class-name (layout-class obj))))
1231     (unless name
1232       (compiler-error "dumping anonymous layout: ~S" obj))
1233     (dump-fop 'fop-normal-load file)
1234     (let ((*cold-load-dump* t))
1235       (dump-object name file))
1236     (dump-fop 'fop-maybe-cold-load file))
1237   (sub-dump-object (layout-inherits obj) file)
1238   (sub-dump-object (layout-depthoid obj) file)
1239   (sub-dump-object (layout-length obj) file)
1240   (dump-fop 'fop-layout file))