src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (missing-arg) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance pathologies with objects for which EQUAL degenerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the ENTRY-INFO structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the ENTRY-INFO structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (missing-arg) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (missing-arg) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to inhibit table access when dumping forms to be read by the
  95 ;;; cold loader
  96 (defvar *cold-load-dump* nil)
  97
  98 ;;; used to turn off the structure validation during dumping of source
  99 ;;; info
 100 (defvar *dump-only-valid-structures* t)
 101 ;;;; utilities
 102
 103 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 104 (defun dump-byte (b fasl-output)
 105   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 106   (write-byte b (fasl-output-stream fasl-output)))
 107
 108 ;; Dump a word-sized integer.
 109 (defun dump-word (num fasl-output)
 110   (declare (type sb!vm:word num))
 111   (declare (type fasl-output fasl-output))
 112   (let ((stream (fasl-output-stream fasl-output)))
 113     (dotimes (i sb!vm:n-word-bytes)
 114       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 115
 116 ;; Dump a 32-bit integer.
 117 (defun dump-unsigned-byte-32 (num fasl-output)
 118   (declare (type sb!vm:word num))
 119   (declare (type fasl-output fasl-output))
 120   (let ((stream (fasl-output-stream fasl-output)))
 121     (dotimes (i 4)
 122       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 123
 124 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 125 ;;; for either signed or unsigned integers. There's no range checking
 126 ;;; -- if you don't specify enough bytes for the number to fit, this
 127 ;;; function cheerfully outputs the low bytes.
 128 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 129   (declare (integer num) (type index bytes))
 130   (declare (type fasl-output fasl-output))
 131   (do ((n num (ash n -8))
 132        (i bytes (1- i)))
 133       ((= i 0))
 134     (declare (type index i))
 135     (dump-byte (logand n #xff) fasl-output))
 136   (values))
 137
 138 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 139 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 140 ;;; counter value before every ordinary fop. This can make it easier
 141 ;;; to follow the progress of LOAD-AS-FASL when
 142 ;;; debugging/testing/experimenting.
 143 #!+sb-show (defvar *fop-nop4-count* nil)
 144 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 145
 146 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 147 ;;;
 148 ;;; FIXME: This should be a function, with a compiler macro expansion
 149 ;;; for the common constant-FS case. (Among other things, that'll stop
 150 ;;; it from EVALing ,FILE multiple times.)
 151 ;;;
 152 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 153 ;;; optimizations should be conditional on #!+SB-FROZEN.
 154 (defmacro dump-fop (fs file)
 155   (let* ((fs (eval fs))
 156          (val (get fs 'fop-code)))
 157     (if val
 158       `(progn
 159          #!+sb-show
 160          (when *fop-nop4-count*
 161            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 162            (dump-integer-as-n-bytes (mod (incf *fop-nop4-count*) (expt 2 32))
 163                                     4 ,file))
 164          (dump-byte ',val ,file))
 165       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 166
 167 ;;; Dump a FOP-CODE along with an integer argument, choosing the FOP
 168 ;;; based on whether the argument will fit in a single byte.
 169 ;;;
 170 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 171 ;;; compiler-macro expansion.
 172 (defmacro dump-fop* (n byte-fop word-fop file)
 173   (once-only ((n-n n)
 174               (n-file file))
 175     `(cond ((< ,n-n 256)
 176             (dump-fop ',byte-fop ,n-file)
 177             (dump-byte ,n-n ,n-file))
 178            (t
 179             (dump-fop ',word-fop ,n-file)
 180             (dump-word ,n-n ,n-file)))))
 181
 182 ;;; Push the object at table offset Handle on the fasl stack.
 183 (defun dump-push (handle fasl-output)
 184   (declare (type index handle) (type fasl-output fasl-output))
 185   (dump-fop* handle fop-byte-push fop-push fasl-output)
 186   (values))
 187
 188 ;;; Pop the object currently on the fasl stack top into the table, and
 189 ;;; return the table index, incrementing the free pointer.
 190 (defun dump-pop (fasl-output)
 191   (prog1
 192       (fasl-output-table-free fasl-output)
 193     (dump-fop 'fop-pop fasl-output)
 194     (incf (fasl-output-table-free fasl-output))))
 195
 196 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 197 ;;; otherwise NIL. If *COLD-LOAD-DUMP* is true, then do nothing and
 198 ;;; return NIL.
 199 (defun equal-check-table (x fasl-output)
 200   (declare (type fasl-output fasl-output))
 201   (unless *cold-load-dump*
 202     (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 203       (cond
 204         (handle (dump-push handle fasl-output) t)
 205         (t nil)))))
 206 (defun string-check-table (x fasl-output)
 207   (declare (type fasl-output fasl-output)
 208            (type string x))
 209   (unless *cold-load-dump*
 210     (let ((handle (cdr (assoc
 211                         (array-element-type x)
 212                         (gethash x (fasl-output-equal-table fasl-output))))))
 213       (cond
 214         (handle (dump-push handle fasl-output) t)
 215         (t nil)))))
 216
 217 ;;; These functions are called after dumping an object to save the
 218 ;;; object in the table. The object (also passed in as X) must already
 219 ;;; be on the top of the FOP stack. If *COLD-LOAD-DUMP* is true, then
 220 ;;; we don't do anything.
 221 (defun eq-save-object (x fasl-output)
 222   (declare (type fasl-output fasl-output))
 223   (unless *cold-load-dump*
 224     (let ((handle (dump-pop fasl-output)))
 225       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 226       (dump-push handle fasl-output)))
 227   (values))
 228 (defun equal-save-object (x fasl-output)
 229   (declare (type fasl-output fasl-output))
 230   (unless *cold-load-dump*
 231     (let ((handle (dump-pop fasl-output)))
 232       (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 233       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 234       (dump-push handle fasl-output)))
 235   (values))
 236 (defun string-save-object (x fasl-output)
 237   (declare (type fasl-output fasl-output)
 238            (type string x))
 239   (unless *cold-load-dump*
 240     (let ((handle (dump-pop fasl-output)))
 241       (push (cons (array-element-type x) handle)
 242             (gethash x (fasl-output-equal-table fasl-output)))
 243       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 244       (dump-push handle fasl-output)))
 245   (values))
 246 ;;; Record X in File's CIRCULARITY-TABLE unless *COLD-LOAD-DUMP* is
 247 ;;; true. This is called on objects that we are about to dump might
 248 ;;; have a circular path through them.
 249 ;;;
 250 ;;; The object must not currently be in this table, since the dumper
 251 ;;; should never be recursively called on a circular reference.
 252 ;;; Instead, the dumping function must detect the circularity and
 253 ;;; arrange for the dumped object to be patched.
 254 (defun note-potential-circularity (x fasl-output)
 255   (unless *cold-load-dump*
 256     (let ((circ (fasl-output-circularity-table fasl-output)))
 257       (aver (not (gethash x circ)))
 258       (setf (gethash x circ) x)))
 259   (values))
 260
 261 ;;; Dump FORM to a fasl file so that it evaluated at load time in normal
 262 ;;; load and at cold-load time in cold load. This is used to dump package
 263 ;;; frobbing forms.
 264 (defun fasl-dump-cold-load-form (form fasl-output)
 265   (declare (type fasl-output fasl-output))
 266   (dump-fop 'fop-normal-load fasl-output)
 267   (let ((*cold-load-dump* t))
 268     (dump-object form fasl-output))
 269   (dump-fop 'fop-eval-for-effect fasl-output)
 270   (dump-fop 'fop-maybe-cold-load fasl-output)
 271   (values))
 272 \f
 273 ;;;; opening and closing fasl files
 274
 275 ;;; A utility function to write strings to (unsigned-byte 8) streams.
 276 ;;; We restrict this to ASCII (with the averrance) because of
 277 ;;; ambiguity of higher bytes: Unicode, some ISO-8859-x, or what? This
 278 ;;; could be revisited in the event of doing funky things with stream
 279 ;;; encodings -- CSR, 2002-04-25
 280 (defun fasl-write-string (string stream)
 281   (loop for char across string
 282         do (let ((code (char-code char)))
 283              (aver (<= 0 code 127))
 284              (write-byte code stream))))
 285
 286 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 287 ;;; object for dumping to it. Some human-readable information about
 288 ;;; the source code is given by the string WHERE.
 289 (defun open-fasl-output (name where)
 290   (declare (type pathname name))
 291   (let* ((stream (open name
 292                        :direction :output
 293                        :if-exists :supersede
 294                        :element-type 'sb!assem:assembly-unit))
 295          (res (make-fasl-output :stream stream)))
 296
 297     ;; Begin the header with the constant machine-readable (and
 298     ;; semi-human-readable) string which is used to identify fasl files.
 299     (fasl-write-string *fasl-header-string-start-string* stream)
 300
 301     ;; The constant string which begins the header is followed by
 302     ;; arbitrary human-readable text, terminated by a special
 303     ;; character code.
 304     (fasl-write-string
 305      (with-standard-io-syntax
 306        (let ((*print-readably* nil)
 307              (*print-pretty* nil))
 308          (format nil
 309                  "~%  ~
 310                   compiled from ~S~%  ~
 311                   at ~A~%  ~
 312                   on ~A~%  ~
 313                   using ~A version ~A~%"
 314          where
 315                  (format-universal-time nil (get-universal-time))
 316                  (machine-instance)
 317                  (sb!xc:lisp-implementation-type)
 318                  (sb!xc:lisp-implementation-version))))
 319      stream)
 320     (dump-byte +fasl-header-string-stop-char-code+ res)
 321
 322     ;; Finish the header by outputting fasl file implementation,
 323     ;; version, and key *FEATURES*.
 324     (flet ((dump-counted-string (string)
 325              ;; The count is dumped as a 32-bit unsigned-byte even on 64-bit
 326              ;; platforms. This ensures that a x86-64 SBCL can gracefully
 327              ;; detect an error when trying to read a x86 fasl, instead
 328              ;; of choking on a ridiculously long counted string.
 329              ;;  -- JES, 2005-12-30
 330              (dump-unsigned-byte-32 (length string) res)
 331              (dotimes (i (length string))
 332                (dump-byte (char-code (aref string i)) res))))
 333       (dump-counted-string (symbol-name +backend-fasl-file-implementation+))
 334       (dump-word +fasl-file-version+ res)
 335       (dump-counted-string *features-affecting-fasl-format*))
 336
 337     res))
 338
 339 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 340 (defun close-fasl-output (fasl-output abort-p)
 341   (declare (type fasl-output fasl-output))
 342
 343   ;; sanity checks
 344   (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 345
 346   ;; End the group.
 347   (dump-fop 'fop-verify-empty-stack fasl-output)
 348   (dump-fop 'fop-verify-table-size fasl-output)
 349   (dump-word (fasl-output-table-free fasl-output)
 350                     fasl-output)
 351   (dump-fop 'fop-end-group fasl-output)
 352
 353   ;; That's all, folks.
 354   (close (fasl-output-stream fasl-output) :abort abort-p)
 355   (values))
 356 \f
 357 ;;;; main entries to object dumping
 358
 359 ;;; This function deals with dumping objects that are complex enough
 360 ;;; so that we want to cache them in the table, rather than repeatedly
 361 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 362 ;;; otherwise, we do a type dispatch to a type specific dumping
 363 ;;; function. The type specific branches do any appropriate
 364 ;;; EQUAL-TABLE check and table entry.
 365 ;;;
 366 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 367 (defun dump-non-immediate-object (x file)
 368   (let ((index (gethash x (fasl-output-eq-table file))))
 369     (cond ((and index (not *cold-load-dump*))
 370            (dump-push index file))
 371           (t
 372            (typecase x
 373              (symbol (dump-symbol x file))
 374              (list
 375               ;; KLUDGE: The code in this case has been hacked
 376               ;; to match Douglas Crosher's quick fix to CMU CL
 377               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 378               ;; with help from Martin Atzmueller. This is not an
 379               ;; ideal solution; to quote DTC,
 380               ;;   The compiler locks up trying to coalesce the
 381               ;;   constant lists. The hack below will disable the
 382               ;;   coalescing of lists while dumping and allows
 383               ;;   the code to compile. The real fix would be to
 384               ;;   take a little more care while dumping these.
 385               ;; So if better list coalescing is needed, start here.
 386               ;; -- WHN 2000-11-07
 387               (if (maybe-cyclic-p x)
 388                   (progn
 389                     (dump-list x file)
 390                     (eq-save-object x file))
 391                   (unless (equal-check-table x file)
 392                     (dump-list x file)
 393                     (equal-save-object x file))))
 394              (layout
 395               (dump-layout x file)
 396               (eq-save-object x file))
 397              (instance
 398               (dump-structure x file)
 399               (eq-save-object x file))
 400              (array
 401               ;; DUMP-ARRAY (and its callees) are responsible for
 402               ;; updating the EQ and EQUAL hash tables.
 403               (dump-array x file))
 404              (number
 405               (unless (equal-check-table x file)
 406                 (etypecase x
 407                   (ratio (dump-ratio x file))
 408                   (complex (dump-complex x file))
 409                   (float (dump-float x file))
 410                   (integer (dump-integer x file)))
 411                 (equal-save-object x file)))
 412              (t
 413               ;; This probably never happens, since bad things tend to
 414               ;; be detected during IR1 conversion.
 415               (error "This object cannot be dumped into a fasl file:~% ~S"
 416                      x))))))
 417   (values))
 418
 419 ;;; Dump an object of any type by dispatching to the correct
 420 ;;; type-specific dumping function. We pick off immediate objects,
 421 ;;; symbols and magic lists here. Other objects are handled by
 422 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 423 ;;;
 424 ;;; This is the function used for recursive calls to the fasl dumper.
 425 ;;; We don't worry about creating circularities here, since it is
 426 ;;; assumed that there is a top level call to DUMP-OBJECT.
 427 (defun sub-dump-object (x file)
 428   (cond ((listp x)
 429          (if x
 430              (dump-non-immediate-object x file)
 431              (dump-fop 'fop-empty-list file)))
 432         ((symbolp x)
 433          (if (eq x t)
 434              (dump-fop 'fop-truth file)
 435              (dump-non-immediate-object x file)))
 436         ((fixnump x) (dump-integer x file))
 437         ((characterp x) (dump-character x file))
 438         (t
 439          (dump-non-immediate-object x file))))
 440
 441 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 442 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 443 ;;; take the value to store on the stack. We compute this value by
 444 ;;; fetching the enclosing object from the table, and then CDR'ing it
 445 ;;; if necessary.
 446 (defun dump-circularities (infos file)
 447   (let ((table (fasl-output-eq-table file)))
 448     (dolist (info infos)
 449
 450       (let* ((value (circularity-value info))
 451              (enclosing (circularity-enclosing-object info)))
 452         (dump-push (gethash enclosing table) file)
 453         (unless (eq enclosing value)
 454           (do ((current enclosing (cdr current))
 455                (i 0 (1+ i)))
 456               ((eq current value)
 457                (dump-fop 'fop-nthcdr file)
 458                (dump-word i file))
 459             (declare (type index i)))))
 460
 461       (ecase (circularity-type info)
 462         (:rplaca     (dump-fop 'fop-rplaca    file))
 463         (:rplacd     (dump-fop 'fop-rplacd    file))
 464         (:svset      (dump-fop 'fop-svset     file))
 465         (:struct-set (dump-fop 'fop-structset file)))
 466       (dump-word (gethash (circularity-object info) table) file)
 467       (dump-word (circularity-index info) file))))
 468
 469 ;;; Set up stuff for circularity detection, then dump an object. All
 470 ;;; shared and circular structure will be exactly preserved within a
 471 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 472 ;;; separate calls is only preserved when convenient.
 473 ;;;
 474 ;;; We peek at the object type so that we only pay the circular
 475 ;;; detection overhead on types of objects that might be circular.
 476 (defun dump-object (x file)
 477   (if (compound-object-p x)
 478       (let ((*circularities-detected* ())
 479             (circ (fasl-output-circularity-table file)))
 480         (clrhash circ)
 481         (sub-dump-object x file)
 482         (when *circularities-detected*
 483           (dump-circularities *circularities-detected* file)
 484           (clrhash circ)))
 485       (sub-dump-object x file)))
 486 \f
 487 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 488
 489 ;;; Emit a funcall of the function and return the handle for the
 490 ;;; result.
 491 (defun fasl-dump-load-time-value-lambda (fun file)
 492   (declare (type sb!c::clambda fun) (type fasl-output file))
 493   (let ((handle (gethash (sb!c::leaf-info fun)
 494                          (fasl-output-entry-table file))))
 495     (aver handle)
 496     (dump-push handle file)
 497     (dump-fop 'fop-funcall file)
 498     (dump-byte 0 file))
 499   (dump-pop file))
 500
 501 ;;; Return T iff CONSTANT has already been dumped. It's been dumped if
 502 ;;; it's in the EQ table.
 503 ;;;
 504 ;;; Note: historically (1) the above comment was "T iff ... has not been dumped",
 505 ;;; (2) the test was  was also true if the constant had been validated / was in
 506 ;;; the valid objects table. This led to substructures occasionally skipping the
 507 ;;; validation, and hence failing the "must have been validated" test.
 508 (defun fasl-constant-already-dumped-p (constant file)
 509   (and (gethash constant (fasl-output-eq-table file)) t))
 510
 511 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 512 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 513 (defun fasl-note-handle-for-constant (constant handle file)
 514   (let ((table (fasl-output-eq-table file)))
 515     (when (gethash constant table)
 516       (error "~S already dumped?" constant))
 517     (setf (gethash constant table) handle))
 518   (values))
 519
 520 ;;; Note that the specified structure can just be dumped by
 521 ;;; enumerating the slots.
 522 (defun fasl-validate-structure (structure file)
 523   (setf (gethash structure (fasl-output-valid-structures file)) t)
 524   (values))
 525 \f
 526 ;;;; number dumping
 527
 528 (defun dump-ratio (x file)
 529   (sub-dump-object (numerator x) file)
 530   (sub-dump-object (denominator x) file)
 531   (dump-fop 'fop-ratio file))
 532
 533 (defun dump-integer (n file)
 534   (typecase n
 535     ((signed-byte 8)
 536      (dump-fop 'fop-byte-integer file)
 537      (dump-byte (logand #xFF n) file))
 538     ((unsigned-byte #.(1- sb!vm:n-word-bits))
 539      (dump-fop 'fop-word-integer file)
 540      (dump-word n file))
 541     ((signed-byte #.sb!vm:n-word-bits)
 542      (dump-fop 'fop-word-integer file)
 543      (dump-integer-as-n-bytes n #.sb!vm:n-word-bytes file))
 544     (t
 545      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 546        (dump-fop* bytes fop-small-integer fop-integer file)
 547        (dump-integer-as-n-bytes n bytes file)))))
 548
 549 (defun dump-float (x file)
 550   (etypecase x
 551     (single-float
 552      (dump-fop 'fop-single-float file)
 553      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 554     (double-float
 555      (dump-fop 'fop-double-float file)
 556      (let ((x x))
 557        (declare (double-float x))
 558        (dump-integer-as-n-bytes (double-float-low-bits x) 4 file)
 559        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 560     #!+long-float
 561     (long-float
 562      (dump-fop 'fop-long-float file)
 563      (dump-long-float x file))))
 564
 565 (defun dump-complex (x file)
 566   (typecase x
 567     #-sb-xc-host
 568     ((complex single-float)
 569      (dump-fop 'fop-complex-single-float file)
 570      (dump-integer-as-n-bytes (single-float-bits (realpart x)) 4 file)
 571      (dump-integer-as-n-bytes (single-float-bits (imagpart x)) 4 file))
 572     #-sb-xc-host
 573     ((complex double-float)
 574      (dump-fop 'fop-complex-double-float file)
 575      (let ((re (realpart x)))
 576        (declare (double-float re))
 577        (dump-integer-as-n-bytes (double-float-low-bits re) 4 file)
 578        (dump-integer-as-n-bytes (double-float-high-bits re) 4 file))
 579      (let ((im (imagpart x)))
 580        (declare (double-float im))
 581        (dump-integer-as-n-bytes (double-float-low-bits im) 4 file)
 582        (dump-integer-as-n-bytes (double-float-high-bits im) 4 file)))
 583     #!+long-float
 584     ((complex long-float)
 585      ;; (There's no easy way to mix #!+LONG-FLOAT and #-SB-XC-HOST
 586      ;; conditionalization at read time, so we do this SB-XC-HOST
 587      ;; conditional at runtime instead.)
 588      #+sb-xc-host (error "can't dump COMPLEX-LONG-FLOAT in cross-compiler")
 589      (dump-fop 'fop-complex-long-float file)
 590      (dump-long-float (realpart x) file)
 591      (dump-long-float (imagpart x) file))
 592     (t
 593      (sub-dump-object (realpart x) file)
 594      (sub-dump-object (imagpart x) file)
 595      (dump-fop 'fop-complex file))))
 596 \f
 597 ;;;; symbol dumping
 598
 599 ;;; Return the table index of PKG, adding the package to the table if
 600 ;;; necessary. During cold load, we read the string as a normal string
 601 ;;; so that we can do the package lookup at cold load time.
 602 ;;;
 603 ;;; FIXME: Despite the parallelism in names, the functionality of
 604 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 605 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 606 ;;; should be made more consistent.
 607 (declaim (ftype (function (package fasl-output) index) dump-package))
 608 (defun dump-package (pkg file)
 609   (declare (inline assoc))
 610   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 611         (t
 612          (unless *cold-load-dump*
 613            (dump-fop 'fop-normal-load file))
 614          #+sb-xc-host
 615          (dump-simple-base-string
 616           (coerce (package-name pkg) 'simple-base-string)
 617           file)
 618          #-sb-xc-host
 619          (#!+sb-unicode dump-simple-character-string
 620           #!-sb-unicode dump-simple-base-string
 621           (coerce (package-name pkg) '(simple-array character (*)))
 622           file)
 623          (dump-fop 'fop-package file)
 624          (unless *cold-load-dump*
 625            (dump-fop 'fop-maybe-cold-load file))
 626          (let ((entry (dump-pop file)))
 627            (push (cons pkg entry) (fasl-output-packages file))
 628            entry))))
 629 \f
 630 ;;; dumper for lists
 631
 632 ;;; Dump a list, setting up patching information when there are
 633 ;;; circularities. We scan down the list, checking for CDR and CAR
 634 ;;; circularities.
 635 ;;;
 636 ;;; If there is a CDR circularity, we terminate the list with NIL and
 637 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 638 ;;;
 639 ;;; If there is no CDR circularity, then we mark the current cons and
 640 ;;; check for a CAR circularity. When there is a CAR circularity, we
 641 ;;; make the CAR NIL initially, arranging for the current cons to be
 642 ;;; patched later.
 643 ;;;
 644 ;;; Otherwise, we recursively call the dumper to dump the current
 645 ;;; element.
 646 ;;;
 647 ;;; Marking of the conses is inhibited when *COLD-LOAD-DUMP* is true.
 648 ;;; This inhibits all circularity detection.
 649 (defun dump-list (list file)
 650   (aver (and list
 651              (not (gethash list (fasl-output-circularity-table file)))))
 652   (do* ((l list (cdr l))
 653         (n 0 (1+ n))
 654         (circ (fasl-output-circularity-table file)))
 655        ((atom l)
 656         (cond ((null l)
 657                (terminate-undotted-list n file))
 658               (t
 659                (sub-dump-object l file)
 660                (terminate-dotted-list n file))))
 661     (declare (type index n))
 662     (let ((ref (gethash l circ)))
 663       (when ref
 664         (push (make-circularity :type :rplacd
 665                                 :object list
 666                                 :index (1- n)
 667                                 :value l
 668                                 :enclosing-object ref)
 669               *circularities-detected*)
 670         (terminate-undotted-list n file)
 671         (return)))
 672
 673     (unless *cold-load-dump*
 674       (setf (gethash l circ) list))
 675
 676     (let* ((obj (car l))
 677            (ref (gethash obj circ)))
 678       (cond (ref
 679              (push (make-circularity :type :rplaca
 680                                      :object list
 681                                      :index n
 682                                      :value obj
 683                                      :enclosing-object ref)
 684                    *circularities-detected*)
 685              (sub-dump-object nil file))
 686             (t
 687              (sub-dump-object obj file))))))
 688
 689 (defun terminate-dotted-list (n file)
 690   (declare (type index n) (type fasl-output file))
 691   (case n
 692     (1 (dump-fop 'fop-list*-1 file))
 693     (2 (dump-fop 'fop-list*-2 file))
 694     (3 (dump-fop 'fop-list*-3 file))
 695     (4 (dump-fop 'fop-list*-4 file))
 696     (5 (dump-fop 'fop-list*-5 file))
 697     (6 (dump-fop 'fop-list*-6 file))
 698     (7 (dump-fop 'fop-list*-7 file))
 699     (8 (dump-fop 'fop-list*-8 file))
 700     (t (do ((nn n (- nn 255)))
 701            ((< nn 256)
 702             (dump-fop 'fop-list* file)
 703             (dump-byte nn file))
 704          (declare (type index nn))
 705          (dump-fop 'fop-list* file)
 706          (dump-byte 255 file)))))
 707
 708 ;;; If N > 255, must build list with one LIST operator, then LIST*
 709 ;;; operators.
 710
 711 (defun terminate-undotted-list (n file)
 712   (declare (type index n) (type fasl-output file))
 713   (case n
 714     (1 (dump-fop 'fop-list-1 file))
 715     (2 (dump-fop 'fop-list-2 file))
 716     (3 (dump-fop 'fop-list-3 file))
 717     (4 (dump-fop 'fop-list-4 file))
 718     (5 (dump-fop 'fop-list-5 file))
 719     (6 (dump-fop 'fop-list-6 file))
 720     (7 (dump-fop 'fop-list-7 file))
 721     (8 (dump-fop 'fop-list-8 file))
 722     (t (cond ((< n 256)
 723               (dump-fop 'fop-list file)
 724               (dump-byte n file))
 725              (t (dump-fop 'fop-list file)
 726                 (dump-byte 255 file)
 727                 (do ((nn (- n 255) (- nn 255)))
 728                     ((< nn 256)
 729                      (dump-fop 'fop-list* file)
 730                      (dump-byte nn file))
 731                   (declare (type index nn))
 732                   (dump-fop 'fop-list* file)
 733                   (dump-byte 255 file)))))))
 734 \f
 735 ;;;; array dumping
 736
 737 ;;; Dump the array thing.
 738 (defun dump-array (x file)
 739   (if (vectorp x)
 740       (dump-vector x file)
 741       (dump-multi-dim-array x file)))
 742
 743 ;;; Dump the vector object. If it's not simple, then actually dump a
 744 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 745 ;;; tables.
 746 (defun dump-vector (x file)
 747   (let ((simple-version (if (array-header-p x)
 748                             (coerce x `(simple-array
 749                                         ,(array-element-type x)
 750                                         (*)))
 751                             x)))
 752     (typecase simple-version
 753       #+sb-xc-host
 754       (simple-string
 755        (unless (string-check-table x file)
 756          (dump-simple-base-string simple-version file)
 757          (string-save-object x file)))
 758       #-sb-xc-host
 759       (simple-base-string
 760        (unless (string-check-table x file)
 761          (dump-simple-base-string simple-version file)
 762          (string-save-object x file)))
 763       #-sb-xc-host
 764       ((simple-array character (*))
 765        #!+sb-unicode
 766        (unless (string-check-table x file)
 767          (dump-simple-character-string simple-version file)
 768          (string-save-object x file))
 769        #!-sb-unicode
 770        (bug "how did we get here?"))
 771       (simple-vector
 772        (dump-simple-vector simple-version file)
 773        (eq-save-object x file))
 774       ((simple-array single-float (*))
 775        (dump-single-float-vector simple-version file)
 776        (eq-save-object x file))
 777       ((simple-array double-float (*))
 778        (dump-double-float-vector simple-version file)
 779        (eq-save-object x file))
 780       #!+long-float
 781       ((simple-array long-float (*))
 782        (dump-long-float-vector simple-version file)
 783        (eq-save-object x file))
 784       ((simple-array (complex single-float) (*))
 785        (dump-complex-single-float-vector simple-version file)
 786        (eq-save-object x file))
 787       ((simple-array (complex double-float) (*))
 788        (dump-complex-double-float-vector simple-version file)
 789        (eq-save-object x file))
 790       #!+long-float
 791       ((simple-array (complex long-float) (*))
 792        (dump-complex-long-float-vector simple-version file)
 793        (eq-save-object x file))
 794       (t
 795        (dump-i-vector simple-version file)
 796        (eq-save-object x file)))))
 797
 798 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 799 (defun dump-simple-vector (v file)
 800   (declare (type simple-vector v) (type fasl-output file))
 801   (note-potential-circularity v file)
 802   (do ((index 0 (1+ index))
 803        (length (length v))
 804        (circ (fasl-output-circularity-table file)))
 805       ((= index length)
 806        (dump-fop* length fop-small-vector fop-vector file))
 807     (let* ((obj (aref v index))
 808            (ref (gethash obj circ)))
 809       (cond (ref
 810              (push (make-circularity :type :svset
 811                                      :object v
 812                                      :index index
 813                                      :value obj
 814                                      :enclosing-object ref)
 815                    *circularities-detected*)
 816              (sub-dump-object nil file))
 817             (t
 818              (sub-dump-object obj file))))))
 819
 820 ;;; In the grand scheme of things I don't pretend to understand any
 821 ;;; more how this works, or indeed whether.  But to write out specialized
 822 ;;; vectors in the same format as fop-int-vector expects to read them
 823 ;;; we need to be target-endian.  dump-integer-as-n-bytes always writes
 824 ;;; little-endian (which is correct for all other integers) so for a bigendian
 825 ;;; target we need to swap octets -- CSR, after DB
 826
 827 (defun octet-swap (word bits)
 828   "BITS must be a multiple of 8"
 829   (do ((input word (ash input -8))
 830        (output 0 (logior (ash output 8) (logand input #xff)))
 831        (bits bits (- bits 8)))
 832       ((<= bits 0) output)))
 833
 834 (defun dump-i-vector (vec file &key data-only)
 835   (declare (type (simple-array * (*)) vec))
 836   (let ((len (length vec)))
 837     (labels ((dump-unsigned-vector (size bytes)
 838                (unless data-only
 839                  (dump-fop 'fop-int-vector file)
 840                  (dump-word len file)
 841                  (dump-byte size file))
 842                ;; The case which is easy to handle in a portable way is when
 843                ;; the element size is a multiple of the output byte size, and
 844                ;; happily that's the only case we need to be portable. (The
 845                ;; cross-compiler has to output debug information (including
 846                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 847                ;; needed in the target SBCL, so we let them be handled with
 848                ;; unportable bit bashing.
 849                (cond ((>= size 7) ; easy cases
 850                       (multiple-value-bind (floor rem) (floor size 8)
 851                         (aver (or (zerop rem) (= rem 7)))
 852                         (when (= rem 7)
 853                           (setq size (1+ size))
 854                           (setq floor (1+ floor)))
 855                         (dovector (i vec)
 856                           (dump-integer-as-n-bytes
 857                            (ecase sb!c:*backend-byte-order*
 858                              (:little-endian i)
 859                              (:big-endian (octet-swap i size)))
 860                            floor file))))
 861                      (t ; harder cases, not supported in cross-compiler
 862                       (dump-raw-bytes vec bytes file))))
 863              (dump-signed-vector (size bytes)
 864                ;; Note: Dumping specialized signed vectors isn't
 865                ;; supported in the cross-compiler. (All cases here end
 866                ;; up trying to call DUMP-RAW-BYTES, which isn't
 867                ;; provided in the cross-compilation host, only on the
 868                ;; target machine.)
 869                (unless data-only
 870                  (dump-fop 'fop-signed-int-vector file)
 871                  (dump-word len file)
 872                  (dump-byte size file))
 873                (dump-raw-bytes vec bytes file)))
 874       (etypecase vec
 875         #-sb-xc-host
 876         ((simple-array nil (*))
 877          (dump-unsigned-vector 0 0))
 878         (simple-bit-vector
 879          (dump-unsigned-vector 1 (ceiling len 8))) ; bits to bytes
 880         ;; KLUDGE: This isn't the best way of expressing that the host
 881         ;; may not have specializations for (unsigned-byte 2) and
 882         ;; (unsigned-byte 4), which means that these types are
 883         ;; type-equivalent to (simple-array (unsigned-byte 8) (*));
 884         ;; the workaround is to remove them from the etypecase, since
 885         ;; they can't be dumped from the cross-compiler anyway. --
 886         ;; CSR, 2002-05-07
 887         #-sb-xc-host
 888         ((simple-array (unsigned-byte 2) (*))
 889          (dump-unsigned-vector 2 (ceiling (ash len 1) 8))) ; bits to bytes
 890         #-sb-xc-host
 891         ((simple-array (unsigned-byte 4) (*))
 892          (dump-unsigned-vector 4 (ceiling (ash len 2) 8))) ; bits to bytes
 893         #-sb-xc-host
 894         ((simple-array (unsigned-byte 7) (*))
 895          (dump-unsigned-vector 7 len))
 896         ((simple-array (unsigned-byte 8) (*))
 897          (dump-unsigned-vector 8 len))
 898         #-sb-xc-host
 899         ((simple-array (unsigned-byte 15) (*))
 900          (dump-unsigned-vector 15 (* 2 len)))
 901         ((simple-array (unsigned-byte 16) (*))
 902          (dump-unsigned-vector 16 (* 2 len)))
 903         #-sb-xc-host
 904         ((simple-array (unsigned-byte 31) (*))
 905          (dump-unsigned-vector 31 (* 4 len)))
 906         ((simple-array (unsigned-byte 32) (*))
 907          (dump-unsigned-vector 32 (* 4 len)))
 908         #-sb-xc-host
 909         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 910         ((simple-array (unsigned-byte 63) (*))
 911          (dump-unsigned-vector 63 (* 8 len)))
 912         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 913         ((simple-array (unsigned-byte 64) (*))
 914          (dump-unsigned-vector 64 (* 8 len)))
 915         ((simple-array (signed-byte 8) (*))
 916          (dump-signed-vector 8 len))
 917         ((simple-array (signed-byte 16) (*))
 918          (dump-signed-vector 16 (* 2 len)))
 919         #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 920         ((simple-array (unsigned-byte 29) (*))
 921          (dump-signed-vector 29 (* 4 len)))
 922         #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 923         ((simple-array (signed-byte 30) (*))
 924          (dump-signed-vector 30 (* 4 len)))
 925         ((simple-array (signed-byte 32) (*))
 926          (dump-signed-vector 32 (* 4 len)))
 927         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 928         ((simple-array (unsigned-byte 60) (*))
 929          (dump-signed-vector 60 (* 8 len)))
 930         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 931         ((simple-array (signed-byte 61) (*))
 932          (dump-signed-vector 61 (* 8 len)))
 933         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 934         ((simple-array (signed-byte 64) (*))
 935          (dump-signed-vector 64 (* 8 len)))))))
 936 \f
 937 ;;; Dump characters and string-ish things.
 938
 939 (defun dump-character (char file)
 940   (let ((code (sb!xc:char-code char)))
 941     (cond
 942       ((< code 256)
 943        (dump-fop 'fop-short-character file)
 944        (dump-byte code file))
 945       (t
 946        (dump-fop 'fop-character file)
 947        (dump-word code file)))))
 948
 949 (defun dump-base-chars-of-string (s fasl-output)
 950   (declare #+sb-xc-host (type simple-string s)
 951            #-sb-xc-host (type simple-base-string s)
 952            (type fasl-output fasl-output))
 953   (dovector (c s)
 954     (dump-byte (sb!xc:char-code c) fasl-output))
 955   (values))
 956
 957
 958 ;;; Dump a SIMPLE-BASE-STRING.
 959 (defun dump-simple-base-string (s file)
 960   #+sb-xc-host (declare (type simple-string s))
 961   #-sb-xc-host (declare (type simple-base-string s))
 962   (dump-fop* (length s) fop-small-base-string fop-base-string file)
 963   (dump-base-chars-of-string s file)
 964   (values))
 965
 966 ;;; If we get here, it is assumed that the symbol isn't in the table,
 967 ;;; but we are responsible for putting it there when appropriate. To
 968 ;;; avoid too much special-casing, we always push the symbol in the
 969 ;;; table, but don't record that we have done so if *COLD-LOAD-DUMP*
 970 ;;; is true.
 971 (defun dump-symbol (s file)
 972   (declare (type fasl-output file))
 973   (let* ((pname (symbol-name s))
 974          (pname-length (length pname))
 975          (pkg (symbol-package s)))
 976
 977     (cond ((null pkg)
 978            (dump-fop* pname-length
 979                       fop-uninterned-small-symbol-save
 980                       fop-uninterned-symbol-save
 981                       file))
 982           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 983           ;; used the current value of *PACKAGE*. Unfortunately that's
 984           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 985           ;; from SBCL.
 986           ;;((eq pkg *package*)
 987           ;; (dump-fop* pname-length
 988           ;;        fop-small-symbol-save
 989           ;;        fop-symbol-save file))
 990           ((eq pkg sb!int:*cl-package*)
 991            (dump-fop* pname-length
 992                       fop-lisp-small-symbol-save
 993                       fop-lisp-symbol-save
 994                       file))
 995           ((eq pkg sb!int:*keyword-package*)
 996            (dump-fop* pname-length
 997                       fop-keyword-small-symbol-save
 998                       fop-keyword-symbol-save
 999                       file))
1000           ((< pname-length 256)
1001            (dump-fop* (dump-package pkg file)
1002                       fop-small-symbol-in-byte-package-save
1003                       fop-small-symbol-in-package-save
1004                       file)
1005            (dump-byte pname-length file))
1006           (t
1007            (dump-fop* (dump-package pkg file)
1008                       fop-symbol-in-byte-package-save
1009                       fop-symbol-in-package-save
1010                       file)
1011            (dump-word pname-length file)))
1012
1013     #+sb-xc-host (dump-base-chars-of-string pname file)
1014     #-sb-xc-host (#!+sb-unicode dump-characters-of-string
1015                   #!-sb-unicode dump-base-chars-of-string
1016                   pname file)
1017
1018     (unless *cold-load-dump*
1019       (setf (gethash s (fasl-output-eq-table file))
1020             (fasl-output-table-free file)))
1021
1022     (incf (fasl-output-table-free file)))
1023
1024   (values))
1025 \f
1026 ;;;; component (function) dumping
1027
1028 (defun dump-segment (segment code-length fasl-output)
1029   (declare (type sb!assem:segment segment)
1030            (type fasl-output fasl-output))
1031   (let* ((stream (fasl-output-stream fasl-output))
1032          (n-written (write-segment-contents segment stream)))
1033     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
1034     ;; argument and the number of bytes actually written. I added this
1035     ;; assertion while trying to debug portable genesis. -- WHN 19990902
1036     (unless (= code-length n-written)
1037       (bug "code-length=~W, n-written=~W" code-length n-written)))
1038   (values))
1039
1040 ;;; Dump all the fixups. Currently there are three flavors of fixup:
1041 ;;;  - assembly routines: named by a symbol
1042 ;;;  - foreign (C) symbols: named by a string
1043 ;;;  - code object references: don't need a name.
1044 (defun dump-fixups (fixups fasl-output)
1045   (declare (list fixups) (type fasl-output fasl-output))
1046   (dolist (note fixups)
1047     (let* ((kind (fixup-note-kind note))
1048            (fixup (fixup-note-fixup note))
1049            (position (fixup-note-position note))
1050            (name (fixup-name fixup))
1051            (flavor (fixup-flavor fixup)))
1052       (dump-fop 'fop-normal-load fasl-output)
1053       (let ((*cold-load-dump* t))
1054         (dump-object kind fasl-output))
1055       (dump-fop 'fop-maybe-cold-load fasl-output)
1056       ;; Depending on the flavor, we may have various kinds of
1057       ;; noise before the position.
1058       (ecase flavor
1059         (:assembly-routine
1060          (aver (symbolp name))
1061          (dump-fop 'fop-normal-load fasl-output)
1062          (let ((*cold-load-dump* t))
1063            (dump-object name fasl-output))
1064          (dump-fop 'fop-maybe-cold-load fasl-output)
1065          (dump-fop 'fop-assembler-fixup fasl-output))
1066         ((:foreign :foreign-dataref)
1067          (aver (stringp name))
1068          (ecase flavor
1069            (:foreign
1070             (dump-fop 'fop-foreign-fixup fasl-output))
1071            #!+linkage-table
1072            (:foreign-dataref
1073             (dump-fop 'fop-foreign-dataref-fixup fasl-output)))
1074          (let ((len (length name)))
1075            (aver (< len 256)) ; (limit imposed by fop definition)
1076            (dump-byte len fasl-output)
1077            (dotimes (i len)
1078              (dump-byte (char-code (schar name i)) fasl-output))))
1079         (:code-object
1080          (aver (null name))
1081          (dump-fop 'fop-code-object-fixup fasl-output)))
1082       ;; No matter what the flavor, we'll always dump the position
1083       (dump-word position fasl-output)))
1084   (values))
1085
1086 ;;; Dump out the constant pool and code-vector for component, push the
1087 ;;; result in the table, and return the offset.
1088 ;;;
1089 ;;; The only tricky thing is handling constant-pool references to
1090 ;;; functions. If we have already dumped the function, then we just
1091 ;;; push the code pointer. Otherwise, we must create back-patching
1092 ;;; information so that the constant will be set when the function is
1093 ;;; eventually dumped. This is a bit awkward, since we don't have the
1094 ;;; handle for the code object being dumped while we are dumping its
1095 ;;; constants.
1096 ;;;
1097 ;;; We dump trap objects in any unused slots or forward referenced slots.
1098 (defun dump-code-object (component
1099                          code-segment
1100                          code-length
1101                          trace-table-as-list
1102                          fixups
1103                          fasl-output)
1104
1105   (declare (type component component)
1106            (list trace-table-as-list)
1107            (type index code-length)
1108            (type fasl-output fasl-output))
1109
1110   (let* ((2comp (component-info component))
1111          (constants (sb!c::ir2-component-constants 2comp))
1112          (header-length (length constants))
1113          (packed-trace-table (pack-trace-table trace-table-as-list))
1114          (total-length (+ code-length
1115                           (* (length packed-trace-table)
1116                              sb!c::tt-bytes-per-entry))))
1117
1118     (collect ((patches))
1119
1120       ;; Dump the offset of the trace table.
1121       (dump-object code-length fasl-output)
1122       ;; FIXME: As long as we don't have GENGC, the trace table is
1123       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
1124       ;; far as I know no modern CMU CL does either -- WHN
1125       ;; 2001-10-05). So might we be able to get rid of trace tables?
1126       ;;
1127       ;; Note that gencgc also does something with the trace table.
1128
1129       ;; Dump the constants, noting any :ENTRY constants that have to
1130       ;; be patched.
1131       (loop for i from sb!vm:code-constants-offset below header-length do
1132         (let ((entry (aref constants i)))
1133           (etypecase entry
1134             (constant
1135              (dump-object (sb!c::constant-value entry) fasl-output))
1136             (cons
1137              (ecase (car entry)
1138                (:entry
1139                 (let* ((info (sb!c::leaf-info (cdr entry)))
1140                        (handle (gethash info
1141                                         (fasl-output-entry-table
1142                                          fasl-output))))
1143                   (declare (type sb!c::entry-info info))
1144                   (cond
1145                    (handle
1146                     (dump-push handle fasl-output))
1147                    (t
1148                     (patches (cons info i))
1149                     (dump-fop 'fop-misc-trap fasl-output)))))
1150                (:load-time-value
1151                 (dump-push (cdr entry) fasl-output))
1152                (:fdefinition
1153                 (dump-object (cdr entry) fasl-output)
1154                 (dump-fop 'fop-fdefinition fasl-output))))
1155             (null
1156              (dump-fop 'fop-misc-trap fasl-output)))))
1157
1158       ;; Dump the debug info.
1159       (let ((info (sb!c::debug-info-for-component component))
1160             (*dump-only-valid-structures* nil))
1161         (dump-object info fasl-output)
1162         (let ((info-handle (dump-pop fasl-output)))
1163           (dump-push info-handle fasl-output)
1164           (push info-handle (fasl-output-debug-info fasl-output))))
1165
1166       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1167         (cond ((and (< num-consts #x100) (< total-length #x10000))
1168                (dump-fop 'fop-small-code fasl-output)
1169                (dump-byte num-consts fasl-output)
1170                (dump-integer-as-n-bytes total-length (/ sb!vm:n-word-bytes 2) fasl-output))
1171               (t
1172                (dump-fop 'fop-code fasl-output)
1173                (dump-word num-consts fasl-output)
1174                (dump-word total-length fasl-output))))
1175
1176       ;; These two dumps are only ones which contribute to our
1177       ;; TOTAL-LENGTH value.
1178       (dump-segment code-segment code-length fasl-output)
1179       (dump-i-vector packed-trace-table fasl-output :data-only t)
1180
1181       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1182       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1183       ;; FOP-CODE/FOP-SMALL-CODE fop.
1184       (dump-fixups fixups fasl-output)
1185
1186       (dump-fop 'fop-sanctify-for-execution fasl-output)
1187
1188       (let ((handle (dump-pop fasl-output)))
1189         (dolist (patch (patches))
1190           (push (cons handle (cdr patch))
1191                 (gethash (car patch)
1192                          (fasl-output-patch-table fasl-output))))
1193         handle))))
1194
1195 (defun dump-assembler-routines (code-segment length fixups routines file)
1196   (dump-fop 'fop-assembler-code file)
1197   (dump-word length file)
1198   (write-segment-contents code-segment (fasl-output-stream file))
1199   (dolist (routine routines)
1200     (dump-fop 'fop-normal-load file)
1201     (let ((*cold-load-dump* t))
1202       (dump-object (car routine) file))
1203     (dump-fop 'fop-maybe-cold-load file)
1204     (dump-fop 'fop-assembler-routine file)
1205     (dump-word (label-position (cdr routine)) file))
1206   (dump-fixups fixups file)
1207   (dump-fop 'fop-sanctify-for-execution file)
1208   (dump-pop file))
1209
1210 ;;; Dump a function entry data structure corresponding to ENTRY to
1211 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1212 ;;; component.
1213 (defun dump-one-entry (entry code-handle file)
1214   (declare (type sb!c::entry-info entry) (type index code-handle)
1215            (type fasl-output file))
1216   (let ((name (sb!c::entry-info-name entry)))
1217     (dump-push code-handle file)
1218     (dump-object name file)
1219     (dump-object (sb!c::entry-info-arguments entry) file)
1220     (dump-object (sb!c::entry-info-type entry) file)
1221     (dump-fop 'fop-fun-entry file)
1222     (dump-word (label-position (sb!c::entry-info-offset entry)) file)
1223     (dump-pop file)))
1224
1225 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1226 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1227 (defun dump-alter-code-object (code-handle offset entry-handle file)
1228   (declare (type index code-handle entry-handle offset))
1229   (declare (type fasl-output file))
1230   (dump-push code-handle file)
1231   (dump-push entry-handle file)
1232   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1233   (values))
1234
1235 ;;; Dump the code, constants, etc. for component. We pass in the
1236 ;;; assembler fixups, code vector and node info.
1237 (defun fasl-dump-component (component
1238                             code-segment
1239                             code-length
1240                             trace-table
1241                             fixups
1242                             file)
1243   (declare (type component component) (list trace-table))
1244   (declare (type fasl-output file))
1245
1246   (dump-fop 'fop-verify-table-size file)
1247   (dump-word (fasl-output-table-free file) file)
1248
1249   #!+sb-dyncount
1250   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1251     (when info
1252       (fasl-validate-structure info file)))
1253
1254   (let ((code-handle (dump-code-object component
1255                                        code-segment
1256                                        code-length
1257                                        trace-table
1258                                        fixups
1259                                        file))
1260         (2comp (component-info component)))
1261
1262     (dolist (entry (sb!c::ir2-component-entries 2comp))
1263       (let ((entry-handle (dump-one-entry entry code-handle file)))
1264         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1265         (let ((old (gethash entry (fasl-output-patch-table file))))
1266           (when old
1267             (dolist (patch old)
1268               (dump-alter-code-object (car patch)
1269                                       (cdr patch)
1270                                       entry-handle
1271                                       file))
1272             (remhash entry (fasl-output-patch-table file)))))))
1273   (values))
1274
1275 (defun dump-push-previously-dumped-fun (fun fasl-output)
1276   (declare (type sb!c::clambda fun))
1277   (let ((handle (gethash (sb!c::leaf-info fun)
1278                          (fasl-output-entry-table fasl-output))))
1279     (aver handle)
1280     (dump-push handle fasl-output))
1281   (values))
1282
1283 ;;; Dump a FOP-FUNCALL to call an already-dumped top level lambda at
1284 ;;; load time.
1285 (defun fasl-dump-toplevel-lambda-call (fun fasl-output)
1286   (declare (type sb!c::clambda fun))
1287   (dump-push-previously-dumped-fun fun fasl-output)
1288   (dump-fop 'fop-funcall-for-effect fasl-output)
1289   (dump-byte 0 fasl-output)
1290   (values))
1291
1292 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1293 ;;; FUN-NAME and the already-dumped function whose dump handle is
1294 ;;; FUN-DUMP-HANDLE.
1295 #+sb-xc-host
1296 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1297   (declare (type fixnum fun-dump-handle))
1298   (aver (legal-fun-name-p fun-name))
1299   (dump-non-immediate-object fun-name fasl-output)
1300   (dump-push fun-dump-handle fasl-output)
1301   (dump-fop 'fop-fset fasl-output)
1302   (values))
1303
1304 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1305 ;;; all of the dumped DEBUG-INFO structures. We clear the
1306 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1307 ;;; different source info may be dumped.
1308 (defun fasl-dump-source-info (info fasl-output)
1309   (declare (type sb!c::source-info info))
1310   (let ((res (sb!c::debug-source-for-info info))
1311         (*dump-only-valid-structures* nil))
1312     (dump-object res fasl-output)
1313     (let ((res-handle (dump-pop fasl-output)))
1314       (dolist (info-handle (fasl-output-debug-info fasl-output))
1315         (dump-push res-handle fasl-output)
1316         (dump-fop 'fop-structset fasl-output)
1317         (dump-word info-handle fasl-output)
1318         ;; FIXME: what is this bare `2'?  --njf, 2004-08-16
1319         (dump-word 2 fasl-output))))
1320   (setf (fasl-output-debug-info fasl-output) nil)
1321   (values))
1322 \f
1323 ;;;; dumping structures
1324
1325 (defun dump-structure (struct file)
1326   (when *dump-only-valid-structures*
1327     (unless (gethash struct (fasl-output-valid-structures file))
1328       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1329              struct)))
1330   (note-potential-circularity struct file)
1331   (aver (%instance-ref struct 0))
1332   (do* ((length (%instance-length struct))
1333         (ntagged (- length (layout-n-untagged-slots (%instance-ref struct 0))))
1334         (circ (fasl-output-circularity-table file))
1335         ;; last slot first on the stack, so that the layout is on top:
1336         (index (1- length) (1- index)))
1337       ((minusp index)
1338        (dump-fop* length fop-small-struct fop-struct file))
1339     (let* ((obj (if (>= index ntagged)
1340                     (%raw-instance-ref/word struct (- length index 1))
1341                     (%instance-ref struct index)))
1342            (ref (gethash obj circ)))
1343       (cond (ref
1344              (aver (not (zerop index)))
1345              (push (make-circularity :type :struct-set
1346                                      :object struct
1347                                      :index index
1348                                      :value obj
1349                                      :enclosing-object ref)
1350                    *circularities-detected*)
1351              (sub-dump-object nil file))
1352             (t
1353              (sub-dump-object obj file))))))
1354
1355 (defun dump-layout (obj file)
1356   (when (layout-invalid obj)
1357     (compiler-error "attempt to dump reference to obsolete class: ~S"
1358                     (layout-classoid obj)))
1359   (let ((name (classoid-name (layout-classoid obj))))
1360     (unless name
1361       (compiler-error "dumping anonymous layout: ~S" obj))
1362     (dump-fop 'fop-normal-load file)
1363     (let ((*cold-load-dump* t))
1364       (dump-object name file))
1365     (dump-fop 'fop-maybe-cold-load file))
1366   (sub-dump-object (layout-inherits obj) file)
1367   (sub-dump-object (layout-depthoid obj) file)
1368   (sub-dump-object (layout-length obj) file)
1369   (sub-dump-object (layout-n-untagged-slots obj) file)
1370   (dump-fop 'fop-layout file))