src/compiler/float-tran.lisp

   1 ;;;; This file contains floating-point-specific transforms, and may be
   2 ;;;; somewhat implementation-dependent in its assumptions of what the
   3 ;;;; formats are.
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15 \f
  16 ;;;; coercions
  17
  18 (defknown %single-float (real) single-float (movable foldable flushable))
  19 (defknown %double-float (real) double-float (movable foldable flushable))
  20
  21 (deftransform float ((n &optional f) (* &optional single-float) * :when :both)
  22   '(%single-float n))
  23
  24 (deftransform float ((n f) (* double-float) * :when :both)
  25   '(%double-float n))
  26
  27 (deftransform %single-float ((n) (single-float) * :when :both)
  28   'n)
  29
  30 (deftransform %double-float ((n) (double-float) * :when :both)
  31   'n)
  32
  33 ;;; RANDOM
  34 (macrolet ((frob (fun type)
  35              `(deftransform random ((num &optional state)
  36                                     (,type &optional *) *
  37                                     :when :both)
  38                 "Use inline float operations."
  39                 '(,fun num (or state *random-state*)))))
  40   (frob %random-single-float single-float)
  41   (frob %random-double-float double-float))
  42
  43 ;;; Mersenne Twister RNG
  44 ;;;
  45 ;;; FIXME: It's unpleasant to have RANDOM functionality scattered
  46 ;;; through the code this way. It would be nice to move this into the
  47 ;;; same file as the other RANDOM definitions.
  48 (deftransform random ((num &optional state)
  49                       ((integer 1 #.(expt 2 32)) &optional *))
  50   ;; FIXME: I almost conditionalized this as #!+sb-doc. Find some way
  51   ;; of automatically finding #!+sb-doc in proximity to DEFTRANSFORM
  52   ;; to let me scan for places that I made this mistake and didn't
  53   ;; catch myself.
  54   "use inline (UNSIGNED-BYTE 32) operations"
  55   (let ((num-high (numeric-type-high (continuation-type num))))
  56     (when (null num-high)
  57       (give-up-ir1-transform))
  58     (cond ((constant-continuation-p num)
  59            ;; Check the worst case sum absolute error for the random number
  60            ;; expectations.
  61            (let ((rem (rem (expt 2 32) num-high)))
  62              (unless (< (/ (* 2 rem (- num-high rem)) num-high (expt 2 32))
  63                         (expt 2 (- sb!kernel::random-integer-extra-bits)))
  64                (give-up-ir1-transform
  65                 "The random number expectations are inaccurate."))
  66              (if (= num-high (expt 2 32))
  67                  '(random-chunk (or state *random-state*))
  68                  #!-x86 '(rem (random-chunk (or state *random-state*)) num)
  69                  #!+x86
  70                  ;; Use multiplication, which is faster.
  71                  '(values (sb!bignum::%multiply
  72                            (random-chunk (or state *random-state*))
  73                            num)))))
  74           ((> num-high random-fixnum-max)
  75            (give-up-ir1-transform
  76             "The range is too large to ensure an accurate result."))
  77           #!+x86
  78           ((< num-high (expt 2 32))
  79            '(values (sb!bignum::%multiply (random-chunk (or state
  80                                                             *random-state*))
  81                      num)))
  82           (t
  83            '(rem (random-chunk (or state *random-state*)) num)))))
  84 \f
  85 ;;;; float accessors
  86
  87 (defknown make-single-float ((signed-byte 32)) single-float
  88   (movable foldable flushable))
  89
  90 (defknown make-double-float ((signed-byte 32) (unsigned-byte 32)) double-float
  91   (movable foldable flushable))
  92
  93 (defknown single-float-bits (single-float) (signed-byte 32)
  94   (movable foldable flushable))
  95
  96 (defknown double-float-high-bits (double-float) (signed-byte 32)
  97   (movable foldable flushable))
  98
  99 (defknown double-float-low-bits (double-float) (unsigned-byte 32)
 100   (movable foldable flushable))
 101
 102 (deftransform float-sign ((float &optional float2)
 103                           (single-float &optional single-float) *)
 104   (if float2
 105       (let ((temp (gensym)))
 106         `(let ((,temp (abs float2)))
 107           (if (minusp (single-float-bits float)) (- ,temp) ,temp)))
 108       '(if (minusp (single-float-bits float)) -1f0 1f0)))
 109
 110 (deftransform float-sign ((float &optional float2)
 111                           (double-float &optional double-float) *)
 112   (if float2
 113       (let ((temp (gensym)))
 114         `(let ((,temp (abs float2)))
 115           (if (minusp (double-float-high-bits float)) (- ,temp) ,temp)))
 116       '(if (minusp (double-float-high-bits float)) -1d0 1d0)))
 117 \f
 118 ;;;; DECODE-FLOAT, INTEGER-DECODE-FLOAT, and SCALE-FLOAT
 119
 120 (defknown decode-single-float (single-float)
 121   (values single-float single-float-exponent (single-float -1f0 1f0))
 122   (movable foldable flushable))
 123
 124 (defknown decode-double-float (double-float)
 125   (values double-float double-float-exponent (double-float -1d0 1d0))
 126   (movable foldable flushable))
 127
 128 (defknown integer-decode-single-float (single-float)
 129   (values single-float-significand single-float-int-exponent (integer -1 1))
 130   (movable foldable flushable))
 131
 132 (defknown integer-decode-double-float (double-float)
 133   (values double-float-significand double-float-int-exponent (integer -1 1))
 134   (movable foldable flushable))
 135
 136 (defknown scale-single-float (single-float fixnum) single-float
 137   (movable foldable flushable))
 138
 139 (defknown scale-double-float (double-float fixnum) double-float
 140   (movable foldable flushable))
 141
 142 (deftransform decode-float ((x) (single-float) * :when :both)
 143   '(decode-single-float x))
 144
 145 (deftransform decode-float ((x) (double-float) * :when :both)
 146   '(decode-double-float x))
 147
 148 (deftransform integer-decode-float ((x) (single-float) * :when :both)
 149   '(integer-decode-single-float x))
 150
 151 (deftransform integer-decode-float ((x) (double-float) * :when :both)
 152   '(integer-decode-double-float x))
 153
 154 (deftransform scale-float ((f ex) (single-float *) * :when :both)
 155   (if (and #!+x86 t #!-x86 nil
 156            (csubtypep (continuation-type ex)
 157                       (specifier-type '(signed-byte 32))))
 158       '(coerce (%scalbn (coerce f 'double-float) ex) 'single-float)
 159       '(scale-single-float f ex)))
 160
 161 (deftransform scale-float ((f ex) (double-float *) * :when :both)
 162   (if (and #!+x86 t #!-x86 nil
 163            (csubtypep (continuation-type ex)
 164                       (specifier-type '(signed-byte 32))))
 165       '(%scalbn f ex)
 166       '(scale-double-float f ex)))
 167
 168 ;;; What is the CROSS-FLOAT-INFINITY-KLUDGE?
 169 ;;;
 170 ;;; SBCL's own implementation of floating point supports floating
 171 ;;; point infinities. Some of the old CMU CL :PROPAGATE-FLOAT-TYPE and
 172 ;;; :PROPAGATE-FUN-TYPE code, like the DEFOPTIMIZERs below, uses this
 173 ;;; floating point support. Thus, we have to avoid running it on the
 174 ;;; cross-compilation host, since we're not guaranteed that the
 175 ;;; cross-compilation host will support floating point infinities.
 176 ;;;
 177 ;;; If we wanted to live dangerously, we could conditionalize the code
 178 ;;; with #+(OR SBCL SB-XC) instead. That way, if the cross-compilation
 179 ;;; host happened to be SBCL, we'd be able to run the infinity-using
 180 ;;; code. Pro:
 181 ;;;   * SBCL itself gets built with more complete optimization.
 182 ;;; Con:
 183 ;;;   * You get a different SBCL depending on what your cross-compilation
 184 ;;;     host is.
 185 ;;; So far the pros and cons seem seem to be mostly academic, since
 186 ;;; AFAIK (WHN 2001-08-28) the propagate-foo-type optimizations aren't
 187 ;;; actually important in compiling SBCL itself. If this changes, then
 188 ;;; we have to decide:
 189 ;;;   * Go for simplicity, leaving things as they are.
 190 ;;;   * Go for performance at the expense of conceptual clarity,
 191 ;;;     using #+(OR SBCL SB-XC) and otherwise leaving the build
 192 ;;;     process as is.
 193 ;;;   * Go for performance at the expense of build time, using
 194 ;;;     #+(OR SBCL SB-XC) and also making SBCL do not just
 195 ;;;     make-host-1.sh and make-host-2.sh, but a third step
 196 ;;;     make-host-3.sh where it builds itself under itself. (Such a
 197 ;;;     3-step build process could also help with other things, e.g.
 198 ;;;     using specialized arrays to represent debug information.)
 199 ;;;   * Rewrite the code so that it doesn't depend on unportable
 200 ;;;     floating point infinities.
 201
 202 ;;; optimizers for SCALE-FLOAT. If the float has bounds, new bounds
 203 ;;; are computed for the result, if possible.
 204 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 205 (progn
 206
 207 (defun scale-float-derive-type-aux (f ex same-arg)
 208   (declare (ignore same-arg))
 209   (flet ((scale-bound (x n)
 210            ;; We need to be a bit careful here and catch any overflows
 211            ;; that might occur. We can ignore underflows which become
 212            ;; zeros.
 213            (set-bound
 214             (handler-case
 215              (scale-float (type-bound-number x) n)
 216              (floating-point-overflow ()
 217                 nil))
 218             (consp x))))
 219     (when (and (numeric-type-p f) (numeric-type-p ex))
 220       (let ((f-lo (numeric-type-low f))
 221             (f-hi (numeric-type-high f))
 222             (ex-lo (numeric-type-low ex))
 223             (ex-hi (numeric-type-high ex))
 224             (new-lo nil)
 225             (new-hi nil))
 226         (when (and f-hi ex-hi)
 227           (setf new-hi (scale-bound f-hi ex-hi)))
 228         (when (and f-lo ex-lo)
 229           (setf new-lo (scale-bound f-lo ex-lo)))
 230         (make-numeric-type :class (numeric-type-class f)
 231                            :format (numeric-type-format f)
 232                            :complexp :real
 233                            :low new-lo
 234                            :high new-hi)))))
 235 (defoptimizer (scale-single-float derive-type) ((f ex))
 236   (two-arg-derive-type f ex #'scale-float-derive-type-aux
 237                        #'scale-single-float t))
 238 (defoptimizer (scale-double-float derive-type) ((f ex))
 239   (two-arg-derive-type f ex #'scale-float-derive-type-aux
 240                        #'scale-double-float t))
 241
 242 ;;; DEFOPTIMIZERs for %SINGLE-FLOAT and %DOUBLE-FLOAT. This makes the
 243 ;;; FLOAT function return the correct ranges if the input has some
 244 ;;; defined range. Quite useful if we want to convert some type of
 245 ;;; bounded integer into a float.
 246 (macrolet
 247     ((frob (fun type)
 248        (let ((aux-name (symbolicate fun "-DERIVE-TYPE-AUX")))
 249          `(progn
 250            (defun ,aux-name (num)
 251              ;; When converting a number to a float, the limits are
 252              ;; the same.
 253              (let* ((lo (bound-func (lambda (x)
 254                                       (coerce x ',type))
 255                                     (numeric-type-low num)))
 256                     (hi (bound-func (lambda (x)
 257                                       (coerce x ',type))
 258                                     (numeric-type-high num))))
 259                (specifier-type `(,',type ,(or lo '*) ,(or hi '*)))))
 260
 261            (defoptimizer (,fun derive-type) ((num))
 262              (one-arg-derive-type num #',aux-name #',fun))))))
 263   (frob %single-float single-float)
 264   (frob %double-float double-float))
 265 ) ; PROGN
 266 \f
 267 ;;;; float contagion
 268
 269 ;;; Do some stuff to recognize when the loser is doing mixed float and
 270 ;;; rational arithmetic, or different float types, and fix it up. If
 271 ;;; we don't, he won't even get so much as an efficiency note.
 272 (deftransform float-contagion-arg1 ((x y) * * :defun-only t :node node)
 273   `(,(continuation-fun-name (basic-combination-fun node))
 274     (float x y) y))
 275 (deftransform float-contagion-arg2 ((x y) * * :defun-only t :node node)
 276   `(,(continuation-fun-name (basic-combination-fun node))
 277     x (float y x)))
 278
 279 (dolist (x '(+ * / -))
 280   (%deftransform x '(function (rational float) *) #'float-contagion-arg1)
 281   (%deftransform x '(function (float rational) *) #'float-contagion-arg2))
 282
 283 (dolist (x '(= < > + * / -))
 284   (%deftransform x '(function (single-float double-float) *)
 285                  #'float-contagion-arg1)
 286   (%deftransform x '(function (double-float single-float) *)
 287                  #'float-contagion-arg2))
 288
 289 ;;; Prevent ZEROP, PLUSP, and MINUSP from losing horribly. We can't in
 290 ;;; general float rational args to comparison, since Common Lisp
 291 ;;; semantics says we are supposed to compare as rationals, but we can
 292 ;;; do it for any rational that has a precise representation as a
 293 ;;; float (such as 0).
 294 (macrolet ((frob (op)
 295              `(deftransform ,op ((x y) (float rational) * :when :both)
 296                 "open-code FLOAT to RATIONAL comparison"
 297                 (unless (constant-continuation-p y)
 298                   (give-up-ir1-transform
 299                    "The RATIONAL value isn't known at compile time."))
 300                 (let ((val (continuation-value y)))
 301                   (unless (eql (rational (float val)) val)
 302                     (give-up-ir1-transform
 303                      "~S doesn't have a precise float representation."
 304                      val)))
 305                 `(,',op x (float y x)))))
 306   (frob <)
 307   (frob >)
 308   (frob =))
 309 \f
 310 ;;;; irrational derive-type methods
 311
 312 ;;; Derive the result to be float for argument types in the
 313 ;;; appropriate domain.
 314 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 315 (dolist (stuff '((asin (real -1.0 1.0))
 316                  (acos (real -1.0 1.0))
 317                  (acosh (real 1.0))
 318                  (atanh (real -1.0 1.0))
 319                  (sqrt (real 0.0))))
 320   (destructuring-bind (name type) stuff
 321     (let ((type (specifier-type type)))
 322       (setf (fun-info-derive-type (fun-info-or-lose name))
 323             (lambda (call)
 324               (declare (type combination call))
 325               (when (csubtypep (continuation-type
 326                                 (first (combination-args call)))
 327                                type)
 328                 (specifier-type 'float)))))))
 329
 330 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 331 (defoptimizer (log derive-type) ((x &optional y))
 332   (when (and (csubtypep (continuation-type x)
 333                         (specifier-type '(real 0.0)))
 334              (or (null y)
 335                  (csubtypep (continuation-type y)
 336                             (specifier-type '(real 0.0)))))
 337     (specifier-type 'float)))
 338 \f
 339 ;;;; irrational transforms
 340
 341 (defknown (%tan %sinh %asinh %atanh %log %logb %log10 %tan-quick)
 342           (double-float) double-float
 343   (movable foldable flushable))
 344
 345 (defknown (%sin %cos %tanh %sin-quick %cos-quick)
 346   (double-float) (double-float -1.0d0 1.0d0)
 347   (movable foldable flushable))
 348
 349 (defknown (%asin %atan)
 350   (double-float) (double-float #.(- (/ pi 2)) #.(/ pi 2))
 351   (movable foldable flushable))
 352
 353 (defknown (%acos)
 354   (double-float) (double-float 0.0d0 #.pi)
 355   (movable foldable flushable))
 356
 357 (defknown (%cosh)
 358   (double-float) (double-float 1.0d0)
 359   (movable foldable flushable))
 360
 361 (defknown (%acosh %exp %sqrt)
 362   (double-float) (double-float 0.0d0)
 363   (movable foldable flushable))
 364
 365 (defknown %expm1
 366   (double-float) (double-float -1d0)
 367   (movable foldable flushable))
 368
 369 (defknown (%hypot)
 370   (double-float double-float) (double-float 0d0)
 371   (movable foldable flushable))
 372
 373 (defknown (%pow)
 374   (double-float double-float) double-float
 375   (movable foldable flushable))
 376
 377 (defknown (%atan2)
 378   (double-float double-float) (double-float #.(- pi) #.pi)
 379   (movable foldable flushable))
 380
 381 (defknown (%scalb)
 382   (double-float double-float) double-float
 383   (movable foldable flushable))
 384
 385 (defknown (%scalbn)
 386   (double-float (signed-byte 32)) double-float
 387   (movable foldable flushable))
 388
 389 (defknown (%log1p)
 390   (double-float) double-float
 391   (movable foldable flushable))
 392
 393 (macrolet ((def-frob (name prim rtype)
 394              `(progn
 395                (deftransform ,name ((x) (single-float) ,rtype)
 396                  `(coerce (,',prim (coerce x 'double-float)) 'single-float))
 397                (deftransform ,name ((x) (double-float) ,rtype :when :both)
 398                  `(,',prim x)))))
 399   (def-frob exp %exp *)
 400   (def-frob log %log float)
 401   (def-frob sqrt %sqrt float)
 402   (def-frob asin %asin float)
 403   (def-frob acos %acos float)
 404   (def-frob atan %atan *)
 405   (def-frob sinh %sinh *)
 406   (def-frob cosh %cosh *)
 407   (def-frob tanh %tanh *)
 408   (def-frob asinh %asinh *)
 409   (def-frob acosh %acosh float)
 410   (def-frob atanh %atanh float))
 411
 412 ;;; The argument range is limited on the x86 FP trig. functions. A
 413 ;;; post-test can detect a failure (and load a suitable result), but
 414 ;;; this test is avoided if possible.
 415 (macrolet ((def-frob (name prim prim-quick)
 416              (declare (ignorable prim-quick))
 417              `(progn
 418                 (deftransform ,name ((x) (single-float) *)
 419                   #!+x86 (cond ((csubtypep (continuation-type x)
 420                                            (specifier-type '(single-float
 421                                                              (#.(- (expt 2f0 64)))
 422                                                              (#.(expt 2f0 64)))))
 423                                 `(coerce (,',prim-quick (coerce x 'double-float))
 424                                   'single-float))
 425                                (t
 426                                 (compiler-note
 427                                  "unable to avoid inline argument range check~@
 428                                   because the argument range (~S) was not within 2^64"
 429                                  (type-specifier (continuation-type x)))
 430                                 `(coerce (,',prim (coerce x 'double-float)) 'single-float)))
 431                   #!-x86 `(coerce (,',prim (coerce x 'double-float)) 'single-float))
 432                (deftransform ,name ((x) (double-float) * :when :both)
 433                  #!+x86 (cond ((csubtypep (continuation-type x)
 434                                           (specifier-type '(double-float
 435                                                             (#.(- (expt 2d0 64)))
 436                                                             (#.(expt 2d0 64)))))
 437                                `(,',prim-quick x))
 438                               (t
 439                                (compiler-note
 440                                 "unable to avoid inline argument range check~@
 441                                  because the argument range (~S) was not within 2^64"
 442                                 (type-specifier (continuation-type x)))
 443                                `(,',prim x)))
 444                  #!-x86 `(,',prim x)))))
 445   (def-frob sin %sin %sin-quick)
 446   (def-frob cos %cos %cos-quick)
 447   (def-frob tan %tan %tan-quick))
 448
 449 (deftransform atan ((x y) (single-float single-float) *)
 450   `(coerce (%atan2 (coerce x 'double-float) (coerce y 'double-float))
 451     'single-float))
 452 (deftransform atan ((x y) (double-float double-float) * :when :both)
 453   `(%atan2 x y))
 454
 455 (deftransform expt ((x y) ((single-float 0f0) single-float) *)
 456   `(coerce (%pow (coerce x 'double-float) (coerce y 'double-float))
 457     'single-float))
 458 (deftransform expt ((x y) ((double-float 0d0) double-float) * :when :both)
 459   `(%pow x y))
 460 (deftransform expt ((x y) ((single-float 0f0) (signed-byte 32)) *)
 461   `(coerce (%pow (coerce x 'double-float) (coerce y 'double-float))
 462     'single-float))
 463 (deftransform expt ((x y) ((double-float 0d0) (signed-byte 32)) * :when :both)
 464   `(%pow x (coerce y 'double-float)))
 465
 466 ;;; ANSI says log with base zero returns zero.
 467 (deftransform log ((x y) (float float) float)
 468   '(if (zerop y) y (/ (log x) (log y))))
 469 \f
 470 ;;; Handle some simple transformations.
 471
 472 (deftransform abs ((x) ((complex double-float)) double-float :when :both)
 473   '(%hypot (realpart x) (imagpart x)))
 474
 475 (deftransform abs ((x) ((complex single-float)) single-float)
 476   '(coerce (%hypot (coerce (realpart x) 'double-float)
 477                    (coerce (imagpart x) 'double-float))
 478           'single-float))
 479
 480 (deftransform phase ((x) ((complex double-float)) double-float :when :both)
 481   '(%atan2 (imagpart x) (realpart x)))
 482
 483 (deftransform phase ((x) ((complex single-float)) single-float)
 484   '(coerce (%atan2 (coerce (imagpart x) 'double-float)
 485                    (coerce (realpart x) 'double-float))
 486           'single-float))
 487
 488 (deftransform phase ((x) ((float)) float :when :both)
 489   '(if (minusp (float-sign x))
 490        (float pi x)
 491        (float 0 x)))
 492
 493 ;;; The number is of type REAL.
 494 (defun numeric-type-real-p (type)
 495   (and (numeric-type-p type)
 496        (eq (numeric-type-complexp type) :real)))
 497
 498 ;;; Coerce a numeric type bound to the given type while handling
 499 ;;; exclusive bounds.
 500 (defun coerce-numeric-bound (bound type)
 501   (when bound
 502     (if (consp bound)
 503         (list (coerce (car bound) type))
 504         (coerce bound type))))
 505
 506 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 507 (progn
 508
 509 ;;;; optimizers for elementary functions
 510 ;;;;
 511 ;;;; These optimizers compute the output range of the elementary
 512 ;;;; function, based on the domain of the input.
 513
 514 ;;; Generate a specifier for a complex type specialized to the same
 515 ;;; type as the argument.
 516 (defun complex-float-type (arg)
 517   (declare (type numeric-type arg))
 518   (let* ((format (case (numeric-type-class arg)
 519                    ((integer rational) 'single-float)
 520                    (t (numeric-type-format arg))))
 521          (float-type (or format 'float)))
 522     (specifier-type `(complex ,float-type))))
 523
 524 ;;; Compute a specifier like '(OR FLOAT (COMPLEX FLOAT)), except float
 525 ;;; should be the right kind of float. Allow bounds for the float
 526 ;;; part too.
 527 (defun float-or-complex-float-type (arg &optional lo hi)
 528   (declare (type numeric-type arg))
 529   (let* ((format (case (numeric-type-class arg)
 530                    ((integer rational) 'single-float)
 531                    (t (numeric-type-format arg))))
 532          (float-type (or format 'float))
 533          (lo (coerce-numeric-bound lo float-type))
 534          (hi (coerce-numeric-bound hi float-type)))
 535     (specifier-type `(or (,float-type ,(or lo '*) ,(or hi '*))
 536                          (complex ,float-type)))))
 537
 538 ;;; Test whether the numeric-type ARG is within in domain specified by
 539 ;;; DOMAIN-LOW and DOMAIN-HIGH, consider negative and positive zero to
 540 ;;; be distinct as for the :NEGATIVE-ZERO-IS-NOT-ZERO feature. With
 541 ;;; the :NEGATIVE-ZERO-IS-NOT-ZERO feature this could be handled by
 542 ;;; the numeric subtype code in type.lisp.
 543 (defun domain-subtypep (arg domain-low domain-high)
 544   (declare (type numeric-type arg)
 545            (type (or real null) domain-low domain-high))
 546   (let* ((arg-lo (numeric-type-low arg))
 547          (arg-lo-val (type-bound-number arg-lo))
 548          (arg-hi (numeric-type-high arg))
 549          (arg-hi-val (type-bound-number arg-hi)))
 550     ;; Check that the ARG bounds are correctly canonicalized.
 551     (when (and arg-lo (floatp arg-lo-val) (zerop arg-lo-val) (consp arg-lo)
 552                (minusp (float-sign arg-lo-val)))
 553       (compiler-note "float zero bound ~S not correctly canonicalized?" arg-lo)
 554       (setq arg-lo '(0l0) arg-lo-val 0l0))
 555     (when (and arg-hi (zerop arg-hi-val) (floatp arg-hi-val) (consp arg-hi)
 556                (plusp (float-sign arg-hi-val)))
 557       (compiler-note "float zero bound ~S not correctly canonicalized?" arg-hi)
 558       (setq arg-hi '(-0l0) arg-hi-val -0l0))
 559     (and (or (null domain-low)
 560              (and arg-lo (>= arg-lo-val domain-low)
 561                   (not (and (zerop domain-low) (floatp domain-low)
 562                             (plusp (float-sign domain-low))
 563                             (zerop arg-lo-val) (floatp arg-lo-val)
 564                             (if (consp arg-lo)
 565                                 (plusp (float-sign arg-lo-val))
 566                                 (minusp (float-sign arg-lo-val)))))))
 567          (or (null domain-high)
 568              (and arg-hi (<= arg-hi-val domain-high)
 569                   (not (and (zerop domain-high) (floatp domain-high)
 570                             (minusp (float-sign domain-high))
 571                             (zerop arg-hi-val) (floatp arg-hi-val)
 572                             (if (consp arg-hi)
 573                                 (minusp (float-sign arg-hi-val))
 574                                 (plusp (float-sign arg-hi-val))))))))))
 575
 576 ;;; Handle monotonic functions of a single variable whose domain is
 577 ;;; possibly part of the real line. ARG is the variable, FCN is the
 578 ;;; function, and DOMAIN is a specifier that gives the (real) domain
 579 ;;; of the function. If ARG is a subset of the DOMAIN, we compute the
 580 ;;; bounds directly. Otherwise, we compute the bounds for the
 581 ;;; intersection between ARG and DOMAIN, and then append a complex
 582 ;;; result, which occurs for the parts of ARG not in the DOMAIN.
 583 ;;;
 584 ;;; Negative and positive zero are considered distinct within
 585 ;;; DOMAIN-LOW and DOMAIN-HIGH, as for the :negative-zero-is-not-zero
 586 ;;; feature.
 587 ;;;
 588 ;;; DEFAULT-LOW and DEFAULT-HIGH are the lower and upper bounds if we
 589 ;;; can't compute the bounds using FCN.
 590 (defun elfun-derive-type-simple (arg fcn domain-low domain-high
 591                                      default-low default-high
 592                                      &optional (increasingp t))
 593   (declare (type (or null real) domain-low domain-high))
 594   (etypecase arg
 595     (numeric-type
 596      (cond ((eq (numeric-type-complexp arg) :complex)
 597             (make-numeric-type :class (numeric-type-class arg)
 598                                :format (numeric-type-format arg)
 599                                :complexp :complex))
 600            ((numeric-type-real-p arg)
 601             ;; The argument is real, so let's find the intersection
 602             ;; between the argument and the domain of the function.
 603             ;; We compute the bounds on the intersection, and for
 604             ;; everything else, we return a complex number of the
 605             ;; appropriate type.
 606             (multiple-value-bind (intersection difference)
 607                 (interval-intersection/difference (numeric-type->interval arg)
 608                                                   (make-interval
 609                                                    :low domain-low
 610                                                    :high domain-high))
 611               (cond
 612                 (intersection
 613                  ;; Process the intersection.
 614                  (let* ((low (interval-low intersection))
 615                         (high (interval-high intersection))
 616                         (res-lo (or (bound-func fcn (if increasingp low high))
 617                                     default-low))
 618                         (res-hi (or (bound-func fcn (if increasingp high low))
 619                                     default-high))
 620                         (format (case (numeric-type-class arg)
 621                                   ((integer rational) 'single-float)
 622                                   (t (numeric-type-format arg))))
 623                         (bound-type (or format 'float))
 624                         (result-type
 625                          (make-numeric-type
 626                           :class 'float
 627                           :format format
 628                           :low (coerce-numeric-bound res-lo bound-type)
 629                           :high (coerce-numeric-bound res-hi bound-type))))
 630                    ;; If the ARG is a subset of the domain, we don't
 631                    ;; have to worry about the difference, because that
 632                    ;; can't occur.
 633                    (if (or (null difference)
 634                            ;; Check whether the arg is within the domain.
 635                            (domain-subtypep arg domain-low domain-high))
 636                        result-type
 637                        (list result-type
 638                              (specifier-type `(complex ,bound-type))))))
 639                 (t
 640                  ;; No intersection so the result must be purely complex.
 641                  (complex-float-type arg)))))
 642            (t
 643             (float-or-complex-float-type arg default-low default-high))))))
 644
 645 (macrolet
 646     ((frob (name domain-low domain-high def-low-bnd def-high-bnd
 647                  &key (increasingp t))
 648        (let ((num (gensym)))
 649          `(defoptimizer (,name derive-type) ((,num))
 650            (one-arg-derive-type
 651             ,num
 652             (lambda (arg)
 653               (elfun-derive-type-simple arg #',name
 654                                         ,domain-low ,domain-high
 655                                         ,def-low-bnd ,def-high-bnd
 656                                         ,increasingp))
 657             #',name)))))
 658   ;; These functions are easy because they are defined for the whole
 659   ;; real line.
 660   (frob exp nil nil 0 nil)
 661   (frob sinh nil nil nil nil)
 662   (frob tanh nil nil -1 1)
 663   (frob asinh nil nil nil nil)
 664
 665   ;; These functions are only defined for part of the real line. The
 666   ;; condition selects the desired part of the line.
 667   (frob asin -1d0 1d0 (- (/ pi 2)) (/ pi 2))
 668   ;; Acos is monotonic decreasing, so we need to swap the function
 669   ;; values at the lower and upper bounds of the input domain.
 670   (frob acos -1d0 1d0 0 pi :increasingp nil)
 671   (frob acosh 1d0 nil nil nil)
 672   (frob atanh -1d0 1d0 -1 1)
 673   ;; Kahan says that (sqrt -0.0) is -0.0, so use a specifier that
 674   ;; includes -0.0.
 675   (frob sqrt -0d0 nil 0 nil))
 676
 677 ;;; Compute bounds for (expt x y). This should be easy since (expt x
 678 ;;; y) = (exp (* y (log x))). However, computations done this way
 679 ;;; have too much roundoff. Thus we have to do it the hard way.
 680 (defun safe-expt (x y)
 681   (handler-case
 682       (expt x y)
 683     (error ()
 684       nil)))
 685
 686 ;;; Handle the case when x >= 1.
 687 (defun interval-expt-> (x y)
 688   (case (sb!c::interval-range-info y 0d0)
 689     ('+
 690      ;; Y is positive and log X >= 0. The range of exp(y * log(x)) is
 691      ;; obviously non-negative. We just have to be careful for
 692      ;; infinite bounds (given by nil).
 693      (let ((lo (safe-expt (type-bound-number (sb!c::interval-low x))
 694                           (type-bound-number (sb!c::interval-low y))))
 695            (hi (safe-expt (type-bound-number (sb!c::interval-high x))
 696                           (type-bound-number (sb!c::interval-high y)))))
 697        (list (sb!c::make-interval :low (or lo 1) :high hi))))
 698     ('-
 699      ;; Y is negative and log x >= 0. The range of exp(y * log(x)) is
 700      ;; obviously [0, 1]. However, underflow (nil) means 0 is the
 701      ;; result.
 702      (let ((lo (safe-expt (type-bound-number (sb!c::interval-high x))
 703                           (type-bound-number (sb!c::interval-low y))))
 704            (hi (safe-expt (type-bound-number (sb!c::interval-low x))
 705                           (type-bound-number (sb!c::interval-high y)))))
 706        (list (sb!c::make-interval :low (or lo 0) :high (or hi 1)))))
 707     (t
 708      ;; Split the interval in half.
 709      (destructuring-bind (y- y+)
 710          (sb!c::interval-split 0 y t)
 711        (list (interval-expt-> x y-)
 712              (interval-expt-> x y+))))))
 713
 714 ;;; Handle the case when x <= 1
 715 (defun interval-expt-< (x y)
 716   (case (sb!c::interval-range-info x 0d0)
 717     ('+
 718      ;; The case of 0 <= x <= 1 is easy
 719      (case (sb!c::interval-range-info y)
 720        ('+
 721         ;; Y is positive and log X <= 0. The range of exp(y * log(x)) is
 722         ;; obviously [0, 1]. We just have to be careful for infinite bounds
 723         ;; (given by nil).
 724         (let ((lo (safe-expt (type-bound-number (sb!c::interval-low x))
 725                              (type-bound-number (sb!c::interval-high y))))
 726               (hi (safe-expt (type-bound-number (sb!c::interval-high x))
 727                              (type-bound-number (sb!c::interval-low y)))))
 728           (list (sb!c::make-interval :low (or lo 0) :high (or hi 1)))))
 729        ('-
 730         ;; Y is negative and log x <= 0. The range of exp(y * log(x)) is
 731         ;; obviously [1, inf].
 732         (let ((hi (safe-expt (type-bound-number (sb!c::interval-low x))
 733                              (type-bound-number (sb!c::interval-low y))))
 734               (lo (safe-expt (type-bound-number (sb!c::interval-high x))
 735                              (type-bound-number (sb!c::interval-high y)))))
 736           (list (sb!c::make-interval :low (or lo 1) :high hi))))
 737        (t
 738         ;; Split the interval in half
 739         (destructuring-bind (y- y+)
 740             (sb!c::interval-split 0 y t)
 741           (list (interval-expt-< x y-)
 742                 (interval-expt-< x y+))))))
 743     ('-
 744      ;; The case where x <= 0. Y MUST be an INTEGER for this to work!
 745      ;; The calling function must insure this! For now we'll just
 746      ;; return the appropriate unbounded float type.
 747      (list (sb!c::make-interval :low nil :high nil)))
 748     (t
 749      (destructuring-bind (neg pos)
 750          (interval-split 0 x t t)
 751        (list (interval-expt-< neg y)
 752              (interval-expt-< pos y))))))
 753
 754 ;;; Compute bounds for (expt x y).
 755 (defun interval-expt (x y)
 756   (case (interval-range-info x 1)
 757     ('+
 758      ;; X >= 1
 759          (interval-expt-> x y))
 760     ('-
 761      ;; X <= 1
 762      (interval-expt-< x y))
 763     (t
 764      (destructuring-bind (left right)
 765          (interval-split 1 x t t)
 766        (list (interval-expt left y)
 767              (interval-expt right y))))))
 768
 769 (defun fixup-interval-expt (bnd x-int y-int x-type y-type)
 770   (declare (ignore x-int))
 771   ;; Figure out what the return type should be, given the argument
 772   ;; types and bounds and the result type and bounds.
 773   (cond ((csubtypep x-type (specifier-type 'integer))
 774          ;; an integer to some power
 775          (case (numeric-type-class y-type)
 776            (integer
 777             ;; Positive integer to an integer power is either an
 778             ;; integer or a rational.
 779             (let ((lo (or (interval-low bnd) '*))
 780                   (hi (or (interval-high bnd) '*)))
 781               (if (and (interval-low y-int)
 782                        (>= (type-bound-number (interval-low y-int)) 0))
 783                   (specifier-type `(integer ,lo ,hi))
 784                   (specifier-type `(rational ,lo ,hi)))))
 785            (rational
 786             ;; Positive integer to rational power is either a rational
 787             ;; or a single-float.
 788             (let* ((lo (interval-low bnd))
 789                    (hi (interval-high bnd))
 790                    (int-lo (if lo
 791                                (floor (type-bound-number lo))
 792                                '*))
 793                    (int-hi (if hi
 794                                (ceiling (type-bound-number hi))
 795                                '*))
 796                    (f-lo (if lo
 797                              (bound-func #'float lo)
 798                              '*))
 799                    (f-hi (if hi
 800                              (bound-func #'float hi)
 801                              '*)))
 802               (specifier-type `(or (rational ,int-lo ,int-hi)
 803                                 (single-float ,f-lo, f-hi)))))
 804            (float
 805             ;; A positive integer to a float power is a float.
 806             (modified-numeric-type y-type
 807                                    :low (interval-low bnd)
 808                                    :high (interval-high bnd)))
 809            (t
 810             ;; A positive integer to a number is a number (for now).
 811             (specifier-type 'number))))
 812         ((csubtypep x-type (specifier-type 'rational))
 813          ;; a rational to some power
 814          (case (numeric-type-class y-type)
 815            (integer
 816             ;; A positive rational to an integer power is always a rational.
 817             (specifier-type `(rational ,(or (interval-low bnd) '*)
 818                                        ,(or (interval-high bnd) '*))))
 819            (rational
 820             ;; A positive rational to rational power is either a rational
 821             ;; or a single-float.
 822             (let* ((lo (interval-low bnd))
 823                    (hi (interval-high bnd))
 824                    (int-lo (if lo
 825                                (floor (type-bound-number lo))
 826                                '*))
 827                    (int-hi (if hi
 828                                (ceiling (type-bound-number hi))
 829                                '*))
 830                    (f-lo (if lo
 831                              (bound-func #'float lo)
 832                              '*))
 833                    (f-hi (if hi
 834                              (bound-func #'float hi)
 835                              '*)))
 836               (specifier-type `(or (rational ,int-lo ,int-hi)
 837                                 (single-float ,f-lo, f-hi)))))
 838            (float
 839             ;; A positive rational to a float power is a float.
 840             (modified-numeric-type y-type
 841                                    :low (interval-low bnd)
 842                                    :high (interval-high bnd)))
 843            (t
 844             ;; A positive rational to a number is a number (for now).
 845             (specifier-type 'number))))
 846         ((csubtypep x-type (specifier-type 'float))
 847          ;; a float to some power
 848          (case (numeric-type-class y-type)
 849            ((or integer rational)
 850             ;; A positive float to an integer or rational power is
 851             ;; always a float.
 852             (make-numeric-type
 853              :class 'float
 854              :format (numeric-type-format x-type)
 855              :low (interval-low bnd)
 856              :high (interval-high bnd)))
 857            (float
 858             ;; A positive float to a float power is a float of the
 859             ;; higher type.
 860             (make-numeric-type
 861              :class 'float
 862              :format (float-format-max (numeric-type-format x-type)
 863                                        (numeric-type-format y-type))
 864              :low (interval-low bnd)
 865              :high (interval-high bnd)))
 866            (t
 867             ;; A positive float to a number is a number (for now)
 868             (specifier-type 'number))))
 869         (t
 870          ;; A number to some power is a number.
 871          (specifier-type 'number))))
 872
 873 (defun merged-interval-expt (x y)
 874   (let* ((x-int (numeric-type->interval x))
 875          (y-int (numeric-type->interval y)))
 876     (mapcar (lambda (type)
 877               (fixup-interval-expt type x-int y-int x y))
 878             (flatten-list (interval-expt x-int y-int)))))
 879
 880 (defun expt-derive-type-aux (x y same-arg)
 881   (declare (ignore same-arg))
 882   (cond ((or (not (numeric-type-real-p x))
 883              (not (numeric-type-real-p y)))
 884          ;; Use numeric contagion if either is not real.
 885          (numeric-contagion x y))
 886         ((csubtypep y (specifier-type 'integer))
 887          ;; A real raised to an integer power is well-defined.
 888          (merged-interval-expt x y))
 889         (t
 890          ;; A real raised to a non-integral power can be a float or a
 891          ;; complex number.
 892          (cond ((or (csubtypep x (specifier-type '(rational 0)))
 893                     (csubtypep x (specifier-type '(float (0d0)))))
 894                 ;; But a positive real to any power is well-defined.
 895                 (merged-interval-expt x y))
 896                (t
 897                 ;; a real to some power. The result could be a real
 898                 ;; or a complex.
 899                 (float-or-complex-float-type (numeric-contagion x y)))))))
 900
 901 (defoptimizer (expt derive-type) ((x y))
 902   (two-arg-derive-type x y #'expt-derive-type-aux #'expt))
 903
 904 ;;; Note we must assume that a type including 0.0 may also include
 905 ;;; -0.0 and thus the result may be complex -infinity + i*pi.
 906 (defun log-derive-type-aux-1 (x)
 907   (elfun-derive-type-simple x #'log 0d0 nil nil nil))
 908
 909 (defun log-derive-type-aux-2 (x y same-arg)
 910   (let ((log-x (log-derive-type-aux-1 x))
 911         (log-y (log-derive-type-aux-1 y))
 912         (accumulated-list nil))
 913     ;; LOG-X or LOG-Y might be union types. We need to run through
 914     ;; the union types ourselves because /-DERIVE-TYPE-AUX doesn't.
 915     (dolist (x-type (prepare-arg-for-derive-type log-x))
 916       (dolist (y-type (prepare-arg-for-derive-type log-y))
 917         (push (/-derive-type-aux x-type y-type same-arg) accumulated-list)))
 918     (apply #'type-union (flatten-list accumulated-list))))
 919
 920 (defoptimizer (log derive-type) ((x &optional y))
 921   (if y
 922       (two-arg-derive-type x y #'log-derive-type-aux-2 #'log)
 923       (one-arg-derive-type x #'log-derive-type-aux-1 #'log)))
 924
 925 (defun atan-derive-type-aux-1 (y)
 926   (elfun-derive-type-simple y #'atan nil nil (- (/ pi 2)) (/ pi 2)))
 927
 928 (defun atan-derive-type-aux-2 (y x same-arg)
 929   (declare (ignore same-arg))
 930   ;; The hard case with two args. We just return the max bounds.
 931   (let ((result-type (numeric-contagion y x)))
 932     (cond ((and (numeric-type-real-p x)
 933                 (numeric-type-real-p y))
 934            (let* (;; FIXME: This expression for FORMAT seems to
 935                   ;; appear multiple times, and should be factored out.
 936                   (format (case (numeric-type-class result-type)
 937                             ((integer rational) 'single-float)
 938                             (t (numeric-type-format result-type))))
 939                   (bound-format (or format 'float)))
 940              (make-numeric-type :class 'float
 941                                 :format format
 942                                 :complexp :real
 943                                 :low (coerce (- pi) bound-format)
 944                                 :high (coerce pi bound-format))))
 945           (t
 946            ;; The result is a float or a complex number
 947            (float-or-complex-float-type result-type)))))
 948
 949 (defoptimizer (atan derive-type) ((y &optional x))
 950   (if x
 951       (two-arg-derive-type y x #'atan-derive-type-aux-2 #'atan)
 952       (one-arg-derive-type y #'atan-derive-type-aux-1 #'atan)))
 953
 954 (defun cosh-derive-type-aux (x)
 955   ;; We note that cosh x = cosh |x| for all real x.
 956   (elfun-derive-type-simple
 957    (if (numeric-type-real-p x)
 958        (abs-derive-type-aux x)
 959        x)
 960    #'cosh nil nil 0 nil))
 961
 962 (defoptimizer (cosh derive-type) ((num))
 963   (one-arg-derive-type num #'cosh-derive-type-aux #'cosh))
 964
 965 (defun phase-derive-type-aux (arg)
 966   (let* ((format (case (numeric-type-class arg)
 967                    ((integer rational) 'single-float)
 968                    (t (numeric-type-format arg))))
 969          (bound-type (or format 'float)))
 970     (cond ((numeric-type-real-p arg)
 971            (case (interval-range-info (numeric-type->interval arg) 0.0)
 972              ('+
 973               ;; The number is positive, so the phase is 0.
 974               (make-numeric-type :class 'float
 975                                  :format format
 976                                  :complexp :real
 977                                  :low (coerce 0 bound-type)
 978                                  :high (coerce 0 bound-type)))
 979              ('-
 980               ;; The number is always negative, so the phase is pi.
 981               (make-numeric-type :class 'float
 982                                  :format format
 983                                  :complexp :real
 984                                  :low (coerce pi bound-type)
 985                                  :high (coerce pi bound-type)))
 986              (t
 987               ;; We can't tell. The result is 0 or pi. Use a union
 988               ;; type for this.
 989               (list
 990                (make-numeric-type :class 'float
 991                                   :format format
 992                                   :complexp :real
 993                                   :low (coerce 0 bound-type)
 994                                   :high (coerce 0 bound-type))
 995                (make-numeric-type :class 'float
 996                                   :format format
 997                                   :complexp :real
 998                                   :low (coerce pi bound-type)
 999                                   :high (coerce pi bound-type))))))
1000           (t
1001            ;; We have a complex number. The answer is the range -pi
1002            ;; to pi. (-pi is included because we have -0.)
1003            (make-numeric-type :class 'float
1004                               :format format
1005                               :complexp :real
1006                               :low (coerce (- pi) bound-type)
1007                               :high (coerce pi bound-type))))))
1008
1009 (defoptimizer (phase derive-type) ((num))
1010   (one-arg-derive-type num #'phase-derive-type-aux #'phase))
1011
1012 ) ; PROGN
1013
1014 (deftransform realpart ((x) ((complex rational)) *)
1015   '(sb!kernel:%realpart x))
1016 (deftransform imagpart ((x) ((complex rational)) *)
1017   '(sb!kernel:%imagpart x))
1018
1019 ;;; Make REALPART and IMAGPART return the appropriate types. This
1020 ;;; should help a lot in optimized code.
1021 (defun realpart-derive-type-aux (type)
1022   (let ((class (numeric-type-class type))
1023         (format (numeric-type-format type)))
1024     (cond ((numeric-type-real-p type)
1025            ;; The realpart of a real has the same type and range as
1026            ;; the input.
1027            (make-numeric-type :class class
1028                               :format format
1029                               :complexp :real
1030                               :low (numeric-type-low type)
1031                               :high (numeric-type-high type)))
1032           (t
1033            ;; We have a complex number. The result has the same type
1034            ;; as the real part, except that it's real, not complex,
1035            ;; obviously.
1036            (make-numeric-type :class class
1037                               :format format
1038                               :complexp :real
1039                               :low (numeric-type-low type)
1040                               :high (numeric-type-high type))))))
1041 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1042 (defoptimizer (realpart derive-type) ((num))
1043   (one-arg-derive-type num #'realpart-derive-type-aux #'realpart))
1044 (defun imagpart-derive-type-aux (type)
1045   (let ((class (numeric-type-class type))
1046         (format (numeric-type-format type)))
1047     (cond ((numeric-type-real-p type)
1048            ;; The imagpart of a real has the same type as the input,
1049            ;; except that it's zero.
1050            (let ((bound-format (or format class 'real)))
1051              (make-numeric-type :class class
1052                                 :format format
1053                                 :complexp :real
1054                                 :low (coerce 0 bound-format)
1055                                 :high (coerce 0 bound-format))))
1056           (t
1057            ;; We have a complex number. The result has the same type as
1058            ;; the imaginary part, except that it's real, not complex,
1059            ;; obviously.
1060            (make-numeric-type :class class
1061                               :format format
1062                               :complexp :real
1063                               :low (numeric-type-low type)
1064                               :high (numeric-type-high type))))))
1065 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1066 (defoptimizer (imagpart derive-type) ((num))
1067   (one-arg-derive-type num #'imagpart-derive-type-aux #'imagpart))
1068
1069 (defun complex-derive-type-aux-1 (re-type)
1070   (if (numeric-type-p re-type)
1071       (make-numeric-type :class (numeric-type-class re-type)
1072                          :format (numeric-type-format re-type)
1073                          :complexp (if (csubtypep re-type
1074                                                   (specifier-type 'rational))
1075                                        :real
1076                                        :complex)
1077                          :low (numeric-type-low re-type)
1078                          :high (numeric-type-high re-type))
1079       (specifier-type 'complex)))
1080
1081 (defun complex-derive-type-aux-2 (re-type im-type same-arg)
1082   (declare (ignore same-arg))
1083   (if (and (numeric-type-p re-type)
1084            (numeric-type-p im-type))
1085       ;; Need to check to make sure numeric-contagion returns the
1086       ;; right type for what we want here.
1087
1088       ;; Also, what about rational canonicalization, like (complex 5 0)
1089       ;; is 5?  So, if the result must be complex, we make it so.
1090       ;; If the result might be complex, which happens only if the
1091       ;; arguments are rational, we make it a union type of (or
1092       ;; rational (complex rational)).
1093       (let* ((element-type (numeric-contagion re-type im-type))
1094              (rat-result-p (csubtypep element-type
1095                                       (specifier-type 'rational))))
1096         (if rat-result-p
1097             (type-union element-type
1098                         (specifier-type
1099                          `(complex ,(numeric-type-class element-type))))
1100             (make-numeric-type :class (numeric-type-class element-type)
1101                                :format (numeric-type-format element-type)
1102                                :complexp (if rat-result-p
1103                                              :real
1104                                              :complex))))
1105       (specifier-type 'complex)))
1106
1107 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1108 (defoptimizer (complex derive-type) ((re &optional im))
1109   (if im
1110       (two-arg-derive-type re im #'complex-derive-type-aux-2 #'complex)
1111       (one-arg-derive-type re #'complex-derive-type-aux-1 #'complex)))
1112
1113 ;;; Define some transforms for complex operations. We do this in lieu
1114 ;;; of complex operation VOPs.
1115 (macrolet ((frob (type)
1116              `(progn
1117                ;; negation
1118                (deftransform %negate ((z) ((complex ,type)) *)
1119                  '(complex (%negate (realpart z)) (%negate (imagpart z))))
1120                ;; complex addition and subtraction
1121                (deftransform + ((w z) ((complex ,type) (complex ,type)) *)
1122                  '(complex (+ (realpart w) (realpart z))
1123                            (+ (imagpart w) (imagpart z))))
1124                (deftransform - ((w z) ((complex ,type) (complex ,type)) *)
1125                  '(complex (- (realpart w) (realpart z))
1126                            (- (imagpart w) (imagpart z))))
1127                ;; Add and subtract a complex and a real.
1128                (deftransform + ((w z) ((complex ,type) real) *)
1129                  '(complex (+ (realpart w) z) (imagpart w)))
1130                (deftransform + ((z w) (real (complex ,type)) *)
1131                  '(complex (+ (realpart w) z) (imagpart w)))
1132                ;; Add and subtract a real and a complex number.
1133                (deftransform - ((w z) ((complex ,type) real) *)
1134                  '(complex (- (realpart w) z) (imagpart w)))
1135                (deftransform - ((z w) (real (complex ,type)) *)
1136                  '(complex (- z (realpart w)) (- (imagpart w))))
1137                ;; Multiply and divide two complex numbers.
1138                (deftransform * ((x y) ((complex ,type) (complex ,type)) *)
1139                  '(let* ((rx (realpart x))
1140                          (ix (imagpart x))
1141                          (ry (realpart y))
1142                          (iy (imagpart y)))
1143                     (complex (- (* rx ry) (* ix iy))
1144                              (+ (* rx iy) (* ix ry)))))
1145                (deftransform / ((x y) ((complex ,type) (complex ,type)) *)
1146                  '(let* ((rx (realpart x))
1147                          (ix (imagpart x))
1148                          (ry (realpart y))
1149                          (iy (imagpart y)))
1150                     (if (> (abs ry) (abs iy))
1151                         (let* ((r (/ iy ry))
1152                                (dn (* ry (+ 1 (* r r)))))
1153                           (complex (/ (+ rx (* ix r)) dn)
1154                                    (/ (- ix (* rx r)) dn)))
1155                         (let* ((r (/ ry iy))
1156                                (dn (* iy (+ 1 (* r r)))))
1157                           (complex (/ (+ (* rx r) ix) dn)
1158                                    (/ (- (* ix r) rx) dn))))))
1159                ;; Multiply a complex by a real or vice versa.
1160                (deftransform * ((w z) ((complex ,type) real) *)
1161                  '(complex (* (realpart w) z) (* (imagpart w) z)))
1162                (deftransform * ((z w) (real (complex ,type)) *)
1163                  '(complex (* (realpart w) z) (* (imagpart w) z)))
1164                ;; Divide a complex by a real.
1165                (deftransform / ((w z) ((complex ,type) real) *)
1166                  '(complex (/ (realpart w) z) (/ (imagpart w) z)))
1167                ;; conjugate of complex number
1168                (deftransform conjugate ((z) ((complex ,type)) *)
1169                  '(complex (realpart z) (- (imagpart z))))
1170                ;; CIS
1171                (deftransform cis ((z) ((,type)) *)
1172                  '(complex (cos z) (sin z)))
1173                ;; comparison
1174                (deftransform = ((w z) ((complex ,type) (complex ,type)) *)
1175                  '(and (= (realpart w) (realpart z))
1176                        (= (imagpart w) (imagpart z))))
1177                (deftransform = ((w z) ((complex ,type) real) *)
1178                  '(and (= (realpart w) z) (zerop (imagpart w))))
1179                (deftransform = ((w z) (real (complex ,type)) *)
1180                  '(and (= (realpart z) w) (zerop (imagpart z)))))))
1181
1182   (frob single-float)
1183   (frob double-float))
1184
1185 ;;; Here are simple optimizers for SIN, COS, and TAN. They do not
1186 ;;; produce a minimal range for the result; the result is the widest
1187 ;;; possible answer. This gets around the problem of doing range
1188 ;;; reduction correctly but still provides useful results when the
1189 ;;; inputs are union types.
1190 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1191 (progn
1192 (defun trig-derive-type-aux (arg domain fcn
1193                                  &optional def-lo def-hi (increasingp t))
1194   (etypecase arg
1195     (numeric-type
1196      (cond ((eq (numeric-type-complexp arg) :complex)
1197             (make-numeric-type :class (numeric-type-class arg)
1198                                :format (numeric-type-format arg)
1199                                :complexp :complex))
1200            ((numeric-type-real-p arg)
1201             (let* ((format (case (numeric-type-class arg)
1202                              ((integer rational) 'single-float)
1203                              (t (numeric-type-format arg))))
1204                    (bound-type (or format 'float)))
1205               ;; If the argument is a subset of the "principal" domain
1206               ;; of the function, we can compute the bounds because
1207               ;; the function is monotonic. We can't do this in
1208               ;; general for these periodic functions because we can't
1209               ;; (and don't want to) do the argument reduction in
1210               ;; exactly the same way as the functions themselves do
1211               ;; it.
1212               (if (csubtypep arg domain)
1213                   (let ((res-lo (bound-func fcn (numeric-type-low arg)))
1214                         (res-hi (bound-func fcn (numeric-type-high arg))))
1215                     (unless increasingp
1216                       (rotatef res-lo res-hi))
1217                     (make-numeric-type
1218                      :class 'float
1219                      :format format
1220                      :low (coerce-numeric-bound res-lo bound-type)
1221                      :high (coerce-numeric-bound res-hi bound-type)))
1222                   (make-numeric-type
1223                    :class 'float
1224                    :format format
1225                    :low (and def-lo (coerce def-lo bound-type))
1226                    :high (and def-hi (coerce def-hi bound-type))))))
1227            (t
1228             (float-or-complex-float-type arg def-lo def-hi))))))
1229
1230 (defoptimizer (sin derive-type) ((num))
1231   (one-arg-derive-type
1232    num
1233    (lambda (arg)
1234      ;; Derive the bounds if the arg is in [-pi/2, pi/2].
1235      (trig-derive-type-aux
1236       arg
1237       (specifier-type `(float ,(- (/ pi 2)) ,(/ pi 2)))
1238       #'sin
1239       -1 1))
1240    #'sin))
1241
1242 (defoptimizer (cos derive-type) ((num))
1243   (one-arg-derive-type
1244    num
1245    (lambda (arg)
1246      ;; Derive the bounds if the arg is in [0, pi].
1247      (trig-derive-type-aux arg
1248                            (specifier-type `(float 0d0 ,pi))
1249                            #'cos
1250                            -1 1
1251                            nil))
1252    #'cos))
1253
1254 (defoptimizer (tan derive-type) ((num))
1255   (one-arg-derive-type
1256    num
1257    (lambda (arg)
1258      ;; Derive the bounds if the arg is in [-pi/2, pi/2].
1259      (trig-derive-type-aux arg
1260                            (specifier-type `(float ,(- (/ pi 2)) ,(/ pi 2)))
1261                            #'tan
1262                            nil nil))
1263    #'tan))
1264
1265 ;;; CONJUGATE always returns the same type as the input type.
1266 ;;;
1267 ;;; FIXME: ANSI allows any subtype of REAL for the components of COMPLEX.
1268 ;;; So what if the input type is (COMPLEX (SINGLE-FLOAT 0 1))?
1269 (defoptimizer (conjugate derive-type) ((num))
1270   (continuation-type num))
1271
1272 (defoptimizer (cis derive-type) ((num))
1273   (one-arg-derive-type num
1274      (lambda (arg)
1275        (sb!c::specifier-type
1276         `(complex ,(or (numeric-type-format arg) 'float))))
1277      #'cis))
1278
1279 ) ; PROGN
1280 \f
1281 ;;;; TRUNCATE, FLOOR, CEILING, and ROUND
1282
1283 (macrolet ((define-frobs (fun ufun)
1284              `(progn
1285                 (defknown ,ufun (real) integer (movable foldable flushable))
1286                 (deftransform ,fun ((x &optional by)
1287                                     (* &optional
1288                                        (constant-argument (member 1))))
1289                   '(let ((res (,ufun x)))
1290                      (values res (- x res)))))))
1291   (define-frobs truncate %unary-truncate)
1292   (define-frobs round %unary-round))
1293
1294 ;;; Convert (TRUNCATE x y) to the obvious implementation.  We only want
1295 ;;; this when under certain conditions and let the generic TRUNCATE
1296 ;;; handle the rest.  (Note: if Y = 1, the divide and multiply by Y
1297 ;;; should be removed by other DEFTRANSFORMs.)
1298 (deftransform truncate ((x &optional y)
1299                         (float &optional (or float integer)))
1300   (let ((defaulted-y (if y 'y 1)))
1301     `(let ((res (%unary-truncate (/ x ,defaulted-y))))
1302        (values res (- x (* ,defaulted-y res))))))
1303
1304 (deftransform floor ((number &optional divisor)
1305                      (float &optional (or integer float)))
1306   (let ((defaulted-divisor (if divisor 'divisor 1)))
1307     `(multiple-value-bind (tru rem) (truncate number ,defaulted-divisor)
1308        (if (and (not (zerop rem))
1309                 (if (minusp ,defaulted-divisor)
1310                     (plusp number)
1311                     (minusp number)))
1312            (values (1- tru) (+ rem ,defaulted-divisor))
1313            (values tru rem)))))
1314
1315 (deftransform ceiling ((number &optional divisor)
1316                        (float &optional (or integer float)))
1317   (let ((defaulted-divisor (if divisor 'divisor 1)))
1318     `(multiple-value-bind (tru rem) (truncate number ,defaulted-divisor)
1319        (if (and (not (zerop rem))
1320                 (if (minusp ,defaulted-divisor)
1321                     (minusp number)
1322                     (plusp number)))
1323            (values (1+ tru) (- rem ,defaulted-divisor))
1324            (values tru rem)))))