src/compiler/dump.lisp

   1 ;;;; stuff that knows about dumping FASL files
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!FASL")
  13 ;;; KLUDGE: Even though we're IN-PACKAGE SB!FASL, some of the code in
  14 ;;; here is awfully chummy with the SB!C package. CMU CL didn't have
  15 ;;; any separation between the two packages, and a lot of tight
  16 ;;; coupling remains. -- WHN 2001-06-04
  17 \f
  18 ;;;; fasl dumper state
  19
  20 ;;; The FASL-OUTPUT structure represents everything we need to
  21 ;;; know about dumping to a fasl file. (We need to objectify the
  22 ;;; state because the fasdumper must be reentrant.)
  23 (defstruct (fasl-output
  24             #-no-ansi-print-object
  25             (:print-object (lambda (x s)
  26                              (print-unreadable-object (x s :type t)
  27                                (prin1 (namestring (fasl-output-stream x))
  28                                       s))))
  29             (:copier nil))
  30   ;; the stream we dump to
  31   (stream (missing-arg) :type stream)
  32   ;; hashtables we use to keep track of dumped constants so that we
  33   ;; can get them from the table rather than dumping them again. The
  34   ;; EQUAL-TABLE is used for lists and strings, and the EQ-TABLE is
  35   ;; used for everything else. We use a separate EQ table to avoid
  36   ;; performance pathologies with objects for which EQUAL degenerates
  37   ;; to EQL. Everything entered in the EQUAL table is also entered in
  38   ;; the EQ table.
  39   (equal-table (make-hash-table :test 'equal) :type hash-table)
  40   (eq-table (make-hash-table :test 'eq) :type hash-table)
  41   ;; the table's current free pointer: the next offset to be used
  42   (table-free 0 :type index)
  43   ;; an alist (PACKAGE . OFFSET) of the table offsets for each package
  44   ;; we have currently located.
  45   (packages () :type list)
  46   ;; a table mapping from the ENTRY-INFO structures for dumped XEPs to
  47   ;; the table offsets of the corresponding code pointers
  48   (entry-table (make-hash-table :test 'eq) :type hash-table)
  49   ;; a table holding back-patching info for forward references to XEPs.
  50   ;; The key is the ENTRY-INFO structure for the XEP, and the value is
  51   ;; a list of conses (<code-handle> . <offset>), where <code-handle>
  52   ;; is the offset in the table of the code object needing to be
  53   ;; patched, and <offset> is the offset that must be patched.
  54   (patch-table (make-hash-table :test 'eq) :type hash-table)
  55   ;; a list of the table handles for all of the DEBUG-INFO structures
  56   ;; dumped in this file. These structures must be back-patched with
  57   ;; source location information when the compilation is complete.
  58   (debug-info () :type list)
  59   ;; This is used to keep track of objects that we are in the process
  60   ;; of dumping so that circularities can be preserved. The key is the
  61   ;; object that we have previously seen, and the value is the object
  62   ;; that we reference in the table to find this previously seen
  63   ;; object. (The value is never NIL.)
  64   ;;
  65   ;; Except with list objects, the key and the value are always the
  66   ;; same. In a list, the key will be some tail of the value.
  67   (circularity-table (make-hash-table :test 'eq) :type hash-table)
  68   ;; a hash table of structures that are allowed to be dumped. If we
  69   ;; try to dump a structure that isn't in this hash table, we lose.
  70   (valid-structures (make-hash-table :test 'eq) :type hash-table))
  71
  72 ;;; This structure holds information about a circularity.
  73 (defstruct (circularity (:copier nil))
  74   ;; the kind of modification to make to create circularity
  75   (type (missing-arg) :type (member :rplaca :rplacd :svset :struct-set))
  76   ;; the object containing circularity
  77   object
  78   ;; index in object for circularity
  79   (index (missing-arg) :type index)
  80   ;; the object to be stored at INDEX in OBJECT. This is that the key
  81   ;; that we were using when we discovered the circularity.
  82   value
  83   ;; the value that was associated with VALUE in the
  84   ;; CIRCULARITY-TABLE. This is the object that we look up in the
  85   ;; EQ-TABLE to locate VALUE.
  86   enclosing-object)
  87
  88 ;;; a list of the CIRCULARITY structures for all of the circularities
  89 ;;; detected in the current top level call to DUMP-OBJECT. Setting
  90 ;;; this lobotomizes circularity detection as well, since circular
  91 ;;; dumping uses the table.
  92 (defvar *circularities-detected*)
  93
  94 ;;; used to turn off the structure validation during dumping of source
  95 ;;; info
  96 (defvar *dump-only-valid-structures* t)
  97 ;;;; utilities
  98
  99 ;;; Write the byte B to the specified FASL-OUTPUT stream.
 100 (defun dump-byte (b fasl-output)
 101   (declare (type (unsigned-byte 8) b) (type fasl-output fasl-output))
 102   (write-byte b (fasl-output-stream fasl-output)))
 103
 104 ;; Dump a word-sized integer.
 105 (defun dump-word (num fasl-output)
 106   (declare (type sb!vm:word num))
 107   (declare (type fasl-output fasl-output))
 108   (let ((stream (fasl-output-stream fasl-output)))
 109     (dotimes (i sb!vm:n-word-bytes)
 110       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 111
 112 ;; Dump a 32-bit integer.
 113 (defun dump-unsigned-byte-32 (num fasl-output)
 114   (declare (type sb!vm:word num))
 115   (declare (type fasl-output fasl-output))
 116   (let ((stream (fasl-output-stream fasl-output)))
 117     (dotimes (i 4)
 118       (write-byte (ldb (byte 8 (* 8 i)) num) stream))))
 119
 120 ;;; Dump NUM to the fasl stream, represented by N bytes. This works
 121 ;;; for either signed or unsigned integers. There's no range checking
 122 ;;; -- if you don't specify enough bytes for the number to fit, this
 123 ;;; function cheerfully outputs the low bytes.
 124 (defun dump-integer-as-n-bytes  (num bytes fasl-output)
 125   (declare (integer num) (type index bytes))
 126   (declare (type fasl-output fasl-output))
 127   (do ((n num (ash n -8))
 128        (i bytes (1- i)))
 129       ((= i 0))
 130     (declare (type index i))
 131     (dump-byte (logand n #xff) fasl-output))
 132   (values))
 133
 134 ;;; Setting this variable to an (UNSIGNED-BYTE 32) value causes
 135 ;;; DUMP-FOP to use it as a counter and emit a FOP-NOP4 with the
 136 ;;; counter value before every ordinary fop. This can make it easier
 137 ;;; to follow the progress of LOAD-AS-FASL when
 138 ;;; debugging/testing/experimenting.
 139 #!+sb-show (defvar *fop-nop4-count* nil)
 140 #!+sb-show (declaim (type (or (unsigned-byte 32) null) *fop-nop4-count*))
 141
 142 ;;; Dump the FOP code for the named FOP to the specified FASL-OUTPUT.
 143 ;;;
 144 ;;; FIXME: This should be a function, with a compiler macro expansion
 145 ;;; for the common constant-FS case. (Among other things, that'll stop
 146 ;;; it from EVALing ,FILE multiple times.)
 147 ;;;
 148 ;;; FIXME: Compiler macros, frozen classes, inlining, and similar
 149 ;;; optimizations should be conditional on #!+SB-FROZEN.
 150 (defmacro dump-fop (fs file)
 151   (let* ((fs (eval fs))
 152          (val (get fs 'fop-code)))
 153     (if val
 154       `(progn
 155          #!+sb-show
 156          (when *fop-nop4-count*
 157            (dump-byte ,(get 'fop-nop4 'fop-code) ,file)
 158            (dump-integer-as-n-bytes (mod (incf *fop-nop4-count*) (expt 2 32))
 159                                     4 ,file))
 160          (dump-byte ',val ,file))
 161       (error "compiler bug: ~S is not a legal fasload operator." fs))))
 162
 163 ;;; Dump a FOP-CODE along with an integer argument, choosing the FOP
 164 ;;; based on whether the argument will fit in a single byte.
 165 ;;;
 166 ;;; FIXME: This, like DUMP-FOP, should be a function with a
 167 ;;; compiler-macro expansion.
 168 (defmacro dump-fop* (n byte-fop word-fop file)
 169   (once-only ((n-n n)
 170               (n-file file))
 171     `(cond ((< ,n-n 256)
 172             (dump-fop ',byte-fop ,n-file)
 173             (dump-byte ,n-n ,n-file))
 174            (t
 175             (dump-fop ',word-fop ,n-file)
 176             (dump-word ,n-n ,n-file)))))
 177
 178 ;;; Push the object at table offset Handle on the fasl stack.
 179 (defun dump-push (handle fasl-output)
 180   (declare (type index handle) (type fasl-output fasl-output))
 181   (dump-fop* handle fop-byte-push fop-push fasl-output)
 182   (values))
 183
 184 ;;; Pop the object currently on the fasl stack top into the table, and
 185 ;;; return the table index, incrementing the free pointer.
 186 (defun dump-pop (fasl-output)
 187   (prog1
 188       (fasl-output-table-free fasl-output)
 189     (dump-fop 'fop-pop fasl-output)
 190     (incf (fasl-output-table-free fasl-output))))
 191
 192 ;;; If X is in File's EQUAL-TABLE, then push the object and return T,
 193 ;;; otherwise NIL.
 194 (defun equal-check-table (x fasl-output)
 195   (declare (type fasl-output fasl-output))
 196   (let ((handle (gethash x (fasl-output-equal-table fasl-output))))
 197     (cond
 198      (handle (dump-push handle fasl-output) t)
 199      (t nil))))
 200 (defun string-check-table (x fasl-output)
 201   (declare (type fasl-output fasl-output)
 202            (type string x))
 203   (let ((handle (cdr (assoc
 204                       #+sb-xc-host 'base-char ; for repeatable xc fasls
 205                       #-sb-xc-host (array-element-type x)
 206                       (gethash x (fasl-output-equal-table fasl-output))))))
 207     (cond
 208      (handle (dump-push handle fasl-output) t)
 209      (t nil))))
 210
 211 ;;; These functions are called after dumping an object to save the
 212 ;;; object in the table. The object (also passed in as X) must already
 213 ;;; be on the top of the FOP stack.
 214 (defun eq-save-object (x fasl-output)
 215   (declare (type fasl-output fasl-output))
 216   (let ((handle (dump-pop fasl-output)))
 217     (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 218     (dump-push handle fasl-output))
 219   (values))
 220 (defun equal-save-object (x fasl-output)
 221   (declare (type fasl-output fasl-output))
 222   (let ((handle (dump-pop fasl-output)))
 223     (setf (gethash x (fasl-output-equal-table fasl-output)) handle)
 224     (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 225     (dump-push handle fasl-output))
 226   (values))
 227 (defun string-save-object (x fasl-output)
 228   (declare (type fasl-output fasl-output)
 229            (type string x))
 230   (let ((handle (dump-pop fasl-output)))
 231     (push (cons #+sb-xc-host 'base-char ; repeatable xc fasls
 232                 #-sb-xc-host (array-element-type x)
 233                 handle)
 234           (gethash x (fasl-output-equal-table fasl-output)))
 235     (setf (gethash x (fasl-output-eq-table fasl-output)) handle)
 236     (dump-push handle fasl-output))
 237   (values))
 238 ;;; Record X in File's CIRCULARITY-TABLE. This is called on objects
 239 ;;; that we are about to dump might have a circular path through them.
 240 ;;;
 241 ;;; The object must not currently be in this table, since the dumper
 242 ;;; should never be recursively called on a circular reference.
 243 ;;; Instead, the dumping function must detect the circularity and
 244 ;;; arrange for the dumped object to be patched.
 245 (defun note-potential-circularity (x fasl-output)
 246   (let ((circ (fasl-output-circularity-table fasl-output)))
 247     (aver (not (gethash x circ)))
 248     (setf (gethash x circ) x))
 249   (values))
 250 \f
 251 ;;;; opening and closing fasl files
 252
 253 ;;; Open a fasl file, write its header, and return a FASL-OUTPUT
 254 ;;; object for dumping to it. Some human-readable information about
 255 ;;; the source code is given by the string WHERE.
 256 (defun open-fasl-output (name where)
 257   (declare (type pathname name))
 258   (flet ((fasl-write-string (string stream)
 259            ;; SB-EXT:STRING-TO-OCTETS is not available while cross-compiling
 260            #+sb-xc-host
 261            (loop for char across string
 262                  do (let ((code (char-code char)))
 263                       (unless (<= 0 code 127)
 264                         (setf char #\?))
 265                       (write-byte code stream)))
 266            ;; UTF-8 is safe to use, because +FASL-HEADER-STRING-STOP-CHAR-CODE+
 267            ;; may not appear in UTF-8 encoded bytes
 268            #-sb-xc-host
 269            (write-sequence (string-to-octets string :external-format :utf-8)
 270                            stream)))
 271     (let* ((stream (open name
 272                          :direction :output
 273                          :if-exists :supersede
 274                          :element-type 'sb!assem:assembly-unit))
 275            (res (make-fasl-output :stream stream)))
 276       ;; Before the actual FASL header, write a shebang line using the current
 277       ;; runtime path, so our fasls can be executed directly from the shell.
 278       (when *runtime-pathname*
 279         (fasl-write-string
 280          (format nil "#!~A --script~%"
 281                  (native-namestring *runtime-pathname* :as-file t))
 282          stream))
 283       ;; Begin the header with the constant machine-readable (and
 284       ;; semi-human-readable) string which is used to identify fasl files.
 285       (fasl-write-string *fasl-header-string-start-string* stream)
 286       ;; The constant string which begins the header is followed by
 287       ;; arbitrary human-readable text, terminated by
 288       ;; +FASL-HEADER-STRING-STOP-CHAR-CODE+.
 289       (fasl-write-string
 290        (with-standard-io-syntax
 291          (let ((*print-readably* nil)
 292                (*print-pretty* nil))
 293            (format nil
 294                    "~%  ~
 295                     compiled from ~S~%  ~
 296                     using ~A version ~A~%"
 297                    where
 298                    (sb!xc:lisp-implementation-type)
 299                    (sb!xc:lisp-implementation-version))))
 300        stream)
 301       (dump-byte +fasl-header-string-stop-char-code+ res)
 302       ;; Finish the header by outputting fasl file implementation,
 303       ;; version, and key *FEATURES*.
 304       (flet ((dump-counted-string (string)
 305                ;; The count is dumped as a 32-bit unsigned-byte even on 64-bit
 306                ;; platforms. This ensures that a x86-64 SBCL can gracefully
 307                ;; detect an error when trying to read a x86 fasl, instead
 308                ;; of choking on a ridiculously long counted string.
 309                ;;  -- JES, 2005-12-30
 310                (dump-unsigned-byte-32 (length string) res)
 311                (dotimes (i (length string))
 312                  (dump-byte (char-code (aref string i)) res))))
 313         (dump-counted-string (symbol-name +backend-fasl-file-implementation+))
 314         (dump-word +fasl-file-version+ res)
 315         (dump-counted-string (sb!xc:lisp-implementation-version))
 316         (dump-counted-string *features-affecting-fasl-format*))
 317       res)))
 318
 319 ;;; Close the specified FASL-OUTPUT, aborting the write if ABORT-P.
 320 (defun close-fasl-output (fasl-output abort-p)
 321   (declare (type fasl-output fasl-output))
 322
 323   (unless abort-p
 324     ;; sanity checks
 325     (aver (zerop (hash-table-count (fasl-output-patch-table fasl-output))))
 326     ;; End the group.
 327     (dump-fop 'fop-verify-empty-stack fasl-output)
 328     (dump-fop 'fop-verify-table-size fasl-output)
 329     (dump-word (fasl-output-table-free fasl-output)
 330                fasl-output)
 331     (dump-fop 'fop-end-group fasl-output))
 332
 333   ;; That's all, folks.
 334   (close (fasl-output-stream fasl-output) :abort abort-p)
 335   (values))
 336 \f
 337 ;;;; main entries to object dumping
 338
 339 ;;; This function deals with dumping objects that are complex enough
 340 ;;; so that we want to cache them in the table, rather than repeatedly
 341 ;;; dumping them. If the object is in the EQ-TABLE, then we push it,
 342 ;;; otherwise, we do a type dispatch to a type specific dumping
 343 ;;; function. The type specific branches do any appropriate
 344 ;;; EQUAL-TABLE check and table entry.
 345 ;;;
 346 ;;; When we go to dump the object, we enter it in the CIRCULARITY-TABLE.
 347 (defun dump-non-immediate-object (x file)
 348   (let ((index (gethash x (fasl-output-eq-table file))))
 349     (cond (index
 350            (dump-push index file))
 351           (t
 352            (typecase x
 353              (symbol (dump-symbol x file))
 354              (list
 355               ;; KLUDGE: The code in this case has been hacked
 356               ;; to match Douglas Crosher's quick fix to CMU CL
 357               ;; (on cmucl-imp 1999-12-27), applied in sbcl-0.6.8.11
 358               ;; with help from Martin Atzmueller. This is not an
 359               ;; ideal solution; to quote DTC,
 360               ;;   The compiler locks up trying to coalesce the
 361               ;;   constant lists. The hack below will disable the
 362               ;;   coalescing of lists while dumping and allows
 363               ;;   the code to compile. The real fix would be to
 364               ;;   take a little more care while dumping these.
 365               ;; So if better list coalescing is needed, start here.
 366               ;; -- WHN 2000-11-07
 367               (if (maybe-cyclic-p x)
 368                   (progn
 369                     (dump-list x file)
 370                     (eq-save-object x file))
 371                   (unless (equal-check-table x file)
 372                     (dump-list x file)
 373                     (equal-save-object x file))))
 374              (layout
 375               (dump-layout x file)
 376               (eq-save-object x file))
 377              (instance
 378               (dump-structure x file)
 379               (eq-save-object x file))
 380              (array
 381               ;; DUMP-ARRAY (and its callees) are responsible for
 382               ;; updating the EQ and EQUAL hash tables.
 383               (dump-array x file))
 384              (number
 385               (unless (equal-check-table x file)
 386                 (etypecase x
 387                   (ratio (dump-ratio x file))
 388                   (complex (dump-complex x file))
 389                   (float (dump-float x file))
 390                   (integer (dump-integer x file)))
 391                 (equal-save-object x file)))
 392              #!+sb-simd-pack
 393              (simd-pack
 394               (unless (equal-check-table x file)
 395                 (dump-fop 'fop-simd-pack file)
 396                 (dump-integer-as-n-bytes (%simd-pack-tag  x) 8 file)
 397                 (dump-integer-as-n-bytes (%simd-pack-low  x) 8 file)
 398                 (dump-integer-as-n-bytes (%simd-pack-high x) 8 file))
 399               (equal-save-object x file))
 400              (t
 401               ;; This probably never happens, since bad things tend to
 402               ;; be detected during IR1 conversion.
 403               (error "This object cannot be dumped into a fasl file:~% ~S"
 404                      x))))))
 405   (values))
 406
 407 ;;; Dump an object of any type by dispatching to the correct
 408 ;;; type-specific dumping function. We pick off immediate objects,
 409 ;;; symbols and magic lists here. Other objects are handled by
 410 ;;; DUMP-NON-IMMEDIATE-OBJECT.
 411 ;;;
 412 ;;; This is the function used for recursive calls to the fasl dumper.
 413 ;;; We don't worry about creating circularities here, since it is
 414 ;;; assumed that there is a top level call to DUMP-OBJECT.
 415 (defun sub-dump-object (x file)
 416   (cond ((listp x)
 417          (if x
 418              (dump-non-immediate-object x file)
 419              (dump-fop 'fop-empty-list file)))
 420         ((symbolp x)
 421          (if (eq x t)
 422              (dump-fop 'fop-truth file)
 423              (dump-non-immediate-object x file)))
 424         ((fixnump x) (dump-integer x file))
 425         ((characterp x) (dump-character x file))
 426         (t
 427          (dump-non-immediate-object x file))))
 428
 429 ;;; Dump stuff to backpatch already dumped objects. INFOS is the list
 430 ;;; of CIRCULARITY structures describing what to do. The patching FOPs
 431 ;;; take the value to store on the stack. We compute this value by
 432 ;;; fetching the enclosing object from the table, and then CDR'ing it
 433 ;;; if necessary.
 434 (defun dump-circularities (infos file)
 435   (let ((table (fasl-output-eq-table file)))
 436     (dolist (info infos)
 437
 438       (let* ((value (circularity-value info))
 439              (enclosing (circularity-enclosing-object info)))
 440         (dump-push (gethash enclosing table) file)
 441         (unless (eq enclosing value)
 442           (do ((current enclosing (cdr current))
 443                (i 0 (1+ i)))
 444               ((eq current value)
 445                (dump-fop 'fop-nthcdr file)
 446                (dump-word i file))
 447             (declare (type index i)))))
 448
 449       (ecase (circularity-type info)
 450         (:rplaca     (dump-fop 'fop-rplaca    file))
 451         (:rplacd     (dump-fop 'fop-rplacd    file))
 452         (:svset      (dump-fop 'fop-svset     file))
 453         (:struct-set (dump-fop 'fop-structset file)))
 454       (dump-word (gethash (circularity-object info) table) file)
 455       (dump-word (circularity-index info) file))))
 456
 457 ;;; Set up stuff for circularity detection, then dump an object. All
 458 ;;; shared and circular structure will be exactly preserved within a
 459 ;;; single call to DUMP-OBJECT. Sharing between objects dumped by
 460 ;;; separate calls is only preserved when convenient.
 461 ;;;
 462 ;;; We peek at the object type so that we only pay the circular
 463 ;;; detection overhead on types of objects that might be circular.
 464 (defun dump-object (x file)
 465   (if (compound-object-p x)
 466       (let ((*circularities-detected* ())
 467             (circ (fasl-output-circularity-table file)))
 468         (clrhash circ)
 469         (sub-dump-object x file)
 470         (when *circularities-detected*
 471           (dump-circularities *circularities-detected* file)
 472           (clrhash circ)))
 473       (sub-dump-object x file)))
 474 \f
 475 ;;;; LOAD-TIME-VALUE and MAKE-LOAD-FORM support
 476
 477 ;;; Emit a funcall of the function and return the handle for the
 478 ;;; result.
 479 (defun fasl-dump-load-time-value-lambda (fun file)
 480   (declare (type sb!c::clambda fun) (type fasl-output file))
 481   (let ((handle (gethash (sb!c::leaf-info fun)
 482                          (fasl-output-entry-table file))))
 483     (aver handle)
 484     (dump-push handle file)
 485     (dump-fop 'fop-funcall file)
 486     (dump-byte 0 file))
 487   (dump-pop file))
 488
 489 ;;; Return T iff CONSTANT has already been dumped. It's been dumped if
 490 ;;; it's in the EQ table.
 491 ;;;
 492 ;;; Note: historically (1) the above comment was "T iff ... has not been dumped",
 493 ;;; (2) the test was  was also true if the constant had been validated / was in
 494 ;;; the valid objects table. This led to substructures occasionally skipping the
 495 ;;; validation, and hence failing the "must have been validated" test.
 496 (defun fasl-constant-already-dumped-p (constant file)
 497   (and (gethash constant (fasl-output-eq-table file)) t))
 498
 499 ;;; Use HANDLE whenever we try to dump CONSTANT. HANDLE should have been
 500 ;;; returned earlier by FASL-DUMP-LOAD-TIME-VALUE-LAMBDA.
 501 (defun fasl-note-handle-for-constant (constant handle file)
 502   (let ((table (fasl-output-eq-table file)))
 503     (when (gethash constant table)
 504       (error "~S already dumped?" constant))
 505     (setf (gethash constant table) handle))
 506   (values))
 507
 508 ;;; Note that the specified structure can just be dumped by
 509 ;;; enumerating the slots.
 510 (defun fasl-validate-structure (structure file)
 511   (setf (gethash structure (fasl-output-valid-structures file)) t)
 512   (values))
 513 \f
 514 ;;;; number dumping
 515
 516 (defun dump-ratio (x file)
 517   (sub-dump-object (numerator x) file)
 518   (sub-dump-object (denominator x) file)
 519   (dump-fop 'fop-ratio file))
 520
 521 (defun dump-integer (n file)
 522   (typecase n
 523     ((signed-byte 8)
 524      (dump-fop 'fop-byte-integer file)
 525      (dump-byte (logand #xFF n) file))
 526     ((unsigned-byte #.(1- sb!vm:n-word-bits))
 527      (dump-fop 'fop-word-integer file)
 528      (dump-word n file))
 529     ((signed-byte #.sb!vm:n-word-bits)
 530      (dump-fop 'fop-word-integer file)
 531      (dump-integer-as-n-bytes n #.sb!vm:n-word-bytes file))
 532     (t
 533      (let ((bytes (ceiling (1+ (integer-length n)) 8)))
 534        (dump-fop* bytes fop-small-integer fop-integer file)
 535        (dump-integer-as-n-bytes n bytes file)))))
 536
 537 (defun dump-float (x file)
 538   (etypecase x
 539     (single-float
 540      (dump-fop 'fop-single-float file)
 541      (dump-integer-as-n-bytes (single-float-bits x) 4 file))
 542     (double-float
 543      (dump-fop 'fop-double-float file)
 544      (let ((x x))
 545        (declare (double-float x))
 546        (dump-integer-as-n-bytes (double-float-low-bits x) 4 file)
 547        (dump-integer-as-n-bytes (double-float-high-bits x) 4 file)))
 548     #!+long-float
 549     (long-float
 550      (dump-fop 'fop-long-float file)
 551      (dump-long-float x file))))
 552
 553 (defun dump-complex-single-float (re im file)
 554   (declare (single-float re im))
 555   (dump-fop 'fop-complex-single-float file)
 556   (dump-integer-as-n-bytes (single-float-bits re) 4 file)
 557   (dump-integer-as-n-bytes (single-float-bits im) 4 file))
 558
 559 (defun dump-complex-double-float (re im file)
 560   (declare (double-float re im))
 561   (dump-fop 'fop-complex-double-float file)
 562   (dump-integer-as-n-bytes (double-float-low-bits re) 4 file)
 563   (dump-integer-as-n-bytes (double-float-high-bits re) 4 file)
 564   (dump-integer-as-n-bytes (double-float-low-bits im) 4 file)
 565   (dump-integer-as-n-bytes (double-float-high-bits im) 4 file))
 566
 567 (defun dump-complex-rational (re im file)
 568   (sub-dump-object re file)
 569   (sub-dump-object im file)
 570   (dump-fop 'fop-complex file))
 571
 572 #+sb-xc-host
 573 (defun dump-complex (x file)
 574   (let ((re (realpart x))
 575         (im (imagpart x)))
 576     (cond ((and (typep re 'single-float)
 577                 (typep im 'single-float))
 578            (dump-complex-single-float re im file))
 579           ((and (typep re 'double-float)
 580                 (typep im 'double-float))
 581            (dump-complex-double-float re im file))
 582           ((and (typep re 'rational)
 583                 (typep im 'rational))
 584            (dump-complex-rational re im file))
 585           (t
 586            (bug "Complex number too complex: ~S" x)))))
 587
 588 #-sb-xc-host
 589 (defun dump-complex (x file)
 590   (typecase x
 591     ((complex single-float)
 592      (dump-complex-single-float (realpart x) (imagpart x) file))
 593     ((complex double-float)
 594      (dump-complex-double-float (realpart x) (imagpart x) file))
 595     #!+long-float
 596     ((complex long-float)
 597      (dump-fop 'fop-complex-long-float file)
 598      (dump-long-float (realpart x) file)
 599      (dump-long-float (imagpart x) file))
 600     (t
 601      (dump-complex-rational (realpart x) (imagpart x) file))))
 602 \f
 603 ;;;; symbol dumping
 604
 605 ;;; Return the table index of PKG, adding the package to the table if
 606 ;;; necessary. During cold load, we read the string as a normal string
 607 ;;; so that we can do the package lookup at cold load time.
 608 ;;;
 609 ;;; FIXME: Despite the parallelism in names, the functionality of
 610 ;;; this function is not parallel to other functions DUMP-FOO, e.g.
 611 ;;; DUMP-SYMBOL and DUMP-LIST. The mapping between names and behavior
 612 ;;; should be made more consistent.
 613 (declaim (ftype (function (package fasl-output) index) dump-package))
 614 (defun dump-package (pkg file)
 615   (declare (inline assoc))
 616   (cond ((cdr (assoc pkg (fasl-output-packages file) :test #'eq)))
 617         (t
 618          (let ((s (package-name pkg)))
 619            (dump-fop* (length s) fop-small-named-package-save fop-named-package-save file)
 620            #+sb-xc-host
 621            (dump-base-chars-of-string (coerce s 'simple-base-string) file)
 622            #-sb-xc-host
 623            (#!+sb-unicode dump-characters-of-string
 624             #!-sb-unicode dump-base-chars-of-string
 625             (coerce s '(simple-array character (*))) file))
 626          (let ((entry (fasl-output-table-free file)))
 627            (incf (fasl-output-table-free file))
 628            (push (cons pkg entry) (fasl-output-packages file))
 629            entry))))
 630 \f
 631 ;;; dumper for lists
 632
 633 ;;; Dump a list, setting up patching information when there are
 634 ;;; circularities. We scan down the list, checking for CDR and CAR
 635 ;;; circularities.
 636 ;;;
 637 ;;; If there is a CDR circularity, we terminate the list with NIL and
 638 ;;; make a CIRCULARITY notation for the CDR of the previous cons.
 639 ;;;
 640 ;;; If there is no CDR circularity, then we mark the current cons and
 641 ;;; check for a CAR circularity. When there is a CAR circularity, we
 642 ;;; make the CAR NIL initially, arranging for the current cons to be
 643 ;;; patched later.
 644 ;;;
 645 ;;; Otherwise, we recursively call the dumper to dump the current
 646 ;;; element.
 647 (defun dump-list (list file)
 648   (aver (and list
 649              (not (gethash list (fasl-output-circularity-table file)))))
 650   (do* ((l list (cdr l))
 651         (n 0 (1+ n))
 652         (circ (fasl-output-circularity-table file)))
 653        ((atom l)
 654         (cond ((null l)
 655                (terminate-undotted-list n file))
 656               (t
 657                (sub-dump-object l file)
 658                (terminate-dotted-list n file))))
 659     (declare (type index n))
 660     (let ((ref (gethash l circ)))
 661       (when ref
 662         (push (make-circularity :type :rplacd
 663                                 :object list
 664                                 :index (1- n)
 665                                 :value l
 666                                 :enclosing-object ref)
 667               *circularities-detected*)
 668         (terminate-undotted-list n file)
 669         (return)))
 670
 671     (setf (gethash l circ) list)
 672
 673     (let* ((obj (car l))
 674            (ref (gethash obj circ)))
 675       (cond (ref
 676              (push (make-circularity :type :rplaca
 677                                      :object list
 678                                      :index n
 679                                      :value obj
 680                                      :enclosing-object ref)
 681                    *circularities-detected*)
 682              (sub-dump-object nil file))
 683             (t
 684              (sub-dump-object obj file))))))
 685
 686 (defun terminate-dotted-list (n file)
 687   (declare (type index n) (type fasl-output file))
 688   (case n
 689     (1 (dump-fop 'fop-list*-1 file))
 690     (2 (dump-fop 'fop-list*-2 file))
 691     (3 (dump-fop 'fop-list*-3 file))
 692     (4 (dump-fop 'fop-list*-4 file))
 693     (5 (dump-fop 'fop-list*-5 file))
 694     (6 (dump-fop 'fop-list*-6 file))
 695     (7 (dump-fop 'fop-list*-7 file))
 696     (8 (dump-fop 'fop-list*-8 file))
 697     (t (do ((nn n (- nn 255)))
 698            ((< nn 256)
 699             (dump-fop 'fop-list* file)
 700             (dump-byte nn file))
 701          (declare (type index nn))
 702          (dump-fop 'fop-list* file)
 703          (dump-byte 255 file)))))
 704
 705 ;;; If N > 255, must build list with one LIST operator, then LIST*
 706 ;;; operators.
 707
 708 (defun terminate-undotted-list (n file)
 709   (declare (type index n) (type fasl-output file))
 710   (case n
 711     (1 (dump-fop 'fop-list-1 file))
 712     (2 (dump-fop 'fop-list-2 file))
 713     (3 (dump-fop 'fop-list-3 file))
 714     (4 (dump-fop 'fop-list-4 file))
 715     (5 (dump-fop 'fop-list-5 file))
 716     (6 (dump-fop 'fop-list-6 file))
 717     (7 (dump-fop 'fop-list-7 file))
 718     (8 (dump-fop 'fop-list-8 file))
 719     (t (cond ((< n 256)
 720               (dump-fop 'fop-list file)
 721               (dump-byte n file))
 722              (t (dump-fop 'fop-list file)
 723                 (dump-byte 255 file)
 724                 (do ((nn (- n 255) (- nn 255)))
 725                     ((< nn 256)
 726                      (dump-fop 'fop-list* file)
 727                      (dump-byte nn file))
 728                   (declare (type index nn))
 729                   (dump-fop 'fop-list* file)
 730                   (dump-byte 255 file)))))))
 731 \f
 732 ;;;; array dumping
 733
 734 ;;; Dump the array thing.
 735 (defun dump-array (x file)
 736   (if (vectorp x)
 737       (dump-vector x file)
 738       (dump-multi-dim-array x file)))
 739
 740 ;;; Dump the vector object. If it's not simple, then actually dump a
 741 ;;; simple version of it. But we enter the original in the EQ or EQUAL
 742 ;;; tables.
 743 (defun dump-vector (x file)
 744   (let ((simple-version (if (array-header-p x)
 745                             (coerce x `(simple-array
 746                                         ,(array-element-type x)
 747                                         (*)))
 748                             x)))
 749     (typecase simple-version
 750       #+sb-xc-host
 751       (simple-string
 752        (unless (string-check-table x file)
 753          (dump-simple-base-string simple-version file)
 754          (string-save-object x file)))
 755       #-sb-xc-host
 756       (simple-base-string
 757        (unless (string-check-table x file)
 758          (dump-simple-base-string simple-version file)
 759          (string-save-object x file)))
 760       #-sb-xc-host
 761       ((simple-array character (*))
 762        #!+sb-unicode
 763        (unless (string-check-table x file)
 764          (dump-simple-character-string simple-version file)
 765          (string-save-object x file))
 766        #!-sb-unicode
 767        (bug "how did we get here?"))
 768       (simple-vector
 769        (dump-simple-vector simple-version file)
 770        (eq-save-object x file))
 771       ((simple-array single-float (*))
 772        (dump-single-float-vector simple-version file)
 773        (eq-save-object x file))
 774       ((simple-array double-float (*))
 775        (dump-double-float-vector simple-version file)
 776        (eq-save-object x file))
 777       #!+long-float
 778       ((simple-array long-float (*))
 779        (dump-long-float-vector simple-version file)
 780        (eq-save-object x file))
 781       ((simple-array (complex single-float) (*))
 782        (dump-complex-single-float-vector simple-version file)
 783        (eq-save-object x file))
 784       ((simple-array (complex double-float) (*))
 785        (dump-complex-double-float-vector simple-version file)
 786        (eq-save-object x file))
 787       #!+long-float
 788       ((simple-array (complex long-float) (*))
 789        (dump-complex-long-float-vector simple-version file)
 790        (eq-save-object x file))
 791       (t
 792        (dump-i-vector simple-version file)
 793        (eq-save-object x file)))))
 794
 795 ;;; Dump a SIMPLE-VECTOR, handling any circularities.
 796 (defun dump-simple-vector (v file)
 797   (declare (type simple-vector v) (type fasl-output file))
 798   (note-potential-circularity v file)
 799   (do ((index 0 (1+ index))
 800        (length (length v))
 801        (circ (fasl-output-circularity-table file)))
 802       ((= index length)
 803        (dump-fop* length fop-small-vector fop-vector file))
 804     (let* ((obj (aref v index))
 805            (ref (gethash obj circ)))
 806       (cond (ref
 807              (push (make-circularity :type :svset
 808                                      :object v
 809                                      :index index
 810                                      :value obj
 811                                      :enclosing-object ref)
 812                    *circularities-detected*)
 813              (sub-dump-object nil file))
 814             (t
 815              (sub-dump-object obj file))))))
 816
 817 ;;; In the grand scheme of things I don't pretend to understand any
 818 ;;; more how this works, or indeed whether.  But to write out specialized
 819 ;;; vectors in the same format as fop-int-vector expects to read them
 820 ;;; we need to be target-endian.  dump-integer-as-n-bytes always writes
 821 ;;; little-endian (which is correct for all other integers) so for a bigendian
 822 ;;; target we need to swap octets -- CSR, after DB
 823
 824 (defun octet-swap (word bits)
 825   "BITS must be a multiple of 8"
 826   (do ((input word (ash input -8))
 827        (output 0 (logior (ash output 8) (logand input #xff)))
 828        (bits bits (- bits 8)))
 829       ((<= bits 0) output)))
 830
 831 (defun dump-i-vector (vec file &key data-only)
 832   (declare (type (simple-array * (*)) vec))
 833   (let ((len (length vec)))
 834     (labels ((dump-unsigned-vector (size bytes)
 835                (unless data-only
 836                  (dump-fop 'fop-int-vector file)
 837                  (dump-word len file)
 838                  (dump-byte size file))
 839                ;; The case which is easy to handle in a portable way is when
 840                ;; the element size is a multiple of the output byte size, and
 841                ;; happily that's the only case we need to be portable. (The
 842                ;; cross-compiler has to output debug information (including
 843                ;; (SIMPLE-ARRAY (UNSIGNED-BYTE 8) *).) The other cases are only
 844                ;; needed in the target SBCL, so we let them be handled with
 845                ;; unportable bit bashing.
 846                (cond ((>= size 7) ; easy cases
 847                       (multiple-value-bind (floor rem) (floor size 8)
 848                         (aver (or (zerop rem) (= rem 7)))
 849                         (when (= rem 7)
 850                           (setq size (1+ size))
 851                           (setq floor (1+ floor)))
 852                         (dovector (i vec)
 853                           (dump-integer-as-n-bytes
 854                            (ecase sb!c:*backend-byte-order*
 855                              (:little-endian i)
 856                              (:big-endian (octet-swap i size)))
 857                            floor file))))
 858                      (t ; harder cases, not supported in cross-compiler
 859                       (dump-raw-bytes vec bytes file))))
 860              (dump-signed-vector (size bytes)
 861                ;; Note: Dumping specialized signed vectors isn't
 862                ;; supported in the cross-compiler. (All cases here end
 863                ;; up trying to call DUMP-RAW-BYTES, which isn't
 864                ;; provided in the cross-compilation host, only on the
 865                ;; target machine.)
 866                (unless data-only
 867                  (dump-fop 'fop-signed-int-vector file)
 868                  (dump-word len file)
 869                  (dump-byte size file))
 870                (dump-raw-bytes vec bytes file)))
 871       (etypecase vec
 872         #-sb-xc-host
 873         ((simple-array nil (*))
 874          (dump-unsigned-vector 0 0))
 875         (simple-bit-vector
 876          (dump-unsigned-vector 1 (ceiling len 8))) ; bits to bytes
 877         ;; KLUDGE: This isn't the best way of expressing that the host
 878         ;; may not have specializations for (unsigned-byte 2) and
 879         ;; (unsigned-byte 4), which means that these types are
 880         ;; type-equivalent to (simple-array (unsigned-byte 8) (*));
 881         ;; the workaround is to remove them from the etypecase, since
 882         ;; they can't be dumped from the cross-compiler anyway. --
 883         ;; CSR, 2002-05-07
 884         #-sb-xc-host
 885         ((simple-array (unsigned-byte 2) (*))
 886          (dump-unsigned-vector 2 (ceiling (ash len 1) 8))) ; bits to bytes
 887         #-sb-xc-host
 888         ((simple-array (unsigned-byte 4) (*))
 889          (dump-unsigned-vector 4 (ceiling (ash len 2) 8))) ; bits to bytes
 890         #-sb-xc-host
 891         ((simple-array (unsigned-byte 7) (*))
 892          (dump-unsigned-vector 7 len))
 893         ((simple-array (unsigned-byte 8) (*))
 894          (dump-unsigned-vector 8 len))
 895         #-sb-xc-host
 896         ((simple-array (unsigned-byte 15) (*))
 897          (dump-unsigned-vector 15 (* 2 len)))
 898         ((simple-array (unsigned-byte 16) (*))
 899          (dump-unsigned-vector 16 (* 2 len)))
 900         #-sb-xc-host
 901         ((simple-array (unsigned-byte 31) (*))
 902          (dump-unsigned-vector 31 (* 4 len)))
 903         ((simple-array (unsigned-byte 32) (*))
 904          (dump-unsigned-vector 32 (* 4 len)))
 905         #-sb-xc-host
 906         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 907         ((simple-array (unsigned-byte 63) (*))
 908          (dump-unsigned-vector 63 (* 8 len)))
 909         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 910         ((simple-array (unsigned-byte 64) (*))
 911          (dump-unsigned-vector 64 (* 8 len)))
 912         ((simple-array (signed-byte 8) (*))
 913          (dump-signed-vector 8 len))
 914         ((simple-array (signed-byte 16) (*))
 915          (dump-signed-vector 16 (* 2 len)))
 916         #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 917         ((simple-array (unsigned-byte 29) (*))
 918          (dump-signed-vector 29 (* 4 len)))
 919         #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 920         ((simple-array (signed-byte 30) (*))
 921          (dump-signed-vector 30 (* 4 len)))
 922         ((simple-array (signed-byte 32) (*))
 923          (dump-signed-vector 32 (* 4 len)))
 924         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 925         ((simple-array (unsigned-byte 60) (*))
 926          (dump-signed-vector 60 (* 8 len)))
 927         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 928         ((simple-array (signed-byte 61) (*))
 929          (dump-signed-vector 61 (* 8 len)))
 930         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 931         ((simple-array (signed-byte 64) (*))
 932          (dump-signed-vector 64 (* 8 len)))))))
 933 \f
 934 ;;; Dump characters and string-ish things.
 935
 936 (defun dump-character (char file)
 937   (let ((code (sb!xc:char-code char)))
 938     (cond
 939       ((< code 256)
 940        (dump-fop 'fop-short-character file)
 941        (dump-byte code file))
 942       (t
 943        (dump-fop 'fop-character file)
 944        (dump-word code file)))))
 945
 946 (defun dump-base-chars-of-string (s fasl-output)
 947   (declare #+sb-xc-host (type simple-string s)
 948            #-sb-xc-host (type simple-base-string s)
 949            (type fasl-output fasl-output))
 950   (dovector (c s)
 951     (dump-byte (sb!xc:char-code c) fasl-output))
 952   (values))
 953
 954
 955 ;;; Dump a SIMPLE-BASE-STRING.
 956 (defun dump-simple-base-string (s file)
 957   #+sb-xc-host (declare (type simple-string s))
 958   #-sb-xc-host (declare (type simple-base-string s))
 959   (dump-fop* (length s) fop-small-base-string fop-base-string file)
 960   (dump-base-chars-of-string s file)
 961   (values))
 962
 963 ;;; If we get here, it is assumed that the symbol isn't in the table,
 964 ;;; but we are responsible for putting it there when appropriate.
 965 (defun dump-symbol (s file)
 966   (declare (type fasl-output file))
 967   (let* ((pname (symbol-name s))
 968          (pname-length (length pname))
 969          (pkg (symbol-package s)))
 970     ;; see comment in genesis: we need this here for repeatable fasls
 971     #+sb-xc-host
 972     (multiple-value-bind (cl-symbol cl-status)
 973         (find-symbol (symbol-name s) sb!int:*cl-package*)
 974       (when (and (eq s cl-symbol)
 975                  (eq cl-status :external))
 976         ;; special case, to work around possible xc host "design
 977         ;; choice" weirdness in COMMON-LISP package
 978         (setq pkg sb!int:*cl-package*)))
 979
 980     (cond ((null pkg)
 981            (dump-fop* pname-length
 982                       fop-uninterned-small-symbol-save
 983                       fop-uninterned-symbol-save
 984                       file))
 985           ;; CMU CL had FOP-SYMBOL-SAVE/FOP-SMALL-SYMBOL-SAVE fops which
 986           ;; used the current value of *PACKAGE*. Unfortunately that's
 987           ;; broken w.r.t. ANSI Common Lisp semantics, so those are gone
 988           ;; from SBCL.
 989           ;;((eq pkg *package*)
 990           ;; (dump-fop* pname-length
 991           ;;        fop-small-symbol-save
 992           ;;        fop-symbol-save file))
 993           ((eq pkg sb!int:*cl-package*)
 994            (dump-fop* pname-length
 995                       fop-lisp-small-symbol-save
 996                       fop-lisp-symbol-save
 997                       file))
 998           ((eq pkg sb!int:*keyword-package*)
 999            (dump-fop* pname-length
1000                       fop-keyword-small-symbol-save
1001                       fop-keyword-symbol-save
1002                       file))
1003           ((< pname-length 256)
1004            (dump-fop* (dump-package pkg file)
1005                       fop-small-symbol-in-byte-package-save
1006                       fop-small-symbol-in-package-save
1007                       file)
1008            (dump-byte pname-length file))
1009           (t
1010            (dump-fop* (dump-package pkg file)
1011                       fop-symbol-in-byte-package-save
1012                       fop-symbol-in-package-save
1013                       file)
1014            (dump-word pname-length file)))
1015
1016     #+sb-xc-host (dump-base-chars-of-string pname file)
1017     #-sb-xc-host (#!+sb-unicode dump-characters-of-string
1018                   #!-sb-unicode dump-base-chars-of-string
1019                   pname file)
1020
1021     (setf (gethash s (fasl-output-eq-table file))
1022           (fasl-output-table-free file))
1023
1024     (incf (fasl-output-table-free file)))
1025
1026   (values))
1027 \f
1028 ;;;; component (function) dumping
1029
1030 (defun dump-segment (segment code-length fasl-output)
1031   (declare (type sb!assem:segment segment)
1032            (type fasl-output fasl-output))
1033   (let* ((stream (fasl-output-stream fasl-output))
1034          (n-written (write-segment-contents segment stream)))
1035     ;; In CMU CL there was no enforced connection between the CODE-LENGTH
1036     ;; argument and the number of bytes actually written. I added this
1037     ;; assertion while trying to debug portable genesis. -- WHN 19990902
1038     (unless (= code-length n-written)
1039       (bug "code-length=~W, n-written=~W" code-length n-written)))
1040   (values))
1041
1042 ;;; Dump all the fixups. Currently there are three flavors of fixup:
1043 ;;;  - assembly routines: named by a symbol
1044 ;;;  - foreign (C) symbols: named by a string
1045 ;;;  - code object references: don't need a name.
1046 (defun dump-fixups (fixups fasl-output)
1047   (declare (list fixups) (type fasl-output fasl-output))
1048   (dolist (note fixups)
1049     (let* ((kind (fixup-note-kind note))
1050            (fixup (fixup-note-fixup note))
1051            (position (fixup-note-position note))
1052            (name (fixup-name fixup))
1053            (flavor (fixup-flavor fixup)))
1054       (dump-object kind fasl-output)
1055       ;; Depending on the flavor, we may have various kinds of
1056       ;; noise before the position.
1057       (ecase flavor
1058         (:assembly-routine
1059          (aver (symbolp name))
1060          (dump-object name fasl-output)
1061          (dump-fop 'fop-assembler-fixup fasl-output))
1062         ((:foreign :foreign-dataref)
1063          (aver (stringp name))
1064          (ecase flavor
1065            (:foreign
1066             (dump-fop 'fop-foreign-fixup fasl-output))
1067            #!+linkage-table
1068            (:foreign-dataref
1069             (dump-fop 'fop-foreign-dataref-fixup fasl-output)))
1070          (let ((len (length name)))
1071            (aver (< len 256)) ; (limit imposed by fop definition)
1072            (dump-byte len fasl-output)
1073            (dotimes (i len)
1074              (dump-byte (char-code (schar name i)) fasl-output))))
1075         (:code-object
1076          (aver (null name))
1077          (dump-fop 'fop-code-object-fixup fasl-output)))
1078       ;; No matter what the flavor, we'll always dump the position
1079       (dump-word position fasl-output)))
1080   (values))
1081
1082 ;;; Dump out the constant pool and code-vector for component, push the
1083 ;;; result in the table, and return the offset.
1084 ;;;
1085 ;;; The only tricky thing is handling constant-pool references to
1086 ;;; functions. If we have already dumped the function, then we just
1087 ;;; push the code pointer. Otherwise, we must create back-patching
1088 ;;; information so that the constant will be set when the function is
1089 ;;; eventually dumped. This is a bit awkward, since we don't have the
1090 ;;; handle for the code object being dumped while we are dumping its
1091 ;;; constants.
1092 ;;;
1093 ;;; We dump trap objects in any unused slots or forward referenced slots.
1094 (defun dump-code-object (component
1095                          code-segment
1096                          code-length
1097                          trace-table-as-list
1098                          fixups
1099                          fasl-output)
1100
1101   (declare (type component component)
1102            (list trace-table-as-list)
1103            (type index code-length)
1104            (type fasl-output fasl-output))
1105
1106   (let* ((2comp (component-info component))
1107          (constants (sb!c::ir2-component-constants 2comp))
1108          (header-length (length constants))
1109          (packed-trace-table (pack-trace-table trace-table-as-list))
1110          (total-length (+ code-length
1111                           (* (length packed-trace-table)
1112                              sb!c::tt-bytes-per-entry))))
1113
1114     (collect ((patches))
1115
1116       ;; Dump the offset of the trace table.
1117       (dump-object code-length fasl-output)
1118       ;; FIXME: As long as we don't have GENGC, the trace table is
1119       ;; hardwired to be empty. And SBCL doesn't have GENGC (and as
1120       ;; far as I know no modern CMU CL does either -- WHN
1121       ;; 2001-10-05). So might we be able to get rid of trace tables?
1122       ;;
1123       ;; Note that gencgc also does something with the trace table.
1124
1125       ;; Dump the constants, noting any :ENTRY constants that have to
1126       ;; be patched.
1127       (loop for i from sb!vm:code-constants-offset below header-length do
1128         (let ((entry (aref constants i)))
1129           (etypecase entry
1130             (constant
1131              (dump-object (sb!c::constant-value entry) fasl-output))
1132             (cons
1133              (ecase (car entry)
1134                (:entry
1135                 (let* ((info (sb!c::leaf-info (cdr entry)))
1136                        (handle (gethash info
1137                                         (fasl-output-entry-table
1138                                          fasl-output))))
1139                   (declare (type sb!c::entry-info info))
1140                   (cond
1141                    (handle
1142                     (dump-push handle fasl-output))
1143                    (t
1144                     (patches (cons info i))
1145                     (dump-fop 'fop-misc-trap fasl-output)))))
1146                (:load-time-value
1147                 (dump-push (cdr entry) fasl-output))
1148                (:fdefinition
1149                 (dump-object (cdr entry) fasl-output)
1150                 (dump-fop 'fop-fdefinition fasl-output))))
1151             (null
1152              (dump-fop 'fop-misc-trap fasl-output)))))
1153
1154       ;; Dump the debug info.
1155       (let ((info (sb!c::debug-info-for-component component))
1156             (*dump-only-valid-structures* nil))
1157         (dump-object info fasl-output)
1158         (let ((info-handle (dump-pop fasl-output)))
1159           (dump-push info-handle fasl-output)
1160           (push info-handle (fasl-output-debug-info fasl-output))))
1161
1162       (let ((num-consts (- header-length sb!vm:code-trace-table-offset-slot)))
1163         (cond ((and (< num-consts #x100) (< total-length #x10000))
1164                (dump-fop 'fop-small-code fasl-output)
1165                (dump-byte num-consts fasl-output)
1166                (dump-integer-as-n-bytes total-length (/ sb!vm:n-word-bytes 2) fasl-output))
1167               (t
1168                (dump-fop 'fop-code fasl-output)
1169                (dump-word num-consts fasl-output)
1170                (dump-word total-length fasl-output))))
1171
1172       ;; These two dumps are only ones which contribute to our
1173       ;; TOTAL-LENGTH value.
1174       (dump-segment code-segment code-length fasl-output)
1175       (dump-i-vector packed-trace-table fasl-output :data-only t)
1176
1177       ;; DUMP-FIXUPS does its own internal DUMP-FOPs: the bytes it
1178       ;; dumps aren't included in the TOTAL-LENGTH passed to our
1179       ;; FOP-CODE/FOP-SMALL-CODE fop.
1180       (dump-fixups fixups fasl-output)
1181
1182       (dump-fop 'fop-sanctify-for-execution fasl-output)
1183
1184       (let ((handle (dump-pop fasl-output)))
1185         (dolist (patch (patches))
1186           (push (cons handle (cdr patch))
1187                 (gethash (car patch)
1188                          (fasl-output-patch-table fasl-output))))
1189         handle))))
1190
1191 (defun dump-assembler-routines (code-segment length fixups routines file)
1192   (dump-fop 'fop-assembler-code file)
1193   (dump-word length file)
1194   (write-segment-contents code-segment (fasl-output-stream file))
1195   (dolist (routine routines)
1196     (dump-object (car routine) file)
1197     (dump-fop 'fop-assembler-routine file)
1198     (dump-word (label-position (cdr routine)) file))
1199   (dump-fixups fixups file)
1200   (dump-fop 'fop-sanctify-for-execution file)
1201   (dump-pop file))
1202
1203 ;;; Dump a function entry data structure corresponding to ENTRY to
1204 ;;; FILE. CODE-HANDLE is the table offset of the code object for the
1205 ;;; component.
1206 (defun dump-one-entry (entry code-handle file)
1207   (declare (type sb!c::entry-info entry) (type index code-handle)
1208            (type fasl-output file))
1209   (let ((name (sb!c::entry-info-name entry)))
1210     (dump-push code-handle file)
1211     (dump-object name file)
1212     (dump-object (sb!c::entry-info-arguments entry) file)
1213     (dump-object (sb!c::entry-info-type entry) file)
1214     (dump-object (sb!c::entry-info-info entry) file)
1215     (dump-fop 'fop-fun-entry file)
1216     (dump-word (label-position (sb!c::entry-info-offset entry)) file)
1217     (dump-pop file)))
1218
1219 ;;; Alter the code object referenced by CODE-HANDLE at the specified
1220 ;;; OFFSET, storing the object referenced by ENTRY-HANDLE.
1221 (defun dump-alter-code-object (code-handle offset entry-handle file)
1222   (declare (type index code-handle entry-handle offset))
1223   (declare (type fasl-output file))
1224   (dump-push code-handle file)
1225   (dump-push entry-handle file)
1226   (dump-fop* offset fop-byte-alter-code fop-alter-code file)
1227   (values))
1228
1229 ;;; Dump the code, constants, etc. for component. We pass in the
1230 ;;; assembler fixups, code vector and node info.
1231 (defun fasl-dump-component (component
1232                             code-segment
1233                             code-length
1234                             trace-table
1235                             fixups
1236                             file)
1237   (declare (type component component) (list trace-table))
1238   (declare (type fasl-output file))
1239
1240   (dump-fop 'fop-verify-table-size file)
1241   (dump-word (fasl-output-table-free file) file)
1242
1243   #!+sb-dyncount
1244   (let ((info (sb!c::ir2-component-dyncount-info (component-info component))))
1245     (when info
1246       (fasl-validate-structure info file)))
1247
1248   (let ((code-handle (dump-code-object component
1249                                        code-segment
1250                                        code-length
1251                                        trace-table
1252                                        fixups
1253                                        file))
1254         (2comp (component-info component)))
1255
1256     (dolist (entry (sb!c::ir2-component-entries 2comp))
1257       (let ((entry-handle (dump-one-entry entry code-handle file)))
1258         (setf (gethash entry (fasl-output-entry-table file)) entry-handle)
1259         (let ((old (gethash entry (fasl-output-patch-table file))))
1260           (when old
1261             (dolist (patch old)
1262               (dump-alter-code-object (car patch)
1263                                       (cdr patch)
1264                                       entry-handle
1265                                       file))
1266             (remhash entry (fasl-output-patch-table file)))))))
1267   (values))
1268
1269 (defun dump-push-previously-dumped-fun (fun fasl-output)
1270   (declare (type sb!c::clambda fun))
1271   (let ((handle (gethash (sb!c::leaf-info fun)
1272                          (fasl-output-entry-table fasl-output))))
1273     (aver handle)
1274     (dump-push handle fasl-output))
1275   (values))
1276
1277 ;;; Dump a FOP-FUNCALL to call an already-dumped top level lambda at
1278 ;;; load time.
1279 (defun fasl-dump-toplevel-lambda-call (fun fasl-output)
1280   (declare (type sb!c::clambda fun))
1281   (dump-push-previously-dumped-fun fun fasl-output)
1282   (dump-fop 'fop-funcall-for-effect fasl-output)
1283   (dump-byte 0 fasl-output)
1284   (values))
1285
1286 ;;; Dump a FOP-FSET to arrange static linkage (at cold init) between
1287 ;;; FUN-NAME and the already-dumped function whose dump handle is
1288 ;;; FUN-DUMP-HANDLE.
1289 #+sb-xc-host
1290 (defun fasl-dump-cold-fset (fun-name fun-dump-handle fasl-output)
1291   (declare (type fixnum fun-dump-handle))
1292   (aver (legal-fun-name-p fun-name))
1293   (dump-non-immediate-object fun-name fasl-output)
1294   (dump-push fun-dump-handle fasl-output)
1295   (dump-fop 'fop-fset fasl-output)
1296   (values))
1297
1298 ;;; Compute the correct list of DEBUG-SOURCE structures and backpatch
1299 ;;; all of the dumped DEBUG-INFO structures. We clear the
1300 ;;; FASL-OUTPUT-DEBUG-INFO, so that subsequent components with
1301 ;;; different source info may be dumped.
1302 (defun fasl-dump-source-info (info fasl-output)
1303   (declare (type sb!c::source-info info))
1304   (let ((res (sb!c::debug-source-for-info info))
1305         (*dump-only-valid-structures* nil))
1306     #+sb-xc-host (setf (sb!c::debug-source-created res) 0
1307                        (sb!c::debug-source-compiled res) 0)
1308     (dump-object res fasl-output)
1309     (let ((res-handle (dump-pop fasl-output)))
1310       (dolist (info-handle (fasl-output-debug-info fasl-output))
1311         (dump-push res-handle fasl-output)
1312         (dump-fop 'fop-structset fasl-output)
1313         (dump-word info-handle fasl-output)
1314         (dump-word sb!c::+debug-info-source-index+ fasl-output))
1315       #+sb-xc-host
1316       (progn
1317         (dump-push res-handle fasl-output)
1318         (dump-fop 'fop-note-debug-source fasl-output))))
1319   (setf (fasl-output-debug-info fasl-output) nil)
1320   (values))
1321 \f
1322 ;;;; dumping structures
1323
1324 (defun dump-structure (struct file)
1325   (when *dump-only-valid-structures*
1326     (unless (gethash struct (fasl-output-valid-structures file))
1327       (error "attempt to dump invalid structure:~%  ~S~%How did this happen?"
1328              struct)))
1329   (note-potential-circularity struct file)
1330   (aver (%instance-ref struct 0))
1331   (do* ((length (%instance-length struct))
1332         (ntagged (- length (layout-n-untagged-slots (%instance-ref struct 0))))
1333         (circ (fasl-output-circularity-table file))
1334         ;; last slot first on the stack, so that the layout is on top:
1335         (index (1- length) (1- index)))
1336       ((minusp index)
1337        (dump-fop* length fop-small-struct fop-struct file))
1338     (let* ((obj (if (>= index ntagged)
1339                     (%raw-instance-ref/word struct (- length index 1))
1340                     (%instance-ref struct index)))
1341            (ref (gethash obj circ)))
1342       (cond (ref
1343              (aver (not (zerop index)))
1344              (push (make-circularity :type :struct-set
1345                                      :object struct
1346                                      :index index
1347                                      :value obj
1348                                      :enclosing-object ref)
1349                    *circularities-detected*)
1350              (sub-dump-object nil file))
1351             (t
1352              (sub-dump-object obj file))))))
1353
1354 (defun dump-layout (obj file)
1355   (when (layout-invalid obj)
1356     (compiler-error "attempt to dump reference to obsolete class: ~S"
1357                     (layout-classoid obj)))
1358   (let ((name (classoid-name (layout-classoid obj))))
1359     (unless name
1360       (compiler-error "dumping anonymous layout: ~S" obj))
1361     (dump-object name file))
1362   (sub-dump-object (layout-inherits obj) file)
1363   (sub-dump-object (layout-depthoid obj) file)
1364   (sub-dump-object (layout-length obj) file)
1365   (sub-dump-object (layout-n-untagged-slots obj) file)
1366   (dump-fop 'fop-layout file))