src/compiler/early-c.lisp

   1 ;;;; This file contains compiler code and compiler-related stuff which
   2 ;;;; can be built early on. Some of the stuff may be here because it's
   3 ;;;; needed early on, some other stuff (e.g. constants) just because
   4 ;;;; it might as well be done early so we don't have to think about
   5 ;;;; whether it's done early enough.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!C")
  17
  18 ;;; ANSI limits on compilation
  19 (def!constant sb!xc:call-arguments-limit sb!xc:most-positive-fixnum
  20   #!+sb-doc
  21   "The exclusive upper bound on the number of arguments which may be passed
  22   to a function, including &REST args.")
  23 (def!constant sb!xc:lambda-parameters-limit sb!xc:most-positive-fixnum
  24   #!+sb-doc
  25   "The exclusive upper bound on the number of parameters which may be specifed
  26   in a given lambda list. This is actually the limit on required and &OPTIONAL
  27   parameters. With &KEY and &AUX you can get more.")
  28 (def!constant sb!xc:multiple-values-limit sb!xc:most-positive-fixnum
  29   #!+sb-doc
  30   "The exclusive upper bound on the number of multiple VALUES that you can
  31   return.")
  32 \f
  33 ;;;; cross-compiler-only versions of CL special variables, so that we
  34 ;;;; don't have weird interactions with the host compiler
  35
  36 (defvar sb!xc:*compile-file-pathname*)
  37 (defvar sb!xc:*compile-file-truename*)
  38 (defvar sb!xc:*compile-print*)
  39 (defvar sb!xc:*compile-verbose*)
  40 \f
  41 ;;;; miscellaneous types used both in the cross-compiler and on the target
  42
  43 ;;;; FIXME: The INDEX and LAYOUT-DEPTHOID definitions probably belong
  44 ;;;; somewhere else, not "early-c", since they're after all not part
  45 ;;;; of the compiler.
  46
  47 ;;; the type of LAYOUT-DEPTHOID slot values
  48 (def!type sb!kernel::layout-depthoid () '(or index (integer -1 -1)))
  49 \f
  50 ;;; possible values for the INLINE-ness of a function.
  51 (deftype inlinep ()
  52   '(member :inline :maybe-inline :notinline nil))
  53 (defparameter *inlinep-translations*
  54   '((inline . :inline)
  55     (notinline . :notinline)
  56     (maybe-inline . :maybe-inline)))
  57
  58 ;;; the lexical environment we are currently converting in
  59 (defvar *lexenv*)
  60 (declaim (type lexenv *lexenv*))
  61
  62 ;;; *FREE-VARS* translates from the names of variables referenced
  63 ;;; globally to the LEAF structures for them. *FREE-FUNS* is like
  64 ;;; *FREE-VARS*, only it deals with function names.
  65 (defvar *free-vars*)
  66 (defvar *free-funs*)
  67 (declaim (type hash-table *free-vars* *free-funs*))
  68
  69 ;;; We use the same CONSTANT structure to represent all equal anonymous
  70 ;;; constants. This hashtable translates from constants to the LEAFs that
  71 ;;; represent them.
  72 (defvar *constants*)
  73 (declaim (type hash-table *constants*))
  74
  75 ;;; *ALLOW-INSTRUMENTING* controls whether we should allow the
  76 ;;; insertion of instrumenting code (like a (CATCH ...)) around code
  77 ;;; to allow the debugger RETURN and STEP commands to function (we
  78 ;;; disallow it for internal stuff).
  79 (defvar *allow-instrumenting*)
  80
  81 ;;; miscellaneous forward declarations
  82 (defvar *code-segment*)
  83 #!+sb-dyncount (defvar *collect-dynamic-statistics*)
  84 (defvar *component-being-compiled*)
  85 (defvar *compiler-error-context*)
  86 (defvar *compiler-error-count*)
  87 (defvar *compiler-warning-count*)
  88 (defvar *compiler-style-warning-count*)
  89 (defvar *compiler-note-count*)
  90 (defvar *compiler-trace-output*)
  91 (defvar *constraint-universe*)
  92 (defvar *count-vop-usages*)
  93 (defvar *current-path*)
  94 (defvar *current-component*)
  95 (defvar *delayed-ir1-transforms*)
  96 (defvar *handled-conditions*)
  97 (defvar *disabled-package-locks*)
  98 (defvar *policy*)
  99 (defvar *dynamic-counts-tn*)
 100 (defvar *elsewhere*)
 101 (defvar *event-info*)
 102 (defvar *event-note-threshold*)
 103 (defvar *failure-p*)
 104 (defvar *fixup-notes*)
 105 (defvar *in-pack*)
 106 (defvar *info-environment*)
 107 (defvar *lexenv*)
 108 (defvar *source-info*)
 109 (defvar *trace-table*)
 110 (defvar *undefined-warnings*)
 111 (defvar *warnings-p*)
 112 (defvar *lambda-conversions*)
 113
 114 (defvar *stack-allocate-dynamic-extent* t
 115   "If true (the default), the compiler respects DYNAMIC-EXTENT declarations
 116 and stack allocates otherwise inaccessible parts of the object whenever
 117 possible. Potentially long (over one page in size) vectors are, however, not
 118 stack allocated except in zero SAFETY code, as such a vector could overflow
 119 the stack without triggering overflow protection.")
 120
 121 (!begin-collecting-cold-init-forms)
 122 ;;; This lock is seized in the compiler, and related areas -- like the
 123 ;;; classoid/layout/class system.
 124 (defvar *world-lock*)
 125 (!cold-init-forms
 126  (setf *world-lock* (sb!thread:make-mutex :name "World Lock")))
 127 (!defun-from-collected-cold-init-forms !world-lock-cold-init)
 128
 129 (defmacro with-world-lock (() &body body)
 130   `(sb!thread:with-recursive-lock (*world-lock*)
 131      ,@body))
 132
 133 (declaim (type fixnum *compiler-sset-counter*))
 134 (defvar *compiler-sset-counter* 0)
 135
 136 ;;; unique ID for the next object created (to let us track object
 137 ;;; identity even across GC, useful for understanding weird compiler
 138 ;;; bugs where something is supposed to be unique but is instead
 139 ;;; exists as duplicate objects)
 140 #!+sb-show
 141 (progn
 142   (defvar *object-id-counter* 0)
 143   (defun new-object-id ()
 144     (prog1
 145         *object-id-counter*
 146       (incf *object-id-counter*))))
 147 \f
 148 ;;;; miscellaneous utilities
 149
 150 ;;; Delete any undefined warnings for NAME and KIND. This is for the
 151 ;;; benefit of the compiler, but it's sometimes called from stuff like
 152 ;;; type-defining code which isn't logically part of the compiler.
 153 (declaim (ftype (function ((or symbol cons) keyword) (values))
 154                 note-name-defined))
 155 (defun note-name-defined (name kind)
 156   ;; We do this BOUNDP check because this function can be called when
 157   ;; not in a compilation unit (as when loading top level forms).
 158   (when (boundp '*undefined-warnings*)
 159     (setq *undefined-warnings*
 160           (delete-if (lambda (x)
 161                        (and (equal (undefined-warning-name x) name)
 162                             (eq (undefined-warning-kind x) kind)))
 163                      *undefined-warnings*)))
 164   (values))
 165
 166 ;;; to be called when a variable is lexically bound
 167 (declaim (ftype (function (symbol) (values)) note-lexical-binding))
 168 (defun note-lexical-binding (symbol)
 169     ;; This check is intended to protect us from getting silently
 170     ;; burned when we define
 171     ;;   foo.lisp:
 172     ;;     (DEFVAR *FOO* -3)
 173     ;;     (DEFUN FOO (X) (+ X *FOO*))
 174     ;;   bar.lisp:
 175     ;;     (DEFUN BAR (X)
 176     ;;       (LET ((*FOO* X))
 177     ;;         (FOO 14)))
 178     ;; and then we happen to compile bar.lisp before foo.lisp.
 179   (when (looks-like-name-of-special-var-p symbol)
 180     ;; FIXME: should be COMPILER-STYLE-WARNING?
 181     (style-warn 'sb!kernel:asterisks-around-lexical-variable-name
 182                 :format-control
 183                 "using the lexical binding of the symbol ~S, not the~@
 184                  dynamic binding"
 185                 :format-arguments (list symbol)))
 186   (values))
 187
 188 (def!struct (debug-name-marker (:make-load-form-fun dump-debug-name-marker)
 189                                (:print-function print-debug-name-marker)))
 190
 191 (defvar *debug-name-level* 4)
 192 (defvar *debug-name-length* 12)
 193 (defvar *debug-name-punt*)
 194 (defvar *debug-name-sharp*)
 195 (defvar *debug-name-ellipsis*)
 196
 197 (eval-when (:compile-toplevel :load-toplevel :execute)
 198   (defun dump-debug-name-marker (marker &optional env)
 199     (declare (ignore env))
 200     (cond ((eq marker *debug-name-sharp*)
 201            `(if (boundp '*debug-name-sharp*)
 202                 *debug-name-sharp*
 203                 (make-debug-name-marker)))
 204           ((eq marker *debug-name-ellipsis*)
 205            `(if (boundp '*debug-name-ellipsis*)
 206                 *debug-name-ellipsis*
 207                 (make-debug-name-marker)))
 208           (t
 209            (warn "Dumping unknown debug-name marker.")
 210            '(make-debug-name-marker)))))
 211
 212 (defun print-debug-name-marker (marker stream level)
 213   (declare (ignore level))
 214   (cond ((eq marker *debug-name-sharp*)
 215          (write-char #\# stream))
 216         ((eq marker *debug-name-ellipsis*)
 217          (write-string "..." stream))
 218         (t
 219          (write-string "???" stream))))
 220
 221 (setf *debug-name-sharp* (make-debug-name-marker)
 222       *debug-name-ellipsis* (make-debug-name-marker))
 223
 224 (defun debug-name (type thing)
 225   (let ((*debug-name-punt* nil))
 226     (labels ((walk (x)
 227                (typecase x
 228                  (cons
 229                   (if (plusp *debug-name-level*)
 230                       (let ((*debug-name-level* (1- *debug-name-level*)))
 231                         (do ((tail (cdr x) (cdr tail))
 232                              (name (cons (walk (car x)) nil)
 233                                    (cons (walk (car tail)) name))
 234                              (n (1- *debug-name-length*) (1- n)))
 235                             ((or (not (consp tail))
 236                                  (not (plusp n))
 237                                  *debug-name-punt*)
 238                              (cond (*debug-name-punt*
 239                                     (setf *debug-name-punt* nil)
 240                                     (nreverse name))
 241                                    ((atom tail)
 242                                     (nconc (nreverse name) (walk tail)))
 243                                    (t
 244                                     (setf *debug-name-punt* t)
 245                                     (nconc (nreverse name) (list *debug-name-ellipsis*)))))))
 246                       *debug-name-sharp*))
 247                  ((or symbol number string)
 248                   x)
 249                  (t
 250                   (type-of x)))))
 251       (let ((name (list type (walk thing))))
 252         (when (legal-fun-name-p name)
 253           (bug "~S is a legal function name, and cannot be used as a ~
 254                 debug name." name))
 255         name))))