src/compiler/generic/objdef.lisp

   1 ;;;; machine-independent aspects of the object representation
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 ;;;; KLUDGE: The primitive objects here may look like self-contained
  15 ;;;; definitions, but in general they're not. In particular, if you
  16 ;;;; try to add a slot to them, beware of the following:
  17 ;;;;   * (mysterious crashes which occur after changing the length
  18 ;;;;     of SIMPLE-FUN, just adding a new slot not even doing anything
  19 ;;;;     with it, still dunno why)
  20 ;;;;   * The GC scavenging code (and for all I know other GC code too)
  21 ;;;;     is not automatically generated from these layouts, but instead
  22 ;;;;     was hand-written to correspond to them. The offsets are
  23 ;;;;     automatically propagated into the GC scavenging code, but the
  24 ;;;;     existence of slots, and whether they should be scavenged, is
  25 ;;;;     not automatically propagated. Thus e.g. if you add a
  26 ;;;;     SIMPLE-FUN-DEBUG-INFO slot holding a tagged object which needs
  27 ;;;;     to be GCed, you need to tweak scav_code_header() and
  28 ;;;;     verify_space() in gencgc.c, and the corresponding code in gc.c.
  29 ;;;;   * The src/runtime/print.c code (used by LDB) is implemented
  30 ;;;;     using hand-written lists of slot names, which aren't automatically
  31 ;;;;     generated from the code in this file.
  32 ;;;;   * Various code (e.g. STATIC-FSET in genesis.lisp) is hard-wired
  33 ;;;;     to know the name of the last slot of the object the code works
  34 ;;;;     with, and implicitly to know that the last slot is special (being
  35 ;;;;     the beginning of an arbitrary-length sequence of bytes following
  36 ;;;;     the fixed-layout slots).
  37 ;;;; -- WHN 2001-12-29
  38 \f
  39 ;;;; the primitive objects themselves
  40
  41 (define-primitive-object (cons :lowtag list-pointer-lowtag
  42                                :alloc-trans cons)
  43   (car :ref-trans car :set-trans sb!c::%rplaca :init :arg
  44        :cas-trans %compare-and-swap-car)
  45   (cdr :ref-trans cdr :set-trans sb!c::%rplacd :init :arg
  46        :cas-trans %compare-and-swap-cdr))
  47
  48 (define-primitive-object (instance :lowtag instance-pointer-lowtag
  49                                    :widetag instance-header-widetag
  50                                    :alloc-trans %make-instance)
  51   (slots :rest-p t))
  52
  53 (define-primitive-object (bignum :lowtag other-pointer-lowtag
  54                                  :widetag bignum-widetag
  55                                  :alloc-trans sb!bignum::%allocate-bignum)
  56   (digits :rest-p t :c-type #!-alpha "long" #!+alpha "u32"))
  57
  58 (define-primitive-object (ratio :type ratio
  59                                 :lowtag other-pointer-lowtag
  60                                 :widetag ratio-widetag
  61                                 :alloc-trans %make-ratio)
  62   (numerator :type integer
  63              :ref-known (flushable movable)
  64              :ref-trans %numerator
  65              :init :arg)
  66   (denominator :type integer
  67                :ref-known (flushable movable)
  68                :ref-trans %denominator
  69                :init :arg))
  70
  71 #!+#.(cl:if (cl:= sb!vm:n-word-bits 32) '(and) '(or))
  72 (define-primitive-object (single-float :lowtag other-pointer-lowtag
  73                                        :widetag single-float-widetag)
  74   (value :c-type "float"))
  75
  76 (define-primitive-object (double-float :lowtag other-pointer-lowtag
  77                                        :widetag double-float-widetag)
  78   #!-x86-64 (filler)
  79   (value :c-type "double" :length #!-x86-64 2 #!+x86-64 1))
  80
  81 #!+long-float
  82 (define-primitive-object (long-float :lowtag other-pointer-lowtag
  83                                      :widetag long-float-widetag)
  84   #!+sparc (filler)
  85   (value :c-type "long double" :length #!+x86 3 #!+sparc 4))
  86
  87 (define-primitive-object (complex :type complex
  88                                   :lowtag other-pointer-lowtag
  89                                   :widetag complex-widetag
  90                                   :alloc-trans %make-complex)
  91   (real :type real
  92         :ref-known (flushable movable)
  93         :ref-trans %realpart
  94         :init :arg)
  95   (imag :type real
  96         :ref-known (flushable movable)
  97         :ref-trans %imagpart
  98         :init :arg))
  99
 100 (define-primitive-object (array :lowtag other-pointer-lowtag
 101                                 :widetag t)
 102   ;; FILL-POINTER of an ARRAY is in the same place as LENGTH of a
 103   ;; VECTOR -- see SHRINK-VECTOR.
 104   (fill-pointer :type index
 105                 :ref-trans %array-fill-pointer
 106                 :ref-known (flushable foldable)
 107                 :set-trans (setf %array-fill-pointer)
 108                 :set-known (unsafe))
 109   (fill-pointer-p :type (member t nil)
 110                   :ref-trans %array-fill-pointer-p
 111                   :ref-known (flushable foldable)
 112                   :set-trans (setf %array-fill-pointer-p)
 113                   :set-known (unsafe))
 114   (elements :type index
 115             :ref-trans %array-available-elements
 116             :ref-known (flushable foldable)
 117             :set-trans (setf %array-available-elements)
 118             :set-known (unsafe))
 119   (data :type array
 120         :ref-trans %array-data-vector
 121         :ref-known (flushable foldable)
 122         :set-trans (setf %array-data-vector)
 123         :set-known (unsafe))
 124   (displacement :type (or index null)
 125                 :ref-trans %array-displacement
 126                 :ref-known (flushable foldable)
 127                 :set-trans (setf %array-displacement)
 128                 :set-known (unsafe))
 129   (displaced-p :type (member t nil)
 130                :ref-trans %array-displaced-p
 131                :ref-known (flushable foldable)
 132                :set-trans (setf %array-displaced-p)
 133                :set-known (unsafe))
 134   (displaced-from :type list
 135                   :ref-trans %array-displaced-from
 136                   :ref-known (flushable)
 137                   :set-trans (setf %array-displaced-from)
 138                   :set-known (unsafe)
 139                   :cas-trans %compare-and-swap-array-displaced-from
 140                   :cas-known (unsafe))
 141   (dimensions :rest-p t))
 142
 143 (define-primitive-object (vector :type vector
 144                                  :lowtag other-pointer-lowtag
 145                                  :widetag t)
 146   ;; FILL-POINTER of an ARRAY is in the same place as LENGTH of a
 147   ;; VECTOR -- see SHRINK-VECTOR.
 148   (length :ref-trans sb!c::vector-length
 149           :type index)
 150   (data :rest-p t :c-type #!-alpha "unsigned long" #!+alpha "u32"))
 151
 152 (define-primitive-object (code :type code-component
 153                                :lowtag other-pointer-lowtag
 154                                :widetag t)
 155   (code-size :type index
 156              :ref-known (flushable movable)
 157              :ref-trans %code-code-size)
 158   (entry-points :type (or function null)
 159                 :ref-known (flushable)
 160                 :ref-trans %code-entry-points
 161                 :set-known (unsafe)
 162                 :set-trans (setf %code-entry-points))
 163   (debug-info :type t
 164               :ref-known (flushable)
 165               :ref-trans %code-debug-info
 166               :set-known (unsafe)
 167               :set-trans (setf %code-debug-info))
 168   (trace-table-offset)
 169   (constants :rest-p t))
 170
 171 (define-primitive-object (fdefn :type fdefn
 172                                 :lowtag other-pointer-lowtag
 173                                 :widetag fdefn-widetag)
 174   (name :ref-trans fdefn-name)
 175   (fun :type (or function null) :ref-trans fdefn-fun)
 176   (raw-addr :c-type #!-alpha "char *" #!+alpha "u32"))
 177
 178 ;;; a simple function (as opposed to hairier things like closures
 179 ;;; which are also subtypes of Common Lisp's FUNCTION type)
 180 (define-primitive-object (simple-fun :type function
 181                                      :lowtag fun-pointer-lowtag
 182                                      :widetag simple-fun-header-widetag)
 183   #!-(or x86 x86-64) (self :ref-trans %simple-fun-self
 184                :set-trans (setf %simple-fun-self))
 185   #!+(or x86 x86-64) (self
 186           ;; KLUDGE: There's no :SET-KNOWN, :SET-TRANS, :REF-KNOWN, or
 187           ;; :REF-TRANS here in this case. Instead, there's separate
 188           ;; DEFKNOWN/DEFINE-VOP/DEFTRANSFORM stuff in
 189           ;; compiler/x86/system.lisp to define and declare them by
 190           ;; hand. I don't know why this is, but that's (basically)
 191           ;; the way it was done in CMU CL, and it works. (It's not
 192           ;; exactly the same way it was done in CMU CL in that CMU
 193           ;; CL's allows duplicate DEFKNOWNs, blithely overwriting any
 194           ;; previous data associated with the previous DEFKNOWN, and
 195           ;; that property was used to mask the definitions here. In
 196           ;; SBCL as of 0.6.12.64 that's not allowed -- too confusing!
 197           ;; -- so we have to explicitly suppress the DEFKNOWNish
 198           ;; stuff here in order to allow this old hack to work in the
 199           ;; new world. -- WHN 2001-08-82
 200           )
 201   (next :type (or function null)
 202         :ref-known (flushable)
 203         :ref-trans %simple-fun-next
 204         :set-known (unsafe)
 205         :set-trans (setf %simple-fun-next))
 206   (name :ref-known (flushable)
 207         :ref-trans %simple-fun-name
 208         :set-known (unsafe)
 209         :set-trans (setf %simple-fun-name))
 210   (arglist :type list
 211            :ref-known (flushable)
 212            :ref-trans %simple-fun-arglist
 213            :set-known (unsafe)
 214            :set-trans (setf %simple-fun-arglist))
 215   (type :ref-known (flushable)
 216         :ref-trans %simple-fun-type
 217         :set-known (unsafe)
 218         :set-trans (setf %simple-fun-type))
 219   (xrefs :init :null
 220          :ref-trans %simple-fun-xrefs
 221          :ref-known (flushable)
 222          :set-trans (setf %simple-fun-xrefs)
 223          :set-known ())
 224   ;; the SB!C::DEBUG-FUN object corresponding to this object, or NIL for none
 225   #+nil ; FIXME: doesn't work (gotcha, lowly maintenoid!) See notes on bug 137.
 226   (debug-fun :ref-known (flushable)
 227              :ref-trans %simple-fun-debug-fun
 228              :set-known (unsafe)
 229              :set-trans (setf %simple-fun-debug-fun))
 230   (code :rest-p t :c-type "unsigned char"))
 231
 232 (define-primitive-object (return-pc :lowtag other-pointer-lowtag :widetag t)
 233   (return-point :c-type "unsigned char" :rest-p t))
 234
 235 (define-primitive-object (closure :lowtag fun-pointer-lowtag
 236                                   :widetag closure-header-widetag)
 237   (fun :init :arg :ref-trans %closure-fun)
 238   (info :rest-p t))
 239
 240 (define-primitive-object (funcallable-instance
 241                           :lowtag fun-pointer-lowtag
 242                           :widetag funcallable-instance-header-widetag
 243                           :alloc-trans %make-funcallable-instance)
 244   (trampoline :init :funcallable-instance-tramp)
 245   (function :ref-known (flushable) :ref-trans %funcallable-instance-function
 246             :set-known (unsafe) :set-trans (setf %funcallable-instance-function))
 247   (info :rest-p t))
 248
 249 (define-primitive-object (value-cell :lowtag other-pointer-lowtag
 250                                      :widetag value-cell-header-widetag
 251                                      ;; FIXME: We also have an explicit VOP
 252                                      ;; for this. Is this needed as well?
 253                                      :alloc-trans make-value-cell)
 254   (value :set-trans value-cell-set
 255          :set-known (unsafe)
 256          :ref-trans value-cell-ref
 257          :ref-known (flushable)
 258          :init :arg))
 259
 260 #!+alpha
 261 (define-primitive-object (sap :lowtag other-pointer-lowtag
 262                               :widetag sap-widetag)
 263   (padding)
 264   (pointer :c-type "char *" :length 2))
 265
 266 #!-alpha
 267 (define-primitive-object (sap :lowtag other-pointer-lowtag
 268                               :widetag sap-widetag)
 269   (pointer :c-type "char *"))
 270
 271
 272 (define-primitive-object (weak-pointer :type weak-pointer
 273                                        :lowtag other-pointer-lowtag
 274                                        :widetag weak-pointer-widetag
 275                                        :alloc-trans make-weak-pointer)
 276   (value :ref-trans sb!c::%weak-pointer-value :ref-known (flushable)
 277          :init :arg)
 278   (broken :type (member t nil)
 279           :ref-trans sb!c::%weak-pointer-broken :ref-known (flushable)
 280           :init :null)
 281   (next :c-type #!-alpha "struct weak_pointer *" #!+alpha "u32"))
 282
 283 ;;;; other non-heap data blocks
 284
 285 (define-primitive-object (binding)
 286   value
 287   symbol)
 288
 289 (define-primitive-object (unwind-block)
 290   (current-uwp :c-type #!-alpha "struct unwind_block *" #!+alpha "u32")
 291   (current-cont :c-type #!-alpha "lispobj *" #!+alpha "u32")
 292   #!-(or x86 x86-64) current-code
 293   entry-pc
 294   #!+win32 next-seh-frame
 295   #!+win32 seh-frame-handler)
 296
 297 (define-primitive-object (catch-block)
 298   (current-uwp :c-type #!-alpha "struct unwind_block *" #!+alpha "u32")
 299   (current-cont :c-type #!-alpha "lispobj *" #!+alpha "u32")
 300   #!-(or x86 x86-64) current-code
 301   entry-pc
 302   #!+win32 next-seh-frame
 303   #!+win32 seh-frame-handler
 304   tag
 305   (previous-catch :c-type #!-alpha "struct catch_block *" #!+alpha "u32"))
 306
 307 ;;; (For an explanation of this, see the comments at the definition of
 308 ;;; KLUDGE-NONDETERMINISTIC-CATCH-BLOCK-SIZE.)
 309 (aver (= kludge-nondeterministic-catch-block-size catch-block-size))
 310 \f
 311 ;;;; symbols
 312
 313 (define-primitive-object (symbol :lowtag other-pointer-lowtag
 314                                  :widetag symbol-header-widetag
 315                                  :alloc-trans %make-symbol)
 316
 317   ;; Beware when changing this definition.  NIL-the-symbol is defined
 318   ;; using this layout, and NIL-the-end-of-list-marker is the cons
 319   ;; ( NIL . NIL ), living in the first two slots of NIL-the-symbol
 320   ;; (conses have no header).  Careful selection of lowtags ensures
 321   ;; that the same pointer can be used for both purposes:
 322   ;; OTHER-POINTER-LOWTAG is 7, LIST-POINTER-LOWTAG is 3, so if you
 323   ;; subtract 3 from (SB-KERNEL:GET-LISP-OBJ-ADDRESS 'NIL) you get the
 324   ;; first data slot, and if you subtract 7 you get a symbol header.
 325
 326   ;; also the CAR of NIL-as-end-of-list
 327   (value :init :unbound :ref-known (flushable) :ref-trans symbol-global-value)
 328   ;; also the CDR of NIL-as-end-of-list.  Its reffer needs special
 329   ;; care for this reason, as hash values must be fixnums.
 330   (hash :set-trans %set-symbol-hash)
 331
 332   (plist :ref-trans symbol-plist
 333          :set-trans %set-symbol-plist
 334          :cas-trans %compare-and-swap-symbol-plist
 335          :type list
 336          :init :null)
 337   (name :ref-trans symbol-name :init :arg)
 338   (package :ref-trans symbol-package
 339            :set-trans %set-symbol-package
 340            :init :null)
 341   #!+sb-thread (tls-index :ref-known (flushable) :ref-trans symbol-tls-index))
 342
 343 (define-primitive-object (complex-single-float
 344                           :lowtag other-pointer-lowtag
 345                           :widetag complex-single-float-widetag)
 346   (real :c-type "float")
 347   (imag :c-type "float"))
 348
 349 (define-primitive-object (complex-double-float
 350                           :lowtag other-pointer-lowtag
 351                           :widetag complex-double-float-widetag)
 352   #!-x86-64 (filler)
 353   (real :c-type "double" :length #!-x86-64 2 #!+x86-64 1)
 354   (imag :c-type "double" :length #!-x86-64 2 #!+x86-64 1))
 355
 356 #!+(and sb-lutex sb-thread)
 357 (define-primitive-object (lutex
 358                           :lowtag other-pointer-lowtag
 359                           :widetag lutex-widetag
 360                           :alloc-trans %make-lutex)
 361   (gen :c-type "long" :length 1)
 362   (live :c-type "long" :length 1)
 363   (next :c-type "struct lutex *" :length 1)
 364   (prev :c-type "struct lutex *" :length 1)
 365   (mutex :c-type "pthread_mutex_t *"
 366          :length 1)
 367   (mutexattr :c-type "pthread_mutexattr_t *"
 368              :length 1)
 369   (condition-variable :c-type "pthread_cond_t *"
 370                       :length 1))
 371
 372 ;;; this isn't actually a lisp object at all, it's a c structure that lives
 373 ;;; in c-land.  However, we need sight of so many parts of it from Lisp that
 374 ;;; it makes sense to define it here anyway, so that the GENESIS machinery
 375 ;;; can take care of maintaining Lisp and C versions.
 376 ;;; Hence the even-fixnum lowtag just so we don't get odd(sic) numbers
 377 ;;; added to the slot offsets
 378 (define-primitive-object (thread :lowtag even-fixnum-lowtag)
 379   ;; no_tls_value_marker is borrowed very briefly at thread startup to
 380   ;; pass the address of initial-function into new_thread_trampoline.
 381   ;; tls[0] = NO_TLS_VALUE_MARKER_WIDETAG because a the tls index slot
 382   ;; of a symbol is initialized to zero
 383   (no-tls-value-marker)
 384   (os-thread :c-type "os_thread_t")
 385   ;; This is the original address at which the memory was allocated,
 386   ;; which may have different alignment then what we prefer to use.
 387   ;; Kept here so that when the thread dies we can release the whole
 388   ;; memory we reserved.
 389   (os-address :c-type "void *" :length #!+alpha 2 #!-alpha 1)
 390   #!+sb-thread
 391   (os-attr :c-type "pthread_attr_t *" :length #!+alpha 2 #!-alpha 1)
 392   #!+sb-thread
 393   (state-lock :c-type "pthread_mutex_t *" :length #!+alpha 2 #!-alpha 1)
 394   #!+sb-thread
 395   (state-cond :c-type "pthread_cond_t *" :length #!+alpha 2 #!-alpha 1)
 396   (binding-stack-start :c-type "lispobj *" :length #!+alpha 2 #!-alpha 1)
 397   (binding-stack-pointer :c-type "lispobj *" :length #!+alpha 2 #!-alpha 1)
 398   (control-stack-start :c-type "lispobj *" :length #!+alpha 2 #!-alpha 1)
 399   (control-stack-end :c-type "lispobj *" :length #!+alpha 2 #!-alpha 1)
 400   (alien-stack-start :c-type "lispobj *" :length #!+alpha 2 #!-alpha 1)
 401   (alien-stack-pointer :c-type "lispobj *" :length #!+alpha 2 #!-alpha 1)
 402   #!+gencgc (alloc-region :c-type "struct alloc_region" :length 5)
 403   (this :c-type "struct thread *" :length #!+alpha 2 #!-alpha 1)
 404   (prev :c-type "struct thread *" :length #!+alpha 2 #!-alpha 1)
 405   (next :c-type "struct thread *" :length #!+alpha 2 #!-alpha 1)
 406   ;; starting, running, suspended, dead
 407   (state :c-type "lispobj")
 408   (tls-cookie)                          ;  on x86, the LDT index
 409   #!+(or x86 x86-64) (pseudo-atomic-bits)
 410   (interrupt-data :c-type "struct interrupt_data *"
 411                   :length #!+alpha 2 #!-alpha 1)
 412   (stepping)
 413   ;; KLUDGE: On alpha, until STEPPING we have been lucky and the 32
 414   ;; bit slots came in pairs. However the C compiler will align
 415   ;; interrupt_contexts on a double word boundary. This logic should
 416   ;; be handled by DEFINE-PRIMITIVE-OBJECT.
 417   #!+alpha
 418   (padding)
 419   (interrupt-contexts :c-type "os_context_t *" :rest-p t))