src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (missing-arg) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance pathologies with objects for which EQUAL degenerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the ENTRY-INFO structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the ENTRY-INFO structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (missing-arg) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (missing-arg) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to inhibit table access when dumping forms to be read by the
  95 ;;; cold loader
  96 (defvar *cold-load-dump* nil)
  97
  98 ;;; used to turn off the structure validation during dumping of source
  99 ;;; info
 100 (defvar *dump-only-valid-structures* t)
 101 ;;;; utilities
 102
 103 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 104 (defun dump-byte (b fasl-output)
 105   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 106   (write-byte b (fasl-output-stream fasl-output)))
 107
 108 ;; Dump a word-sized integer.
 109 (defun dump-word (num fasl-output)
 110   (declare (type sb!vm:word num))
 111   (declare (type fasl-output fasl-output))
 112   (let ((stream (fasl-output-stream fasl-output)))
 113     (dotimes (i sb!vm:n-word-bytes)
 114       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 115
 116 ;; Dump a 32-bit integer.
 117 (defun dump-unsigned-byte-32 (num fasl-output)
 118   (declare (type sb!vm:word num))
 119   (declare (type fasl-output fasl-output))
 120   (let ((stream (fasl-output-stream fasl-output)))
 121     (dotimes (i 4)
 122       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 123
 124 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 125 ;;; for either signed or unsigned integers. There's no range checking
 126 ;;; -- if you don't specify enough bytes for the number to fit, this
 127 ;;; function cheerfully outputs the low bytes.
 128 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 129   (declare (integer num) (type index bytes))
 130   (declare (type fasl-output fasl-output))
 131   (do ((n num (ash n -8))
 132        (i bytes (1- i)))
 133       ((= i 0))
 134     (declare (type index i))
 135     (dump-byte (logand n #xff) fasl-output))
 136   (values))
 137
 138 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 139 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 140 ;;; counter value before every ordinary fop. This can make it easier
 141 ;;; to follow the progress of LOAD-AS-FASL when
 142 ;;; debugging/testing/experimenting.
 143 #!+sb-show (defvar *fop-nop4-count* nil)
 144 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 145
 146 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 147 ;;;
 148 ;;; FIXME: This should be a function, with a compiler macro expansion
 149 ;;; for the common constant-FS case. (Among other things, that'll stop
 150 ;;; it from EVALing ,FILE multiple times.)
 151 ;;;
 152 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 153 ;;; optimizations should be conditional on #!+SB-FROZEN.
 154 (defmacro dump-fop (fs file)
 155   (let* ((fs (eval fs))
 156          (val (get fs 'fop-code)))
 157     (if val
 158       `(progn
 159          #!+sb-show
 160          (when *fop-nop4-count*
 161            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 162            (dump-integer-as-n-bytes (mod (incf *fop-nop4-count*) (expt 2 32))
 163                                     4 ,file))
 164          (dump-byte ',val ,file))
 165       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 166
 167 ;;; Dump a FOP-CODE along with an integer argument, choosing the FOP
 168 ;;; based on whether the argument will fit in a single byte.
 169 ;;;
 170 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 171 ;;; compiler-macro expansion.
 172 (defmacro dump-fop* (n byte-fop word-fop file)
 173   (once-only ((n-n n)
 174               (n-file file))
 175     `(cond ((< ,n-n 256)
 176             (dump-fop ',byte-fop ,n-file)
 177             (dump-byte ,n-n ,n-file))
 178            (t
 179             (dump-fop ',word-fop ,n-file)
 180             (dump-word ,n-n ,n-file)))))
 181
 182 ;;; Push the object at table offset Handle on the fasl stack.
 183 (defun dump-push (handle fasl-output)
 184   (declare (type index handle) (type fasl-output fasl-output))
 185   (dump-fop* handle fop-byte-push fop-push fasl-output)
 186   (values))
 187
 188 ;;; Pop the object currently on the fasl stack top into the table, and
 189 ;;; return the table index, incrementing the free pointer.
 190 (defun dump-pop (fasl-output)
 191   (prog1
 192       (fasl-output-table-free fasl-output)
 193     (dump-fop 'fop-pop fasl-output)
 194     (incf (fasl-output-table-free fasl-output))))
 195
 196 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 197 ;;; otherwise NIL. If *COLD-LOAD-DUMP* is true, then do nothing and
 198 ;;; return NIL.
 199 (defun equal-check-table (x fasl-output)
 200   (declare (type fasl-output fasl-output))
 201   (unless *cold-load-dump*
 202     (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 203       (cond
 204         (handle (dump-push handle fasl-output) t)
 205         (t nil)))))
 206 (defun string-check-table (x fasl-output)
 207   (declare (type fasl-output fasl-output)
 208            (type string x))
 209   (unless *cold-load-dump*
 210     (let ((handle (cdr (assoc
 211                         (array-element-type x)
 212                         (gethash x (fasl-output-equal-table fasl-output))))))
 213       (cond
 214         (handle (dump-push handle fasl-output) t)
 215         (t nil)))))
 216
 217 ;;; These functions are called after dumping an object to save the
 218 ;;; object in the table. The object (also passed in as X) must already
 219 ;;; be on the top of the FOP stack. If *COLD-LOAD-DUMP* is true, then
 220 ;;; we don't do anything.
 221 (defun eq-save-object (x fasl-output)
 222   (declare (type fasl-output fasl-output))
 223   (unless *cold-load-dump*
 224     (let ((handle (dump-pop fasl-output)))
 225       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 226       (dump-push handle fasl-output)))
 227   (values))
 228 (defun equal-save-object (x fasl-output)
 229   (declare (type fasl-output fasl-output))
 230   (unless *cold-load-dump*
 231     (let ((handle (dump-pop fasl-output)))
 232       (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 233       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 234       (dump-push handle fasl-output)))
 235   (values))
 236 (defun string-save-object (x fasl-output)
 237   (declare (type fasl-output fasl-output)
 238            (type string x))
 239   (unless *cold-load-dump*
 240     (let ((handle (dump-pop fasl-output)))
 241       (push (cons (array-element-type x) handle)
 242             (gethash x (fasl-output-equal-table fasl-output)))
 243       (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 244       (dump-push handle fasl-output)))
 245   (values))
 246 ;;; Record X in File's CIRCULARITY-TABLE unless *COLD-LOAD-DUMP* is
 247 ;;; true. This is called on objects that we are about to dump might
 248 ;;; have a circular path through them.
 249 ;;;
 250 ;;; The object must not currently be in this table, since the dumper
 251 ;;; should never be recursively called on a circular reference.
 252 ;;; Instead, the dumping function must detect the circularity and
 253 ;;; arrange for the dumped object to be patched.
 254 (defun note-potential-circularity (x fasl-output)
 255   (unless *cold-load-dump*
 256     (let ((circ (fasl-output-circularity-table fasl-output)))
 257       (aver (not (gethash x circ)))
 258       (setf (gethash x circ) x)))
 259   (values))
 260
 261 ;;; Dump FORM to a fasl file so that it evaluated at load time in normal
 262 ;;; load and at cold-load time in cold load. This is used to dump package
 263 ;;; frobbing forms.
 264 (defun fasl-dump-cold-load-form (form fasl-output)
 265   (declare (type fasl-output fasl-output))
 266   (dump-fop 'fop-normal-load fasl-output)
 267   (let ((*cold-load-dump* t))
 268     (dump-object form fasl-output))
 269   (dump-fop 'fop-eval-for-effect fasl-output)
 270   (dump-fop 'fop-maybe-cold-load fasl-output)
 271   (values))
 272 \f
 273 ;;;; opening and closing fasl files
 274
 275 ;;; A utility function to write strings to (unsigned-byte 8) streams.
 276 ;;; We restrict this to ASCII (with the averrance) because of
 277 ;;; ambiguity of higher bytes: Unicode, some ISO-8859-x, or what? This
 278 ;;; could be revisited in the event of doing funky things with stream
 279 ;;; encodings -- CSR, 2002-04-25
 280 (defun fasl-write-string (string stream)
 281   (loop for char across string
 282         do (let ((code (char-code char)))
 283              (aver (<= 0 code 127))
 284              (write-byte code stream))))
 285
 286 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 287 ;;; object for dumping to it. Some human-readable information about
 288 ;;; the source code is given by the string WHERE.
 289 (defun open-fasl-output (name where)
 290   (declare (type pathname name))
 291   (let* ((stream (open name
 292                        :direction :output
 293                        :if-exists :supersede
 294                        :element-type 'sb!assem:assembly-unit))
 295          (res (make-fasl-output :stream stream)))
 296
 297     ;; Begin the header with the constant machine-readable (and
 298     ;; semi-human-readable) string which is used to identify fasl files.
 299     (fasl-write-string *fasl-header-string-start-string* stream)
 300
 301     ;; The constant string which begins the header is followed by
 302     ;; arbitrary human-readable text, terminated by a special
 303     ;; character code.
 304     (fasl-write-string
 305      (with-standard-io-syntax
 306        (let ((*print-readably* nil)
 307              (*print-pretty* nil))
 308          (format nil
 309                  "~%  ~
 310                   compiled from ~S~%  ~
 311                   at ~A~%  ~
 312                   on ~A~%  ~
 313                   using ~A version ~A~%"
 314          where
 315                  (format-universal-time nil (get-universal-time))
 316                  (machine-instance)
 317                  (sb!xc:lisp-implementation-type)
 318                  (sb!xc:lisp-implementation-version))))
 319      stream)
 320     (dump-byte +fasl-header-string-stop-char-code+ res)
 321
 322     ;; Finish the header by outputting fasl file implementation,
 323     ;; version, and key *FEATURES*.
 324     (flet ((dump-counted-string (string)
 325              ;; The count is dumped as a 32-bit unsigned-byte even on 64-bit
 326              ;; platforms. This ensures that a x86-64 SBCL can gracefully
 327              ;; detect an error when trying to read a x86 fasl, instead
 328              ;; of choking on a ridiculously long counted string.
 329              ;;  -- JES, 2005-12-30
 330              (dump-unsigned-byte-32 (length string) res)
 331              (dotimes (i (length string))
 332                (dump-byte (char-code (aref string i)) res))))
 333       (dump-counted-string (symbol-name +backend-fasl-file-implementation+))
 334       (dump-word +fasl-file-version+ res)
 335       (dump-counted-string *features-affecting-fasl-format*))
 336
 337     res))
 338
 339 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 340 (defun close-fasl-output (fasl-output abort-p)
 341   (declare (type fasl-output fasl-output))
 342
 343   ;; sanity checks
 344   (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 345
 346   ;; End the group.
 347   (dump-fop 'fop-verify-empty-stack fasl-output)
 348   (dump-fop 'fop-verify-table-size fasl-output)
 349   (dump-word (fasl-output-table-free fasl-output)
 350                     fasl-output)
 351   (dump-fop 'fop-end-group fasl-output)
 352
 353   ;; That's all, folks.
 354   (close (fasl-output-stream fasl-output) :abort abort-p)
 355   (values))
 356 \f
 357 ;;;; main entries to object dumping
 358
 359 ;;; This function deals with dumping objects that are complex enough
 360 ;;; so that we want to cache them in the table, rather than repeatedly
 361 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 362 ;;; otherwise, we do a type dispatch to a type specific dumping
 363 ;;; function. The type specific branches do any appropriate
 364 ;;; EQUAL-TABLE check and table entry.
 365 ;;;
 366 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 367 (defun dump-non-immediate-object (x file)
 368   (let ((index (gethash x (fasl-output-eq-table file))))
 369     (cond ((and index (not *cold-load-dump*))
 370            (dump-push index file))
 371           (t
 372            (typecase x
 373              (symbol (dump-symbol x file))
 374              (list
 375               ;; KLUDGE: The code in this case has been hacked
 376               ;; to match Douglas Crosher's quick fix to CMU CL
 377               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 378               ;; with help from Martin Atzmueller. This is not an
 379               ;; ideal solution; to quote DTC,
 380               ;;   The compiler locks up trying to coalesce the
 381               ;;   constant lists. The hack below will disable the
 382               ;;   coalescing of lists while dumping and allows
 383               ;;   the code to compile. The real fix would be to
 384               ;;   take a little more care while dumping these.
 385               ;; So if better list coalescing is needed, start here.
 386               ;; -- WHN 2000-11-07
 387               (if (cyclic-list-p x)
 388                   (progn
 389                     (dump-list x file)
 390                     (eq-save-object x file))
 391                   (unless (equal-check-table x file)
 392                     (dump-list x file)
 393                     (equal-save-object x file))))
 394              (layout
 395               (dump-layout x file)
 396               (eq-save-object x file))
 397              (instance
 398               (dump-structure x file)
 399               (eq-save-object x file))
 400              (array
 401               ;; DUMP-ARRAY (and its callees) are responsible for
 402               ;; updating the EQ and EQUAL hash tables.
 403               (dump-array x file))
 404              (number
 405               (unless (equal-check-table x file)
 406                 (etypecase x
 407                   (ratio (dump-ratio x file))
 408                   (complex (dump-complex x file))
 409                   (float (dump-float x file))
 410                   (integer (dump-integer x file)))
 411                 (equal-save-object x file)))
 412              (t
 413               ;; This probably never happens, since bad things tend to
 414               ;; be detected during IR1 conversion.
 415               (error "This object cannot be dumped into a fasl file:~% ~S"
 416                      x))))))
 417   (values))
 418
 419 ;;; Dump an object of any type by dispatching to the correct
 420 ;;; type-specific dumping function. We pick off immediate objects,
 421 ;;; symbols and magic lists here. Other objects are handled by
 422 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 423 ;;;
 424 ;;; This is the function used for recursive calls to the fasl dumper.
 425 ;;; We don't worry about creating circularities here, since it is
 426 ;;; assumed that there is a top level call to DUMP-OBJECT.
 427 (defun sub-dump-object (x file)
 428   (cond ((listp x)
 429          (if x
 430              (dump-non-immediate-object x file)
 431              (dump-fop 'fop-empty-list file)))
 432         ((symbolp x)
 433          (if (eq x t)
 434              (dump-fop 'fop-truth file)
 435              (dump-non-immediate-object x file)))
 436         ((fixnump x) (dump-integer x file))
 437         ((characterp x) (dump-character x file))
 438         (t
 439          (dump-non-immediate-object x file))))
 440
 441 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 442 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 443 ;;; take the value to store on the stack. We compute this value by
 444 ;;; fetching the enclosing object from the table, and then CDR'ing it
 445 ;;; if necessary.
 446 (defun dump-circularities (infos file)
 447   (let ((table (fasl-output-eq-table file)))
 448     (dolist (info infos)
 449
 450       (let* ((value (circularity-value info))
 451              (enclosing (circularity-enclosing-object info)))
 452         (dump-push (gethash enclosing table) file)
 453         (unless (eq enclosing value)
 454           (do ((current enclosing (cdr current))
 455                (i 0 (1+ i)))
 456               ((eq current value)
 457                (dump-fop 'fop-nthcdr file)
 458                (dump-word i file))
 459             (declare (type index i)))))
 460
 461       (ecase (circularity-type info)
 462         (:rplaca     (dump-fop 'fop-rplaca    file))
 463         (:rplacd     (dump-fop 'fop-rplacd    file))
 464         (:svset      (dump-fop 'fop-svset     file))
 465         (:struct-set (dump-fop 'fop-structset file)))
 466       (dump-word (gethash (circularity-object info) table) file)
 467       (dump-word (circularity-index info) file))))
 468
 469 ;;; Set up stuff for circularity detection, then dump an object. All
 470 ;;; shared and circular structure will be exactly preserved within a
 471 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 472 ;;; separate calls is only preserved when convenient.
 473 ;;;
 474 ;;; We peek at the object type so that we only pay the circular
 475 ;;; detection overhead on types of objects that might be circular.
 476 (defun dump-object (x file)
 477   (if (compound-object-p x)
 478       (let ((*circularities-detected* ())
 479             (circ (fasl-output-circularity-table file)))
 480         (clrhash circ)
 481         (sub-dump-object x file)
 482         (when *circularities-detected*
 483           (dump-circularities *circularities-detected* file)
 484           (clrhash circ)))
 485       (sub-dump-object x file)))
 486 \f
 487 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 488
 489 ;;; Emit a funcall of the function and return the handle for the
 490 ;;; result.
 491 (defun fasl-dump-load-time-value-lambda (fun file)
 492   (declare (type sb!c::clambda fun) (type fasl-output file))
 493   (let ((handle (gethash (sb!c::leaf-info fun)
 494                          (fasl-output-entry-table file))))
 495     (aver handle)
 496     (dump-push handle file)
 497     (dump-fop 'fop-funcall file)
 498     (dump-byte 0 file))
 499   (dump-pop file))
 500
 501 ;;; Return T iff CONSTANT has not already been dumped. It's been
 502 ;;; dumped if it's in the EQ table.
 503 (defun fasl-constant-already-dumped-p (constant file)
 504   (if (or (gethash constant (fasl-output-eq-table file))
 505           (gethash constant (fasl-output-valid-structures file)))
 506       t
 507       nil))
 508
 509 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 510 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 511 (defun fasl-note-handle-for-constant (constant handle file)
 512   (let ((table (fasl-output-eq-table file)))
 513     (when (gethash constant table)
 514       (error "~S already dumped?" constant))
 515     (setf (gethash constant table) handle))
 516   (values))
 517
 518 ;;; Note that the specified structure can just be dumped by
 519 ;;; enumerating the slots.
 520 (defun fasl-validate-structure (structure file)
 521   (setf (gethash structure (fasl-output-valid-structures file)) t)
 522   (values))
 523 \f
 524 ;;;; number dumping
 525
 526 (defun dump-ratio (x file)
 527   (sub-dump-object (numerator x) file)
 528   (sub-dump-object (denominator x) file)
 529   (dump-fop 'fop-ratio file))
 530
 531 (defun dump-integer (n file)
 532   (typecase n
 533     ((signed-byte 8)
 534      (dump-fop 'fop-byte-integer file)
 535      (dump-byte (logand #xFF n) file))
 536     ((unsigned-byte #.(1- sb!vm:n-word-bits))
 537      (dump-fop 'fop-word-integer file)
 538      (dump-word n file))
 539     ((signed-byte #.sb!vm:n-word-bits)
 540      (dump-fop 'fop-word-integer file)
 541      (dump-integer-as-n-bytes n #.sb!vm:n-word-bytes file))
 542     (t
 543      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 544        (dump-fop* bytes fop-small-integer fop-integer file)
 545        (dump-integer-as-n-bytes n bytes file)))))
 546
 547 (defun dump-float (x file)
 548   (etypecase x
 549     (single-float
 550      (dump-fop 'fop-single-float file)
 551      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 552     (double-float
 553      (dump-fop 'fop-double-float file)
 554      (let ((x x))
 555        (declare (double-float x))
 556        (dump-integer-as-n-bytes (double-float-low-bits x) 4 file)
 557        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 558     #!+long-float
 559     (long-float
 560      (dump-fop 'fop-long-float file)
 561      (dump-long-float x file))))
 562
 563 (defun dump-complex (x file)
 564   (typecase x
 565     #-sb-xc-host
 566     ((complex single-float)
 567      (dump-fop 'fop-complex-single-float file)
 568      (dump-integer-as-n-bytes (single-float-bits (realpart x)) 4 file)
 569      (dump-integer-as-n-bytes (single-float-bits (imagpart x)) 4 file))
 570     #-sb-xc-host
 571     ((complex double-float)
 572      (dump-fop 'fop-complex-double-float file)
 573      (let ((re (realpart x)))
 574        (declare (double-float re))
 575        (dump-integer-as-n-bytes (double-float-low-bits re) 4 file)
 576        (dump-integer-as-n-bytes (double-float-high-bits re) 4 file))
 577      (let ((im (imagpart x)))
 578        (declare (double-float im))
 579        (dump-integer-as-n-bytes (double-float-low-bits im) 4 file)
 580        (dump-integer-as-n-bytes (double-float-high-bits im) 4 file)))
 581     #!+long-float
 582     ((complex long-float)
 583      ;; (There's no easy way to mix #!+LONG-FLOAT and #-SB-XC-HOST
 584      ;; conditionalization at read time, so we do this SB-XC-HOST
 585      ;; conditional at runtime instead.)
 586      #+sb-xc-host (error "can't dump COMPLEX-LONG-FLOAT in cross-compiler")
 587      (dump-fop 'fop-complex-long-float file)
 588      (dump-long-float (realpart x) file)
 589      (dump-long-float (imagpart x) file))
 590     (t
 591      (sub-dump-object (realpart x) file)
 592      (sub-dump-object (imagpart x) file)
 593      (dump-fop 'fop-complex file))))
 594 \f
 595 ;;;; symbol dumping
 596
 597 ;;; Return the table index of PKG, adding the package to the table if
 598 ;;; necessary. During cold load, we read the string as a normal string
 599 ;;; so that we can do the package lookup at cold load time.
 600 ;;;
 601 ;;; FIXME: Despite the parallelism in names, the functionality of
 602 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 603 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 604 ;;; should be made more consistent.
 605 (declaim (ftype (function (package fasl-output) index) dump-package))
 606 (defun dump-package (pkg file)
 607   (declare (inline assoc))
 608   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 609         (t
 610          (unless *cold-load-dump*
 611            (dump-fop 'fop-normal-load file))
 612          #+sb-xc-host
 613          (dump-simple-base-string
 614           (coerce (package-name pkg) 'simple-base-string)
 615           file)
 616          #-sb-xc-host
 617          (#!+sb-unicode dump-simple-character-string
 618           #!-sb-unicode dump-simple-base-string
 619           (coerce (package-name pkg) '(simple-array character (*)))
 620           file)
 621          (dump-fop 'fop-package file)
 622          (unless *cold-load-dump*
 623            (dump-fop 'fop-maybe-cold-load file))
 624          (let ((entry (dump-pop file)))
 625            (push (cons pkg entry) (fasl-output-packages file))
 626            entry))))
 627 \f
 628 ;;; dumper for lists
 629
 630 ;;; Dump a list, setting up patching information when there are
 631 ;;; circularities. We scan down the list, checking for CDR and CAR
 632 ;;; circularities.
 633 ;;;
 634 ;;; If there is a CDR circularity, we terminate the list with NIL and
 635 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 636 ;;;
 637 ;;; If there is no CDR circularity, then we mark the current cons and
 638 ;;; check for a CAR circularity. When there is a CAR circularity, we
 639 ;;; make the CAR NIL initially, arranging for the current cons to be
 640 ;;; patched later.
 641 ;;;
 642 ;;; Otherwise, we recursively call the dumper to dump the current
 643 ;;; element.
 644 ;;;
 645 ;;; Marking of the conses is inhibited when *COLD-LOAD-DUMP* is true.
 646 ;;; This inhibits all circularity detection.
 647 (defun dump-list (list file)
 648   (aver (and list
 649              (not (gethash list (fasl-output-circularity-table file)))))
 650   (do* ((l list (cdr l))
 651         (n 0 (1+ n))
 652         (circ (fasl-output-circularity-table file)))
 653        ((atom l)
 654         (cond ((null l)
 655                (terminate-undotted-list n file))
 656               (t
 657                (sub-dump-object l file)
 658                (terminate-dotted-list n file))))
 659     (declare (type index n))
 660     (let ((ref (gethash l circ)))
 661       (when ref
 662         (push (make-circularity :type :rplacd
 663                                 :object list
 664                                 :index (1- n)
 665                                 :value l
 666                                 :enclosing-object ref)
 667               *circularities-detected*)
 668         (terminate-undotted-list n file)
 669         (return)))
 670
 671     (unless *cold-load-dump*
 672       (setf (gethash l circ) list))
 673
 674     (let* ((obj (car l))
 675            (ref (gethash obj circ)))
 676       (cond (ref
 677              (push (make-circularity :type :rplaca
 678                                      :object list
 679                                      :index n
 680                                      :value obj
 681                                      :enclosing-object ref)
 682                    *circularities-detected*)
 683              (sub-dump-object nil file))
 684             (t
 685              (sub-dump-object obj file))))))
 686
 687 (defun terminate-dotted-list (n file)
 688   (declare (type index n) (type fasl-output file))
 689   (case n
 690     (1 (dump-fop 'fop-list*-1 file))
 691     (2 (dump-fop 'fop-list*-2 file))
 692     (3 (dump-fop 'fop-list*-3 file))
 693     (4 (dump-fop 'fop-list*-4 file))
 694     (5 (dump-fop 'fop-list*-5 file))
 695     (6 (dump-fop 'fop-list*-6 file))
 696     (7 (dump-fop 'fop-list*-7 file))
 697     (8 (dump-fop 'fop-list*-8 file))
 698     (t (do ((nn n (- nn 255)))
 699            ((< nn 256)
 700             (dump-fop 'fop-list* file)
 701             (dump-byte nn file))
 702          (declare (type index nn))
 703          (dump-fop 'fop-list* file)
 704          (dump-byte 255 file)))))
 705
 706 ;;; If N > 255, must build list with one LIST operator, then LIST*
 707 ;;; operators.
 708
 709 (defun terminate-undotted-list (n file)
 710   (declare (type index n) (type fasl-output file))
 711   (case n
 712     (1 (dump-fop 'fop-list-1 file))
 713     (2 (dump-fop 'fop-list-2 file))
 714     (3 (dump-fop 'fop-list-3 file))
 715     (4 (dump-fop 'fop-list-4 file))
 716     (5 (dump-fop 'fop-list-5 file))
 717     (6 (dump-fop 'fop-list-6 file))
 718     (7 (dump-fop 'fop-list-7 file))
 719     (8 (dump-fop 'fop-list-8 file))
 720     (t (cond ((< n 256)
 721               (dump-fop 'fop-list file)
 722               (dump-byte n file))
 723              (t (dump-fop 'fop-list file)
 724                 (dump-byte 255 file)
 725                 (do ((nn (- n 255) (- nn 255)))
 726                     ((< nn 256)
 727                      (dump-fop 'fop-list* file)
 728                      (dump-byte nn file))
 729                   (declare (type index nn))
 730                   (dump-fop 'fop-list* file)
 731                   (dump-byte 255 file)))))))
 732 \f
 733 ;;;; array dumping
 734
 735 ;;; Dump the array thing.
 736 (defun dump-array (x file)
 737   (if (vectorp x)
 738       (dump-vector x file)
 739       (dump-multi-dim-array x file)))
 740
 741 ;;; Dump the vector object. If it's not simple, then actually dump a
 742 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 743 ;;; tables.
 744 (defun dump-vector (x file)
 745   (let ((simple-version (if (array-header-p x)
 746                             (coerce x `(simple-array
 747                                         ,(array-element-type x)
 748                                         (*)))
 749                             x)))
 750     (typecase simple-version
 751       #+sb-xc-host
 752       (simple-string
 753        (unless (string-check-table x file)
 754          (dump-simple-base-string simple-version file)
 755          (string-save-object x file)))
 756       #-sb-xc-host
 757       (simple-base-string
 758        (unless (string-check-table x file)
 759          (dump-simple-base-string simple-version file)
 760          (string-save-object x file)))
 761       #-sb-xc-host
 762       ((simple-array character (*))
 763        #!+sb-unicode
 764        (unless (string-check-table x file)
 765          (dump-simple-character-string simple-version file)
 766          (string-save-object x file))
 767        #!-sb-unicode
 768        (bug "how did we get here?"))
 769       (simple-vector
 770        (dump-simple-vector simple-version file)
 771        (eq-save-object x file))
 772       ((simple-array single-float (*))
 773        (dump-single-float-vector simple-version file)
 774        (eq-save-object x file))
 775       ((simple-array double-float (*))
 776        (dump-double-float-vector simple-version file)
 777        (eq-save-object x file))
 778       #!+long-float
 779       ((simple-array long-float (*))
 780        (dump-long-float-vector simple-version file)
 781        (eq-save-object x file))
 782       ((simple-array (complex single-float) (*))
 783        (dump-complex-single-float-vector simple-version file)
 784        (eq-save-object x file))
 785       ((simple-array (complex double-float) (*))
 786        (dump-complex-double-float-vector simple-version file)
 787        (eq-save-object x file))
 788       #!+long-float
 789       ((simple-array (complex long-float) (*))
 790        (dump-complex-long-float-vector simple-version file)
 791        (eq-save-object x file))
 792       (t
 793        (dump-i-vector simple-version file)
 794        (eq-save-object x file)))))
 795
 796 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 797 (defun dump-simple-vector (v file)
 798   (declare (type simple-vector v) (type fasl-output file))
 799   (note-potential-circularity v file)
 800   (do ((index 0 (1+ index))
 801        (length (length v))
 802        (circ (fasl-output-circularity-table file)))
 803       ((= index length)
 804        (dump-fop* length fop-small-vector fop-vector file))
 805     (let* ((obj (aref v index))
 806            (ref (gethash obj circ)))
 807       (cond (ref
 808              (push (make-circularity :type :svset
 809                                      :object v
 810                                      :index index
 811                                      :value obj
 812                                      :enclosing-object ref)
 813                    *circularities-detected*)
 814              (sub-dump-object nil file))
 815             (t
 816              (sub-dump-object obj file))))))
 817
 818 ;;; In the grand scheme of things I don't pretend to understand any
 819 ;;; more how this works, or indeed whether.  But to write out specialized
 820 ;;; vectors in the same format as fop-int-vector expects to read them
 821 ;;; we need to be target-endian.  dump-integer-as-n-bytes always writes
 822 ;;; little-endian (which is correct for all other integers) so for a bigendian
 823 ;;; target we need to swap octets -- CSR, after DB
 824
 825 (defun octet-swap (word bits)
 826   "BITS must be a multiple of 8"
 827   (do ((input word (ash input -8))
 828        (output 0 (logior (ash output 8) (logand input #xff)))
 829        (bits bits (- bits 8)))
 830       ((<= bits 0) output)))
 831
 832 (defun dump-i-vector (vec file &key data-only)
 833   (declare (type (simple-array * (*)) vec))
 834   (let ((len (length vec)))
 835     (labels ((dump-unsigned-vector (size bytes)
 836                (unless data-only
 837                  (dump-fop 'fop-int-vector file)
 838                  (dump-word len file)
 839                  (dump-byte size file))
 840                ;; The case which is easy to handle in a portable way is when
 841                ;; the element size is a multiple of the output byte size, and
 842                ;; happily that's the only case we need to be portable. (The
 843                ;; cross-compiler has to output debug information (including
 844                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 845                ;; needed in the target SBCL, so we let them be handled with
 846                ;; unportable bit bashing.
 847                (cond ((>= size 7) ; easy cases
 848                       (multiple-value-bind (floor rem) (floor size 8)
 849                         (aver (or (zerop rem) (= rem 7)))
 850                         (when (= rem 7)
 851                           (setq size (1+ size))
 852                           (setq floor (1+ floor)))
 853                         (dovector (i vec)
 854                           (dump-integer-as-n-bytes
 855                            (ecase sb!c:*backend-byte-order*
 856                              (:little-endian i)
 857                              (:big-endian (octet-swap i size)))
 858                            floor file))))
 859                      (t ; harder cases, not supported in cross-compiler
 860                       (dump-raw-bytes vec bytes file))))
 861              (dump-signed-vector (size bytes)
 862                ;; Note: Dumping specialized signed vectors isn't
 863                ;; supported in the cross-compiler. (All cases here end
 864                ;; up trying to call DUMP-RAW-BYTES, which isn't
 865                ;; provided in the cross-compilation host, only on the
 866                ;; target machine.)
 867                (unless data-only
 868                  (dump-fop 'fop-signed-int-vector file)
 869                  (dump-word len file)
 870                  (dump-byte size file))
 871                (dump-raw-bytes vec bytes file)))
 872       (etypecase vec
 873         #-sb-xc-host
 874         ((simple-array nil (*))
 875          (dump-unsigned-vector 0 0))
 876         (simple-bit-vector
 877          (dump-unsigned-vector 1 (ceiling len 8))) ; bits to bytes
 878         ;; KLUDGE: This isn't the best way of expressing that the host
 879         ;; may not have specializations for (unsigned-byte 2) and
 880         ;; (unsigned-byte 4), which means that these types are
 881         ;; type-equivalent to (simple-array (unsigned-byte 8) (*));
 882         ;; the workaround is to remove them from the etypecase, since
 883         ;; they can't be dumped from the cross-compiler anyway. --
 884         ;; CSR, 2002-05-07
 885         #-sb-xc-host
 886         ((simple-array (unsigned-byte 2) (*))
 887          (dump-unsigned-vector 2 (ceiling (ash len 1) 8))) ; bits to bytes
 888         #-sb-xc-host
 889         ((simple-array (unsigned-byte 4) (*))
 890          (dump-unsigned-vector 4 (ceiling (ash len 2) 8))) ; bits to bytes
 891         #-sb-xc-host
 892         ((simple-array (unsigned-byte 7) (*))
 893          (dump-unsigned-vector 7 len))
 894         ((simple-array (unsigned-byte 8) (*))
 895          (dump-unsigned-vector 8 len))
 896         #-sb-xc-host
 897         ((simple-array (unsigned-byte 15) (*))
 898          (dump-unsigned-vector 15 (* 2 len)))
 899         ((simple-array (unsigned-byte 16) (*))
 900          (dump-unsigned-vector 16 (* 2 len)))
 901         #-sb-xc-host
 902         ((simple-array (unsigned-byte 31) (*))
 903          (dump-unsigned-vector 31 (* 4 len)))
 904         ((simple-array (unsigned-byte 32) (*))
 905          (dump-unsigned-vector 32 (* 4 len)))
 906         #-sb-xc-host
 907         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 908         ((simple-array (unsigned-byte 63) (*))
 909          (dump-unsigned-vector 63 (* 8 len)))
 910         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 911         ((simple-array (unsigned-byte 64) (*))
 912          (dump-unsigned-vector 64 (* 8 len)))
 913         ((simple-array (signed-byte 8) (*))
 914          (dump-signed-vector 8 len))
 915         ((simple-array (signed-byte 16) (*))
 916          (dump-signed-vector 16 (* 2 len)))
 917         #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 918         ((simple-array (unsigned-byte 29) (*))
 919          (dump-signed-vector 29 (* 4 len)))
 920         #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 921         ((simple-array (signed-byte 30) (*))
 922          (dump-signed-vector 30 (* 4 len)))
 923         ((simple-array (signed-byte 32) (*))
 924          (dump-signed-vector 32 (* 4 len)))
 925         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 926         ((simple-array (unsigned-byte 60) (*))
 927          (dump-signed-vector 60 (* 8 len)))
 928         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 929         ((simple-array (signed-byte 61) (*))
 930          (dump-signed-vector 61 (* 8 len)))
 931         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 932         ((simple-array (signed-byte 64) (*))
 933          (dump-signed-vector 64 (* 8 len)))))))
 934 \f
 935 ;;; Dump characters and string-ish things.
 936
 937 (defun dump-character (char file)
 938   (let ((code (sb!xc:char-code char)))
 939     (cond
 940       ((< code 256)
 941        (dump-fop 'fop-short-character file)
 942        (dump-byte code file))
 943       (t
 944        (dump-fop 'fop-character file)
 945        (dump-word code file)))))
 946
 947 (defun dump-base-chars-of-string (s fasl-output)
 948   (declare #+sb-xc-host (type simple-string s)
 949            #-sb-xc-host (type simple-base-string s)
 950            (type fasl-output fasl-output))
 951   (dovector (c s)
 952     (dump-byte (sb!xc:char-code c) fasl-output))
 953   (values))
 954
 955
 956 ;;; Dump a SIMPLE-BASE-STRING.
 957 (defun dump-simple-base-string (s file)
 958   #+sb-xc-host (declare (type simple-string s))
 959   #-sb-xc-host (declare (type simple-base-string s))
 960   (dump-fop* (length s) fop-small-base-string fop-base-string file)
 961   (dump-base-chars-of-string s file)
 962   (values))
 963
 964 ;;; If we get here, it is assumed that the symbol isn't in the table,
 965 ;;; but we are responsible for putting it there when appropriate. To
 966 ;;; avoid too much special-casing, we always push the symbol in the
 967 ;;; table, but don't record that we have done so if *COLD-LOAD-DUMP*
 968 ;;; is true.
 969 (defun dump-symbol (s file)
 970   (declare (type fasl-output file))
 971   (let* ((pname (symbol-name s))
 972          (pname-length (length pname))
 973          (pkg (symbol-package s)))
 974
 975     (cond ((null pkg)
 976            (dump-fop* pname-length
 977                       fop-uninterned-small-symbol-save
 978                       fop-uninterned-symbol-save
 979                       file))
 980           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 981           ;; used the current value of *PACKAGE*. Unfortunately that's
 982           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 983           ;; from SBCL.
 984           ;;((eq pkg *package*)
 985           ;; (dump-fop* pname-length
 986           ;;        fop-small-symbol-save
 987           ;;        fop-symbol-save file))
 988           ((eq pkg sb!int:*cl-package*)
 989            (dump-fop* pname-length
 990                       fop-lisp-small-symbol-save
 991                       fop-lisp-symbol-save
 992                       file))
 993           ((eq pkg sb!int:*keyword-package*)
 994            (dump-fop* pname-length
 995                       fop-keyword-small-symbol-save
 996                       fop-keyword-symbol-save
 997                       file))
 998           ((< pname-length 256)
 999            (dump-fop* (dump-package pkg file)
1000                       fop-small-symbol-in-byte-package-save
1001                       fop-small-symbol-in-package-save
1002                       file)
1003            (dump-byte pname-length file))
1004           (t
1005            (dump-fop* (dump-package pkg file)
1006                       fop-symbol-in-byte-package-save
1007                       fop-symbol-in-package-save
1008                       file)
1009            (dump-word pname-length file)))
1010
1011     #+sb-xc-host (dump-base-chars-of-string pname file)
1012     #-sb-xc-host (#!+sb-unicode dump-characters-of-string
1013                   #!-sb-unicode dump-base-chars-of-string
1014                   pname file)
1015
1016     (unless *cold-load-dump*
1017       (setf (gethash s (fasl-output-eq-table file))
1018             (fasl-output-table-free file)))
1019
1020     (incf (fasl-output-table-free file)))
1021
1022   (values))
1023 \f
1024 ;;;; component (function) dumping
1025
1026 (defun dump-segment (segment code-length fasl-output)
1027   (declare (type sb!assem:segment segment)
1028            (type fasl-output fasl-output))
1029   (let* ((stream (fasl-output-stream fasl-output))
1030          (n-written (write-segment-contents segment stream)))
1031     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
1032     ;; argument and the number of bytes actually written. I added this
1033     ;; assertion while trying to debug portable genesis. -- WHN 19990902
1034     (unless (= code-length n-written)
1035       (bug "code-length=~W, n-written=~W" code-length n-written)))
1036   (values))
1037
1038 ;;; Dump all the fixups. Currently there are three flavors of fixup:
1039 ;;;  - assembly routines: named by a symbol
1040 ;;;  - foreign (C) symbols: named by a string
1041 ;;;  - code object references: don't need a name.
1042 (defun dump-fixups (fixups fasl-output)
1043   (declare (list fixups) (type fasl-output fasl-output))
1044   (dolist (note fixups)
1045     (let* ((kind (fixup-note-kind note))
1046            (fixup (fixup-note-fixup note))
1047            (position (fixup-note-position note))
1048            (name (fixup-name fixup))
1049            (flavor (fixup-flavor fixup)))
1050       (dump-fop 'fop-normal-load fasl-output)
1051       (let ((*cold-load-dump* t))
1052         (dump-object kind fasl-output))
1053       (dump-fop 'fop-maybe-cold-load fasl-output)
1054       ;; Depending on the flavor, we may have various kinds of
1055       ;; noise before the position.
1056       (ecase flavor
1057         (:assembly-routine
1058          (aver (symbolp name))
1059          (dump-fop 'fop-normal-load fasl-output)
1060          (let ((*cold-load-dump* t))
1061            (dump-object name fasl-output))
1062          (dump-fop 'fop-maybe-cold-load fasl-output)
1063          (dump-fop 'fop-assembler-fixup fasl-output))
1064         ((:foreign :foreign-dataref)
1065          (aver (stringp name))
1066          (ecase flavor
1067            (:foreign
1068             (dump-fop 'fop-foreign-fixup fasl-output))
1069            #!+linkage-table
1070            (:foreign-dataref
1071             (dump-fop 'fop-foreign-dataref-fixup fasl-output)))
1072          (let ((len (length name)))
1073            (aver (< len 256)) ; (limit imposed by fop definition)
1074            (dump-byte len fasl-output)
1075            (dotimes (i len)
1076              (dump-byte (char-code (schar name i)) fasl-output))))
1077         (:code-object
1078          (aver (null name))
1079          (dump-fop 'fop-code-object-fixup fasl-output)))
1080       ;; No matter what the flavor, we'll always dump the position
1081       (dump-word position fasl-output)))
1082   (values))
1083
1084 ;;; Dump out the constant pool and code-vector for component, push the
1085 ;;; result in the table, and return the offset.
1086 ;;;
1087 ;;; The only tricky thing is handling constant-pool references to
1088 ;;; functions. If we have already dumped the function, then we just
1089 ;;; push the code pointer. Otherwise, we must create back-patching
1090 ;;; information so that the constant will be set when the function is
1091 ;;; eventually dumped. This is a bit awkward, since we don't have the
1092 ;;; handle for the code object being dumped while we are dumping its
1093 ;;; constants.
1094 ;;;
1095 ;;; We dump trap objects in any unused slots or forward referenced slots.
1096 (defun dump-code-object (component
1097                          code-segment
1098                          code-length
1099                          trace-table-as-list
1100                          fixups
1101                          fasl-output)
1102
1103   (declare (type component component)
1104            (list trace-table-as-list)
1105            (type index code-length)
1106            (type fasl-output fasl-output))
1107
1108   (let* ((2comp (component-info component))
1109          (constants (sb!c::ir2-component-constants 2comp))
1110          (header-length (length constants))
1111          (packed-trace-table (pack-trace-table trace-table-as-list))
1112          (total-length (+ code-length
1113                           (* (length packed-trace-table)
1114                              sb!c::tt-bytes-per-entry))))
1115
1116     (collect ((patches))
1117
1118       ;; Dump the offset of the trace table.
1119       (dump-object code-length fasl-output)
1120       ;; FIXME: As long as we don't have GENGC, the trace table is
1121       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
1122       ;; far as I know no modern CMU CL does either -- WHN
1123       ;; 2001-10-05). So might we be able to get rid of trace tables?
1124       ;;
1125       ;; Note that gencgc also does something with the trace table.
1126
1127       ;; Dump the constants, noting any :ENTRY constants that have to
1128       ;; be patched.
1129       (loop for i from sb!vm:code-constants-offset below header-length do
1130         (let ((entry (aref constants i)))
1131           (etypecase entry
1132             (constant
1133              (dump-object (sb!c::constant-value entry) fasl-output))
1134             (cons
1135              (ecase (car entry)
1136                (:entry
1137                 (let* ((info (sb!c::leaf-info (cdr entry)))
1138                        (handle (gethash info
1139                                         (fasl-output-entry-table
1140                                          fasl-output))))
1141                   (declare (type sb!c::entry-info info))
1142                   (cond
1143                    (handle
1144                     (dump-push handle fasl-output))
1145                    (t
1146                     (patches (cons info i))
1147                     (dump-fop 'fop-misc-trap fasl-output)))))
1148                (:load-time-value
1149                 (dump-push (cdr entry) fasl-output))
1150                (:fdefinition
1151                 (dump-object (cdr entry) fasl-output)
1152                 (dump-fop 'fop-fdefinition fasl-output))))
1153             (null
1154              (dump-fop 'fop-misc-trap fasl-output)))))
1155
1156       ;; Dump the debug info.
1157       (let ((info (sb!c::debug-info-for-component component))
1158             (*dump-only-valid-structures* nil))
1159         (dump-object info fasl-output)
1160         (let ((info-handle (dump-pop fasl-output)))
1161           (dump-push info-handle fasl-output)
1162           (push info-handle (fasl-output-debug-info fasl-output))))
1163
1164       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1165         (cond ((and (< num-consts #x100) (< total-length #x10000))
1166                (dump-fop 'fop-small-code fasl-output)
1167                (dump-byte num-consts fasl-output)
1168                (dump-integer-as-n-bytes total-length (/ sb!vm:n-word-bytes 2) fasl-output))
1169               (t
1170                (dump-fop 'fop-code fasl-output)
1171                (dump-word num-consts fasl-output)
1172                (dump-word total-length fasl-output))))
1173
1174       ;; These two dumps are only ones which contribute to our
1175       ;; TOTAL-LENGTH value.
1176       (dump-segment code-segment code-length fasl-output)
1177       (dump-i-vector packed-trace-table fasl-output :data-only t)
1178
1179       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1180       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1181       ;; FOP-CODE/FOP-SMALL-CODE fop.
1182       (dump-fixups fixups fasl-output)
1183
1184       (dump-fop 'fop-sanctify-for-execution fasl-output)
1185
1186       (let ((handle (dump-pop fasl-output)))
1187         (dolist (patch (patches))
1188           (push (cons handle (cdr patch))
1189                 (gethash (car patch)
1190                          (fasl-output-patch-table fasl-output))))
1191         handle))))
1192
1193 (defun dump-assembler-routines (code-segment length fixups routines file)
1194   (dump-fop 'fop-assembler-code file)
1195   (dump-word length file)
1196   (write-segment-contents code-segment (fasl-output-stream file))
1197   (dolist (routine routines)
1198     (dump-fop 'fop-normal-load file)
1199     (let ((*cold-load-dump* t))
1200       (dump-object (car routine) file))
1201     (dump-fop 'fop-maybe-cold-load file)
1202     (dump-fop 'fop-assembler-routine file)
1203     (dump-word (label-position (cdr routine)) file))
1204   (dump-fixups fixups file)
1205   (dump-fop 'fop-sanctify-for-execution file)
1206   (dump-pop file))
1207
1208 ;;; Dump a function entry data structure corresponding to ENTRY to
1209 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1210 ;;; component.
1211 (defun dump-one-entry (entry code-handle file)
1212   (declare (type sb!c::entry-info entry) (type index code-handle)
1213            (type fasl-output file))
1214   (let ((name (sb!c::entry-info-name entry)))
1215     (dump-push code-handle file)
1216     (dump-object name file)
1217     (dump-object (sb!c::entry-info-arguments entry) file)
1218     (dump-object (sb!c::entry-info-type entry) file)
1219     (dump-fop 'fop-fun-entry file)
1220     (dump-word (label-position (sb!c::entry-info-offset entry)) file)
1221     (dump-pop file)))
1222
1223 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1224 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1225 (defun dump-alter-code-object (code-handle offset entry-handle file)
1226   (declare (type index code-handle entry-handle offset))
1227   (declare (type fasl-output file))
1228   (dump-push code-handle file)
1229   (dump-push entry-handle file)
1230   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1231   (values))
1232
1233 ;;; Dump the code, constants, etc. for component. We pass in the
1234 ;;; assembler fixups, code vector and node info.
1235 (defun fasl-dump-component (component
1236                             code-segment
1237                             code-length
1238                             trace-table
1239                             fixups
1240                             file)
1241   (declare (type component component) (list trace-table))
1242   (declare (type fasl-output file))
1243
1244   (dump-fop 'fop-verify-empty-stack file)
1245   (dump-fop 'fop-verify-table-size file)
1246   (dump-word (fasl-output-table-free file) file)
1247
1248   #!+sb-dyncount
1249   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1250     (when info
1251       (fasl-validate-structure info file)))
1252
1253   (let ((code-handle (dump-code-object component
1254                                        code-segment
1255                                        code-length
1256                                        trace-table
1257                                        fixups
1258                                        file))
1259         (2comp (component-info component)))
1260     (dump-fop 'fop-verify-empty-stack file)
1261
1262     (dolist (entry (sb!c::ir2-component-entries 2comp))
1263       (let ((entry-handle (dump-one-entry entry code-handle file)))
1264         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1265         (let ((old (gethash entry (fasl-output-patch-table file))))
1266           (when old
1267             (dolist (patch old)
1268               (dump-alter-code-object (car patch)
1269                                       (cdr patch)
1270                                       entry-handle
1271                                       file))
1272             (remhash entry (fasl-output-patch-table file)))))))
1273   (values))
1274
1275 (defun dump-push-previously-dumped-fun (fun fasl-output)
1276   (declare (type sb!c::clambda fun))
1277   (let ((handle (gethash (sb!c::leaf-info fun)
1278                          (fasl-output-entry-table fasl-output))))
1279     (aver handle)
1280     (dump-push handle fasl-output))
1281   (values))
1282
1283 ;;; Dump a FOP-FUNCALL to call an already-dumped top level lambda at
1284 ;;; load time.
1285 (defun fasl-dump-toplevel-lambda-call (fun fasl-output)
1286   (declare (type sb!c::clambda fun))
1287   (dump-push-previously-dumped-fun fun fasl-output)
1288   (dump-fop 'fop-funcall-for-effect fasl-output)
1289   (dump-byte 0 fasl-output)
1290   (values))
1291
1292 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1293 ;;; FUN-NAME and the already-dumped function whose dump handle is
1294 ;;; FUN-DUMP-HANDLE.
1295 #+sb-xc-host
1296 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1297   (declare (type fixnum fun-dump-handle))
1298   (aver (legal-fun-name-p fun-name))
1299   (dump-non-immediate-object fun-name fasl-output)
1300   (dump-push fun-dump-handle fasl-output)
1301   (dump-fop 'fop-fset fasl-output)
1302   (values))
1303
1304 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1305 ;;; all of the dumped DEBUG-INFO structures. We clear the
1306 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1307 ;;; different source info may be dumped.
1308 (defun fasl-dump-source-info (info fasl-output)
1309   (declare (type sb!c::source-info info))
1310   (let ((res (sb!c::debug-source-for-info info))
1311         (*dump-only-valid-structures* nil))
1312     (dump-object res fasl-output)
1313     (let ((res-handle (dump-pop fasl-output)))
1314       (dolist (info-handle (fasl-output-debug-info fasl-output))
1315         (dump-push res-handle fasl-output)
1316         (dump-fop 'fop-structset fasl-output)
1317         (dump-word info-handle fasl-output)
1318         ;; FIXME: what is this bare `2'?  --njf, 2004-08-16
1319         (dump-word 2 fasl-output))))
1320   (setf (fasl-output-debug-info fasl-output) nil)
1321   (values))
1322 \f
1323 ;;;; dumping structures
1324
1325 (defun dump-structure (struct file)
1326   (when *dump-only-valid-structures*
1327     (unless (gethash struct (fasl-output-valid-structures file))
1328       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1329              struct)))
1330   (note-potential-circularity struct file)
1331   (aver (%instance-ref struct 0))
1332   (do* ((length (%instance-length struct))
1333         (ntagged (- length (layout-n-untagged-slots (%instance-ref struct 0))))
1334         (circ (fasl-output-circularity-table file))
1335         ;; last slot first on the stack, so that the layout is on top:
1336         (index (1- length) (1- index)))
1337       ((minusp index)
1338        (dump-fop* length fop-small-struct fop-struct file))
1339     (let* ((obj (if (>= index ntagged)
1340                     (%raw-instance-ref/word struct (- length index 1))
1341                     (%instance-ref struct index)))
1342            (ref (gethash obj circ)))
1343       (cond (ref
1344              (aver (not (zerop index)))
1345              (push (make-circularity :type :struct-set
1346                                      :object struct
1347                                      :index index
1348                                      :value obj
1349                                      :enclosing-object ref)
1350                    *circularities-detected*)
1351              (sub-dump-object nil file))
1352             (t
1353              (sub-dump-object obj file))))))
1354
1355 (defun dump-layout (obj file)
1356   (when (layout-invalid obj)
1357     (compiler-error "attempt to dump reference to obsolete class: ~S"
1358                     (layout-classoid obj)))
1359   (let ((name (classoid-name (layout-classoid obj))))
1360     (unless name
1361       (compiler-error "dumping anonymous layout: ~S" obj))
1362     (dump-fop 'fop-normal-load file)
1363     (let ((*cold-load-dump* t))
1364       (dump-object name file))
1365     (dump-fop 'fop-maybe-cold-load file))
1366   (sub-dump-object (layout-inherits obj) file)
1367   (sub-dump-object (layout-depthoid obj) file)
1368   (sub-dump-object (layout-length obj) file)
1369   (sub-dump-object (layout-n-untagged-slots obj) file)
1370   (dump-fop 'fop-layout file))